cgit.sxemacs.org Git - gnus/blob - lisp/gnus-srvr.el

   1 ;;; gnus-srvr.el --- virtual server support for Gnus
   2
   3 ;; Copyright (C) 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003,
   4 ;;   2004, 2005 Free Software Foundation, Inc.
   5
   6 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   7 ;; Keywords: news
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  24 ;; Boston, MA 02110-1301, USA.
  25
  26 ;;; Commentary:
  27
  28 ;;; Code:
  29
  30 (eval-when-compile (require 'cl))
  31
  32 (require 'gnus)
  33 (require 'gnus-spec)
  34 (require 'gnus-group)
  35 (require 'gnus-int)
  36 (require 'gnus-range)
  37
  38 (defcustom gnus-server-mode-hook nil
  39   "Hook run in `gnus-server-mode' buffers."
  40   :group 'gnus-server
  41   :type 'hook)
  42
  43 (defcustom gnus-server-exit-hook nil
  44   "Hook run when exiting the server buffer."
  45   :group 'gnus-server
  46   :type 'hook)
  47
  48 (defcustom gnus-server-line-format "     {%(%h:%w%)} %s%a\n"
  49   "Format of server lines.
  50 It works along the same lines as a normal formatting string,
  51 with some simple extensions.
  52
  53 The following specs are understood:
  54
  55 %h back end
  56 %n name
  57 %w address
  58 %s status
  59 %a agent covered
  60
  61 General format specifiers can also be used.
  62 See Info node `(gnus)Formatting Variables'."
  63   :link '(custom-manual "(gnus)Formatting Variables")
  64   :group 'gnus-server-visual
  65   :type 'string)
  66
  67 (defcustom gnus-server-mode-line-format "Gnus: %%b"
  68   "The format specification for the server mode line."
  69   :group 'gnus-server-visual
  70   :type 'string)
  71
  72 (defcustom gnus-server-browse-in-group-buffer nil
  73   "Whether server browsing should take place in the group buffer.
  74 If nil, a faster, but more primitive, buffer is used instead."
  75   :version "22.1"
  76   :group 'gnus-server-visual
  77   :type 'boolean)
  78
  79 ;;; Internal variables.
  80
  81 (defvar gnus-inserted-opened-servers nil)
  82
  83 (defvar gnus-server-line-format-alist
  84   `((?h gnus-tmp-how ?s)
  85     (?n gnus-tmp-name ?s)
  86     (?w gnus-tmp-where ?s)
  87     (?s gnus-tmp-status ?s)
  88     (?a gnus-tmp-agent ?s)))
  89
  90 (defvar gnus-server-mode-line-format-alist
  91   `((?S gnus-tmp-news-server ?s)
  92     (?M gnus-tmp-news-method ?s)
  93     (?u gnus-tmp-user-defined ?s)))
  94
  95 (defvar gnus-server-line-format-spec nil)
  96 (defvar gnus-server-mode-line-format-spec nil)
  97 (defvar gnus-server-killed-servers nil)
  98
  99 (defvar gnus-server-mode-map)
 100
 101 (defvar gnus-server-menu-hook nil
 102   "*Hook run after the creation of the server mode menu.")
 103
 104 (defun gnus-server-make-menu-bar ()
 105   (gnus-turn-off-edit-menu 'server)
 106   (unless (boundp 'gnus-server-server-menu)
 107     (easy-menu-define
 108      gnus-server-server-menu gnus-server-mode-map ""
 109      '("Server"
 110        ["Add..." gnus-server-add-server t]
 111        ["Browse" gnus-server-read-server t]
 112        ["Scan" gnus-server-scan-server t]
 113        ["List" gnus-server-list-servers t]
 114        ["Kill" gnus-server-kill-server t]
 115        ["Yank" gnus-server-yank-server t]
 116        ["Copy" gnus-server-copy-server t]
 117        ["Edit" gnus-server-edit-server t]
 118        ["Regenerate" gnus-server-regenerate-server t]
 119        ["Compact" gnus-server-compact-server t]
 120        ["Exit" gnus-server-exit t]))
 121
 122     (easy-menu-define
 123      gnus-server-connections-menu gnus-server-mode-map ""
 124      '("Connections"
 125        ["Open" gnus-server-open-server t]
 126        ["Close" gnus-server-close-server t]
 127        ["Offline" gnus-server-offline-server t]
 128        ["Deny" gnus-server-deny-server t]
 129        "---"
 130        ["Open All" gnus-server-open-all-servers t]
 131        ["Close All" gnus-server-close-all-servers t]
 132        ["Reset All" gnus-server-remove-denials t]))
 133
 134     (gnus-run-hooks 'gnus-server-menu-hook)))
 135
 136 (defvar gnus-server-mode-map nil)
 137 (put 'gnus-server-mode 'mode-class 'special)
 138
 139 (unless gnus-server-mode-map
 140   (setq gnus-server-mode-map (make-sparse-keymap))
 141   (suppress-keymap gnus-server-mode-map)
 142
 143   (gnus-define-keys gnus-server-mode-map
 144     " " gnus-server-read-server-in-server-buffer
 145     "\r" gnus-server-read-server
 146     gnus-mouse-2 gnus-server-pick-server
 147     "q" gnus-server-exit
 148     "l" gnus-server-list-servers
 149     "k" gnus-server-kill-server
 150     "y" gnus-server-yank-server
 151     "c" gnus-server-copy-server
 152     "a" gnus-server-add-server
 153     "e" gnus-server-edit-server
 154     "s" gnus-server-scan-server
 155
 156     "O" gnus-server-open-server
 157     "\M-o" gnus-server-open-all-servers
 158     "C" gnus-server-close-server
 159     "\M-c" gnus-server-close-all-servers
 160     "D" gnus-server-deny-server
 161     "L" gnus-server-offline-server
 162     "R" gnus-server-remove-denials
 163
 164     "n" next-line
 165     "p" previous-line
 166
 167     "g" gnus-server-regenerate-server
 168
 169     "z" gnus-server-compact-server
 170
 171     "\C-c\C-i" gnus-info-find-node
 172     "\C-c\C-b" gnus-bug))
 173
 174 (defface gnus-server-agent
 175   '((((class color) (background light)) (:foreground "PaleTurquoise" :bold t))
 176     (((class color) (background dark)) (:foreground "PaleTurquoise" :bold t))
 177     (t (:bold t)))
 178   "Face used for displaying AGENTIZED servers"
 179   :group 'gnus-server-visual)
 180 ;; backward-compatibility alias
 181 (put 'gnus-server-agent-face 'face-alias 'gnus-server-agent)
 182
 183 (defface gnus-server-opened
 184   '((((class color) (background light)) (:foreground "Green3" :bold t))
 185     (((class color) (background dark)) (:foreground "Green1" :bold t))
 186     (t (:bold t)))
 187   "Face used for displaying OPENED servers"
 188   :group 'gnus-server-visual)
 189 ;; backward-compatibility alias
 190 (put 'gnus-server-opened-face 'face-alias 'gnus-server-opened)
 191
 192 (defface gnus-server-closed
 193   '((((class color) (background light)) (:foreground "Steel Blue" :italic t))
 194     (((class color) (background dark))
 195      (:foreground "Light Steel Blue" :italic t))
 196     (t (:italic t)))
 197   "Face used for displaying CLOSED servers"
 198   :group 'gnus-server-visual)
 199 ;; backward-compatibility alias
 200 (put 'gnus-server-closed-face 'face-alias 'gnus-server-closed)
 201
 202 (defface gnus-server-denied
 203   '((((class color) (background light)) (:foreground "Red" :bold t))
 204     (((class color) (background dark)) (:foreground "Pink" :bold t))
 205     (t (:inverse-video t :bold t)))
 206   "Face used for displaying DENIED servers"
 207   :group 'gnus-server-visual)
 208 ;; backward-compatibility alias
 209 (put 'gnus-server-denied-face 'face-alias 'gnus-server-denied)
 210
 211 (defface gnus-server-offline
 212   '((((class color) (background light)) (:foreground "Orange" :bold t))
 213     (((class color) (background dark)) (:foreground "Yellow" :bold t))
 214     (t (:inverse-video t :bold t)))
 215   "Face used for displaying OFFLINE servers"
 216   :group 'gnus-server-visual)
 217 ;; backward-compatibility alias
 218 (put 'gnus-server-offline-face 'face-alias 'gnus-server-offline)
 219
 220 (defcustom gnus-server-agent-face 'gnus-server-agent
 221   "Face name to use on AGENTIZED servers."
 222   :version "22.1"
 223   :group 'gnus-server-visual
 224   :type 'face)
 225
 226 (defcustom gnus-server-opened-face 'gnus-server-opened
 227   "Face name to use on OPENED servers."
 228   :version "22.1"
 229   :group 'gnus-server-visual
 230   :type 'face)
 231
 232 (defcustom gnus-server-closed-face 'gnus-server-closed
 233   "Face name to use on CLOSED servers."
 234   :version "22.1"
 235   :group 'gnus-server-visual
 236   :type 'face)
 237
 238 (defcustom gnus-server-denied-face 'gnus-server-denied
 239   "Face name to use on DENIED servers."
 240   :version "22.1"
 241   :group 'gnus-server-visual
 242   :type 'face)
 243
 244 (defcustom gnus-server-offline-face 'gnus-server-offline
 245   "Face name to use on OFFLINE servers."
 246   :version "22.1"
 247   :group 'gnus-server-visual
 248   :type 'face)
 249
 250 (defvar gnus-server-font-lock-keywords
 251   (list
 252    '("(\\(agent\\))" 1 gnus-server-agent-face)
 253    '("(\\(opened\\))" 1 gnus-server-opened-face)
 254    '("(\\(closed\\))" 1 gnus-server-closed-face)
 255    '("(\\(offline\\))" 1 gnus-server-offline-face)
 256    '("(\\(denied\\))" 1 gnus-server-denied-face)))
 257
 258 (defun gnus-server-mode ()
 259   "Major mode for listing and editing servers.
 260
 261 All normal editing commands are switched off.
 262 \\<gnus-server-mode-map>
 263 For more in-depth information on this mode, read the manual
 264 \(`\\[gnus-info-find-node]').
 265
 266 The following commands are available:
 267
 268 \\{gnus-server-mode-map}"
 269   (interactive)
 270   (when (gnus-visual-p 'server-menu 'menu)
 271     (gnus-server-make-menu-bar))
 272   (kill-all-local-variables)
 273   (gnus-simplify-mode-line)
 274   (setq major-mode 'gnus-server-mode)
 275   (setq mode-name "Server")
 276   (gnus-set-default-directory)
 277   (setq mode-line-process nil)
 278   (use-local-map gnus-server-mode-map)
 279   (buffer-disable-undo)
 280   (setq truncate-lines t)
 281   (setq buffer-read-only t)
 282   (if (featurep 'xemacs)
 283       (put 'gnus-server-mode 'font-lock-defaults '(gnus-server-font-lock-keywords t))
 284     (set (make-local-variable 'font-lock-defaults)
 285          '(gnus-server-font-lock-keywords t)))
 286   (gnus-run-mode-hooks 'gnus-server-mode-hook))
 287
 288 (defun gnus-server-insert-server-line (gnus-tmp-name method)
 289   (let* ((gnus-tmp-how (car method))
 290          (gnus-tmp-where (nth 1 method))
 291          (elem (assoc method gnus-opened-servers))
 292          (gnus-tmp-status
 293           (cond
 294            ((eq (nth 1 elem) 'denied) "(denied)")
 295            ((eq (nth 1 elem) 'offline) "(offline)")
 296            (t
 297             (condition-case nil
 298                 (if (or (gnus-server-opened method)
 299                         (eq (nth 1 elem) 'ok))
 300                     "(opened)"
 301                   "(closed)")
 302               ((error) "(error)")))))
 303          (gnus-tmp-agent (if (and gnus-agent
 304                                   (gnus-agent-method-p method))
 305                              " (agent)"
 306                            "")))
 307     (beginning-of-line)
 308     (gnus-add-text-properties
 309      (point)
 310      (prog1 (1+ (point))
 311        ;; Insert the text.
 312        (eval gnus-server-line-format-spec))
 313      (list 'gnus-server (intern gnus-tmp-name)
 314            'gnus-named-server (intern (gnus-method-to-server method))))))
 315
 316 (defun gnus-enter-server-buffer ()
 317   "Set up the server buffer."
 318   (gnus-server-setup-buffer)
 319   (gnus-configure-windows 'server)
 320   (gnus-server-prepare))
 321
 322 (defun gnus-server-setup-buffer ()
 323   "Initialize the server buffer."
 324   (unless (get-buffer gnus-server-buffer)
 325     (save-excursion
 326       (set-buffer (gnus-get-buffer-create gnus-server-buffer))
 327       (gnus-server-mode)
 328       (when gnus-carpal
 329         (gnus-carpal-setup-buffer 'server)))))
 330
 331 (defun gnus-server-prepare ()
 332   (gnus-set-format 'server-mode)
 333   (gnus-set-format 'server t)
 334   (let ((alist gnus-server-alist)
 335         (buffer-read-only nil)
 336         done server op-ser)
 337     (erase-buffer)
 338     (setq gnus-inserted-opened-servers nil)
 339     ;; First we do the real list of servers.
 340     (while alist
 341       (unless (member (cdar alist) done)
 342         (push (cdar alist) done)
 343         (setq server (pop alist))
 344         (when (and server (car server) (cdr server))
 345           (gnus-server-insert-server-line (car server) (cdr server))))
 346       (when (member (cdar alist) done)
 347         (pop alist)))
 348     ;; Then we insert the list of servers that have been opened in
 349     ;; this session.
 350     (dolist (open gnus-opened-servers)
 351       (when (and (not (member (car open) done))
 352                  ;; Just ignore ephemeral servers.
 353                  (not (member (car open) gnus-ephemeral-servers)))
 354         (push (car open) done)
 355         (gnus-server-insert-server-line
 356          (setq op-ser (format "%s:%s" (caar open) (nth 1 (car open))))
 357          (car open))
 358         (push (list op-ser (car open)) gnus-inserted-opened-servers))))
 359   (goto-char (point-min))
 360   (gnus-server-position-point))
 361
 362 (defun gnus-server-server-name ()
 363   (let ((server (get-text-property (point-at-bol) 'gnus-server)))
 364     (and server (symbol-name server))))
 365
 366 (defun gnus-server-named-server ()
 367   "Return a server name that matches one of the names returned by
 368 `gnus-method-to-server'."
 369   (let ((server (get-text-property (point-at-bol) 'gnus-named-server)))
 370     (and server (symbol-name server))))
 371
 372 (defalias 'gnus-server-position-point 'gnus-goto-colon)
 373
 374 (defconst gnus-server-edit-buffer "*Gnus edit server*")
 375
 376 (defun gnus-server-update-server (server)
 377   (save-excursion
 378     (set-buffer gnus-server-buffer)
 379     (let* ((buffer-read-only nil)
 380            (entry (assoc server gnus-server-alist))
 381            (oentry (assoc (gnus-server-to-method server)
 382                           gnus-opened-servers)))
 383       (when entry
 384         (gnus-dribble-enter
 385          (concat "(gnus-server-set-info \"" server "\" '"
 386                  (gnus-prin1-to-string (cdr entry)) ")\n")))
 387       (when (or entry oentry)
 388         ;; Buffer may be narrowed.
 389         (save-restriction
 390           (widen)
 391           (when (gnus-server-goto-server server)
 392             (gnus-delete-line))
 393           (if entry
 394               (gnus-server-insert-server-line (car entry) (cdr entry))
 395             (gnus-server-insert-server-line
 396              (format "%s:%s" (caar oentry) (nth 1 (car oentry)))
 397              (car oentry)))
 398           (gnus-server-position-point))))))
 399
 400 (defun gnus-server-set-info (server info)
 401   ;; Enter a select method into the virtual server alist.
 402   (when (and server info)
 403     (gnus-dribble-enter
 404      (concat "(gnus-server-set-info \"" server "\" '"
 405              (gnus-prin1-to-string info) ")"))
 406     (let* ((server (nth 1 info))
 407            (entry (assoc server gnus-server-alist))
 408            (cached (assoc server gnus-server-method-cache)))
 409       (if cached
 410           (setq gnus-server-method-cache
 411                 (delq cached gnus-server-method-cache)))
 412       (if entry
 413           (progn
 414             ;; Remove the server from `gnus-opened-servers' since
 415             ;; it has never been opened with the new `info' yet.
 416             (gnus-opened-servers-remove (cdr entry))
 417             ;; Don't make a new Lisp object.
 418             (setcar (cdr entry) (car info))
 419             (setcdr (cdr entry) (cdr info)))
 420         (setq gnus-server-alist
 421               (nconc gnus-server-alist (list (cons server info))))))))
 422
 423 ;;; Interactive server functions.
 424
 425 (defun gnus-server-kill-server (server)
 426   "Kill the server on the current line."
 427   (interactive (list (gnus-server-server-name)))
 428   (unless (gnus-server-goto-server server)
 429     (if server (error "No such server: %s" server)
 430       (error "No server on the current line")))
 431   (unless (assoc server gnus-server-alist)
 432     (error "Read-only server %s" server))
 433   (gnus-dribble-touch)
 434   (let ((buffer-read-only nil))
 435     (gnus-delete-line))
 436   (push (assoc server gnus-server-alist) gnus-server-killed-servers)
 437   (setq gnus-server-alist (delq (car gnus-server-killed-servers)
 438                                 gnus-server-alist))
 439   (let ((groups (gnus-groups-from-server server)))
 440     (when (and groups
 441                (gnus-yes-or-no-p
 442                 (format "Kill all %s groups from this server? "
 443                         (length groups))))
 444       (dolist (group groups)
 445         (setq gnus-newsrc-alist
 446               (delq (assoc group gnus-newsrc-alist)
 447                     gnus-newsrc-alist))
 448         (when gnus-group-change-level-function
 449           (funcall gnus-group-change-level-function
 450                    group gnus-level-killed 3)))))
 451   (gnus-server-position-point))
 452
 453 (defun gnus-server-yank-server ()
 454   "Yank the previously killed server."
 455   (interactive)
 456   (unless gnus-server-killed-servers
 457     (error "No killed servers to be yanked"))
 458   (let ((alist gnus-server-alist)
 459         (server (gnus-server-server-name))
 460         (killed (car gnus-server-killed-servers)))
 461     (if (not server)
 462         (setq gnus-server-alist (nconc gnus-server-alist (list killed)))
 463       (if (string= server (caar gnus-server-alist))
 464           (push killed gnus-server-alist)
 465         (while (and (cdr alist)
 466                     (not (string= server (caadr alist))))
 467           (setq alist (cdr alist)))
 468         (if alist
 469             (setcdr alist (cons killed (cdr alist)))
 470           (setq gnus-server-alist (list killed)))))
 471     (gnus-server-update-server (car killed))
 472     (setq gnus-server-killed-servers (cdr gnus-server-killed-servers))
 473     (gnus-server-position-point)))
 474
 475 (defun gnus-server-exit ()
 476   "Return to the group buffer."
 477   (interactive)
 478   (gnus-run-hooks 'gnus-server-exit-hook)
 479   (gnus-kill-buffer (current-buffer))
 480   (gnus-configure-windows 'group t))
 481
 482 (defun gnus-server-list-servers ()
 483   "List all available servers."
 484   (interactive)
 485   (let ((cur (gnus-server-server-name)))
 486     (gnus-server-prepare)
 487     (if cur (gnus-server-goto-server cur)
 488       (goto-char (point-max))
 489       (forward-line -1))
 490     (gnus-server-position-point)))
 491
 492 (defun gnus-server-set-status (method status)
 493   "Make METHOD have STATUS."
 494   (let ((entry (assoc method gnus-opened-servers)))
 495     (if entry
 496         (setcar (cdr entry) status)
 497       (push (list method status) gnus-opened-servers))))
 498
 499 (defun gnus-opened-servers-remove (method)
 500   "Remove METHOD from the list of opened servers."
 501   (setq gnus-opened-servers (delq (assoc method gnus-opened-servers)
 502                                   gnus-opened-servers)))
 503
 504 (defun gnus-server-open-server (server)
 505   "Force an open of SERVER."
 506   (interactive (list (gnus-server-server-name)))
 507   (let ((method (gnus-server-to-method server)))
 508     (unless method
 509       (error "No such server: %s" server))
 510     (gnus-server-set-status method 'ok)
 511     (prog1
 512         (or (gnus-open-server method)
 513             (progn (message "Couldn't open %s" server) nil))
 514       (gnus-server-update-server server)
 515       (gnus-server-position-point))))
 516
 517 (defun gnus-server-open-all-servers ()
 518   "Open all servers."
 519   (interactive)
 520   (dolist (server gnus-inserted-opened-servers)
 521     (gnus-server-open-server (car server))))
 522
 523 (defun gnus-server-close-server (server)
 524   "Close SERVER."
 525   (interactive (list (gnus-server-server-name)))
 526   (let ((method (gnus-server-to-method server)))
 527     (unless method
 528       (error "No such server: %s" server))
 529     (gnus-server-set-status method 'closed)
 530     (prog1
 531         (gnus-close-server method)
 532       (gnus-server-update-server server)
 533       (gnus-server-position-point))))
 534
 535 (defun gnus-server-offline-server (server)
 536   "Set SERVER to offline."
 537   (interactive (list (gnus-server-server-name)))
 538   (let ((method (gnus-server-to-method server)))
 539     (unless method
 540       (error "No such server: %s" server))
 541     (prog1
 542         (gnus-close-server method)
 543       (gnus-server-set-status method 'offline)
 544       (gnus-server-update-server server)
 545       (gnus-server-position-point))))
 546
 547 (defun gnus-server-close-all-servers ()
 548   "Close all servers."
 549   (interactive)
 550   (dolist (server gnus-inserted-opened-servers)
 551     (gnus-server-close-server (car server))))
 552
 553 (defun gnus-server-deny-server (server)
 554   "Make sure SERVER will never be attempted opened."
 555   (interactive (list (gnus-server-server-name)))
 556   (let ((method (gnus-server-to-method server)))
 557     (unless method
 558       (error "No such server: %s" server))
 559     (gnus-server-set-status method 'denied))
 560   (gnus-server-update-server server)
 561   (gnus-server-position-point)
 562   t)
 563
 564 (defun gnus-server-remove-denials ()
 565   "Make all denied servers into closed servers."
 566   (interactive)
 567   (dolist (server gnus-opened-servers)
 568     (when (eq (nth 1 server) 'denied)
 569       (setcar (nthcdr 1 server) 'closed)))
 570   (gnus-server-list-servers))
 571
 572 (defun gnus-server-copy-server (from to)
 573   (interactive
 574    (list
 575     (or (gnus-server-server-name)
 576         (error "No server on the current line"))
 577     (read-string "Copy to: ")))
 578   (unless from
 579     (error "No server on current line"))
 580   (unless (and to (not (string= to "")))
 581     (error "No name to copy to"))
 582   (when (assoc to gnus-server-alist)
 583     (error "%s already exists" to))
 584   (unless (gnus-server-to-method from)
 585     (error "%s: no such server" from))
 586   (let ((to-entry (cons from (gnus-copy-sequence
 587                               (gnus-server-to-method from)))))
 588     (setcar to-entry to)
 589     (setcar (nthcdr 2 to-entry) to)
 590     (push to-entry gnus-server-killed-servers)
 591     (gnus-server-yank-server)))
 592
 593 (defun gnus-server-add-server (how where)
 594   (interactive
 595    (list (intern (completing-read "Server method: "
 596                                   gnus-valid-select-methods nil t))
 597          (read-string "Server name: ")))
 598   (when (assq where gnus-server-alist)
 599     (error "Server with that name already defined"))
 600   (push (list where how where) gnus-server-killed-servers)
 601   (gnus-server-yank-server))
 602
 603 (defun gnus-server-goto-server (server)
 604   "Jump to a server line."
 605   (interactive
 606    (list (completing-read "Goto server: " gnus-server-alist nil t)))
 607   (let ((to (text-property-any (point-min) (point-max)
 608                                'gnus-server (intern server))))
 609     (when to
 610       (goto-char to)
 611       (gnus-server-position-point))))
 612
 613 (defun gnus-server-edit-server (server)
 614   "Edit the server on the current line."
 615   (interactive (list (gnus-server-server-name)))
 616   (unless server
 617     (error "No server on current line"))
 618   (unless (assoc server gnus-server-alist)
 619     (error "This server can't be edited"))
 620   (let ((info (cdr (assoc server gnus-server-alist))))
 621     (gnus-close-server info)
 622     (gnus-edit-form
 623      info "Editing the server."
 624      `(lambda (form)
 625         (gnus-server-set-info ,server form)
 626         (gnus-server-list-servers)
 627         (gnus-server-position-point)))))
 628
 629 (defun gnus-server-scan-server (server)
 630   "Request a scan from the current server."
 631   (interactive (list (gnus-server-server-name)))
 632   (let ((method (gnus-server-to-method server)))
 633     (if (not (gnus-get-function method 'request-scan))
 634         (error "Server %s can't scan" (car method))
 635       (gnus-message 3 "Scanning %s..." server)
 636       (gnus-request-scan nil method)
 637       (gnus-message 3 "Scanning %s...done" server))))
 638
 639 (defun gnus-server-read-server-in-server-buffer (server)
 640   "Browse a server in server buffer."
 641   (interactive (list (gnus-server-server-name)))
 642   (let (gnus-server-browse-in-group-buffer)
 643     (gnus-server-read-server server)))
 644
 645 (defun gnus-server-read-server (server)
 646   "Browse a server."
 647   (interactive (list (gnus-server-server-name)))
 648   (let ((buf (current-buffer)))
 649     (prog1
 650         (gnus-browse-foreign-server server buf)
 651       (save-excursion
 652         (set-buffer buf)
 653         (gnus-server-update-server (gnus-server-server-name))
 654         (gnus-server-position-point)))))
 655
 656 (defun gnus-server-pick-server (e)
 657   (interactive "e")
 658   (mouse-set-point e)
 659   (gnus-server-read-server (gnus-server-server-name)))
 660
 661 \f
 662 ;;;
 663 ;;; Browse Server Mode
 664 ;;;
 665
 666 (defvar gnus-browse-menu-hook nil
 667   "*Hook run after the creation of the browse mode menu.")
 668
 669 (defvar gnus-browse-mode-hook nil)
 670 (defvar gnus-browse-mode-map nil)
 671 (put 'gnus-browse-mode 'mode-class 'special)
 672
 673 (unless gnus-browse-mode-map
 674   (setq gnus-browse-mode-map (make-keymap))
 675   (suppress-keymap gnus-browse-mode-map)
 676
 677   (gnus-define-keys
 678       gnus-browse-mode-map
 679     " " gnus-browse-read-group
 680     "=" gnus-browse-select-group
 681     "n" gnus-browse-next-group
 682     "p" gnus-browse-prev-group
 683     "\177" gnus-browse-prev-group
 684     [delete] gnus-browse-prev-group
 685     "N" gnus-browse-next-group
 686     "P" gnus-browse-prev-group
 687     "\M-n" gnus-browse-next-group
 688     "\M-p" gnus-browse-prev-group
 689     "\r" gnus-browse-select-group
 690     "u" gnus-browse-unsubscribe-current-group
 691     "l" gnus-browse-exit
 692     "L" gnus-browse-exit
 693     "q" gnus-browse-exit
 694     "Q" gnus-browse-exit
 695     "d" gnus-browse-describe-group
 696     "\C-c\C-c" gnus-browse-exit
 697     "?" gnus-browse-describe-briefly
 698
 699     "\C-c\C-i" gnus-info-find-node
 700     "\C-c\C-b" gnus-bug))
 701
 702 (defun gnus-browse-make-menu-bar ()
 703   (gnus-turn-off-edit-menu 'browse)
 704   (unless (boundp 'gnus-browse-menu)
 705     (easy-menu-define
 706      gnus-browse-menu gnus-browse-mode-map ""
 707      '("Browse"
 708        ["Subscribe" gnus-browse-unsubscribe-current-group t]
 709        ["Read" gnus-browse-read-group t]
 710        ["Select" gnus-browse-select-group t]
 711        ["Describe" gnus-browse-describe-group t]
 712        ["Next" gnus-browse-next-group t]
 713        ["Prev" gnus-browse-prev-group t]
 714        ["Exit" gnus-browse-exit t]))
 715     (gnus-run-hooks 'gnus-browse-menu-hook)))
 716
 717 (defvar gnus-browse-current-method nil)
 718 (defvar gnus-browse-return-buffer nil)
 719
 720 (defvar gnus-browse-buffer "*Gnus Browse Server*")
 721
 722 (defun gnus-browse-foreign-server (server &optional return-buffer)
 723   "Browse the server SERVER."
 724   (setq gnus-browse-current-method (gnus-server-to-method server))
 725   (setq gnus-browse-return-buffer return-buffer)
 726   (let* ((method gnus-browse-current-method)
 727          (orig-select-method gnus-select-method)
 728          (gnus-select-method method)
 729          groups group)
 730     (gnus-message 5 "Connecting to %s..." (nth 1 method))
 731     (cond
 732      ((not (gnus-check-server method))
 733       (gnus-message
 734        1 "Unable to contact server %s: %s" (nth 1 method)
 735        (gnus-status-message method))
 736       nil)
 737      ((not
 738        (prog2
 739            (gnus-message 6 "Reading active file...")
 740            (gnus-request-list method)
 741          (gnus-message 6 "Reading active file...done")))
 742       (gnus-message
 743        1 "Couldn't request list: %s" (gnus-status-message method))
 744       nil)
 745      (t
 746       (with-current-buffer nntp-server-buffer
 747         (let ((cur (current-buffer)))
 748           (goto-char (point-min))
 749           (unless (string= gnus-ignored-newsgroups "")
 750             (delete-matching-lines gnus-ignored-newsgroups))
 751           ;; We treat NNTP as a special case to avoid problems with
 752           ;; garbage group names like `"foo' that appear in some badly
 753           ;; managed active files. -jh.
 754           (if (eq (car method) 'nntp)
 755               (while (not (eobp))
 756                 (ignore-errors
 757                   (push (cons
 758                          (buffer-substring
 759                           (point)
 760                           (progn
 761                             (skip-chars-forward "^ \t")
 762                             (point)))
 763                          (let ((last (read cur)))
 764                            (cons (read cur) last)))
 765                         groups))
 766                 (forward-line))
 767             (while (not (eobp))
 768               (ignore-errors
 769                 (push (cons
 770                        (if (eq (char-after) ?\")
 771                            (read cur)
 772                          (let ((p (point)) (name ""))
 773                            (skip-chars-forward "^ \t\\\\")
 774                            (setq name (buffer-substring p (point)))
 775                            (while (eq (char-after) ?\\)
 776                              (setq p (1+ (point)))
 777                              (forward-char 2)
 778                              (skip-chars-forward "^ \t\\\\")
 779                              (setq name (concat name (buffer-substring
 780                                                       p (point)))))
 781                            name))
 782                        (let ((last (read cur)))
 783                          (cons (read cur) last)))
 784                       groups))
 785               (forward-line)))))
 786       (setq groups (sort groups
 787                          (lambda (l1 l2)
 788                            (string< (car l1) (car l2)))))
 789       (if gnus-server-browse-in-group-buffer
 790           (let* ((gnus-select-method orig-select-method)
 791                  (gnus-group-listed-groups
 792                   (mapcar (lambda (group)
 793                             (let ((name
 794                                    (gnus-group-prefixed-name
 795                                     (car group) method)))
 796                               (gnus-set-active name (cdr group))
 797                               name))
 798                           groups)))
 799             (gnus-configure-windows 'group)
 800             (funcall gnus-group-prepare-function
 801                      gnus-level-killed 'ignore 1 'ignore))
 802         (gnus-get-buffer-create gnus-browse-buffer)
 803         (when gnus-carpal
 804           (gnus-carpal-setup-buffer 'browse))
 805         (gnus-configure-windows 'browse)
 806         (buffer-disable-undo)
 807         (let ((buffer-read-only nil))
 808           (erase-buffer))
 809         (gnus-browse-mode)
 810         (setq mode-line-buffer-identification
 811               (list
 812                (format
 813                 "Gnus: %%b {%s:%s}" (car method) (cadr method))))
 814         (let ((buffer-read-only nil)
 815               name
 816               (prefix (let ((gnus-select-method orig-select-method))
 817                         (gnus-group-prefixed-name "" method))))
 818           (while (setq group (pop groups))
 819             (gnus-add-text-properties
 820              (point)
 821              (prog1 (1+ (point))
 822                (insert
 823                 (format "%c%7d: %s\n"
 824                         (let ((level
 825                                (if (string= prefix "")
 826                                    (gnus-group-level (setq name (car group)))
 827                                  (gnus-group-level
 828                                   (concat prefix (setq name (car group)))))))
 829                           (cond
 830                            ((<= level gnus-level-subscribed) ? )
 831                            ((<= level gnus-level-unsubscribed) ?U)
 832                            ((= level gnus-level-zombie) ?Z)
 833                            (t ?K)))
 834                         (max 0 (- (1+ (cddr group)) (cadr group)))
 835                         ;; Don't decode if name is ASCII
 836                         (if (and (fboundp 'detect-coding-string)
 837                                  (eq (detect-coding-string name t) 'undecided))
 838                             name
 839                           (mm-decode-coding-string
 840                            name
 841                            (inline (gnus-group-name-charset method name)))))))
 842              (list 'gnus-group name)
 843              )))
 844         (switch-to-buffer (current-buffer)))
 845       (goto-char (point-min))
 846       (gnus-group-position-point)
 847       (gnus-message 5 "Connecting to %s...done" (nth 1 method))
 848       t))))
 849
 850 (defun gnus-browse-mode ()
 851   "Major mode for browsing a foreign server.
 852
 853 All normal editing commands are switched off.
 854
 855 \\<gnus-browse-mode-map>
 856 The only things you can do in this buffer is
 857
 858 1) `\\[gnus-browse-unsubscribe-current-group]' to subscribe to a group.
 859 The group will be inserted into the group buffer upon exit from this
 860 buffer.
 861
 862 2) `\\[gnus-browse-read-group]' to read a group ephemerally.
 863
 864 3) `\\[gnus-browse-exit]' to return to the group buffer."
 865   (interactive)
 866   (kill-all-local-variables)
 867   (when (gnus-visual-p 'browse-menu 'menu)
 868     (gnus-browse-make-menu-bar))
 869   (gnus-simplify-mode-line)
 870   (setq major-mode 'gnus-browse-mode)
 871   (setq mode-name "Browse Server")
 872   (setq mode-line-process nil)
 873   (use-local-map gnus-browse-mode-map)
 874   (buffer-disable-undo)
 875   (setq truncate-lines t)
 876   (gnus-set-default-directory)
 877   (setq buffer-read-only t)
 878   (gnus-run-mode-hooks 'gnus-browse-mode-hook))
 879
 880 (defun gnus-browse-read-group (&optional no-article number)
 881   "Enter the group at the current line.
 882 If NUMBER, fetch this number of articles."
 883   (interactive "P")
 884   (let ((group (gnus-browse-group-name)))
 885     (if (or (not (gnus-get-info group))
 886             (gnus-ephemeral-group-p group))
 887         (unless (gnus-group-read-ephemeral-group
 888                  group gnus-browse-current-method nil
 889                  (cons (current-buffer) 'browse)
 890                  nil nil nil number)
 891           (error "Couldn't enter %s" group))
 892       (unless (gnus-group-read-group nil no-article group)
 893         (error "Couldn't enter %s" group)))))
 894
 895 (defun gnus-browse-select-group (&optional number)
 896   "Select the current group.
 897 If NUMBER, fetch this number of articles."
 898   (interactive "P")
 899   (gnus-browse-read-group 'no number))
 900
 901 (defun gnus-browse-next-group (n)
 902   "Go to the next group."
 903   (interactive "p")
 904   (prog1
 905       (forward-line n)
 906     (gnus-group-position-point)))
 907
 908 (defun gnus-browse-prev-group (n)
 909   "Go to the next group."
 910   (interactive "p")
 911   (gnus-browse-next-group (- n)))
 912
 913 (defun gnus-browse-unsubscribe-current-group (arg)
 914   "(Un)subscribe to the next ARG groups."
 915   (interactive "p")
 916   (when (eobp)
 917     (error "No group at current line"))
 918   (let ((ward (if (< arg 0) -1 1))
 919         (arg (abs arg)))
 920     (while (and (> arg 0)
 921                 (not (eobp))
 922                 (gnus-browse-unsubscribe-group)
 923                 (zerop (gnus-browse-next-group ward)))
 924       (decf arg))
 925     (gnus-group-position-point)
 926     (when (/= 0 arg)
 927       (gnus-message 7 "No more newsgroups"))
 928     arg))
 929
 930 (defun gnus-browse-group-name ()
 931   (save-excursion
 932     (beginning-of-line)
 933     (let ((name (get-text-property (point) 'gnus-group)))
 934       (when (re-search-forward ": \\(.*\\)$" (point-at-eol) t)
 935         (concat (gnus-method-to-server-name gnus-browse-current-method) ":"
 936                 (or name
 937                     (match-string-no-properties 1)))))))
 938
 939 (defun gnus-browse-describe-group (group)
 940   "Describe the current group."
 941   (interactive (list (gnus-browse-group-name)))
 942   (gnus-group-describe-group nil group))
 943
 944 (defun gnus-browse-unsubscribe-group ()
 945   "Toggle subscription of the current group in the browse buffer."
 946   (let ((sub nil)
 947         (buffer-read-only nil)
 948         group)
 949     (save-excursion
 950       (beginning-of-line)
 951       ;; If this group it killed, then we want to subscribe it.
 952       (unless (eq (char-after) ? )
 953         (setq sub t))
 954       (setq group (gnus-browse-group-name))
 955       (when (gnus-server-equal gnus-browse-current-method "native")
 956         (setq group (gnus-group-real-name group)))
 957       (if sub
 958           (progn
 959             ;; Make sure the group has been properly removed before we
 960             ;; subscribe to it.
 961             (gnus-kill-ephemeral-group group)
 962             (gnus-group-change-level
 963              (list t group gnus-level-default-subscribed
 964                    nil nil (if (gnus-server-equal
 965                                 gnus-browse-current-method "native")
 966                                nil
 967                              (gnus-method-simplify
 968                               gnus-browse-current-method)))
 969              gnus-level-default-subscribed (gnus-group-level group)
 970              (and (car (nth 1 gnus-newsrc-alist))
 971                   (gnus-group-entry (car (nth 1 gnus-newsrc-alist))))
 972              t)
 973             (delete-char 1)
 974             (insert ? ))
 975         (gnus-group-change-level
 976          group gnus-level-unsubscribed gnus-level-default-subscribed)
 977         (delete-char 1)
 978         (insert ?U)))
 979     t))
 980
 981 (defun gnus-browse-exit ()
 982   "Quit browsing and return to the group buffer."
 983   (interactive)
 984   (when (eq major-mode 'gnus-browse-mode)
 985     (gnus-kill-buffer (current-buffer)))
 986   ;; Insert the newly subscribed groups in the group buffer.
 987   (save-excursion
 988     (set-buffer gnus-group-buffer)
 989     (gnus-group-list-groups nil))
 990   (if gnus-browse-return-buffer
 991       (gnus-configure-windows 'server 'force)
 992     (gnus-configure-windows 'group 'force)))
 993
 994 (defun gnus-browse-describe-briefly ()
 995   "Give a one line description of the group mode commands."
 996   (interactive)
 997   (gnus-message 6
 998                 (substitute-command-keys "\\<gnus-browse-mode-map>\\[gnus-group-next-group]:Forward  \\[gnus-group-prev-group]:Backward  \\[gnus-browse-exit]:Exit  \\[gnus-info-find-node]:Run Info  \\[gnus-browse-describe-briefly]:This help")))
 999
1000 (defun gnus-server-regenerate-server ()
1001   "Issue a command to the server to regenerate all its data structures."
1002   (interactive)
1003   (let ((server (gnus-server-server-name)))
1004     (unless server
1005       (error "No server on the current line"))
1006     (condition-case ()
1007         (gnus-get-function (gnus-server-to-method server)
1008                            'request-regenerate)
1009       (error
1010         (error "This back end doesn't support regeneration")))
1011     (gnus-message 5 "Requesting regeneration of %s..." server)
1012     (unless (gnus-open-server server)
1013       (error "Couldn't open server"))
1014     (if (gnus-request-regenerate server)
1015         (gnus-message 5 "Requesting regeneration of %s...done" server)
1016       (gnus-message 5 "Couldn't regenerate %s" server))))
1017
1018
1019 ;;;
1020 ;;; Server compaction
1021 ;;;
1022
1023 ;; #### FIXME: this function currently fails to update the Group buffer's
1024 ;; #### FIXME: appearance. -- dvl
1025 (defun gnus-server-compact-server ()
1026   "Issue a command to the server to compact all its groups."
1027   (interactive)
1028   (let ((server (gnus-server-server-name)))
1029     (unless server
1030       (error "No server on the current line"))
1031     (condition-case ()
1032         (gnus-get-function (gnus-server-to-method server)
1033                            'request-compact)
1034       (error
1035        (error "This back end doesn't support compaction")))
1036     (gnus-message 5 "\
1037 Requesting compaction of %s... (this may take a long time)"
1038                   server)
1039     (unless (gnus-open-server server)
1040       (error "Couldn't open server"))
1041     (if (gnus-request-compact server)
1042         (gnus-message 5 "Requesting compaction of %s...done" server)
1043       (gnus-message 5 "Couldn't compact %s" server))))
1044
1045 (provide 'gnus-srvr)
1046
1047 ;;; arch-tag: c0117f64-27ca-475d-9406-8da6854c7a25
1048 ;;; gnus-srvr.el ends here