cgit.sxemacs.org Git - gnus/blob - lisp/gnus-win.el

   1 ;;; gnus-win.el --- window configuration functions for Gnus
   2
   3 ;; Copyright (C) 1996-2011 Free Software Foundation, Inc.
   4
   5 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   6 ;; Keywords: news
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;;; Code:
  26
  27 (eval-when-compile (require 'cl))
  28
  29 (require 'gnus)
  30 (require 'gnus-util)
  31
  32 (defgroup gnus-windows nil
  33   "Window configuration."
  34   :group 'gnus)
  35
  36 (defcustom gnus-use-full-window t
  37   "*If non-nil, use the entire Emacs screen."
  38   :group 'gnus-windows
  39   :type 'boolean)
  40
  41 (defcustom gnus-window-min-width 2
  42   "*Minimum width of Gnus buffers."
  43   :group 'gnus-windows
  44   :type 'integer)
  45
  46 (defcustom gnus-window-min-height 1
  47   "*Minimum height of Gnus buffers."
  48   :group 'gnus-windows
  49   :type 'integer)
  50
  51 (defcustom gnus-always-force-window-configuration nil
  52   "*If non-nil, always force the Gnus window configurations."
  53   :group 'gnus-windows
  54   :type 'boolean)
  55
  56 (defcustom gnus-use-frames-on-any-display nil
  57   "*If non-nil, frames on all displays will be considered useable by Gnus.
  58 When nil, only frames on the same display as the selected frame will be
  59 used to display Gnus windows."
  60   :version "22.1"
  61   :group 'gnus-windows
  62   :type 'boolean)
  63
  64 (defvar gnus-buffer-configuration
  65   '((group
  66      (vertical 1.0
  67                (group 1.0 point)))
  68     (summary
  69      (vertical 1.0
  70                (summary 1.0 point)))
  71     (article
  72      (cond
  73       (gnus-use-trees
  74        '(vertical 1.0
  75                   (summary 0.25 point)
  76                   (tree 0.25)
  77                   (article 1.0)))
  78       (t
  79        '(vertical 1.0
  80                   (summary 0.25 point)
  81                   (article 1.0)))))
  82     (server
  83      (vertical 1.0
  84                (server 1.0 point)))
  85     (browse
  86      (vertical 1.0
  87                (browse 1.0 point)))
  88     (message
  89      (vertical 1.0
  90                (message 1.0 point)))
  91     (pick
  92      (vertical 1.0
  93                (article 1.0 point)))
  94     (info
  95      (vertical 1.0
  96                (info 1.0 point)))
  97     (summary-faq
  98      (vertical 1.0
  99                (summary 0.25)
 100                (faq 1.0 point)))
 101     (only-article
 102      (vertical 1.0
 103                (article 1.0 point)))
 104     (edit-article
 105      (vertical 1.0
 106                (article 1.0 point)))
 107     (edit-form
 108      (vertical 1.0
 109                (group 0.5)
 110                (edit-form 1.0 point)))
 111     (edit-score
 112      (vertical 1.0
 113                (summary 0.25)
 114                (edit-score 1.0 point)))
 115     (edit-server
 116      (vertical 1.0
 117                (server 0.5)
 118                (edit-form 1.0 point)))
 119     (post
 120      (vertical 1.0
 121                (post 1.0 point)))
 122     (reply
 123      (vertical 1.0
 124                (article 0.5)
 125                (message 1.0 point)))
 126     (forward
 127      (vertical 1.0
 128                (message 1.0 point)))
 129     (reply-yank
 130      (vertical 1.0
 131                (message 1.0 point)))
 132     (mail-bounce
 133      (vertical 1.0
 134                (article 0.5)
 135                (message 1.0 point)))
 136     (pipe
 137      (vertical 1.0
 138                (summary 0.25 point)
 139                ("*Shell Command Output*" 1.0)))
 140     (bug
 141      (vertical 1.0
 142                (if gnus-bug-create-help-buffer '("*Gnus Help Bug*" 0.5))
 143                ("*Gnus Bug*" 1.0 point)))
 144     (score-trace
 145      (vertical 1.0
 146                (summary 0.5 point)
 147                ("*Score Trace*" 1.0)))
 148     (score-words
 149      (vertical 1.0
 150                (summary 0.5 point)
 151                ("*Score Words*" 1.0)))
 152     (split-trace
 153      (vertical 1.0
 154                (summary 0.5 point)
 155                ("*Split Trace*" 1.0)))
 156     (category
 157      (vertical 1.0
 158                (category 1.0)))
 159     (compose-bounce
 160      (vertical 1.0
 161                (article 0.5)
 162                (message 1.0 point)))
 163     (display-term
 164      (vertical 1.0
 165                ("*display*" 1.0)))
 166     (mml-preview
 167      (vertical 1.0
 168                (message 0.5)
 169                (mml-preview 1.0 point))))
 170   "Window configuration for all possible Gnus buffers.
 171 See the Gnus manual for an explanation of the syntax used.")
 172
 173 (defvar gnus-window-to-buffer
 174   '((group . gnus-group-buffer)
 175     (summary . gnus-summary-buffer)
 176     (article . gnus-article-buffer)
 177     (server . gnus-server-buffer)
 178     (browse . "*Gnus Browse Server*")
 179     (edit-group . gnus-group-edit-buffer)
 180     (edit-form . gnus-edit-form-buffer)
 181     (edit-server . gnus-server-edit-buffer)
 182     (edit-score . gnus-score-edit-buffer)
 183     (message . gnus-message-buffer)
 184     (mail . gnus-message-buffer)
 185     (post-news . gnus-message-buffer)
 186     (faq . gnus-faq-buffer)
 187     (tree . gnus-tree-buffer)
 188     (score-trace . "*Score Trace*")
 189     (split-trace . "*Split Trace*")
 190     (info . gnus-info-buffer)
 191     (category . gnus-category-buffer)
 192     (article-copy . gnus-article-copy)
 193     (draft . gnus-draft-buffer)
 194     (mml-preview . mml-preview-buffer))
 195   "Mapping from short symbols to buffer names or buffer variables.")
 196
 197 (defcustom gnus-configure-windows-hook nil
 198   "*A hook called when configuring windows."
 199   :version "22.1"
 200   :group 'gnus-windows
 201   :type 'hook)
 202
 203 ;;; Internal variables.
 204
 205 (defvar gnus-current-window-configuration nil
 206   "The most recently set window configuration.")
 207
 208 (defvar gnus-created-frames nil)
 209 (defvar gnus-window-frame-focus nil)
 210
 211 (defun gnus-kill-gnus-frames ()
 212   "Kill all frames Gnus has created."
 213   (while gnus-created-frames
 214     (when (frame-live-p (car gnus-created-frames))
 215       ;; We slap a condition-case around this `delete-frame' to ensure
 216       ;; against errors if we try do delete the single frame that's left.
 217       (ignore-errors
 218         (delete-frame (car gnus-created-frames))))
 219     (pop gnus-created-frames)))
 220
 221 ;;;###autoload
 222 (defun gnus-add-configuration (conf)
 223   "Add the window configuration CONF to `gnus-buffer-configuration'."
 224   (setq gnus-buffer-configuration
 225         (cons conf (delq (assq (car conf) gnus-buffer-configuration)
 226                          gnus-buffer-configuration))))
 227
 228 (defvar gnus-frame-list nil)
 229
 230 (defun gnus-window-to-buffer-helper (obj)
 231   (cond ((not (symbolp obj))
 232          obj)
 233         ((boundp obj)
 234          (symbol-value obj))
 235         ((fboundp obj)
 236          (funcall obj))
 237         (t
 238          nil)))
 239
 240 (defun gnus-configure-frame (split &optional window)
 241   "Split WINDOW according to SPLIT."
 242   (let* ((current-window (or (get-buffer-window (current-buffer)) (selected-window)))
 243          (window (or window current-window)))
 244     (select-window window)
 245     ;; The SPLIT might be something that is to be evaled to
 246     ;; return a new SPLIT.
 247     (while (and (not (assq (car split) gnus-window-to-buffer))
 248                 (symbolp (car split)) (fboundp (car split)))
 249       (setq split (eval split)))
 250     (let* ((type (car split))
 251            (subs (cddr split))
 252            (len (if (eq type 'horizontal) (window-width) (window-height)))
 253            (total 0)
 254            (window-min-width (or gnus-window-min-width window-min-width))
 255            (window-min-height (or gnus-window-min-height window-min-height))
 256            s result new-win rest comp-subs size sub)
 257       (cond
 258        ;; Nothing to do here.
 259        ((null split))
 260        ;; Don't switch buffers.
 261        ((null type)
 262         (and (memq 'point split) window))
 263        ;; This is a buffer to be selected.
 264        ((not (memq type '(frame horizontal vertical)))
 265         (let ((buffer (cond ((stringp type) type)
 266                             (t (cdr (assq type gnus-window-to-buffer))))))
 267           (unless buffer
 268             (error "Invalid buffer type: %s" type))
 269           (let ((buf (gnus-get-buffer-create
 270                       (gnus-window-to-buffer-helper buffer))))
 271             (when (buffer-name buf)
 272               (if (eq buf (window-buffer (selected-window)))
 273                   (set-buffer buf)
 274                 (switch-to-buffer buf))))
 275           (when (memq 'frame-focus split)
 276             (setq gnus-window-frame-focus window))
 277           ;; We return the window if it has the `point' spec.
 278           (and (memq 'point split) window)))
 279        ;; This is a frame split.
 280        ((eq type 'frame)
 281         (unless gnus-frame-list
 282           (setq gnus-frame-list (list (window-frame current-window))))
 283         (let ((i 0)
 284               params frame fresult)
 285           (while (< i (length subs))
 286             ;; Frame parameter is gotten from the sub-split.
 287             (setq params (cadr (elt subs i)))
 288             ;; It should be a list.
 289             (unless (listp params)
 290               (setq params nil))
 291             ;; Create a new frame?
 292             (unless (setq frame (elt gnus-frame-list i))
 293               (nconc gnus-frame-list (list (setq frame (make-frame params))))
 294               (push frame gnus-created-frames))
 295             ;; Is the old frame still alive?
 296             (unless (frame-live-p frame)
 297               (setcar (nthcdr i gnus-frame-list)
 298                       (setq frame (make-frame params))))
 299             ;; Select the frame in question and do more splits there.
 300             (select-frame frame)
 301             (setq fresult (or (gnus-configure-frame (elt subs i)) fresult))
 302             (incf i))
 303           ;; Select the frame that has the selected buffer.
 304           (when fresult
 305             (select-frame (window-frame fresult)))))
 306        ;; This is a normal split.
 307        (t
 308         (when (> (length subs) 0)
 309           ;; First we have to compute the sizes of all new windows.
 310           (while subs
 311             (setq sub (append (pop subs) nil))
 312             (while (and (not (assq (car sub) gnus-window-to-buffer))
 313                         (symbolp (car sub)) (fboundp (car sub)))
 314               (setq sub (eval sub)))
 315             (when sub
 316               (push sub comp-subs)
 317               (setq size (cadar comp-subs))
 318               (cond ((equal size 1.0)
 319                      (setq rest (car comp-subs))
 320                      (setq s 0))
 321                     ((floatp size)
 322                      (setq s (floor (* size len))))
 323                     ((integerp size)
 324                      (setq s size))
 325                     (t
 326                      (error "Invalid size: %s" size)))
 327               ;; Try to make sure that we are inside the safe limits.
 328               (cond ((zerop s))
 329                     ((eq type 'horizontal)
 330                      (setq s (max s window-min-width)))
 331                     ((eq type 'vertical)
 332                      (setq s (max s window-min-height))))
 333               (setcar (cdar comp-subs) s)
 334               (incf total s)))
 335           ;; Take care of the "1.0" spec.
 336           (if rest
 337               (setcar (cdr rest) (- len total))
 338             (error "No 1.0 specs in %s" split))
 339           ;; The we do the actual splitting in a nice recursive
 340           ;; fashion.
 341           (setq comp-subs (nreverse comp-subs))
 342           (while comp-subs
 343             (if (null (cdr comp-subs))
 344                 (setq new-win window)
 345               (setq new-win
 346                     (split-window window (cadar comp-subs)
 347                                   (eq type 'horizontal))))
 348             (setq result (or (gnus-configure-frame
 349                               (car comp-subs) window)
 350                              result))
 351             (select-window new-win)
 352             (setq window new-win)
 353             (setq comp-subs (cdr comp-subs))))
 354         ;; Return the proper window, if any.
 355         (when result
 356           (select-window result)))))))
 357
 358 (defvar gnus-frame-split-p nil)
 359
 360 (defun gnus-configure-windows (setting &optional force)
 361   (if (window-configuration-p setting)
 362       (set-window-configuration setting)
 363     (setq gnus-current-window-configuration setting)
 364     (setq force (or force gnus-always-force-window-configuration))
 365     (let ((split (if (symbolp setting)
 366                      (cadr (assq setting gnus-buffer-configuration))
 367                    setting))
 368           all-visible)
 369
 370       (setq gnus-frame-split-p nil)
 371
 372       (unless split
 373         (error "No such setting in `gnus-buffer-configuration': %s" setting))
 374
 375       (if (and (setq all-visible (gnus-all-windows-visible-p split))
 376                (not force))
 377           ;; All the windows mentioned are already visible, so we just
 378           ;; put point in the assigned buffer, and do not touch the
 379           ;; winconf.
 380           (select-window all-visible)
 381
 382         ;; Make sure "the other" buffer, nntp-server-buffer, is live.
 383         (unless (gnus-buffer-live-p nntp-server-buffer)
 384           (nnheader-init-server-buffer))
 385
 386         ;; Either remove all windows or just remove all Gnus windows.
 387         (let ((frame (selected-frame)))
 388           (unwind-protect
 389               (if gnus-use-full-window
 390                   ;; We want to remove all other windows.
 391                   (if (not gnus-frame-split-p)
 392                       ;; This is not a `frame' split, so we ignore the
 393                       ;; other frames.
 394                       (delete-other-windows)
 395                     ;; This is a `frame' split, so we delete all windows
 396                     ;; on all frames.
 397                     (gnus-delete-windows-in-gnusey-frames))
 398                 ;; Just remove some windows.
 399                 (gnus-remove-some-windows)
 400                 (if (featurep 'xemacs)
 401                     (switch-to-buffer nntp-server-buffer)
 402                   (set-buffer nntp-server-buffer)))
 403             (select-frame frame)))
 404
 405         (let (gnus-window-frame-focus)
 406           (if (featurep 'xemacs)
 407               (switch-to-buffer nntp-server-buffer)
 408             (set-buffer nntp-server-buffer))
 409           (gnus-configure-frame split)
 410           (run-hooks 'gnus-configure-windows-hook)
 411           (when gnus-window-frame-focus
 412             (gnus-select-frame-set-input-focus
 413              (window-frame gnus-window-frame-focus))))))))
 414
 415 (defun gnus-delete-windows-in-gnusey-frames ()
 416   "Do a `delete-other-windows' in all frames that have Gnus windows."
 417   (let ((buffers (gnus-buffers)))
 418     (mapcar
 419      (lambda (frame)
 420        (unless (eq (cdr (assq 'minibuffer
 421                               (frame-parameters frame)))
 422                    'only)
 423          (select-frame frame)
 424          (let (do-delete)
 425            (walk-windows
 426             (lambda (window)
 427               (when (memq (window-buffer window) buffers)
 428                 (setq do-delete t))))
 429            (when do-delete
 430              (delete-other-windows)))))
 431      (frame-list))))
 432
 433 (defun gnus-all-windows-visible-p (split)
 434   "Say whether all buffers in SPLIT are currently visible.
 435 In particular, the value returned will be the window that
 436 should have point."
 437   (let ((stack (list split))
 438         (all-visible t)
 439         type buffer win buf)
 440     (while (and (setq split (pop stack))
 441                 all-visible)
 442       (when (consp (car split))
 443         (push 1.0 split)
 444         (push 'vertical split))
 445       ;; The SPLIT might be something that is to be evaled to
 446       ;; return a new SPLIT.
 447       (while (and (not (assq (car split) gnus-window-to-buffer))
 448                   (symbolp (car split)) (fboundp (car split)))
 449         (setq split (eval split)))
 450
 451       (setq type (elt split 0))
 452       (cond
 453        ;; Nothing here.
 454        ((null split) t)
 455        ;; A buffer.
 456        ((not (memq type '(horizontal vertical frame)))
 457         (setq buffer (cond ((stringp type) type)
 458                            (t (cdr (assq type gnus-window-to-buffer)))))
 459         (unless buffer
 460           (error "Invalid buffer type: %s" type))
 461         (if (and (setq buf (get-buffer (gnus-window-to-buffer-helper buffer)))
 462                  (setq win (gnus-get-buffer-window buf t)))
 463             (if (memq 'point split)
 464                 (setq all-visible win))
 465           (setq all-visible nil)))
 466        (t
 467         (when (eq type 'frame)
 468           (setq gnus-frame-split-p t))
 469         (setq stack (append (cddr split) stack)))))
 470     (unless (eq all-visible t)
 471       all-visible)))
 472
 473 (defun gnus-window-top-edge (&optional window)
 474   "Return the top coordinate of WINDOW."
 475   (nth 1 (window-edges window)))
 476
 477 (defun gnus-remove-some-windows ()
 478   (let ((buffers (gnus-buffers))
 479         buf bufs lowest-buf lowest)
 480     (save-excursion
 481       ;; Remove windows on all known Gnus buffers.
 482       (while (setq buf (pop buffers))
 483         (when (get-buffer-window buf)
 484           (push buf bufs)
 485           (pop-to-buffer buf)
 486           (when (or (not lowest)
 487                     (< (gnus-window-top-edge) lowest))
 488             (setq lowest (gnus-window-top-edge)
 489                   lowest-buf buf))))
 490       (when lowest-buf
 491         (pop-to-buffer lowest-buf)
 492         (if (featurep 'xemacs)
 493             (switch-to-buffer nntp-server-buffer)
 494           (set-buffer nntp-server-buffer)))
 495       (mapcar (lambda (b) (delete-windows-on b t))
 496               (delq lowest-buf bufs)))))
 497
 498 (eval-and-compile
 499   (cond
 500    ((fboundp 'frames-on-display-list)
 501     (defalias 'gnus-frames-on-display-list 'frames-on-display-list))
 502    ((and (featurep 'xemacs) (fboundp 'frame-device))
 503     (defun gnus-frames-on-display-list ()
 504       (apply 'filtered-frame-list 'identity (list (frame-device nil)))))
 505    (t
 506     (defalias 'gnus-frames-on-display-list 'frame-list))))
 507
 508 (defun gnus-get-buffer-window (buffer &optional frame)
 509   (cond ((and (null gnus-use-frames-on-any-display)
 510               (memq frame '(t 0 visible)))
 511          (car
 512           (let ((frames (gnus-frames-on-display-list)))
 513             (gnus-remove-if (lambda (win) (not (memq (window-frame win)
 514                                                      frames)))
 515                             (get-buffer-window-list buffer nil frame)))))
 516         (t
 517          (get-buffer-window buffer frame))))
 518
 519 (provide 'gnus-win)
 520
 521 ;;; gnus-win.el ends here