cgit.sxemacs.org Git - gnus/blob - lisp/gnus-srvr.el

   1 ;;; gnus-srvr.el --- virtual server support for Gnus
   2 ;; Copyright (C) 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003
   3 ;;        Free Software Foundation, Inc.
   4
   5 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   6 ;; Keywords: news
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;;; Code:
  28
  29 (eval-when-compile (require 'cl))
  30
  31 (require 'gnus)
  32 (require 'gnus-spec)
  33 (require 'gnus-group)
  34 (require 'gnus-int)
  35 (require 'gnus-range)
  36
  37 (defcustom gnus-server-mode-hook nil
  38   "Hook run in `gnus-server-mode' buffers."
  39   :group 'gnus-server
  40   :type 'hook)
  41
  42 (defcustom gnus-server-exit-hook nil
  43   "Hook run when exiting the server buffer."
  44   :group 'gnus-server
  45   :type 'hook)
  46
  47 (defcustom gnus-server-line-format "     {%(%h:%w%)} %s%a\n"
  48   "Format of server lines.
  49 It works along the same lines as a normal formatting string,
  50 with some simple extensions.
  51
  52 The following specs are understood:
  53
  54 %h backend
  55 %n name
  56 %w address
  57 %s status
  58 %a agent covered
  59
  60 General format specifiers can also be used.
  61 See Info node `(gnus)Formatting Variables'."
  62   :link '(custom-manual "(gnus)Formatting Variables")
  63   :group 'gnus-server-visual
  64   :type 'string)
  65
  66 (defcustom gnus-server-mode-line-format "Gnus: %%b"
  67   "The format specification for the server mode line."
  68   :group 'gnus-server-visual
  69   :type 'string)
  70
  71 (defcustom gnus-server-browse-in-group-buffer nil
  72   "Whether server browsing should take place in the group buffer.
  73 If nil, a faster, but more primitive, buffer is used instead."
  74   :group 'gnus-server-visual
  75   :type 'boolean)
  76
  77 ;;; Internal variables.
  78
  79 (defvar gnus-inserted-opened-servers nil)
  80
  81 (defvar gnus-server-line-format-alist
  82   `((?h gnus-tmp-how ?s)
  83     (?n gnus-tmp-name ?s)
  84     (?w gnus-tmp-where ?s)
  85     (?s gnus-tmp-status ?s)
  86     (?a gnus-tmp-agent ?s)))
  87
  88 (defvar gnus-server-mode-line-format-alist
  89   `((?S gnus-tmp-news-server ?s)
  90     (?M gnus-tmp-news-method ?s)
  91     (?u gnus-tmp-user-defined ?s)))
  92
  93 (defvar gnus-server-line-format-spec nil)
  94 (defvar gnus-server-mode-line-format-spec nil)
  95 (defvar gnus-server-killed-servers nil)
  96
  97 (defvar gnus-server-mode-map)
  98
  99 (defvar gnus-server-menu-hook nil
 100   "*Hook run after the creation of the server mode menu.")
 101
 102 (defun gnus-server-make-menu-bar ()
 103   (gnus-turn-off-edit-menu 'server)
 104   (unless (boundp 'gnus-server-server-menu)
 105     (easy-menu-define
 106      gnus-server-server-menu gnus-server-mode-map ""
 107      '("Server"
 108        ["Add..." gnus-server-add-server t]
 109        ["Browse" gnus-server-read-server t]
 110        ["Scan" gnus-server-scan-server t]
 111        ["List" gnus-server-list-servers t]
 112        ["Kill" gnus-server-kill-server t]
 113        ["Yank" gnus-server-yank-server t]
 114        ["Copy" gnus-server-copy-server t]
 115        ["Edit" gnus-server-edit-server t]
 116        ["Regenerate" gnus-server-regenerate-server t]
 117        ["Exit" gnus-server-exit t]))
 118
 119     (easy-menu-define
 120      gnus-server-connections-menu gnus-server-mode-map ""
 121      '("Connections"
 122        ["Open" gnus-server-open-server t]
 123        ["Close" gnus-server-close-server t]
 124        ["Offline" gnus-server-offline-server t]
 125        ["Deny" gnus-server-deny-server t]
 126        "---"
 127        ["Open All" gnus-server-open-all-servers t]
 128        ["Close All" gnus-server-close-all-servers t]
 129        ["Reset All" gnus-server-remove-denials t]))
 130
 131     (gnus-run-hooks 'gnus-server-menu-hook)))
 132
 133 (defvar gnus-server-mode-map nil)
 134 (put 'gnus-server-mode 'mode-class 'special)
 135
 136 (unless gnus-server-mode-map
 137   (setq gnus-server-mode-map (make-sparse-keymap))
 138   (suppress-keymap gnus-server-mode-map)
 139
 140   (gnus-define-keys gnus-server-mode-map
 141     " " gnus-server-read-server-in-server-buffer
 142     "\r" gnus-server-read-server
 143     gnus-mouse-2 gnus-server-pick-server
 144     "q" gnus-server-exit
 145     "l" gnus-server-list-servers
 146     "k" gnus-server-kill-server
 147     "y" gnus-server-yank-server
 148     "c" gnus-server-copy-server
 149     "a" gnus-server-add-server
 150     "e" gnus-server-edit-server
 151     "s" gnus-server-scan-server
 152
 153     "O" gnus-server-open-server
 154     "\M-o" gnus-server-open-all-servers
 155     "C" gnus-server-close-server
 156     "\M-c" gnus-server-close-all-servers
 157     "D" gnus-server-deny-server
 158     "L" gnus-server-offline-server
 159     "R" gnus-server-remove-denials
 160
 161     "n" next-line
 162     "p" previous-line
 163
 164     "g" gnus-server-regenerate-server
 165
 166     "\C-c\C-i" gnus-info-find-node
 167     "\C-c\C-b" gnus-bug))
 168
 169 (defface gnus-server-agent-face
 170   '((((class color) (background light)) (:foreground "PaleTurquoise" :bold t))
 171     (((class color) (background dark)) (:foreground "PaleTurquoise" :bold t))
 172     (t (:bold t)))
 173   "Face used for displaying AGENTIZED servers"
 174   :group 'gnus-server-visual)
 175
 176 (defface gnus-server-opened-face
 177   '((((class color) (background light)) (:foreground "Green3" :bold t))
 178     (((class color) (background dark)) (:foreground "Green1" :bold t))
 179     (t (:bold t)))
 180   "Face used for displaying OPENED servers"
 181   :group 'gnus-server-visual)
 182
 183 (defface gnus-server-closed-face
 184   '((((class color) (background light)) (:foreground "Steel Blue" :italic t))
 185     (((class color) (background dark))
 186      (:foreground "Light Steel Blue" :italic t))
 187     (t (:italic t)))
 188   "Face used for displaying CLOSED servers"
 189   :group 'gnus-server-visual)
 190
 191 (defface gnus-server-denied-face
 192   '((((class color) (background light)) (:foreground "Red" :bold t))
 193     (((class color) (background dark)) (:foreground "Pink" :bold t))
 194     (t (:inverse-video t :bold t)))
 195   "Face used for displaying DENIED servers"
 196   :group 'gnus-server-visual)
 197
 198 (defface gnus-server-offline-face
 199   '((((class color) (background light)) (:foreground "Orange" :bold t))
 200     (((class color) (background dark)) (:foreground "Yellow" :bold t))
 201     (t (:inverse-video t :bold t)))
 202   "Face used for displaying OFFLINE servers"
 203   :group 'gnus-server-visual)
 204
 205 (defcustom gnus-server-agent-face 'gnus-server-agent-face
 206   "Face name to use on AGENTIZED servers."
 207   :group 'gnus-server-visual
 208   :type 'face)
 209
 210 (defcustom gnus-server-opened-face 'gnus-server-opened-face
 211   "Face name to use on OPENED servers."
 212   :group 'gnus-server-visual
 213   :type 'face)
 214
 215 (defcustom gnus-server-closed-face 'gnus-server-closed-face
 216   "Face name to use on CLOSED servers."
 217   :group 'gnus-server-visual
 218   :type 'face)
 219
 220 (defcustom gnus-server-denied-face 'gnus-server-denied-face
 221   "Face name to use on DENIED servers."
 222   :group 'gnus-server-visual
 223   :type 'face)
 224
 225 (defcustom gnus-server-offline-face 'gnus-server-offline-face
 226   "Face name to use on OFFLINE servers."
 227   :group 'gnus-server-visual
 228   :type 'face)
 229
 230 (defvar gnus-server-font-lock-keywords
 231   (list
 232    '("(\\(agent\\))" 1 gnus-server-agent-face)
 233    '("(\\(opened\\))" 1 gnus-server-opened-face)
 234    '("(\\(closed\\))" 1 gnus-server-closed-face)
 235    '("(\\(offline\\))" 1 gnus-server-offline-face)
 236    '("(\\(denied\\))" 1 gnus-server-denied-face)))
 237
 238 (defun gnus-server-mode ()
 239   "Major mode for listing and editing servers.
 240
 241 All normal editing commands are switched off.
 242 \\<gnus-server-mode-map>
 243 For more in-depth information on this mode, read the manual
 244 \(`\\[gnus-info-find-node]').
 245
 246 The following commands are available:
 247
 248 \\{gnus-server-mode-map}"
 249   (interactive)
 250   (when (gnus-visual-p 'server-menu 'menu)
 251     (gnus-server-make-menu-bar))
 252   (kill-all-local-variables)
 253   (gnus-simplify-mode-line)
 254   (setq major-mode 'gnus-server-mode)
 255   (setq mode-name "Server")
 256   (gnus-set-default-directory)
 257   (setq mode-line-process nil)
 258   (use-local-map gnus-server-mode-map)
 259   (buffer-disable-undo)
 260   (setq truncate-lines t)
 261   (setq buffer-read-only t)
 262   (if (featurep 'xemacs)
 263       (put 'gnus-server-mode 'font-lock-defaults '(gnus-server-font-lock-keywords t))
 264     (set (make-local-variable 'font-lock-defaults)
 265          '(gnus-server-font-lock-keywords t)))
 266   (gnus-run-hooks 'gnus-server-mode-hook))
 267
 268 (defun gnus-server-insert-server-line (gnus-tmp-name method)
 269   (let* ((gnus-tmp-how (car method))
 270          (gnus-tmp-where (nth 1 method))
 271          (elem (assoc method gnus-opened-servers))
 272          (gnus-tmp-status
 273           (cond
 274            ((eq (nth 1 elem) 'denied) "(denied)")
 275            ((eq (nth 1 elem) 'offline) "(offline)")
 276            (t
 277             (condition-case nil
 278                 (if (or (gnus-server-opened method)
 279                         (eq (nth 1 elem) 'ok))
 280                     "(opened)"
 281                   "(closed)")
 282               ((error) "(error)")))))
 283          (gnus-tmp-agent (if (and gnus-agent
 284                                   (gnus-agent-method-p method))
 285                              " (agent)"
 286                            "")))
 287     (beginning-of-line)
 288     (gnus-add-text-properties
 289      (point)
 290      (prog1 (1+ (point))
 291        ;; Insert the text.
 292        (eval gnus-server-line-format-spec))
 293      (list 'gnus-server (intern gnus-tmp-name)
 294            'gnus-named-server (intern (gnus-method-to-server method))))))
 295
 296 (defun gnus-enter-server-buffer ()
 297   "Set up the server buffer."
 298   (gnus-server-setup-buffer)
 299   (gnus-configure-windows 'server)
 300   (gnus-server-prepare))
 301
 302 (defun gnus-server-setup-buffer ()
 303   "Initialize the server buffer."
 304   (unless (get-buffer gnus-server-buffer)
 305     (save-excursion
 306       (set-buffer (gnus-get-buffer-create gnus-server-buffer))
 307       (gnus-server-mode)
 308       (when gnus-carpal
 309         (gnus-carpal-setup-buffer 'server)))))
 310
 311 (defun gnus-server-prepare ()
 312   (gnus-set-format 'server-mode)
 313   (gnus-set-format 'server t)
 314   (let ((alist gnus-server-alist)
 315         (buffer-read-only nil)
 316         (opened gnus-opened-servers)
 317         done server op-ser)
 318     (erase-buffer)
 319     (setq gnus-inserted-opened-servers nil)
 320     ;; First we do the real list of servers.
 321     (while alist
 322       (unless (member (cdar alist) done)
 323         (push (cdar alist) done)
 324         (setq server (pop alist))
 325         (when (and server (car server) (cdr server))
 326           (gnus-server-insert-server-line (car server) (cdr server))))
 327       (when (member (cdar alist) done)
 328         (pop alist)))
 329     ;; Then we insert the list of servers that have been opened in
 330     ;; this session.
 331     (while opened
 332       (when (and (not (member (caar opened) done))
 333                  ;; Just ignore ephemeral servers.
 334                  (not (member (caar opened) gnus-ephemeral-servers)))
 335         (push (caar opened) done)
 336         (gnus-server-insert-server-line
 337          (setq op-ser (format "%s:%s" (caaar opened) (nth 1 (caar opened))))
 338          (caar opened))
 339         (push (list op-ser (caar opened)) gnus-inserted-opened-servers))
 340       (setq opened (cdr opened))))
 341   (goto-char (point-min))
 342   (gnus-server-position-point))
 343
 344 (defun gnus-server-server-name ()
 345   (let ((server (get-text-property (gnus-point-at-bol) 'gnus-server)))
 346     (and server (symbol-name server))))
 347
 348 (defun gnus-server-named-server ()
 349   "Returns a server name that matches one of the names returned by
 350 gnus-method-to-server."
 351   (let ((server (get-text-property (gnus-point-at-bol) 'gnus-named-server)))
 352     (and server (symbol-name server))))
 353
 354 (defalias 'gnus-server-position-point 'gnus-goto-colon)
 355
 356 (defconst gnus-server-edit-buffer "*Gnus edit server*")
 357
 358 (defun gnus-server-update-server (server)
 359   (save-excursion
 360     (set-buffer gnus-server-buffer)
 361     (let* ((buffer-read-only nil)
 362            (entry (assoc server gnus-server-alist))
 363            (oentry (assoc (gnus-server-to-method server)
 364                           gnus-opened-servers)))
 365       (when entry
 366         (gnus-dribble-enter
 367          (concat "(gnus-server-set-info \"" server "\" '"
 368                  (gnus-prin1-to-string (cdr entry)) ")\n")))
 369       (when (or entry oentry)
 370         ;; Buffer may be narrowed.
 371         (save-restriction
 372           (widen)
 373           (when (gnus-server-goto-server server)
 374             (gnus-delete-line))
 375           (if entry
 376               (gnus-server-insert-server-line (car entry) (cdr entry))
 377             (gnus-server-insert-server-line
 378              (format "%s:%s" (caar oentry) (nth 1 (car oentry)))
 379              (car oentry)))
 380           (gnus-server-position-point))))))
 381
 382 (defun gnus-server-set-info (server info)
 383   ;; Enter a select method into the virtual server alist.
 384   (when (and server info)
 385     (gnus-dribble-enter
 386      (concat "(gnus-server-set-info \"" server "\" '"
 387              (gnus-prin1-to-string info) ")"))
 388     (let* ((server (nth 1 info))
 389            (entry (assoc server gnus-server-alist))
 390            (cached (assoc server gnus-server-method-cache)))
 391       (if cached
 392           (setq gnus-server-method-cache
 393                 (delq cached gnus-server-method-cache)))
 394       (if entry (setcdr entry info)
 395         (setq gnus-server-alist
 396               (nconc gnus-server-alist (list (cons server info))))))))
 397
 398 ;;; Interactive server functions.
 399
 400 (defun gnus-server-kill-server (server)
 401   "Kill the server on the current line."
 402   (interactive (list (gnus-server-server-name)))
 403   (unless (gnus-server-goto-server server)
 404     (if server (error "No such server: %s" server)
 405       (error "No server on the current line")))
 406   (unless (assoc server gnus-server-alist)
 407     (error "Read-only server %s" server))
 408   (gnus-dribble-touch)
 409   (let ((buffer-read-only nil))
 410     (gnus-delete-line))
 411   (push (assoc server gnus-server-alist) gnus-server-killed-servers)
 412   (setq gnus-server-alist (delq (car gnus-server-killed-servers)
 413                                 gnus-server-alist))
 414   (let ((groups (gnus-groups-from-server server)))
 415     (when (and groups
 416                (gnus-yes-or-no-p
 417                 (format "Kill all %s groups from this server? "
 418                         (length groups))))
 419       (dolist (group groups)
 420         (setq gnus-newsrc-alist
 421               (delq (assoc group gnus-newsrc-alist)
 422                     gnus-newsrc-alist))
 423         (when gnus-group-change-level-function
 424           (funcall gnus-group-change-level-function
 425                    group gnus-level-killed 3)))))
 426   (gnus-server-position-point))
 427
 428 (defun gnus-server-yank-server ()
 429   "Yank the previously killed server."
 430   (interactive)
 431   (unless gnus-server-killed-servers
 432     (error "No killed servers to be yanked"))
 433   (let ((alist gnus-server-alist)
 434         (server (gnus-server-server-name))
 435         (killed (car gnus-server-killed-servers)))
 436     (if (not server)
 437         (setq gnus-server-alist (nconc gnus-server-alist (list killed)))
 438       (if (string= server (caar gnus-server-alist))
 439           (push killed gnus-server-alist)
 440         (while (and (cdr alist)
 441                     (not (string= server (caadr alist))))
 442           (setq alist (cdr alist)))
 443         (if alist
 444             (setcdr alist (cons killed (cdr alist)))
 445           (setq gnus-server-alist (list killed)))))
 446     (gnus-server-update-server (car killed))
 447     (setq gnus-server-killed-servers (cdr gnus-server-killed-servers))
 448     (gnus-server-position-point)))
 449
 450 (defun gnus-server-exit ()
 451   "Return to the group buffer."
 452   (interactive)
 453   (gnus-run-hooks 'gnus-server-exit-hook)
 454   (gnus-kill-buffer (current-buffer))
 455   (gnus-configure-windows 'group t))
 456
 457 (defun gnus-server-list-servers ()
 458   "List all available servers."
 459   (interactive)
 460   (let ((cur (gnus-server-server-name)))
 461     (gnus-server-prepare)
 462     (if cur (gnus-server-goto-server cur)
 463       (goto-char (point-max))
 464       (forward-line -1))
 465     (gnus-server-position-point)))
 466
 467 (defun gnus-server-set-status (method status)
 468   "Make METHOD have STATUS."
 469   (let ((entry (assoc method gnus-opened-servers)))
 470     (if entry
 471         (setcar (cdr entry) status)
 472       (push (list method status) gnus-opened-servers))))
 473
 474 (defun gnus-opened-servers-remove (method)
 475   "Remove METHOD from the list of opened servers."
 476   (setq gnus-opened-servers (delq (assoc method gnus-opened-servers)
 477                                   gnus-opened-servers)))
 478
 479 (defun gnus-server-open-server (server)
 480   "Force an open of SERVER."
 481   (interactive (list (gnus-server-server-name)))
 482   (let ((method (gnus-server-to-method server)))
 483     (unless method
 484       (error "No such server: %s" server))
 485     (gnus-server-set-status method 'ok)
 486     (prog1
 487         (or (gnus-open-server method)
 488             (progn (message "Couldn't open %s" server) nil))
 489       (gnus-server-update-server server)
 490       (gnus-server-position-point))))
 491
 492 (defun gnus-server-open-all-servers ()
 493   "Open all servers."
 494   (interactive)
 495   (let ((servers gnus-inserted-opened-servers))
 496     (while servers
 497       (gnus-server-open-server (car (pop servers))))))
 498
 499 (defun gnus-server-close-server (server)
 500   "Close SERVER."
 501   (interactive (list (gnus-server-server-name)))
 502   (let ((method (gnus-server-to-method server)))
 503     (unless method
 504       (error "No such server: %s" server))
 505     (gnus-server-set-status method 'closed)
 506     (prog1
 507         (gnus-close-server method)
 508       (gnus-server-update-server server)
 509       (gnus-server-position-point))))
 510
 511 (defun gnus-server-offline-server (server)
 512   "Set SERVER to offline."
 513   (interactive (list (gnus-server-server-name)))
 514   (let ((method (gnus-server-to-method server)))
 515     (unless method
 516       (error "No such server: %s" server))
 517     (prog1
 518         (gnus-close-server method)
 519       (gnus-server-set-status method 'offline)
 520       (gnus-server-update-server server)
 521       (gnus-server-position-point))))
 522
 523 (defun gnus-server-close-all-servers ()
 524   "Close all servers."
 525   (interactive)
 526   (dolist (server gnus-inserted-opened-servers)
 527     (gnus-server-close-server (car server))))
 528
 529 (defun gnus-server-deny-server (server)
 530   "Make sure SERVER will never be attempted opened."
 531   (interactive (list (gnus-server-server-name)))
 532   (let ((method (gnus-server-to-method server)))
 533     (unless method
 534       (error "No such server: %s" server))
 535     (gnus-server-set-status method 'denied))
 536   (gnus-server-update-server server)
 537   (gnus-server-position-point)
 538   t)
 539
 540 (defun gnus-server-remove-denials ()
 541   "Make all denied servers into closed servers."
 542   (interactive)
 543   (dolist (server gnus-opened-servers)
 544     (when (eq (nth 1 server) 'denied)
 545       (setcar (nthcdr 1 server) 'closed)))
 546   (gnus-server-list-servers))
 547
 548 (defun gnus-server-copy-server (from to)
 549   (interactive
 550    (list
 551     (or (gnus-server-server-name)
 552         (error "No server on the current line"))
 553     (read-string "Copy to: ")))
 554   (unless from
 555     (error "No server on current line"))
 556   (unless (and to (not (string= to "")))
 557     (error "No name to copy to"))
 558   (when (assoc to gnus-server-alist)
 559     (error "%s already exists" to))
 560   (unless (gnus-server-to-method from)
 561     (error "%s: no such server" from))
 562   (let ((to-entry (cons from (gnus-copy-sequence
 563                               (gnus-server-to-method from)))))
 564     (setcar to-entry to)
 565     (setcar (nthcdr 2 to-entry) to)
 566     (push to-entry gnus-server-killed-servers)
 567     (gnus-server-yank-server)))
 568
 569 (defun gnus-server-add-server (how where)
 570   (interactive
 571    (list (intern (completing-read "Server method: "
 572                                   gnus-valid-select-methods nil t))
 573          (read-string "Server name: ")))
 574   (when (assq where gnus-server-alist)
 575     (error "Server with that name already defined"))
 576   (push (list where how where) gnus-server-killed-servers)
 577   (gnus-server-yank-server))
 578
 579 (defun gnus-server-goto-server (server)
 580   "Jump to a server line."
 581   (interactive
 582    (list (completing-read "Goto server: " gnus-server-alist nil t)))
 583   (let ((to (text-property-any (point-min) (point-max)
 584                                'gnus-server (intern server))))
 585     (when to
 586       (goto-char to)
 587       (gnus-server-position-point))))
 588
 589 (defun gnus-server-edit-server (server)
 590   "Edit the server on the current line."
 591   (interactive (list (gnus-server-server-name)))
 592   (unless server
 593     (error "No server on current line"))
 594   (unless (assoc server gnus-server-alist)
 595     (error "This server can't be edited"))
 596   (let ((info (cdr (assoc server gnus-server-alist))))
 597     (gnus-close-server info)
 598     (gnus-edit-form
 599      info "Editing the server."
 600      `(lambda (form)
 601         (gnus-server-set-info ,server form)
 602         (gnus-server-list-servers)
 603         (gnus-server-position-point)))))
 604
 605 (defun gnus-server-scan-server (server)
 606   "Request a scan from the current server."
 607   (interactive (list (gnus-server-server-name)))
 608   (let ((method (gnus-server-to-method server)))
 609     (if (not (gnus-get-function method 'request-scan))
 610         (error "Server %s can't scan" (car method))
 611       (gnus-message 3 "Scanning %s..." server)
 612       (gnus-request-scan nil method)
 613       (gnus-message 3 "Scanning %s...done" server))))
 614
 615 (defun gnus-server-read-server-in-server-buffer (server)
 616   "Browse a server in server buffer."
 617   (interactive (list (gnus-server-server-name)))
 618   (let (gnus-server-browse-in-group-buffer)
 619     (gnus-server-read-server server)))
 620
 621 (defun gnus-server-read-server (server)
 622   "Browse a server."
 623   (interactive (list (gnus-server-server-name)))
 624   (let ((buf (current-buffer)))
 625     (prog1
 626         (gnus-browse-foreign-server server buf)
 627       (save-excursion
 628         (set-buffer buf)
 629         (gnus-server-update-server (gnus-server-server-name))
 630         (gnus-server-position-point)))))
 631
 632 (defun gnus-server-pick-server (e)
 633   (interactive "e")
 634   (mouse-set-point e)
 635   (gnus-server-read-server (gnus-server-server-name)))
 636
 637 \f
 638 ;;;
 639 ;;; Browse Server Mode
 640 ;;;
 641
 642 (defvar gnus-browse-menu-hook nil
 643   "*Hook run after the creation of the browse mode menu.")
 644
 645 (defvar gnus-browse-mode-hook nil)
 646 (defvar gnus-browse-mode-map nil)
 647 (put 'gnus-browse-mode 'mode-class 'special)
 648
 649 (unless gnus-browse-mode-map
 650   (setq gnus-browse-mode-map (make-keymap))
 651   (suppress-keymap gnus-browse-mode-map)
 652
 653   (gnus-define-keys
 654       gnus-browse-mode-map
 655     " " gnus-browse-read-group
 656     "=" gnus-browse-select-group
 657     "n" gnus-browse-next-group
 658     "p" gnus-browse-prev-group
 659     "\177" gnus-browse-prev-group
 660     [delete] gnus-browse-prev-group
 661     "N" gnus-browse-next-group
 662     "P" gnus-browse-prev-group
 663     "\M-n" gnus-browse-next-group
 664     "\M-p" gnus-browse-prev-group
 665     "\r" gnus-browse-select-group
 666     "u" gnus-browse-unsubscribe-current-group
 667     "l" gnus-browse-exit
 668     "L" gnus-browse-exit
 669     "q" gnus-browse-exit
 670     "Q" gnus-browse-exit
 671     "d" gnus-browse-describe-group
 672     "\C-c\C-c" gnus-browse-exit
 673     "?" gnus-browse-describe-briefly
 674
 675     "\C-c\C-i" gnus-info-find-node
 676     "\C-c\C-b" gnus-bug))
 677
 678 (defun gnus-browse-make-menu-bar ()
 679   (gnus-turn-off-edit-menu 'browse)
 680   (unless (boundp 'gnus-browse-menu)
 681     (easy-menu-define
 682      gnus-browse-menu gnus-browse-mode-map ""
 683      '("Browse"
 684        ["Subscribe" gnus-browse-unsubscribe-current-group t]
 685        ["Read" gnus-browse-read-group t]
 686        ["Select" gnus-browse-select-group t]
 687        ["Describe" gnus-browse-describe-group t]
 688        ["Next" gnus-browse-next-group t]
 689        ["Prev" gnus-browse-prev-group t]
 690        ["Exit" gnus-browse-exit t]))
 691     (gnus-run-hooks 'gnus-browse-menu-hook)))
 692
 693 (defvar gnus-browse-current-method nil)
 694 (defvar gnus-browse-return-buffer nil)
 695
 696 (defvar gnus-browse-buffer "*Gnus Browse Server*")
 697
 698 (defun gnus-browse-foreign-server (server &optional return-buffer)
 699   "Browse the server SERVER."
 700   (setq gnus-browse-current-method (gnus-server-to-method server))
 701   (setq gnus-browse-return-buffer return-buffer)
 702   (let* ((method gnus-browse-current-method)
 703          (orig-select-method gnus-select-method)
 704          (gnus-select-method method)
 705          groups group)
 706     (gnus-message 5 "Connecting to %s..." (nth 1 method))
 707     (cond
 708      ((not (gnus-check-server method))
 709       (gnus-message
 710        1 "Unable to contact server %s: %s" (nth 1 method)
 711        (gnus-status-message method))
 712       nil)
 713      ((not
 714        (prog2
 715            (gnus-message 6 "Reading active file...")
 716            (gnus-request-list method)
 717          (gnus-message 6 "Reading active file...done")))
 718       (gnus-message
 719        1 "Couldn't request list: %s" (gnus-status-message method))
 720       nil)
 721      (t
 722       (with-current-buffer nntp-server-buffer
 723         (let ((cur (current-buffer)))
 724           (goto-char (point-min))
 725           (unless (string= gnus-ignored-newsgroups "")
 726             (delete-matching-lines gnus-ignored-newsgroups))
 727           ;; We treat NNTP as a special case to avoid problems with
 728           ;; garbage group names like `"foo' that appear in some badly
 729           ;; managed active files. -jh.
 730           (if (eq (car method) 'nntp)
 731               (while (not (eobp))
 732                 (ignore-errors
 733                   (push (cons
 734                          (buffer-substring
 735                           (point)
 736                           (progn
 737                             (skip-chars-forward "^ \t")
 738                             (point)))
 739                          (let ((last (read cur)))
 740                            (cons (read cur) last)))
 741                         groups))
 742                 (forward-line))
 743             (while (not (eobp))
 744               (ignore-errors
 745                 (push (cons
 746                        (if (eq (char-after) ?\")
 747                            (read cur)
 748                          (let ((p (point)) (name ""))
 749                            (skip-chars-forward "^ \t\\\\")
 750                            (setq name (buffer-substring p (point)))
 751                            (while (eq (char-after) ?\\)
 752                              (setq p (1+ (point)))
 753                              (forward-char 2)
 754                              (skip-chars-forward "^ \t\\\\")
 755                              (setq name (concat name (buffer-substring
 756                                                       p (point)))))
 757                            name))
 758                        (let ((last (read cur)))
 759                          (cons (read cur) last)))
 760                       groups))
 761               (forward-line)))))
 762       (setq groups (sort groups
 763                          (lambda (l1 l2)
 764                            (string< (car l1) (car l2)))))
 765       (if gnus-server-browse-in-group-buffer
 766           (let* ((gnus-select-method orig-select-method)
 767                  (gnus-group-listed-groups
 768                   (mapcar (lambda (group)
 769                             (let ((name
 770                                    (gnus-group-prefixed-name
 771                                     (car group) method)))
 772                               (gnus-set-active name (cdr group))
 773                               name))
 774                           groups)))
 775             (gnus-configure-windows 'group)
 776             (funcall gnus-group-prepare-function
 777                      gnus-level-killed 'ignore 1 'ignore))
 778         (gnus-get-buffer-create gnus-browse-buffer)
 779         (when gnus-carpal
 780           (gnus-carpal-setup-buffer 'browse))
 781         (gnus-configure-windows 'browse)
 782         (buffer-disable-undo)
 783         (let ((buffer-read-only nil))
 784           (erase-buffer))
 785         (gnus-browse-mode)
 786         (setq mode-line-buffer-identification
 787               (list
 788                (format
 789                 "Gnus: %%b {%s:%s}" (car method) (cadr method))))
 790         (let ((buffer-read-only nil)
 791               name
 792               (prefix (let ((gnus-select-method orig-select-method))
 793                         (gnus-group-prefixed-name "" method))))
 794           (while (setq group (pop groups))
 795             (gnus-add-text-properties
 796              (point)
 797              (prog1 (1+ (point))
 798                (insert
 799                 (format "%c%7d: %s\n"
 800                         (let ((level (gnus-group-level
 801                                       (concat prefix (setq name (car group))))))
 802                               (cond
 803                                ((<= level gnus-level-subscribed) ? )
 804                                ((<= level gnus-level-unsubscribed) ?U)
 805                                ((= level gnus-level-zombie) ?Z)
 806                                (t ?K)))
 807                         (max 0 (- (1+ (cddr group)) (cadr group)))
 808                         (mm-decode-coding-string
 809                          name
 810                          (inline (gnus-group-name-charset method name))))))
 811              (list 'gnus-group name))))
 812         (switch-to-buffer (current-buffer)))
 813       (goto-char (point-min))
 814       (gnus-group-position-point)
 815       (gnus-message 5 "Connecting to %s...done" (nth 1 method))
 816       t))))
 817
 818 (defun gnus-browse-mode ()
 819   "Major mode for browsing a foreign server.
 820
 821 All normal editing commands are switched off.
 822
 823 \\<gnus-browse-mode-map>
 824 The only things you can do in this buffer is
 825
 826 1) `\\[gnus-browse-unsubscribe-current-group]' to subscribe to a group.
 827 The group will be inserted into the group buffer upon exit from this
 828 buffer.
 829
 830 2) `\\[gnus-browse-read-group]' to read a group ephemerally.
 831
 832 3) `\\[gnus-browse-exit]' to return to the group buffer."
 833   (interactive)
 834   (kill-all-local-variables)
 835   (when (gnus-visual-p 'browse-menu 'menu)
 836     (gnus-browse-make-menu-bar))
 837   (gnus-simplify-mode-line)
 838   (setq major-mode 'gnus-browse-mode)
 839   (setq mode-name "Browse Server")
 840   (setq mode-line-process nil)
 841   (use-local-map gnus-browse-mode-map)
 842   (buffer-disable-undo)
 843   (setq truncate-lines t)
 844   (gnus-set-default-directory)
 845   (setq buffer-read-only t)
 846   (gnus-run-hooks 'gnus-browse-mode-hook))
 847
 848 (defun gnus-browse-read-group (&optional no-article)
 849   "Enter the group at the current line."
 850   (interactive)
 851   (let ((group (gnus-browse-group-name)))
 852     (if (or (not (gnus-get-info group))
 853             (gnus-ephemeral-group-p group))
 854         (unless (gnus-group-read-ephemeral-group
 855                  group gnus-browse-current-method nil
 856                  (cons (current-buffer) 'browse))
 857           (error "Couldn't enter %s" group))
 858       (unless (gnus-group-read-group nil no-article group)
 859         (error "Couldn't enter %s" group)))))
 860
 861 (defun gnus-browse-select-group ()
 862   "Select the current group."
 863   (interactive)
 864   (gnus-browse-read-group 'no))
 865
 866 (defun gnus-browse-next-group (n)
 867   "Go to the next group."
 868   (interactive "p")
 869   (prog1
 870       (forward-line n)
 871     (gnus-group-position-point)))
 872
 873 (defun gnus-browse-prev-group (n)
 874   "Go to the next group."
 875   (interactive "p")
 876   (gnus-browse-next-group (- n)))
 877
 878 (defun gnus-browse-unsubscribe-current-group (arg)
 879   "(Un)subscribe to the next ARG groups."
 880   (interactive "p")
 881   (when (eobp)
 882     (error "No group at current line"))
 883   (let ((ward (if (< arg 0) -1 1))
 884         (arg (abs arg)))
 885     (while (and (> arg 0)
 886                 (not (eobp))
 887                 (gnus-browse-unsubscribe-group)
 888                 (zerop (gnus-browse-next-group ward)))
 889       (decf arg))
 890     (gnus-group-position-point)
 891     (when (/= 0 arg)
 892       (gnus-message 7 "No more newsgroups"))
 893     arg))
 894
 895 (defun gnus-browse-group-name ()
 896   (save-excursion
 897     (beginning-of-line)
 898     (let ((name (get-text-property (point) 'gnus-group)))
 899       (when (re-search-forward ": \\(.*\\)$" (gnus-point-at-eol) t)
 900         (concat (gnus-method-to-server-name gnus-browse-current-method) ":"
 901                 (or name
 902                     (match-string-no-properties 1)))))))
 903
 904 (defun gnus-browse-describe-group (group)
 905   "Describe the current group."
 906   (interactive (list (gnus-browse-group-name)))
 907   (gnus-group-describe-group nil group))
 908
 909 (defun gnus-browse-unsubscribe-group ()
 910   "Toggle subscription of the current group in the browse buffer."
 911   (let ((sub nil)
 912         (buffer-read-only nil)
 913         group)
 914     (save-excursion
 915       (beginning-of-line)
 916       ;; If this group it killed, then we want to subscribe it.
 917       (unless (eq (char-after) ? )
 918         (setq sub t))
 919       (setq group (gnus-browse-group-name))
 920       (when (gnus-server-equal gnus-browse-current-method "native")
 921         (setq group (gnus-group-real-name group)))
 922       (if sub
 923           (progn
 924             ;; Make sure the group has been properly removed before we
 925             ;; subscribe to it.
 926             (gnus-kill-ephemeral-group group)
 927             (gnus-group-change-level
 928              (list t group gnus-level-default-subscribed
 929                    nil nil (if (gnus-server-equal
 930                                 gnus-browse-current-method "native")
 931                                nil
 932                              (gnus-method-simplify
 933                               gnus-browse-current-method)))
 934              gnus-level-default-subscribed (gnus-group-level group)
 935              (and (car (nth 1 gnus-newsrc-alist))
 936                   (gnus-gethash (car (nth 1 gnus-newsrc-alist))
 937                                 gnus-newsrc-hashtb))
 938              t)
 939             (delete-char 1)
 940             (insert ? ))
 941         (gnus-group-change-level
 942          group gnus-level-unsubscribed gnus-level-default-subscribed)
 943         (delete-char 1)
 944         (insert ?U)))
 945     t))
 946
 947 (defun gnus-browse-exit ()
 948   "Quit browsing and return to the group buffer."
 949   (interactive)
 950   (when (eq major-mode 'gnus-browse-mode)
 951     (gnus-kill-buffer (current-buffer)))
 952   ;; Insert the newly subscribed groups in the group buffer.
 953   (save-excursion
 954     (set-buffer gnus-group-buffer)
 955     (gnus-group-list-groups nil))
 956   (if gnus-browse-return-buffer
 957       (gnus-configure-windows 'server 'force)
 958     (gnus-configure-windows 'group 'force)))
 959
 960 (defun gnus-browse-describe-briefly ()
 961   "Give a one line description of the group mode commands."
 962   (interactive)
 963   (gnus-message 6
 964                 (substitute-command-keys "\\<gnus-browse-mode-map>\\[gnus-group-next-group]:Forward  \\[gnus-group-prev-group]:Backward  \\[gnus-browse-exit]:Exit  \\[gnus-info-find-node]:Run Info  \\[gnus-browse-describe-briefly]:This help")))
 965
 966 (defun gnus-server-regenerate-server ()
 967   "Issue a command to the server to regenerate all its data structures."
 968   (interactive)
 969   (let ((server (gnus-server-server-name)))
 970     (unless server
 971       (error "No server on the current line"))
 972     (condition-case ()
 973         (gnus-get-function (gnus-server-to-method server)
 974                            'request-regenerate)
 975       (error
 976         (error "This backend doesn't support regeneration")))
 977     (gnus-message 5 "Requesting regeneration of %s..." server)
 978     (unless (gnus-open-server server)
 979       (error "Couldn't open server"))
 980     (if (gnus-request-regenerate server)
 981         (gnus-message 5 "Requesting regeneration of %s...done" server)
 982       (gnus-message 5 "Couldn't regenerate %s" server))))
 983
 984 (provide 'gnus-srvr)
 985
 986 ;;; gnus-srvr.el ends here