cgit.sxemacs.org Git - gnus/blob - lisp/gnus-util.el

   1 ;;; gnus-util.el --- utility functions for Gnus
   2
   3 ;; Copyright (C) 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003, 2004,
   4 ;;   2005, 2006, 2007, 2008, 2009, 2010 Free Software Foundation, Inc.
   5
   6 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   7 ;; Keywords: news
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;; Nothing in this file depends on any other parts of Gnus -- all
  27 ;; functions and macros in this file are utility functions that are
  28 ;; used by Gnus and may be used by any other package without loading
  29 ;; Gnus first.
  30
  31 ;; [Unfortunately, it does depend on other parts of Gnus, e.g. the
  32 ;; autoloads and defvars below...]
  33
  34 ;;; Code:
  35
  36 ;; For Emacs < 22.2.
  37 (eval-and-compile
  38   (unless (fboundp 'declare-function) (defmacro declare-function (&rest r))))
  39 (eval-when-compile
  40   (require 'cl))
  41
  42 (eval-when-compile
  43   (unless (fboundp 'with-no-warnings)
  44     (defmacro with-no-warnings (&rest body)
  45       `(progn ,@body))))
  46
  47 ;; Fixme: this should be a gnus variable, not nnmail-.
  48 (defvar nnmail-pathname-coding-system)
  49 (defvar nnmail-active-file-coding-system)
  50
  51 ;; Inappropriate references to other parts of Gnus.
  52 (defvar gnus-emphasize-whitespace-regexp)
  53 (defvar gnus-original-article-buffer)
  54 (defvar gnus-user-agent)
  55
  56 (autoload 'gnus-get-buffer-window "gnus-win")
  57 (autoload 'nnheader-narrow-to-headers "nnheader")
  58 (autoload 'nnheader-replace-chars-in-string "nnheader")
  59 (autoload 'mail-header-remove-comments "mail-parse")
  60
  61 (eval-and-compile
  62   (cond
  63    ;; Prefer `replace-regexp-in-string' (present in Emacs, XEmacs 21.5,
  64    ;; SXEmacs 22.1.4) over `replace-in-string'.  The latter leads to inf-loops
  65    ;; on empty matches:
  66    ;;   (replace-in-string "foo" "/*$" "/")
  67    ;;   (replace-in-string "xe" "\\(x\\)?" "")
  68    ((fboundp 'replace-regexp-in-string)
  69     (defun gnus-replace-in-string  (string regexp newtext &optional literal)
  70       "Replace all matches for REGEXP with NEWTEXT in STRING.
  71 If LITERAL is non-nil, insert NEWTEXT literally.  Return a new
  72 string containing the replacements.
  73
  74 This is a compatibility function for different Emacsen."
  75       (replace-regexp-in-string regexp newtext string nil literal)))
  76    ((fboundp 'replace-in-string)
  77     (defalias 'gnus-replace-in-string 'replace-in-string))))
  78
  79 (defun gnus-boundp (variable)
  80   "Return non-nil if VARIABLE is bound and non-nil."
  81   (and (boundp variable)
  82        (symbol-value variable)))
  83
  84 (defmacro gnus-eval-in-buffer-window (buffer &rest forms)
  85   "Pop to BUFFER, evaluate FORMS, and then return to the original window."
  86   (let ((tempvar (make-symbol "GnusStartBufferWindow"))
  87         (w (make-symbol "w"))
  88         (buf (make-symbol "buf")))
  89     `(let* ((,tempvar (selected-window))
  90             (,buf ,buffer)
  91             (,w (gnus-get-buffer-window ,buf 'visible)))
  92        (unwind-protect
  93            (progn
  94              (if ,w
  95                  (progn
  96                    (select-window ,w)
  97                    (set-buffer (window-buffer ,w)))
  98                (pop-to-buffer ,buf))
  99              ,@forms)
 100          (select-window ,tempvar)))))
 101
 102 (put 'gnus-eval-in-buffer-window 'lisp-indent-function 1)
 103 (put 'gnus-eval-in-buffer-window 'edebug-form-spec '(form body))
 104
 105 (defmacro gnus-intern-safe (string hashtable)
 106   "Get hash value.  Arguments are STRING and HASHTABLE."
 107   `(let ((symbol (intern ,string ,hashtable)))
 108      (or (boundp symbol)
 109          (set symbol nil))
 110      symbol))
 111
 112 (defsubst gnus-goto-char (point)
 113   (and point (goto-char point)))
 114
 115 (defmacro gnus-buffer-exists-p (buffer)
 116   `(let ((buffer ,buffer))
 117      (when buffer
 118        (funcall (if (stringp buffer) 'get-buffer 'buffer-name)
 119                 buffer))))
 120
 121 ;; The LOCAL arg to `add-hook' is interpreted differently in Emacs and
 122 ;; XEmacs.  In Emacs we don't need to call `make-local-hook' first.
 123 ;; It's harmless, though, so the main purpose of this alias is to shut
 124 ;; up the byte compiler.
 125 (defalias 'gnus-make-local-hook
 126   (if (eq (get 'make-local-hook 'byte-compile)
 127           'byte-compile-obsolete)
 128       'ignore                           ; Emacs
 129     'make-local-hook))                  ; XEmacs
 130
 131 (defun gnus-delete-first (elt list)
 132   "Delete by side effect the first occurrence of ELT as a member of LIST."
 133   (if (equal (car list) elt)
 134       (cdr list)
 135     (let ((total list))
 136       (while (and (cdr list)
 137                   (not (equal (cadr list) elt)))
 138         (setq list (cdr list)))
 139       (when (cdr list)
 140         (setcdr list (cddr list)))
 141       total)))
 142
 143 ;; Delete the current line (and the next N lines).
 144 (defmacro gnus-delete-line (&optional n)
 145   `(delete-region (point-at-bol)
 146                   (progn (forward-line ,(or n 1)) (point))))
 147
 148 (defun gnus-byte-code (func)
 149   "Return a form that can be `eval'ed based on FUNC."
 150   (let ((fval (indirect-function func)))
 151     (if (byte-code-function-p fval)
 152         (let ((flist (append fval nil)))
 153           (setcar flist 'byte-code)
 154           flist)
 155       (cons 'progn (cddr fval)))))
 156
 157 (defun gnus-extract-address-components (from)
 158   "Extract address components from a From header.
 159 Given an RFC-822 address FROM, extract full name and canonical address.
 160 Returns a list of the form (FULL-NAME CANONICAL-ADDRESS).  Much more simple
 161 solution than `mail-extract-address-components', which works much better, but
 162 is slower."
 163   (let (name address)
 164     ;; First find the address - the thing with the @ in it.  This may
 165     ;; not be accurate in mail addresses, but does the trick most of
 166     ;; the time in news messages.
 167     (cond (;; Check ``<foo@bar>'' first in order to handle the quite common
 168            ;; form ``"abc@xyz" <foo@bar>'' (i.e. ``@'' as part of a comment)
 169            ;; correctly.
 170            (string-match "<\\([^@ \t<>]+[!@][^@ \t<>]+\\)>" from)
 171            (setq address (substring from (match-beginning 1) (match-end 1))))
 172           ((string-match "\\b[^@ \t<>]+[!@][^@ \t<>]+\\b" from)
 173            (setq address (substring from (match-beginning 0) (match-end 0)))))
 174     ;; Then we check whether the "name <address>" format is used.
 175     (and address
 176          ;; Linear white space is not required.
 177          (string-match (concat "[ \t]*<" (regexp-quote address) ">") from)
 178          (and (setq name (substring from 0 (match-beginning 0)))
 179               ;; Strip any quotes from the name.
 180               (string-match "^\".*\"$" name)
 181               (setq name (substring name 1 (1- (match-end 0))))))
 182     ;; If not, then "address (name)" is used.
 183     (or name
 184         (and (string-match "(.+)" from)
 185              (setq name (substring from (1+ (match-beginning 0))
 186                                    (1- (match-end 0)))))
 187         (and (string-match "()" from)
 188              (setq name address))
 189         ;; XOVER might not support folded From headers.
 190         (and (string-match "(.*" from)
 191              (setq name (substring from (1+ (match-beginning 0))
 192                                    (match-end 0)))))
 193     (list (if (string= name "") nil name) (or address from))))
 194
 195 (defun gnus-extract-address-component-name (from)
 196   "Extract name from a From header.
 197 Uses `gnus-extract-address-components'."
 198   (nth 0 (gnus-extract-address-components from)))
 199
 200 (defun gnus-extract-address-component-email (from)
 201   "Extract e-mail address from a From header.
 202 Uses `gnus-extract-address-components'."
 203   (nth 1 (gnus-extract-address-components from)))
 204
 205 (declare-function message-fetch-field "message" (header &optional not-all))
 206
 207 (defun gnus-fetch-field (field)
 208   "Return the value of the header FIELD of current article."
 209   (require 'message)
 210   (save-excursion
 211     (save-restriction
 212       (let ((inhibit-point-motion-hooks t))
 213         (nnheader-narrow-to-headers)
 214         (message-fetch-field field)))))
 215
 216 (defun gnus-fetch-original-field (field)
 217   "Fetch FIELD from the original version of the current article."
 218   (with-current-buffer gnus-original-article-buffer
 219     (gnus-fetch-field field)))
 220
 221
 222 (defun gnus-goto-colon ()
 223   (beginning-of-line)
 224   (let ((eol (point-at-eol)))
 225     (goto-char (or (text-property-any (point) eol 'gnus-position t)
 226                    (search-forward ":" eol t)
 227                    (point)))))
 228
 229 (declare-function gnus-find-method-for-group "gnus" (group &optional info))
 230 (declare-function gnus-group-name-decode "gnus-group" (string charset))
 231 (declare-function gnus-group-name-charset "gnus-group" (method group))
 232 ;; gnus-group requires gnus-int which requires message.
 233 (declare-function message-tokenize-header "message"
 234                   (header &optional separator))
 235
 236 (defun gnus-decode-newsgroups (newsgroups group &optional method)
 237   (require 'gnus-group)
 238   (let ((method (or method (gnus-find-method-for-group group))))
 239     (mapconcat (lambda (group)
 240                  (gnus-group-name-decode group (gnus-group-name-charset
 241                                                 method group)))
 242                (message-tokenize-header newsgroups)
 243                ",")))
 244
 245 (defun gnus-remove-text-with-property (prop)
 246   "Delete all text in the current buffer with text property PROP."
 247   (let ((start (point-min))
 248         end)
 249     (unless (get-text-property start prop)
 250       (setq start (next-single-property-change start prop)))
 251     (while start
 252       (setq end (text-property-any start (point-max) prop nil))
 253       (delete-region start (or end (point-max)))
 254       (setq start (when end
 255                     (next-single-property-change start prop))))))
 256
 257 (defun gnus-newsgroup-directory-form (newsgroup)
 258   "Make hierarchical directory name from NEWSGROUP name."
 259   (let* ((newsgroup (gnus-newsgroup-savable-name newsgroup))
 260          (idx (string-match ":" newsgroup)))
 261     (concat
 262      (if idx (substring newsgroup 0 idx))
 263      (if idx "/")
 264      (nnheader-replace-chars-in-string
 265       (if idx (substring newsgroup (1+ idx)) newsgroup)
 266       ?. ?/))))
 267
 268 (defun gnus-newsgroup-savable-name (group)
 269   ;; Replace any slashes in a group name (eg. an ange-ftp nndoc group)
 270   ;; with dots.
 271   (nnheader-replace-chars-in-string group ?/ ?.))
 272
 273 (defun gnus-string> (s1 s2)
 274   (not (or (string< s1 s2)
 275            (string= s1 s2))))
 276
 277 (defun gnus-string< (s1 s2)
 278   "Return t if first arg string is less than second in lexicographic order.
 279 Case is significant if and only if `case-fold-search' is nil.
 280 Symbols are also allowed; their print names are used instead."
 281   (if case-fold-search
 282       (string-lessp (downcase (if (symbolp s1) (symbol-name s1) s1))
 283                     (downcase (if (symbolp s2) (symbol-name s2) s2)))
 284     (string-lessp s1 s2)))
 285
 286 ;;; Time functions.
 287
 288 (defun gnus-file-newer-than (file date)
 289   (let ((fdate (nth 5 (file-attributes file))))
 290     (or (> (car fdate) (car date))
 291         (and (= (car fdate) (car date))
 292              (> (nth 1 fdate) (nth 1 date))))))
 293
 294 (eval-and-compile
 295   (if (and (fboundp 'float-time)
 296            (subrp (symbol-function 'float-time)))
 297       (defalias 'gnus-float-time 'float-time)
 298     (defun gnus-float-time (&optional time)
 299       "Convert time value TIME to a floating point number.
 300 TIME defaults to the current time."
 301       (with-no-warnings (time-to-seconds (or time (current-time)))))))
 302
 303 ;;; Keymap macros.
 304
 305 (defmacro gnus-local-set-keys (&rest plist)
 306   "Set the keys in PLIST in the current keymap."
 307   `(gnus-define-keys-1 (current-local-map) ',plist))
 308
 309 (defmacro gnus-define-keys (keymap &rest plist)
 310   "Define all keys in PLIST in KEYMAP."
 311   `(gnus-define-keys-1 (quote ,keymap) (quote ,plist)))
 312
 313 (defmacro gnus-define-keys-safe (keymap &rest plist)
 314   "Define all keys in PLIST in KEYMAP without overwriting previous definitions."
 315   `(gnus-define-keys-1 (quote ,keymap) (quote ,plist) t))
 316
 317 (put 'gnus-define-keys 'lisp-indent-function 1)
 318 (put 'gnus-define-keys-safe 'lisp-indent-function 1)
 319 (put 'gnus-local-set-keys 'lisp-indent-function 1)
 320
 321 (defmacro gnus-define-keymap (keymap &rest plist)
 322   "Define all keys in PLIST in KEYMAP."
 323   `(gnus-define-keys-1 ,keymap (quote ,plist)))
 324
 325 (put 'gnus-define-keymap 'lisp-indent-function 1)
 326
 327 (defun gnus-define-keys-1 (keymap plist &optional safe)
 328   (when (null keymap)
 329     (error "Can't set keys in a null keymap"))
 330   (cond ((symbolp keymap)
 331          (setq keymap (symbol-value keymap)))
 332         ((keymapp keymap))
 333         ((listp keymap)
 334          (set (car keymap) nil)
 335          (define-prefix-command (car keymap))
 336          (define-key (symbol-value (caddr keymap)) (cadr keymap) (car keymap))
 337          (setq keymap (symbol-value (car keymap)))))
 338   (let (key)
 339     (while plist
 340       (when (symbolp (setq key (pop plist)))
 341         (setq key (symbol-value key)))
 342       (if (or (not safe)
 343               (eq (lookup-key keymap key) 'undefined))
 344           (define-key keymap key (pop plist))
 345         (pop plist)))))
 346
 347 (defun gnus-completing-read-with-default (default prompt &rest args)
 348   ;; Like `completing-read', except that DEFAULT is the default argument.
 349   (let* ((prompt (if default
 350                      (concat prompt " (default " default "): ")
 351                    (concat prompt ": ")))
 352          (answer (apply 'completing-read prompt args)))
 353     (if (or (null answer) (zerop (length answer)))
 354         default
 355       answer)))
 356
 357 ;; Two silly functions to ensure that all `y-or-n-p' questions clear
 358 ;; the echo area.
 359 ;;
 360 ;; Do we really need these functions?  Workarounds for bugs in the corresponding
 361 ;; Emacs functions?  Maybe these bugs are no longer present in any supported
 362 ;; (X)Emacs version?  Alias them to the original functions and see if anyone
 363 ;; reports a problem.  If not, replace with original functions.  --rsteib,
 364 ;; 2007-12-14
 365 ;;
 366 ;; All supported Emacsen clear the echo area after `yes-or-no-p', so we can
 367 ;; remove `yes-or-no-p'.  RMS says that not clearing after `y-or-n-p' is
 368 ;; intentional (see below), so we could remove `gnus-y-or-n-p' too.
 369 ;; Objections?  --rsteib, 2008-02-16
 370 ;;
 371 ;; ,----[ http://thread.gmane.org/gmane.emacs.gnus.general/65099/focus=66070 ]
 372 ;; | From: Richard Stallman
 373 ;; | Subject: Re: Do we need gnus-yes-or-no-p and gnus-y-or-n-p?
 374 ;; | To: Katsumi Yamaoka [...]
 375 ;; | Cc: emacs-devel@[...], xemacs-beta@[...], ding@[...]
 376 ;; | Date: Mon, 07 Jan 2008 12:16:05 -0500
 377 ;; | Message-ID: <E1JBva1-000528-VY@fencepost.gnu.org>
 378 ;; |
 379 ;; |     The behavior of `y-or-n-p' that it doesn't clear the question
 380 ;; |     and the answer is not serious of course, but I feel it is not
 381 ;; |     cool.
 382 ;; |
 383 ;; | It is intentional.
 384 ;; |
 385 ;; |     Currently, it is commented out in the trunk by Reiner Steib.  He
 386 ;; |     also wrote the benefit of leaving the question and the answer in
 387 ;; |     the echo area as follows:
 388 ;; |
 389 ;; |     (http://article.gmane.org/gmane.emacs.gnus.general/66061)
 390 ;; |     > In contrast to yes-or-no-p it is much easier to type y, n,
 391 ;; |     > SPC, DEL, etc accidentally, so it might be useful for the user
 392 ;; |     > to see what he has typed.
 393 ;; |
 394 ;; | Yes, that is the reason.
 395 ;; `----
 396
 397 ;; (defun gnus-y-or-n-p (prompt)
 398 ;;   (prog1
 399 ;;       (y-or-n-p prompt)
 400 ;;     (message "")))
 401 ;; (defun gnus-yes-or-no-p (prompt)
 402 ;;   (prog1
 403 ;;       (yes-or-no-p prompt)
 404 ;;     (message "")))
 405
 406 (defalias 'gnus-y-or-n-p 'y-or-n-p)
 407 (defalias 'gnus-yes-or-no-p 'yes-or-no-p)
 408
 409 ;; By Frank Schmitt <ich@Frank-Schmitt.net>. Allows to have
 410 ;; age-depending date representations. (e.g. just the time if it's
 411 ;; from today, the day of the week if it's within the last 7 days and
 412 ;; the full date if it's older)
 413
 414 (defun gnus-seconds-today ()
 415   "Return the number of seconds passed today."
 416   (let ((now (decode-time (current-time))))
 417     (+ (car now) (* (car (cdr now)) 60) (* (car (nthcdr 2 now)) 3600))))
 418
 419 (defun gnus-seconds-month ()
 420   "Return the number of seconds passed this month."
 421   (let ((now (decode-time (current-time))))
 422     (+ (car now) (* (car (cdr now)) 60) (* (car (nthcdr 2 now)) 3600)
 423        (* (- (car (nthcdr 3 now)) 1) 3600 24))))
 424
 425 (defun gnus-seconds-year ()
 426   "Return the number of seconds passed this year."
 427   (let ((now (decode-time (current-time)))
 428         (days (format-time-string "%j" (current-time))))
 429     (+ (car now) (* (car (cdr now)) 60) (* (car (nthcdr 2 now)) 3600)
 430        (* (- (string-to-number days) 1) 3600 24))))
 431
 432 (defmacro gnus-date-get-time (date)
 433   "Convert DATE string to Emacs time.
 434 Cache the result as a text property stored in DATE."
 435   ;; Either return the cached value...
 436   `(let ((d ,date))
 437      (if (equal "" d)
 438          '(0 0)
 439        (or (get-text-property 0 'gnus-time d)
 440            ;; or compute the value...
 441            (let ((time (safe-date-to-time d)))
 442              ;; and store it back in the string.
 443              (put-text-property 0 1 'gnus-time time d)
 444              time)))))
 445
 446 (defvar gnus-user-date-format-alist
 447   '(((gnus-seconds-today) . "%k:%M")
 448     (604800 . "%a %k:%M")                   ;;that's one week
 449     ((gnus-seconds-month) . "%a %d")
 450     ((gnus-seconds-year) . "%b %d")
 451     (t . "%b %d '%y"))                      ;;this one is used when no
 452                                             ;;other does match
 453   "Specifies date format depending on age of article.
 454 This is an alist of items (AGE . FORMAT).  AGE can be a number (of
 455 seconds) or a Lisp expression evaluating to a number.  When the age of
 456 the article is less than this number, then use `format-time-string'
 457 with the corresponding FORMAT for displaying the date of the article.
 458 If AGE is not a number or a Lisp expression evaluating to a
 459 non-number, then the corresponding FORMAT is used as a default value.
 460
 461 Note that the list is processed from the beginning, so it should be
 462 sorted by ascending AGE.  Also note that items following the first
 463 non-number AGE will be ignored.
 464
 465 You can use the functions `gnus-seconds-today', `gnus-seconds-month'
 466 and `gnus-seconds-year' in the AGE spec.  They return the number of
 467 seconds passed since the start of today, of this month, of this year,
 468 respectively.")
 469
 470 (defun gnus-user-date (messy-date)
 471   "Format the messy-date according to gnus-user-date-format-alist.
 472 Returns \"  ?  \" if there's bad input or if another error occurs.
 473 Input should look like this: \"Sun, 14 Oct 2001 13:34:39 +0200\"."
 474   (condition-case ()
 475       (let* ((messy-date (gnus-float-time (gnus-date-get-time messy-date)))
 476              (now (gnus-float-time))
 477              ;;If we don't find something suitable we'll use this one
 478              (my-format "%b %d '%y"))
 479         (let* ((difference (- now messy-date))
 480                (templist gnus-user-date-format-alist)
 481                (top (eval (caar templist))))
 482           (while (if (numberp top) (< top difference) (not top))
 483             (progn
 484               (setq templist (cdr templist))
 485               (setq top (eval (caar templist)))))
 486           (if (stringp (cdr (car templist)))
 487               (setq my-format (cdr (car templist)))))
 488         (format-time-string (eval my-format) (seconds-to-time messy-date)))
 489     (error "  ?   ")))
 490
 491 (defun gnus-dd-mmm (messy-date)
 492   "Return a string like DD-MMM from a big messy string."
 493   (condition-case ()
 494       (format-time-string "%d-%b" (gnus-date-get-time messy-date))
 495     (error "  -   ")))
 496
 497 (defsubst gnus-time-iso8601 (time)
 498   "Return a string of TIME in YYYYMMDDTHHMMSS format."
 499   (format-time-string "%Y%m%dT%H%M%S" time))
 500
 501 (defun gnus-date-iso8601 (date)
 502   "Convert the DATE to YYYYMMDDTHHMMSS."
 503   (condition-case ()
 504       (gnus-time-iso8601 (gnus-date-get-time date))
 505     (error "")))
 506
 507 (defun gnus-mode-string-quote (string)
 508   "Quote all \"%\"'s in STRING."
 509   (gnus-replace-in-string string "%" "%%"))
 510
 511 ;; Make a hash table (default and minimum size is 256).
 512 ;; Optional argument HASHSIZE specifies the table size.
 513 (defun gnus-make-hashtable (&optional hashsize)
 514   (make-vector (if hashsize (max (gnus-create-hash-size hashsize) 256) 256) 0))
 515
 516 ;; Make a number that is suitable for hashing; bigger than MIN and
 517 ;; equal to some 2^x.  Many machines (such as sparcs) do not have a
 518 ;; hardware modulo operation, so they implement it in software.  On
 519 ;; many sparcs over 50% of the time to intern is spent in the modulo.
 520 ;; Yes, it's slower than actually computing the hash from the string!
 521 ;; So we use powers of 2 so people can optimize the modulo to a mask.
 522 (defun gnus-create-hash-size (min)
 523   (let ((i 1))
 524     (while (< i min)
 525       (setq i (* 2 i)))
 526     i))
 527
 528 (defcustom gnus-verbose 7
 529   "*Integer that says how verbose Gnus should be.
 530 The higher the number, the more messages Gnus will flash to say what
 531 it's doing.  At zero, Gnus will be totally mute; at five, Gnus will
 532 display most important messages; and at ten, Gnus will keep on
 533 jabbering all the time."
 534   :group 'gnus-start
 535   :type 'integer)
 536
 537 (defcustom gnus-add-timestamp-to-message nil
 538   "Non-nil means add timestamps to messages that Gnus issues.
 539 If it is `log', add timestamps to only the messages that go into the
 540 \"*Messages*\" buffer (in XEmacs, it is the \" *Message-Log*\" buffer).
 541 If it is neither nil nor `log', add timestamps not only to log messages
 542 but also to the ones displayed in the echo area."
 543   :version "23.1" ;; No Gnus
 544   :group  'gnus-various
 545   :type '(choice :format "%{%t%}:\n %[Value Menu%] %v"
 546                  (const :tag "Logged messages only" log)
 547                  (sexp :tag "All messages"
 548                        :match (lambda (widget value) value)
 549                        :value t)
 550                  (const :tag "No timestamp" nil)))
 551
 552 (eval-when-compile
 553   (defmacro gnus-message-with-timestamp-1 (format-string args)
 554     (let ((timestamp '((format-time-string "%Y%m%dT%H%M%S" time)
 555                        "." (format "%03d" (/ (nth 2 time) 1000)) "> ")))
 556       (if (featurep 'xemacs)
 557           `(let (str time)
 558              (if (or (and (null ,format-string) (null ,args))
 559                      (progn
 560                        (setq str (apply 'format ,format-string ,args))
 561                        (zerop (length str))))
 562                  (prog1
 563                      (and ,format-string str)
 564                    (clear-message nil))
 565                (cond ((eq gnus-add-timestamp-to-message 'log)
 566                       (setq time (current-time))
 567                       (display-message 'no-log str)
 568                       (log-message 'message (concat ,@timestamp str)))
 569                      (gnus-add-timestamp-to-message
 570                       (setq time (current-time))
 571                       (display-message 'message (concat ,@timestamp str)))
 572                      (t
 573                       (display-message 'message str))))
 574              str)
 575         `(let (str time)
 576            (cond ((eq gnus-add-timestamp-to-message 'log)
 577                   (setq str (let (message-log-max)
 578                               (apply 'message ,format-string ,args)))
 579                   (when (and message-log-max
 580                              (> message-log-max 0)
 581                              (/= (length str) 0))
 582                     (setq time (current-time))
 583                     (with-current-buffer (get-buffer-create "*Messages*")
 584                       (goto-char (point-max))
 585                       (insert ,@timestamp str "\n")
 586                       (forward-line (- message-log-max))
 587                       (delete-region (point-min) (point))
 588                       (goto-char (point-max))))
 589                   str)
 590                  (gnus-add-timestamp-to-message
 591                   (if (or (and (null ,format-string) (null ,args))
 592                           (progn
 593                             (setq str (apply 'format ,format-string ,args))
 594                             (zerop (length str))))
 595                       (prog1
 596                           (and ,format-string str)
 597                         (message nil))
 598                     (setq time (current-time))
 599                     (message "%s" (concat ,@timestamp str))
 600                     str))
 601                  (t
 602                   (apply 'message ,format-string ,args))))))))
 603
 604 (defun gnus-message-with-timestamp (format-string &rest args)
 605   "Display message with timestamp.  Arguments are the same as `message'.
 606 The `gnus-add-timestamp-to-message' variable controls how to add
 607 timestamp to message."
 608   (gnus-message-with-timestamp-1 format-string args))
 609
 610 (defun gnus-message (level &rest args)
 611   "If LEVEL is lower than `gnus-verbose' print ARGS using `message'.
 612
 613 Guideline for numbers:
 614 1 - error messages, 3 - non-serious error messages, 5 - messages for things
 615 that take a long time, 7 - not very important messages on stuff, 9 - messages
 616 inside loops."
 617   (if (<= level gnus-verbose)
 618       (if gnus-add-timestamp-to-message
 619           (apply 'gnus-message-with-timestamp args)
 620         (apply 'message args))
 621     ;; We have to do this format thingy here even if the result isn't
 622     ;; shown - the return value has to be the same as the return value
 623     ;; from `message'.
 624     (apply 'format args)))
 625
 626 (defun gnus-error (level &rest args)
 627   "Beep an error if LEVEL is equal to or less than `gnus-verbose'.
 628 ARGS are passed to `message'."
 629   (when (<= (floor level) gnus-verbose)
 630     (apply 'message args)
 631     (ding)
 632     (let (duration)
 633       (when (and (floatp level)
 634                  (not (zerop (setq duration (* 10 (- level (floor level)))))))
 635         (sit-for duration))))
 636   nil)
 637
 638 (defun gnus-split-references (references)
 639   "Return a list of Message-IDs in REFERENCES."
 640   (let ((beg 0)
 641         (references (mail-header-remove-comments (or references "")))
 642         ids)
 643     (while (string-match "<[^<]+[^< \t]" references beg)
 644       (push (substring references (match-beginning 0) (setq beg (match-end 0)))
 645             ids))
 646     (nreverse ids)))
 647
 648 (defun gnus-extract-references (references)
 649   "Return a list of Message-IDs in REFERENCES (in In-Reply-To
 650   format), trimmed to only contain the Message-IDs."
 651   (let ((ids (gnus-split-references references))
 652         refs)
 653     (dolist (id ids)
 654       (when (string-match "<[^<>]+>" id)
 655         (push (match-string 0 id) refs)))
 656     refs))
 657
 658 (defsubst gnus-parent-id (references &optional n)
 659   "Return the last Message-ID in REFERENCES.
 660 If N, return the Nth ancestor instead."
 661   (when (and references
 662              (not (zerop (length references))))
 663     (if n
 664         (let ((ids (inline (gnus-split-references references))))
 665           (while (nthcdr n ids)
 666             (setq ids (cdr ids)))
 667           (car ids))
 668       (let ((references (mail-header-remove-comments references)))
 669         (when (string-match "\\(<[^<]+>\\)[ \t]*\\'" references)
 670           (match-string 1 references))))))
 671
 672 (defun gnus-buffer-live-p (buffer)
 673   "Say whether BUFFER is alive or not."
 674   (and buffer
 675        (get-buffer buffer)
 676        (buffer-name (get-buffer buffer))))
 677
 678 (defun gnus-horizontal-recenter ()
 679   "Recenter the current buffer horizontally."
 680   (if (< (current-column) (/ (window-width) 2))
 681       (set-window-hscroll (gnus-get-buffer-window (current-buffer) t) 0)
 682     (let* ((orig (point))
 683            (end (window-end (gnus-get-buffer-window (current-buffer) t)))
 684            (max 0))
 685       (when end
 686         ;; Find the longest line currently displayed in the window.
 687         (goto-char (window-start))
 688         (while (and (not (eobp))
 689                     (< (point) end))
 690           (end-of-line)
 691           (setq max (max max (current-column)))
 692           (forward-line 1))
 693         (goto-char orig)
 694         ;; Scroll horizontally to center (sort of) the point.
 695         (if (> max (window-width))
 696             (set-window-hscroll
 697              (gnus-get-buffer-window (current-buffer) t)
 698              (min (- (current-column) (/ (window-width) 3))
 699                   (+ 2 (- max (window-width)))))
 700           (set-window-hscroll (gnus-get-buffer-window (current-buffer) t) 0))
 701         max))))
 702
 703 (defun gnus-read-event-char (&optional prompt)
 704   "Get the next event."
 705   (let ((event (read-event prompt)))
 706     ;; should be gnus-characterp, but this can't be called in XEmacs anyway
 707     (cons (and (numberp event) event) event)))
 708
 709 (defun gnus-sortable-date (date)
 710   "Make string suitable for sorting from DATE."
 711   (gnus-time-iso8601 (date-to-time date)))
 712
 713 (defun gnus-copy-file (file &optional to)
 714   "Copy FILE to TO."
 715   (interactive
 716    (list (read-file-name "Copy file: " default-directory)
 717          (read-file-name "Copy file to: " default-directory)))
 718   (unless to
 719     (setq to (read-file-name "Copy file to: " default-directory)))
 720   (when (file-directory-p to)
 721     (setq to (concat (file-name-as-directory to)
 722                      (file-name-nondirectory file))))
 723   (copy-file file to))
 724
 725 (defvar gnus-work-buffer " *gnus work*")
 726
 727 (declare-function gnus-get-buffer-create "gnus" (name))
 728 ;; gnus.el requires mm-util.
 729 (declare-function mm-enable-multibyte "mm-util")
 730
 731 (defun gnus-set-work-buffer ()
 732   "Put point in the empty Gnus work buffer."
 733   (if (get-buffer gnus-work-buffer)
 734       (progn
 735         (set-buffer gnus-work-buffer)
 736         (erase-buffer))
 737     (set-buffer (gnus-get-buffer-create gnus-work-buffer))
 738     (kill-all-local-variables)
 739     (mm-enable-multibyte)))
 740
 741 (defmacro gnus-group-real-name (group)
 742   "Find the real name of a foreign newsgroup."
 743   `(let ((gname ,group))
 744      (if (string-match "^[^:]+:" gname)
 745          (substring gname (match-end 0))
 746        gname)))
 747
 748 (defmacro gnus-group-server (group)
 749   "Find the server name of a foreign newsgroup.
 750 For example, (gnus-group-server \"nnimap+yxa:INBOX.foo\") would
 751 yield \"nnimap:yxa\"."
 752   `(let ((gname ,group))
 753      (if (string-match "^\\([^:+]+\\)\\(?:\\+\\([^:]*\\)\\)?:" gname)
 754          (format "%s:%s" (match-string 1 gname) (or
 755                                                  (match-string 2 gname)
 756                                                  ""))
 757        (format "%s:%s" (car gnus-select-method) (cadr gnus-select-method)))))
 758
 759 (defun gnus-make-sort-function (funs)
 760   "Return a composite sort condition based on the functions in FUNS."
 761   (cond
 762    ;; Just a simple function.
 763    ((functionp funs) funs)
 764    ;; No functions at all.
 765    ((null funs) funs)
 766    ;; A list of functions.
 767    ((or (cdr funs)
 768         (listp (car funs)))
 769     (gnus-byte-compile
 770      `(lambda (t1 t2)
 771         ,(gnus-make-sort-function-1 (reverse funs)))))
 772    ;; A list containing just one function.
 773    (t
 774     (car funs))))
 775
 776 (defun gnus-make-sort-function-1 (funs)
 777   "Return a composite sort condition based on the functions in FUNS."
 778   (let ((function (car funs))
 779         (first 't1)
 780         (last 't2))
 781     (when (consp function)
 782       (cond
 783        ;; Reversed spec.
 784        ((eq (car function) 'not)
 785         (setq function (cadr function)
 786               first 't2
 787               last 't1))
 788        ((functionp function)
 789         ;; Do nothing.
 790         )
 791        (t
 792         (error "Invalid sort spec: %s" function))))
 793     (if (cdr funs)
 794         `(or (,function ,first ,last)
 795              (and (not (,function ,last ,first))
 796                   ,(gnus-make-sort-function-1 (cdr funs))))
 797       `(,function ,first ,last))))
 798
 799 (defun gnus-turn-off-edit-menu (type)
 800   "Turn off edit menu in `gnus-TYPE-mode-map'."
 801   (define-key (symbol-value (intern (format "gnus-%s-mode-map" type)))
 802     [menu-bar edit] 'undefined))
 803
 804 (defmacro gnus-bind-print-variables (&rest forms)
 805   "Bind print-* variables and evaluate FORMS.
 806 This macro is used with `prin1', `pp', etc. in order to ensure printed
 807 Lisp objects are loadable.  Bind `print-quoted' and `print-readably'
 808 to t, and `print-escape-multibyte', `print-escape-newlines',
 809 `print-escape-nonascii', `print-length', `print-level' and
 810 `print-string-length' to nil."
 811   `(let ((print-quoted t)
 812          (print-readably t)
 813          ;;print-circle
 814          ;;print-continuous-numbering
 815          print-escape-multibyte
 816          print-escape-newlines
 817          print-escape-nonascii
 818          ;;print-gensym
 819          print-length
 820          print-level
 821          print-string-length)
 822      ,@forms))
 823
 824 (defun gnus-prin1 (form)
 825   "Use `prin1' on FORM in the current buffer.
 826 Bind `print-quoted' and `print-readably' to t, and `print-length' and
 827 `print-level' to nil.  See also `gnus-bind-print-variables'."
 828   (gnus-bind-print-variables (prin1 form (current-buffer))))
 829
 830 (defun gnus-prin1-to-string (form)
 831   "The same as `prin1'.
 832 Bind `print-quoted' and `print-readably' to t, and `print-length' and
 833 `print-level' to nil.  See also `gnus-bind-print-variables'."
 834   (gnus-bind-print-variables (prin1-to-string form)))
 835
 836 (defun gnus-pp (form &optional stream)
 837   "Use `pp' on FORM in the current buffer.
 838 Bind `print-quoted' and `print-readably' to t, and `print-length' and
 839 `print-level' to nil.  See also `gnus-bind-print-variables'."
 840   (gnus-bind-print-variables (pp form (or stream (current-buffer)))))
 841
 842 (defun gnus-pp-to-string (form)
 843   "The same as `pp-to-string'.
 844 Bind `print-quoted' and `print-readably' to t, and `print-length' and
 845 `print-level' to nil.  See also `gnus-bind-print-variables'."
 846   (gnus-bind-print-variables (pp-to-string form)))
 847
 848 (defun gnus-make-directory (directory)
 849   "Make DIRECTORY (and all its parents) if it doesn't exist."
 850   (require 'nnmail)
 851   (let ((file-name-coding-system nnmail-pathname-coding-system))
 852     (when (and directory
 853                (not (file-exists-p directory)))
 854       (make-directory directory t)))
 855   t)
 856
 857 (defun gnus-write-buffer (file)
 858   "Write the current buffer's contents to FILE."
 859   (let ((file-name-coding-system nnmail-pathname-coding-system))
 860     ;; Make sure the directory exists.
 861     (gnus-make-directory (file-name-directory file))
 862     ;; Write the buffer.
 863     (write-region (point-min) (point-max) file nil 'quietly)))
 864
 865 (defun gnus-delete-file (file)
 866   "Delete FILE if it exists."
 867   (when (file-exists-p file)
 868     (delete-file file)))
 869
 870 (defun gnus-delete-directory (directory)
 871   "Delete files in DIRECTORY.  Subdirectories remain.
 872 If there's no subdirectory, delete DIRECTORY as well."
 873   (when (file-directory-p directory)
 874     (let ((files (directory-files
 875                   directory t "^\\([^.]\\|\\.\\([^.]\\|\\..\\)\\).*"))
 876           file dir)
 877       (while files
 878         (setq file (pop files))
 879         (if (eq t (car (file-attributes file)))
 880             ;; `file' is a subdirectory.
 881             (setq dir t)
 882           ;; `file' is a file or a symlink.
 883           (delete-file file)))
 884       (unless dir
 885         (delete-directory directory)))))
 886
 887 ;; The following two functions are used in gnus-registry.
 888 ;; They were contributed by Andreas Fuchs <asf@void.at>.
 889 (defun gnus-alist-to-hashtable (alist)
 890   "Build a hashtable from the values in ALIST."
 891   (let ((ht (make-hash-table
 892              :size 4096
 893              :test 'equal)))
 894     (mapc
 895      (lambda (kv-pair)
 896        (puthash (car kv-pair) (cdr kv-pair) ht))
 897      alist)
 898      ht))
 899
 900 (defun gnus-hashtable-to-alist (hash)
 901   "Build an alist from the values in HASH."
 902   (let ((list nil))
 903     (maphash
 904      (lambda (key value)
 905        (setq list (cons (cons key value) list)))
 906      hash)
 907     list))
 908
 909 (defun gnus-strip-whitespace (string)
 910   "Return STRING stripped of all whitespace."
 911   (while (string-match "[\r\n\t ]+" string)
 912     (setq string (replace-match "" t t string)))
 913   string)
 914
 915 (declare-function gnus-put-text-property "gnus"
 916                   (start end property value &optional object))
 917
 918 (defsubst gnus-put-text-property-excluding-newlines (beg end prop val)
 919   "The same as `put-text-property', but don't put this prop on any newlines in the region."
 920   (save-match-data
 921     (save-excursion
 922       (save-restriction
 923         (goto-char beg)
 924         (while (re-search-forward gnus-emphasize-whitespace-regexp end 'move)
 925           (gnus-put-text-property beg (match-beginning 0) prop val)
 926           (setq beg (point)))
 927         (gnus-put-text-property beg (point) prop val)))))
 928
 929 (declare-function gnus-overlay-put  "gnus" (overlay prop value))
 930 (declare-function gnus-make-overlay "gnus"
 931                   (beg end &optional buffer front-advance rear-advance))
 932
 933 (defsubst gnus-put-overlay-excluding-newlines (beg end prop val)
 934   "The same as `put-text-property', but don't put this prop on any newlines in the region."
 935   (save-match-data
 936     (save-excursion
 937       (save-restriction
 938         (goto-char beg)
 939         (while (re-search-forward gnus-emphasize-whitespace-regexp end 'move)
 940           (gnus-overlay-put
 941            (gnus-make-overlay beg (match-beginning 0))
 942            prop val)
 943           (setq beg (point)))
 944         (gnus-overlay-put (gnus-make-overlay beg (point)) prop val)))))
 945
 946 (defun gnus-put-text-property-excluding-characters-with-faces (beg end
 947                                                                    prop val)
 948   "The same as `put-text-property', but don't put props on characters with the `gnus-face' property."
 949   (let ((b beg))
 950     (while (/= b end)
 951       (when (get-text-property b 'gnus-face)
 952         (setq b (next-single-property-change b 'gnus-face nil end)))
 953       (when (/= b end)
 954         (inline
 955           (gnus-put-text-property
 956            b (setq b (next-single-property-change b 'gnus-face nil end))
 957            prop val))))))
 958
 959 (defmacro gnus-faces-at (position)
 960   "Return a list of faces at POSITION."
 961   (if (featurep 'xemacs)
 962       `(let ((pos ,position))
 963          (mapcar-extents 'extent-face
 964                          nil (current-buffer) pos pos nil 'face))
 965     `(let ((pos ,position))
 966        (delq nil (cons (get-text-property pos 'face)
 967                        (mapcar
 968                         (lambda (overlay)
 969                           (overlay-get overlay 'face))
 970                         (overlays-at pos)))))))
 971
 972 (if (fboundp 'invisible-p)
 973     (defalias 'gnus-invisible-p 'invisible-p)
 974   ;; for Emacs < 22.2, and XEmacs.
 975   (defun gnus-invisible-p (pos)
 976     "Return non-nil if the character after POS is currently invisible."
 977     (let ((prop (get-char-property pos 'invisible)))
 978       (if (eq buffer-invisibility-spec t)
 979           prop
 980         (or (memq prop buffer-invisibility-spec)
 981             (assq prop buffer-invisibility-spec))))))
 982
 983 ;; Note: the optional 2nd argument has a different meaning between
 984 ;; Emacs and XEmacs.
 985 ;; (next-char-property-change POSITION &optional LIMIT)
 986 ;; (next-extent-change        POS      &optional OBJECT)
 987 (defalias 'gnus-next-char-property-change
 988   (if (fboundp 'next-extent-change)
 989       'next-extent-change 'next-char-property-change))
 990
 991 (defalias 'gnus-previous-char-property-change
 992   (if (fboundp 'previous-extent-change)
 993       'previous-extent-change 'previous-char-property-change))
 994
 995 ;;; Protected and atomic operations.  dmoore@ucsd.edu 21.11.1996
 996 ;; The primary idea here is to try to protect internal datastructures
 997 ;; from becoming corrupted when the user hits C-g, or if a hook or
 998 ;; similar blows up.  Often in Gnus multiple tables/lists need to be
 999 ;; updated at the same time, or information can be lost.
1000
1001 (defvar gnus-atomic-be-safe t
1002   "If t, certain operations will be protected from interruption by C-g.")
1003
1004 (defmacro gnus-atomic-progn (&rest forms)
1005   "Evaluate FORMS atomically, which means to protect the evaluation
1006 from being interrupted by the user.  An error from the forms themselves
1007 will return without finishing the operation.  Since interrupts from
1008 the user are disabled, it is recommended that only the most minimal
1009 operations are performed by FORMS.  If you wish to assign many
1010 complicated values atomically, compute the results into temporary
1011 variables and then do only the assignment atomically."
1012   `(let ((inhibit-quit gnus-atomic-be-safe))
1013      ,@forms))
1014
1015 (put 'gnus-atomic-progn 'lisp-indent-function 0)
1016
1017 (defmacro gnus-atomic-progn-assign (protect &rest forms)
1018   "Evaluate FORMS, but ensure that the variables listed in PROTECT
1019 are not changed if anything in FORMS signals an error or otherwise
1020 non-locally exits.  The variables listed in PROTECT are updated atomically.
1021 It is safe to use gnus-atomic-progn-assign with long computations.
1022
1023 Note that if any of the symbols in PROTECT were unbound, they will be
1024 set to nil on a successful assignment.  In case of an error or other
1025 non-local exit, it will still be unbound."
1026   (let* ((temp-sym-map (mapcar (lambda (x) (list (make-symbol
1027                                                   (concat (symbol-name x)
1028                                                           "-tmp"))
1029                                                  x))
1030                                protect))
1031          (sym-temp-map (mapcar (lambda (x) (list (cadr x) (car x)))
1032                                temp-sym-map))
1033          (temp-sym-let (mapcar (lambda (x) (list (car x)
1034                                                  `(and (boundp ',(cadr x))
1035                                                        ,(cadr x))))
1036                                temp-sym-map))
1037          (sym-temp-let sym-temp-map)
1038          (temp-sym-assign (apply 'append temp-sym-map))
1039          (sym-temp-assign (apply 'append sym-temp-map))
1040          (result (make-symbol "result-tmp")))
1041     `(let (,@temp-sym-let
1042            ,result)
1043        (let ,sym-temp-let
1044          (setq ,result (progn ,@forms))
1045          (setq ,@temp-sym-assign))
1046        (let ((inhibit-quit gnus-atomic-be-safe))
1047          (setq ,@sym-temp-assign))
1048        ,result)))
1049
1050 (put 'gnus-atomic-progn-assign 'lisp-indent-function 1)
1051 ;(put 'gnus-atomic-progn-assign 'edebug-form-spec '(sexp body))
1052
1053 (defmacro gnus-atomic-setq (&rest pairs)
1054   "Similar to setq, except that the real symbols are only assigned when
1055 there are no errors.  And when the real symbols are assigned, they are
1056 done so atomically.  If other variables might be changed via side-effect,
1057 see gnus-atomic-progn-assign.  It is safe to use gnus-atomic-setq
1058 with potentially long computations."
1059   (let ((tpairs pairs)
1060         syms)
1061     (while tpairs
1062       (push (car tpairs) syms)
1063       (setq tpairs (cddr tpairs)))
1064     `(gnus-atomic-progn-assign ,syms
1065        (setq ,@pairs))))
1066
1067 ;(put 'gnus-atomic-setq 'edebug-form-spec '(body))
1068
1069
1070 ;;; Functions for saving to babyl/mail files.
1071
1072 (eval-when-compile
1073   (if (featurep 'xemacs)
1074       ;; Don't load tm and apel XEmacs packages that provide some
1075       ;; Emacs emulating functions and variables.
1076       (let ((features features))
1077         (provide 'tm-view)
1078         (unless (fboundp 'set-alist) (defalias 'set-alist 'ignore))
1079         (require 'rmail)) ;; It requires tm-view that loads apel.
1080     (require 'rmail))
1081   (autoload 'rmail-update-summary "rmailsum"))
1082
1083 (defvar mm-text-coding-system)
1084
1085 (declare-function mm-append-to-file "mm-util"
1086                   (start end filename &optional codesys inhibit))
1087
1088 (defun gnus-output-to-rmail (filename &optional ask)
1089   "Append the current article to an Rmail file named FILENAME.
1090 In Emacs 22 this writes Babyl format; in Emacs 23 it writes mbox unless
1091 FILENAME exists and is Babyl format."
1092   (require 'rmail)
1093   (require 'mm-util)
1094   ;; Some of this codes is borrowed from rmailout.el.
1095   (setq filename (expand-file-name filename))
1096   ;; FIXME should we really be messing with this defcustom?
1097   ;; It is not needed for the operation of this function.
1098   (if (boundp 'rmail-default-rmail-file)
1099       (setq rmail-default-rmail-file filename) ; 22
1100     (setq rmail-default-file filename))        ; 23
1101   (let ((artbuf (current-buffer))
1102         (tmpbuf (get-buffer-create " *Gnus-output*"))
1103         ;; Babyl rmail.el defines this, mbox does not.
1104         (babyl (fboundp 'rmail-insert-rmail-file-header)))
1105     (save-excursion
1106       ;; Note that we ignore the possibility of visiting a Babyl
1107       ;; format buffer in Emacs 23, since Rmail no longer supports that.
1108      (or (get-file-buffer filename)
1109          (progn
1110            ;; In case someone wants to write to a Babyl file from Emacs 23.
1111            (when (file-exists-p filename)
1112              (setq babyl (mail-file-babyl-p filename))
1113              t))
1114           (if (or (not ask)
1115                   (gnus-yes-or-no-p
1116                    (concat "\"" filename "\" does not exist, create it? ")))
1117               (let ((file-buffer (create-file-buffer filename)))
1118                 (with-current-buffer file-buffer
1119                   (if (fboundp 'rmail-insert-rmail-file-header)
1120                       (rmail-insert-rmail-file-header))
1121                   (let ((require-final-newline nil)
1122                         (coding-system-for-write mm-text-coding-system))
1123                     (gnus-write-buffer filename)))
1124                 (kill-buffer file-buffer))
1125             (error "Output file does not exist")))
1126       (set-buffer tmpbuf)
1127       (erase-buffer)
1128       (insert-buffer-substring artbuf)
1129       (if babyl
1130           (gnus-convert-article-to-rmail)
1131         ;; Non-Babyl case copied from gnus-output-to-mail.
1132         (goto-char (point-min))
1133         (if (looking-at "From ")
1134             (forward-line 1)
1135           (insert "From nobody " (current-time-string) "\n"))
1136         (let (case-fold-search)
1137           (while (re-search-forward "^From " nil t)
1138             (beginning-of-line)
1139             (insert ">"))))
1140       ;; Decide whether to append to a file or to an Emacs buffer.
1141       (let ((outbuf (get-file-buffer filename)))
1142         (if (not outbuf)
1143             (progn
1144               (unless babyl             ; from gnus-output-to-mail
1145                 (let ((buffer-read-only nil))
1146                   (goto-char (point-max))
1147                   (forward-char -2)
1148                   (unless (looking-at "\n\n")
1149                     (goto-char (point-max))
1150                     (unless (bolp)
1151                       (insert "\n"))
1152                     (insert "\n"))))
1153               (let ((file-name-coding-system nnmail-pathname-coding-system))
1154                 (mm-append-to-file (point-min) (point-max) filename)))
1155           ;; File has been visited, in buffer OUTBUF.
1156           (set-buffer outbuf)
1157           (let ((buffer-read-only nil)
1158                 (msg (and (boundp 'rmail-current-message)
1159                           (symbol-value 'rmail-current-message))))
1160             ;; If MSG is non-nil, buffer is in RMAIL mode.
1161             ;; Compare this with rmail-output-to-rmail-buffer in Emacs 23.
1162             (when msg
1163               (unless babyl
1164                 (rmail-swap-buffers-maybe)
1165                 (rmail-maybe-set-message-counters))
1166               (widen)
1167               (narrow-to-region (point-max) (point-max)))
1168             (insert-buffer-substring tmpbuf)
1169             (when msg
1170               (when babyl
1171                 (goto-char (point-min))
1172                 (widen)
1173                 (search-backward "\n\^_")
1174                 (narrow-to-region (point) (point-max)))
1175               (rmail-count-new-messages t)
1176               (when (rmail-summary-exists)
1177                 (rmail-select-summary
1178                  (rmail-update-summary)))
1179               (rmail-show-message msg))
1180             (save-buffer)))))
1181     (kill-buffer tmpbuf)))
1182
1183 (defun gnus-output-to-mail (filename &optional ask)
1184   "Append the current article to a mail file named FILENAME."
1185   (setq filename (expand-file-name filename))
1186   (let ((artbuf (current-buffer))
1187         (tmpbuf (get-buffer-create " *Gnus-output*")))
1188     (save-excursion
1189       ;; Create the file, if it doesn't exist.
1190       (when (and (not (get-file-buffer filename))
1191                  (not (file-exists-p filename)))
1192         (if (or (not ask)
1193                 (gnus-y-or-n-p
1194                  (concat "\"" filename "\" does not exist, create it? ")))
1195             (let ((file-buffer (create-file-buffer filename)))
1196               (with-current-buffer file-buffer
1197                 (let ((require-final-newline nil)
1198                       (coding-system-for-write mm-text-coding-system))
1199                   (gnus-write-buffer filename)))
1200               (kill-buffer file-buffer))
1201           (error "Output file does not exist")))
1202       (set-buffer tmpbuf)
1203       (erase-buffer)
1204       (insert-buffer-substring artbuf)
1205       (goto-char (point-min))
1206       (if (looking-at "From ")
1207           (forward-line 1)
1208         (insert "From nobody " (current-time-string) "\n"))
1209       (let (case-fold-search)
1210         (while (re-search-forward "^From " nil t)
1211           (beginning-of-line)
1212           (insert ">")))
1213       ;; Decide whether to append to a file or to an Emacs buffer.
1214       (let ((outbuf (get-file-buffer filename)))
1215         (if (not outbuf)
1216             (let ((buffer-read-only nil))
1217               (save-excursion
1218                 (goto-char (point-max))
1219                 (forward-char -2)
1220                 (unless (looking-at "\n\n")
1221                   (goto-char (point-max))
1222                   (unless (bolp)
1223                     (insert "\n"))
1224                   (insert "\n"))
1225                 (goto-char (point-max))
1226                 (let ((file-name-coding-system nnmail-pathname-coding-system))
1227                   (mm-append-to-file (point-min) (point-max) filename))))
1228           ;; File has been visited, in buffer OUTBUF.
1229           (set-buffer outbuf)
1230           (let ((buffer-read-only nil))
1231             (goto-char (point-max))
1232             (unless (eobp)
1233               (insert "\n"))
1234             (insert "\n")
1235             (insert-buffer-substring tmpbuf)))))
1236     (kill-buffer tmpbuf)))
1237
1238 (defun gnus-convert-article-to-rmail ()
1239   "Convert article in current buffer to Rmail message format."
1240   (let ((buffer-read-only nil))
1241     ;; Convert article directly into Babyl format.
1242     (goto-char (point-min))
1243     (insert "\^L\n0, unseen,,\n*** EOOH ***\n")
1244     (while (search-forward "\n\^_" nil t) ;single char
1245       (replace-match "\n^_" t t))       ;2 chars: "^" and "_"
1246     (goto-char (point-max))
1247     (insert "\^_")))
1248
1249 (defun gnus-map-function (funs arg)
1250   "Apply the result of the first function in FUNS to the second, and so on.
1251 ARG is passed to the first function."
1252   (while funs
1253     (setq arg (funcall (pop funs) arg)))
1254   arg)
1255
1256 (defun gnus-run-hooks (&rest funcs)
1257   "Does the same as `run-hooks', but saves the current buffer."
1258   (save-current-buffer
1259     (apply 'run-hooks funcs)))
1260
1261 (defun gnus-run-mode-hooks (&rest funcs)
1262   "Run `run-mode-hooks' if it is available, otherwise `run-hooks'.
1263 This function saves the current buffer."
1264   (if (fboundp 'run-mode-hooks)
1265       (save-current-buffer (apply 'run-mode-hooks funcs))
1266     (save-current-buffer (apply 'run-hooks funcs))))
1267
1268 ;;; Various
1269
1270 (defvar gnus-group-buffer)              ; Compiler directive
1271 (defun gnus-alive-p ()
1272   "Say whether Gnus is running or not."
1273   (and (boundp 'gnus-group-buffer)
1274        (get-buffer gnus-group-buffer)
1275        (with-current-buffer gnus-group-buffer
1276          (eq major-mode 'gnus-group-mode))))
1277
1278 (defun gnus-remove-if (predicate list)
1279   "Return a copy of LIST with all items satisfying PREDICATE removed."
1280   (let (out)
1281     (while list
1282       (unless (funcall predicate (car list))
1283         (push (car list) out))
1284       (setq list (cdr list)))
1285     (nreverse out)))
1286
1287 (if (fboundp 'assq-delete-all)
1288     (defalias 'gnus-delete-alist 'assq-delete-all)
1289   (defun gnus-delete-alist (key alist)
1290     "Delete from ALIST all elements whose car is KEY.
1291 Return the modified alist."
1292     (let (entry)
1293       (while (setq entry (assq key alist))
1294         (setq alist (delq entry alist)))
1295       alist)))
1296
1297 (defun gnus-grep-in-list (word list)
1298   "Find if a WORD matches any regular expression in the given LIST."
1299   (when (and word list)
1300     (catch 'found
1301       (dolist (r list)
1302         (when (string-match r word)
1303           (throw 'found r))))))
1304
1305 (defmacro gnus-pull (key alist &optional assoc-p)
1306   "Modify ALIST to be without KEY."
1307   (unless (symbolp alist)
1308     (error "Not a symbol: %s" alist))
1309   (let ((fun (if assoc-p 'assoc 'assq)))
1310     `(setq ,alist (delq (,fun ,key ,alist) ,alist))))
1311
1312 (defun gnus-globalify-regexp (re)
1313   "Return a regexp that matches a whole line, if RE matches a part of it."
1314   (concat (unless (string-match "^\\^" re) "^.*")
1315           re
1316           (unless (string-match "\\$$" re) ".*$")))
1317
1318 (defun gnus-set-window-start (&optional point)
1319   "Set the window start to POINT, or (point) if nil."
1320   (let ((win (gnus-get-buffer-window (current-buffer) t)))
1321     (when win
1322       (set-window-start win (or point (point))))))
1323
1324 (defun gnus-annotation-in-region-p (b e)
1325   (if (= b e)
1326       (eq (cadr (memq 'gnus-undeletable (text-properties-at b))) t)
1327     (text-property-any b e 'gnus-undeletable t)))
1328
1329 (defun gnus-or (&rest elems)
1330   "Return non-nil if any of the elements are non-nil."
1331   (catch 'found
1332     (while elems
1333       (when (pop elems)
1334         (throw 'found t)))))
1335
1336 (defun gnus-and (&rest elems)
1337   "Return non-nil if all of the elements are non-nil."
1338   (catch 'found
1339     (while elems
1340       (unless (pop elems)
1341         (throw 'found nil)))
1342     t))
1343
1344 ;; gnus.el requires mm-util.
1345 (declare-function mm-disable-multibyte "mm-util")
1346
1347 (defun gnus-write-active-file (file hashtb &optional full-names)
1348   ;; `coding-system-for-write' should be `raw-text' or equivalent.
1349   (let ((coding-system-for-write nnmail-active-file-coding-system))
1350     (with-temp-file file
1351       ;; The buffer should be in the unibyte mode because group names
1352       ;; are ASCII text or encoded non-ASCII text (i.e., unibyte).
1353       (mm-disable-multibyte)
1354       (mapatoms
1355        (lambda (sym)
1356          (when (and sym
1357                     (boundp sym)
1358                     (symbol-value sym))
1359            (insert (format "%S %d %d y\n"
1360                            (if full-names
1361                                sym
1362                              (intern (gnus-group-real-name (symbol-name sym))))
1363                            (or (cdr (symbol-value sym))
1364                                (car (symbol-value sym)))
1365                            (car (symbol-value sym))))))
1366        hashtb)
1367       (goto-char (point-max))
1368       (while (search-backward "\\." nil t)
1369         (delete-char 1)))))
1370
1371 ;; Fixme: Why not use `with-output-to-temp-buffer'?
1372 (defmacro gnus-with-output-to-file (file &rest body)
1373   (let ((buffer (make-symbol "output-buffer"))
1374         (size (make-symbol "output-buffer-size"))
1375         (leng (make-symbol "output-buffer-length"))
1376         (append (make-symbol "output-buffer-append")))
1377     `(let* ((,size 131072)
1378             (,buffer (make-string ,size 0))
1379             (,leng 0)
1380             (,append nil)
1381             (standard-output
1382              (lambda (c)
1383                (aset ,buffer ,leng c)
1384
1385                (if (= ,size (setq ,leng (1+ ,leng)))
1386                    (progn (write-region ,buffer nil ,file ,append 'no-msg)
1387                           (setq ,leng 0
1388                                 ,append t))))))
1389        ,@body
1390        (when (> ,leng 0)
1391          (let ((coding-system-for-write 'no-conversion))
1392          (write-region (substring ,buffer 0 ,leng) nil ,file
1393                        ,append 'no-msg))))))
1394
1395 (put 'gnus-with-output-to-file 'lisp-indent-function 1)
1396 (put 'gnus-with-output-to-file 'edebug-form-spec '(form body))
1397
1398 (if (fboundp 'union)
1399     (defalias 'gnus-union 'union)
1400   (defun gnus-union (l1 l2)
1401     "Set union of lists L1 and L2."
1402     (cond ((null l1) l2)
1403           ((null l2) l1)
1404           ((equal l1 l2) l1)
1405           (t
1406            (or (>= (length l1) (length l2))
1407                (setq l1 (prog1 l2 (setq l2 l1))))
1408            (while l2
1409              (or (member (car l2) l1)
1410                  (push (car l2) l1))
1411              (pop l2))
1412            l1))))
1413
1414 (declare-function gnus-add-text-properties "gnus"
1415                   (start end properties &optional object))
1416
1417 (defun gnus-add-text-properties-when
1418   (property value start end properties &optional object)
1419   "Like `gnus-add-text-properties', only applied on where PROPERTY is VALUE."
1420   (let (point)
1421     (while (and start
1422                 (< start end) ;; XEmacs will loop for every when start=end.
1423                 (setq point (text-property-not-all start end property value)))
1424       (gnus-add-text-properties start point properties object)
1425       (setq start (text-property-any point end property value)))
1426     (if start
1427         (gnus-add-text-properties start end properties object))))
1428
1429 (defun gnus-remove-text-properties-when
1430   (property value start end properties &optional object)
1431   "Like `remove-text-properties', only applied on where PROPERTY is VALUE."
1432   (let (point)
1433     (while (and start
1434                 (< start end)
1435                 (setq point (text-property-not-all start end property value)))
1436       (remove-text-properties start point properties object)
1437       (setq start (text-property-any point end property value)))
1438     (if start
1439         (remove-text-properties start end properties object))
1440     t))
1441
1442 (defun gnus-string-remove-all-properties (string)
1443   (condition-case ()
1444       (let ((s string))
1445         (set-text-properties 0 (length string) nil string)
1446         s)
1447     (error string)))
1448
1449 ;; This might use `compare-strings' to reduce consing in the
1450 ;; case-insensitive case, but it has to cope with null args.
1451 ;; (`string-equal' uses symbol print names.)
1452 (defun gnus-string-equal (x y)
1453   "Like `string-equal', except it compares case-insensitively."
1454   (and (= (length x) (length y))
1455        (or (string-equal x y)
1456            (string-equal (downcase x) (downcase y)))))
1457
1458 (defcustom gnus-use-byte-compile t
1459   "If non-nil, byte-compile crucial run-time code.
1460 Setting it to nil has no effect after the first time `gnus-byte-compile'
1461 is run."
1462   :type 'boolean
1463   :version "22.1"
1464   :group 'gnus-various)
1465
1466 (defun gnus-byte-compile (form)
1467   "Byte-compile FORM if `gnus-use-byte-compile' is non-nil."
1468   (if gnus-use-byte-compile
1469       (progn
1470         (condition-case nil
1471             ;; Work around a bug in XEmacs 21.4
1472             (require 'byte-optimize)
1473           (error))
1474         (require 'bytecomp)
1475         (defalias 'gnus-byte-compile
1476           (lambda (form)
1477             (let ((byte-compile-warnings '(unresolved callargs redefine)))
1478               (byte-compile form))))
1479         (gnus-byte-compile form))
1480     form))
1481
1482 (defun gnus-remassoc (key alist)
1483   "Delete by side effect any elements of LIST whose car is `equal' to KEY.
1484 The modified LIST is returned.  If the first member
1485 of LIST has a car that is `equal' to KEY, there is no way to remove it
1486 by side effect; therefore, write `(setq foo (gnus-remassoc key foo))' to be
1487 sure of changing the value of `foo'."
1488   (when alist
1489     (if (equal key (caar alist))
1490         (cdr alist)
1491       (setcdr alist (gnus-remassoc key (cdr alist)))
1492       alist)))
1493
1494 (defun gnus-update-alist-soft (key value alist)
1495   (if value
1496       (cons (cons key value) (gnus-remassoc key alist))
1497     (gnus-remassoc key alist)))
1498
1499 (defun gnus-create-info-command (node)
1500   "Create a command that will go to info NODE."
1501   `(lambda ()
1502      (interactive)
1503      ,(concat "Enter the info system at node " node)
1504      (Info-goto-node ,node)
1505      (setq gnus-info-buffer (current-buffer))
1506      (gnus-configure-windows 'info)))
1507
1508 (defun gnus-not-ignore (&rest args)
1509   t)
1510
1511 (defvar gnus-directory-sep-char-regexp "/"
1512   "The regexp of directory separator character.
1513 If you find some problem with the directory separator character, try
1514 \"[/\\\\\]\" for some systems.")
1515
1516 (defun gnus-url-unhex (x)
1517   (if (> x ?9)
1518       (if (>= x ?a)
1519           (+ 10 (- x ?a))
1520         (+ 10 (- x ?A)))
1521     (- x ?0)))
1522
1523 ;; Fixme: Do it like QP.
1524 (defun gnus-url-unhex-string (str &optional allow-newlines)
1525   "Remove %XX, embedded spaces, etc in a url.
1526 If optional second argument ALLOW-NEWLINES is non-nil, then allow the
1527 decoding of carriage returns and line feeds in the string, which is normally
1528 forbidden in URL encoding."
1529   (let ((tmp "")
1530         (case-fold-search t))
1531     (while (string-match "%[0-9a-f][0-9a-f]" str)
1532       (let* ((start (match-beginning 0))
1533              (ch1 (gnus-url-unhex (elt str (+ start 1))))
1534              (code (+ (* 16 ch1)
1535                       (gnus-url-unhex (elt str (+ start 2))))))
1536         (setq tmp (concat
1537                    tmp (substring str 0 start)
1538                    (cond
1539                     (allow-newlines
1540                      (char-to-string code))
1541                     ((or (= code ?\n) (= code ?\r))
1542                      " ")
1543                     (t (char-to-string code))))
1544               str (substring str (match-end 0)))))
1545     (setq tmp (concat tmp str))
1546     tmp))
1547
1548 (defun gnus-make-predicate (spec)
1549   "Transform SPEC into a function that can be called.
1550 SPEC is a predicate specifier that contains stuff like `or', `and',
1551 `not', lists and functions.  The functions all take one parameter."
1552   `(lambda (elem) ,(gnus-make-predicate-1 spec)))
1553
1554 (defun gnus-make-predicate-1 (spec)
1555   (cond
1556    ((symbolp spec)
1557     `(,spec elem))
1558    ((listp spec)
1559     (if (memq (car spec) '(or and not))
1560         `(,(car spec) ,@(mapcar 'gnus-make-predicate-1 (cdr spec)))
1561       (error "Invalid predicate specifier: %s" spec)))))
1562
1563 (defun gnus-completing-read (prompt table &optional predicate require-match
1564                                     history)
1565   (when (and history
1566              (not (boundp history)))
1567     (set history nil))
1568   (completing-read
1569    (if (symbol-value history)
1570        (concat prompt " (" (car (symbol-value history)) "): ")
1571      (concat prompt ": "))
1572    table
1573    predicate
1574    require-match
1575    nil
1576    history
1577    (car (symbol-value history))))
1578
1579 (defun gnus-graphic-display-p ()
1580   (if (featurep 'xemacs)
1581       (device-on-window-system-p)
1582     (display-graphic-p)))
1583
1584 (put 'gnus-parse-without-error 'lisp-indent-function 0)
1585 (put 'gnus-parse-without-error 'edebug-form-spec '(body))
1586
1587 (defmacro gnus-parse-without-error (&rest body)
1588   "Allow continuing onto the next line even if an error occurs."
1589   `(while (not (eobp))
1590      (condition-case ()
1591          (progn
1592            ,@body
1593            (goto-char (point-max)))
1594        (error
1595         (gnus-error 4 "Invalid data on line %d"
1596                     (count-lines (point-min) (point)))
1597         (forward-line 1)))))
1598
1599 (defun gnus-cache-file-contents (file variable function)
1600   "Cache the contents of FILE in VARIABLE.  The contents come from FUNCTION."
1601   (let ((time (nth 5 (file-attributes file)))
1602         contents value)
1603     (if (or (null (setq value (symbol-value variable)))
1604             (not (equal (car value) file))
1605             (not (equal (nth 1 value) time)))
1606         (progn
1607           (setq contents (funcall function file))
1608           (set variable (list file time contents))
1609           contents)
1610       (nth 2 value))))
1611
1612 (defun gnus-multiple-choice (prompt choice &optional idx)
1613   "Ask user a multiple choice question.
1614 CHOICE is a list of the choice char and help message at IDX."
1615   (let (tchar buf)
1616     (save-window-excursion
1617       (save-excursion
1618         (while (not tchar)
1619           (message "%s (%s): "
1620                    prompt
1621                    (concat
1622                     (mapconcat (lambda (s) (char-to-string (car s)))
1623                                choice ", ") ", ?"))
1624           (setq tchar (read-char))
1625           (when (not (assq tchar choice))
1626             (setq tchar nil)
1627             (setq buf (get-buffer-create "*Gnus Help*"))
1628             (pop-to-buffer buf)
1629             (fundamental-mode)          ; for Emacs 20.4+
1630             (buffer-disable-undo)
1631             (erase-buffer)
1632             (insert prompt ":\n\n")
1633             (let ((max -1)
1634                   (list choice)
1635                   (alist choice)
1636                   (idx (or idx 1))
1637                   (i 0)
1638                   n width pad format)
1639               ;; find the longest string to display
1640               (while list
1641                 (setq n (length (nth idx (car list))))
1642                 (unless (> max n)
1643                   (setq max n))
1644                 (setq list (cdr list)))
1645               (setq max (+ max 4))      ; %c, `:', SPACE, a SPACE at end
1646               (setq n (/ (1- (window-width)) max)) ; items per line
1647               (setq width (/ (1- (window-width)) n)) ; width of each item
1648               ;; insert `n' items, each in a field of width `width'
1649               (while alist
1650                 (if (< i n)
1651                     ()
1652                   (setq i 0)
1653                   (delete-char -1)              ; the `\n' takes a char
1654                   (insert "\n"))
1655                 (setq pad (- width 3))
1656                 (setq format (concat "%c: %-" (int-to-string pad) "s"))
1657                 (insert (format format (caar alist) (nth idx (car alist))))
1658                 (setq alist (cdr alist))
1659                 (setq i (1+ i))))))))
1660     (if (buffer-live-p buf)
1661         (kill-buffer buf))
1662     tchar))
1663
1664 (declare-function x-focus-frame "xfns.c" (frame))
1665 (declare-function w32-focus-frame "../term/w32-win" (frame))
1666
1667 (defun gnus-select-frame-set-input-focus (frame)
1668   "Select FRAME, raise it, and set input focus, if possible."
1669   (cond ((featurep 'xemacs)
1670          (if (fboundp 'select-frame-set-input-focus)
1671              (select-frame-set-input-focus frame)
1672            (raise-frame frame)
1673            (select-frame frame)
1674            (focus-frame frame)))
1675         ;; `select-frame-set-input-focus' defined in Emacs 21 will not
1676         ;; set the input focus.
1677         ((>= emacs-major-version 22)
1678          (select-frame-set-input-focus frame))
1679         (t
1680          (raise-frame frame)
1681          (select-frame frame)
1682          (cond ((memq window-system '(x ns mac))
1683                 (x-focus-frame frame))
1684                ((eq window-system 'w32)
1685                 (w32-focus-frame frame)))
1686          (when focus-follows-mouse
1687            (set-mouse-position frame (1- (frame-width frame)) 0)))))
1688
1689 (defun gnus-frame-or-window-display-name (object)
1690   "Given a frame or window, return the associated display name.
1691 Return nil otherwise."
1692   (if (featurep 'xemacs)
1693       (device-connection (dfw-device object))
1694     (if (or (framep object)
1695             (and (windowp object)
1696                  (setq object (window-frame object))))
1697         (let ((display (frame-parameter object 'display)))
1698           (if (and (stringp display)
1699                    ;; Exclude invalid display names.
1700                    (string-match "\\`[^:]*:[0-9]+\\(\\.[0-9]+\\)?\\'"
1701                                  display))
1702               display)))))
1703
1704 (defvar tool-bar-mode)
1705
1706 (defun gnus-tool-bar-update (&rest ignore)
1707   "Update the tool bar."
1708   (when (and (boundp 'tool-bar-mode)
1709              tool-bar-mode)
1710     (let* ((args nil)
1711            (func (cond ((featurep 'xemacs)
1712                         'ignore)
1713                        ((fboundp 'tool-bar-update)
1714                         'tool-bar-update)
1715                        ((fboundp 'force-window-update)
1716                         'force-window-update)
1717                        ((fboundp 'redraw-frame)
1718                         (setq args (list (selected-frame)))
1719                         'redraw-frame)
1720                        (t 'ignore))))
1721       (apply func args))))
1722
1723 ;; Fixme: This has only one use (in gnus-agent), which isn't worthwhile.
1724 (defmacro gnus-mapcar (function seq1 &rest seqs2_n)
1725   "Apply FUNCTION to each element of the sequences, and make a list of the results.
1726 If there are several sequences, FUNCTION is called with that many arguments,
1727 and mapping stops as soon as the shortest sequence runs out.  With just one
1728 sequence, this is like `mapcar'.  With several, it is like the Common Lisp
1729 `mapcar' function extended to arbitrary sequence types."
1730
1731   (if seqs2_n
1732       (let* ((seqs (cons seq1 seqs2_n))
1733              (cnt 0)
1734              (heads (mapcar (lambda (seq)
1735                               (make-symbol (concat "head"
1736                                                    (int-to-string
1737                                                     (setq cnt (1+ cnt))))))
1738                             seqs))
1739              (result (make-symbol "result"))
1740              (result-tail (make-symbol "result-tail")))
1741         `(let* ,(let* ((bindings (cons nil nil))
1742                        (heads heads))
1743                   (nconc bindings (list (list result '(cons nil nil))))
1744                   (nconc bindings (list (list result-tail result)))
1745                   (while heads
1746                     (nconc bindings (list (list (pop heads) (pop seqs)))))
1747                   (cdr bindings))
1748            (while (and ,@heads)
1749              (setcdr ,result-tail (cons (funcall ,function
1750                                                  ,@(mapcar (lambda (h) (list 'car h))
1751                                                            heads))
1752                                         nil))
1753              (setq ,result-tail (cdr ,result-tail)
1754                    ,@(apply 'nconc (mapcar (lambda (h) (list h (list 'cdr h))) heads))))
1755            (cdr ,result)))
1756     `(mapcar ,function ,seq1)))
1757
1758 (if (fboundp 'merge)
1759     (defalias 'gnus-merge 'merge)
1760   ;; Adapted from cl-seq.el
1761   (defun gnus-merge (type list1 list2 pred)
1762     "Destructively merge lists LIST1 and LIST2 to produce a new list.
1763 Argument TYPE is for compatibility and ignored.
1764 Ordering of the elements is preserved according to PRED, a `less-than'
1765 predicate on the elements."
1766     (let ((res nil))
1767       (while (and list1 list2)
1768         (if (funcall pred (car list2) (car list1))
1769             (push (pop list2) res)
1770           (push (pop list1) res)))
1771       (nconc (nreverse res) list1 list2))))
1772
1773 (defvar xemacs-codename)
1774 (defvar sxemacs-codename)
1775 (defvar emacs-program-version)
1776
1777 (defun gnus-emacs-version ()
1778   "Stringified Emacs version."
1779   (let* ((lst (if (listp gnus-user-agent)
1780                   gnus-user-agent
1781                 '(gnus emacs type)))
1782          (system-v (cond ((memq 'config lst)
1783                           system-configuration)
1784                          ((memq 'type lst)
1785                           (symbol-name system-type))
1786                          (t nil)))
1787          codename emacsname)
1788     (cond ((featurep 'sxemacs)
1789            (setq emacsname "SXEmacs"
1790                  codename sxemacs-codename))
1791           ((featurep 'xemacs)
1792            (setq emacsname "XEmacs"
1793                  codename xemacs-codename))
1794           (t
1795            (setq emacsname "Emacs")))
1796     (cond
1797      ((not (memq 'emacs lst))
1798       nil)
1799      ((string-match "^\\(\\([.0-9]+\\)*\\)\\.[0-9]+$" emacs-version)
1800       ;; Emacs:
1801       (concat "Emacs/" (match-string 1 emacs-version)
1802               (if system-v
1803                   (concat " (" system-v ")")
1804                 "")))
1805      ((or (featurep 'sxemacs) (featurep 'xemacs))
1806       ;; XEmacs or SXEmacs:
1807       (concat emacsname "/" emacs-program-version
1808               (let (plst)
1809                 (when (memq 'codename lst)
1810                   (push codename plst))
1811                 (when system-v
1812                   (push system-v plst))
1813                 (unless (featurep 'mule)
1814                   (push "no MULE" plst))
1815                 (when (> (length plst) 0)
1816                   (concat
1817                    " (" (mapconcat 'identity (reverse plst) ", ") ")")))))
1818      (t emacs-version))))
1819
1820 (defun gnus-rename-file (old-path new-path &optional trim)
1821   "Rename OLD-PATH as NEW-PATH.  If TRIM, recursively delete
1822 empty directories from OLD-PATH."
1823   (when (file-exists-p old-path)
1824     (let* ((old-dir (file-name-directory old-path))
1825            (old-name (file-name-nondirectory old-path))
1826            (new-dir (file-name-directory new-path))
1827            (new-name (file-name-nondirectory new-path))
1828            temp)
1829       (gnus-make-directory new-dir)
1830       (rename-file old-path new-path t)
1831       (when trim
1832         (while (progn (setq temp (directory-files old-dir))
1833                       (while (member (car temp) '("." ".."))
1834                         (setq temp (cdr temp)))
1835                       (= (length temp) 0))
1836           (delete-directory old-dir)
1837           (setq old-dir (file-name-as-directory
1838                          (file-truename
1839                           (concat old-dir "..")))))))))
1840
1841 (defun gnus-set-file-modes (filename mode)
1842   "Wrapper for set-file-modes."
1843   (ignore-errors
1844     (set-file-modes filename mode)))
1845
1846 (if (fboundp 'set-process-query-on-exit-flag)
1847     (defalias 'gnus-set-process-query-on-exit-flag
1848       'set-process-query-on-exit-flag)
1849   (defalias 'gnus-set-process-query-on-exit-flag
1850     'process-kill-without-query))
1851
1852 (if (fboundp 'with-local-quit)
1853     (defalias 'gnus-with-local-quit 'with-local-quit)
1854   (defmacro gnus-with-local-quit (&rest body)
1855     "Execute BODY, allowing quits to terminate BODY but not escape further.
1856 When a quit terminates BODY, `gnus-with-local-quit' returns nil but
1857 requests another quit.  That quit will be processed as soon as quitting
1858 is allowed once again.  (Immediately, if `inhibit-quit' is nil.)"
1859     ;;(declare (debug t) (indent 0))
1860     `(condition-case nil
1861          (let ((inhibit-quit nil))
1862            ,@body)
1863        (quit (setq quit-flag t)
1864              ;; This call is to give a chance to handle quit-flag
1865              ;; in case inhibit-quit is nil.
1866              ;; Without this, it will not be handled until the next function
1867              ;; call, and that might allow it to exit thru a condition-case
1868              ;; that intends to handle the quit signal next time.
1869              (eval '(ignore nil))))))
1870
1871 (defalias 'gnus-read-shell-command
1872   (if (fboundp 'read-shell-command) 'read-shell-command 'read-string))
1873
1874 (defmacro gnus-put-display-table (range value display-table)
1875   "Set the value for char RANGE to VALUE in DISPLAY-TABLE.  "
1876   (if (featurep 'xemacs)
1877       (progn
1878         `(if (fboundp 'put-display-table)
1879           (put-display-table ,range ,value ,display-table)
1880           (if (sequencep ,display-table)
1881               (aset ,display-table ,range ,value)
1882             (put-char-table ,range ,value ,display-table))))
1883     `(aset ,display-table ,range ,value)))
1884
1885 (defmacro gnus-get-display-table (character display-table)
1886   "Find value for CHARACTER in DISPLAY-TABLE.  "
1887   (if (featurep 'xemacs)
1888       `(if (fboundp 'get-display-table)
1889           (get-display-table ,character ,display-table)
1890           (if (sequencep ,display-table)
1891               (aref ,display-table ,character)
1892             (get-char-table ,character ,display-table)))
1893     `(aref ,display-table ,character)))
1894
1895 (provide 'gnus-util)
1896
1897 ;;; gnus-util.el ends here