cgit.sxemacs.org Git - gnus/blob - lisp/gnus-win.el

   1 ;;; gnus-win.el --- window configuration functions for Gnus
   2
   3 ;; Copyright (C) 1996-2011 Free Software Foundation, Inc.
   4
   5 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   6 ;; Keywords: news
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;;; Code:
  26
  27 (eval-when-compile (require 'cl))
  28
  29 (require 'gnus)
  30 (require 'gnus-util)
  31
  32 (defgroup gnus-windows nil
  33   "Window configuration."
  34   :group 'gnus)
  35
  36 (defcustom gnus-use-full-window t
  37   "*If non-nil, use the entire Emacs screen."
  38   :group 'gnus-windows
  39   :type 'boolean)
  40
  41 (defcustom gnus-window-min-width 2
  42   "*Minimum width of Gnus buffers."
  43   :group 'gnus-windows
  44   :type 'integer)
  45
  46 (defcustom gnus-window-min-height 1
  47   "*Minimum height of Gnus buffers."
  48   :group 'gnus-windows
  49   :type 'integer)
  50
  51 (defcustom gnus-always-force-window-configuration nil
  52   "*If non-nil, always force the Gnus window configurations."
  53   :group 'gnus-windows
  54   :type 'boolean)
  55
  56 (defcustom gnus-use-frames-on-any-display nil
  57   "*If non-nil, frames on all displays will be considered useable by Gnus.
  58 When nil, only frames on the same display as the selected frame will be
  59 used to display Gnus windows."
  60   :version "22.1"
  61   :group 'gnus-windows
  62   :type 'boolean)
  63
  64 (defvar gnus-buffer-configuration
  65   '((group
  66      (vertical 1.0
  67                (group 1.0 point)))
  68     (summary
  69      (vertical 1.0
  70                (summary 1.0 point)))
  71     (article
  72      (cond
  73       (gnus-use-trees
  74        '(vertical 1.0
  75                   (summary 0.25 point)
  76                   (tree 0.25)
  77                   (article 1.0)))
  78       (t
  79        '(vertical 1.0
  80                   (summary 0.25 point)
  81                   (article 1.0)))))
  82     (server
  83      (vertical 1.0
  84                (server 1.0 point)))
  85     (browse
  86      (vertical 1.0
  87                (browse 1.0 point)))
  88     (message
  89      (vertical 1.0
  90                (message 1.0 point)))
  91     (pick
  92      (vertical 1.0
  93                (article 1.0 point)))
  94     (info
  95      (vertical 1.0
  96                (info 1.0 point)))
  97     (summary-faq
  98      (vertical 1.0
  99                (summary 0.25)
 100                (faq 1.0 point)))
 101     (only-article
 102      (vertical 1.0
 103                (article 1.0 point)))
 104     (edit-article
 105      (vertical 1.0
 106                (article 1.0 point)))
 107     (edit-form
 108      (vertical 1.0
 109                (group 0.5)
 110                (edit-form 1.0 point)))
 111     (edit-score
 112      (vertical 1.0
 113                (summary 0.25)
 114                (edit-score 1.0 point)))
 115     (edit-server
 116      (vertical 1.0
 117                (server 0.5)
 118                (edit-form 1.0 point)))
 119     (post
 120      (vertical 1.0
 121                (post 1.0 point)))
 122     (reply
 123      (vertical 1.0
 124                (article 0.5)
 125                (message 1.0 point)))
 126     (forward
 127      (vertical 1.0
 128                (message 1.0 point)))
 129     (reply-yank
 130      (vertical 1.0
 131                (message 1.0 point)))
 132     (mail-bounce
 133      (vertical 1.0
 134                (article 0.5)
 135                (message 1.0 point)))
 136     (pipe
 137      (vertical 1.0
 138                (summary 0.25 point)
 139                ("*Shell Command Output*" 1.0)))
 140     (bug
 141      (vertical 1.0
 142                (if gnus-bug-create-help-buffer '("*Gnus Help Bug*" 0.5))
 143                ("*Gnus Bug*" 1.0 point)))
 144     (score-trace
 145      (vertical 1.0
 146                (summary 0.5 point)
 147                ("*Score Trace*" 1.0)))
 148     (score-words
 149      (vertical 1.0
 150                (summary 0.5 point)
 151                ("*Score Words*" 1.0)))
 152     (split-trace
 153      (vertical 1.0
 154                (summary 0.5 point)
 155                ("*Split Trace*" 1.0)))
 156     (category
 157      (vertical 1.0
 158                (category 1.0)))
 159     (compose-bounce
 160      (vertical 1.0
 161                (article 0.5)
 162                (message 1.0 point)))
 163     (display-term
 164      (vertical 1.0
 165                ("*display*" 1.0)))
 166     (mml-preview
 167      (vertical 1.0
 168                (message 0.5)
 169                (mml-preview 1.0 point))))
 170   "Window configuration for all possible Gnus buffers.
 171 See the Gnus manual for an explanation of the syntax used.")
 172
 173 (defvar gnus-window-to-buffer
 174   '((group . gnus-group-buffer)
 175     (summary . gnus-summary-buffer)
 176     (article . gnus-article-buffer)
 177     (server . gnus-server-buffer)
 178     (browse . "*Gnus Browse Server*")
 179     (edit-group . gnus-group-edit-buffer)
 180     (edit-form . gnus-edit-form-buffer)
 181     (edit-server . gnus-server-edit-buffer)
 182     (edit-score . gnus-score-edit-buffer)
 183     (message . gnus-message-buffer)
 184     (mail . gnus-message-buffer)
 185     (post-news . gnus-message-buffer)
 186     (faq . gnus-faq-buffer)
 187     (tree . gnus-tree-buffer)
 188     (score-trace . "*Score Trace*")
 189     (split-trace . "*Split Trace*")
 190     (info . gnus-info-buffer)
 191     (category . gnus-category-buffer)
 192     (article-copy . gnus-article-copy)
 193     (draft . gnus-draft-buffer)
 194     (mml-preview . mml-preview-buffer))
 195   "Mapping from short symbols to buffer names or buffer variables.")
 196
 197 (defcustom gnus-configure-windows-hook nil
 198   "*A hook called when configuring windows."
 199   :version "22.1"
 200   :group 'gnus-windows
 201   :type 'hook)
 202
 203 ;;; Internal variables.
 204
 205 (defvar gnus-current-window-configuration nil
 206   "The most recently set window configuration.")
 207
 208 (defvar gnus-created-frames nil)
 209 (defvar gnus-window-frame-focus nil)
 210
 211 (defun gnus-kill-gnus-frames ()
 212   "Kill all frames Gnus has created."
 213   (while gnus-created-frames
 214     (when (frame-live-p (car gnus-created-frames))
 215       ;; We slap a condition-case around this `delete-frame' to ensure
 216       ;; against errors if we try do delete the single frame that's left.
 217       (ignore-errors
 218         (delete-frame (car gnus-created-frames))))
 219     (pop gnus-created-frames)))
 220
 221 ;;;###autoload
 222 (defun gnus-add-configuration (conf)
 223   "Add the window configuration CONF to `gnus-buffer-configuration'."
 224   (setq gnus-buffer-configuration
 225         (cons conf (delq (assq (car conf) gnus-buffer-configuration)
 226                          gnus-buffer-configuration))))
 227
 228 (defvar gnus-frame-list nil)
 229
 230 (defun gnus-window-to-buffer-helper (obj)
 231   (cond ((not (symbolp obj))
 232          obj)
 233         ((boundp obj)
 234          (symbol-value obj))
 235         ((fboundp obj)
 236          (funcall obj))
 237         (t
 238          nil)))
 239
 240 (defun gnus-configure-frame (split &optional window)
 241   "Split WINDOW according to SPLIT."
 242   (let* ((current-window (or (get-buffer-window (current-buffer)) (selected-window)))
 243          (window (or window current-window)))
 244     (select-window window)
 245     ;; The SPLIT might be something that is to be evaled to
 246     ;; return a new SPLIT.
 247     (while (and (not (assq (car split) gnus-window-to-buffer))
 248                 (symbolp (car split)) (fboundp (car split)))
 249       (setq split (eval split)))
 250     (let* ((type (car split))
 251            (subs (cddr split))
 252            (len (if (eq type 'horizontal) (window-width) (window-height)))
 253            (total 0)
 254            (window-min-width (or gnus-window-min-width window-min-width))
 255            (window-min-height (or gnus-window-min-height window-min-height))
 256            s result new-win rest comp-subs size sub)
 257       (cond
 258        ;; Nothing to do here.
 259        ((null split))
 260        ;; Don't switch buffers.
 261        ((null type)
 262         (and (memq 'point split) window))
 263        ;; This is a buffer to be selected.
 264        ((not (memq type '(frame horizontal vertical)))
 265         (let ((buffer (cond ((stringp type) type)
 266                             (t (cdr (assq type gnus-window-to-buffer))))))
 267           (unless buffer
 268             (error "Invalid buffer type: %s" type))
 269           (let ((buf (gnus-get-buffer-create
 270                       (gnus-window-to-buffer-helper buffer))))
 271             (if (eq buf (window-buffer (selected-window))) (set-buffer buf)
 272               (switch-to-buffer buf)))
 273           (when (memq 'frame-focus split)
 274             (setq gnus-window-frame-focus window))
 275           ;; We return the window if it has the `point' spec.
 276           (and (memq 'point split) window)))
 277        ;; This is a frame split.
 278        ((eq type 'frame)
 279         (unless gnus-frame-list
 280           (setq gnus-frame-list (list (window-frame current-window))))
 281         (let ((i 0)
 282               params frame fresult)
 283           (while (< i (length subs))
 284             ;; Frame parameter is gotten from the sub-split.
 285             (setq params (cadr (elt subs i)))
 286             ;; It should be a list.
 287             (unless (listp params)
 288               (setq params nil))
 289             ;; Create a new frame?
 290             (unless (setq frame (elt gnus-frame-list i))
 291               (nconc gnus-frame-list (list (setq frame (make-frame params))))
 292               (push frame gnus-created-frames))
 293             ;; Is the old frame still alive?
 294             (unless (frame-live-p frame)
 295               (setcar (nthcdr i gnus-frame-list)
 296                       (setq frame (make-frame params))))
 297             ;; Select the frame in question and do more splits there.
 298             (select-frame frame)
 299             (setq fresult (or (gnus-configure-frame (elt subs i)) fresult))
 300             (incf i))
 301           ;; Select the frame that has the selected buffer.
 302           (when fresult
 303             (select-frame (window-frame fresult)))))
 304        ;; This is a normal split.
 305        (t
 306         (when (> (length subs) 0)
 307           ;; First we have to compute the sizes of all new windows.
 308           (while subs
 309             (setq sub (append (pop subs) nil))
 310             (while (and (not (assq (car sub) gnus-window-to-buffer))
 311                         (symbolp (car sub)) (fboundp (car sub)))
 312               (setq sub (eval sub)))
 313             (when sub
 314               (push sub comp-subs)
 315               (setq size (cadar comp-subs))
 316               (cond ((equal size 1.0)
 317                      (setq rest (car comp-subs))
 318                      (setq s 0))
 319                     ((floatp size)
 320                      (setq s (floor (* size len))))
 321                     ((integerp size)
 322                      (setq s size))
 323                     (t
 324                      (error "Invalid size: %s" size)))
 325               ;; Try to make sure that we are inside the safe limits.
 326               (cond ((zerop s))
 327                     ((eq type 'horizontal)
 328                      (setq s (max s window-min-width)))
 329                     ((eq type 'vertical)
 330                      (setq s (max s window-min-height))))
 331               (setcar (cdar comp-subs) s)
 332               (incf total s)))
 333           ;; Take care of the "1.0" spec.
 334           (if rest
 335               (setcar (cdr rest) (- len total))
 336             (error "No 1.0 specs in %s" split))
 337           ;; The we do the actual splitting in a nice recursive
 338           ;; fashion.
 339           (setq comp-subs (nreverse comp-subs))
 340           (while comp-subs
 341             (if (null (cdr comp-subs))
 342                 (setq new-win window)
 343               (setq new-win
 344                     (split-window window (cadar comp-subs)
 345                                   (eq type 'horizontal))))
 346             (setq result (or (gnus-configure-frame
 347                               (car comp-subs) window)
 348                              result))
 349             (select-window new-win)
 350             (setq window new-win)
 351             (setq comp-subs (cdr comp-subs))))
 352         ;; Return the proper window, if any.
 353         (when result
 354           (select-window result)))))))
 355
 356 (defvar gnus-frame-split-p nil)
 357
 358 (defun gnus-configure-windows (setting &optional force)
 359   (if (window-configuration-p setting)
 360       (set-window-configuration setting)
 361     (setq gnus-current-window-configuration setting)
 362     (setq force (or force gnus-always-force-window-configuration))
 363     (let ((split (if (symbolp setting)
 364                      (cadr (assq setting gnus-buffer-configuration))
 365                    setting))
 366           all-visible)
 367
 368       (setq gnus-frame-split-p nil)
 369
 370       (unless split
 371         (error "No such setting in `gnus-buffer-configuration': %s" setting))
 372
 373       (if (and (setq all-visible (gnus-all-windows-visible-p split))
 374                (not force))
 375           ;; All the windows mentioned are already visible, so we just
 376           ;; put point in the assigned buffer, and do not touch the
 377           ;; winconf.
 378           (select-window all-visible)
 379
 380         ;; Make sure "the other" buffer, nntp-server-buffer, is live.
 381         (unless (gnus-buffer-live-p nntp-server-buffer)
 382           (nnheader-init-server-buffer))
 383
 384         ;; Either remove all windows or just remove all Gnus windows.
 385         (let ((frame (selected-frame)))
 386           (unwind-protect
 387               (if gnus-use-full-window
 388                   ;; We want to remove all other windows.
 389                   (if (not gnus-frame-split-p)
 390                       ;; This is not a `frame' split, so we ignore the
 391                       ;; other frames.
 392                       (delete-other-windows)
 393                     ;; This is a `frame' split, so we delete all windows
 394                     ;; on all frames.
 395                     (gnus-delete-windows-in-gnusey-frames))
 396                 ;; Just remove some windows.
 397                 (gnus-remove-some-windows)
 398                 (if (featurep 'xemacs)
 399                     (switch-to-buffer nntp-server-buffer)
 400                   (set-buffer nntp-server-buffer)))
 401             (select-frame frame)))
 402
 403         (let (gnus-window-frame-focus)
 404           (if (featurep 'xemacs)
 405               (switch-to-buffer nntp-server-buffer)
 406             (set-buffer nntp-server-buffer))
 407           (gnus-configure-frame split)
 408           (run-hooks 'gnus-configure-windows-hook)
 409           (when gnus-window-frame-focus
 410             (gnus-select-frame-set-input-focus
 411              (window-frame gnus-window-frame-focus))))))))
 412
 413 (defun gnus-delete-windows-in-gnusey-frames ()
 414   "Do a `delete-other-windows' in all frames that have Gnus windows."
 415   (let ((buffers (gnus-buffers)))
 416     (mapcar
 417      (lambda (frame)
 418        (unless (eq (cdr (assq 'minibuffer
 419                               (frame-parameters frame)))
 420                    'only)
 421          (select-frame frame)
 422          (let (do-delete)
 423            (walk-windows
 424             (lambda (window)
 425               (when (memq (window-buffer window) buffers)
 426                 (setq do-delete t))))
 427            (when do-delete
 428              (delete-other-windows)))))
 429      (frame-list))))
 430
 431 (defun gnus-all-windows-visible-p (split)
 432   "Say whether all buffers in SPLIT are currently visible.
 433 In particular, the value returned will be the window that
 434 should have point."
 435   (let ((stack (list split))
 436         (all-visible t)
 437         type buffer win buf)
 438     (while (and (setq split (pop stack))
 439                 all-visible)
 440       ;; Be backwards compatible.
 441       (when (vectorp split)
 442         (setq split (append split nil)))
 443       (when (or (consp (car split))
 444                 (vectorp (car split)))
 445         (push 1.0 split)
 446         (push 'vertical split))
 447       ;; The SPLIT might be something that is to be evaled to
 448       ;; return a new SPLIT.
 449       (while (and (not (assq (car split) gnus-window-to-buffer))
 450                   (symbolp (car split)) (fboundp (car split)))
 451         (setq split (eval split)))
 452
 453       (setq type (elt split 0))
 454       (cond
 455        ;; Nothing here.
 456        ((null split) t)
 457        ;; A buffer.
 458        ((not (memq type '(horizontal vertical frame)))
 459         (setq buffer (cond ((stringp type) type)
 460                            (t (cdr (assq type gnus-window-to-buffer)))))
 461         (unless buffer
 462           (error "Invalid buffer type: %s" type))
 463         (if (and (setq buf (get-buffer (gnus-window-to-buffer-helper buffer)))
 464                  (setq win (gnus-get-buffer-window buf t)))
 465             (if (memq 'point split)
 466                 (setq all-visible win))
 467           (setq all-visible nil)))
 468        (t
 469         (when (eq type 'frame)
 470           (setq gnus-frame-split-p t))
 471         (setq stack (append (cddr split) stack)))))
 472     (unless (eq all-visible t)
 473       all-visible)))
 474
 475 (defun gnus-window-top-edge (&optional window)
 476   (nth 1 (window-edges window)))
 477
 478 (defun gnus-remove-some-windows ()
 479   (let ((buffers (gnus-buffers))
 480         buf bufs lowest-buf lowest)
 481     (save-excursion
 482       ;; Remove windows on all known Gnus buffers.
 483       (while (setq buf (pop buffers))
 484         (when (get-buffer-window buf)
 485           (push buf bufs)
 486           (pop-to-buffer buf)
 487           (when (or (not lowest)
 488                     (< (gnus-window-top-edge) lowest))
 489             (setq lowest (gnus-window-top-edge)
 490                   lowest-buf buf))))
 491       (when lowest-buf
 492         (pop-to-buffer lowest-buf)
 493         (if (featurep 'xemacs)
 494             (switch-to-buffer nntp-server-buffer)
 495           (set-buffer nntp-server-buffer)))
 496       (mapcar (lambda (b) (delete-windows-on b t))
 497               (delq lowest-buf bufs)))))
 498
 499 (eval-and-compile
 500   (cond
 501    ((fboundp 'frames-on-display-list)
 502     (defalias 'gnus-frames-on-display-list 'frames-on-display-list))
 503    ((and (featurep 'xemacs) (fboundp 'frame-device))
 504     (defun gnus-frames-on-display-list ()
 505       (apply 'filtered-frame-list 'identity (list (frame-device nil)))))
 506    (t
 507     (defalias 'gnus-frames-on-display-list 'frame-list))))
 508
 509 (defun gnus-get-buffer-window (buffer &optional frame)
 510   (cond ((and (null gnus-use-frames-on-any-display)
 511               (memq frame '(t 0 visible)))
 512          (car
 513           (let ((frames (gnus-frames-on-display-list)))
 514             (gnus-remove-if (lambda (win) (not (memq (window-frame win)
 515                                                      frames)))
 516                             (get-buffer-window-list buffer nil frame)))))
 517         (t
 518          (get-buffer-window buffer frame))))
 519
 520 (provide 'gnus-win)
 521
 522 ;;; gnus-win.el ends here