cgit.sxemacs.org Git - gnus/blob - lisp/gnus-undo.el

   1 ;;; gnus-undo.el --- minor mode for undoing in Gnus
   2
   3 ;; Copyright (C) 1996, 1997, 1998, 1999, 2000, 2003
   4 ;;      Free Software Foundation, Inc.
   5
   6 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   7 ;; Keywords: news
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; This package allows arbitrary undoing in Gnus buffers.  As all the
  29 ;; Gnus buffers aren't very text-oriented (what is in the buffers is
  30 ;; just some arbitrary representation of the actual data), normal Emacs
  31 ;; undoing doesn't work at all for Gnus.
  32 ;;
  33 ;; This package works by letting Gnus register functions for reversing
  34 ;; actions, and then calling these functions when the user pushes the
  35 ;; `undo' key.  As with normal `undo', there it is possible to set
  36 ;; undo boundaries and so on.
  37 ;;
  38 ;; Internally, the undo sequence is represented by the
  39 ;; `gnus-undo-actions' list, where each element is a list of functions
  40 ;; to be called, in sequence, to undo some action.  (An "action" is a
  41 ;; collection of functions.)
  42 ;;
  43 ;; For instance, a function for killing a group will call
  44 ;; `gnus-undo-register' with a function that un-kills the group.  This
  45 ;; package will put that function into an action.
  46
  47 ;;; Code:
  48
  49 (eval-when-compile (require 'cl))
  50
  51 (require 'gnus-util)
  52 (require 'gnus)
  53
  54 (defgroup gnus-undo nil
  55   "Undoing in Gnus buffers."
  56   :group 'gnus)
  57
  58 (defcustom gnus-undo-limit 2000
  59   "The number of undoable actions recorded."
  60   :type 'integer
  61   :group 'gnus-undo)
  62
  63 (defcustom gnus-undo-mode nil
  64   "Minor mode for undoing in Gnus buffers."
  65   :type 'boolean
  66   :group 'gnus-undo)
  67
  68 (defcustom gnus-undo-mode-hook nil
  69   "Hook called in all `gnus-undo-mode' buffers."
  70   :type 'hook
  71   :group 'gnus-undo)
  72
  73 ;;; Internal variables.
  74
  75 (defvar gnus-undo-actions nil)
  76 (defvar gnus-undo-boundary t)
  77 (defvar gnus-undo-last nil)
  78 (defvar gnus-undo-boundary-inhibit nil)
  79
  80 ;;; Minor mode definition.
  81
  82 (defvar gnus-undo-mode-map nil)
  83
  84 (unless gnus-undo-mode-map
  85   (setq gnus-undo-mode-map (make-sparse-keymap))
  86
  87   (gnus-define-keys gnus-undo-mode-map
  88     "\M-\C-_"     gnus-undo
  89     "\C-_"        gnus-undo
  90     "\C-xu"       gnus-undo
  91     ;; many people are used to type `C-/' on X terminals and get `C-_'.
  92     [(control /)] gnus-undo))
  93
  94 (defun gnus-undo-make-menu-bar ()
  95   ;; This is disabled for the time being.
  96   (when nil
  97     (define-key-after (current-local-map) [menu-bar file gnus-undo]
  98       (cons "Undo" 'gnus-undo-actions)
  99       [menu-bar file whatever])))
 100
 101 (defun gnus-undo-mode (&optional arg)
 102   "Minor mode for providing `undo' in Gnus buffers.
 103
 104 \\{gnus-undo-mode-map}"
 105   (interactive "P")
 106   (set (make-local-variable 'gnus-undo-mode)
 107        (if (null arg) (not gnus-undo-mode)
 108          (> (prefix-numeric-value arg) 0)))
 109   (set (make-local-variable 'gnus-undo-actions) nil)
 110   (set (make-local-variable 'gnus-undo-boundary) t)
 111   (when gnus-undo-mode
 112     ;; Set up the menu.
 113     (when (gnus-visual-p 'undo-menu 'menu)
 114       (gnus-undo-make-menu-bar))
 115     (add-minor-mode 'gnus-undo-mode "" gnus-undo-mode-map)
 116     (gnus-make-local-hook 'post-command-hook)
 117     (add-hook 'post-command-hook 'gnus-undo-boundary nil t)
 118     (gnus-run-hooks 'gnus-undo-mode-hook)))
 119
 120 ;;; Interface functions.
 121
 122 (defun gnus-disable-undo (&optional buffer)
 123   "Disable undoing in the current buffer."
 124   (interactive)
 125   (save-excursion
 126     (when buffer
 127       (set-buffer buffer))
 128     (gnus-undo-mode -1)))
 129
 130 (defun gnus-undo-boundary ()
 131   "Set Gnus undo boundary."
 132   (if gnus-undo-boundary-inhibit
 133       (setq gnus-undo-boundary-inhibit nil)
 134     (setq gnus-undo-boundary t)))
 135
 136 (defun gnus-undo-force-boundary ()
 137   "Set Gnus undo boundary."
 138   (setq gnus-undo-boundary-inhibit nil
 139         gnus-undo-boundary t))
 140
 141 (defun gnus-undo-register (form)
 142   "Register FORMS as something to be performed to undo a change.
 143 FORMS may use backtick quote syntax."
 144   (when gnus-undo-mode
 145     (gnus-undo-register-1
 146      `(lambda ()
 147         ,form))))
 148
 149 (put 'gnus-undo-register 'lisp-indent-function 0)
 150 (put 'gnus-undo-register 'edebug-form-spec '(body))
 151
 152 (defun gnus-undo-register-1 (function)
 153   "Register FUNCTION as something to be performed to undo a change."
 154   (when gnus-undo-mode
 155     (cond
 156      ;; We are on a boundary, so we create a new action.
 157      (gnus-undo-boundary
 158       (push (list function) gnus-undo-actions)
 159       (setq gnus-undo-boundary nil))
 160      ;; Prepend the function to an old action.
 161      (gnus-undo-actions
 162       (setcar gnus-undo-actions (cons function (car gnus-undo-actions))))
 163      ;; Initialize list.
 164      (t
 165       (setq gnus-undo-actions (list (list function)))))
 166     ;; Limit the length of the undo list.
 167     (let ((next (nthcdr gnus-undo-limit gnus-undo-actions)))
 168       (when next
 169         (setcdr next nil)))
 170     ;; We are not at a boundary...
 171     (setq gnus-undo-boundary-inhibit t)))
 172
 173 (defun gnus-undo (n)
 174   "Undo some previous changes in Gnus buffers.
 175 Repeat this command to undo more changes.
 176 A numeric argument serves as a repeat count."
 177   (interactive "p")
 178   (unless gnus-undo-mode
 179     (error "Undoing is not enabled in this buffer"))
 180   (message "%s" last-command)
 181   (when (or (not (eq last-command 'gnus-undo))
 182             (not gnus-undo-last))
 183     (setq gnus-undo-last gnus-undo-actions))
 184   (let ((action (pop gnus-undo-last)))
 185     (unless action
 186       (error "Nothing further to undo"))
 187     (setq gnus-undo-actions (delq action gnus-undo-actions))
 188     (setq gnus-undo-boundary t)
 189     (while action
 190       (funcall (pop action)))))
 191
 192 (provide 'gnus-undo)
 193
 194 ;;; gnus-undo.el ends here