cgit.sxemacs.org Git - gnus/blob - lisp/gnus-topic.el

   1 ;;; gnus-topic.el --- a folding minor mode for Gnus group buffers
   2
   3 ;; Copyright (C) 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003,
   4 ;;   2004, 2005, 2006, 2007, 2008, 2009, 2010 Free Software Foundation, Inc.
   5
   6 ;; Author: Ilja Weis <kult@uni-paderborn.de>
   7 ;;      Lars Magne Ingebrigtsen <larsi@gnus.org>
   8 ;; Keywords: news
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;;; Code:
  28
  29 (eval-when-compile (require 'cl))
  30
  31 (require 'gnus)
  32 (require 'gnus-group)
  33 (require 'gnus-start)
  34 (require 'gnus-util)
  35
  36 (defgroup gnus-topic nil
  37   "Group topics."
  38   :group 'gnus-group)
  39
  40 (defvar gnus-topic-mode nil
  41   "Minor mode for Gnus group buffers.")
  42
  43 (defcustom gnus-topic-mode-hook nil
  44   "Hook run in topic mode buffers."
  45   :type 'hook
  46   :group 'gnus-topic)
  47
  48 (when (featurep 'xemacs)
  49   (add-hook 'gnus-topic-mode-hook 'gnus-xmas-topic-menu-add))
  50
  51 (defcustom gnus-topic-line-format "%i[ %(%{%n%}%) -- %A ]%v\n"
  52   "Format of topic lines.
  53 It works along the same lines as a normal formatting string,
  54 with some simple extensions.
  55
  56 %i  Indentation based on topic level.
  57 %n  Topic name.
  58 %v  Nothing if the topic is visible, \"...\" otherwise.
  59 %g  Number of groups in the topic.
  60 %a  Number of unread articles in the groups in the topic.
  61 %A  Number of unread articles in the groups in the topic and its subtopics.
  62
  63 General format specifiers can also be used.
  64 See Info node `(gnus)Formatting Variables'."
  65   :link '(custom-manual "(gnus)Formatting Variables")
  66   :type 'string
  67   :group 'gnus-topic)
  68
  69 (defcustom gnus-topic-indent-level 2
  70   "*How much each subtopic should be indented."
  71   :type 'integer
  72   :group 'gnus-topic)
  73
  74 (defcustom gnus-topic-display-empty-topics t
  75   "*If non-nil, display the topic lines even of topics that have no unread articles."
  76   :type 'boolean
  77   :group 'gnus-topic)
  78
  79 ;; Internal variables.
  80
  81 (defvar gnus-topic-active-topology nil)
  82 (defvar gnus-topic-active-alist nil)
  83 (defvar gnus-topic-unreads nil)
  84
  85 (defvar gnus-topology-checked-p nil
  86   "Whether the topology has been checked in this session.")
  87
  88 (defvar gnus-topic-killed-topics nil)
  89 (defvar gnus-topic-inhibit-change-level nil)
  90
  91 (defconst gnus-topic-line-format-alist
  92   `((?n name ?s)
  93     (?v visible ?s)
  94     (?i indentation ?s)
  95     (?g number-of-groups ?d)
  96     (?a (gnus-topic-articles-in-topic entries) ?d)
  97     (?A total-number-of-articles ?d)
  98     (?l level ?d)))
  99
 100 (defvar gnus-topic-line-format-spec nil)
 101
 102 ;;; Utility functions
 103
 104 (defun gnus-group-topic-name ()
 105   "The name of the topic on the current line."
 106   (let ((topic (get-text-property (point-at-bol) 'gnus-topic)))
 107     (and topic (symbol-name topic))))
 108
 109 (defun gnus-group-topic-level ()
 110   "The level of the topic on the current line."
 111   (get-text-property (point-at-bol) 'gnus-topic-level))
 112
 113 (defun gnus-group-topic-unread ()
 114   "The number of unread articles in topic on the current line."
 115   (get-text-property (point-at-bol) 'gnus-topic-unread))
 116
 117 (defun gnus-topic-unread (topic)
 118   "Return the number of unread articles in TOPIC."
 119   (or (cdr (assoc topic gnus-topic-unreads))
 120       0))
 121
 122 (defun gnus-group-topic-p ()
 123   "Return non-nil if the current line is a topic."
 124   (gnus-group-topic-name))
 125
 126 (defun gnus-topic-visible-p ()
 127   "Return non-nil if the current topic is visible."
 128   (get-text-property (point-at-bol) 'gnus-topic-visible))
 129
 130 (defun gnus-topic-articles-in-topic (entries)
 131   (let ((total 0)
 132         number)
 133     (while entries
 134       (when (numberp (setq number (car (pop entries))))
 135         (incf total number)))
 136     total))
 137
 138 (defun gnus-group-topic (group)
 139   "Return the topic GROUP is a member of."
 140   (let ((alist gnus-topic-alist)
 141         out)
 142     (while alist
 143       (when (member group (cdar alist))
 144         (setq out (caar alist)
 145               alist nil))
 146       (setq alist (cdr alist)))
 147     out))
 148
 149 (defun gnus-group-parent-topic (group)
 150   "Return the topic GROUP is member of by looking at the group buffer."
 151   (with-current-buffer gnus-group-buffer
 152     (if (gnus-group-goto-group group)
 153         (gnus-current-topic)
 154       (gnus-group-topic group))))
 155
 156 (defun gnus-topic-goto-topic (topic)
 157   (when topic
 158     (gnus-goto-char (text-property-any (point-min) (point-max)
 159                                        'gnus-topic (intern topic)))))
 160
 161 (defun gnus-topic-jump-to-topic (topic)
 162   "Go to TOPIC."
 163   (interactive
 164    (list (gnus-completing-read "Go to topic" (gnus-topic-list) t)))
 165   (let ((buffer-read-only nil))
 166     (dolist (topic (gnus-current-topics topic))
 167       (unless (gnus-topic-goto-topic topic)
 168         (gnus-topic-goto-missing-topic topic)
 169         (gnus-topic-display-missing-topic topic))))
 170   (gnus-topic-goto-topic topic))
 171
 172 (defun gnus-current-topic ()
 173   "Return the name of the current topic."
 174   (let ((result
 175          (or (get-text-property (point) 'gnus-topic)
 176              (save-excursion
 177                (and (gnus-goto-char (previous-single-property-change
 178                                      (point) 'gnus-topic))
 179                     (get-text-property (max (1- (point)) (point-min))
 180                                        'gnus-topic))))))
 181     (when result
 182       (symbol-name result))))
 183
 184 (defun gnus-current-topics (&optional topic)
 185   "Return a list of all current topics, lowest in hierarchy first.
 186 If TOPIC, start with that topic."
 187   (let ((topic (or topic (gnus-current-topic)))
 188         topics)
 189     (while topic
 190       (push topic topics)
 191       (setq topic (gnus-topic-parent-topic topic)))
 192     (nreverse topics)))
 193
 194 (defun gnus-group-active-topic-p ()
 195   "Say whether the current topic comes from the active topics."
 196   (get-text-property (point-at-bol) 'gnus-active))
 197
 198 (defun gnus-topic-find-groups (topic &optional level all lowest recursive)
 199   "Return entries for all visible groups in TOPIC.
 200 If RECURSIVE is t, return groups in its subtopics too."
 201   (let ((groups (cdr (assoc topic gnus-topic-alist)))
 202         info clevel unread group params visible-groups entry active)
 203     (setq lowest (or lowest 1))
 204     (setq level (or level gnus-level-unsubscribed))
 205     ;; We go through the newsrc to look for matches.
 206     (while groups
 207       (when (setq group (pop groups))
 208         (setq entry (gnus-group-entry group)
 209               info (nth 2 entry)
 210               params (gnus-info-params info)
 211               active (gnus-active group)
 212               unread (or (car entry)
 213                          (and (not (equal group "dummy.group"))
 214                               active
 215                               (- (1+ (cdr active)) (car active))))
 216               clevel (or (gnus-info-level info)
 217                          (if (member group gnus-zombie-list)
 218                              gnus-level-zombie gnus-level-killed))))
 219       (and
 220        info                             ; nil means that the group is dead.
 221        (<= clevel level)
 222        (>= clevel lowest)               ; Is inside the level we want.
 223        (or all
 224            (if (or (eq unread t)
 225                    (eq unread nil))
 226                gnus-group-list-inactive-groups
 227              (> unread 0))
 228            (and gnus-list-groups-with-ticked-articles
 229                 (cdr (assq 'tick (gnus-info-marks info))))
 230            ;; Has right readedness.
 231            ;; Check for permanent visibility.
 232            (and gnus-permanently-visible-groups
 233                 (string-match gnus-permanently-visible-groups group))
 234            (memq 'visible params)
 235            (cdr (assq 'visible params)))
 236        ;; Add this group to the list of visible groups.
 237        (push (or entry group) visible-groups)))
 238     (setq visible-groups (nreverse visible-groups))
 239     (when recursive
 240       (if (eq recursive t)
 241           (setq recursive (cdr (gnus-topic-find-topology topic))))
 242       (dolist (topic-topology (cdr recursive))
 243         (setq visible-groups
 244               (nconc visible-groups
 245                      (gnus-topic-find-groups
 246                       (caar topic-topology)
 247                       level all lowest topic-topology)))))
 248     visible-groups))
 249
 250 (defun gnus-topic-goto-previous-topic (n)
 251   "Go to the N'th previous topic."
 252   (interactive "p")
 253   (gnus-topic-goto-next-topic (- n)))
 254
 255 (defun gnus-topic-goto-next-topic (n)
 256   "Go to the N'th next topic."
 257   (interactive "p")
 258   (let ((backward (< n 0))
 259         (n (abs n))
 260         (topic (gnus-current-topic)))
 261     (while (and (> n 0)
 262                 (setq topic
 263                       (if backward
 264                           (gnus-topic-previous-topic topic)
 265                         (gnus-topic-next-topic topic))))
 266       (gnus-topic-goto-topic topic)
 267       (setq n (1- n)))
 268     (when (/= 0 n)
 269       (gnus-message 7 "No more topics"))
 270     n))
 271
 272 (defun gnus-topic-previous-topic (topic)
 273   "Return the previous topic on the same level as TOPIC."
 274   (let ((top (cddr (gnus-topic-find-topology
 275                     (gnus-topic-parent-topic topic)))))
 276     (unless (equal topic (caaar top))
 277       (while (and top (not (equal (caaadr top) topic)))
 278         (setq top (cdr top)))
 279       (caaar top))))
 280
 281 (defun gnus-topic-parent-topic (topic &optional topology)
 282   "Return the parent of TOPIC."
 283   (unless topology
 284     (setq topology gnus-topic-topology))
 285   (let ((parent (car (pop topology)))
 286         result found)
 287     (while (and topology
 288                 (not (setq found (equal (caaar topology) topic)))
 289                 (not (setq result (gnus-topic-parent-topic
 290                                    topic (car topology)))))
 291       (setq topology (cdr topology)))
 292     (or result (and found parent))))
 293
 294 (defun gnus-topic-next-topic (topic &optional previous)
 295   "Return the next sibling of TOPIC."
 296   (let ((parentt (cddr (gnus-topic-find-topology
 297                         (gnus-topic-parent-topic topic))))
 298         prev)
 299     (while (and parentt
 300                 (not (equal (caaar parentt) topic)))
 301       (setq prev (caaar parentt)
 302             parentt (cdr parentt)))
 303     (if previous
 304         prev
 305       (caaadr parentt))))
 306
 307 (defun gnus-topic-forward-topic (num)
 308   "Go to the next topic on the same level as the current one."
 309   (let* ((topic (gnus-current-topic))
 310          (way (if (< num 0) 'gnus-topic-previous-topic
 311                 'gnus-topic-next-topic))
 312          (num (abs num)))
 313     (while (and (not (zerop num))
 314                 (setq topic (funcall way topic)))
 315       (when (gnus-topic-goto-topic topic)
 316         (decf num)))
 317     (unless (zerop num)
 318       (goto-char (point-max)))
 319     num))
 320
 321 (defun gnus-topic-find-topology (topic &optional topology level remove)
 322   "Return the topology of TOPIC."
 323   (unless topology
 324     (setq topology gnus-topic-topology)
 325     (setq level 0))
 326   (let ((top topology)
 327         result)
 328     (if (equal (caar topology) topic)
 329         (progn
 330           (when remove
 331             (delq topology remove))
 332           (cons level topology))
 333       (setq topology (cdr topology))
 334       (while (and topology
 335                   (not (setq result (gnus-topic-find-topology
 336                                      topic (car topology) (1+ level)
 337                                      (and remove top)))))
 338         (setq topology (cdr topology)))
 339       result)))
 340
 341 (defvar gnus-tmp-topics nil)
 342 (defun gnus-topic-list (&optional topology)
 343   "Return a list of all topics in the topology."
 344   (unless topology
 345     (setq topology gnus-topic-topology
 346           gnus-tmp-topics nil))
 347   (push (caar topology) gnus-tmp-topics)
 348   (mapc 'gnus-topic-list (cdr topology))
 349   gnus-tmp-topics)
 350
 351 ;;; Topic parameter jazz
 352
 353 (defun gnus-topic-parameters (topic)
 354   "Return the parameters for TOPIC."
 355   (let ((top (gnus-topic-find-topology topic)))
 356     (when top
 357       (nth 3 (cadr top)))))
 358
 359 (defun gnus-topic-set-parameters (topic parameters)
 360   "Set the topic parameters of TOPIC to PARAMETERS."
 361   (let ((top (gnus-topic-find-topology topic)))
 362     (unless top
 363       (error "No such topic: %s" topic))
 364     ;; We may have to extend if there is no parameters here
 365     ;; to begin with.
 366     (unless (nthcdr 2 (cadr top))
 367       (nconc (cadr top) (list nil)))
 368     (unless (nthcdr 3 (cadr top))
 369       (nconc (cadr top) (list nil)))
 370     (setcar (nthcdr 3 (cadr top)) parameters)
 371     (gnus-dribble-enter
 372      (format "(gnus-topic-set-parameters %S '%S)" topic parameters))))
 373
 374 (defun gnus-group-topic-parameters (group)
 375   "Compute the group parameters for GROUP in topic mode.
 376 Possibly inherit parameters from topics above GROUP."
 377   (let ((params-list (copy-sequence (gnus-group-get-parameter group))))
 378     (save-excursion
 379       (gnus-topic-hierarchical-parameters
 380        ;; First we try to go to the group within the group buffer and find the
 381        ;; topic for the group that way. This hopefully copes well with groups
 382        ;; that are in more than one topic. Failing that (i.e. when the group
 383        ;; isn't visible in the group buffer) we find a topic for the group via
 384        ;; gnus-group-topic.
 385        (or (and (gnus-group-goto-group group)
 386                 (gnus-current-topic))
 387            (gnus-group-topic group))
 388        params-list))))
 389
 390 (defun gnus-topic-hierarchical-parameters (topic &optional group-params-list)
 391   "Compute the topic parameters for TOPIC.
 392 Possibly inherit parameters from topics above TOPIC.
 393 If optional argument GROUP-PARAMS-LIST is non-nil, use it as the basis for
 394 inheritance."
 395   (let ((params-list
 396          ;; We probably have lots of nil elements here, so we remove them.
 397          ;; Probably faster than doing this "properly".
 398          (delq nil (cons group-params-list
 399                          (mapcar 'gnus-topic-parameters
 400                                  (gnus-current-topics topic)))))
 401         param out params)
 402     ;; Now we have all the parameters, so we go through them
 403     ;; and do inheritance in the obvious way.
 404     (let (posting-style)
 405       (while (setq params (pop params-list))
 406         (while (setq param (pop params))
 407           (when (atom param)
 408             (setq param (cons param t)))
 409           (cond ((eq (car param) 'posting-style)
 410                  (let ((param (cdr param))
 411                        elt)
 412                    (while (setq elt (pop param))
 413                      (unless (assoc (car elt) posting-style)
 414                        (push elt posting-style)))))
 415                 (t
 416                  (unless (assq (car param) out)
 417                    (push param out))))))
 418       (and posting-style (push (cons 'posting-style posting-style) out)))
 419     ;; Return the resulting parameter list.
 420     out))
 421
 422 ;;; General utility functions
 423
 424 (defun gnus-topic-enter-dribble ()
 425   (gnus-dribble-enter
 426    (format "(setq gnus-topic-topology '%S)" gnus-topic-topology)))
 427
 428 ;;; Generating group buffers
 429
 430 (defun gnus-group-prepare-topics (level &optional predicate lowest
 431                                         regexp list-topic topic-level)
 432   "List all newsgroups with unread articles of level LEVEL or lower.
 433 Use the `gnus-group-topics' to sort the groups.
 434 If PREDICTE is a function, list groups that the function returns non-nil;
 435 if it is t, list groups that have no unread articles.
 436 If LOWEST is non-nil, list all newsgroups of level LOWEST or higher."
 437   (set-buffer gnus-group-buffer)
 438   (let ((buffer-read-only nil)
 439         (lowest (or lowest 1))
 440         (not-in-list
 441          (and gnus-group-listed-groups
 442               (copy-sequence gnus-group-listed-groups))))
 443
 444     (gnus-update-format-specifications nil 'topic)
 445
 446     (when (or (not gnus-topic-alist)
 447               (not gnus-topology-checked-p))
 448       (gnus-topic-check-topology))
 449
 450     (unless list-topic
 451       (erase-buffer))
 452
 453     ;; List dead groups?
 454     (when (or gnus-group-listed-groups
 455               (and (>= level gnus-level-zombie)
 456                    (<= lowest gnus-level-zombie)))
 457       (gnus-group-prepare-flat-list-dead
 458        (setq gnus-zombie-list (sort gnus-zombie-list 'string<))
 459        gnus-level-zombie ?Z
 460        regexp))
 461
 462     (when (or gnus-group-listed-groups
 463                (and (>= level gnus-level-killed)
 464                     (<= lowest gnus-level-killed)))
 465       (gnus-group-prepare-flat-list-dead
 466        (setq gnus-killed-list (sort gnus-killed-list 'string<))
 467        gnus-level-killed ?K regexp)
 468       (when not-in-list
 469         (unless gnus-killed-hashtb
 470           (gnus-make-hashtable-from-killed))
 471         (gnus-group-prepare-flat-list-dead
 472          (gnus-remove-if (lambda (group)
 473                            (or (gnus-group-entry group)
 474                                (gnus-gethash group gnus-killed-hashtb)))
 475                          not-in-list)
 476          gnus-level-killed ?K regexp)))
 477
 478     ;; Use topics.
 479     (prog1
 480         (when (or (< lowest gnus-level-zombie)
 481                   gnus-group-listed-groups)
 482           (if list-topic
 483               (let ((top (gnus-topic-find-topology list-topic)))
 484                 (gnus-topic-prepare-topic (cdr top) (car top)
 485                                           (or topic-level level) predicate
 486                                           nil lowest regexp))
 487             (gnus-topic-prepare-topic gnus-topic-topology 0
 488                                       (or topic-level level) predicate
 489                                       nil lowest regexp)))
 490       (gnus-group-set-mode-line)
 491       (setq gnus-group-list-mode (cons level predicate))
 492       (gnus-run-hooks 'gnus-group-prepare-hook))))
 493
 494 (defun gnus-topic-prepare-topic (topicl level &optional list-level
 495                                         predicate silent
 496                                         lowest regexp)
 497   "Insert TOPIC into the group buffer.
 498 If SILENT, don't insert anything.  Return the number of unread
 499 articles in the topic and its subtopics."
 500   (let* ((type (pop topicl))
 501          (entries (gnus-topic-find-groups
 502                    (car type)
 503                    (if gnus-group-listed-groups
 504                        gnus-level-killed
 505                      list-level)
 506                    (or predicate gnus-group-listed-groups
 507                        (cdr (assq 'visible
 508                                   (gnus-topic-hierarchical-parameters
 509                                    (car type)))))
 510                    (if gnus-group-listed-groups 0 lowest)))
 511          (visiblep (and (eq (nth 1 type) 'visible) (not silent)))
 512          (gnus-group-indentation
 513           (make-string (* gnus-topic-indent-level level) ? ))
 514          (beg (progn (beginning-of-line) (point)))
 515          (topicl (reverse topicl))
 516          (all-entries entries)
 517          (point-max (point-max))
 518          (unread 0)
 519          (topic (car type))
 520          info entry end active tick)
 521     ;; Insert any sub-topics.
 522     (while topicl
 523       (incf unread
 524             (gnus-topic-prepare-topic
 525              (pop topicl) (1+ level) list-level predicate
 526              (not visiblep) lowest regexp)))
 527     (setq end (point))
 528     (goto-char beg)
 529     ;; Insert all the groups that belong in this topic.
 530     (while (setq entry (pop entries))
 531       (when (if (stringp entry)
 532                 (gnus-group-prepare-logic
 533                  entry
 534                  (and
 535                   (or (not gnus-group-listed-groups)
 536                       (if (< list-level gnus-level-zombie) nil
 537                         (let ((entry-level
 538                                (if (member entry gnus-zombie-list)
 539                                    gnus-level-zombie gnus-level-killed)))
 540                           (and (<= entry-level list-level)
 541                                (>= entry-level lowest)))))
 542                   (cond
 543                    ((stringp regexp)
 544                     (string-match regexp entry))
 545                    ((functionp regexp)
 546                     (funcall regexp entry))
 547                    ((null regexp) t)
 548                    (t nil))))
 549               (setq info (nth 2 entry))
 550               (gnus-group-prepare-logic
 551                (gnus-info-group info)
 552                (and (or (not gnus-group-listed-groups)
 553                         (let ((entry-level (gnus-info-level info)))
 554                           (and (<= entry-level list-level)
 555                                (>= entry-level lowest))))
 556                     (or (not (functionp predicate))
 557                         (funcall predicate info))
 558                     (or (not (stringp regexp))
 559                         (string-match regexp (gnus-info-group info))))))
 560         (when visiblep
 561           (if (stringp entry)
 562               ;; Dead groups.
 563               (gnus-group-insert-group-line
 564                entry (if (member entry gnus-zombie-list)
 565                          gnus-level-zombie gnus-level-killed)
 566                nil (- (1+ (cdr (setq active (gnus-active entry))))
 567                       (car active))
 568                nil)
 569             ;; Living groups.
 570             (when (setq info (nth 2 entry))
 571               (gnus-group-insert-group-line
 572                (gnus-info-group info)
 573                (gnus-info-level info) (gnus-info-marks info)
 574                (car entry) (gnus-info-method info)))))
 575         (when (and (listp entry)
 576                    (numberp (car entry)))
 577           (incf unread (car entry)))
 578         (when (listp entry)
 579           (setq tick t))))
 580     (goto-char beg)
 581     ;; Insert the topic line.
 582     (when (and (not silent)
 583                (or gnus-topic-display-empty-topics ;We want empty topics
 584                    (not (zerop unread)) ;Non-empty
 585                    tick                 ;Ticked articles
 586                    (/= point-max (point-max)))) ;Unactivated groups
 587       (gnus-extent-start-open (point))
 588       (gnus-topic-insert-topic-line
 589        (car type) visiblep
 590        (not (eq (nth 2 type) 'hidden))
 591        level all-entries unread))
 592     (gnus-topic-update-unreads (car type) unread)
 593     (when gnus-group-update-tool-bar
 594       (gnus-put-text-property beg end 'point-entered
 595                               'gnus-tool-bar-update)
 596       (gnus-put-text-property beg end 'point-left
 597                               'gnus-tool-bar-update))
 598     (goto-char end)
 599     unread))
 600
 601 (defun gnus-topic-remove-topic (&optional insert total-remove hide in-level)
 602   "Remove the current topic."
 603   (let ((topic (gnus-group-topic-name))
 604         (level (gnus-group-topic-level))
 605         (beg (progn (beginning-of-line) (point)))
 606         buffer-read-only)
 607     (when topic
 608       (while (and (zerop (forward-line 1))
 609                   (> (or (gnus-group-topic-level) (1+ level)) level)))
 610       (delete-region beg (point))
 611       ;; Do the change in this rather odd manner because it has been
 612       ;; reported that some topics share parts of some lists, for some
 613       ;; reason.  I have been unable to determine why this is the
 614       ;; case, but this hack seems to take care of things.
 615       (let ((data (cadr (gnus-topic-find-topology topic))))
 616         (setcdr data
 617                 (list (if insert 'visible 'invisible)
 618                       (caddr data)
 619                       (cadddr data))))
 620       (if total-remove
 621           (setq gnus-topic-alist
 622                 (delq (assoc topic gnus-topic-alist) gnus-topic-alist))
 623         (gnus-topic-insert-topic topic in-level)))))
 624
 625 (defun gnus-topic-insert-topic (topic &optional level)
 626   "Insert TOPIC."
 627   (gnus-group-prepare-topics
 628    (car gnus-group-list-mode) (cdr gnus-group-list-mode)
 629    nil nil topic level))
 630
 631 (defun gnus-topic-fold (&optional insert topic)
 632   "Remove/insert the current topic."
 633   (let ((topic (or topic (gnus-group-topic-name))))
 634     (when topic
 635       (save-excursion
 636         (if (not (gnus-group-active-topic-p))
 637             (gnus-topic-remove-topic
 638              (or insert (not (gnus-topic-visible-p))))
 639           (let ((gnus-topic-topology gnus-topic-active-topology)
 640                 (gnus-topic-alist gnus-topic-active-alist)
 641                 (gnus-group-list-mode (cons 5 t)))
 642             (gnus-topic-remove-topic
 643              (or insert (not (gnus-topic-visible-p))) nil nil 9)
 644             (gnus-topic-enter-dribble)))))))
 645
 646 (defun gnus-topic-insert-topic-line (name visiblep shownp level entries
 647                                           &optional unread)
 648   (let* ((visible (if visiblep "" "..."))
 649          (indentation (make-string (* gnus-topic-indent-level level) ? ))
 650          (total-number-of-articles unread)
 651          (number-of-groups (length entries))
 652          (active-topic (eq gnus-topic-alist gnus-topic-active-alist))
 653          gnus-tmp-header)
 654     (gnus-topic-update-unreads name unread)
 655     (beginning-of-line)
 656     ;; Insert the text.
 657     (if shownp
 658         (gnus-add-text-properties
 659          (point)
 660          (prog1 (1+ (point))
 661            (eval gnus-topic-line-format-spec))
 662          (list 'gnus-topic (intern name)
 663                'gnus-topic-level level
 664                'gnus-topic-unread unread
 665                'gnus-active active-topic
 666                'gnus-topic-visible visiblep)))))
 667
 668 (defun gnus-topic-update-unreads (topic unreads)
 669   (setq gnus-topic-unreads (delq (assoc topic gnus-topic-unreads)
 670                                  gnus-topic-unreads))
 671   (push (cons topic unreads) gnus-topic-unreads))
 672
 673 (defun gnus-topic-update-topics-containing-group (group)
 674   "Update all topics that have GROUP as a member."
 675   (when (and (eq major-mode 'gnus-group-mode)
 676              gnus-topic-mode)
 677     (save-excursion
 678       (let ((alist gnus-topic-alist))
 679         ;; This is probably not entirely correct.  If a topic
 680         ;; isn't shown, then it's not updated.  But the updating
 681         ;; should be performed in any case, since the topic's
 682         ;; parent should be updated.  Pfft.
 683         (while alist
 684           (when (and (member group (cdar alist))
 685                      (gnus-topic-goto-topic (caar alist)))
 686             (gnus-topic-update-topic-line (caar alist)))
 687           (pop alist))))))
 688
 689 (defun gnus-topic-update-topic ()
 690   "Update all parent topics to the current group."
 691   (when (and (eq major-mode 'gnus-group-mode)
 692              gnus-topic-mode)
 693     (let ((group (gnus-group-group-name))
 694           (m (point-marker))
 695           (buffer-read-only nil))
 696       (when (and group
 697                  (gnus-get-info group)
 698                  (gnus-topic-goto-topic (gnus-current-topic)))
 699         (gnus-topic-update-topic-line (gnus-group-topic-name))
 700         (goto-char m)
 701         (set-marker m nil)
 702         (gnus-group-position-point)))))
 703
 704 (defun gnus-topic-goto-missing-group (group)
 705   "Place point where GROUP is supposed to be inserted."
 706   (let* ((topic (gnus-group-topic group))
 707          (groups (cdr (assoc topic gnus-topic-alist)))
 708          (g (cdr (member group groups)))
 709          (unfound t)
 710          entry)
 711     ;; Try to jump to a visible group.
 712     (while (and g
 713                 (not (gnus-group-goto-group (car g) t)))
 714       (pop g))
 715     ;; It wasn't visible, so we try to see where to insert it.
 716     (when (not g)
 717       (setq g (cdr (member group (reverse groups))))
 718       (while (and g unfound)
 719         (when (gnus-group-goto-group (pop g) t)
 720           (forward-line 1)
 721           (setq unfound nil)))
 722       (when (and unfound
 723                  topic
 724                  (not (gnus-topic-goto-missing-topic topic)))
 725         (gnus-topic-display-missing-topic topic)))))
 726
 727 (defun gnus-topic-display-missing-topic (topic)
 728   "Insert topic lines recursively for missing topics."
 729   (let ((parent (gnus-topic-find-topology
 730                  (gnus-topic-parent-topic topic))))
 731     (when (and parent
 732                (not (gnus-topic-goto-missing-topic (caadr parent))))
 733       (gnus-topic-display-missing-topic (caadr parent))))
 734   (gnus-topic-goto-missing-topic topic)
 735   ;; Skip past all groups in the topic we're in.
 736   (while (gnus-group-group-name)
 737     (forward-line 1))
 738   (let* ((top (gnus-topic-find-topology topic))
 739          (children (cddr top))
 740          (type (cadr top))
 741          (unread 0)
 742          (entries (gnus-topic-find-groups
 743                    (car type) (car gnus-group-list-mode)
 744                    (cdr gnus-group-list-mode)))
 745         entry)
 746     (while children
 747       (incf unread (gnus-topic-unread (caar (pop children)))))
 748     (while (setq entry (pop entries))
 749       (when (numberp (car entry))
 750         (incf unread (car entry))))
 751     (gnus-topic-insert-topic-line
 752      topic t t (car (gnus-topic-find-topology topic)) nil unread)))
 753
 754 (defun gnus-topic-goto-missing-topic (topic)
 755   (if (gnus-topic-goto-topic topic)
 756       (forward-line 1)
 757     ;; Topic not displayed.
 758     (let* ((top (gnus-topic-find-topology
 759                  (gnus-topic-parent-topic topic)))
 760            (tp (reverse (cddr top))))
 761       (if (not top)
 762           (gnus-topic-insert-topic-line
 763            topic t t (car (gnus-topic-find-topology topic)) nil 0)
 764         (while (not (equal (caaar tp) topic))
 765           (setq tp (cdr tp)))
 766         (pop tp)
 767         (while (and tp
 768                     (not (gnus-topic-goto-topic (caaar tp))))
 769           (pop tp))
 770         (if tp
 771             (gnus-topic-forward-topic 1)
 772           (gnus-topic-goto-missing-topic (caadr top)))))
 773     nil))
 774
 775 (defun gnus-topic-update-topic-line (topic-name &optional reads)
 776   (let* ((top (gnus-topic-find-topology topic-name))
 777          (type (cadr top))
 778          (children (cddr top))
 779          (entries (gnus-topic-find-groups
 780                    (car type) (car gnus-group-list-mode)
 781                    (cdr gnus-group-list-mode)))
 782          (parent (gnus-topic-parent-topic topic-name))
 783          (all-entries entries)
 784          (unread 0)
 785          old-unread entry new-unread)
 786     (when (gnus-topic-goto-topic (car type))
 787       ;; Tally all the groups that belong in this topic.
 788       (if reads
 789           (setq unread (- (gnus-group-topic-unread) reads))
 790         (while children
 791           (incf unread (gnus-topic-unread (caar (pop children)))))
 792         (while (setq entry (pop entries))
 793           (when (numberp (car entry))
 794             (incf unread (car entry)))))
 795       (setq old-unread (gnus-group-topic-unread))
 796       ;; Insert the topic line.
 797       (gnus-topic-insert-topic-line
 798        (car type) (gnus-topic-visible-p)
 799        (not (eq (nth 2 type) 'hidden))
 800        (gnus-group-topic-level) all-entries unread)
 801       (gnus-delete-line)
 802       (forward-line -1)
 803       (setq new-unread (gnus-group-topic-unread)))
 804     (when parent
 805       (forward-line -1)
 806       (gnus-topic-update-topic-line
 807        parent
 808        (- (or old-unread 0) (or new-unread 0))))
 809     unread))
 810
 811 (defun gnus-topic-group-indentation ()
 812   (make-string
 813    (* gnus-topic-indent-level
 814       (or (save-excursion
 815             (forward-line -1)
 816             (gnus-topic-goto-topic (gnus-current-topic))
 817             (gnus-group-topic-level))
 818           0))
 819    ? ))
 820
 821 ;;; Initialization
 822
 823 (gnus-add-shutdown 'gnus-topic-close 'gnus)
 824
 825 (defun gnus-topic-close ()
 826   (setq gnus-topic-active-topology nil
 827         gnus-topic-active-alist nil
 828         gnus-topic-killed-topics nil
 829         gnus-topology-checked-p nil))
 830
 831 (defun gnus-topic-check-topology ()
 832   ;; The first time we set the topology to whatever we have
 833   ;; gotten here, which can be rather random.
 834   (unless gnus-topic-alist
 835     (gnus-topic-init-alist))
 836
 837   (setq gnus-topology-checked-p t)
 838   ;; Go through the topic alist and make sure that all topics
 839   ;; are in the topic topology.
 840   (let ((topics (gnus-topic-list))
 841         (alist gnus-topic-alist)
 842         changed)
 843     (while alist
 844       (unless (member (caar alist) topics)
 845         (nconc gnus-topic-topology
 846                (list (list (list (caar alist) 'visible))))
 847         (setq changed t))
 848       (setq alist (cdr alist)))
 849     (when changed
 850       (gnus-topic-enter-dribble))
 851     ;; Conversely, go through the topology and make sure that all
 852     ;; topologies have alists.
 853     (while topics
 854       (unless (assoc (car topics) gnus-topic-alist)
 855         (push (list (car topics)) gnus-topic-alist))
 856       (pop topics)))
 857   ;; Go through all living groups and make sure that
 858   ;; they belong to some topic.
 859   (let* ((tgroups (apply 'append (mapcar 'cdr gnus-topic-alist)))
 860          (entry (last (assoc (caar gnus-topic-topology) gnus-topic-alist)))
 861          (newsrc (cdr gnus-newsrc-alist))
 862          group)
 863     (while newsrc
 864       (unless (member (setq group (gnus-info-group (pop newsrc))) tgroups)
 865         (setcdr entry (list group))
 866         (setq entry (cdr entry)))))
 867   ;; Go through all topics and make sure they contain only living groups.
 868   (let ((alist gnus-topic-alist)
 869         topic)
 870     (while (setq topic (pop alist))
 871       (while (cdr topic)
 872         (if (and (cadr topic)
 873                  (gnus-group-entry (cadr topic)))
 874             (setq topic (cdr topic))
 875           (setcdr topic (cddr topic)))))))
 876
 877 (defun gnus-topic-init-alist ()
 878   "Initialize the topic structures."
 879   (setq gnus-topic-topology
 880         (cons (list "Gnus" 'visible)
 881               (mapcar (lambda (topic)
 882                         (list (list (car topic) 'visible)))
 883                       '(("misc")))))
 884   (setq gnus-topic-alist
 885         (list (cons "misc"
 886                     (mapcar (lambda (info) (gnus-info-group info))
 887                             (cdr gnus-newsrc-alist)))
 888               (list "Gnus")))
 889   (gnus-topic-enter-dribble))
 890
 891 ;;; Maintenance
 892
 893 (defun gnus-topic-clean-alist ()
 894   "Remove bogus groups from the topic alist."
 895   (let ((topic-alist gnus-topic-alist)
 896         result topic)
 897     (unless gnus-killed-hashtb
 898       (gnus-make-hashtable-from-killed))
 899     (while (setq topic (pop topic-alist))
 900       (let ((topic-name (pop topic))
 901             group filtered-topic)
 902         (while (setq group (pop topic))
 903           (when (and (or (gnus-active group)
 904                          (gnus-info-method (gnus-get-info group)))
 905                      (not (gnus-gethash group gnus-killed-hashtb)))
 906             (push group filtered-topic)))
 907         (push (cons topic-name (nreverse filtered-topic)) result)))
 908     (setq gnus-topic-alist (nreverse result))))
 909
 910 (defun gnus-topic-change-level (group level oldlevel &optional previous)
 911   "Run when changing levels to enter/remove groups from topics."
 912   (with-current-buffer gnus-group-buffer
 913     (let ((buffer-read-only nil))
 914       (unless gnus-topic-inhibit-change-level
 915         (gnus-group-goto-group (or (car (nth 2 previous)) group))
 916         (when (and gnus-topic-mode
 917                    gnus-topic-alist
 918                    (not gnus-topic-inhibit-change-level))
 919           ;; Remove the group from the topics.
 920           (if (and (< oldlevel gnus-level-zombie)
 921                    (>= level gnus-level-zombie))
 922               (let ((alist gnus-topic-alist))
 923                 (while (gnus-group-goto-group group)
 924                   (gnus-delete-line))
 925                 (while alist
 926                   (when (member group (car alist))
 927                     (setcdr (car alist) (delete group (cdar alist))))
 928                   (pop alist)))
 929             ;; If the group is subscribed we enter it into the topics.
 930             (when (and (< level gnus-level-zombie)
 931                        (>= oldlevel gnus-level-zombie))
 932               (let* ((prev (gnus-group-group-name))
 933                      (gnus-topic-inhibit-change-level t)
 934                      (gnus-group-indentation
 935                       (make-string
 936                        (* gnus-topic-indent-level
 937                           (or (save-excursion
 938                                 (gnus-topic-goto-topic (gnus-current-topic))
 939                                 (gnus-group-topic-level))
 940                               0))
 941                        ? ))
 942                      (yanked (list group))
 943                      alist talist end)
 944                 ;; Then we enter the yanked groups into the topics
 945                 ;; they belong to.
 946                 (when (setq alist (assoc (save-excursion
 947                                            (forward-line -1)
 948                                            (or
 949                                             (gnus-current-topic)
 950                                             (caar gnus-topic-topology)))
 951                                          gnus-topic-alist))
 952                   (setq talist alist)
 953                   (when (stringp yanked)
 954                     (setq yanked (list yanked)))
 955                   (if (not prev)
 956                       (nconc alist yanked)
 957                     (if (not (cdr alist))
 958                         (setcdr alist (nconc yanked (cdr alist)))
 959                       (while (and (not end) (cdr alist))
 960                         (when (equal (cadr alist) prev)
 961                           (setcdr alist (nconc yanked (cdr alist)))
 962                           (setq end t))
 963                         (setq alist (cdr alist)))
 964                       (unless end
 965                         (nconc talist yanked))))))
 966               (gnus-topic-update-topic))))))))
 967
 968 (defun gnus-topic-goto-next-group (group props)
 969   "Go to group or the next group after group."
 970   (if (not group)
 971       (if (not (memq 'gnus-topic props))
 972           (goto-char (point-max))
 973         (gnus-topic-goto-topic (symbol-name (cadr (memq 'gnus-topic props)))))
 974     (if (gnus-group-goto-group group)
 975         t
 976       ;; The group is no longer visible.
 977       (let* ((list (assoc (gnus-group-topic group) gnus-topic-alist))
 978              (after (cdr (member group (cdr list)))))
 979         ;; First try to put point on a group after the current one.
 980         (while (and after
 981                     (not (gnus-group-goto-group (car after))))
 982           (setq after (cdr after)))
 983         ;; Then try to put point on a group before point.
 984         (unless after
 985           (setq after (cdr (member group (reverse (cdr list)))))
 986           (while (and after
 987                       (not (gnus-group-goto-group (car after))))
 988             (setq after (cdr after))))
 989         ;; Finally, just put point on the topic.
 990         (if (not (car list))
 991             (goto-char (point-min))
 992           (unless after
 993             (gnus-topic-goto-topic (car list))
 994             (setq after nil)))
 995         t))))
 996
 997 ;;; Topic-active functions
 998
 999 (defun gnus-topic-grok-active (&optional force)
1000   "Parse all active groups and create topic structures for them."
1001   ;; First we make sure that we have really read the active file.
1002   (when (or force
1003             (not gnus-topic-active-alist))
1004     (let (groups)
1005       ;; Get a list of all groups available.
1006       (mapatoms (lambda (g) (when (symbol-value g)
1007                               (push (symbol-name g) groups)))
1008                 gnus-active-hashtb)
1009       (setq groups (sort groups 'string<))
1010       ;; Init the variables.
1011       (setq gnus-topic-active-topology (list (list "" 'visible)))
1012       (setq gnus-topic-active-alist nil)
1013       ;; Descend the top-level hierarchy.
1014       (gnus-topic-grok-active-1 gnus-topic-active-topology groups)
1015       ;; Set the top-level topic names to something nice.
1016       (setcar (car gnus-topic-active-topology) "Gnus active")
1017       (setcar (car gnus-topic-active-alist) "Gnus active"))))
1018
1019 (defun gnus-topic-grok-active-1 (topology groups)
1020   (let* ((name (caar topology))
1021          (prefix (concat "^" (regexp-quote name)))
1022          tgroups ntopology group)
1023     (while (and groups
1024                 (string-match prefix (setq group (car groups))))
1025       (if (not (string-match "\\." group (match-end 0)))
1026           ;; There are no further hierarchies here, so we just
1027           ;; enter this group into the list belonging to this
1028           ;; topic.
1029           (push (pop groups) tgroups)
1030         ;; New sub-hierarchy, so we add it to the topology.
1031         (nconc topology (list (setq ntopology
1032                                     (list (list (substring
1033                                                  group 0 (match-end 0))
1034                                                 'invisible)))))
1035         ;; Descend the hierarchy.
1036         (setq groups (gnus-topic-grok-active-1 ntopology groups))))
1037     ;; We remove the trailing "." from the topic name.
1038     (setq name
1039           (if (string-match "\\.$" name)
1040               (substring name 0 (match-beginning 0))
1041             name))
1042     ;; Add this topic and its groups to the topic alist.
1043     (push (cons name (nreverse tgroups)) gnus-topic-active-alist)
1044     (setcar (car topology) name)
1045     ;; We return the rest of the groups that didn't belong
1046     ;; to this topic.
1047     groups))
1048
1049 ;;; Topic mode, commands and keymap.
1050
1051 (defvar gnus-topic-mode-map nil)
1052 (defvar gnus-group-topic-map nil)
1053
1054 (unless gnus-topic-mode-map
1055   (setq gnus-topic-mode-map (make-sparse-keymap))
1056
1057   ;; Override certain group mode keys.
1058   (gnus-define-keys gnus-topic-mode-map
1059     "=" gnus-topic-select-group
1060     "\r" gnus-topic-select-group
1061     " " gnus-topic-read-group
1062     "\C-c\C-x" gnus-topic-expire-articles
1063     "c" gnus-topic-catchup-articles
1064     "\C-k" gnus-topic-kill-group
1065     "\C-y" gnus-topic-yank-group
1066     "\M-g" gnus-topic-get-new-news-this-topic
1067     "AT" gnus-topic-list-active
1068     "Gp" gnus-topic-edit-parameters
1069     "#" gnus-topic-mark-topic
1070     "\M-#" gnus-topic-unmark-topic
1071     [tab] gnus-topic-indent
1072     [(meta tab)] gnus-topic-unindent
1073     "\C-i" gnus-topic-indent
1074     "\M-\C-i" gnus-topic-unindent
1075     gnus-mouse-2 gnus-mouse-pick-topic)
1076
1077   ;; Define a new submap.
1078   (gnus-define-keys (gnus-group-topic-map "T" gnus-group-mode-map)
1079     "#" gnus-topic-mark-topic
1080     "\M-#" gnus-topic-unmark-topic
1081     "n" gnus-topic-create-topic
1082     "m" gnus-topic-move-group
1083     "D" gnus-topic-remove-group
1084     "c" gnus-topic-copy-group
1085     "h" gnus-topic-hide-topic
1086     "s" gnus-topic-show-topic
1087     "j" gnus-topic-jump-to-topic
1088     "M" gnus-topic-move-matching
1089     "C" gnus-topic-copy-matching
1090     "\M-p" gnus-topic-goto-previous-topic
1091     "\M-n" gnus-topic-goto-next-topic
1092     "\C-i" gnus-topic-indent
1093     [tab] gnus-topic-indent
1094     "r" gnus-topic-rename
1095     "\177" gnus-topic-delete
1096     [delete] gnus-topic-delete
1097     "H" gnus-topic-toggle-display-empty-topics)
1098
1099   (gnus-define-keys (gnus-topic-sort-map "S" gnus-group-topic-map)
1100     "s" gnus-topic-sort-groups
1101     "a" gnus-topic-sort-groups-by-alphabet
1102     "u" gnus-topic-sort-groups-by-unread
1103     "l" gnus-topic-sort-groups-by-level
1104     "e" gnus-topic-sort-groups-by-server
1105     "v" gnus-topic-sort-groups-by-score
1106     "r" gnus-topic-sort-groups-by-rank
1107     "m" gnus-topic-sort-groups-by-method))
1108
1109 (defun gnus-topic-make-menu-bar ()
1110   (unless (boundp 'gnus-topic-menu)
1111     (easy-menu-define
1112      gnus-topic-menu gnus-topic-mode-map ""
1113      '("Topics"
1114        ["Toggle topics" gnus-topic-mode t]
1115        ("Groups"
1116         ["Copy..." gnus-topic-copy-group t]
1117         ["Move..." gnus-topic-move-group t]
1118         ["Remove" gnus-topic-remove-group t]
1119         ["Copy matching..." gnus-topic-copy-matching t]
1120         ["Move matching..." gnus-topic-move-matching t])
1121        ("Topics"
1122         ["Goto..." gnus-topic-jump-to-topic t]
1123         ["Show" gnus-topic-show-topic t]
1124         ["Hide" gnus-topic-hide-topic t]
1125         ["Delete" gnus-topic-delete t]
1126         ["Rename..." gnus-topic-rename t]
1127         ["Create..." gnus-topic-create-topic t]
1128         ["Mark" gnus-topic-mark-topic t]
1129         ["Indent" gnus-topic-indent t]
1130         ["Sort" gnus-topic-sort-topics t]
1131         ["Previous topic" gnus-topic-goto-previous-topic t]
1132         ["Next topic" gnus-topic-goto-next-topic t]
1133         ["Toggle hide empty" gnus-topic-toggle-display-empty-topics t]
1134         ["Edit parameters" gnus-topic-edit-parameters t])
1135        ["List active" gnus-topic-list-active t]))))
1136
1137 (defun gnus-topic-mode (&optional arg redisplay)
1138   "Minor mode for topicsifying Gnus group buffers."
1139   ;; FIXME: Use define-minor-mode.
1140   (interactive (list current-prefix-arg t))
1141   (when (eq major-mode 'gnus-group-mode)
1142     (make-local-variable 'gnus-topic-mode)
1143     (setq gnus-topic-mode
1144           (if (null arg) (not gnus-topic-mode)
1145             (> (prefix-numeric-value arg) 0)))
1146     ;; Infest Gnus with topics.
1147     (if (not gnus-topic-mode)
1148         (setq gnus-goto-missing-group-function nil)
1149       (when (gnus-visual-p 'topic-menu 'menu)
1150         (gnus-topic-make-menu-bar))
1151       (gnus-set-format 'topic t)
1152       (add-minor-mode 'gnus-topic-mode " Topic" gnus-topic-mode-map)
1153       (add-hook 'gnus-group-catchup-group-hook 'gnus-topic-update-topic)
1154       (set (make-local-variable 'gnus-group-prepare-function)
1155            'gnus-group-prepare-topics)
1156       (set (make-local-variable 'gnus-group-get-parameter-function)
1157            'gnus-group-topic-parameters)
1158       (set (make-local-variable 'gnus-group-goto-next-group-function)
1159            'gnus-topic-goto-next-group)
1160       (set (make-local-variable 'gnus-group-indentation-function)
1161            'gnus-topic-group-indentation)
1162       (set (make-local-variable 'gnus-group-update-group-function)
1163            'gnus-topic-update-topics-containing-group)
1164       (set (make-local-variable 'gnus-group-sort-alist-function)
1165            'gnus-group-sort-topic)
1166       (setq gnus-group-change-level-function 'gnus-topic-change-level)
1167       (setq gnus-goto-missing-group-function 'gnus-topic-goto-missing-group)
1168       (gnus-make-local-hook 'gnus-check-bogus-groups-hook)
1169       (add-hook 'gnus-check-bogus-groups-hook 'gnus-topic-clean-alist
1170                 nil 'local)
1171       (setq gnus-topology-checked-p nil)
1172       ;; We check the topology.
1173       (when gnus-newsrc-alist
1174         (gnus-topic-check-topology))
1175       (gnus-run-hooks 'gnus-topic-mode-hook))
1176     ;; Remove topic infestation.
1177     (unless gnus-topic-mode
1178       (remove-hook 'gnus-summary-exit-hook 'gnus-topic-update-topic)
1179       (setq gnus-group-change-level-function nil)
1180       (remove-hook 'gnus-check-bogus-groups-hook 'gnus-topic-clean-alist)
1181       (setq gnus-group-prepare-function 'gnus-group-prepare-flat)
1182       (setq gnus-group-sort-alist-function 'gnus-group-sort-flat))
1183     (when redisplay
1184       (gnus-group-list-groups))))
1185
1186 (defun gnus-topic-select-group (&optional all)
1187   "Select this newsgroup.
1188 No article is selected automatically.
1189 If the group is opened, just switch the summary buffer.
1190 If ALL is non-nil, already read articles become readable.
1191
1192 If ALL is a positive number, fetch this number of the latest
1193 articles in the group.  If ALL is a negative number, fetch this
1194 number of the earliest articles in the group.
1195
1196 If performed over a topic line, toggle folding the topic."
1197   (interactive "P")
1198   (when (and (eobp) (not (gnus-group-group-name)))
1199     (forward-line -1))
1200   (if (gnus-group-topic-p)
1201       (let ((gnus-group-list-mode
1202              (if all (cons (if (numberp all) all 7) t) gnus-group-list-mode)))
1203         (gnus-topic-fold all)
1204         (gnus-dribble-touch))
1205     (gnus-group-select-group all)))
1206
1207 (defun gnus-mouse-pick-topic (e)
1208   "Select the group or topic under the mouse pointer."
1209   (interactive "e")
1210   (mouse-set-point e)
1211   (gnus-topic-read-group nil))
1212
1213 (defun gnus-topic-expire-articles (topic)
1214   "Expire articles in this topic or group."
1215   (interactive (list (gnus-group-topic-name)))
1216   (if (not topic)
1217       (call-interactively 'gnus-group-expire-articles)
1218     (save-excursion
1219       (gnus-message 5 "Expiring groups in %s..." topic)
1220       (let ((gnus-group-marked
1221              (mapcar (lambda (entry) (car (nth 2 entry)))
1222                      (gnus-topic-find-groups topic gnus-level-killed t
1223                                              nil t))))
1224         (gnus-group-expire-articles nil))
1225       (gnus-message 5 "Expiring groups in %s...done" topic))))
1226
1227 (defun gnus-topic-catchup-articles (topic)
1228   "Catchup this topic or group.
1229 Also see `gnus-group-catchup'."
1230   (interactive (list (gnus-group-topic-name)))
1231   (if (not topic)
1232       (call-interactively 'gnus-group-catchup-current)
1233     (save-excursion
1234       (let* ((groups
1235              (mapcar (lambda (entry) (car (nth 2 entry)))
1236                      (gnus-topic-find-groups topic gnus-level-killed t
1237                                              nil t)))
1238              (buffer-read-only nil)
1239              (gnus-group-marked groups))
1240         (gnus-group-catchup-current)
1241         (mapcar 'gnus-topic-update-topics-containing-group groups)))))
1242
1243 (defun gnus-topic-read-group (&optional all no-article group)
1244   "Read news in this newsgroup.
1245 If the prefix argument ALL is non-nil, already read articles become
1246 readable.
1247
1248 If ALL is a positive number, fetch this number of the latest
1249 articles in the group.  If ALL is a negative number, fetch this
1250 number of the earliest articles in the group.
1251
1252 If the optional argument NO-ARTICLE is non-nil, no article will
1253 be auto-selected upon group entry.  If GROUP is non-nil, fetch
1254 that group.
1255
1256 If performed over a topic line, toggle folding the topic."
1257   (interactive "P")
1258   (when (and (eobp) (not (gnus-group-group-name)))
1259     (forward-line -1))
1260   (if (gnus-group-topic-p)
1261       (let ((gnus-group-list-mode
1262              (if all (cons (if (numberp all) all 7) t) gnus-group-list-mode)))
1263         (gnus-topic-fold all))
1264     (gnus-group-read-group all no-article group)))
1265
1266 (defun gnus-topic-create-topic (topic parent &optional previous full-topic)
1267   "Create a new TOPIC under PARENT.
1268 When used interactively, PARENT will be the topic under point."
1269   (interactive
1270    (list
1271     (read-string "New topic: ")
1272     (gnus-current-topic)))
1273   ;; Check whether this topic already exists.
1274   (when (gnus-topic-find-topology topic)
1275     (error "Topic already exists"))
1276   (unless parent
1277     (setq parent (caar gnus-topic-topology)))
1278   (let ((top (cdr (gnus-topic-find-topology parent)))
1279         (full-topic (or full-topic (list (list topic 'visible nil nil)))))
1280     (unless top
1281       (error "No such parent topic: %s" parent))
1282     (if previous
1283         (progn
1284           (while (and (cdr top)
1285                       (not (equal (caaadr top) previous)))
1286             (setq top (cdr top)))
1287           (setcdr top (cons full-topic (cdr top))))
1288       (nconc top (list full-topic)))
1289     (unless (assoc topic gnus-topic-alist)
1290       (push (list topic) gnus-topic-alist)))
1291   (gnus-topic-enter-dribble)
1292   (gnus-group-list-groups)
1293   (gnus-topic-goto-topic topic))
1294
1295 ;; FIXME:
1296 ;;  1. When the marked groups are overlapped with the process
1297 ;;     region, the behavior of move or remove is not right.
1298 ;;  2. Can't process on several marked groups with a same name,
1299 ;;     because gnus-group-marked only keeps one copy.
1300
1301 (defun gnus-topic-move-group (n topic &optional copyp)
1302   "Move the next N groups to TOPIC.
1303 If COPYP, copy the groups instead."
1304   (interactive
1305    (list current-prefix-arg
1306          (gnus-completing-read "Move to topic" (mapcar 'car gnus-topic-alist) t
1307                                nil 'gnus-topic-history)))
1308   (let ((use-marked (and (not n) (not (gnus-region-active-p))
1309                          gnus-group-marked t))
1310         (groups (gnus-group-process-prefix n))
1311         (topicl (assoc topic gnus-topic-alist))
1312         (start-topic (gnus-group-topic-name))
1313         (start-group (progn (forward-line 1) (gnus-group-group-name)))
1314         entry)
1315     (if (and (not groups) (not copyp) start-topic)
1316         (gnus-topic-move start-topic topic)
1317       (dolist (g groups)
1318         (gnus-group-remove-mark g use-marked)
1319         (when (and
1320                (setq entry (assoc (gnus-current-topic) gnus-topic-alist))
1321                (not copyp))
1322           (setcdr entry (gnus-delete-first g (cdr entry))))
1323         (nconc topicl (list g)))
1324       (gnus-topic-enter-dribble)
1325       (if start-group
1326           (gnus-group-goto-group start-group)
1327         (gnus-topic-goto-topic start-topic))
1328       (gnus-group-list-groups))))
1329
1330 (defun gnus-topic-remove-group (&optional n)
1331   "Remove the current group from the topic."
1332   (interactive "P")
1333   (let ((use-marked (and (not n) (not (gnus-region-active-p))
1334                          gnus-group-marked t))
1335         (groups (gnus-group-process-prefix n)))
1336     (mapc
1337      (lambda (group)
1338        (gnus-group-remove-mark group use-marked)
1339        (let ((topicl (assoc (gnus-current-topic) gnus-topic-alist))
1340              (buffer-read-only nil))
1341          (when (and topicl group)
1342            (gnus-delete-line)
1343            (gnus-delete-first group topicl))
1344          (gnus-topic-update-topic)))
1345      groups)
1346     (gnus-topic-enter-dribble)
1347     (gnus-group-position-point)))
1348
1349 (defun gnus-topic-copy-group (n topic)
1350   "Copy the current group to a topic."
1351   (interactive
1352    (list current-prefix-arg
1353          (gnus-completing-read
1354           "Copy to topic" (mapcar 'car gnus-topic-alist) t)))
1355   (gnus-topic-move-group n topic t))
1356
1357 (defun gnus-topic-kill-group (&optional n discard)
1358   "Kill the next N groups."
1359   (interactive "P")
1360   (if (gnus-group-topic-p)
1361       (let ((topic (gnus-group-topic-name)))
1362         (push (cons
1363                (gnus-topic-find-topology topic)
1364                (assoc topic gnus-topic-alist))
1365               gnus-topic-killed-topics)
1366         (gnus-topic-remove-topic nil t)
1367         (gnus-topic-find-topology topic nil nil gnus-topic-topology)
1368         (gnus-topic-enter-dribble))
1369     (gnus-group-kill-group n discard)
1370     (if (not (gnus-group-topic-p))
1371         (gnus-topic-update-topic)
1372       ;; Move up one line so that we update the right topic.
1373       (forward-line -1)
1374       (gnus-topic-update-topic)
1375       (forward-line 1))))
1376
1377 (defun gnus-topic-yank-group (&optional arg)
1378   "Yank the last topic."
1379   (interactive "p")
1380   (if gnus-topic-killed-topics
1381       (let* ((previous
1382               (or (gnus-group-topic-name)
1383                   (gnus-topic-next-topic (gnus-current-topic))))
1384              (data (pop gnus-topic-killed-topics))
1385              (alist (cdr data))
1386              (item (cdar data)))
1387         (push alist gnus-topic-alist)
1388         (gnus-topic-create-topic
1389          (caar item) (gnus-topic-parent-topic previous) previous
1390          item)
1391         (gnus-topic-enter-dribble)
1392         (gnus-topic-goto-topic (caar item)))
1393     (let* ((prev (gnus-group-group-name))
1394            (gnus-topic-inhibit-change-level t)
1395            (gnus-group-indentation
1396             (make-string
1397              (* gnus-topic-indent-level
1398                 (or (save-excursion
1399                       (gnus-topic-goto-topic (gnus-current-topic))
1400                       (gnus-group-topic-level))
1401                     0))
1402              ? ))
1403            yanked alist)
1404       ;; We first yank the groups the normal way...
1405       (setq yanked (gnus-group-yank-group arg))
1406       ;; Then we enter the yanked groups into the topics they belong
1407       ;; to.
1408       (setq alist (assoc (save-excursion
1409                            (forward-line -1)
1410                            (gnus-current-topic))
1411                          gnus-topic-alist))
1412       (when (stringp yanked)
1413         (setq yanked (list yanked)))
1414       (if (not prev)
1415           (nconc alist yanked)
1416         (if (not (cdr alist))
1417             (setcdr alist (nconc yanked (cdr alist)))
1418           (while (cdr alist)
1419             (when (equal (cadr alist) prev)
1420               (setcdr alist (nconc yanked (cdr alist)))
1421               (setq alist nil))
1422             (setq alist (cdr alist))))))
1423     (gnus-topic-update-topic)))
1424
1425 (defun gnus-topic-hide-topic (&optional permanent)
1426   "Hide the current topic.
1427 If PERMANENT, make it stay hidden in subsequent sessions as well."
1428   (interactive "P")
1429   (when (gnus-current-topic)
1430     (gnus-topic-goto-topic (gnus-current-topic))
1431     (if permanent
1432         (setcar (cddr
1433                  (cadr
1434                   (gnus-topic-find-topology (gnus-current-topic))))
1435                 'hidden))
1436     (gnus-topic-remove-topic nil nil)))
1437
1438 (defun gnus-topic-show-topic (&optional permanent)
1439   "Show the hidden topic.
1440 If PERMANENT, make it stay shown in subsequent sessions as well."
1441   (interactive "P")
1442   (when (gnus-group-topic-p)
1443     (if (not permanent)
1444         (gnus-topic-remove-topic t nil)
1445       (let ((topic
1446              (gnus-topic-find-topology
1447               (gnus-completing-read "Show topic"
1448                                     (mapcar 'car gnus-topic-alist) t))))
1449         (setcar (cddr (cadr topic)) nil)
1450         (setcar (cdr (cadr topic)) 'visible)
1451         (gnus-group-list-groups)))))
1452
1453 (defun gnus-topic-mark-topic (topic &optional unmark non-recursive)
1454   "Mark all groups in the TOPIC with the process mark.
1455 If NON-RECURSIVE (which is the prefix) is t, don't mark its subtopics."
1456   (interactive (list (gnus-group-topic-name)
1457                      nil
1458                      (and current-prefix-arg t)))
1459   (if (not topic)
1460       (call-interactively 'gnus-group-mark-group)
1461     (save-excursion
1462       (let ((groups (gnus-topic-find-groups topic gnus-level-killed t nil
1463                                             (not non-recursive))))
1464         (while groups
1465           (funcall (if unmark 'gnus-group-remove-mark 'gnus-group-set-mark)
1466                    (gnus-info-group (nth 2 (pop groups)))))))))
1467
1468 (defun gnus-topic-unmark-topic (topic &optional dummy non-recursive)
1469   "Remove the process mark from all groups in the TOPIC.
1470 If NON-RECURSIVE (which is the prefix) is t, don't unmark its subtopics."
1471   (interactive (list (gnus-group-topic-name)
1472                      nil
1473                      (and current-prefix-arg t)))
1474   (if (not topic)
1475       (call-interactively 'gnus-group-unmark-group)
1476     (gnus-topic-mark-topic topic t non-recursive)))
1477
1478 (defun gnus-topic-get-new-news-this-topic (&optional n)
1479   "Check for new news in the current topic."
1480   (interactive "P")
1481   (if (not (gnus-group-topic-p))
1482       (gnus-group-get-new-news-this-group n)
1483     (let* ((topic (gnus-group-topic-name))
1484            (data (cadr (gnus-topic-find-topology topic))))
1485       (save-excursion
1486         (gnus-topic-mark-topic topic nil (and n t))
1487         (gnus-group-get-new-news-this-group))
1488       (gnus-topic-remove-topic (eq 'visible (cadr data))))))
1489
1490 (defun gnus-topic-move-matching (regexp topic &optional copyp)
1491   "Move all groups that match REGEXP to some topic."
1492   (interactive
1493    (let (topic)
1494      (nreverse
1495       (list
1496        (setq topic (gnus-completing-read "Move to topic"
1497                                          (mapcar 'car gnus-topic-alist) t))
1498        (read-string (format "Move to %s (regexp): " topic))))))
1499   (gnus-group-mark-regexp regexp)
1500   (gnus-topic-move-group nil topic copyp))
1501
1502 (defun gnus-topic-copy-matching (regexp topic &optional copyp)
1503   "Copy all groups that match REGEXP to some topic."
1504   (interactive
1505    (let (topic)
1506      (nreverse
1507       (list
1508        (setq topic (gnus-completing-read "Copy to topic"
1509                                          (mapcar 'car gnus-topic-alist) t))
1510        (read-string (format "Copy to %s (regexp): " topic))))))
1511   (gnus-topic-move-matching regexp topic t))
1512
1513 (defun gnus-topic-delete (topic)
1514   "Delete a topic."
1515   (interactive (list (gnus-group-topic-name)))
1516   (unless topic
1517     (error "No topic to be deleted"))
1518   (let ((entry (assoc topic gnus-topic-alist))
1519         (buffer-read-only nil))
1520     (when (cdr entry)
1521       (error "Topic not empty"))
1522     ;; Delete if visible.
1523     (when (gnus-topic-goto-topic topic)
1524       (gnus-delete-line))
1525     ;; Remove from alist.
1526     (setq gnus-topic-alist (delq entry gnus-topic-alist))
1527     ;; Remove from topology.
1528     (gnus-topic-find-topology topic nil nil 'delete)
1529     (gnus-dribble-touch)))
1530
1531 (defun gnus-topic-rename (old-name new-name)
1532   "Rename a topic."
1533   (interactive
1534    (let ((topic (gnus-current-topic)))
1535      (list topic
1536            (read-string (format "Rename %s to: " topic) topic))))
1537   ;; Check whether the new name exists.
1538   (when (gnus-topic-find-topology new-name)
1539     (error "Topic '%s' already exists" new-name))
1540   ;; "nil" is an invalid name, for reasons I'd rather not go
1541   ;; into here.  Trust me.
1542   (when (equal new-name "nil")
1543     (error "Invalid name: %s" nil))
1544   ;; Do the renaming.
1545   (let ((top (gnus-topic-find-topology old-name))
1546         (entry (assoc old-name gnus-topic-alist)))
1547     (when top
1548       (setcar (cadr top) new-name))
1549     (when entry
1550       (setcar entry new-name))
1551     (forward-line -1)
1552     (gnus-dribble-touch)
1553     (gnus-group-list-groups)
1554     (forward-line 1)))
1555
1556 (defun gnus-topic-indent (&optional unindent)
1557   "Indent a topic -- make it a sub-topic of the previous topic.
1558 If UNINDENT, remove an indentation."
1559   (interactive "P")
1560   (if unindent
1561       (gnus-topic-unindent)
1562     (let* ((topic (gnus-current-topic))
1563            (parent (gnus-topic-previous-topic topic))
1564            (buffer-read-only nil))
1565       (unless parent
1566         (error "Nothing to indent %s into" topic))
1567       (when topic
1568         (gnus-topic-goto-topic topic)
1569         (gnus-topic-kill-group)
1570         (push (cdar gnus-topic-killed-topics) gnus-topic-alist)
1571         (gnus-topic-create-topic
1572          topic parent nil (cdar (car gnus-topic-killed-topics)))
1573         (pop gnus-topic-killed-topics)
1574         (or (gnus-topic-goto-topic topic)
1575             (gnus-topic-goto-topic parent))))))
1576
1577 (defun gnus-topic-unindent ()
1578   "Unindent a topic."
1579   (interactive)
1580   (let* ((topic (gnus-current-topic))
1581          (parent (gnus-topic-parent-topic topic))
1582          (grandparent (gnus-topic-parent-topic parent)))
1583     (unless grandparent
1584       (error "Nothing to indent %s into" topic))
1585     (when topic
1586       (gnus-topic-goto-topic topic)
1587       (gnus-topic-kill-group)
1588       (push (cdar gnus-topic-killed-topics) gnus-topic-alist)
1589       (gnus-topic-create-topic
1590        topic grandparent (gnus-topic-next-topic parent)
1591        (cdar (car gnus-topic-killed-topics)))
1592       (pop gnus-topic-killed-topics)
1593       (gnus-topic-goto-topic topic))))
1594
1595 (defun gnus-topic-list-active (&optional force)
1596   "List all groups that Gnus knows about in a topicsified fashion.
1597 If FORCE, always re-read the active file."
1598   (interactive "P")
1599   (when force
1600     (gnus-get-killed-groups))
1601   (gnus-topic-grok-active force)
1602   (let ((gnus-topic-topology gnus-topic-active-topology)
1603         (gnus-topic-alist gnus-topic-active-alist)
1604         gnus-killed-list gnus-zombie-list)
1605     (gnus-group-list-groups gnus-level-killed nil 1)))
1606
1607 (defun gnus-topic-toggle-display-empty-topics ()
1608   "Show/hide topics that have no unread articles."
1609   (interactive)
1610   (setq gnus-topic-display-empty-topics
1611         (not gnus-topic-display-empty-topics))
1612   (gnus-group-list-groups)
1613   (message "%s empty topics"
1614            (if gnus-topic-display-empty-topics
1615                "Showing" "Hiding")))
1616
1617 ;;; Topic sorting functions
1618
1619 (defun gnus-topic-edit-parameters (group)
1620   "Edit the group parameters of GROUP.
1621 If performed on a topic, edit the topic parameters instead."
1622   (interactive (list (gnus-group-group-name)))
1623   (if group
1624       (gnus-group-edit-group-parameters group)
1625     (if (not (gnus-group-topic-p))
1626         (error "Nothing to edit on the current line")
1627       (let ((topic (gnus-group-topic-name)))
1628         (gnus-edit-form
1629          (gnus-topic-parameters topic)
1630          (format "Editing the topic parameters for `%s'."
1631                  (or group topic))
1632          `(lambda (form)
1633             (gnus-topic-set-parameters ,topic form)))))))
1634
1635 (defun gnus-group-sort-topic (func reverse)
1636   "Sort groups in the topics according to FUNC and REVERSE."
1637   (let ((alist gnus-topic-alist))
1638     (while alist
1639       ;; !!!Sometimes nil elements sneak into the alist,
1640       ;; for some reason or other.
1641       (setcar alist (delq nil (car alist)))
1642       (setcar alist (delete "dummy.group" (car alist)))
1643       (gnus-topic-sort-topic (pop alist) func reverse))))
1644
1645 (defun gnus-topic-sort-topic (topic func reverse)
1646   ;; Each topic only lists the name of the group, while
1647   ;; the sort predicates expect group infos as inputs.
1648   ;; So we first transform the group names into infos,
1649   ;; then sort, and then transform back into group names.
1650   (setcdr
1651    topic
1652    (mapcar
1653     (lambda (info) (gnus-info-group info))
1654     (sort
1655      (mapcar
1656       (lambda (group) (gnus-get-info group))
1657       (cdr topic))
1658      func)))
1659   ;; Do the reversal, if necessary.
1660   (when reverse
1661     (setcdr topic (nreverse (cdr topic)))))
1662
1663 (defun gnus-topic-sort-groups (func &optional reverse)
1664   "Sort the current topic according to FUNC.
1665 If REVERSE, reverse the sorting order."
1666   (interactive (list gnus-group-sort-function current-prefix-arg))
1667   (let ((topic (assoc (gnus-current-topic) gnus-topic-alist)))
1668     (gnus-topic-sort-topic
1669      topic (gnus-make-sort-function func) reverse)
1670     (gnus-group-list-groups)))
1671
1672 (defun gnus-topic-sort-groups-by-alphabet (&optional reverse)
1673   "Sort the current topic alphabetically by group name.
1674 If REVERSE, sort in reverse order."
1675   (interactive "P")
1676   (gnus-topic-sort-groups 'gnus-group-sort-by-alphabet reverse))
1677
1678 (defun gnus-topic-sort-groups-by-unread (&optional reverse)
1679   "Sort the current topic by number of unread articles.
1680 If REVERSE, sort in reverse order."
1681   (interactive "P")
1682   (gnus-topic-sort-groups 'gnus-group-sort-by-unread reverse))
1683
1684 (defun gnus-topic-sort-groups-by-level (&optional reverse)
1685   "Sort the current topic by group level.
1686 If REVERSE, sort in reverse order."
1687   (interactive "P")
1688   (gnus-topic-sort-groups 'gnus-group-sort-by-level reverse))
1689
1690 (defun gnus-topic-sort-groups-by-score (&optional reverse)
1691   "Sort the current topic by group score.
1692 If REVERSE, sort in reverse order."
1693   (interactive "P")
1694   (gnus-topic-sort-groups 'gnus-group-sort-by-score reverse))
1695
1696 (defun gnus-topic-sort-groups-by-rank (&optional reverse)
1697   "Sort the current topic by group rank.
1698 If REVERSE, sort in reverse order."
1699   (interactive "P")
1700   (gnus-topic-sort-groups 'gnus-group-sort-by-rank reverse))
1701
1702 (defun gnus-topic-sort-groups-by-method (&optional reverse)
1703   "Sort the current topic alphabetically by backend name.
1704 If REVERSE, sort in reverse order."
1705   (interactive "P")
1706   (gnus-topic-sort-groups 'gnus-group-sort-by-method reverse))
1707
1708 (defun gnus-topic-sort-groups-by-server (&optional reverse)
1709   "Sort the current topic alphabetically by server name.
1710 If REVERSE, sort in reverse order."
1711   (interactive "P")
1712   (gnus-topic-sort-groups 'gnus-group-sort-by-server reverse))
1713
1714 (defun gnus-topic-sort-topics-1 (top reverse)
1715   (if (cdr top)
1716       (let ((subtop
1717              (mapcar (gnus-byte-compile
1718                       `(lambda (top)
1719                          (gnus-topic-sort-topics-1 top ,reverse)))
1720                      (sort (cdr top)
1721                            (lambda (t1 t2)
1722                              (string-lessp (caar t1) (caar t2)))))))
1723         (setcdr top (if reverse (reverse subtop) subtop))))
1724   top)
1725
1726 (defun gnus-topic-sort-topics (&optional topic reverse)
1727   "Sort topics in TOPIC alphabetically by topic name.
1728 If REVERSE, reverse the sorting order."
1729   (interactive
1730    (list (gnus-completing-read "Sort topics in"
1731                                (mapcar 'car gnus-topic-alist) t
1732                                (gnus-current-topic))
1733          current-prefix-arg))
1734   (let ((topic-topology (or (and topic (cdr (gnus-topic-find-topology topic)))
1735                             gnus-topic-topology)))
1736     (gnus-topic-sort-topics-1 topic-topology reverse)
1737     (gnus-topic-enter-dribble)
1738     (gnus-group-list-groups)
1739     (gnus-topic-goto-topic topic)))
1740
1741 (defun gnus-topic-move (current to)
1742   "Move the CURRENT topic to TO."
1743   (interactive
1744    (list
1745     (gnus-group-topic-name)
1746     (gnus-completing-read "Move to topic" (mapcar 'car gnus-topic-alist) t)))
1747   (unless (and current to)
1748     (error "Can't find topic"))
1749   (let ((current-top (cdr (gnus-topic-find-topology current)))
1750         (to-top (cdr (gnus-topic-find-topology to))))
1751     (unless current-top
1752       (error "Can't find topic `%s'" current))
1753     (unless to-top
1754       (error "Can't find topic `%s'" to))
1755     (if (gnus-topic-find-topology to current-top 0);; Don't care the level
1756         (error "Can't move `%s' to its sub-level" current))
1757     (gnus-topic-find-topology current nil nil 'delete)
1758     (setcdr (last to-top) (list current-top))
1759     (gnus-topic-enter-dribble)
1760     (gnus-group-list-groups)
1761     (gnus-topic-goto-topic current)))
1762
1763 (defun gnus-subscribe-topics (newsgroup)
1764   (catch 'end
1765     (let (match gnus-group-change-level-function)
1766       (dolist (topic (gnus-topic-list))
1767         (when (and (setq match (cdr (assq 'subscribe
1768                                           (gnus-topic-parameters topic))))
1769                    (string-match match newsgroup))
1770           ;; Just subscribe the group.
1771           (gnus-subscribe-alphabetically newsgroup)
1772           ;; Add the group to the topic.
1773           (nconc (assoc topic gnus-topic-alist) (list newsgroup))
1774           ;; if this topic specifies a default level, use it
1775           (let ((subscribe-level (cdr (assq 'subscribe-level
1776                                             (gnus-topic-parameters topic)))))
1777             (when subscribe-level
1778                 (gnus-group-change-level newsgroup subscribe-level
1779                                          gnus-level-default-subscribed)))
1780           (throw 'end t)))
1781       nil)))
1782
1783 (provide 'gnus-topic)
1784
1785 ;;; gnus-topic.el ends here