cgit.sxemacs.org Git - gnus/blob - lisp/gnus-srvr.el

   1 ;;; gnus-srvr.el --- virtual server support for Gnus
   2 ;; Copyright (C) 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003, 2004
   3 ;;        Free Software Foundation, Inc.
   4
   5 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   6 ;; Keywords: news
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;;; Code:
  28
  29 (eval-when-compile (require 'cl))
  30
  31 (require 'gnus)
  32 (require 'gnus-spec)
  33 (require 'gnus-group)
  34 (require 'gnus-int)
  35 (require 'gnus-range)
  36
  37 (defcustom gnus-server-mode-hook nil
  38   "Hook run in `gnus-server-mode' buffers."
  39   :group 'gnus-server
  40   :type 'hook)
  41
  42 (defcustom gnus-server-exit-hook nil
  43   "Hook run when exiting the server buffer."
  44   :group 'gnus-server
  45   :type 'hook)
  46
  47 (defcustom gnus-server-line-format "     {%(%h:%w%)} %s%a\n"
  48   "Format of server lines.
  49 It works along the same lines as a normal formatting string,
  50 with some simple extensions.
  51
  52 The following specs are understood:
  53
  54 %h back end
  55 %n name
  56 %w address
  57 %s status
  58 %a agent covered
  59
  60 General format specifiers can also be used.
  61 See Info node `(gnus)Formatting Variables'."
  62   :link '(custom-manual "(gnus)Formatting Variables")
  63   :group 'gnus-server-visual
  64   :type 'string)
  65
  66 (defcustom gnus-server-mode-line-format "Gnus: %%b"
  67   "The format specification for the server mode line."
  68   :group 'gnus-server-visual
  69   :type 'string)
  70
  71 (defcustom gnus-server-browse-in-group-buffer nil
  72   "Whether server browsing should take place in the group buffer.
  73 If nil, a faster, but more primitive, buffer is used instead."
  74   :group 'gnus-server-visual
  75   :type 'boolean)
  76
  77 ;;; Internal variables.
  78
  79 (defvar gnus-inserted-opened-servers nil)
  80
  81 (defvar gnus-server-line-format-alist
  82   `((?h gnus-tmp-how ?s)
  83     (?n gnus-tmp-name ?s)
  84     (?w gnus-tmp-where ?s)
  85     (?s gnus-tmp-status ?s)
  86     (?a gnus-tmp-agent ?s)))
  87
  88 (defvar gnus-server-mode-line-format-alist
  89   `((?S gnus-tmp-news-server ?s)
  90     (?M gnus-tmp-news-method ?s)
  91     (?u gnus-tmp-user-defined ?s)))
  92
  93 (defvar gnus-server-line-format-spec nil)
  94 (defvar gnus-server-mode-line-format-spec nil)
  95 (defvar gnus-server-killed-servers nil)
  96
  97 (defvar gnus-server-mode-map)
  98
  99 (defvar gnus-server-menu-hook nil
 100   "*Hook run after the creation of the server mode menu.")
 101
 102 (defun gnus-server-make-menu-bar ()
 103   (gnus-turn-off-edit-menu 'server)
 104   (unless (boundp 'gnus-server-server-menu)
 105     (easy-menu-define
 106      gnus-server-server-menu gnus-server-mode-map ""
 107      '("Server"
 108        ["Add..." gnus-server-add-server t]
 109        ["Browse" gnus-server-read-server t]
 110        ["Scan" gnus-server-scan-server t]
 111        ["List" gnus-server-list-servers t]
 112        ["Kill" gnus-server-kill-server t]
 113        ["Yank" gnus-server-yank-server t]
 114        ["Copy" gnus-server-copy-server t]
 115        ["Edit" gnus-server-edit-server t]
 116        ["Regenerate" gnus-server-regenerate-server t]
 117        ["Exit" gnus-server-exit t]))
 118
 119     (easy-menu-define
 120      gnus-server-connections-menu gnus-server-mode-map ""
 121      '("Connections"
 122        ["Open" gnus-server-open-server t]
 123        ["Close" gnus-server-close-server t]
 124        ["Offline" gnus-server-offline-server t]
 125        ["Deny" gnus-server-deny-server t]
 126        "---"
 127        ["Open All" gnus-server-open-all-servers t]
 128        ["Close All" gnus-server-close-all-servers t]
 129        ["Reset All" gnus-server-remove-denials t]))
 130
 131     (gnus-run-hooks 'gnus-server-menu-hook)))
 132
 133 (defvar gnus-server-mode-map nil)
 134 (put 'gnus-server-mode 'mode-class 'special)
 135
 136 (unless gnus-server-mode-map
 137   (setq gnus-server-mode-map (make-sparse-keymap))
 138   (suppress-keymap gnus-server-mode-map)
 139
 140   (gnus-define-keys gnus-server-mode-map
 141     " " gnus-server-read-server-in-server-buffer
 142     "\r" gnus-server-read-server
 143     gnus-mouse-2 gnus-server-pick-server
 144     "q" gnus-server-exit
 145     "l" gnus-server-list-servers
 146     "k" gnus-server-kill-server
 147     "y" gnus-server-yank-server
 148     "c" gnus-server-copy-server
 149     "a" gnus-server-add-server
 150     "e" gnus-server-edit-server
 151     "s" gnus-server-scan-server
 152
 153     "O" gnus-server-open-server
 154     "\M-o" gnus-server-open-all-servers
 155     "C" gnus-server-close-server
 156     "\M-c" gnus-server-close-all-servers
 157     "D" gnus-server-deny-server
 158     "L" gnus-server-offline-server
 159     "R" gnus-server-remove-denials
 160
 161     "n" next-line
 162     "p" previous-line
 163
 164     "g" gnus-server-regenerate-server
 165
 166     "\C-c\C-i" gnus-info-find-node
 167     "\C-c\C-b" gnus-bug))
 168
 169 (defface gnus-server-agent-face
 170   '((((class color) (background light)) (:foreground "PaleTurquoise" :bold t))
 171     (((class color) (background dark)) (:foreground "PaleTurquoise" :bold t))
 172     (t (:bold t)))
 173   "Face used for displaying AGENTIZED servers"
 174   :group 'gnus-server-visual)
 175
 176 (defface gnus-server-opened-face
 177   '((((class color) (background light)) (:foreground "Green3" :bold t))
 178     (((class color) (background dark)) (:foreground "Green1" :bold t))
 179     (t (:bold t)))
 180   "Face used for displaying OPENED servers"
 181   :group 'gnus-server-visual)
 182
 183 (defface gnus-server-closed-face
 184   '((((class color) (background light)) (:foreground "Steel Blue" :italic t))
 185     (((class color) (background dark))
 186      (:foreground "Light Steel Blue" :italic t))
 187     (t (:italic t)))
 188   "Face used for displaying CLOSED servers"
 189   :group 'gnus-server-visual)
 190
 191 (defface gnus-server-denied-face
 192   '((((class color) (background light)) (:foreground "Red" :bold t))
 193     (((class color) (background dark)) (:foreground "Pink" :bold t))
 194     (t (:inverse-video t :bold t)))
 195   "Face used for displaying DENIED servers"
 196   :group 'gnus-server-visual)
 197
 198 (defface gnus-server-offline-face
 199   '((((class color) (background light)) (:foreground "Orange" :bold t))
 200     (((class color) (background dark)) (:foreground "Yellow" :bold t))
 201     (t (:inverse-video t :bold t)))
 202   "Face used for displaying OFFLINE servers"
 203   :group 'gnus-server-visual)
 204
 205 (defcustom gnus-server-agent-face 'gnus-server-agent-face
 206   "Face name to use on AGENTIZED servers."
 207   :group 'gnus-server-visual
 208   :type 'face)
 209
 210 (defcustom gnus-server-opened-face 'gnus-server-opened-face
 211   "Face name to use on OPENED servers."
 212   :group 'gnus-server-visual
 213   :type 'face)
 214
 215 (defcustom gnus-server-closed-face 'gnus-server-closed-face
 216   "Face name to use on CLOSED servers."
 217   :group 'gnus-server-visual
 218   :type 'face)
 219
 220 (defcustom gnus-server-denied-face 'gnus-server-denied-face
 221   "Face name to use on DENIED servers."
 222   :group 'gnus-server-visual
 223   :type 'face)
 224
 225 (defcustom gnus-server-offline-face 'gnus-server-offline-face
 226   "Face name to use on OFFLINE servers."
 227   :group 'gnus-server-visual
 228   :type 'face)
 229
 230 (defvar gnus-server-font-lock-keywords
 231   (list
 232    '("(\\(agent\\))" 1 gnus-server-agent-face)
 233    '("(\\(opened\\))" 1 gnus-server-opened-face)
 234    '("(\\(closed\\))" 1 gnus-server-closed-face)
 235    '("(\\(offline\\))" 1 gnus-server-offline-face)
 236    '("(\\(denied\\))" 1 gnus-server-denied-face)))
 237
 238 (defun gnus-server-mode ()
 239   "Major mode for listing and editing servers.
 240
 241 All normal editing commands are switched off.
 242 \\<gnus-server-mode-map>
 243 For more in-depth information on this mode, read the manual
 244 \(`\\[gnus-info-find-node]').
 245
 246 The following commands are available:
 247
 248 \\{gnus-server-mode-map}"
 249   (interactive)
 250   (when (gnus-visual-p 'server-menu 'menu)
 251     (gnus-server-make-menu-bar))
 252   (kill-all-local-variables)
 253   (gnus-simplify-mode-line)
 254   (setq major-mode 'gnus-server-mode)
 255   (setq mode-name "Server")
 256   (gnus-set-default-directory)
 257   (setq mode-line-process nil)
 258   (use-local-map gnus-server-mode-map)
 259   (buffer-disable-undo)
 260   (setq truncate-lines t)
 261   (setq buffer-read-only t)
 262   (if (featurep 'xemacs)
 263       (put 'gnus-server-mode 'font-lock-defaults '(gnus-server-font-lock-keywords t))
 264     (set (make-local-variable 'font-lock-defaults)
 265          '(gnus-server-font-lock-keywords t)))
 266   (gnus-run-hooks 'gnus-server-mode-hook))
 267
 268 (defun gnus-server-insert-server-line (gnus-tmp-name method)
 269   (let* ((gnus-tmp-how (car method))
 270          (gnus-tmp-where (nth 1 method))
 271          (elem (assoc method gnus-opened-servers))
 272          (gnus-tmp-status
 273           (cond
 274            ((eq (nth 1 elem) 'denied) "(denied)")
 275            ((eq (nth 1 elem) 'offline) "(offline)")
 276            (t
 277             (condition-case nil
 278                 (if (or (gnus-server-opened method)
 279                         (eq (nth 1 elem) 'ok))
 280                     "(opened)"
 281                   "(closed)")
 282               ((error) "(error)")))))
 283          (gnus-tmp-agent (if (and gnus-agent
 284                                   (gnus-agent-method-p method))
 285                              " (agent)"
 286                            "")))
 287     (beginning-of-line)
 288     (gnus-add-text-properties
 289      (point)
 290      (prog1 (1+ (point))
 291        ;; Insert the text.
 292        (eval gnus-server-line-format-spec))
 293      (list 'gnus-server (intern gnus-tmp-name)
 294            'gnus-named-server (intern (gnus-method-to-server method))))))
 295
 296 (defun gnus-enter-server-buffer ()
 297   "Set up the server buffer."
 298   (gnus-server-setup-buffer)
 299   (gnus-configure-windows 'server)
 300   (gnus-server-prepare))
 301
 302 (defun gnus-server-setup-buffer ()
 303   "Initialize the server buffer."
 304   (unless (get-buffer gnus-server-buffer)
 305     (save-excursion
 306       (set-buffer (gnus-get-buffer-create gnus-server-buffer))
 307       (gnus-server-mode)
 308       (when gnus-carpal
 309         (gnus-carpal-setup-buffer 'server)))))
 310
 311 (defun gnus-server-prepare ()
 312   (gnus-set-format 'server-mode)
 313   (gnus-set-format 'server t)
 314   (let ((alist gnus-server-alist)
 315         (buffer-read-only nil)
 316         (opened gnus-opened-servers)
 317         done server op-ser)
 318     (erase-buffer)
 319     (setq gnus-inserted-opened-servers nil)
 320     ;; First we do the real list of servers.
 321     (while alist
 322       (unless (member (cdar alist) done)
 323         (push (cdar alist) done)
 324         (setq server (pop alist))
 325         (when (and server (car server) (cdr server))
 326           (gnus-server-insert-server-line (car server) (cdr server))))
 327       (when (member (cdar alist) done)
 328         (pop alist)))
 329     ;; Then we insert the list of servers that have been opened in
 330     ;; this session.
 331     (while opened
 332       (when (and (not (member (caar opened) done))
 333                  ;; Just ignore ephemeral servers.
 334                  (not (member (caar opened) gnus-ephemeral-servers)))
 335         (push (caar opened) done)
 336         (gnus-server-insert-server-line
 337          (setq op-ser (format "%s:%s" (caaar opened) (nth 1 (caar opened))))
 338          (caar opened))
 339         (push (list op-ser (caar opened)) gnus-inserted-opened-servers))
 340       (setq opened (cdr opened))))
 341   (goto-char (point-min))
 342   (gnus-server-position-point))
 343
 344 (defun gnus-server-server-name ()
 345   (let ((server (get-text-property (point-at-bol) 'gnus-server)))
 346     (and server (symbol-name server))))
 347
 348 (defun gnus-server-named-server ()
 349   "Return a server name that matches one of the names returned by
 350 `gnus-method-to-server'."
 351   (let ((server (get-text-property (point-at-bol) 'gnus-named-server)))
 352     (and server (symbol-name server))))
 353
 354 (defalias 'gnus-server-position-point 'gnus-goto-colon)
 355
 356 (defconst gnus-server-edit-buffer "*Gnus edit server*")
 357
 358 (defun gnus-server-update-server (server)
 359   (save-excursion
 360     (set-buffer gnus-server-buffer)
 361     (let* ((buffer-read-only nil)
 362            (entry (assoc server gnus-server-alist))
 363            (oentry (assoc (gnus-server-to-method server)
 364                           gnus-opened-servers)))
 365       (when entry
 366         (gnus-dribble-enter
 367          (concat "(gnus-server-set-info \"" server "\" '"
 368                  (gnus-prin1-to-string (cdr entry)) ")\n")))
 369       (when (or entry oentry)
 370         ;; Buffer may be narrowed.
 371         (save-restriction
 372           (widen)
 373           (when (gnus-server-goto-server server)
 374             (gnus-delete-line))
 375           (if entry
 376               (gnus-server-insert-server-line (car entry) (cdr entry))
 377             (gnus-server-insert-server-line
 378              (format "%s:%s" (caar oentry) (nth 1 (car oentry)))
 379              (car oentry)))
 380           (gnus-server-position-point))))))
 381
 382 (defun gnus-server-set-info (server info)
 383   ;; Enter a select method into the virtual server alist.
 384   (when (and server info)
 385     (gnus-dribble-enter
 386      (concat "(gnus-server-set-info \"" server "\" '"
 387              (gnus-prin1-to-string info) ")"))
 388     (let* ((server (nth 1 info))
 389            (entry (assoc server gnus-server-alist))
 390            (cached (assoc server gnus-server-method-cache)))
 391       (if cached
 392           (setq gnus-server-method-cache
 393                 (delq cached gnus-server-method-cache)))
 394       (if entry
 395           (progn
 396             ;; Remove the server from `gnus-opened-servers' since
 397             ;; it has never been opened with the new `info' yet.
 398             (setq gnus-opened-servers
 399                   (delq (assoc (cdr entry) gnus-opened-servers)
 400                         gnus-opened-servers))
 401             (setcdr entry info))
 402         (setq gnus-server-alist
 403               (nconc gnus-server-alist (list (cons server info))))))))
 404
 405 ;;; Interactive server functions.
 406
 407 (defun gnus-server-kill-server (server)
 408   "Kill the server on the current line."
 409   (interactive (list (gnus-server-server-name)))
 410   (unless (gnus-server-goto-server server)
 411     (if server (error "No such server: %s" server)
 412       (error "No server on the current line")))
 413   (unless (assoc server gnus-server-alist)
 414     (error "Read-only server %s" server))
 415   (gnus-dribble-touch)
 416   (let ((buffer-read-only nil))
 417     (gnus-delete-line))
 418   (push (assoc server gnus-server-alist) gnus-server-killed-servers)
 419   (setq gnus-server-alist (delq (car gnus-server-killed-servers)
 420                                 gnus-server-alist))
 421   (let ((groups (gnus-groups-from-server server)))
 422     (when (and groups
 423                (gnus-yes-or-no-p
 424                 (format "Kill all %s groups from this server? "
 425                         (length groups))))
 426       (dolist (group groups)
 427         (setq gnus-newsrc-alist
 428               (delq (assoc group gnus-newsrc-alist)
 429                     gnus-newsrc-alist))
 430         (when gnus-group-change-level-function
 431           (funcall gnus-group-change-level-function
 432                    group gnus-level-killed 3)))))
 433   (gnus-server-position-point))
 434
 435 (defun gnus-server-yank-server ()
 436   "Yank the previously killed server."
 437   (interactive)
 438   (unless gnus-server-killed-servers
 439     (error "No killed servers to be yanked"))
 440   (let ((alist gnus-server-alist)
 441         (server (gnus-server-server-name))
 442         (killed (car gnus-server-killed-servers)))
 443     (if (not server)
 444         (setq gnus-server-alist (nconc gnus-server-alist (list killed)))
 445       (if (string= server (caar gnus-server-alist))
 446           (push killed gnus-server-alist)
 447         (while (and (cdr alist)
 448                     (not (string= server (caadr alist))))
 449           (setq alist (cdr alist)))
 450         (if alist
 451             (setcdr alist (cons killed (cdr alist)))
 452           (setq gnus-server-alist (list killed)))))
 453     (gnus-server-update-server (car killed))
 454     (setq gnus-server-killed-servers (cdr gnus-server-killed-servers))
 455     (gnus-server-position-point)))
 456
 457 (defun gnus-server-exit ()
 458   "Return to the group buffer."
 459   (interactive)
 460   (gnus-run-hooks 'gnus-server-exit-hook)
 461   (gnus-kill-buffer (current-buffer))
 462   (gnus-configure-windows 'group t))
 463
 464 (defun gnus-server-list-servers ()
 465   "List all available servers."
 466   (interactive)
 467   (let ((cur (gnus-server-server-name)))
 468     (gnus-server-prepare)
 469     (if cur (gnus-server-goto-server cur)
 470       (goto-char (point-max))
 471       (forward-line -1))
 472     (gnus-server-position-point)))
 473
 474 (defun gnus-server-set-status (method status)
 475   "Make METHOD have STATUS."
 476   (let ((entry (assoc method gnus-opened-servers)))
 477     (if entry
 478         (setcar (cdr entry) status)
 479       (push (list method status) gnus-opened-servers))))
 480
 481 (defun gnus-opened-servers-remove (method)
 482   "Remove METHOD from the list of opened servers."
 483   (setq gnus-opened-servers (delq (assoc method gnus-opened-servers)
 484                                   gnus-opened-servers)))
 485
 486 (defun gnus-server-open-server (server)
 487   "Force an open of SERVER."
 488   (interactive (list (gnus-server-server-name)))
 489   (let ((method (gnus-server-to-method server)))
 490     (unless method
 491       (error "No such server: %s" server))
 492     (gnus-server-set-status method 'ok)
 493     (prog1
 494         (or (gnus-open-server method)
 495             (progn (message "Couldn't open %s" server) nil))
 496       (gnus-server-update-server server)
 497       (gnus-server-position-point))))
 498
 499 (defun gnus-server-open-all-servers ()
 500   "Open all servers."
 501   (interactive)
 502   (let ((servers gnus-inserted-opened-servers))
 503     (while servers
 504       (gnus-server-open-server (car (pop servers))))))
 505
 506 (defun gnus-server-close-server (server)
 507   "Close SERVER."
 508   (interactive (list (gnus-server-server-name)))
 509   (let ((method (gnus-server-to-method server)))
 510     (unless method
 511       (error "No such server: %s" server))
 512     (gnus-server-set-status method 'closed)
 513     (prog1
 514         (gnus-close-server method)
 515       (gnus-server-update-server server)
 516       (gnus-server-position-point))))
 517
 518 (defun gnus-server-offline-server (server)
 519   "Set SERVER to offline."
 520   (interactive (list (gnus-server-server-name)))
 521   (let ((method (gnus-server-to-method server)))
 522     (unless method
 523       (error "No such server: %s" server))
 524     (prog1
 525         (gnus-close-server method)
 526       (gnus-server-set-status method 'offline)
 527       (gnus-server-update-server server)
 528       (gnus-server-position-point))))
 529
 530 (defun gnus-server-close-all-servers ()
 531   "Close all servers."
 532   (interactive)
 533   (dolist (server gnus-inserted-opened-servers)
 534     (gnus-server-close-server (car server))))
 535
 536 (defun gnus-server-deny-server (server)
 537   "Make sure SERVER will never be attempted opened."
 538   (interactive (list (gnus-server-server-name)))
 539   (let ((method (gnus-server-to-method server)))
 540     (unless method
 541       (error "No such server: %s" server))
 542     (gnus-server-set-status method 'denied))
 543   (gnus-server-update-server server)
 544   (gnus-server-position-point)
 545   t)
 546
 547 (defun gnus-server-remove-denials ()
 548   "Make all denied servers into closed servers."
 549   (interactive)
 550   (dolist (server gnus-opened-servers)
 551     (when (eq (nth 1 server) 'denied)
 552       (setcar (nthcdr 1 server) 'closed)))
 553   (gnus-server-list-servers))
 554
 555 (defun gnus-server-copy-server (from to)
 556   (interactive
 557    (list
 558     (or (gnus-server-server-name)
 559         (error "No server on the current line"))
 560     (read-string "Copy to: ")))
 561   (unless from
 562     (error "No server on current line"))
 563   (unless (and to (not (string= to "")))
 564     (error "No name to copy to"))
 565   (when (assoc to gnus-server-alist)
 566     (error "%s already exists" to))
 567   (unless (gnus-server-to-method from)
 568     (error "%s: no such server" from))
 569   (let ((to-entry (cons from (gnus-copy-sequence
 570                               (gnus-server-to-method from)))))
 571     (setcar to-entry to)
 572     (setcar (nthcdr 2 to-entry) to)
 573     (push to-entry gnus-server-killed-servers)
 574     (gnus-server-yank-server)))
 575
 576 (defun gnus-server-add-server (how where)
 577   (interactive
 578    (list (intern (completing-read "Server method: "
 579                                   gnus-valid-select-methods nil t))
 580          (read-string "Server name: ")))
 581   (when (assq where gnus-server-alist)
 582     (error "Server with that name already defined"))
 583   (push (list where how where) gnus-server-killed-servers)
 584   (gnus-server-yank-server))
 585
 586 (defun gnus-server-goto-server (server)
 587   "Jump to a server line."
 588   (interactive
 589    (list (completing-read "Goto server: " gnus-server-alist nil t)))
 590   (let ((to (text-property-any (point-min) (point-max)
 591                                'gnus-server (intern server))))
 592     (when to
 593       (goto-char to)
 594       (gnus-server-position-point))))
 595
 596 (defun gnus-server-edit-server (server)
 597   "Edit the server on the current line."
 598   (interactive (list (gnus-server-server-name)))
 599   (unless server
 600     (error "No server on current line"))
 601   (unless (assoc server gnus-server-alist)
 602     (error "This server can't be edited"))
 603   (let ((info (cdr (assoc server gnus-server-alist))))
 604     (gnus-close-server info)
 605     (gnus-edit-form
 606      info "Editing the server."
 607      `(lambda (form)
 608         (gnus-server-set-info ,server form)
 609         (gnus-server-list-servers)
 610         (gnus-server-position-point)))))
 611
 612 (defun gnus-server-scan-server (server)
 613   "Request a scan from the current server."
 614   (interactive (list (gnus-server-server-name)))
 615   (let ((method (gnus-server-to-method server)))
 616     (if (not (gnus-get-function method 'request-scan))
 617         (error "Server %s can't scan" (car method))
 618       (gnus-message 3 "Scanning %s..." server)
 619       (gnus-request-scan nil method)
 620       (gnus-message 3 "Scanning %s...done" server))))
 621
 622 (defun gnus-server-read-server-in-server-buffer (server)
 623   "Browse a server in server buffer."
 624   (interactive (list (gnus-server-server-name)))
 625   (let (gnus-server-browse-in-group-buffer)
 626     (gnus-server-read-server server)))
 627
 628 (defun gnus-server-read-server (server)
 629   "Browse a server."
 630   (interactive (list (gnus-server-server-name)))
 631   (let ((buf (current-buffer)))
 632     (prog1
 633         (gnus-browse-foreign-server server buf)
 634       (save-excursion
 635         (set-buffer buf)
 636         (gnus-server-update-server (gnus-server-server-name))
 637         (gnus-server-position-point)))))
 638
 639 (defun gnus-server-pick-server (e)
 640   (interactive "e")
 641   (mouse-set-point e)
 642   (gnus-server-read-server (gnus-server-server-name)))
 643
 644 \f
 645 ;;;
 646 ;;; Browse Server Mode
 647 ;;;
 648
 649 (defvar gnus-browse-menu-hook nil
 650   "*Hook run after the creation of the browse mode menu.")
 651
 652 (defvar gnus-browse-mode-hook nil)
 653 (defvar gnus-browse-mode-map nil)
 654 (put 'gnus-browse-mode 'mode-class 'special)
 655
 656 (unless gnus-browse-mode-map
 657   (setq gnus-browse-mode-map (make-keymap))
 658   (suppress-keymap gnus-browse-mode-map)
 659
 660   (gnus-define-keys
 661       gnus-browse-mode-map
 662     " " gnus-browse-read-group
 663     "=" gnus-browse-select-group
 664     "n" gnus-browse-next-group
 665     "p" gnus-browse-prev-group
 666     "\177" gnus-browse-prev-group
 667     [delete] gnus-browse-prev-group
 668     "N" gnus-browse-next-group
 669     "P" gnus-browse-prev-group
 670     "\M-n" gnus-browse-next-group
 671     "\M-p" gnus-browse-prev-group
 672     "\r" gnus-browse-select-group
 673     "u" gnus-browse-unsubscribe-current-group
 674     "l" gnus-browse-exit
 675     "L" gnus-browse-exit
 676     "q" gnus-browse-exit
 677     "Q" gnus-browse-exit
 678     "d" gnus-browse-describe-group
 679     "\C-c\C-c" gnus-browse-exit
 680     "?" gnus-browse-describe-briefly
 681
 682     "\C-c\C-i" gnus-info-find-node
 683     "\C-c\C-b" gnus-bug))
 684
 685 (defun gnus-browse-make-menu-bar ()
 686   (gnus-turn-off-edit-menu 'browse)
 687   (unless (boundp 'gnus-browse-menu)
 688     (easy-menu-define
 689      gnus-browse-menu gnus-browse-mode-map ""
 690      '("Browse"
 691        ["Subscribe" gnus-browse-unsubscribe-current-group t]
 692        ["Read" gnus-browse-read-group t]
 693        ["Select" gnus-browse-select-group t]
 694        ["Describe" gnus-browse-describe-group t]
 695        ["Next" gnus-browse-next-group t]
 696        ["Prev" gnus-browse-prev-group t]
 697        ["Exit" gnus-browse-exit t]))
 698     (gnus-run-hooks 'gnus-browse-menu-hook)))
 699
 700 (defvar gnus-browse-current-method nil)
 701 (defvar gnus-browse-return-buffer nil)
 702
 703 (defvar gnus-browse-buffer "*Gnus Browse Server*")
 704
 705 (defun gnus-browse-foreign-server (server &optional return-buffer)
 706   "Browse the server SERVER."
 707   (setq gnus-browse-current-method (gnus-server-to-method server))
 708   (setq gnus-browse-return-buffer return-buffer)
 709   (let* ((method gnus-browse-current-method)
 710          (orig-select-method gnus-select-method)
 711          (gnus-select-method method)
 712          groups group)
 713     (gnus-message 5 "Connecting to %s..." (nth 1 method))
 714     (cond
 715      ((not (gnus-check-server method))
 716       (gnus-message
 717        1 "Unable to contact server %s: %s" (nth 1 method)
 718        (gnus-status-message method))
 719       nil)
 720      ((not
 721        (prog2
 722            (gnus-message 6 "Reading active file...")
 723            (gnus-request-list method)
 724          (gnus-message 6 "Reading active file...done")))
 725       (gnus-message
 726        1 "Couldn't request list: %s" (gnus-status-message method))
 727       nil)
 728      (t
 729       (with-current-buffer nntp-server-buffer
 730         (let ((cur (current-buffer)))
 731           (goto-char (point-min))
 732           (unless (string= gnus-ignored-newsgroups "")
 733             (delete-matching-lines gnus-ignored-newsgroups))
 734           ;; We treat NNTP as a special case to avoid problems with
 735           ;; garbage group names like `"foo' that appear in some badly
 736           ;; managed active files. -jh.
 737           (if (eq (car method) 'nntp)
 738               (while (not (eobp))
 739                 (ignore-errors
 740                   (push (cons
 741                          (buffer-substring
 742                           (point)
 743                           (progn
 744                             (skip-chars-forward "^ \t")
 745                             (point)))
 746                          (let ((last (read cur)))
 747                            (cons (read cur) last)))
 748                         groups))
 749                 (forward-line))
 750             (while (not (eobp))
 751               (ignore-errors
 752                 (push (cons
 753                        (if (eq (char-after) ?\")
 754                            (read cur)
 755                          (let ((p (point)) (name ""))
 756                            (skip-chars-forward "^ \t\\\\")
 757                            (setq name (buffer-substring p (point)))
 758                            (while (eq (char-after) ?\\)
 759                              (setq p (1+ (point)))
 760                              (forward-char 2)
 761                              (skip-chars-forward "^ \t\\\\")
 762                              (setq name (concat name (buffer-substring
 763                                                       p (point)))))
 764                            name))
 765                        (let ((last (read cur)))
 766                          (cons (read cur) last)))
 767                       groups))
 768               (forward-line)))))
 769       (setq groups (sort groups
 770                          (lambda (l1 l2)
 771                            (string< (car l1) (car l2)))))
 772       (if gnus-server-browse-in-group-buffer
 773           (let* ((gnus-select-method orig-select-method)
 774                  (gnus-group-listed-groups
 775                   (mapcar (lambda (group)
 776                             (let ((name
 777                                    (gnus-group-prefixed-name
 778                                     (car group) method)))
 779                               (gnus-set-active name (cdr group))
 780                               name))
 781                           groups)))
 782             (gnus-configure-windows 'group)
 783             (funcall gnus-group-prepare-function
 784                      gnus-level-killed 'ignore 1 'ignore))
 785         (gnus-get-buffer-create gnus-browse-buffer)
 786         (when gnus-carpal
 787           (gnus-carpal-setup-buffer 'browse))
 788         (gnus-configure-windows 'browse)
 789         (buffer-disable-undo)
 790         (let ((buffer-read-only nil))
 791           (erase-buffer))
 792         (gnus-browse-mode)
 793         (setq mode-line-buffer-identification
 794               (list
 795                (format
 796                 "Gnus: %%b {%s:%s}" (car method) (cadr method))))
 797         (let ((buffer-read-only nil)
 798               name
 799               (prefix (let ((gnus-select-method orig-select-method))
 800                         (gnus-group-prefixed-name "" method))))
 801           (while (setq group (pop groups))
 802             (gnus-add-text-properties
 803              (point)
 804              (prog1 (1+ (point))
 805                (insert
 806                 (format "%c%7d: %s\n"
 807                         (let ((level
 808                                (if (string= prefix "")
 809                                    (gnus-group-level (setq name (car group)))
 810                                  (gnus-group-level
 811                                   (concat prefix (setq name (car group)))))))
 812                           (cond
 813                            ((<= level gnus-level-subscribed) ? )
 814                            ((<= level gnus-level-unsubscribed) ?U)
 815                            ((= level gnus-level-zombie) ?Z)
 816                            (t ?K)))
 817                         (max 0 (- (1+ (cddr group)) (cadr group)))
 818                         ;; Don't decode if name is ASCII
 819                         (if (and (fboundp 'detect-coding-string)
 820                                  (eq (detect-coding-string name t) 'undecided))
 821                             name
 822                           (mm-decode-coding-string
 823                            name
 824                            (inline (gnus-group-name-charset method name)))))))
 825              (list 'gnus-group name)
 826              )))
 827         (switch-to-buffer (current-buffer)))
 828       (goto-char (point-min))
 829       (gnus-group-position-point)
 830       (gnus-message 5 "Connecting to %s...done" (nth 1 method))
 831       t))))
 832
 833 (defun gnus-browse-mode ()
 834   "Major mode for browsing a foreign server.
 835
 836 All normal editing commands are switched off.
 837
 838 \\<gnus-browse-mode-map>
 839 The only things you can do in this buffer is
 840
 841 1) `\\[gnus-browse-unsubscribe-current-group]' to subscribe to a group.
 842 The group will be inserted into the group buffer upon exit from this
 843 buffer.
 844
 845 2) `\\[gnus-browse-read-group]' to read a group ephemerally.
 846
 847 3) `\\[gnus-browse-exit]' to return to the group buffer."
 848   (interactive)
 849   (kill-all-local-variables)
 850   (when (gnus-visual-p 'browse-menu 'menu)
 851     (gnus-browse-make-menu-bar))
 852   (gnus-simplify-mode-line)
 853   (setq major-mode 'gnus-browse-mode)
 854   (setq mode-name "Browse Server")
 855   (setq mode-line-process nil)
 856   (use-local-map gnus-browse-mode-map)
 857   (buffer-disable-undo)
 858   (setq truncate-lines t)
 859   (gnus-set-default-directory)
 860   (setq buffer-read-only t)
 861   (gnus-run-hooks 'gnus-browse-mode-hook))
 862
 863 (defun gnus-browse-read-group (&optional no-article)
 864   "Enter the group at the current line."
 865   (interactive)
 866   (let ((group (gnus-browse-group-name)))
 867     (if (or (not (gnus-get-info group))
 868             (gnus-ephemeral-group-p group))
 869         (unless (gnus-group-read-ephemeral-group
 870                  group gnus-browse-current-method nil
 871                  (cons (current-buffer) 'browse))
 872           (error "Couldn't enter %s" group))
 873       (unless (gnus-group-read-group nil no-article group)
 874         (error "Couldn't enter %s" group)))))
 875
 876 (defun gnus-browse-select-group ()
 877   "Select the current group."
 878   (interactive)
 879   (gnus-browse-read-group 'no))
 880
 881 (defun gnus-browse-next-group (n)
 882   "Go to the next group."
 883   (interactive "p")
 884   (prog1
 885       (forward-line n)
 886     (gnus-group-position-point)))
 887
 888 (defun gnus-browse-prev-group (n)
 889   "Go to the next group."
 890   (interactive "p")
 891   (gnus-browse-next-group (- n)))
 892
 893 (defun gnus-browse-unsubscribe-current-group (arg)
 894   "(Un)subscribe to the next ARG groups."
 895   (interactive "p")
 896   (when (eobp)
 897     (error "No group at current line"))
 898   (let ((ward (if (< arg 0) -1 1))
 899         (arg (abs arg)))
 900     (while (and (> arg 0)
 901                 (not (eobp))
 902                 (gnus-browse-unsubscribe-group)
 903                 (zerop (gnus-browse-next-group ward)))
 904       (decf arg))
 905     (gnus-group-position-point)
 906     (when (/= 0 arg)
 907       (gnus-message 7 "No more newsgroups"))
 908     arg))
 909
 910 (defun gnus-browse-group-name ()
 911   (save-excursion
 912     (beginning-of-line)
 913     (let ((name (get-text-property (point) 'gnus-group)))
 914       (when (re-search-forward ": \\(.*\\)$" (point-at-eol) t)
 915         (concat (gnus-method-to-server-name gnus-browse-current-method) ":"
 916                 (or name
 917                     (match-string-no-properties 1)))))))
 918
 919 (defun gnus-browse-describe-group (group)
 920   "Describe the current group."
 921   (interactive (list (gnus-browse-group-name)))
 922   (gnus-group-describe-group nil group))
 923
 924 (defun gnus-browse-unsubscribe-group ()
 925   "Toggle subscription of the current group in the browse buffer."
 926   (let ((sub nil)
 927         (buffer-read-only nil)
 928         group)
 929     (save-excursion
 930       (beginning-of-line)
 931       ;; If this group it killed, then we want to subscribe it.
 932       (unless (eq (char-after) ? )
 933         (setq sub t))
 934       (setq group (gnus-browse-group-name))
 935       (when (gnus-server-equal gnus-browse-current-method "native")
 936         (setq group (gnus-group-real-name group)))
 937       (if sub
 938           (progn
 939             ;; Make sure the group has been properly removed before we
 940             ;; subscribe to it.
 941             (gnus-kill-ephemeral-group group)
 942             (gnus-group-change-level
 943              (list t group gnus-level-default-subscribed
 944                    nil nil (if (gnus-server-equal
 945                                 gnus-browse-current-method "native")
 946                                nil
 947                              (gnus-method-simplify
 948                               gnus-browse-current-method)))
 949              gnus-level-default-subscribed (gnus-group-level group)
 950              (and (car (nth 1 gnus-newsrc-alist))
 951                   (gnus-group-entry (car (nth 1 gnus-newsrc-alist))))
 952              t)
 953             (delete-char 1)
 954             (insert ? ))
 955         (gnus-group-change-level
 956          group gnus-level-unsubscribed gnus-level-default-subscribed)
 957         (delete-char 1)
 958         (insert ?U)))
 959     t))
 960
 961 (defun gnus-browse-exit ()
 962   "Quit browsing and return to the group buffer."
 963   (interactive)
 964   (when (eq major-mode 'gnus-browse-mode)
 965     (gnus-kill-buffer (current-buffer)))
 966   ;; Insert the newly subscribed groups in the group buffer.
 967   (save-excursion
 968     (set-buffer gnus-group-buffer)
 969     (gnus-group-list-groups nil))
 970   (if gnus-browse-return-buffer
 971       (gnus-configure-windows 'server 'force)
 972     (gnus-configure-windows 'group 'force)))
 973
 974 (defun gnus-browse-describe-briefly ()
 975   "Give a one line description of the group mode commands."
 976   (interactive)
 977   (gnus-message 6
 978                 (substitute-command-keys "\\<gnus-browse-mode-map>\\[gnus-group-next-group]:Forward  \\[gnus-group-prev-group]:Backward  \\[gnus-browse-exit]:Exit  \\[gnus-info-find-node]:Run Info  \\[gnus-browse-describe-briefly]:This help")))
 979
 980 (defun gnus-server-regenerate-server ()
 981   "Issue a command to the server to regenerate all its data structures."
 982   (interactive)
 983   (let ((server (gnus-server-server-name)))
 984     (unless server
 985       (error "No server on the current line"))
 986     (condition-case ()
 987         (gnus-get-function (gnus-server-to-method server)
 988                            'request-regenerate)
 989       (error
 990         (error "This back end doesn't support regeneration")))
 991     (gnus-message 5 "Requesting regeneration of %s..." server)
 992     (unless (gnus-open-server server)
 993       (error "Couldn't open server"))
 994     (if (gnus-request-regenerate server)
 995         (gnus-message 5 "Requesting regeneration of %s...done" server)
 996       (gnus-message 5 "Couldn't regenerate %s" server))))
 997
 998 (provide 'gnus-srvr)
 999
1000 ;;; arch-tag: c0117f64-27ca-475d-9406-8da6854c7a25
1001 ;;; gnus-srvr.el ends here