cgit.sxemacs.org Git - gnus/blob - lisp/gnus-srvr.el

   1 ;;; gnus-srvr.el --- virtual server support for Gnus
   2
   3 ;; Copyright (C) 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003,
   4 ;;   2004, 2005 Free Software Foundation, Inc.
   5
   6 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   7 ;; Keywords: news
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  24 ;; Boston, MA 02110-1301, USA.
  25
  26 ;;; Commentary:
  27
  28 ;;; Code:
  29
  30 (eval-when-compile (require 'cl))
  31
  32 (require 'gnus)
  33 (require 'gnus-spec)
  34 (require 'gnus-group)
  35 (require 'gnus-int)
  36 (require 'gnus-range)
  37
  38 (defcustom gnus-server-mode-hook nil
  39   "Hook run in `gnus-server-mode' buffers."
  40   :group 'gnus-server
  41   :type 'hook)
  42
  43 (defcustom gnus-server-exit-hook nil
  44   "Hook run when exiting the server buffer."
  45   :group 'gnus-server
  46   :type 'hook)
  47
  48 (defcustom gnus-server-line-format "     {%(%h:%w%)} %s%a\n"
  49   "Format of server lines.
  50 It works along the same lines as a normal formatting string,
  51 with some simple extensions.
  52
  53 The following specs are understood:
  54
  55 %h back end
  56 %n name
  57 %w address
  58 %s status
  59 %a agent covered
  60
  61 General format specifiers can also be used.
  62 See Info node `(gnus)Formatting Variables'."
  63   :link '(custom-manual "(gnus)Formatting Variables")
  64   :group 'gnus-server-visual
  65   :type 'string)
  66
  67 (defcustom gnus-server-mode-line-format "Gnus: %%b"
  68   "The format specification for the server mode line."
  69   :group 'gnus-server-visual
  70   :type 'string)
  71
  72 (defcustom gnus-server-browse-in-group-buffer nil
  73   "Whether server browsing should take place in the group buffer.
  74 If nil, a faster, but more primitive, buffer is used instead."
  75   :version "22.1"
  76   :group 'gnus-server-visual
  77   :type 'boolean)
  78
  79 ;;; Internal variables.
  80
  81 (defvar gnus-inserted-opened-servers nil)
  82
  83 (defvar gnus-server-line-format-alist
  84   `((?h gnus-tmp-how ?s)
  85     (?n gnus-tmp-name ?s)
  86     (?w gnus-tmp-where ?s)
  87     (?s gnus-tmp-status ?s)
  88     (?a gnus-tmp-agent ?s)))
  89
  90 (defvar gnus-server-mode-line-format-alist
  91   `((?S gnus-tmp-news-server ?s)
  92     (?M gnus-tmp-news-method ?s)
  93     (?u gnus-tmp-user-defined ?s)))
  94
  95 (defvar gnus-server-line-format-spec nil)
  96 (defvar gnus-server-mode-line-format-spec nil)
  97 (defvar gnus-server-killed-servers nil)
  98
  99 (defvar gnus-server-mode-map)
 100
 101 (defvar gnus-server-menu-hook nil
 102   "*Hook run after the creation of the server mode menu.")
 103
 104 (defun gnus-server-make-menu-bar ()
 105   (gnus-turn-off-edit-menu 'server)
 106   (unless (boundp 'gnus-server-server-menu)
 107     (easy-menu-define
 108      gnus-server-server-menu gnus-server-mode-map ""
 109      '("Server"
 110        ["Add..." gnus-server-add-server t]
 111        ["Browse" gnus-server-read-server t]
 112        ["Scan" gnus-server-scan-server t]
 113        ["List" gnus-server-list-servers t]
 114        ["Kill" gnus-server-kill-server t]
 115        ["Yank" gnus-server-yank-server t]
 116        ["Copy" gnus-server-copy-server t]
 117        ["Edit" gnus-server-edit-server t]
 118        ["Regenerate" gnus-server-regenerate-server t]
 119        ["Exit" gnus-server-exit t]))
 120
 121     (easy-menu-define
 122      gnus-server-connections-menu gnus-server-mode-map ""
 123      '("Connections"
 124        ["Open" gnus-server-open-server t]
 125        ["Close" gnus-server-close-server t]
 126        ["Offline" gnus-server-offline-server t]
 127        ["Deny" gnus-server-deny-server t]
 128        "---"
 129        ["Open All" gnus-server-open-all-servers t]
 130        ["Close All" gnus-server-close-all-servers t]
 131        ["Reset All" gnus-server-remove-denials t]))
 132
 133     (gnus-run-hooks 'gnus-server-menu-hook)))
 134
 135 (defvar gnus-server-mode-map nil)
 136 (put 'gnus-server-mode 'mode-class 'special)
 137
 138 (unless gnus-server-mode-map
 139   (setq gnus-server-mode-map (make-sparse-keymap))
 140   (suppress-keymap gnus-server-mode-map)
 141
 142   (gnus-define-keys gnus-server-mode-map
 143     " " gnus-server-read-server-in-server-buffer
 144     "\r" gnus-server-read-server
 145     gnus-mouse-2 gnus-server-pick-server
 146     "q" gnus-server-exit
 147     "l" gnus-server-list-servers
 148     "k" gnus-server-kill-server
 149     "y" gnus-server-yank-server
 150     "c" gnus-server-copy-server
 151     "a" gnus-server-add-server
 152     "e" gnus-server-edit-server
 153     "s" gnus-server-scan-server
 154
 155     "O" gnus-server-open-server
 156     "\M-o" gnus-server-open-all-servers
 157     "C" gnus-server-close-server
 158     "\M-c" gnus-server-close-all-servers
 159     "D" gnus-server-deny-server
 160     "L" gnus-server-offline-server
 161     "R" gnus-server-remove-denials
 162
 163     "n" next-line
 164     "p" previous-line
 165
 166     "g" gnus-server-regenerate-server
 167
 168     "\C-c\C-i" gnus-info-find-node
 169     "\C-c\C-b" gnus-bug))
 170
 171 (defface gnus-server-agent
 172   '((((class color) (background light)) (:foreground "PaleTurquoise" :bold t))
 173     (((class color) (background dark)) (:foreground "PaleTurquoise" :bold t))
 174     (t (:bold t)))
 175   "Face used for displaying AGENTIZED servers"
 176   :group 'gnus-server-visual)
 177 ;; backward-compatibility alias
 178 (put 'gnus-server-agent-face 'face-alias 'gnus-server-agent)
 179
 180 (defface gnus-server-opened
 181   '((((class color) (background light)) (:foreground "Green3" :bold t))
 182     (((class color) (background dark)) (:foreground "Green1" :bold t))
 183     (t (:bold t)))
 184   "Face used for displaying OPENED servers"
 185   :group 'gnus-server-visual)
 186 ;; backward-compatibility alias
 187 (put 'gnus-server-opened-face 'face-alias 'gnus-server-opened)
 188
 189 (defface gnus-server-closed
 190   '((((class color) (background light)) (:foreground "Steel Blue" :italic t))
 191     (((class color) (background dark))
 192      (:foreground "Light Steel Blue" :italic t))
 193     (t (:italic t)))
 194   "Face used for displaying CLOSED servers"
 195   :group 'gnus-server-visual)
 196 ;; backward-compatibility alias
 197 (put 'gnus-server-closed-face 'face-alias 'gnus-server-closed)
 198
 199 (defface gnus-server-denied
 200   '((((class color) (background light)) (:foreground "Red" :bold t))
 201     (((class color) (background dark)) (:foreground "Pink" :bold t))
 202     (t (:inverse-video t :bold t)))
 203   "Face used for displaying DENIED servers"
 204   :group 'gnus-server-visual)
 205 ;; backward-compatibility alias
 206 (put 'gnus-server-denied-face 'face-alias 'gnus-server-denied)
 207
 208 (defface gnus-server-offline
 209   '((((class color) (background light)) (:foreground "Orange" :bold t))
 210     (((class color) (background dark)) (:foreground "Yellow" :bold t))
 211     (t (:inverse-video t :bold t)))
 212   "Face used for displaying OFFLINE servers"
 213   :group 'gnus-server-visual)
 214 ;; backward-compatibility alias
 215 (put 'gnus-server-offline-face 'face-alias 'gnus-server-offline)
 216
 217 (defcustom gnus-server-agent-face 'gnus-server-agent
 218   "Face name to use on AGENTIZED servers."
 219   :version "22.1"
 220   :group 'gnus-server-visual
 221   :type 'face)
 222
 223 (defcustom gnus-server-opened-face 'gnus-server-opened
 224   "Face name to use on OPENED servers."
 225   :version "22.1"
 226   :group 'gnus-server-visual
 227   :type 'face)
 228
 229 (defcustom gnus-server-closed-face 'gnus-server-closed
 230   "Face name to use on CLOSED servers."
 231   :version "22.1"
 232   :group 'gnus-server-visual
 233   :type 'face)
 234
 235 (defcustom gnus-server-denied-face 'gnus-server-denied
 236   "Face name to use on DENIED servers."
 237   :version "22.1"
 238   :group 'gnus-server-visual
 239   :type 'face)
 240
 241 (defcustom gnus-server-offline-face 'gnus-server-offline
 242   "Face name to use on OFFLINE servers."
 243   :version "22.1"
 244   :group 'gnus-server-visual
 245   :type 'face)
 246
 247 (defvar gnus-server-font-lock-keywords
 248   (list
 249    '("(\\(agent\\))" 1 gnus-server-agent-face)
 250    '("(\\(opened\\))" 1 gnus-server-opened-face)
 251    '("(\\(closed\\))" 1 gnus-server-closed-face)
 252    '("(\\(offline\\))" 1 gnus-server-offline-face)
 253    '("(\\(denied\\))" 1 gnus-server-denied-face)))
 254
 255 (defun gnus-server-mode ()
 256   "Major mode for listing and editing servers.
 257
 258 All normal editing commands are switched off.
 259 \\<gnus-server-mode-map>
 260 For more in-depth information on this mode, read the manual
 261 \(`\\[gnus-info-find-node]').
 262
 263 The following commands are available:
 264
 265 \\{gnus-server-mode-map}"
 266   (interactive)
 267   (when (gnus-visual-p 'server-menu 'menu)
 268     (gnus-server-make-menu-bar))
 269   (kill-all-local-variables)
 270   (gnus-simplify-mode-line)
 271   (setq major-mode 'gnus-server-mode)
 272   (setq mode-name "Server")
 273   (gnus-set-default-directory)
 274   (setq mode-line-process nil)
 275   (use-local-map gnus-server-mode-map)
 276   (buffer-disable-undo)
 277   (setq truncate-lines t)
 278   (setq buffer-read-only t)
 279   (if (featurep 'xemacs)
 280       (put 'gnus-server-mode 'font-lock-defaults '(gnus-server-font-lock-keywords t))
 281     (set (make-local-variable 'font-lock-defaults)
 282          '(gnus-server-font-lock-keywords t)))
 283   (gnus-run-mode-hooks 'gnus-server-mode-hook))
 284
 285 (defun gnus-server-insert-server-line (gnus-tmp-name method)
 286   (let* ((gnus-tmp-how (car method))
 287          (gnus-tmp-where (nth 1 method))
 288          (elem (assoc method gnus-opened-servers))
 289          (gnus-tmp-status
 290           (cond
 291            ((eq (nth 1 elem) 'denied) "(denied)")
 292            ((eq (nth 1 elem) 'offline) "(offline)")
 293            (t
 294             (condition-case nil
 295                 (if (or (gnus-server-opened method)
 296                         (eq (nth 1 elem) 'ok))
 297                     "(opened)"
 298                   "(closed)")
 299               ((error) "(error)")))))
 300          (gnus-tmp-agent (if (and gnus-agent
 301                                   (gnus-agent-method-p method))
 302                              " (agent)"
 303                            "")))
 304     (beginning-of-line)
 305     (gnus-add-text-properties
 306      (point)
 307      (prog1 (1+ (point))
 308        ;; Insert the text.
 309        (eval gnus-server-line-format-spec))
 310      (list 'gnus-server (intern gnus-tmp-name)
 311            'gnus-named-server (intern (gnus-method-to-server method))))))
 312
 313 (defun gnus-enter-server-buffer ()
 314   "Set up the server buffer."
 315   (gnus-server-setup-buffer)
 316   (gnus-configure-windows 'server)
 317   (gnus-server-prepare))
 318
 319 (defun gnus-server-setup-buffer ()
 320   "Initialize the server buffer."
 321   (unless (get-buffer gnus-server-buffer)
 322     (save-excursion
 323       (set-buffer (gnus-get-buffer-create gnus-server-buffer))
 324       (gnus-server-mode)
 325       (when gnus-carpal
 326         (gnus-carpal-setup-buffer 'server)))))
 327
 328 (defun gnus-server-prepare ()
 329   (gnus-set-format 'server-mode)
 330   (gnus-set-format 'server t)
 331   (let ((alist gnus-server-alist)
 332         (buffer-read-only nil)
 333         done server op-ser)
 334     (erase-buffer)
 335     (setq gnus-inserted-opened-servers nil)
 336     ;; First we do the real list of servers.
 337     (while alist
 338       (unless (member (cdar alist) done)
 339         (push (cdar alist) done)
 340         (setq server (pop alist))
 341         (when (and server (car server) (cdr server))
 342           (gnus-server-insert-server-line (car server) (cdr server))))
 343       (when (member (cdar alist) done)
 344         (pop alist)))
 345     ;; Then we insert the list of servers that have been opened in
 346     ;; this session.
 347     (dolist (open gnus-opened-servers)
 348       (when (and (not (member (car open) done))
 349                  ;; Just ignore ephemeral servers.
 350                  (not (member (car open) gnus-ephemeral-servers)))
 351         (push (car open) done)
 352         (gnus-server-insert-server-line
 353          (setq op-ser (format "%s:%s" (caar open) (nth 1 (car open))))
 354          (car open))
 355         (push (list op-ser (car open)) gnus-inserted-opened-servers))))
 356   (goto-char (point-min))
 357   (gnus-server-position-point))
 358
 359 (defun gnus-server-server-name ()
 360   (let ((server (get-text-property (point-at-bol) 'gnus-server)))
 361     (and server (symbol-name server))))
 362
 363 (defun gnus-server-named-server ()
 364   "Return a server name that matches one of the names returned by
 365 `gnus-method-to-server'."
 366   (let ((server (get-text-property (point-at-bol) 'gnus-named-server)))
 367     (and server (symbol-name server))))
 368
 369 (defalias 'gnus-server-position-point 'gnus-goto-colon)
 370
 371 (defconst gnus-server-edit-buffer "*Gnus edit server*")
 372
 373 (defun gnus-server-update-server (server)
 374   (save-excursion
 375     (set-buffer gnus-server-buffer)
 376     (let* ((buffer-read-only nil)
 377            (entry (assoc server gnus-server-alist))
 378            (oentry (assoc (gnus-server-to-method server)
 379                           gnus-opened-servers)))
 380       (when entry
 381         (gnus-dribble-enter
 382          (concat "(gnus-server-set-info \"" server "\" '"
 383                  (gnus-prin1-to-string (cdr entry)) ")\n")))
 384       (when (or entry oentry)
 385         ;; Buffer may be narrowed.
 386         (save-restriction
 387           (widen)
 388           (when (gnus-server-goto-server server)
 389             (gnus-delete-line))
 390           (if entry
 391               (gnus-server-insert-server-line (car entry) (cdr entry))
 392             (gnus-server-insert-server-line
 393              (format "%s:%s" (caar oentry) (nth 1 (car oentry)))
 394              (car oentry)))
 395           (gnus-server-position-point))))))
 396
 397 (defun gnus-server-set-info (server info)
 398   ;; Enter a select method into the virtual server alist.
 399   (when (and server info)
 400     (gnus-dribble-enter
 401      (concat "(gnus-server-set-info \"" server "\" '"
 402              (gnus-prin1-to-string info) ")"))
 403     (let* ((server (nth 1 info))
 404            (entry (assoc server gnus-server-alist))
 405            (cached (assoc server gnus-server-method-cache)))
 406       (if cached
 407           (setq gnus-server-method-cache
 408                 (delq cached gnus-server-method-cache)))
 409       (if entry
 410           (progn
 411             ;; Remove the server from `gnus-opened-servers' since
 412             ;; it has never been opened with the new `info' yet.
 413             (gnus-opened-servers-remove (cdr entry))
 414             ;; Don't make a new Lisp object.
 415             (setcar (cdr entry) (car info))
 416             (setcdr (cdr entry) (cdr info)))
 417         (setq gnus-server-alist
 418               (nconc gnus-server-alist (list (cons server info))))))))
 419
 420 ;;; Interactive server functions.
 421
 422 (defun gnus-server-kill-server (server)
 423   "Kill the server on the current line."
 424   (interactive (list (gnus-server-server-name)))
 425   (unless (gnus-server-goto-server server)
 426     (if server (error "No such server: %s" server)
 427       (error "No server on the current line")))
 428   (unless (assoc server gnus-server-alist)
 429     (error "Read-only server %s" server))
 430   (gnus-dribble-touch)
 431   (let ((buffer-read-only nil))
 432     (gnus-delete-line))
 433   (push (assoc server gnus-server-alist) gnus-server-killed-servers)
 434   (setq gnus-server-alist (delq (car gnus-server-killed-servers)
 435                                 gnus-server-alist))
 436   (let ((groups (gnus-groups-from-server server)))
 437     (when (and groups
 438                (gnus-yes-or-no-p
 439                 (format "Kill all %s groups from this server? "
 440                         (length groups))))
 441       (dolist (group groups)
 442         (setq gnus-newsrc-alist
 443               (delq (assoc group gnus-newsrc-alist)
 444                     gnus-newsrc-alist))
 445         (when gnus-group-change-level-function
 446           (funcall gnus-group-change-level-function
 447                    group gnus-level-killed 3)))))
 448   (gnus-server-position-point))
 449
 450 (defun gnus-server-yank-server ()
 451   "Yank the previously killed server."
 452   (interactive)
 453   (unless gnus-server-killed-servers
 454     (error "No killed servers to be yanked"))
 455   (let ((alist gnus-server-alist)
 456         (server (gnus-server-server-name))
 457         (killed (car gnus-server-killed-servers)))
 458     (if (not server)
 459         (setq gnus-server-alist (nconc gnus-server-alist (list killed)))
 460       (if (string= server (caar gnus-server-alist))
 461           (push killed gnus-server-alist)
 462         (while (and (cdr alist)
 463                     (not (string= server (caadr alist))))
 464           (setq alist (cdr alist)))
 465         (if alist
 466             (setcdr alist (cons killed (cdr alist)))
 467           (setq gnus-server-alist (list killed)))))
 468     (gnus-server-update-server (car killed))
 469     (setq gnus-server-killed-servers (cdr gnus-server-killed-servers))
 470     (gnus-server-position-point)))
 471
 472 (defun gnus-server-exit ()
 473   "Return to the group buffer."
 474   (interactive)
 475   (gnus-run-hooks 'gnus-server-exit-hook)
 476   (gnus-kill-buffer (current-buffer))
 477   (gnus-configure-windows 'group t))
 478
 479 (defun gnus-server-list-servers ()
 480   "List all available servers."
 481   (interactive)
 482   (let ((cur (gnus-server-server-name)))
 483     (gnus-server-prepare)
 484     (if cur (gnus-server-goto-server cur)
 485       (goto-char (point-max))
 486       (forward-line -1))
 487     (gnus-server-position-point)))
 488
 489 (defun gnus-server-set-status (method status)
 490   "Make METHOD have STATUS."
 491   (let ((entry (assoc method gnus-opened-servers)))
 492     (if entry
 493         (setcar (cdr entry) status)
 494       (push (list method status) gnus-opened-servers))))
 495
 496 (defun gnus-opened-servers-remove (method)
 497   "Remove METHOD from the list of opened servers."
 498   (setq gnus-opened-servers (delq (assoc method gnus-opened-servers)
 499                                   gnus-opened-servers)))
 500
 501 (defun gnus-server-open-server (server)
 502   "Force an open of SERVER."
 503   (interactive (list (gnus-server-server-name)))
 504   (let ((method (gnus-server-to-method server)))
 505     (unless method
 506       (error "No such server: %s" server))
 507     (gnus-server-set-status method 'ok)
 508     (prog1
 509         (or (gnus-open-server method)
 510             (progn (message "Couldn't open %s" server) nil))
 511       (gnus-server-update-server server)
 512       (gnus-server-position-point))))
 513
 514 (defun gnus-server-open-all-servers ()
 515   "Open all servers."
 516   (interactive)
 517   (dolist (server gnus-inserted-opened-servers)
 518     (gnus-server-open-server (car server))))
 519
 520 (defun gnus-server-close-server (server)
 521   "Close SERVER."
 522   (interactive (list (gnus-server-server-name)))
 523   (let ((method (gnus-server-to-method server)))
 524     (unless method
 525       (error "No such server: %s" server))
 526     (gnus-server-set-status method 'closed)
 527     (prog1
 528         (gnus-close-server method)
 529       (gnus-server-update-server server)
 530       (gnus-server-position-point))))
 531
 532 (defun gnus-server-offline-server (server)
 533   "Set SERVER to offline."
 534   (interactive (list (gnus-server-server-name)))
 535   (let ((method (gnus-server-to-method server)))
 536     (unless method
 537       (error "No such server: %s" server))
 538     (prog1
 539         (gnus-close-server method)
 540       (gnus-server-set-status method 'offline)
 541       (gnus-server-update-server server)
 542       (gnus-server-position-point))))
 543
 544 (defun gnus-server-close-all-servers ()
 545   "Close all servers."
 546   (interactive)
 547   (dolist (server gnus-inserted-opened-servers)
 548     (gnus-server-close-server (car server))))
 549
 550 (defun gnus-server-deny-server (server)
 551   "Make sure SERVER will never be attempted opened."
 552   (interactive (list (gnus-server-server-name)))
 553   (let ((method (gnus-server-to-method server)))
 554     (unless method
 555       (error "No such server: %s" server))
 556     (gnus-server-set-status method 'denied))
 557   (gnus-server-update-server server)
 558   (gnus-server-position-point)
 559   t)
 560
 561 (defun gnus-server-remove-denials ()
 562   "Make all denied servers into closed servers."
 563   (interactive)
 564   (dolist (server gnus-opened-servers)
 565     (when (eq (nth 1 server) 'denied)
 566       (setcar (nthcdr 1 server) 'closed)))
 567   (gnus-server-list-servers))
 568
 569 (defun gnus-server-copy-server (from to)
 570   (interactive
 571    (list
 572     (or (gnus-server-server-name)
 573         (error "No server on the current line"))
 574     (read-string "Copy to: ")))
 575   (unless from
 576     (error "No server on current line"))
 577   (unless (and to (not (string= to "")))
 578     (error "No name to copy to"))
 579   (when (assoc to gnus-server-alist)
 580     (error "%s already exists" to))
 581   (unless (gnus-server-to-method from)
 582     (error "%s: no such server" from))
 583   (let ((to-entry (cons from (gnus-copy-sequence
 584                               (gnus-server-to-method from)))))
 585     (setcar to-entry to)
 586     (setcar (nthcdr 2 to-entry) to)
 587     (push to-entry gnus-server-killed-servers)
 588     (gnus-server-yank-server)))
 589
 590 (defun gnus-server-add-server (how where)
 591   (interactive
 592    (list (intern (completing-read "Server method: "
 593                                   gnus-valid-select-methods nil t))
 594          (read-string "Server name: ")))
 595   (when (assq where gnus-server-alist)
 596     (error "Server with that name already defined"))
 597   (push (list where how where) gnus-server-killed-servers)
 598   (gnus-server-yank-server))
 599
 600 (defun gnus-server-goto-server (server)
 601   "Jump to a server line."
 602   (interactive
 603    (list (completing-read "Goto server: " gnus-server-alist nil t)))
 604   (let ((to (text-property-any (point-min) (point-max)
 605                                'gnus-server (intern server))))
 606     (when to
 607       (goto-char to)
 608       (gnus-server-position-point))))
 609
 610 (defun gnus-server-edit-server (server)
 611   "Edit the server on the current line."
 612   (interactive (list (gnus-server-server-name)))
 613   (unless server
 614     (error "No server on current line"))
 615   (unless (assoc server gnus-server-alist)
 616     (error "This server can't be edited"))
 617   (let ((info (cdr (assoc server gnus-server-alist))))
 618     (gnus-close-server info)
 619     (gnus-edit-form
 620      info "Editing the server."
 621      `(lambda (form)
 622         (gnus-server-set-info ,server form)
 623         (gnus-server-list-servers)
 624         (gnus-server-position-point)))))
 625
 626 (defun gnus-server-scan-server (server)
 627   "Request a scan from the current server."
 628   (interactive (list (gnus-server-server-name)))
 629   (let ((method (gnus-server-to-method server)))
 630     (if (not (gnus-get-function method 'request-scan))
 631         (error "Server %s can't scan" (car method))
 632       (gnus-message 3 "Scanning %s..." server)
 633       (gnus-request-scan nil method)
 634       (gnus-message 3 "Scanning %s...done" server))))
 635
 636 (defun gnus-server-read-server-in-server-buffer (server)
 637   "Browse a server in server buffer."
 638   (interactive (list (gnus-server-server-name)))
 639   (let (gnus-server-browse-in-group-buffer)
 640     (gnus-server-read-server server)))
 641
 642 (defun gnus-server-read-server (server)
 643   "Browse a server."
 644   (interactive (list (gnus-server-server-name)))
 645   (let ((buf (current-buffer)))
 646     (prog1
 647         (gnus-browse-foreign-server server buf)
 648       (save-excursion
 649         (set-buffer buf)
 650         (gnus-server-update-server (gnus-server-server-name))
 651         (gnus-server-position-point)))))
 652
 653 (defun gnus-server-pick-server (e)
 654   (interactive "e")
 655   (mouse-set-point e)
 656   (gnus-server-read-server (gnus-server-server-name)))
 657
 658 \f
 659 ;;;
 660 ;;; Browse Server Mode
 661 ;;;
 662
 663 (defvar gnus-browse-menu-hook nil
 664   "*Hook run after the creation of the browse mode menu.")
 665
 666 (defvar gnus-browse-mode-hook nil)
 667 (defvar gnus-browse-mode-map nil)
 668 (put 'gnus-browse-mode 'mode-class 'special)
 669
 670 (unless gnus-browse-mode-map
 671   (setq gnus-browse-mode-map (make-keymap))
 672   (suppress-keymap gnus-browse-mode-map)
 673
 674   (gnus-define-keys
 675       gnus-browse-mode-map
 676     " " gnus-browse-read-group
 677     "=" gnus-browse-select-group
 678     "n" gnus-browse-next-group
 679     "p" gnus-browse-prev-group
 680     "\177" gnus-browse-prev-group
 681     [delete] gnus-browse-prev-group
 682     "N" gnus-browse-next-group
 683     "P" gnus-browse-prev-group
 684     "\M-n" gnus-browse-next-group
 685     "\M-p" gnus-browse-prev-group
 686     "\r" gnus-browse-select-group
 687     "u" gnus-browse-unsubscribe-current-group
 688     "l" gnus-browse-exit
 689     "L" gnus-browse-exit
 690     "q" gnus-browse-exit
 691     "Q" gnus-browse-exit
 692     "d" gnus-browse-describe-group
 693     "\C-c\C-c" gnus-browse-exit
 694     "?" gnus-browse-describe-briefly
 695
 696     "\C-c\C-i" gnus-info-find-node
 697     "\C-c\C-b" gnus-bug))
 698
 699 (defun gnus-browse-make-menu-bar ()
 700   (gnus-turn-off-edit-menu 'browse)
 701   (unless (boundp 'gnus-browse-menu)
 702     (easy-menu-define
 703      gnus-browse-menu gnus-browse-mode-map ""
 704      '("Browse"
 705        ["Subscribe" gnus-browse-unsubscribe-current-group t]
 706        ["Read" gnus-browse-read-group t]
 707        ["Select" gnus-browse-select-group t]
 708        ["Describe" gnus-browse-describe-group t]
 709        ["Next" gnus-browse-next-group t]
 710        ["Prev" gnus-browse-prev-group t]
 711        ["Exit" gnus-browse-exit t]))
 712     (gnus-run-hooks 'gnus-browse-menu-hook)))
 713
 714 (defvar gnus-browse-current-method nil)
 715 (defvar gnus-browse-return-buffer nil)
 716
 717 (defvar gnus-browse-buffer "*Gnus Browse Server*")
 718
 719 (defun gnus-browse-foreign-server (server &optional return-buffer)
 720   "Browse the server SERVER."
 721   (setq gnus-browse-current-method (gnus-server-to-method server))
 722   (setq gnus-browse-return-buffer return-buffer)
 723   (let* ((method gnus-browse-current-method)
 724          (orig-select-method gnus-select-method)
 725          (gnus-select-method method)
 726          groups group)
 727     (gnus-message 5 "Connecting to %s..." (nth 1 method))
 728     (cond
 729      ((not (gnus-check-server method))
 730       (gnus-message
 731        1 "Unable to contact server %s: %s" (nth 1 method)
 732        (gnus-status-message method))
 733       nil)
 734      ((not
 735        (prog2
 736            (gnus-message 6 "Reading active file...")
 737            (gnus-request-list method)
 738          (gnus-message 6 "Reading active file...done")))
 739       (gnus-message
 740        1 "Couldn't request list: %s" (gnus-status-message method))
 741       nil)
 742      (t
 743       (with-current-buffer nntp-server-buffer
 744         (let ((cur (current-buffer)))
 745           (goto-char (point-min))
 746           (unless (string= gnus-ignored-newsgroups "")
 747             (delete-matching-lines gnus-ignored-newsgroups))
 748           ;; We treat NNTP as a special case to avoid problems with
 749           ;; garbage group names like `"foo' that appear in some badly
 750           ;; managed active files. -jh.
 751           (if (eq (car method) 'nntp)
 752               (while (not (eobp))
 753                 (ignore-errors
 754                   (push (cons
 755                          (buffer-substring
 756                           (point)
 757                           (progn
 758                             (skip-chars-forward "^ \t")
 759                             (point)))
 760                          (let ((last (read cur)))
 761                            (cons (read cur) last)))
 762                         groups))
 763                 (forward-line))
 764             (while (not (eobp))
 765               (ignore-errors
 766                 (push (cons
 767                        (if (eq (char-after) ?\")
 768                            (read cur)
 769                          (let ((p (point)) (name ""))
 770                            (skip-chars-forward "^ \t\\\\")
 771                            (setq name (buffer-substring p (point)))
 772                            (while (eq (char-after) ?\\)
 773                              (setq p (1+ (point)))
 774                              (forward-char 2)
 775                              (skip-chars-forward "^ \t\\\\")
 776                              (setq name (concat name (buffer-substring
 777                                                       p (point)))))
 778                            name))
 779                        (let ((last (read cur)))
 780                          (cons (read cur) last)))
 781                       groups))
 782               (forward-line)))))
 783       (setq groups (sort groups
 784                          (lambda (l1 l2)
 785                            (string< (car l1) (car l2)))))
 786       (if gnus-server-browse-in-group-buffer
 787           (let* ((gnus-select-method orig-select-method)
 788                  (gnus-group-listed-groups
 789                   (mapcar (lambda (group)
 790                             (let ((name
 791                                    (gnus-group-prefixed-name
 792                                     (car group) method)))
 793                               (gnus-set-active name (cdr group))
 794                               name))
 795                           groups)))
 796             (gnus-configure-windows 'group)
 797             (funcall gnus-group-prepare-function
 798                      gnus-level-killed 'ignore 1 'ignore))
 799         (gnus-get-buffer-create gnus-browse-buffer)
 800         (when gnus-carpal
 801           (gnus-carpal-setup-buffer 'browse))
 802         (gnus-configure-windows 'browse)
 803         (buffer-disable-undo)
 804         (let ((buffer-read-only nil))
 805           (erase-buffer))
 806         (gnus-browse-mode)
 807         (setq mode-line-buffer-identification
 808               (list
 809                (format
 810                 "Gnus: %%b {%s:%s}" (car method) (cadr method))))
 811         (let ((buffer-read-only nil)
 812               name
 813               (prefix (let ((gnus-select-method orig-select-method))
 814                         (gnus-group-prefixed-name "" method))))
 815           (while (setq group (pop groups))
 816             (gnus-add-text-properties
 817              (point)
 818              (prog1 (1+ (point))
 819                (insert
 820                 (format "%c%7d: %s\n"
 821                         (let ((level
 822                                (if (string= prefix "")
 823                                    (gnus-group-level (setq name (car group)))
 824                                  (gnus-group-level
 825                                   (concat prefix (setq name (car group)))))))
 826                           (cond
 827                            ((<= level gnus-level-subscribed) ? )
 828                            ((<= level gnus-level-unsubscribed) ?U)
 829                            ((= level gnus-level-zombie) ?Z)
 830                            (t ?K)))
 831                         (max 0 (- (1+ (cddr group)) (cadr group)))
 832                         ;; Don't decode if name is ASCII
 833                         (if (and (fboundp 'detect-coding-string)
 834                                  (eq (detect-coding-string name t) 'undecided))
 835                             name
 836                           (mm-decode-coding-string
 837                            name
 838                            (inline (gnus-group-name-charset method name)))))))
 839              (list 'gnus-group name)
 840              )))
 841         (switch-to-buffer (current-buffer)))
 842       (goto-char (point-min))
 843       (gnus-group-position-point)
 844       (gnus-message 5 "Connecting to %s...done" (nth 1 method))
 845       t))))
 846
 847 (defun gnus-browse-mode ()
 848   "Major mode for browsing a foreign server.
 849
 850 All normal editing commands are switched off.
 851
 852 \\<gnus-browse-mode-map>
 853 The only things you can do in this buffer is
 854
 855 1) `\\[gnus-browse-unsubscribe-current-group]' to subscribe to a group.
 856 The group will be inserted into the group buffer upon exit from this
 857 buffer.
 858
 859 2) `\\[gnus-browse-read-group]' to read a group ephemerally.
 860
 861 3) `\\[gnus-browse-exit]' to return to the group buffer."
 862   (interactive)
 863   (kill-all-local-variables)
 864   (when (gnus-visual-p 'browse-menu 'menu)
 865     (gnus-browse-make-menu-bar))
 866   (gnus-simplify-mode-line)
 867   (setq major-mode 'gnus-browse-mode)
 868   (setq mode-name "Browse Server")
 869   (setq mode-line-process nil)
 870   (use-local-map gnus-browse-mode-map)
 871   (buffer-disable-undo)
 872   (setq truncate-lines t)
 873   (gnus-set-default-directory)
 874   (setq buffer-read-only t)
 875   (gnus-run-mode-hooks 'gnus-browse-mode-hook))
 876
 877 (defun gnus-browse-read-group (&optional no-article number)
 878   "Enter the group at the current line.
 879 If NUMBER, fetch this number of articles."
 880   (interactive "P")
 881   (let ((group (gnus-browse-group-name)))
 882     (if (or (not (gnus-get-info group))
 883             (gnus-ephemeral-group-p group))
 884         (unless (gnus-group-read-ephemeral-group
 885                  group gnus-browse-current-method nil
 886                  (cons (current-buffer) 'browse)
 887                  nil nil nil number)
 888           (error "Couldn't enter %s" group))
 889       (unless (gnus-group-read-group nil no-article group)
 890         (error "Couldn't enter %s" group)))))
 891
 892 (defun gnus-browse-select-group (&optional number)
 893   "Select the current group.
 894 If NUMBER, fetch this number of articles."
 895   (interactive "P")
 896   (gnus-browse-read-group 'no number))
 897
 898 (defun gnus-browse-next-group (n)
 899   "Go to the next group."
 900   (interactive "p")
 901   (prog1
 902       (forward-line n)
 903     (gnus-group-position-point)))
 904
 905 (defun gnus-browse-prev-group (n)
 906   "Go to the next group."
 907   (interactive "p")
 908   (gnus-browse-next-group (- n)))
 909
 910 (defun gnus-browse-unsubscribe-current-group (arg)
 911   "(Un)subscribe to the next ARG groups."
 912   (interactive "p")
 913   (when (eobp)
 914     (error "No group at current line"))
 915   (let ((ward (if (< arg 0) -1 1))
 916         (arg (abs arg)))
 917     (while (and (> arg 0)
 918                 (not (eobp))
 919                 (gnus-browse-unsubscribe-group)
 920                 (zerop (gnus-browse-next-group ward)))
 921       (decf arg))
 922     (gnus-group-position-point)
 923     (when (/= 0 arg)
 924       (gnus-message 7 "No more newsgroups"))
 925     arg))
 926
 927 (defun gnus-browse-group-name ()
 928   (save-excursion
 929     (beginning-of-line)
 930     (let ((name (get-text-property (point) 'gnus-group)))
 931       (when (re-search-forward ": \\(.*\\)$" (point-at-eol) t)
 932         (concat (gnus-method-to-server-name gnus-browse-current-method) ":"
 933                 (or name
 934                     (match-string-no-properties 1)))))))
 935
 936 (defun gnus-browse-describe-group (group)
 937   "Describe the current group."
 938   (interactive (list (gnus-browse-group-name)))
 939   (gnus-group-describe-group nil group))
 940
 941 (defun gnus-browse-unsubscribe-group ()
 942   "Toggle subscription of the current group in the browse buffer."
 943   (let ((sub nil)
 944         (buffer-read-only nil)
 945         group)
 946     (save-excursion
 947       (beginning-of-line)
 948       ;; If this group it killed, then we want to subscribe it.
 949       (unless (eq (char-after) ? )
 950         (setq sub t))
 951       (setq group (gnus-browse-group-name))
 952       (when (gnus-server-equal gnus-browse-current-method "native")
 953         (setq group (gnus-group-real-name group)))
 954       (if sub
 955           (progn
 956             ;; Make sure the group has been properly removed before we
 957             ;; subscribe to it.
 958             (gnus-kill-ephemeral-group group)
 959             (gnus-group-change-level
 960              (list t group gnus-level-default-subscribed
 961                    nil nil (if (gnus-server-equal
 962                                 gnus-browse-current-method "native")
 963                                nil
 964                              (gnus-method-simplify
 965                               gnus-browse-current-method)))
 966              gnus-level-default-subscribed (gnus-group-level group)
 967              (and (car (nth 1 gnus-newsrc-alist))
 968                   (gnus-group-entry (car (nth 1 gnus-newsrc-alist))))
 969              t)
 970             (delete-char 1)
 971             (insert ? ))
 972         (gnus-group-change-level
 973          group gnus-level-unsubscribed gnus-level-default-subscribed)
 974         (delete-char 1)
 975         (insert ?U)))
 976     t))
 977
 978 (defun gnus-browse-exit ()
 979   "Quit browsing and return to the group buffer."
 980   (interactive)
 981   (when (eq major-mode 'gnus-browse-mode)
 982     (gnus-kill-buffer (current-buffer)))
 983   ;; Insert the newly subscribed groups in the group buffer.
 984   (save-excursion
 985     (set-buffer gnus-group-buffer)
 986     (gnus-group-list-groups nil))
 987   (if gnus-browse-return-buffer
 988       (gnus-configure-windows 'server 'force)
 989     (gnus-configure-windows 'group 'force)))
 990
 991 (defun gnus-browse-describe-briefly ()
 992   "Give a one line description of the group mode commands."
 993   (interactive)
 994   (gnus-message 6
 995                 (substitute-command-keys "\\<gnus-browse-mode-map>\\[gnus-group-next-group]:Forward  \\[gnus-group-prev-group]:Backward  \\[gnus-browse-exit]:Exit  \\[gnus-info-find-node]:Run Info  \\[gnus-browse-describe-briefly]:This help")))
 996
 997 (defun gnus-server-regenerate-server ()
 998   "Issue a command to the server to regenerate all its data structures."
 999   (interactive)
1000   (let ((server (gnus-server-server-name)))
1001     (unless server
1002       (error "No server on the current line"))
1003     (condition-case ()
1004         (gnus-get-function (gnus-server-to-method server)
1005                            'request-regenerate)
1006       (error
1007         (error "This back end doesn't support regeneration")))
1008     (gnus-message 5 "Requesting regeneration of %s..." server)
1009     (unless (gnus-open-server server)
1010       (error "Couldn't open server"))
1011     (if (gnus-request-regenerate server)
1012         (gnus-message 5 "Requesting regeneration of %s...done" server)
1013       (gnus-message 5 "Couldn't regenerate %s" server))))
1014
1015 (provide 'gnus-srvr)
1016
1017 ;;; arch-tag: c0117f64-27ca-475d-9406-8da6854c7a25
1018 ;;; gnus-srvr.el ends here