Do a `gnus-request-scan' for the methods that support -retrieve-groups, too.
[gnus] / lisp / gnus-start.el
1 ;;; gnus-start.el --- startup functions for Gnus
2
3 ;; Copyright (C) 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003, 2004,
4 ;;   2005, 2006, 2007, 2008, 2009, 2010 Free Software Foundation, Inc.
5
6 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
7 ;; Keywords: news
8
9 ;; This file is part of GNU Emacs.
10
11 ;; GNU Emacs is free software: you can redistribute it and/or modify
12 ;; it under the terms of the GNU General Public License as published by
13 ;; the Free Software Foundation, either version 3 of the License, or
14 ;; (at your option) any later version.
15
16 ;; GNU Emacs is distributed in the hope that it will be useful,
17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
19 ;; GNU General Public License for more details.
20
21 ;; You should have received a copy of the GNU General Public License
22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
23
24 ;;; Commentary:
25
26 ;;; Code:
27
28 (require 'gnus)
29 (require 'gnus-win)
30 (require 'gnus-int)
31 (require 'gnus-spec)
32 (require 'gnus-range)
33 (require 'gnus-util)
34 (autoload 'message-make-date "message")
35 (autoload 'gnus-agent-read-servers-validate "gnus-agent")
36 (autoload 'gnus-agent-save-local "gnus-agent")
37 (autoload 'gnus-agent-possibly-alter-active "gnus-agent")
38
39 (eval-when-compile
40   (require 'cl))
41
42 (defvar gnus-agent-covered-methods)
43 (defvar gnus-agent-file-loading-local)
44 (defvar gnus-agent-file-loading-cache)
45
46 (defcustom gnus-startup-file (nnheader-concat gnus-home-directory ".newsrc")
47   "Your `.newsrc' file.
48 `.newsrc-SERVER' will be used instead if that exists."
49   :group 'gnus-start
50   :type 'file)
51
52 (defcustom gnus-backup-startup-file 'never
53   "Control use of version numbers for backups of `gnus-startup-file'.
54 This variable takes the same values as the `version-control'
55 variable."
56   :version "22.1"
57   :group 'gnus-start
58   :type '(choice (const :tag "Never" never)
59                  (const :tag "If existing" nil)
60                  (other :tag "Always" t)))
61
62 (defcustom gnus-save-startup-file-via-temp-buffer t
63   "Whether to write the startup file contents to a buffer then save
64 the buffer or write directly to the file.  The buffer is faster
65 because all of the contents are written at once.  The direct write
66 uses considerably less memory."
67   :version "22.1"
68   :group 'gnus-start
69   :type '(choice (const :tag "Write via buffer" t)
70                  (const :tag "Write directly to file" nil)))
71
72 (defcustom gnus-init-file (nnheader-concat gnus-home-directory ".gnus")
73   "Your Gnus Emacs-Lisp startup file name.
74 If a file with the `.el' or `.elc' suffixes exists, it will be read instead."
75   :group 'gnus-start
76   :type 'file)
77
78 (defcustom gnus-site-init-file
79   (condition-case nil
80       (concat (file-name-directory
81                (directory-file-name installation-directory))
82               "site-lisp/gnus-init")
83     (error nil))
84   "The site-wide Gnus Emacs-Lisp startup file name, or nil if none.
85 If a file with the `.el' or `.elc' suffixes exists, it will be read instead."
86   :group 'gnus-start
87   :type '(choice file (const nil)))
88
89 (defcustom gnus-default-subscribed-newsgroups nil
90   "List of newsgroups to subscribe, when a user runs Gnus the first time.
91 The value should be a list of strings.
92 If it is t, Gnus will not do anything special the first time it is
93 started; it'll just use the normal newsgroups subscription methods."
94   :group 'gnus-start
95   :type '(choice (repeat string) (const :tag "Nothing special" t)))
96
97 (defcustom gnus-use-dribble-file t
98   "*Non-nil means that Gnus will use a dribble file to store user updates.
99 If Emacs should crash without saving the .newsrc files, complete
100 information can be restored from the dribble file."
101   :group 'gnus-dribble-file
102   :type 'boolean)
103
104 (defcustom gnus-dribble-directory nil
105   "*The directory where dribble files will be saved.
106 If this variable is nil, the directory where the .newsrc files are
107 saved will be used."
108   :group 'gnus-dribble-file
109   :type '(choice directory (const nil)))
110
111 (defcustom gnus-check-new-newsgroups 'ask-server
112   "*Non-nil means that Gnus will run `gnus-find-new-newsgroups' at startup.
113 This normally finds new newsgroups by comparing the active groups the
114 servers have already reported with those Gnus already knows, either alive
115 or killed.
116
117 When any of the following are true, `gnus-find-new-newsgroups' will instead
118 ask the servers (primary, secondary, and archive servers) to list new
119 groups since the last time it checked:
120   1. This variable is `ask-server'.
121   2. This variable is a list of select methods (see below).
122   3. `gnus-read-active-file' is nil or `some'.
123   4. A prefix argument is given to `gnus-find-new-newsgroups' interactively.
124
125 Thus, if this variable is `ask-server' or a list of select methods or
126 `gnus-read-active-file' is nil or `some', then the killed list is no
127 longer necessary, so you could safely set `gnus-save-killed-list' to nil.
128
129 This variable can be a list of select methods which Gnus will query with
130 the `ask-server' method in addition to the primary, secondary, and archive
131 servers.
132
133 Eg.
134   (setq gnus-check-new-newsgroups
135         '((nntp \"some.server\") (nntp \"other.server\")))
136
137 If this variable is nil, then you have to tell Gnus explicitly to
138 check for new newsgroups with \\<gnus-group-mode-map>\\[gnus-find-new-newsgroups]."
139   :group 'gnus-start
140   :type '(choice (const :tag "no" nil)
141                  (const :tag "by brute force" t)
142                  (const :tag "ask servers" ask-server)
143                  (repeat :menu-tag "ask additional servers"
144                          :tag "ask additional servers"
145                          :value ((nntp ""))
146                          (sexp :format "%v"))))
147
148 (defcustom gnus-check-bogus-newsgroups nil
149   "*Non-nil means that Gnus will check and remove bogus newsgroup at startup.
150 If this variable is nil, then you have to tell Gnus explicitly to
151 check for bogus newsgroups with \\<gnus-group-mode-map>\\[gnus-group-check-bogus-groups]."
152   :group 'gnus-start-server
153   :type 'boolean)
154
155 (defcustom gnus-read-active-file 'some
156   "*Non-nil means that Gnus will read the entire active file at startup.
157 If this variable is nil, Gnus will only know about the groups in your
158 `.newsrc' file.
159
160 If this variable is `some', Gnus will try to only read the relevant
161 parts of the active file from the server.  Not all servers support
162 this, and it might be quite slow with other servers, but this should
163 generally be faster than both the t and nil value.
164
165 If you set this variable to nil or `some', you probably still want to
166 be told about new newsgroups that arrive.  To do that, set
167 `gnus-check-new-newsgroups' to `ask-server'.  This may not work
168 properly with all servers."
169   :group 'gnus-start-server
170   :type '(choice (const nil)
171                  (const some)
172                  (const t)))
173
174 (defconst gnus-level-subscribed 5
175   "Groups with levels less than or equal to this variable are subscribed.")
176
177 (defconst gnus-level-unsubscribed 7
178   "Groups with levels less than or equal to this variable are unsubscribed.
179
180 Groups with levels less than `gnus-level-subscribed', which
181 should be less than this variable, are subscribed.  Groups with
182 levels from `gnus-level-subscribed' (exclusive) upto this
183 variable (inclusive) are unsubscribed.  See also
184 `gnus-level-zombie', `gnus-level-killed' and the Info node `(gnus)Group
185 Levels' for details.")
186
187 (defconst gnus-level-zombie 8
188   "Groups with this level are zombie groups.")
189
190 (defconst gnus-level-killed 9
191   "Groups with this level are killed.")
192
193 (defcustom gnus-level-default-subscribed 3
194   "*New subscribed groups will be subscribed at this level."
195   :group 'gnus-group-levels
196   :type 'integer)
197
198 (defcustom gnus-level-default-unsubscribed 6
199   "*New unsubscribed groups will be unsubscribed at this level."
200   :group 'gnus-group-levels
201   :type 'integer)
202
203 (defcustom gnus-activate-level (1+ gnus-level-subscribed)
204   "*Groups higher than this level won't be activated on startup.
205 Setting this variable to something low might save lots of time when
206 you have many groups that you aren't interested in."
207   :group 'gnus-group-levels
208   :type 'integer)
209
210 (defcustom gnus-activate-foreign-newsgroups 4
211   "*If nil, Gnus will not check foreign newsgroups at startup.
212 If it is non-nil, it should be a number between one and nine.  Foreign
213 newsgroups that have a level lower or equal to this number will be
214 activated on startup.  For instance, if you want to active all
215 subscribed newsgroups, but not the rest, you'd set this variable to
216 `gnus-level-subscribed'.
217
218 If you subscribe to lots of newsgroups from different servers, startup
219 might take a while.  By setting this variable to nil, you'll save time,
220 but you won't be told how many unread articles there are in the
221 groups."
222   :group 'gnus-group-levels
223   :type '(choice integer
224                  (const :tag "none" nil)))
225
226 (defcustom gnus-read-newsrc-file t
227   "*Non-nil means that Gnus will read the `.newsrc' file.
228 Gnus always reads its own startup file, which is called
229 \".newsrc.eld\".  The file called \".newsrc\" is in a format that can
230 be readily understood by other newsreaders.  If you don't plan on
231 using other newsreaders, set this variable to nil to save some time on
232 entry."
233   :version "21.1"
234   :group 'gnus-newsrc
235   :type 'boolean)
236
237 (defcustom gnus-save-newsrc-file t
238   "*Non-nil means that Gnus will save the `.newsrc' file.
239 Gnus always saves its own startup file, which is called
240 \".newsrc.eld\".  The file called \".newsrc\" is in a format that can
241 be readily understood by other newsreaders.  If you don't plan on
242 using other newsreaders, set this variable to nil to save some time on
243 exit."
244   :group 'gnus-newsrc
245   :type 'boolean)
246
247 (defcustom gnus-save-killed-list t
248   "*If non-nil, save the list of killed groups to the startup file.
249 If you set this variable to nil, you'll save both time (when starting
250 and quitting) and space (both memory and disk), but it will also mean
251 that Gnus has no record of which groups are new and which are old, so
252 the automatic new newsgroups subscription methods become meaningless.
253
254 You should always set `gnus-check-new-newsgroups' to `ask-server' or
255 nil if you set this variable to nil.
256
257 This variable can also be a regexp.  In that case, all groups that do
258 not match this regexp will be removed before saving the list."
259   :group 'gnus-newsrc
260   :type '(radio (sexp :format "Non-nil\n"
261                       :match (lambda (widget value)
262                                (and value (not (stringp value))))
263                       :value t)
264                 (const nil)
265                 regexp))
266
267 (defcustom gnus-ignored-newsgroups
268   (mapconcat 'identity
269              '("^to\\."                 ; not "real" groups
270                "^[0-9. \t]+\\( \\|$\\)" ; all digits in name
271                "^[\"][]\"[#'()]"        ; bogus characters
272                )
273              "\\|")
274   "*A regexp to match uninteresting newsgroups in the active file.
275 Any lines in the active file matching this regular expression are
276 removed from the newsgroup list before anything else is done to it,
277 thus making them effectively non-existent."
278   :group 'gnus-group-new
279   :type 'regexp)
280
281 (defcustom gnus-subscribe-newsgroup-method 'gnus-subscribe-zombies
282   "*Function(s) called with a group name when new group is detected.
283 A few pre-made functions are supplied: `gnus-subscribe-randomly'
284 inserts new groups at the beginning of the list of groups;
285 `gnus-subscribe-alphabetically' inserts new groups in strict
286 alphabetic order; `gnus-subscribe-hierarchically' inserts new groups
287 in hierarchical newsgroup order; `gnus-subscribe-interactively' asks
288 for your decision; `gnus-subscribe-killed' kills all new groups;
289 `gnus-subscribe-zombies' will make all new groups into zombies;
290 `gnus-subscribe-topics' will enter groups into the topics that
291 claim them."
292   :group 'gnus-group-new
293   :type '(radio (function-item gnus-subscribe-randomly)
294                 (function-item gnus-subscribe-alphabetically)
295                 (function-item gnus-subscribe-hierarchically)
296                 (function-item gnus-subscribe-interactively)
297                 (function-item gnus-subscribe-killed)
298                 (function-item gnus-subscribe-zombies)
299                 (function-item gnus-subscribe-topics)
300                 function
301                 (repeat function)))
302
303 (defcustom gnus-subscribe-newsgroup-hooks nil
304   "*Hooks run after you subscribe to a new group.
305 The hooks will be called with new group's name as argument."
306   :version "22.1"
307   :group 'gnus-group-new
308   :type 'hook)
309
310 (defcustom gnus-subscribe-options-newsgroup-method
311   'gnus-subscribe-alphabetically
312   "*Function(s) called to subscribe newsgroups mentioned on \"options -n\" lines.
313 If, for instance, you want to subscribe to all newsgroups in the
314 \"no\" and \"alt\" hierarchies, you'd put the following in your
315 .newsrc file:
316
317 options -n no.all alt.all
318
319 Gnus will then subscribe all new newsgroups in these hierarchies
320 with the subscription method in this variable."
321   :group 'gnus-group-new
322   :type '(radio (function-item gnus-subscribe-randomly)
323                 (function-item gnus-subscribe-alphabetically)
324                 (function-item gnus-subscribe-hierarchically)
325                 (function-item gnus-subscribe-interactively)
326                 (function-item gnus-subscribe-killed)
327                 (function-item gnus-subscribe-zombies)
328                 (function-item gnus-subscribe-topics)
329                 function
330                 (repeat function)))
331
332 (defcustom gnus-subscribe-hierarchical-interactive nil
333   "*If non-nil, Gnus will offer to subscribe hierarchically.
334 When a new hierarchy appears, Gnus will ask the user:
335
336 'alt.binaries': Do you want to subscribe to this hierarchy? ([d]ys):
337
338 If the user pressed `d', Gnus will descend the hierarchy, `y' will
339 subscribe to all newsgroups in the hierarchy and `s' will skip this
340 hierarchy in its entirety."
341   :group 'gnus-group-new
342   :type 'boolean)
343
344 (defcustom gnus-auto-subscribed-groups
345   "^nnml\\|^nnfolder\\|^nnmbox\\|^nnmh\\|^nnbabyl\\|^nnmaildir"
346   "*All new groups that match this regexp will be subscribed automatically.
347 Note that this variable only deals with new groups.  It has no effect
348 whatsoever on old groups.
349
350 New groups that match this regexp will not be handled by
351 `gnus-subscribe-newsgroup-method'.  Instead, they will
352 be subscribed using `gnus-subscribe-options-newsgroup-method'."
353   :group 'gnus-group-new
354   :type 'regexp)
355
356 (defcustom gnus-options-subscribe nil
357   "*All new groups matching this regexp will be subscribed unconditionally.
358 Note that this variable deals only with new newsgroups.  This variable
359 does not affect old newsgroups.
360
361 New groups that match this regexp will not be handled by
362 `gnus-subscribe-newsgroup-method'.  Instead, they will
363 be subscribed using `gnus-subscribe-options-newsgroup-method'."
364   :group 'gnus-group-new
365   :type '(choice regexp
366                  (const :tag "none" nil)))
367
368 (defcustom gnus-options-not-subscribe nil
369   "*All new groups matching this regexp will be ignored.
370 Note that this variable deals only with new newsgroups.  This variable
371 does not affect old (already subscribed) newsgroups."
372   :group 'gnus-group-new
373   :type '(choice regexp
374                  (const :tag "none" nil)))
375
376 (defcustom gnus-modtime-botch nil
377   "*Non-nil means .newsrc should be deleted prior to save.
378 Its use is due to the bogus appearance that .newsrc was modified on
379 disc."
380   :group 'gnus-newsrc
381   :type 'boolean)
382
383 (defcustom gnus-check-bogus-groups-hook nil
384   "A hook run after removing bogus groups."
385   :group 'gnus-start-server
386   :type 'hook)
387
388 (defcustom gnus-startup-hook nil
389   "A hook called at startup.
390 This hook is called after Gnus is connected to the NNTP server."
391   :group 'gnus-start
392   :type 'hook)
393
394 (defcustom gnus-before-startup-hook nil
395   "A hook called before startup.
396 This hook is called as the first thing when Gnus is started."
397   :group 'gnus-start
398   :type 'hook)
399
400 (defcustom gnus-started-hook nil
401   "A hook called as the last thing after startup."
402   :group 'gnus-start
403   :type 'hook)
404
405 (defcustom gnus-setup-news-hook
406   '(gnus-fixup-nnimap-unread-after-getting-new-news)
407   "A hook after reading the .newsrc file, but before generating the buffer."
408   :group 'gnus-start
409   :type 'hook)
410
411 (defcustom gnus-get-top-new-news-hook nil
412   "A hook run just before Gnus checks for new news globally."
413   :version "22.1"
414   :group 'gnus-group-new
415   :type 'hook)
416
417 (defcustom gnus-get-new-news-hook nil
418   "A hook run just before Gnus checks for new news."
419   :group 'gnus-group-new
420   :type 'hook)
421
422 (defcustom gnus-after-getting-new-news-hook
423   '(gnus-display-time-event-handler
424     gnus-fixup-nnimap-unread-after-getting-new-news)
425   "*A hook run after Gnus checks for new news when Gnus is already running."
426   :group 'gnus-group-new
427   :type 'hook)
428
429 (defcustom gnus-read-newsrc-el-hook nil
430   "A hook called after reading the newsrc.eld? file."
431   :group 'gnus-newsrc
432   :type 'hook)
433
434 (defcustom gnus-save-newsrc-hook nil
435   "A hook called before saving any of the newsrc files."
436   :group 'gnus-newsrc
437   :type 'hook)
438
439 (defcustom gnus-save-quick-newsrc-hook nil
440   "A hook called just before saving the quick newsrc file.
441 Can be used to turn version control on or off."
442   :group 'gnus-newsrc
443   :type 'hook)
444
445 (defcustom gnus-save-standard-newsrc-hook nil
446   "A hook called just before saving the standard newsrc file.
447 Can be used to turn version control on or off."
448   :group 'gnus-newsrc
449   :type 'hook)
450
451 (defcustom gnus-group-mode-hook nil
452   "Hook for Gnus group mode."
453   :group 'gnus-group-various
454   :options '(gnus-topic-mode)
455   :type 'hook)
456
457 (defcustom gnus-always-read-dribble-file nil
458   "Unconditionally read the dribble file."
459   :group 'gnus-newsrc
460   :type 'boolean)
461
462 ;;; Internal variables
463
464 ;; Fixme: deal with old emacs-mule when mm-universal-coding-system is
465 ;; utf-8-emacs.
466 (defvar gnus-ding-file-coding-system mm-universal-coding-system
467   "Coding system for ding file.")
468
469 (defvar gnus-newsrc-file-version nil)
470 (defvar gnus-override-subscribe-method nil)
471 (defvar gnus-dribble-buffer nil)
472 (defvar gnus-newsrc-options nil
473   "Options line in the .newsrc file.")
474
475 (defvar gnus-newsrc-options-n nil
476   "List of regexps representing groups to be subscribed/ignored unconditionally.")
477
478 (defvar gnus-newsrc-last-checked-date nil
479   "Date Gnus last asked server for new newsgroups.")
480
481 (defvar gnus-current-startup-file nil
482   "Startup file for the current host.")
483
484 ;; Byte-compiler warning.
485 (defvar gnus-group-line-format)
486
487 ;; Suggested by Brian Edmonds <edmonds@cs.ubc.ca>.
488 (defvar gnus-init-inhibit nil)
489 (defun gnus-read-init-file (&optional inhibit-next)
490   ;; Don't load .gnus if the -q option was used.
491   (when init-file-user
492     (if gnus-init-inhibit
493         (setq gnus-init-inhibit nil)
494       (setq gnus-init-inhibit inhibit-next)
495       (dolist (file (list gnus-site-init-file gnus-init-file))
496         (when (and file
497                    (locate-library file))
498           (if (or debug-on-error debug-on-quit)
499               (load file nil t)
500             (condition-case var
501                 (load file nil t)
502               (error
503                (error "Error in %s: %s" file (cadr var))))))))))
504
505 ;; For subscribing new newsgroup
506
507 (defun gnus-subscribe-hierarchical-interactive (groups)
508   (let ((groups (sort groups 'string<))
509         prefixes prefix start ans group starts real-group)
510     (while groups
511       (setq prefixes (list "^"))
512       (while (and groups prefixes)
513         (while (not (string-match (car prefixes)
514                                   (gnus-group-real-name (car groups))))
515           (setq prefixes (cdr prefixes)))
516         (setq prefix (car prefixes))
517         (setq start (1- (length prefix)))
518         (if (and (string-match "[^\\.]\\." (gnus-group-real-name (car groups))
519                                start)
520                  (cdr groups)
521                  (setq prefix
522                        (concat "^" (substring
523                                     (gnus-group-real-name (car groups))
524                                     0 (match-end 0))))
525                  (string-match prefix (gnus-group-real-name (cadr groups))))
526             (progn
527               (push prefix prefixes)
528               (message "Descend hierarchy %s? ([y]nsq): "
529                        (substring prefix 1 (1- (length prefix))))
530               (while (not (memq (setq ans (read-char-exclusive))
531                                 '(?y ?\n ?\r ?n ?s ?q)))
532                 (ding)
533                 (message "Descend hierarchy %s? ([y]nsq): "
534                          (substring prefix 1 (1- (length prefix)))))
535               (cond ((= ans ?n)
536                      (while (and groups
537                                  (setq group (car groups)
538                                        real-group (gnus-group-real-name group))
539                                  (string-match prefix real-group))
540                        (push group gnus-killed-list)
541                        (gnus-sethash group group gnus-killed-hashtb)
542                        (setq groups (cdr groups)))
543                      (setq starts (cdr starts)))
544                     ((= ans ?s)
545                      (while (and groups
546                                  (setq group (car groups)
547                                        real-group (gnus-group-real-name group))
548                                  (string-match prefix real-group))
549                        (gnus-sethash group group gnus-killed-hashtb)
550                        (gnus-subscribe-alphabetically (car groups))
551                        (setq groups (cdr groups)))
552                      (setq starts (cdr starts)))
553                     ((= ans ?q)
554                      (while groups
555                        (setq group (car groups))
556                        (push group gnus-killed-list)
557                        (gnus-sethash group group gnus-killed-hashtb)
558                        (setq groups (cdr groups))))
559                     (t nil)))
560           (message "Subscribe %s? ([n]yq)" (car groups))
561           (while (not (memq (setq ans (read-char-exclusive))
562                             '(?y ?\n ?\r ?q ?n)))
563             (ding)
564             (message "Subscribe %s? ([n]yq)" (car groups)))
565           (setq group (car groups))
566           (cond ((= ans ?y)
567                  (gnus-subscribe-alphabetically (car groups))
568                  (gnus-sethash group group gnus-killed-hashtb))
569                 ((= ans ?q)
570                  (while groups
571                    (setq group (car groups))
572                    (push group gnus-killed-list)
573                    (gnus-sethash group group gnus-killed-hashtb)
574                    (setq groups (cdr groups))))
575                 (t
576                  (push group gnus-killed-list)
577                  (gnus-sethash group group gnus-killed-hashtb)))
578           (setq groups (cdr groups)))))))
579
580 (defun gnus-subscribe-randomly (newsgroup)
581   "Subscribe new NEWSGROUP by making it the first newsgroup."
582   (gnus-subscribe-newsgroup newsgroup))
583
584 (defun gnus-subscribe-alphabetically (newgroup)
585   "Subscribe new NEWGROUP and insert it in alphabetical order."
586   (let ((groups (cdr gnus-newsrc-alist))
587         before)
588     (while (and (not before) groups)
589       (if (string< newgroup (caar groups))
590           (setq before (caar groups))
591         (setq groups (cdr groups))))
592     (gnus-subscribe-newsgroup newgroup before)))
593
594 (defun gnus-subscribe-hierarchically (newgroup)
595   "Subscribe new NEWGROUP and insert it in hierarchical newsgroup order."
596   ;; Basic ideas by mike-w@cs.aukuni.ac.nz (Mike Williams)
597   (save-excursion
598     (set-buffer (nnheader-find-file-noselect gnus-current-startup-file))
599     (prog1
600         (let ((groupkey newgroup) before)
601           (while (and (not before) groupkey)
602             (goto-char (point-min))
603             (let ((groupkey-re
604                    (concat "^\\(" (regexp-quote groupkey) ".*\\)[!:]")))
605               (while (and (re-search-forward groupkey-re nil t)
606                           (progn
607                             (setq before (match-string 1))
608                             (string< before newgroup)))))
609             ;; Remove tail of newsgroup name (eg. a.b.c -> a.b)
610             (setq groupkey
611                   (when (string-match "^\\(.*\\)\\.[^.]+$" groupkey)
612                     (substring groupkey (match-beginning 1) (match-end 1)))))
613           (gnus-subscribe-newsgroup newgroup before))
614       (kill-buffer (current-buffer)))))
615
616 (defun gnus-subscribe-interactively (group)
617   "Subscribe the new GROUP interactively.
618 It is inserted in hierarchical newsgroup order if subscribed.  If not,
619 it is killed."
620   (if (gnus-y-or-n-p (format "Subscribe new newsgroup %s? " group))
621       (gnus-subscribe-hierarchically group)
622     (push group gnus-killed-list)))
623
624 (defun gnus-subscribe-zombies (group)
625   "Make the new GROUP into a zombie group."
626   (push group gnus-zombie-list))
627
628 (defun gnus-subscribe-killed (group)
629   "Make the new GROUP a killed group."
630   (push group gnus-killed-list))
631
632 (defun gnus-subscribe-newsgroup (newsgroup &optional next)
633   "Subscribe new NEWSGROUP.
634 If NEXT is non-nil, it is inserted before NEXT.  Otherwise it is made
635 the first newsgroup."
636   (save-excursion
637     (goto-char (point-min))
638     ;; We subscribe the group by changing its level to `subscribed'.
639     (gnus-group-change-level
640      newsgroup gnus-level-default-subscribed
641      gnus-level-killed (gnus-group-entry (or next "dummy.group")))
642     (gnus-message 5 "Subscribe newsgroup: %s" newsgroup)
643     (run-hook-with-args 'gnus-subscribe-newsgroup-hooks newsgroup)
644     t))
645
646 (defun gnus-read-active-file-p ()
647   "Say whether the active file has been read from `gnus-select-method'."
648   (memq gnus-select-method gnus-have-read-active-file))
649
650 ;;; General various misc type functions.
651
652 ;; Silence byte-compiler.
653 (defvar gnus-current-headers)
654 (defvar gnus-thread-indent-array)
655 (defvar gnus-newsgroup-name)
656 (defvar gnus-newsgroup-headers)
657 (defvar gnus-group-list-mode)
658 (defvar gnus-group-mark-positions)
659 (defvar gnus-newsgroup-data)
660 (defvar gnus-newsgroup-unreads)
661 (defvar nnoo-state-alist)
662 (defvar gnus-current-select-method)
663 (defvar mail-sources)
664 (defvar nnmail-scan-directory-mail-source-once)
665 (defvar nnmail-split-history)
666 (defvar nnmail-spool-file)
667
668 (defun gnus-close-all-servers ()
669   "Close all servers."
670   (interactive)
671   (dolist (server gnus-opened-servers)
672     (gnus-close-server (car server))))
673
674 (defun gnus-clear-system ()
675   "Clear all variables and buffers."
676   ;; Clear Gnus variables.
677   (let ((variables (remove 'gnus-format-specs gnus-variable-list)))
678     (while variables
679       (set (car variables) nil)
680       (setq variables (cdr variables))))
681   ;; Clear other internal variables.
682   (setq gnus-list-of-killed-groups nil
683         gnus-have-read-active-file nil
684         gnus-agent-covered-methods nil
685         gnus-agent-file-loading-local nil
686         gnus-agent-file-loading-cache nil
687         gnus-server-method-cache nil
688         gnus-newsrc-alist nil
689         gnus-newsrc-hashtb nil
690         gnus-killed-list nil
691         gnus-zombie-list nil
692         gnus-killed-hashtb nil
693         gnus-active-hashtb nil
694         gnus-moderated-hashtb nil
695         gnus-description-hashtb nil
696         gnus-current-headers nil
697         gnus-thread-indent-array nil
698         gnus-newsgroup-headers nil
699         gnus-newsgroup-name nil
700         gnus-server-alist nil
701         gnus-group-list-mode nil
702         gnus-opened-servers nil
703         gnus-group-mark-positions nil
704         gnus-newsgroup-data nil
705         gnus-newsgroup-unreads nil
706         nnoo-state-alist nil
707         gnus-current-select-method nil
708         nnmail-split-history nil
709         gnus-ephemeral-servers nil)
710   (gnus-shutdown 'gnus)
711   ;; Kill the startup file.
712   (and gnus-current-startup-file
713        (get-file-buffer gnus-current-startup-file)
714        (kill-buffer (get-file-buffer gnus-current-startup-file)))
715   ;; Clear the dribble buffer.
716   (gnus-dribble-clear)
717   ;; Kill global KILL file buffer.
718   (when (get-file-buffer (gnus-newsgroup-kill-file nil))
719     (kill-buffer (get-file-buffer (gnus-newsgroup-kill-file nil))))
720   (gnus-kill-buffer nntp-server-buffer)
721   ;; Kill Gnus buffers.
722   (dolist (buffer (gnus-buffers))
723     (gnus-kill-buffer buffer))
724   ;; Remove Gnus frames.
725   (gnus-kill-gnus-frames))
726
727 (defun gnus-no-server-1 (&optional arg slave)
728   "Read network news.
729 If ARG is a positive number, Gnus will use that as the startup
730 level.  If ARG is nil, Gnus will be started at level 2
731 \(`gnus-level-default-subscribed' minus one).  If ARG is non-nil
732 and not a positive number, Gnus will prompt the user for the name
733 of an NNTP server to use.  As opposed to \\[gnus], this command
734 will not connect to the local server."
735   (interactive "P")
736   (let ((val (or arg (1- gnus-level-default-subscribed))))
737     (gnus val t slave)
738     (make-local-variable 'gnus-group-use-permanent-levels)
739     (setq gnus-group-use-permanent-levels val)))
740
741 (defun gnus-1 (&optional arg dont-connect slave)
742   "Read network news.
743 If ARG is non-nil and a positive number, Gnus will use that as the
744 startup level.  If ARG is non-nil and not a positive number, Gnus will
745 prompt the user for the name of an NNTP server to use."
746   (interactive "P")
747
748   (if (gnus-alive-p)
749       (progn
750         (switch-to-buffer gnus-group-buffer)
751         (gnus-group-get-new-news
752          (and (numberp arg)
753               (> arg 0)
754               (max (car gnus-group-list-mode) arg))))
755
756     (gnus-clear-system)
757     (gnus-splash)
758     (gnus-run-hooks 'gnus-before-startup-hook)
759     (nnheader-init-server-buffer)
760     (setq gnus-slave slave)
761     (gnus-read-init-file)
762
763     ;; Add "native" to gnus-predefined-server-alist just to have a
764     ;; name for the native select method.
765     (when gnus-select-method
766       (push (cons "native" gnus-select-method)
767             gnus-predefined-server-alist))
768
769     (if gnus-agent
770         (gnus-agentize))
771
772     (when gnus-simple-splash
773       (setq gnus-simple-splash nil)
774       (cond
775        ((featurep 'xemacs)
776         (gnus-xmas-splash))
777        (window-system
778         (gnus-x-splash))))
779
780     (let ((level (and (numberp arg) (> arg 0) arg))
781           did-connect)
782       (unwind-protect
783           (progn
784             (unless dont-connect
785               (setq did-connect
786                     (gnus-start-news-server (and arg (not level))))))
787         (if (and (not dont-connect)
788                  (not did-connect))
789             (gnus-group-quit)
790           (gnus-run-hooks 'gnus-startup-hook)
791           ;; NNTP server is successfully open.
792
793           ;; Find the current startup file name.
794           (setq gnus-current-startup-file
795                 (gnus-make-newsrc-file gnus-startup-file))
796
797           ;; Read the dribble file.
798           (when (or gnus-slave gnus-use-dribble-file)
799             (gnus-dribble-read-file))
800
801           ;; Do the actual startup.
802           (if gnus-agent
803               (gnus-request-create-group "queue" '(nndraft "")))
804           (gnus-request-create-group "drafts" '(nndraft ""))
805           (gnus-setup-news nil level dont-connect)
806           (gnus-run-hooks 'gnus-setup-news-hook)
807           (gnus-start-draft-setup)
808           ;; Generate the group buffer.
809           (gnus-group-list-groups level)
810           (gnus-group-first-unread-group)
811           (gnus-configure-windows 'group)
812           (gnus-group-set-mode-line)
813           (gnus-run-hooks 'gnus-started-hook))))))
814
815 (defun gnus-start-draft-setup ()
816   "Make sure the draft group exists."
817   (interactive)
818   (gnus-request-create-group "drafts" '(nndraft ""))
819   (unless (gnus-group-entry "nndraft:drafts")
820     (let ((gnus-level-default-subscribed 1))
821       (gnus-subscribe-group "nndraft:drafts" nil '(nndraft ""))))
822   (unless (equal (gnus-group-get-parameter "nndraft:drafts" 'gnus-dummy t)
823                  '((gnus-draft-mode)))
824     (gnus-message 3 "Setting up drafts group")
825     (gnus-group-set-parameter
826      "nndraft:drafts" 'gnus-dummy '((gnus-draft-mode)))))
827
828 \f
829 ;;;
830 ;;; Dribble file
831 ;;;
832
833 (defvar gnus-dribble-ignore nil)
834 (defvar gnus-dribble-eval-file nil)
835
836 (defun gnus-dribble-file-name ()
837   "Return the dribble file for the current .newsrc."
838   (concat
839    (if gnus-dribble-directory
840        (concat (file-name-as-directory gnus-dribble-directory)
841                (file-name-nondirectory gnus-current-startup-file))
842      gnus-current-startup-file)
843    "-dribble"))
844
845 (defun gnus-dribble-enter (string)
846   "Enter STRING into the dribble buffer."
847   (when (and (not gnus-dribble-ignore)
848              gnus-dribble-buffer
849              (buffer-name gnus-dribble-buffer))
850     (let ((obuf (current-buffer)))
851       (set-buffer gnus-dribble-buffer)
852       (goto-char (point-max))
853       (insert string "\n")
854       ;; This has been commented by Josh Huber <huber@alum.wpi.edu>
855       ;; It causes problems with both XEmacs and Emacs 21, and doesn't
856       ;; seem to be of much value. (FIXME: remove this after we make sure
857       ;; it's not needed).
858       ;; (set-window-point (get-buffer-window (current-buffer)) (point-max))
859       (bury-buffer gnus-dribble-buffer)
860       (save-excursion
861         (set-buffer gnus-group-buffer)
862         (gnus-group-set-mode-line))
863       (set-buffer obuf))))
864
865 (defun gnus-dribble-touch ()
866   "Touch the dribble buffer."
867   (gnus-dribble-enter ""))
868
869 (defun gnus-dribble-read-file ()
870   "Read the dribble file from disk."
871   (let ((dribble-file (gnus-dribble-file-name)))
872     (unless (file-exists-p (file-name-directory dribble-file))
873       (make-directory (file-name-directory dribble-file) t))
874     (save-excursion
875       (set-buffer (setq gnus-dribble-buffer
876                         (gnus-get-buffer-create
877                          (file-name-nondirectory dribble-file))))
878       (set (make-local-variable 'file-precious-flag) t)
879       (erase-buffer)
880       (setq buffer-file-name dribble-file)
881       (auto-save-mode t)
882       (buffer-disable-undo)
883       (bury-buffer (current-buffer))
884       (set-buffer-modified-p nil)
885       (let ((auto (make-auto-save-file-name))
886             (gnus-dribble-ignore t)
887             (purpose nil)
888             modes)
889         (when (or (file-exists-p auto) (file-exists-p dribble-file))
890           ;; Load whichever file is newest -- the auto save file
891           ;; or the "real" file.
892           (if (file-newer-than-file-p auto dribble-file)
893               (nnheader-insert-file-contents auto)
894             (nnheader-insert-file-contents dribble-file))
895           (unless (zerop (buffer-size))
896             (set-buffer-modified-p t))
897           ;; Set the file modes to reflect the .newsrc file modes.
898           (save-buffer)
899           (when (and (file-exists-p gnus-current-startup-file)
900                      (file-exists-p dribble-file)
901                      (setq modes (file-modes gnus-current-startup-file)))
902             (gnus-set-file-modes dribble-file modes))
903           (goto-char (point-min))
904           (when (search-forward "Gnus was exited on purpose" nil t)
905             (setq purpose t))
906           ;; Possibly eval the file later.
907           (when (or gnus-always-read-dribble-file
908                     (gnus-y-or-n-p
909                      (if purpose
910                          "Gnus exited on purpose without saving; read auto-save file anyway? "
911                      "Gnus auto-save file exists.  Do you want to read it? ")))
912             (setq gnus-dribble-eval-file t)))))))
913
914 (defun gnus-dribble-eval-file ()
915   (when gnus-dribble-eval-file
916     (setq gnus-dribble-eval-file nil)
917     (save-excursion
918       (let ((gnus-dribble-ignore t))
919         (set-buffer gnus-dribble-buffer)
920         (eval-buffer (current-buffer))))))
921
922 (defun gnus-dribble-delete-file ()
923   (when (file-exists-p (gnus-dribble-file-name))
924     (delete-file (gnus-dribble-file-name)))
925   (when gnus-dribble-buffer
926     (save-excursion
927       (set-buffer gnus-dribble-buffer)
928       (let ((auto (make-auto-save-file-name)))
929         (when (file-exists-p auto)
930           (delete-file auto))
931         (erase-buffer)
932         (set-buffer-modified-p nil)))))
933
934 (defun gnus-dribble-save ()
935   (when (and gnus-dribble-buffer
936              (buffer-name gnus-dribble-buffer))
937     (save-excursion
938       (set-buffer gnus-dribble-buffer)
939       (save-buffer))))
940
941 (defun gnus-dribble-clear ()
942   (when (gnus-buffer-exists-p gnus-dribble-buffer)
943     (save-excursion
944       (set-buffer gnus-dribble-buffer)
945       (erase-buffer)
946       (set-buffer-modified-p nil)
947       (setq buffer-saved-size (buffer-size)))))
948
949 \f
950 ;;;
951 ;;; Active & Newsrc File Handling
952 ;;;
953
954 (defun gnus-setup-news (&optional rawfile level dont-connect)
955   "Setup news information.
956 If RAWFILE is non-nil, the .newsrc file will also be read.
957 If LEVEL is non-nil, the news will be set up at level LEVEL."
958   (require 'nnmail)
959   (let ((init (not (and gnus-newsrc-alist gnus-active-hashtb (not rawfile))))
960         ;; Binding this variable will inhibit multiple fetchings
961         ;; of the same mail source.
962         (nnmail-fetched-sources (list t)))
963
964     (when init
965       ;; Clear some variables to re-initialize news information.
966       (setq gnus-newsrc-alist nil
967             gnus-active-hashtb nil)
968       ;; Read the newsrc file and create `gnus-newsrc-hashtb'.
969       (gnus-read-newsrc-file rawfile))
970
971     ;; Make sure the archive server is available to all and sundry.
972     (let ((method (or (and (stringp gnus-message-archive-method)
973                            (gnus-server-to-method
974                             gnus-message-archive-method))
975                       gnus-message-archive-method)))
976       ;; Check whether the archive method is writable.
977       (unless (or (not method)
978                   (stringp method)
979                   (memq 'respool (assoc (format "%s" (car method))
980                                         gnus-valid-select-methods)))
981         (setq method "archive")) ;; The default.
982       (when (stringp method)
983         (setq method `(nnfolder
984                        ,method
985                        (nnfolder-directory
986                         ,(nnheader-concat message-directory method))
987                        (nnfolder-active-file
988                         ,(nnheader-concat message-directory
989                                           (concat method "/active")))
990                        (nnfolder-get-new-mail nil)
991                        (nnfolder-inhibit-expiry t))))
992       (if (assoc "archive" gnus-server-alist)
993           (when gnus-update-message-archive-method
994             (if method
995                 (setcdr (assoc "archive" gnus-server-alist) method)
996               (setq gnus-server-alist (delq (assoc "archive" gnus-server-alist)
997                                             gnus-server-alist))))
998         (when method
999           (push (cons "archive" method) gnus-server-alist))))
1000
1001     ;; If we don't read the complete active file, we fill in the
1002     ;; hashtb here.
1003     (when (or (null gnus-read-active-file)
1004               (eq gnus-read-active-file 'some))
1005       (gnus-update-active-hashtb-from-killed))
1006
1007     ;; Validate agent covered methods now that gnus-server-alist has
1008     ;; been initialized.
1009     ;; NOTE: This is here for one purpose only.  By validating the
1010     ;; agentized server's, it converts the old 5.10.3, and earlier,
1011     ;; format to the current format.  That enables the agent code
1012     ;; within gnus-read-active-file to function correctly.
1013     (if gnus-agent
1014         (gnus-agent-read-servers-validate))
1015
1016     ;; Read the active file and create `gnus-active-hashtb'.
1017     ;; If `gnus-read-active-file' is nil, then we just create an empty
1018     ;; hash table.  The partial filling out of the hash table will be
1019     ;; done in `gnus-get-unread-articles'.
1020     (and gnus-read-active-file
1021          (not level)
1022          (gnus-read-active-file nil dont-connect))
1023
1024     (unless gnus-active-hashtb
1025       (setq gnus-active-hashtb (gnus-make-hashtable 4096)))
1026
1027     ;; Initialize the cache.
1028     (when gnus-use-cache
1029       (gnus-cache-open))
1030
1031     ;; Possibly eval the dribble file.
1032     (and init
1033          (or gnus-use-dribble-file gnus-slave)
1034          (gnus-dribble-eval-file))
1035
1036     ;; Slave Gnusii should then clear the dribble buffer.
1037     (when (and init gnus-slave)
1038       (gnus-dribble-clear))
1039
1040     (gnus-update-format-specifications)
1041
1042     ;; See whether we need to read the description file.
1043     (when (and (boundp 'gnus-group-line-format)
1044                (stringp gnus-group-line-format)
1045                (let ((case-fold-search nil))
1046                  (string-match "%[-,0-9]*D" gnus-group-line-format))
1047                (not gnus-description-hashtb)
1048                (not dont-connect)
1049                gnus-read-active-file)
1050       (gnus-read-all-descriptions-files))
1051
1052     ;; Find new newsgroups and treat them.
1053     (when (and init gnus-check-new-newsgroups (not level)
1054                (gnus-check-server gnus-select-method)
1055                (not gnus-slave)
1056                gnus-plugged)
1057       (gnus-find-new-newsgroups))
1058
1059     ;; Check and remove bogus newsgroups.
1060     (when (and init gnus-check-bogus-newsgroups
1061                gnus-read-active-file (not level)
1062                (gnus-server-opened gnus-select-method))
1063       (gnus-check-bogus-newsgroups))
1064
1065     ;; We might read in new NoCeM messages here.
1066     (when (and (not dont-connect)
1067                gnus-use-nocem
1068                (or (and (numberp gnus-use-nocem)
1069                         (numberp level)
1070                         (>= level gnus-use-nocem))
1071                    (not level)))
1072       (gnus-nocem-scan-groups))
1073
1074     ;; Read any slave files.
1075     (gnus-master-read-slave-newsrc)
1076
1077     ;; Find the number of unread articles in each non-dead group.
1078     (let ((gnus-read-active-file (and (not level) gnus-read-active-file)))
1079       (gnus-get-unread-articles level))))
1080
1081 (defun gnus-call-subscribe-functions (method group)
1082   "Call METHOD to subscribe GROUP.
1083 If no function returns `non-nil', call `gnus-subscribe-zombies'."
1084   (unless (cond
1085            ((functionp method)
1086             (funcall method group))
1087            ((listp method)
1088             (catch 'found
1089               (dolist (func method)
1090                 (if (funcall func group)
1091                     (throw 'found t)))
1092               nil))
1093            (t nil))
1094     (gnus-subscribe-zombies group)))
1095
1096 (defun gnus-find-new-newsgroups (&optional arg)
1097   "Search for new newsgroups and add them.
1098 Each new newsgroup will be treated with `gnus-subscribe-newsgroup-method'.
1099 The `-n' option line from .newsrc is respected.
1100
1101 With 1 C-u, use the `ask-server' method to query the server for new
1102 groups.
1103 With 2 C-u's, use most complete method possible to query the server
1104 for new groups, and subscribe the new groups as zombies."
1105   (interactive "p")
1106   (let* ((gnus-subscribe-newsgroup-method
1107           gnus-subscribe-newsgroup-method)
1108          (check (cond
1109                  ((or (and (= (or arg 1) 4)
1110                            (not (listp gnus-check-new-newsgroups)))
1111                       (null gnus-read-active-file)
1112                       (eq gnus-read-active-file 'some))
1113                   'ask-server)
1114                  ((= (or arg 1) 16)
1115                   (setq gnus-subscribe-newsgroup-method
1116                         'gnus-subscribe-zombies)
1117                   t)
1118                  (t gnus-check-new-newsgroups))))
1119     (unless (gnus-check-first-time-used)
1120       (if (or (consp check)
1121               (eq check 'ask-server))
1122           ;; Ask the server for new groups.
1123           (gnus-ask-server-for-new-groups)
1124         ;; Go through the active hashtb and look for new groups.
1125         (let ((groups 0)
1126               group new-newsgroups)
1127           (gnus-message 5 "Looking for new newsgroups...")
1128           (unless gnus-have-read-active-file
1129             (gnus-read-active-file))
1130           (setq gnus-newsrc-last-checked-date (message-make-date))
1131           (unless gnus-killed-hashtb
1132             (gnus-make-hashtable-from-killed))
1133           ;; Go though every newsgroup in `gnus-active-hashtb' and compare
1134           ;; with `gnus-newsrc-hashtb' and `gnus-killed-hashtb'.
1135           (mapatoms
1136            (lambda (sym)
1137              (if (or (null (setq group (symbol-name sym)))
1138                      (not (boundp sym))
1139                      (null (symbol-value sym))
1140                      (gnus-gethash group gnus-killed-hashtb)
1141                      (gnus-gethash group gnus-newsrc-hashtb))
1142                  ()
1143                (let ((do-sub (gnus-matches-options-n group)))
1144                  (cond
1145                   ((eq do-sub 'subscribe)
1146                    (setq groups (1+ groups))
1147                    (gnus-sethash group group gnus-killed-hashtb)
1148                    (gnus-call-subscribe-functions
1149                     gnus-subscribe-options-newsgroup-method group))
1150                   ((eq do-sub 'ignore)
1151                    nil)
1152                   (t
1153                    (setq groups (1+ groups))
1154                    (gnus-sethash group group gnus-killed-hashtb)
1155                    (if gnus-subscribe-hierarchical-interactive
1156                        (push group new-newsgroups)
1157                      (gnus-call-subscribe-functions
1158                       gnus-subscribe-newsgroup-method group)))))))
1159            gnus-active-hashtb)
1160           (when new-newsgroups
1161             (gnus-subscribe-hierarchical-interactive new-newsgroups))
1162           (if (> groups 0)
1163               (gnus-message 5 "%d new newsgroup%s arrived."
1164                             groups (if (> groups 1) "s have" " has"))
1165             (gnus-message 5 "No new newsgroups.")))))))
1166
1167 (defun gnus-matches-options-n (group)
1168   ;; Returns `subscribe' if the group is to be unconditionally
1169   ;; subscribed, `ignore' if it is to be ignored, and nil if there is
1170   ;; no match for the group.
1171
1172   ;; First we check the two user variables.
1173   (cond
1174    ((and gnus-options-subscribe
1175          (string-match gnus-options-subscribe group))
1176     'subscribe)
1177    ((and gnus-auto-subscribed-groups
1178          (string-match gnus-auto-subscribed-groups group))
1179     'subscribe)
1180    ((and gnus-options-not-subscribe
1181          (string-match gnus-options-not-subscribe group))
1182     'ignore)
1183    ;; Then we go through the list that was retrieved from the .newsrc
1184    ;; file.  This list has elements on the form
1185    ;; `(REGEXP . {ignore,subscribe})'.  The first match found (the list
1186    ;; is in the reverse order of the options line) is returned.
1187    (t
1188     (let ((regs gnus-newsrc-options-n))
1189       (while (and regs
1190                   (not (string-match (caar regs) group)))
1191         (setq regs (cdr regs)))
1192       (and regs (cdar regs))))))
1193
1194 (defun gnus-ask-server-for-new-groups ()
1195   (let* ((new-date (message-make-date))
1196          (date (or gnus-newsrc-last-checked-date new-date))
1197          (methods (cons gnus-select-method
1198                         (nconc
1199                          (when (gnus-archive-server-wanted-p)
1200                            (list "archive"))
1201                          (append
1202                           (and (consp gnus-check-new-newsgroups)
1203                                gnus-check-new-newsgroups)
1204                           gnus-secondary-select-methods))))
1205          (groups 0)
1206          group new-newsgroups got-new method hashtb
1207          gnus-override-subscribe-method)
1208     (unless gnus-killed-hashtb
1209       (gnus-make-hashtable-from-killed))
1210     ;; Go through both primary and secondary select methods and
1211     ;; request new newsgroups.
1212     (while (setq method (gnus-server-get-method nil (pop methods)))
1213       (setq new-newsgroups nil
1214             gnus-override-subscribe-method method)
1215       (when (and (gnus-check-server method)
1216                  (gnus-request-newgroups date method))
1217         (save-excursion
1218           (setq got-new t
1219                 hashtb (gnus-make-hashtable 100))
1220           (set-buffer nntp-server-buffer)
1221           ;; Enter all the new groups into a hashtable.
1222           (gnus-active-to-gnus-format method hashtb 'ignore))
1223         ;; Now all new groups from `method' are in `hashtb'.
1224         (mapatoms
1225          (lambda (group-sym)
1226            (if (or (null (setq group (symbol-name group-sym)))
1227                    (not (boundp group-sym))
1228                    (null (symbol-value group-sym))
1229                    (gnus-gethash group gnus-newsrc-hashtb)
1230                    (member group gnus-zombie-list)
1231                    (member group gnus-killed-list))
1232                ;; The group is already known.
1233                ()
1234              ;; Make this group active.
1235              (when (symbol-value group-sym)
1236                (gnus-set-active group (symbol-value group-sym)))
1237              ;; Check whether we want it or not.
1238              (let ((do-sub (gnus-matches-options-n group)))
1239                (cond
1240                 ((eq do-sub 'subscribe)
1241                  (incf groups)
1242                  (gnus-sethash group group gnus-killed-hashtb)
1243                  (gnus-call-subscribe-functions
1244                   gnus-subscribe-options-newsgroup-method group))
1245                 ((eq do-sub 'ignore)
1246                  nil)
1247                 (t
1248                  (incf groups)
1249                  (gnus-sethash group group gnus-killed-hashtb)
1250                  (if gnus-subscribe-hierarchical-interactive
1251                      (push group new-newsgroups)
1252                    (gnus-call-subscribe-functions
1253                     gnus-subscribe-newsgroup-method group)))))))
1254          hashtb))
1255       (when new-newsgroups
1256         (gnus-subscribe-hierarchical-interactive new-newsgroups)))
1257     (if (> groups 0)
1258         (gnus-message 5 "%d new newsgroup%s arrived"
1259                       groups (if (> groups 1) "s have" " has"))
1260       (gnus-message 5 "No new newsgroups"))
1261     (when got-new
1262       (setq gnus-newsrc-last-checked-date new-date))
1263     got-new))
1264
1265 (defun gnus-check-first-time-used ()
1266   (catch 'ended
1267     ;; First check if any of the following files exist.  If they do,
1268     ;; it's not the first time the user has used Gnus.
1269     (dolist (file (list (concat gnus-current-startup-file ".el")
1270                         (concat gnus-current-startup-file ".eld")
1271                         (concat gnus-startup-file ".el")
1272                         (concat gnus-startup-file ".eld")))
1273       (when (file-exists-p file)
1274         (throw 'ended nil)))
1275     (gnus-message 6 "First time user; subscribing you to default groups")
1276     (unless (gnus-read-active-file-p)
1277       (let ((gnus-read-active-file t))
1278         (gnus-read-active-file)))
1279     (setq gnus-newsrc-last-checked-date (message-make-date))
1280     ;; Subscribe to the default newsgroups.
1281     (let ((groups (or gnus-default-subscribed-newsgroups
1282                       gnus-backup-default-subscribed-newsgroups))
1283           group)
1284       (if (eq groups t)
1285           ;; If t, we subscribe (or not) all groups as if they were new.
1286           (mapatoms
1287            (lambda (sym)
1288              (when (setq group (symbol-name sym))
1289                (let ((do-sub (gnus-matches-options-n group)))
1290                  (cond
1291                   ((eq do-sub 'subscribe)
1292                    (gnus-sethash group group gnus-killed-hashtb)
1293                    (gnus-call-subscribe-functions
1294                     gnus-subscribe-options-newsgroup-method group))
1295                   ((eq do-sub 'ignore)
1296                    nil)
1297                   (t
1298                    (push group gnus-killed-list))))))
1299            gnus-active-hashtb)
1300         (dolist (group groups)
1301           ;; Only subscribe the default groups that are activated.
1302           (when (gnus-active group)
1303             (gnus-group-change-level
1304              group gnus-level-default-subscribed gnus-level-killed)))
1305         (save-excursion
1306           (set-buffer gnus-group-buffer)
1307           ;; Don't error if the group already exists. This happens when a
1308           ;; first-time user types 'F'. -- didier
1309           (gnus-group-make-help-group t))
1310         (when gnus-novice-user
1311           (gnus-message 7 "`A k' to list killed groups"))))))
1312
1313 (defun gnus-subscribe-group (group &optional previous method)
1314   "Subscribe GROUP and put it after PREVIOUS."
1315   (gnus-group-change-level
1316    (if method
1317        (list t group gnus-level-default-subscribed nil nil method)
1318      group)
1319    gnus-level-default-subscribed gnus-level-killed previous t)
1320   t)
1321
1322 ;; `gnus-group-change-level' is the fundamental function for changing
1323 ;; subscription levels of newsgroups.  This might mean just changing
1324 ;; from level 1 to 2, which is pretty trivial, from 2 to 6 or back
1325 ;; again, which subscribes/unsubscribes a group, which is equally
1326 ;; trivial.  Changing from 1-7 to 8-9 means that you kill a group, and
1327 ;; from 8-9 to 1-7 means that you remove the group from the list of
1328 ;; killed (or zombie) groups and add them to the (kinda) subscribed
1329 ;; groups.  And last but not least, moving from 8 to 9 and 9 to 8,
1330 ;; which is trivial.
1331 ;; ENTRY can either be a string (newsgroup name) or a list (if
1332 ;; FROMKILLED is t, it's a list on the format (NUM INFO-LIST),
1333 ;; otherwise it's a list in the format of the `gnus-newsrc-hashtb'
1334 ;; entries.
1335 ;; LEVEL is the new level of the group, OLDLEVEL is the old level and
1336 ;; PREVIOUS is the group (in hashtb entry format) to insert this group
1337 ;; after.
1338 (defun gnus-group-change-level (entry level &optional oldlevel
1339                                       previous fromkilled)
1340   (let (group info active num)
1341     ;; Glean what info we can from the arguments
1342     (if (consp entry)
1343         (if fromkilled (setq group (nth 1 entry))
1344           (setq group (car (nth 2 entry))))
1345       (setq group entry))
1346     (when (and (stringp entry)
1347                oldlevel
1348                (< oldlevel gnus-level-zombie))
1349       (setq entry (gnus-group-entry entry)))
1350     (if (and (not oldlevel)
1351              (consp entry))
1352         (setq oldlevel (gnus-info-level (nth 2 entry)))
1353       (setq oldlevel (or oldlevel gnus-level-killed)))
1354     (when (stringp previous)
1355       (setq previous (gnus-group-entry previous)))
1356
1357     (if (and (>= oldlevel gnus-level-zombie)
1358              (gnus-group-entry group))
1359         ;; We are trying to subscribe a group that is already
1360         ;; subscribed.
1361         ()                              ; Do nothing.
1362
1363       (unless (gnus-ephemeral-group-p group)
1364         (gnus-dribble-enter
1365          (format "(gnus-group-change-level %S %S %S %S %S)"
1366                  group level oldlevel (car (nth 2 previous)) fromkilled)))
1367
1368       ;; Then we remove the newgroup from any old structures, if needed.
1369       ;; If the group was killed, we remove it from the killed or zombie
1370       ;; list.  If not, and it is in fact going to be killed, we remove
1371       ;; it from the newsrc hash table and assoc.
1372       (cond
1373        ((>= oldlevel gnus-level-zombie)
1374         ;; oldlevel could be wrong.
1375         (setq gnus-zombie-list (delete group gnus-zombie-list))
1376         (setq gnus-killed-list (delete group gnus-killed-list)))
1377        (t
1378         (when (and (>= level gnus-level-zombie)
1379                    entry)
1380           (gnus-sethash (car (nth 2 entry)) nil gnus-newsrc-hashtb)
1381           (when (nth 3 entry)
1382             (setcdr (gnus-group-entry (car (nth 3 entry)))
1383                     (cdr entry)))
1384           (setcdr (cdr entry) (cdddr entry)))))
1385
1386       ;; Finally we enter (if needed) the list where it is supposed to
1387       ;; go, and change the subscription level.  If it is to be killed,
1388       ;; we enter it into the killed or zombie list.
1389       (cond
1390        ((>= level gnus-level-zombie)
1391         ;; Remove from the hash table.
1392         (gnus-sethash group nil gnus-newsrc-hashtb)
1393         ;; We do not enter foreign groups into the list of dead
1394         ;; groups.
1395         (unless (gnus-group-foreign-p group)
1396           (if (= level gnus-level-zombie)
1397               (push group gnus-zombie-list)
1398             (if (= oldlevel gnus-level-killed)
1399                 ;; Remove from active hashtb.
1400                 (unintern group gnus-active-hashtb)
1401               ;; Don't add it into killed-list if it was killed.
1402               (push group gnus-killed-list)))))
1403        (t
1404         ;; If the list is to be entered into the newsrc assoc, and
1405         ;; it was killed, we have to create an entry in the newsrc
1406         ;; hashtb format and fix the pointers in the newsrc assoc.
1407         (if (< oldlevel gnus-level-zombie)
1408             ;; It was alive, and it is going to stay alive, so we
1409             ;; just change the level and don't change any pointers or
1410             ;; hash table entries.
1411             (setcar (cdaddr entry) level)
1412           (if (listp entry)
1413               (setq info (cdr entry)
1414                     num (car entry))
1415             (setq active (gnus-active group))
1416             (setq num
1417                   (if active (- (1+ (cdr active)) (car active)) t))
1418             ;; Shorten the select method if possible, if we need to
1419             ;; store it at all (native groups).
1420             (let ((method (gnus-method-simplify
1421                            (or gnus-override-subscribe-method
1422                                (gnus-group-method group)))))
1423               (if method
1424                   (setq info (list group level nil nil method))
1425                 (setq info (list group level nil)))))
1426           (unless previous
1427             (setq previous
1428                   (let ((p gnus-newsrc-alist))
1429                     (while (cddr p)
1430                       (setq p (cdr p)))
1431                     p)))
1432           (setq entry (cons info (cddr previous)))
1433           (if (cdr previous)
1434               (progn
1435                 (setcdr (cdr previous) entry)
1436                 (gnus-sethash group (cons num (cdr previous))
1437                               gnus-newsrc-hashtb))
1438             (setcdr previous entry)
1439             (gnus-sethash group (cons num previous)
1440                           gnus-newsrc-hashtb))
1441           (when (cdr entry)
1442             (setcdr (gnus-group-entry (caadr entry)) entry))
1443           (gnus-dribble-enter
1444            (format
1445             "(gnus-group-set-info '%S)" info)))))
1446       (when gnus-group-change-level-function
1447         (funcall gnus-group-change-level-function
1448                  group level oldlevel previous)))))
1449
1450 (defun gnus-kill-newsgroup (newsgroup)
1451   "Obsolete function.  Kills a newsgroup."
1452   (gnus-group-change-level
1453    (gnus-group-entry newsgroup) gnus-level-killed))
1454
1455 (defun gnus-check-bogus-newsgroups (&optional confirm)
1456   "Remove bogus newsgroups.
1457 If CONFIRM is non-nil, the user has to confirm the deletion of every
1458 newsgroup."
1459   (let ((newsrc (cdr gnus-newsrc-alist))
1460         bogus group entry info)
1461     (gnus-message 5 "Checking bogus newsgroups...")
1462     (unless (gnus-read-active-file-p)
1463       (gnus-read-active-file t))
1464     (when (gnus-read-active-file-p)
1465       ;; Find all bogus newsgroup that are subscribed.
1466       (while newsrc
1467         (setq info (pop newsrc)
1468               group (gnus-info-group info))
1469         (unless (or (gnus-active group) ; Active
1470                     (and (gnus-info-method info)
1471                          (not (gnus-secondary-method-p
1472                                (gnus-info-method info))))) ; Foreign
1473           ;; Found a bogus newsgroup.
1474           (push group bogus)))
1475       (if confirm
1476           (map-y-or-n-p
1477            "Remove bogus group %s? "
1478            (lambda (group)
1479              ;; Remove all bogus subscribed groups by first killing them, and
1480              ;; then removing them from the list of killed groups.
1481              (when (setq entry (gnus-group-entry group))
1482                (gnus-group-change-level entry gnus-level-killed)
1483                (setq gnus-killed-list (delete group gnus-killed-list))))
1484            bogus '("group" "groups" "remove"))
1485         (while (setq group (pop bogus))
1486           ;; Remove all bogus subscribed groups by first killing them, and
1487           ;; then removing them from the list of killed groups.
1488           (when (setq entry (gnus-group-entry group))
1489             (gnus-group-change-level entry gnus-level-killed)
1490             (setq gnus-killed-list (delete group gnus-killed-list)))))
1491       ;; Then we remove all bogus groups from the list of killed and
1492       ;; zombie groups.  They are removed without confirmation.
1493       (let ((dead-lists '(gnus-killed-list gnus-zombie-list))
1494             killed)
1495         (while dead-lists
1496           (setq killed (symbol-value (car dead-lists)))
1497           (while killed
1498             (unless (gnus-active (setq group (pop killed)))
1499               ;; The group is bogus.
1500               ;; !!!Slow as hell.
1501               (set (car dead-lists)
1502                    (delete group (symbol-value (car dead-lists))))))
1503           (setq dead-lists (cdr dead-lists))))
1504       (gnus-run-hooks 'gnus-check-bogus-groups-hook)
1505       (gnus-message 5 "Checking bogus newsgroups...done"))))
1506
1507 (defun gnus-check-duplicate-killed-groups ()
1508   "Remove duplicates from the list of killed groups."
1509   (interactive)
1510   (let ((killed gnus-killed-list))
1511     (while killed
1512       (gnus-message 9 "%d" (length killed))
1513       (setcdr killed (delete (car killed) (cdr killed)))
1514       (setq killed (cdr killed)))))
1515
1516 ;; We want to inline a function from gnus-cache, so we cheat here:
1517 (defvar gnus-cache-active-hashtb)
1518 (eval-when-compile
1519   (defun gnus-cache-possibly-alter-active (group active)
1520     "Alter the ACTIVE info for GROUP to reflect the articles in the cache."
1521     (when gnus-cache-active-hashtb
1522       (let ((cache-active (gnus-gethash group gnus-cache-active-hashtb)))
1523         (when cache-active
1524           (when (< (car cache-active) (car active))
1525             (setcar active (car cache-active)))
1526           (when (> (cdr cache-active) (cdr active))
1527             (setcdr active (cdr cache-active))))))))
1528
1529 (defun gnus-activate-group (group &optional scan dont-check method
1530                                   dont-sub-check)
1531   "Check whether a group has been activated or not.
1532 If SCAN, request a scan of that group as well."
1533   (let ((method (or method (inline (gnus-find-method-for-group group))))
1534         active)
1535     (and (inline (gnus-check-server method))
1536          ;; We escape all bugs and quit here to make it possible to
1537          ;; continue if a group is so out-there that it reports bugs
1538          ;; and stuff.
1539          (progn
1540            (and scan
1541                 (gnus-check-backend-function 'request-scan (car method))
1542                 (gnus-request-scan group method))
1543            t)
1544          (if (or debug-on-error debug-on-quit)
1545              (inline (gnus-request-group group (or dont-sub-check dont-check)
1546                                          method))
1547            (condition-case nil
1548                (inline (gnus-request-group group (or dont-sub-check dont-check)
1549                                            method))
1550              ;;(error nil)
1551              (quit
1552               (message "Quit activating %s" group)
1553               nil)))
1554          (unless dont-check
1555            (setq active (gnus-parse-active))
1556            ;; If there are no articles in the group, the GROUP
1557            ;; command may have responded with the `(0 . 0)'.  We
1558            ;; ignore this if we already have an active entry
1559            ;; for the group.
1560            (if (and (zerop (or (car active) 0))
1561                     (zerop (or (cdr active) 0))
1562                     (gnus-active group))
1563                (gnus-active group)
1564
1565              ;; If a cache is present, we may have to alter the active info.
1566              (when gnus-use-cache
1567                (inline (gnus-cache-possibly-alter-active
1568                         group active)))
1569
1570              ;; If the agent is enabled, we may have to alter the active info.
1571              (when gnus-agent
1572                (gnus-agent-possibly-alter-active group active))
1573
1574              (gnus-set-active group active)
1575              ;; Return the new active info.
1576              active)))))
1577
1578 (defun gnus-get-unread-articles-in-group (info active &optional update)
1579   (when (and info active)
1580     ;; Allow the backend to update the info in the group.
1581     (when (and update
1582                (gnus-request-update-info
1583                 info (inline (gnus-find-method-for-group
1584                               (gnus-info-group info)))))
1585       (gnus-activate-group (gnus-info-group info) nil t))
1586
1587     (let* ((range (gnus-info-read info))
1588            (num 0))
1589
1590       ;; These checks are present in gnus-activate-group but skipped
1591       ;; due to setting dont-check in the preceeding call.
1592
1593       ;; If a cache is present, we may have to alter the active info.
1594       (when (and gnus-use-cache info)
1595         (inline (gnus-cache-possibly-alter-active
1596                  (gnus-info-group info) active)))
1597
1598       ;; If the agent is enabled, we may have to alter the active info.
1599       (when (and gnus-agent info)
1600         (gnus-agent-possibly-alter-active (gnus-info-group info) active info))
1601
1602       ;; Modify the list of read articles according to what articles
1603       ;; are available; then tally the unread articles and add the
1604       ;; number to the group hash table entry.
1605       (cond
1606        ((zerop (cdr active))
1607         (setq num 0))
1608        ((not range)
1609         (setq num (- (1+ (cdr active)) (car active))))
1610        ((not (listp (cdr range)))
1611         ;; Fix a single (num . num) range according to the
1612         ;; active hash table.
1613         ;; Fix by Carsten Bormann <cabo@Informatik.Uni-Bremen.DE>.
1614         (and (< (cdr range) (car active)) (setcdr range (1- (car active))))
1615         (and (> (cdr range) (cdr active)) (setcdr range (cdr active)))
1616         ;; Compute number of unread articles.
1617         (setq num (max 0 (- (cdr active) (- (1+ (cdr range)) (car range))))))
1618        (t
1619         ;; The read list is a list of ranges.  Fix them according to
1620         ;; the active hash table.
1621         ;; First peel off any elements that are below the lower
1622         ;; active limit.
1623         (while (and (cdr range)
1624                     (>= (car active)
1625                         (or (and (atom (cadr range)) (cadr range))
1626                             (caadr range))))
1627           (if (numberp (car range))
1628               (setcar range
1629                       (cons (car range)
1630                             (or (and (numberp (cadr range))
1631                                      (cadr range))
1632                                 (cdadr range))))
1633             (setcdr (car range)
1634                     (or (and (numberp (nth 1 range)) (nth 1 range))
1635                         (cdadr range))))
1636           (setcdr range (cddr range)))
1637         ;; Adjust the first element to be the same as the lower limit.
1638         (when (and (not (atom (car range)))
1639                    (< (cdar range) (car active)))
1640           (setcdr (car range) (1- (car active))))
1641         ;; Then we want to peel off any elements that are higher
1642         ;; than the upper active limit.
1643         (let ((srange range))
1644           ;; Go past all valid elements.
1645           (while (and (cdr srange)
1646                       (<= (or (and (atom (cadr srange))
1647                                    (cadr srange))
1648                               (caadr srange))
1649                           (cdr active)))
1650             (setq srange (cdr srange)))
1651           (when (cdr srange)
1652             ;; Nuke all remaining invalid elements.
1653             (setcdr srange nil))
1654
1655           ;; Adjust the final element.
1656           (when (and (not (atom (car srange)))
1657                      (> (cdar srange) (cdr active)))
1658             (setcdr (car srange) (cdr active))))
1659         ;; Compute the number of unread articles.
1660         (while range
1661           (setq num (+ num (- (1+ (or (and (atom (car range)) (car range))
1662                                       (cdar range)))
1663                               (or (and (atom (car range)) (car range))
1664                                   (caar range)))))
1665           (setq range (cdr range)))
1666         (setq num (max 0 (- (cdr active) num)))))
1667       ;; Set the number of unread articles.
1668       (when (and info
1669                  (gnus-group-entry (gnus-info-group info)))
1670         (setcar (gnus-group-entry (gnus-info-group info)) num))
1671       num)))
1672
1673 ;; Go though `gnus-newsrc-alist' and compare with `gnus-active-hashtb'
1674 ;; and compute how many unread articles there are in each group.
1675 (defun gnus-get-unread-articles (&optional level)
1676   (setq gnus-server-method-cache nil)
1677   (let* ((newsrc (cdr gnus-newsrc-alist))
1678          (alevel (or level gnus-activate-level (1+ gnus-level-subscribed)))
1679          (foreign-level
1680           (min
1681            (cond ((and gnus-activate-foreign-newsgroups
1682                        (not (numberp gnus-activate-foreign-newsgroups)))
1683                   (1+ gnus-level-subscribed))
1684                  ((numberp gnus-activate-foreign-newsgroups)
1685                   gnus-activate-foreign-newsgroups)
1686                  (t 0))
1687            alevel))
1688          (methods-cache nil)
1689          (type-cache nil)
1690          (gnus-agent-article-local-times 0)
1691          (archive-method (gnus-server-to-method "archive"))
1692          infos info group active method cmethod
1693          method-type method-group-list)
1694     (gnus-message 6 "Checking new news...")
1695
1696     (while newsrc
1697       (setq active (gnus-active (setq group (gnus-info-group
1698                                              (setq info (pop newsrc))))))
1699
1700       ;; Check newsgroups.  If the user doesn't want to check them, or
1701       ;; they can't be checked (for instance, if the news server can't
1702       ;; be reached) we just set the number of unread articles in this
1703       ;; newsgroup to t.  This means that Gnus thinks that there are
1704       ;; unread articles, but it has no idea how many.
1705
1706       ;; To be more explicit:
1707       ;; >0 for an active group with messages
1708       ;; 0 for an active group with no unread messages
1709       ;; nil for non-foreign groups that the user has requested not be checked
1710       ;; t for unchecked foreign groups or bogus groups, or groups that can't
1711       ;;   be checked, for one reason or other.
1712
1713       ;; First go through all the groups, see what select methods they
1714       ;; belong to, and then collect them into lists per unique select
1715       ;; method.
1716       (if (not (setq method (gnus-info-method info)))
1717           (setq method gnus-select-method)
1718         (if (setq cmethod (assoc method methods-cache))
1719             (setq method (cdr cmethod))
1720           (setq cmethod (inline (gnus-server-get-method nil method)))
1721           (push (cons method cmethod) methods-cache)
1722           (setq method cmethod)))
1723       (setq method-group-list (assoc method type-cache))
1724       (unless method-group-list
1725         (setq method-type
1726               (cond
1727                ((or (gnus-secondary-method-p method)
1728                     (and (gnus-archive-server-wanted-p)
1729                          (gnus-methods-equal-p archive-method method)))
1730                 'secondary)
1731                ((inline (gnus-server-equal gnus-select-method method))
1732                 'primary)
1733                (t
1734                 'foreign)))
1735         (push (setq method-group-list (list method method-type nil))
1736               type-cache))
1737       ;; Only add groups that need updating.
1738       (when (<= (gnus-info-level info)
1739                 (if (eq (cadr method-group-list) 'foreign)
1740                     foreign-level
1741                   alevel))
1742         (setcar (nthcdr 2 method-group-list)
1743                 (cons info (nth 2 method-group-list)))))
1744
1745     ;; Sort the methods based so that the primary and secondary
1746     ;; methods come first.  This is done for legacy reasons to try to
1747     ;; ensure that side-effect behaviour doesn't change from previous
1748     ;; Gnus versions.
1749     (setq type-cache
1750           (sort (nreverse type-cache)
1751                 (lambda (c1 c2)
1752                   (< (gnus-method-rank (cadr c1) (car c1))
1753                      (gnus-method-rank (cadr c2) (car c2))))))
1754
1755     (while type-cache
1756       (setq method (nth 0 (car type-cache))
1757             method-type (nth 1 (car type-cache))
1758             infos (nth 2 (car type-cache)))
1759       (pop type-cache)
1760
1761       (when (and method
1762                  infos)
1763         ;; See if any of the groups from this method require updating.
1764         (gnus-read-active-for-groups method infos)
1765         (dolist (info infos)
1766           (inline (gnus-get-unread-articles-in-group
1767                    info (gnus-active (gnus-info-group info)))))))
1768     (gnus-message 6 "Checking new news...done")))
1769
1770 (defun gnus-method-rank (type method)
1771   (cond
1772    ;; Get info for virtual groups last.
1773    ((eq (car method) 'nnvirtual)
1774     200)
1775    ((eq type 'primary)
1776     1)
1777    ;; Compute the rank of the secondary methods based on where they
1778    ;; are in the secondary select list.
1779    ((eq type 'secondary)
1780     (let ((i 2))
1781       (block nil
1782         (dolist (smethod gnus-secondary-select-methods)
1783           (when (equal method smethod)
1784             (return i))
1785           (incf i))
1786         i)))
1787    ;; Just say that all foreign groups have the same rank.
1788    (t
1789     100)))
1790
1791 (defun gnus-read-active-for-groups (method infos)
1792   (with-current-buffer nntp-server-buffer
1793     (cond
1794      ((gnus-check-backend-function 'retrieve-groups (car method))
1795       (when (gnus-check-backend-function 'request-scan (car method))
1796         (gnus-request-scan nil method))
1797       (gnus-read-active-file-2
1798        (mapcar (lambda (info)
1799                  (gnus-group-real-name (gnus-info-group info)))
1800                infos)
1801        method))
1802      ((gnus-check-backend-function 'request-list (car method))
1803       (gnus-read-active-file-1 method nil))
1804      (t
1805       (dolist (info infos)
1806         (gnus-activate-group (gnus-info-group info) nil nil method t))))))
1807
1808 ;; Create a hash table out of the newsrc alist.  The `car's of the
1809 ;; alist elements are used as keys.
1810 (defun gnus-make-hashtable-from-newsrc-alist ()
1811   (let ((alist gnus-newsrc-alist)
1812         (ohashtb gnus-newsrc-hashtb)
1813         prev info method rest methods)
1814     (setq gnus-newsrc-hashtb (gnus-make-hashtable (length alist)))
1815     (setq alist
1816           (setq prev (setq gnus-newsrc-alist
1817                            (if (equal (caar gnus-newsrc-alist)
1818                                       "dummy.group")
1819                                gnus-newsrc-alist
1820                              (cons (list "dummy.group" 0 nil) alist)))))
1821     (while alist
1822       (setq info (car alist))
1823       ;; Make the same select-methods identical Lisp objects.
1824       (when (setq method (gnus-info-method info))
1825         (if (setq rest (member method methods))
1826             (gnus-info-set-method info (car rest))
1827           (push method methods)))
1828       ;; Check for duplicates.
1829       (if (gnus-gethash (car info) gnus-newsrc-hashtb)
1830           ;; Remove this entry from the alist.
1831           (setcdr prev (cddr prev))
1832         (gnus-sethash
1833          (car info)
1834          ;; Preserve number of unread articles in groups.
1835          (cons (and ohashtb (car (gnus-gethash (car info) ohashtb)))
1836                prev)
1837          gnus-newsrc-hashtb)
1838         (setq prev alist))
1839       (setq alist (cdr alist)))
1840     ;; Make the same select-methods in `gnus-server-alist' identical
1841     ;; as well.
1842     (while methods
1843       (setq method (pop methods))
1844       (when (setq rest (rassoc method gnus-server-alist))
1845         (setcdr rest method)))))
1846
1847 (defun gnus-make-hashtable-from-killed ()
1848   "Create a hash table from the killed and zombie lists."
1849   (let ((lists '(gnus-killed-list gnus-zombie-list))
1850         list)
1851     (setq gnus-killed-hashtb
1852           (gnus-make-hashtable
1853            (+ (length gnus-killed-list) (length gnus-zombie-list))))
1854     (while lists
1855       (setq list (symbol-value (pop lists)))
1856       (while list
1857         (gnus-sethash (car list) (pop list) gnus-killed-hashtb)))))
1858
1859 (defun gnus-parse-active ()
1860   "Parse active info in the nntp server buffer."
1861   (save-excursion
1862     (set-buffer nntp-server-buffer)
1863     (goto-char (point-min))
1864     ;; Parse the result we got from `gnus-request-group'.
1865     (when (looking-at "[0-9]+ [0-9]+ \\([0-9]+\\) [0-9]+")
1866       (goto-char (match-beginning 1))
1867       (cons (read (current-buffer))
1868             (read (current-buffer))))))
1869
1870 (defun gnus-make-articles-unread (group articles)
1871   "Mark ARTICLES in GROUP as unread."
1872   (let* ((info (nth 2 (or (gnus-group-entry group)
1873                           (gnus-group-entry
1874                            (gnus-group-real-name group)))))
1875          (ranges (gnus-info-read info))
1876          news article)
1877     (while articles
1878       (when (gnus-member-of-range
1879              (setq article (pop articles)) ranges)
1880         (push article news)))
1881     (when news
1882       ;; Enter this list into the group info.
1883       (gnus-info-set-read
1884        info (gnus-remove-from-range (gnus-info-read info) (nreverse news)))
1885
1886       ;; Set the number of unread articles in gnus-newsrc-hashtb.
1887       (gnus-get-unread-articles-in-group info (gnus-active group))
1888
1889       ;; Insert the change into the group buffer and the dribble file.
1890       (gnus-group-update-group group t))))
1891
1892 (defun gnus-make-ascending-articles-unread (group articles)
1893   "Mark ascending ARTICLES in GROUP as unread."
1894   (let* ((entry (or (gnus-group-entry group)
1895                     (gnus-group-entry (gnus-group-real-name group))))
1896          (info (nth 2 entry))
1897          (ranges (gnus-info-read info))
1898          (r ranges)
1899          modified)
1900
1901     (while articles
1902       (let ((article (pop articles))) ; get the next article to remove from ranges
1903         (while (let ((range (car ranges))) ; note the current range
1904                  (if (atom range)       ; single value range
1905                      (cond ((not range)
1906                             ;; the articles extend past the end of the ranges
1907                             ;; OK - I'm done
1908                             (setq articles nil))
1909                            ((< range article)
1910                             ;; this range preceeds the article. Leave the range unmodified.
1911                             (pop ranges)
1912                             ranges)
1913                            ((= range article)
1914                             ;; this range exactly matches the article; REMOVE THE RANGE.
1915                             ;; NOTE: When the range being removed is the last range, the list is corrupted by inserting null at its end.
1916                             (setcar ranges (cadr ranges))
1917                             (setcdr ranges (cddr ranges))
1918                             (setq modified (if (car ranges) t 'remove-null))
1919                             nil))
1920                    (let ((min (car range))
1921                          (max (cdr range)))
1922                      ;; I have a min/max range to consider
1923                      (cond ((> min max) ; invalid range introduced by splitter
1924                             (setcar ranges (cadr ranges))
1925                             (setcdr ranges (cddr ranges))
1926                             (setq modified (if (car ranges) t 'remove-null))
1927                             ranges)
1928                            ((= min max)
1929                             ;; replace min/max range with a single-value range
1930                             (setcar ranges min)
1931                             ranges)
1932                            ((< max article)
1933                             ;; this range preceeds the article. Leave the range unmodified.
1934                             (pop ranges)
1935                             ranges)
1936                            ((< article min)
1937                             ;; this article preceeds the range.  Return null to move to the
1938                             ;; next article
1939                             nil)
1940                            (t
1941                             ;; this article splits the range into two parts
1942                             (setcdr ranges (cons (cons (1+ article) max) (cdr ranges)))
1943                             (setcdr range (1- article))
1944                             (setq modified t)
1945                             ranges))))))))
1946
1947     (when modified
1948       (when (eq modified 'remove-null)
1949         (setq r (delq nil r)))
1950       ;; Enter this list into the group info.
1951       (gnus-info-set-read info r)
1952
1953       ;; Set the number of unread articles in gnus-newsrc-hashtb.
1954       (gnus-get-unread-articles-in-group info (gnus-active group))
1955
1956       ;; Insert the change into the group buffer and the dribble file.
1957       (gnus-group-update-group group t))))
1958
1959 ;; Enter all dead groups into the hashtb.
1960 (defun gnus-update-active-hashtb-from-killed ()
1961   (let ((hashtb (setq gnus-active-hashtb (gnus-make-hashtable 4096)))
1962         (lists (list gnus-killed-list gnus-zombie-list))
1963         killed)
1964     (while lists
1965       (setq killed (car lists))
1966       (while killed
1967         (gnus-sethash (mm-string-as-unibyte (car killed)) nil hashtb)
1968         (setq killed (cdr killed)))
1969       (setq lists (cdr lists)))))
1970
1971 (defun gnus-get-killed-groups ()
1972   "Go through the active hashtb and mark all unknown groups as killed."
1973   ;; First make sure active file has been read.
1974   (unless (gnus-read-active-file-p)
1975     (let ((gnus-read-active-file t))
1976       (gnus-read-active-file)))
1977   (unless gnus-killed-hashtb
1978     (gnus-make-hashtable-from-killed))
1979   ;; Go through all newsgroups that are known to Gnus - enlarge kill list.
1980   (mapatoms
1981    (lambda (sym)
1982      (let ((groups 0)
1983            (group (symbol-name sym)))
1984        (if (or (null group)
1985                (gnus-gethash group gnus-killed-hashtb)
1986                (gnus-gethash group gnus-newsrc-hashtb))
1987            ()
1988          (let ((do-sub (gnus-matches-options-n group)))
1989            (if (or (eq do-sub 'subscribe) (eq do-sub 'ignore))
1990                ()
1991              (setq groups (1+ groups))
1992              (push group gnus-killed-list)
1993              (gnus-sethash group group gnus-killed-hashtb))))))
1994    gnus-active-hashtb)
1995   (gnus-dribble-touch))
1996
1997 ;; Get the active file(s) from the backend(s).
1998 (defun gnus-read-active-file (&optional force not-native)
1999   (gnus-group-set-mode-line)
2000   (let ((methods
2001          (mapcar
2002           (lambda (m) (if (stringp m) (gnus-server-get-method nil m) m))
2003           (append
2004            (if (and (not not-native)
2005                     (gnus-check-server gnus-select-method))
2006                ;; The native server is available.
2007                (cons gnus-select-method gnus-secondary-select-methods)
2008              ;; The native server is down, so we just do the
2009              ;; secondary ones.
2010              gnus-secondary-select-methods)
2011            ;; Also read from the archive server.
2012            (when (gnus-archive-server-wanted-p)
2013              (list "archive")))))
2014         method)
2015     (setq gnus-have-read-active-file nil)
2016     (save-excursion
2017       (set-buffer nntp-server-buffer)
2018       (while (setq method (pop methods))
2019         ;; Only do each method once, in case the methods appear more
2020         ;; than once in this list.
2021         (unless (member method methods)
2022           (if (or debug-on-error debug-on-quit)
2023               (gnus-read-active-file-1 method force)
2024             (condition-case ()
2025                 (gnus-read-active-file-1 method force)
2026               ;; We catch C-g so that we can continue past servers
2027               ;; that do not respond.
2028               (quit
2029                (message "Quit reading the active file")
2030                nil))))))))
2031
2032 (defun gnus-read-active-file-1 (method force)
2033   (let (where mesg)
2034     (setq where (nth 1 method)
2035           mesg (format "Reading active file%s via %s..."
2036                        (if (and where (not (zerop (length where))))
2037                            (concat " from " where) "")
2038                        (car method)))
2039     (gnus-message 5 mesg)
2040     (when (gnus-check-server method)
2041       ;; Request that the backend scan its incoming messages.
2042       (when (and gnus-agent
2043                  (gnus-online method)
2044                  (gnus-check-backend-function 'request-scan (car method)))
2045         (gnus-request-scan nil method))
2046       (cond
2047        ((and (eq gnus-read-active-file 'some)
2048              (gnus-check-backend-function 'retrieve-groups (car method))
2049              (not force))
2050         (let ((newsrc (cdr gnus-newsrc-alist))
2051               (gmethod (gnus-server-get-method nil method))
2052               groups info)
2053           (while (setq info (pop newsrc))
2054             (when (inline
2055                     (gnus-server-equal
2056                           (inline
2057                             (gnus-find-method-for-group
2058                                   (gnus-info-group info) info))
2059                           gmethod))
2060               (push (gnus-group-real-name (gnus-info-group info))
2061                     groups)))
2062           (gnus-read-active-file-2 groups method)))
2063        ((null method)
2064         t)
2065        (t
2066         (if (not (gnus-request-list method))
2067             (unless (equal method gnus-message-archive-method)
2068               (gnus-error 1 "Cannot read active file from %s server"
2069                           (car method)))
2070           (gnus-message 5 mesg)
2071           (gnus-active-to-gnus-format method gnus-active-hashtb nil t)
2072           ;; We mark this active file as read.
2073           (push method gnus-have-read-active-file)
2074           (gnus-message 5 "%sdone" mesg)))))))
2075
2076 (defun gnus-read-active-file-2 (groups method)
2077   "Read an active file for GROUPS in METHOD using `gnus-retrieve-groups'."
2078   (when groups
2079     (save-excursion
2080       (set-buffer nntp-server-buffer)
2081       (gnus-check-server method)
2082       (let ((list-type (gnus-retrieve-groups groups method)))
2083         (cond ((not list-type)
2084                (gnus-error
2085                 1.2 "Cannot read partial active file from %s server."
2086                 (car method)))
2087               ((eq list-type 'active)
2088                (gnus-active-to-gnus-format method gnus-active-hashtb nil t))
2089               (t
2090                (gnus-groups-to-gnus-format method gnus-active-hashtb t)))))))
2091
2092 ;; Read an active file and place the results in `gnus-active-hashtb'.
2093 (defun gnus-active-to-gnus-format (&optional method hashtb ignore-errors
2094                                              real-active)
2095   (unless method
2096     (setq method gnus-select-method))
2097   (let ((cur (current-buffer))
2098         (hashtb (or hashtb
2099                     (if (and gnus-active-hashtb
2100                              (not (equal method gnus-select-method)))
2101                         gnus-active-hashtb
2102                       (setq gnus-active-hashtb
2103                             (if (equal method gnus-select-method)
2104                                 (gnus-make-hashtable
2105                                  (count-lines (point-min) (point-max)))
2106                               (gnus-make-hashtable 4096))))))
2107         group max min)
2108     ;; Delete unnecessary lines.
2109     (goto-char (point-min))
2110     (cond
2111      ((string= gnus-ignored-newsgroups "")
2112       (delete-matching-lines "^to\\."))
2113      (t
2114       (delete-matching-lines (concat "^to\\.\\|" gnus-ignored-newsgroups))))
2115
2116     (goto-char (point-min))
2117     (unless (re-search-forward "[\\\"]" nil t)
2118       ;; Make the group names readable as a lisp expression even if they
2119       ;; contain special characters.
2120       (goto-char (point-max))
2121       (while (re-search-backward "[][';?()#]" nil t)
2122         (insert ?\\)))
2123
2124     ;; Let the Gnus agent save the active file.
2125     (when (and gnus-agent real-active (gnus-online method))
2126       (gnus-agent-save-active method))
2127
2128     ;; If these are groups from a foreign select method, we insert the
2129     ;; group prefix in front of the group names.
2130     (when (not (gnus-server-equal
2131                 (gnus-server-get-method nil method)
2132                 (gnus-server-get-method nil gnus-select-method)))
2133       (let ((prefix (gnus-group-prefixed-name "" method)))
2134         (goto-char (point-min))
2135         (while (and (not (eobp))
2136                     (progn
2137                       (when (= (following-char) ?\")
2138                         (forward-char 1))
2139                       (insert prefix)
2140                       (zerop (forward-line 1)))))))
2141     ;; Store the active file in a hash table.
2142     ;; Use a unibyte buffer in order to make `read' read non-ASCII
2143     ;; group names (which have been encoded) as unibyte strings.
2144     (mm-with-unibyte-buffer
2145       (insert-buffer-substring cur)
2146       (setq cur (current-buffer))
2147       (goto-char (point-min))
2148       (while (not (eobp))
2149         (condition-case ()
2150             (progn
2151               (narrow-to-region (point) (point-at-eol))
2152               ;; group gets set to a symbol interned in the hash table
2153               ;; (what a hack!!) - jwz
2154               (setq group (let ((obarray hashtb)) (read cur)))
2155               ;; ### The extended group name scheme makes
2156               ;; the previous optimization strategy sort of pointless...
2157               (when (stringp group)
2158                 (setq group (intern group hashtb)))
2159               (if (and (numberp (setq max (read cur)))
2160                        (numberp (setq min (read cur)))
2161                        (progn
2162                          (skip-chars-forward " \t")
2163                          (not
2164                           (or (eq (char-after) ?=)
2165                               (eq (char-after) ?x)
2166                               (eq (char-after) ?j)))))
2167                   (progn
2168                     (set group (cons min max))
2169                     ;; if group is moderated, stick in moderation table
2170                     (when (eq (char-after) ?m)
2171                       (unless gnus-moderated-hashtb
2172                         (setq gnus-moderated-hashtb (gnus-make-hashtable)))
2173                       (gnus-sethash (symbol-name group) t
2174                                     gnus-moderated-hashtb)))
2175                 (set group nil)))
2176           (error
2177            (and group
2178                 (symbolp group)
2179                 (set group nil))
2180            (unless ignore-errors
2181              (gnus-message 3 "Warning - invalid active: %s"
2182                            (buffer-substring
2183                             (point-at-bol) (point-at-eol))))))
2184         (widen)
2185         (forward-line 1)))))
2186
2187 (defun gnus-groups-to-gnus-format (method &optional hashtb real-active)
2188   ;; Parse a "groups" active file.
2189   (let ((cur (current-buffer))
2190         (hashtb (or hashtb
2191                     (if (and method gnus-active-hashtb)
2192                         gnus-active-hashtb
2193                       (setq gnus-active-hashtb
2194                             (gnus-make-hashtable
2195                              (count-lines (point-min) (point-max)))))))
2196         (prefix (and method
2197                      (not (gnus-server-equal
2198                            (gnus-server-get-method nil method)
2199                            (gnus-server-get-method nil gnus-select-method)))
2200                      (gnus-group-prefixed-name "" method))))
2201
2202     ;; Let the Gnus agent save the active file.
2203     (if (and gnus-agent
2204              real-active
2205              (gnus-online method)
2206              (gnus-agent-method-p method))
2207         (progn
2208           (gnus-agent-save-active method)
2209           (gnus-active-to-gnus-format method hashtb nil real-active))
2210
2211       (goto-char (point-min))
2212       ;; We split this into to separate loops, one with the prefix
2213       ;; and one without to speed the reading up somewhat.
2214       (if prefix
2215           (let (min max opoint group)
2216             (while (not (eobp))
2217               (condition-case ()
2218                   (progn
2219                     (read cur) (read cur)
2220                     (setq min (read cur)
2221                           max (read cur)
2222                           opoint (point))
2223                     (skip-chars-forward " \t")
2224                     (insert prefix)
2225                     (goto-char opoint)
2226                     (set (let ((obarray hashtb)) (read cur))
2227                          (cons min max)))
2228                 (error (and group (symbolp group) (set group nil))))
2229               (forward-line 1)))
2230         (let (min max group)
2231           (while (not (eobp))
2232             (condition-case ()
2233                 (when (eq (char-after) ?2)
2234                   (read cur) (read cur)
2235                   (setq min (read cur)
2236                         max (read cur))
2237                   (set (setq group (let ((obarray hashtb)) (read cur)))
2238                        (cons min max)))
2239               (error (and group (symbolp group) (set group nil))))
2240             (forward-line 1)))))))
2241
2242 (defun gnus-read-newsrc-file (&optional force)
2243   "Read startup file.
2244 If FORCE is non-nil, the .newsrc file is read."
2245   ;; Reset variables that might be defined in the .newsrc.eld file.
2246   (let ((variables (remove 'gnus-format-specs gnus-variable-list)))
2247     (while variables
2248       (set (car variables) nil)
2249       (setq variables (cdr variables))))
2250   (let* ((newsrc-file gnus-current-startup-file)
2251          (quick-file (concat newsrc-file ".el")))
2252     (save-excursion
2253       ;; We always load the .newsrc.eld file.  If always contains
2254       ;; much information that can not be gotten from the .newsrc
2255       ;; file (ticked articles, killed groups, foreign methods, etc.)
2256       (gnus-read-newsrc-el-file quick-file)
2257
2258       (when (and gnus-read-newsrc-file
2259                  (file-exists-p gnus-current-startup-file)
2260                  (or force
2261                      (and (file-newer-than-file-p newsrc-file quick-file)
2262                           (file-newer-than-file-p newsrc-file
2263                                                   (concat quick-file "d")))
2264                      (not gnus-newsrc-alist)))
2265         ;; We read the .newsrc file.  Note that if there if a
2266         ;; .newsrc.eld file exists, it has already been read, and
2267         ;; the `gnus-newsrc-hashtb' has been created.  While reading
2268         ;; the .newsrc file, Gnus will only use the information it
2269         ;; can find there for changing the data already read -
2270         ;; i. e., reading the .newsrc file will not trash the data
2271         ;; already read (except for read articles).
2272         (save-excursion
2273           (gnus-message 5 "Reading %s..." newsrc-file)
2274           (set-buffer (nnheader-find-file-noselect newsrc-file))
2275           (buffer-disable-undo)
2276           (gnus-newsrc-to-gnus-format)
2277           (kill-buffer (current-buffer))
2278           (gnus-message 5 "Reading %s...done" newsrc-file)))
2279
2280       ;; Convert old to new.
2281       (gnus-convert-old-newsrc))))
2282
2283 (defun gnus-convert-old-newsrc ()
2284   "Convert old newsrc formats into the current format, if needed."
2285   (let ((fcv (and gnus-newsrc-file-version
2286                   (gnus-continuum-version gnus-newsrc-file-version)))
2287         (gcv (gnus-continuum-version)))
2288     (when fcv
2289       ;; A newsrc file was loaded.
2290       (let (prompt-displayed
2291             (converters
2292              (sort
2293               (mapcar (lambda (date-func)
2294                         (cons (gnus-continuum-version (car date-func))
2295                               date-func))
2296                       ;; This is a list of converters that must be run
2297                       ;; to bring the newsrc file up to the current
2298                       ;; version.  If you create an incompatibility
2299                       ;; with older versions, you should create an
2300                       ;; entry here.  The entry should consist of the
2301                       ;; current gnus version (hardcoded so that it
2302                       ;; doesn't change with each release) and the
2303                       ;; function that must be applied to convert the
2304                       ;; previous version into the current version.
2305                       '(("September Gnus v0.1" nil
2306                          gnus-convert-old-ticks)
2307                         ("Oort Gnus v0.08"     "legacy-gnus-agent"
2308                          gnus-agent-convert-to-compressed-agentview)
2309                         ("Gnus v5.10.7"        "legacy-gnus-agent"
2310                          gnus-agent-unlist-expire-days)
2311                         ("Gnus v5.10.7"        "legacy-gnus-agent"
2312                          gnus-agent-unhook-expire-days)))
2313               #'car-less-than-car)))
2314         ;; Skip converters older than the file version
2315         (while (and converters (>= fcv (caar converters)))
2316           (pop converters))
2317
2318         ;; Perform converters to bring older version up to date.
2319         (when (and converters (< fcv (caar converters)))
2320           (while (and converters (< fcv (caar converters))
2321                       (<= (caar converters) gcv))
2322             (let* ((converter-spec  (pop converters))
2323                    (convert-to      (nth 1 converter-spec))
2324                    (load-from       (nth 2 converter-spec))
2325                    (func            (nth 3 converter-spec)))
2326               (when (and load-from
2327                          (not (fboundp func)))
2328                 (load load-from t))
2329               (or prompt-displayed
2330                   (not (gnus-convert-converter-needs-prompt func))
2331                   (while (let (c
2332                                (cursor-in-echo-area t)
2333                                (echo-keystrokes 0))
2334                            (message "Convert gnus from version '%s' to '%s'? (n/y/?)"
2335                                     gnus-newsrc-file-version gnus-version)
2336                            (setq c (read-char-exclusive))
2337
2338                            (cond ((or (eq c ?n) (eq c ?N))
2339                                   (error "Can not start gnus without converting"))
2340                                  ((or (eq c ?y) (eq c ?Y))
2341                                   (setq prompt-displayed t)
2342                                   nil)
2343                                  ((eq c ?\?)
2344                                   (message "This conversion is irreversible. \
2345  To be safe, you should backup your files before proceeding.")
2346                                   (sit-for 5)
2347                                   t)
2348                                  (t
2349                                   (gnus-message 3 "Ignoring unexpected input")
2350                                   (sit-for 3)
2351                                   t)))))
2352
2353               (funcall func convert-to)))
2354           (gnus-dribble-enter
2355            (format ";Converted gnus from version '%s' to '%s'."
2356                    gnus-newsrc-file-version gnus-version)))))))
2357
2358 (defun gnus-convert-mark-converter-prompt (converter no-prompt)
2359   "Indicate whether CONVERTER requires gnus-convert-old-newsrc to
2360   display the conversion prompt.  NO-PROMPT may be nil (prompt),
2361   t (no prompt), or any form that can be called as a function.
2362   The form should return either t or nil."
2363   (put converter 'gnus-convert-no-prompt no-prompt))
2364
2365 (defun gnus-convert-converter-needs-prompt (converter)
2366   (let ((no-prompt (get converter 'gnus-convert-no-prompt)))
2367     (not (if (memq no-prompt '(t nil))
2368              no-prompt
2369            (funcall no-prompt)))))
2370
2371 (defun gnus-convert-old-ticks (converting-to)
2372   (let ((newsrc (cdr gnus-newsrc-alist))
2373         marks info dormant ticked)
2374     (while (setq info (pop newsrc))
2375       (when (setq marks (gnus-info-marks info))
2376         (setq dormant (cdr (assq 'dormant marks))
2377               ticked (cdr (assq 'tick marks)))
2378         (when (or dormant ticked)
2379           (gnus-info-set-read
2380            info
2381            (gnus-add-to-range
2382             (gnus-info-read info)
2383             (nconc (gnus-uncompress-range dormant)
2384                    (gnus-uncompress-range ticked)))))))))
2385
2386 (defun gnus-load (file)
2387   "Load FILE, but in such a way that read errors can be reported."
2388   (with-temp-buffer
2389     (insert-file-contents file)
2390     (while (not (eobp))
2391       (condition-case type
2392           (let ((form (read (current-buffer))))
2393             (eval form))
2394         (error
2395          (unless (eq (car type) 'end-of-file)
2396            (let ((errmsg (format "Error in %s line %d" file
2397                                  (count-lines (point-min) (point)))))
2398              (ding)
2399              (unless (gnus-yes-or-no-p (concat errmsg "; continue? "))
2400                (error "%s" errmsg)))))))))
2401
2402 (defun gnus-read-newsrc-el-file (file)
2403   (let ((ding-file (concat file "d")))
2404     (when (file-exists-p ding-file)
2405       ;; We always, always read the .eld file.
2406       (gnus-message 5 "Reading %s..." ding-file)
2407       (let (gnus-newsrc-assoc)
2408         (gnus-load ding-file)
2409         ;; Older versions of `gnus-format-specs' are no longer valid
2410         ;; in Oort Gnus 0.01.
2411         (let ((version
2412                (and gnus-newsrc-file-version
2413                     (gnus-continuum-version gnus-newsrc-file-version))))
2414           (when (or (not version)
2415                     (< version 5.090009))
2416             (setq gnus-format-specs gnus-default-format-specs)))
2417         (when gnus-newsrc-assoc
2418           (setq gnus-newsrc-alist gnus-newsrc-assoc))))
2419     (dolist (elem gnus-newsrc-alist)
2420       (setcar elem (mm-string-as-unibyte (car elem))))
2421     (gnus-make-hashtable-from-newsrc-alist)
2422     (when (file-newer-than-file-p file ding-file)
2423       ;; Old format quick file
2424       (gnus-message 5 "Reading %s..." file)
2425       ;; The .el file is newer than the .eld file, so we read that one
2426       ;; as well.
2427       (gnus-read-old-newsrc-el-file file)))
2428   (gnus-run-hooks 'gnus-read-newsrc-el-hook))
2429
2430 ;; Parse the old-style quick startup file
2431 (defun gnus-read-old-newsrc-el-file (file)
2432   (let (newsrc killed marked group m info)
2433     (prog1
2434         (let ((gnus-killed-assoc nil)
2435               gnus-marked-assoc gnus-newsrc-alist gnus-newsrc-assoc)
2436           (prog1
2437               (ignore-errors
2438                 (load file t t t))
2439             (setq newsrc gnus-newsrc-assoc
2440                   killed gnus-killed-assoc
2441                   marked gnus-marked-assoc)))
2442       (setq gnus-newsrc-alist nil)
2443       (while (setq group (pop newsrc))
2444         (if (setq info (gnus-get-info (car group)))
2445             (progn
2446               (gnus-info-set-read info (cddr group))
2447               (gnus-info-set-level
2448                info (if (nth 1 group) gnus-level-default-subscribed
2449                       gnus-level-default-unsubscribed))
2450               (push info gnus-newsrc-alist))
2451           (push (setq info
2452                       (list (car group)
2453                             (if (nth 1 group) gnus-level-default-subscribed
2454                               gnus-level-default-unsubscribed)
2455                             (cddr group)))
2456                 gnus-newsrc-alist))
2457         ;; Copy marks into info.
2458         (when (setq m (assoc (car group) marked))
2459           (unless (nthcdr 3 info)
2460             (nconc info (list nil)))
2461           (gnus-info-set-marks
2462            info (list (cons 'tick (gnus-compress-sequence
2463                                    (sort (cdr m) '<) t))))))
2464       (setq newsrc killed)
2465       (while newsrc
2466         (setcar newsrc (caar newsrc))
2467         (setq newsrc (cdr newsrc)))
2468       (setq gnus-killed-list killed))
2469     ;; The .el file version of this variable does not begin with
2470     ;; "options", while the .eld version does, so we just add it if it
2471     ;; isn't there.
2472     (when
2473         gnus-newsrc-options
2474       (when (not (string-match "^ *options" gnus-newsrc-options))
2475         (setq gnus-newsrc-options (concat "options " gnus-newsrc-options)))
2476       (when (not (string-match "\n$" gnus-newsrc-options))
2477         (setq gnus-newsrc-options (concat gnus-newsrc-options "\n")))
2478       ;; Finally, if we read some options lines, we parse them.
2479       (unless (string= gnus-newsrc-options "")
2480         (gnus-newsrc-parse-options gnus-newsrc-options)))
2481
2482     (setq gnus-newsrc-alist (nreverse gnus-newsrc-alist))
2483     (gnus-make-hashtable-from-newsrc-alist)))
2484
2485 (defun gnus-make-newsrc-file (file)
2486   "Make server dependent file name by catenating FILE and server host name."
2487   (let* ((file (expand-file-name file nil))
2488          (real-file (concat file "-" (nth 1 gnus-select-method))))
2489     (if (or (file-exists-p real-file)
2490             (file-exists-p (concat real-file ".el"))
2491             (file-exists-p (concat real-file ".eld")))
2492         real-file
2493       file)))
2494
2495 (defun gnus-newsrc-to-gnus-format ()
2496   (setq gnus-newsrc-options "")
2497   (setq gnus-newsrc-options-n nil)
2498
2499   (unless gnus-active-hashtb
2500     (setq gnus-active-hashtb (gnus-make-hashtable 4096)))
2501   (let ((buf (current-buffer))
2502         (already-read (> (length gnus-newsrc-alist) 1))
2503         group subscribed options-symbol newsrc Options-symbol
2504         symbol reads num1)
2505     (goto-char (point-min))
2506     ;; We intern the symbol `options' in the active hashtb so that we
2507     ;; can `eq' against it later.
2508     (set (setq options-symbol (intern "options" gnus-active-hashtb)) nil)
2509     (set (setq Options-symbol (intern "Options" gnus-active-hashtb)) nil)
2510
2511     (while (not (eobp))
2512       ;; We first read the first word on the line by narrowing and
2513       ;; then reading into `gnus-active-hashtb'.  Most groups will
2514       ;; already exist in that hashtb, so this will save some string
2515       ;; space.
2516       (narrow-to-region
2517        (point)
2518        (progn (skip-chars-forward "^ \t!:\n") (point)))
2519       (goto-char (point-min))
2520       (setq symbol
2521             (and (/= (point-min) (point-max))
2522                  (let ((obarray gnus-active-hashtb)) (read buf))))
2523       (widen)
2524       ;; Now, the symbol we have read is either `options' or a group
2525       ;; name.  If it is an options line, we just add it to a string.
2526       (cond
2527        ((or (eq symbol options-symbol)
2528             (eq symbol Options-symbol))
2529         (setq gnus-newsrc-options
2530               ;; This concating is quite inefficient, but since our
2531               ;; thorough studies show that approx 99.37% of all
2532               ;; .newsrc files only contain a single options line, we
2533               ;; don't give a damn, frankly, my dear.
2534               (concat gnus-newsrc-options
2535                       (buffer-substring
2536                        (point-at-bol)
2537                        ;; Options may continue on the next line.
2538                        (or (and (re-search-forward "^[^ \t]" nil 'move)
2539                                 (point-at-bol))
2540                            (point)))))
2541         (forward-line -1))
2542        (symbol
2543         ;; Group names can be just numbers.
2544         (when (numberp symbol)
2545           (setq symbol (intern (int-to-string symbol) gnus-active-hashtb)))
2546         (unless (boundp symbol)
2547           (set symbol nil))
2548         ;; It was a group name.
2549         (setq subscribed (eq (char-after) ?:)
2550               group (symbol-name symbol)
2551               reads nil)
2552         (if (eolp)
2553             ;; If the line ends here, this is clearly a buggy line, so
2554             ;; we put point a the beginning of line and let the cond
2555             ;; below do the error handling.
2556             (beginning-of-line)
2557           ;; We skip to the beginning of the ranges.
2558           (skip-chars-forward "!: \t"))
2559         ;; We are now at the beginning of the list of read articles.
2560         ;; We read them range by range.
2561         (while
2562             (cond
2563              ((looking-at "[0-9]+")
2564               ;; We narrow and read a number instead of buffer-substring/
2565               ;; string-to-number because it's faster.  narrow/widen is
2566               ;; faster than save-restriction/narrow, and save-restriction
2567               ;; produces a garbage object.
2568               (setq num1 (progn
2569                            (narrow-to-region (match-beginning 0) (match-end 0))
2570                            (read buf)))
2571               (widen)
2572               ;; If the next character is a dash, then this is a range.
2573               (if (eq (char-after) ?-)
2574                   (progn
2575                     ;; We read the upper bound of the range.
2576                     (forward-char 1)
2577                     (if (not (looking-at "[0-9]+"))
2578                         ;; This is a buggy line, by we pretend that
2579                         ;; it's kinda OK.  Perhaps the user should be
2580                         ;; dinged?
2581                         (push num1 reads)
2582                       (push
2583                        (cons num1
2584                              (progn
2585                                (narrow-to-region (match-beginning 0)
2586                                                  (match-end 0))
2587                                (read buf)))
2588                        reads)
2589                       (widen)))
2590                 ;; It was just a simple number, so we add it to the
2591                 ;; list of ranges.
2592                 (push num1 reads))
2593               ;; If the next char in ?\n, then we have reached the end
2594               ;; of the line and return nil.
2595               (not (eq (char-after) ?\n)))
2596              ((eq (char-after) ?\n)
2597               ;; End of line, so we end.
2598               nil)
2599              (t
2600               ;; Not numbers and not eol, so this might be a buggy
2601               ;; line...
2602               (unless (eobp)
2603                 ;; If it was eob instead of ?\n, we allow it.
2604                 ;; The line was buggy.
2605                 (setq group nil)
2606                 (gnus-error 3.1 "Mangled line: %s"
2607                             (buffer-substring (point-at-bol)
2608                                               (point-at-eol))))
2609               nil))
2610           ;; Skip past ", ".  Spaces are invalid in these ranges, but
2611           ;; we allow them, because it's a common mistake to put a
2612           ;; space after the comma.
2613           (skip-chars-forward ", "))
2614
2615         ;; We have already read .newsrc.eld, so we gently update the
2616         ;; data in the hash table with the information we have just
2617         ;; read.
2618         (when group
2619           (let ((info (gnus-get-info group))
2620                 level)
2621             (if info
2622                 ;; There is an entry for this file in the alist.
2623                 (progn
2624                   (gnus-info-set-read info (nreverse reads))
2625                   ;; We update the level very gently.  In fact, we
2626                   ;; only change it if there's been a status change
2627                   ;; from subscribed to unsubscribed, or vice versa.
2628                   (setq level (gnus-info-level info))
2629                   (cond ((and (<= level gnus-level-subscribed)
2630                               (not subscribed))
2631                          (setq level (if reads
2632                                          gnus-level-default-unsubscribed
2633                                        (1+ gnus-level-default-unsubscribed))))
2634                         ((and (> level gnus-level-subscribed) subscribed)
2635                          (setq level gnus-level-default-subscribed)))
2636                   (gnus-info-set-level info level))
2637               ;; This is a new group.
2638               (setq info (list group
2639                                (if subscribed
2640                                    gnus-level-default-subscribed
2641                                  (if reads
2642                                      (1+ gnus-level-subscribed)
2643                                    gnus-level-default-unsubscribed))
2644                                (nreverse reads))))
2645             (push info newsrc)))))
2646       (forward-line 1))
2647
2648     (setq newsrc (nreverse newsrc))
2649
2650     (if (not already-read)
2651         ()
2652       ;; We now have two newsrc lists - `newsrc', which is what we
2653       ;; have read from .newsrc, and `gnus-newsrc-alist', which is
2654       ;; what we've read from .newsrc.eld.  We have to merge these
2655       ;; lists.  We do this by "attaching" any (foreign) groups in the
2656       ;; gnus-newsrc-alist to the (native) group that precedes them.
2657       (let ((rc (cdr gnus-newsrc-alist))
2658             (prev gnus-newsrc-alist)
2659             entry mentry)
2660         (while rc
2661           (or (null (nth 4 (car rc)))   ; It's a native group.
2662               (assoc (caar rc) newsrc)  ; It's already in the alist.
2663               (if (setq entry (assoc (caar prev) newsrc))
2664                   (setcdr (setq mentry (memq entry newsrc))
2665                           (cons (car rc) (cdr mentry)))
2666                 (push (car rc) newsrc)))
2667           (setq prev rc
2668                 rc (cdr rc)))))
2669
2670     (setq gnus-newsrc-alist newsrc)
2671     ;; We make the newsrc hashtb.
2672     (gnus-make-hashtable-from-newsrc-alist)
2673
2674     ;; Finally, if we read some options lines, we parse them.
2675     (unless (string= gnus-newsrc-options "")
2676       (gnus-newsrc-parse-options gnus-newsrc-options))))
2677
2678 ;; Parse options lines to find "options -n !all rec.all" and stuff.
2679 ;; The return value will be a list on the form
2680 ;; ((regexp1 . ignore)
2681 ;;  (regexp2 . subscribe)...)
2682 ;; When handling new newsgroups, groups that match a `ignore' regexp
2683 ;; will be ignored, and groups that match a `subscribe' regexp will be
2684 ;; subscribed.  A line like
2685 ;; options -n !all rec.all
2686 ;; will lead to a list that looks like
2687 ;; (("^rec\\..+" . subscribe)
2688 ;;  ("^.+" . ignore))
2689 ;; So all "rec.*" groups will be subscribed, while all the other
2690 ;; groups will be ignored.  Note that "options -n !all rec.all" is very
2691 ;; different from "options -n rec.all !all".
2692 (defun gnus-newsrc-parse-options (options)
2693   (let (out eol)
2694     (save-excursion
2695       (gnus-set-work-buffer)
2696       (insert (regexp-quote options))
2697       ;; First we treat all continuation lines.
2698       (goto-char (point-min))
2699       (while (re-search-forward "\n[ \t]+" nil t)
2700         (replace-match " " t t))
2701       ;; Then we transform all "all"s into ".+"s.
2702       (goto-char (point-min))
2703       (while (re-search-forward "\\ball\\b" nil t)
2704         (replace-match ".+" t t))
2705       (goto-char (point-min))
2706       ;; We remove all other options than the "-n" ones.
2707       (while (re-search-forward "[ \t]-[^n][^-]*" nil t)
2708         (replace-match " ")
2709         (forward-char -1))
2710       (goto-char (point-min))
2711
2712       ;; We are only interested in "options -n" lines - we
2713       ;; ignore the other option lines.
2714       (while (re-search-forward "[ \t]-n" nil t)
2715         (setq eol
2716               (or (save-excursion
2717                     (and (re-search-forward "[ \t]-n" (point-at-eol) t)
2718                          (- (point) 2)))
2719                   (point-at-eol)))
2720         ;; Search for all "words"...
2721         (while (re-search-forward "[^ \t,\n]+" eol t)
2722           (if (eq (char-after (match-beginning 0)) ?!)
2723               ;; If the word begins with a bang (!), this is a "not"
2724               ;; spec.  We put this spec (minus the bang) and the
2725               ;; symbol `ignore' into the list.
2726               (push (cons (concat
2727                            "^" (buffer-substring
2728                                 (1+ (match-beginning 0))
2729                                 (match-end 0))
2730                            "\\($\\|\\.\\)")
2731                           'ignore)
2732                     out)
2733             ;; There was no bang, so this is a "yes" spec.
2734             (push (cons (concat "^" (match-string 0) "\\($\\|\\.\\)")
2735                         'subscribe)
2736                   out))))
2737
2738       (setq gnus-newsrc-options-n out))))
2739
2740 (eval-and-compile
2741   (defalias 'gnus-long-file-names
2742     (if (fboundp 'msdos-long-file-names)
2743       'msdos-long-file-names
2744       (lambda () t))))
2745
2746 (defun gnus-save-newsrc-file (&optional force)
2747   "Save .newsrc file."
2748   ;; Note: We cannot save .newsrc file if all newsgroups are removed
2749   ;; from the variable gnus-newsrc-alist.
2750   (when (and (or gnus-newsrc-alist gnus-killed-list)
2751              gnus-current-startup-file)
2752     ;; Save agent range limits for the currently active method.
2753     (when gnus-agent
2754       (gnus-agent-save-local force))
2755
2756     (save-excursion
2757       (if (and (or gnus-use-dribble-file gnus-slave)
2758                (not force)
2759                (or (not gnus-dribble-buffer)
2760                    (not (buffer-name gnus-dribble-buffer))
2761                    (zerop (save-excursion
2762                             (set-buffer gnus-dribble-buffer)
2763                             (buffer-size)))))
2764           (gnus-message 4 "(No changes need to be saved)")
2765         (gnus-run-hooks 'gnus-save-newsrc-hook)
2766         (if gnus-slave
2767             (gnus-slave-save-newsrc)
2768           ;; Save .newsrc.
2769           (when gnus-save-newsrc-file
2770             (gnus-message 8 "Saving %s..." gnus-current-startup-file)
2771             (gnus-gnus-to-newsrc-format)
2772             (gnus-message 8 "Saving %s...done" gnus-current-startup-file))
2773
2774           ;; Save .newsrc.eld.
2775           (set-buffer (gnus-get-buffer-create " *Gnus-newsrc*"))
2776           (make-local-variable 'version-control)
2777           (setq version-control gnus-backup-startup-file)
2778           (setq buffer-file-name
2779                 (concat gnus-current-startup-file ".eld"))
2780           (setq default-directory (file-name-directory buffer-file-name))
2781           (buffer-disable-undo)
2782           (erase-buffer)
2783           (gnus-message 5 "Saving %s.eld..." gnus-current-startup-file)
2784
2785           (if gnus-save-startup-file-via-temp-buffer
2786               (let ((coding-system-for-write gnus-ding-file-coding-system)
2787                     (standard-output (current-buffer)))
2788                 (gnus-gnus-to-quick-newsrc-format)
2789                 (gnus-run-hooks 'gnus-save-quick-newsrc-hook)
2790                 (save-buffer))
2791             (let ((coding-system-for-write gnus-ding-file-coding-system)
2792                   (version-control gnus-backup-startup-file)
2793                   (startup-file (concat gnus-current-startup-file ".eld"))
2794                   (working-dir (file-name-directory gnus-current-startup-file))
2795                   working-file
2796                   (i -1))
2797               ;; Generate the name of a non-existent file.
2798               (while (progn (setq working-file
2799                                   (format
2800                                    (if (and (eq system-type 'ms-dos)
2801                                             (not (gnus-long-file-names)))
2802                                        "%s#%d.tm#" ; MSDOS limits files to 8+3
2803                                      "%s#tmp#%d")
2804                                    working-dir (setq i (1+ i))))
2805                             (file-exists-p working-file)))
2806
2807               (unwind-protect
2808                   (progn
2809                     (gnus-with-output-to-file working-file
2810                       (gnus-gnus-to-quick-newsrc-format)
2811                       (gnus-run-hooks 'gnus-save-quick-newsrc-hook))
2812
2813                     ;; These bindings will mislead the current buffer
2814                     ;; into thinking that it is visiting the startup
2815                     ;; file.
2816                     (let ((buffer-backed-up nil)
2817                           (buffer-file-name startup-file)
2818                           (file-precious-flag t)
2819                           (setmodes (file-modes startup-file)))
2820                       ;; Backup the current version of the startup file.
2821                       (backup-buffer)
2822
2823                       ;; Replace the existing startup file with the temp file.
2824                       (rename-file working-file startup-file t)
2825                       (gnus-set-file-modes startup-file setmodes)))
2826                 (condition-case nil
2827                     (delete-file working-file)
2828                   (file-error nil)))))
2829
2830           (gnus-kill-buffer (current-buffer))
2831           (gnus-message
2832            5 "Saving %s.eld...done" gnus-current-startup-file))
2833         (gnus-dribble-delete-file)
2834         (gnus-group-set-mode-line)))))
2835
2836 (defun gnus-gnus-to-quick-newsrc-format (&optional minimal name &rest specific-variables)
2837   "Print Gnus variables such as `gnus-newsrc-alist' in Lisp format."
2838     (princ (format ";; -*- mode:emacs-lisp; coding: %s; -*-\n"
2839                    gnus-ding-file-coding-system))
2840     (if name
2841         (princ (format ";; %s\n" name))
2842       (princ ";; Gnus startup file.\n"))
2843
2844     (unless minimal
2845       (princ "\
2846 ;; Never delete this file -- if you want to force Gnus to read the
2847 ;; .newsrc file (if you have one), touch .newsrc instead.\n")
2848       (princ "(setq gnus-newsrc-file-version ")
2849       (princ (gnus-prin1-to-string gnus-version))
2850       (princ ")\n"))
2851
2852     (let* ((print-quoted t)
2853            (print-readably t)
2854            (print-escape-multibyte nil)
2855            (print-escape-nonascii t)
2856            (print-length nil)
2857            (print-level nil)
2858            (print-circle nil)
2859            (print-escape-newlines t)
2860            (gnus-killed-list
2861             (if (and gnus-save-killed-list
2862                      (stringp gnus-save-killed-list))
2863                 (gnus-strip-killed-list)
2864               gnus-killed-list))
2865            (variables
2866             (or specific-variables
2867                 (if gnus-save-killed-list gnus-variable-list
2868                   ;; Remove the `gnus-killed-list' from the list of variables
2869                   ;; to be saved, if required.
2870                   (delq 'gnus-killed-list (copy-sequence gnus-variable-list)))))
2871            ;; Peel off the "dummy" group.
2872            (gnus-newsrc-alist (cdr gnus-newsrc-alist))
2873            variable)
2874       ;; Insert the variables into the file.
2875       (while variables
2876         (when (and (boundp (setq variable (pop variables)))
2877                    (symbol-value variable))
2878           (princ "\n(setq ")
2879           (princ (symbol-name variable))
2880           (princ " '")
2881           (prin1 (symbol-value variable))
2882           (princ ")\n")))))
2883
2884 (defun gnus-strip-killed-list ()
2885   "Return the killed list minus the groups that match `gnus-save-killed-list'."
2886   (let ((list gnus-killed-list)
2887         olist)
2888     (while list
2889       (when (string-match gnus-save-killed-list (car list))
2890         (push (car list) olist))
2891       (pop list))
2892     (nreverse olist)))
2893
2894 (defun gnus-gnus-to-newsrc-format ()
2895   ;; Generate and save the .newsrc file.
2896   (save-excursion
2897     (set-buffer (create-file-buffer gnus-current-startup-file))
2898     (let ((newsrc (cdr gnus-newsrc-alist))
2899           (standard-output (current-buffer))
2900           info ranges range method)
2901       (setq buffer-file-name gnus-current-startup-file)
2902       (setq default-directory (file-name-directory buffer-file-name))
2903       (buffer-disable-undo)
2904       (erase-buffer)
2905       ;; Use a unibyte buffer since group names are unibyte strings;
2906       ;; in particular, non-ASCII group names are the ones encoded by
2907       ;; a certain coding system.
2908       (mm-disable-multibyte)
2909       ;; Write options.
2910       (when gnus-newsrc-options
2911         (insert gnus-newsrc-options))
2912       ;; Write subscribed and unsubscribed.
2913       (while (setq info (pop newsrc))
2914         ;; Don't write foreign groups to .newsrc.
2915         (when (or (null (setq method (gnus-info-method info)))
2916                   (equal method "native")
2917                   (inline (gnus-server-equal method gnus-select-method)))
2918           (insert (gnus-info-group info)
2919                   (if (> (gnus-info-level info) gnus-level-subscribed)
2920                       "!" ":"))
2921           (when (setq ranges (gnus-info-read info))
2922             (insert " ")
2923             (if (not (listp (cdr ranges)))
2924                 (if (= (car ranges) (cdr ranges))
2925                     (princ (car ranges))
2926                   (princ (car ranges))
2927                   (insert "-")
2928                   (princ (cdr ranges)))
2929               (while (setq range (pop ranges))
2930                 (if (or (atom range) (= (car range) (cdr range)))
2931                     (princ (or (and (atom range) range) (car range)))
2932                   (princ (car range))
2933                   (insert "-")
2934                   (princ (cdr range)))
2935                 (when ranges
2936                   (insert ",")))))
2937           (insert "\n")))
2938       (make-local-variable 'version-control)
2939       (setq version-control 'never)
2940       ;; It has been reported that sometime the modtime on the .newsrc
2941       ;; file seems to be off.  We really do want to overwrite it, so
2942       ;; we clear the modtime here before saving.  It's a bit odd,
2943       ;; though...
2944       ;; sometimes the modtime clear isn't sufficient.  most brute force:
2945       ;; delete the silly thing entirely first.  but this fails to provide
2946       ;; such niceties as .newsrc~ creation.
2947       (if gnus-modtime-botch
2948           (delete-file gnus-startup-file)
2949         (clear-visited-file-modtime))
2950       (gnus-run-hooks 'gnus-save-standard-newsrc-hook)
2951       (let ((coding-system-for-write 'raw-text))
2952         (save-buffer))
2953       (kill-buffer (current-buffer)))))
2954
2955 \f
2956 ;;;
2957 ;;; Slave functions.
2958 ;;;
2959
2960 (defvar gnus-slave-mode nil)
2961
2962 (defun gnus-slave-mode ()
2963   "Minor mode for slave Gnusae."
2964   ;; FIXME: gnus-slave-mode appears to never be set (i.e. it'll always be nil):
2965   ;; Remove, or fix and use define-minor-mode.
2966   (add-minor-mode 'gnus-slave-mode " Slave" (make-sparse-keymap))
2967   (gnus-run-hooks 'gnus-slave-mode-hook))
2968
2969 (defun gnus-slave-save-newsrc ()
2970   (save-excursion
2971     (set-buffer gnus-dribble-buffer)
2972     (let ((slave-name
2973            (mm-make-temp-file (concat gnus-current-startup-file "-slave-")))
2974           (modes (ignore-errors
2975                    (file-modes (concat gnus-current-startup-file ".eld")))))
2976       (let ((coding-system-for-write gnus-ding-file-coding-system))
2977         (gnus-write-buffer slave-name))
2978       (when modes
2979         (gnus-set-file-modes slave-name modes)))))
2980
2981 (defun gnus-master-read-slave-newsrc ()
2982   (let ((slave-files
2983          (directory-files
2984           (file-name-directory gnus-current-startup-file)
2985           t (concat
2986              "^" (regexp-quote
2987                   (concat
2988                    (file-name-nondirectory gnus-current-startup-file)
2989                    "-slave-")))
2990           t))
2991         file)
2992     (if (not slave-files)
2993         ()                              ; There are no slave files to read.
2994       (gnus-message 7 "Reading slave newsrcs...")
2995       (save-excursion
2996         (set-buffer (gnus-get-buffer-create " *gnus slave*"))
2997         (setq slave-files
2998               (sort (mapcar (lambda (file)
2999                               (list (nth 5 (file-attributes file)) file))
3000                             slave-files)
3001                     (lambda (f1 f2)
3002                       (or (< (caar f1) (caar f2))
3003                           (< (nth 1 (car f1)) (nth 1 (car f2)))))))
3004         (while slave-files
3005           (erase-buffer)
3006           (setq file (nth 1 (car slave-files)))
3007           (nnheader-insert-file-contents file)
3008           (when (condition-case ()
3009                     (progn
3010                       (eval-buffer (current-buffer))
3011                       t)
3012                   (error
3013                    (gnus-error 3.2 "Possible error in %s" file)
3014                    nil))
3015             (unless gnus-slave          ; Slaves shouldn't delete these files.
3016               (ignore-errors
3017                 (delete-file file))))
3018           (setq slave-files (cdr slave-files))))
3019       (gnus-dribble-touch)
3020       (gnus-message 7 "Reading slave newsrcs...done"))))
3021
3022 \f
3023 ;;;
3024 ;;; Group description.
3025 ;;;
3026
3027 (defun gnus-read-all-descriptions-files ()
3028   (let ((methods (cons gnus-select-method
3029                        (nconc
3030                         (when (gnus-archive-server-wanted-p)
3031                           (list "archive"))
3032                         gnus-secondary-select-methods))))
3033     (while methods
3034       (gnus-read-descriptions-file (car methods))
3035       (setq methods (cdr methods)))
3036     t))
3037
3038 (defun gnus-read-descriptions-file (&optional method)
3039   (let ((method (or method gnus-select-method))
3040         group)
3041     (when (stringp method)
3042       (setq method (gnus-server-to-method method)))
3043     ;; We create the hashtable whether we manage to read the desc file
3044     ;; to avoid trying to re-read after a failed read.
3045     (unless gnus-description-hashtb
3046       (setq gnus-description-hashtb
3047             (gnus-make-hashtable (length gnus-active-hashtb))))
3048     ;; Mark this method's desc file as read.
3049     (gnus-sethash (gnus-group-prefixed-name "" method) "Has read"
3050                   gnus-description-hashtb)
3051
3052     (gnus-message 5 "Reading descriptions file via %s..." (car method))
3053     (cond
3054      ((null (gnus-get-function method 'request-list-newsgroups t))
3055       t)
3056      ((not (gnus-check-server method))
3057       (gnus-message 1 "Couldn't open server")
3058       nil)
3059      ((not (gnus-request-list-newsgroups method))
3060       (gnus-message 1 "Couldn't read newsgroups descriptions")
3061       nil)
3062      (t
3063       (save-excursion
3064         ;; FIXME: Shouldn't save-restriction be done after set-buffer?
3065         (save-restriction
3066           (set-buffer nntp-server-buffer)
3067           (goto-char (point-min))
3068           (when (or (search-forward "\n.\n" nil t)
3069                     (goto-char (point-max)))
3070             (beginning-of-line)
3071             (narrow-to-region (point-min) (point)))
3072           ;; If these are groups from a foreign select method, we insert the
3073           ;; group prefix in front of the group names.
3074           (and method (not (inline
3075                              (gnus-server-equal
3076                               (gnus-server-get-method nil method)
3077                               (gnus-server-get-method
3078                                nil gnus-select-method))))
3079                (let ((prefix (gnus-group-prefixed-name "" method)))
3080                  (goto-char (point-min))
3081                  (while (and (not (eobp))
3082                              (progn (insert prefix)
3083                                     (zerop (forward-line 1)))))))
3084           (goto-char (point-min))
3085           (while (not (eobp))
3086             ;; If we get an error, we set group to 0, which is not a
3087             ;; symbol...
3088             (setq group
3089                   (condition-case ()
3090                       (let ((obarray gnus-description-hashtb))
3091                         ;; Group is set to a symbol interned in this
3092                         ;; hash table.
3093                         (read nntp-server-buffer))
3094                     (error 0)))
3095             (skip-chars-forward " \t")
3096             ;; ...  which leads to this line being effectively ignored.
3097             (when (symbolp group)
3098               (let* ((str (buffer-substring
3099                            (point) (progn (end-of-line) (point))))
3100                      (name (symbol-name group))
3101                      (charset
3102                       (or (gnus-group-name-charset method name)
3103                           (gnus-parameter-charset name)
3104                           gnus-default-charset)))
3105                 ;; Fixme: Don't decode in unibyte mode.
3106                 (when (and str charset (featurep 'mule))
3107                   (setq str (mm-decode-coding-string str charset)))
3108                 (set group str)))
3109             (forward-line 1))))
3110       (gnus-message 5 "Reading descriptions file...done")
3111       t))))
3112
3113 (defun gnus-group-get-description (group)
3114   "Get the description of a group by sending XGTITLE to the server."
3115   (when (gnus-request-group-description group)
3116     (save-excursion
3117       (set-buffer nntp-server-buffer)
3118       (goto-char (point-min))
3119       (when (looking-at "[^ \t]+[ \t]+\\(.*\\)")
3120         (match-string 1)))))
3121
3122 ;;;###autoload
3123 (defun gnus-declare-backend (name &rest abilities)
3124   "Declare back end NAME with ABILITIES as a Gnus back end."
3125   (setq gnus-valid-select-methods
3126         (nconc gnus-valid-select-methods
3127                (list (apply 'list name abilities))))
3128   (gnus-redefine-select-method-widget))
3129
3130 (defun gnus-set-default-directory ()
3131   "Set the default directory in the current buffer to `gnus-default-directory'.
3132 If this variable is nil, don't do anything."
3133   (setq default-directory
3134         (if (and gnus-default-directory
3135                  (file-exists-p gnus-default-directory))
3136             (file-name-as-directory (expand-file-name gnus-default-directory))
3137           default-directory)))
3138
3139 (defun gnus-display-time-event-handler ()
3140   (if (and (fboundp 'display-time-event-handler)
3141            (gnus-boundp 'display-time-timer))
3142       (display-time-event-handler)))
3143
3144 ;;;###autoload
3145 (defun gnus-fixup-nnimap-unread-after-getting-new-news ()
3146   (let (server group info)
3147     (mapatoms
3148      (lambda (sym)
3149        (when (and (setq group (symbol-name sym))
3150                   (gnus-group-entry group)
3151                   (setq info (symbol-value sym)))
3152          (gnus-sethash group (cons (nth 2 info) (cdr (gnus-group-entry group)))
3153                        gnus-newsrc-hashtb)))
3154      (if (boundp 'nnimap-mailbox-info)
3155          (symbol-value 'nnimap-mailbox-info)
3156        (make-vector 1 0)))))
3157
3158 (defun gnus-check-reasonable-setup ()
3159   ;; Check whether nnml and nnfolder share a directory.
3160   (let ((display-warn
3161          (if (fboundp 'display-warning)
3162              'display-warning
3163            (lambda (type message)
3164              (if noninteractive
3165                  (message "Warning (%s): %s" type message)
3166                (let (window)
3167                  (with-current-buffer (get-buffer-create "*Warnings*")
3168                    (goto-char (point-max))
3169                    (unless (bolp)
3170                      (insert "\n"))
3171                    (insert (format "Warning (%s): %s\n" type message))
3172                    (setq window (display-buffer (current-buffer)))
3173                    (set-window-start
3174                     window
3175                     (prog2
3176                         (forward-line (- 1 (window-height window)))
3177                         (point)
3178                       (goto-char (point-max))))))))))
3179         method active actives match)
3180     (dolist (server gnus-server-alist)
3181       (setq method (gnus-server-to-method server)
3182             active (intern (format "%s-active-file" (car method))))
3183       (when (and (member (car method) '(nnml nnfolder))
3184                  (gnus-server-opened method)
3185                  (boundp active))
3186         (when (setq match (assoc (symbol-value active) actives))
3187           (funcall display-warn 'gnus-server
3188                    (format "%s and %s share the same active file %s"
3189                            (car method)
3190                            (cadr match)
3191                            (car match))))
3192         (push (list (symbol-value active) method) actives)))))
3193
3194 (provide 'gnus-start)
3195
3196 ;;; gnus-start.el ends here