cgit.sxemacs.org Git - gnus/blob - lisp/gnus-undo.el

   1 ;;; gnus-undo.el --- minor mode for undoing in Gnus
   2 ;; Copyright (C) 1996 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@ifi.uio.no>
   5 ;; Keywords: news
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  22 ;; Boston, MA 02111-1307, USA.
  23
  24 ;;; Commentary:
  25
  26 ;; This package allows arbitrary undoing in Gnus buffers.  As all the
  27 ;; Gnus buffers aren't very text-oriented (what is in the buffers is
  28 ;; just some random representation of the actual data), normal Emacs
  29 ;; undoing doesn't work at all for Gnus.
  30 ;;
  31 ;; This package works by letting Gnus register functions for reversing
  32 ;; actions, and then calling these functions when the user pushes the
  33 ;; `undo' key.  As with normal `undo', there it is possible to set
  34 ;; undo boundaries and so on.
  35 ;;
  36 ;; Internally, the undo sequence is represented by the
  37 ;; `gnus-undo-actions' list, where each element is a list of functions
  38 ;; to be called, in sequence, to undo some action.  (An "action" is a
  39 ;; collection of functions.)
  40 ;;
  41 ;; For instance, a function for killing a group will call
  42 ;; `gnus-undo-register' with a function that un-kills the group.  This
  43 ;; package will put that function into an action.
  44
  45 ;;; Code:
  46
  47 (require 'gnus-util)
  48 (require 'gnus)
  49
  50 (defvar gnus-undo-mode nil
  51   "Minor mode for undoing in Gnus buffers.")
  52
  53 (defvar gnus-undo-mode-hook nil
  54   "Hook called in all `gnus-undo-mode' buffers.")
  55
  56 ;;; Internal variables.
  57
  58 (defvar gnus-undo-actions nil)
  59 (defvar gnus-undo-boundary t)
  60 (defvar gnus-undo-last nil)
  61 (defvar gnus-undo-boundary-inhibit nil)
  62
  63 ;;; Minor mode definition.
  64
  65 (defvar gnus-undo-mode-map nil)
  66
  67 (unless gnus-undo-mode-map
  68   (setq gnus-undo-mode-map (make-sparse-keymap))
  69
  70   (gnus-define-keys gnus-undo-mode-map
  71    "\M-\C-_" gnus-undo))
  72
  73 (defun gnus-undo-make-menu-bar ()
  74   (unless (boundp 'gnus-undo-menu)
  75     (easy-menu-define
  76      gnus-undo-menu gnus-undo-mode-map ""
  77      '("Undo"
  78        ("Undo"
  79         ["Undo" gnus-undo gnus-undo-actions])))))
  80
  81 (defun gnus-undo-mode (&optional arg)
  82   "Minor mode for providing `undo' in Gnus buffers.
  83
  84 \\{gnus-undo-mode-map}"
  85   (interactive "P")
  86   (set (make-local-variable 'gnus-undo-mode)
  87        (if (null arg) (not gnus-undo-mode)
  88          (> (prefix-numeric-value arg) 0)))
  89   (set (make-local-variable 'gnus-undo-actions) nil)
  90   (set (make-local-variable 'gnus-undo-boundary) t)
  91   (when gnus-undo-mode
  92     ;; Set up the menu.
  93     (when (and menu-bar-mode
  94                (gnus-visual-p 'undo-menu 'menu))
  95       (gnus-undo-make-menu-bar))
  96     ;; Don't display anything in the mode line -- too annoying.
  97     ;;(unless (assq 'gnus-undo-mode minor-mode-alist)
  98     ;;  (push '(gnus-undo-mode " Undo") minor-mode-alist))
  99     (unless (assq 'gnus-undo-mode minor-mode-map-alist)
 100       (push (cons 'gnus-undo-mode gnus-undo-mode-map)
 101             minor-mode-map-alist))
 102     (gnus-make-local-hook 'post-command-hook)
 103     (gnus-add-hook 'post-command-hook 'gnus-undo-boundary nil t)
 104     (run-hooks 'gnus-undo-mode-hook)))
 105
 106 ;;; Interface functions.
 107
 108 (defun gnus-disable-undo (&optional buffer)
 109   "Disable undoing in the current buffer."
 110   (interactive)
 111   (save-excursion
 112     (when buffer
 113       (set-buffer buffer))
 114     (gnus-undo-mode -1)))
 115
 116 (defun gnus-undo-boundary ()
 117   "Set Gnus undo boundary."
 118   (if gnus-undo-boundary-inhibit
 119       (setq gnus-undo-boundary-inhibit nil)
 120     (setq gnus-undo-boundary t)))
 121
 122 (defun gnus-undo-register (form)
 123   "Register FORMS as something to be performed to undo a change.
 124 FORMS may use backtick quote syntax."
 125   (when gnus-undo-mode
 126     (gnus-undo-register-1
 127      `(lambda ()
 128         ,@form))))
 129
 130 (put 'gnus-undo-register 'lisp-indent-function 0)
 131 (put 'gnus-undo-register 'edebug-form-spec '(body))
 132
 133 (defun gnus-undo-register-1 (function)
 134   "Register FUNCTION as something to be performed to undo a change."
 135   (when gnus-undo-mode
 136     (cond
 137      ;; We are on a boundary, so we create a new action.
 138      (gnus-undo-boundary
 139       (push (list function) gnus-undo-actions)
 140       (setq gnus-undo-boundary nil))
 141      ;; Prepend the function to an old action.
 142      (gnus-undo-actions
 143       (setcar gnus-undo-actions (cons function (car gnus-undo-actions))))
 144      ;; Initialize list.
 145      (t
 146       (setq gnus-undo-actions (list (list function)))))
 147     (setq gnus-undo-boundary-inhibit t)))
 148
 149 (defun gnus-undo (n)
 150   "Undo some previous changes in Gnus buffers.
 151 Repeat this command to undo more changes.
 152 A numeric argument serves as a repeat count."
 153   (interactive "p")
 154   (unless gnus-undo-mode
 155     (error "Undoing is not enabled in this buffer"))
 156   (message "%s" last-command)
 157   (when (or (not (eq last-command 'gnus-undo))
 158             (not gnus-undo-last))
 159     (setq gnus-undo-last gnus-undo-actions))
 160   (let ((action (pop gnus-undo-last)))
 161     (unless action
 162       (error "Nothing further to undo"))
 163     (setq gnus-undo-actions (delq action gnus-undo-actions))
 164     (setq gnus-undo-boundary t)
 165     (while action
 166       (funcall (pop action)))))
 167
 168 (provide 'gnus-undo)
 169
 170 ;;; gnus-undo.el ends here