cgit.sxemacs.org Git - gnus/blob - lisp/gnus-srvr.el

   1 ;;; gnus-srvr.el --- virtual server support for Gnus
   2 ;; Copyright (C) 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003
   3 ;;        Free Software Foundation, Inc.
   4
   5 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   6 ;; Keywords: news
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;;; Code:
  28
  29 (eval-when-compile (require 'cl))
  30
  31 (require 'gnus)
  32 (require 'gnus-spec)
  33 (require 'gnus-group)
  34 (require 'gnus-int)
  35 (require 'gnus-range)
  36
  37 (defcustom gnus-server-mode-hook nil
  38   "Hook run in `gnus-server-mode' buffers."
  39   :group 'gnus-server
  40   :type 'hook)
  41
  42 (defcustom gnus-server-exit-hook nil
  43   "Hook run when exiting the server buffer."
  44   :group 'gnus-server
  45   :type 'hook)
  46
  47 (defcustom gnus-server-line-format "     {%(%h:%w%)} %s%a\n"
  48   "Format of server lines.
  49 It works along the same lines as a normal formatting string,
  50 with some simple extensions.
  51
  52 The following specs are understood:
  53
  54 %h backend
  55 %n name
  56 %w address
  57 %s status
  58 %a agent covered
  59
  60 General format specifiers can also be used.
  61 See Info node `(gnus)Formatting Variables'."
  62   :link '(custom-manual "(gnus)Formatting Variables")
  63   :group 'gnus-server-visual
  64   :type 'string)
  65
  66 (defcustom gnus-server-mode-line-format "Gnus: %%b"
  67   "The format specification for the server mode line."
  68   :group 'gnus-server-visual
  69   :type 'string)
  70
  71 (defcustom gnus-server-browse-in-group-buffer nil
  72   "Whether server browsing should take place in the group buffer.
  73 If nil, a faster, but more primitive, buffer is used instead."
  74   :group 'gnus-server-visual
  75   :type 'boolean)
  76
  77 ;;; Internal variables.
  78
  79 (defvar gnus-inserted-opened-servers nil)
  80
  81 (defvar gnus-server-line-format-alist
  82   `((?h gnus-tmp-how ?s)
  83     (?n gnus-tmp-name ?s)
  84     (?w gnus-tmp-where ?s)
  85     (?s gnus-tmp-status ?s)
  86     (?a gnus-tmp-agent ?s)))
  87
  88 (defvar gnus-server-mode-line-format-alist
  89   `((?S gnus-tmp-news-server ?s)
  90     (?M gnus-tmp-news-method ?s)
  91     (?u gnus-tmp-user-defined ?s)))
  92
  93 (defvar gnus-server-line-format-spec nil)
  94 (defvar gnus-server-mode-line-format-spec nil)
  95 (defvar gnus-server-killed-servers nil)
  96
  97 (defvar gnus-server-mode-map)
  98
  99 (defvar gnus-server-menu-hook nil
 100   "*Hook run after the creation of the server mode menu.")
 101
 102 (defun gnus-server-make-menu-bar ()
 103   (gnus-turn-off-edit-menu 'server)
 104   (unless (boundp 'gnus-server-server-menu)
 105     (easy-menu-define
 106      gnus-server-server-menu gnus-server-mode-map ""
 107      '("Server"
 108        ["Add..." gnus-server-add-server t]
 109        ["Browse" gnus-server-read-server t]
 110        ["Scan" gnus-server-scan-server t]
 111        ["List" gnus-server-list-servers t]
 112        ["Kill" gnus-server-kill-server t]
 113        ["Yank" gnus-server-yank-server t]
 114        ["Copy" gnus-server-copy-server t]
 115        ["Edit" gnus-server-edit-server t]
 116        ["Regenerate" gnus-server-regenerate-server t]
 117        ["Exit" gnus-server-exit t]))
 118
 119     (easy-menu-define
 120      gnus-server-connections-menu gnus-server-mode-map ""
 121      '("Connections"
 122        ["Open" gnus-server-open-server t]
 123        ["Close" gnus-server-close-server t]
 124        ["Offline" gnus-server-offline-server t]
 125        ["Deny" gnus-server-deny-server t]
 126        "---"
 127        ["Open All" gnus-server-open-all-servers t]
 128        ["Close All" gnus-server-close-all-servers t]
 129        ["Reset All" gnus-server-remove-denials t]))
 130
 131     (gnus-run-hooks 'gnus-server-menu-hook)))
 132
 133 (defvar gnus-server-mode-map nil)
 134 (put 'gnus-server-mode 'mode-class 'special)
 135
 136 (unless gnus-server-mode-map
 137   (setq gnus-server-mode-map (make-sparse-keymap))
 138   (suppress-keymap gnus-server-mode-map)
 139
 140   (gnus-define-keys gnus-server-mode-map
 141     " " gnus-server-read-server-in-server-buffer
 142     "\r" gnus-server-read-server
 143     gnus-mouse-2 gnus-server-pick-server
 144     "q" gnus-server-exit
 145     "l" gnus-server-list-servers
 146     "k" gnus-server-kill-server
 147     "y" gnus-server-yank-server
 148     "c" gnus-server-copy-server
 149     "a" gnus-server-add-server
 150     "e" gnus-server-edit-server
 151     "s" gnus-server-scan-server
 152
 153     "O" gnus-server-open-server
 154     "\M-o" gnus-server-open-all-servers
 155     "C" gnus-server-close-server
 156     "\M-c" gnus-server-close-all-servers
 157     "D" gnus-server-deny-server
 158     "L" gnus-server-offline-server
 159     "R" gnus-server-remove-denials
 160
 161     "n" next-line
 162     "p" previous-line
 163
 164     "g" gnus-server-regenerate-server
 165
 166     "\C-c\C-i" gnus-info-find-node
 167     "\C-c\C-b" gnus-bug))
 168
 169 (defface gnus-server-agent-face
 170   '((((class color) (background light)) (:foreground "PaleTurquoise" :bold t))
 171     (((class color) (background dark)) (:foreground "PaleTurquoise" :bold t))
 172     (t (:bold t)))
 173   "Face used for displaying AGENTIZED servers"
 174   :group 'gnus-server-visual)
 175
 176 (defface gnus-server-opened-face
 177   '((((class color) (background light)) (:foreground "Green3" :bold t))
 178     (((class color) (background dark)) (:foreground "Green1" :bold t))
 179     (t (:bold t)))
 180   "Face used for displaying OPENED servers"
 181   :group 'gnus-server-visual)
 182
 183 (defface gnus-server-closed-face
 184   '((((class color) (background light)) (:foreground "Steel Blue" :italic t))
 185     (((class color) (background dark))
 186      (:foreground "Light Steel Blue" :italic t))
 187     (t (:italic t)))
 188   "Face used for displaying CLOSED servers"
 189   :group 'gnus-server-visual)
 190
 191 (defface gnus-server-denied-face
 192   '((((class color) (background light)) (:foreground "Red" :bold t))
 193     (((class color) (background dark)) (:foreground "Pink" :bold t))
 194     (t (:inverse-video t :bold t)))
 195   "Face used for displaying DENIED servers"
 196   :group 'gnus-server-visual)
 197
 198 (defface gnus-server-offline-face
 199   '((((class color) (background light)) (:foreground "Orange" :bold t))
 200     (((class color) (background dark)) (:foreground "Yellow" :bold t))
 201     (t (:inverse-video t :bold t)))
 202   "Face used for displaying OFFLINE servers"
 203   :group 'gnus-server-visual)
 204
 205 (defcustom gnus-server-agent-face 'gnus-server-agent-face
 206   "Face name to use on AGENTIZED servers."
 207   :group 'gnus-server-visual
 208   :type 'face)
 209
 210 (defcustom gnus-server-opened-face 'gnus-server-opened-face
 211   "Face name to use on OPENED servers."
 212   :group 'gnus-server-visual
 213   :type 'face)
 214
 215 (defcustom gnus-server-closed-face 'gnus-server-closed-face
 216   "Face name to use on CLOSED servers."
 217   :group 'gnus-server-visual
 218   :type 'face)
 219
 220 (defcustom gnus-server-denied-face 'gnus-server-denied-face
 221   "Face name to use on DENIED servers."
 222   :group 'gnus-server-visual
 223   :type 'face)
 224
 225 (defcustom gnus-server-offline-face 'gnus-server-offline-face
 226   "Face name to use on OFFLINE servers."
 227   :group 'gnus-server-visual
 228   :type 'face)
 229
 230 (defvar gnus-server-font-lock-keywords
 231   (list
 232    '("(\\(agent\\))" 1 gnus-server-agent-face)
 233    '("(\\(opened\\))" 1 gnus-server-opened-face)
 234    '("(\\(closed\\))" 1 gnus-server-closed-face)
 235    '("(\\(offline\\))" 1 gnus-server-offline-face)
 236    '("(\\(denied\\))" 1 gnus-server-denied-face)))
 237
 238 (defun gnus-server-mode ()
 239   "Major mode for listing and editing servers.
 240
 241 All normal editing commands are switched off.
 242 \\<gnus-server-mode-map>
 243 For more in-depth information on this mode, read the manual
 244 \(`\\[gnus-info-find-node]').
 245
 246 The following commands are available:
 247
 248 \\{gnus-server-mode-map}"
 249   (interactive)
 250   (when (gnus-visual-p 'server-menu 'menu)
 251     (gnus-server-make-menu-bar))
 252   (kill-all-local-variables)
 253   (gnus-simplify-mode-line)
 254   (setq major-mode 'gnus-server-mode)
 255   (setq mode-name "Server")
 256   (gnus-set-default-directory)
 257   (setq mode-line-process nil)
 258   (use-local-map gnus-server-mode-map)
 259   (buffer-disable-undo)
 260   (setq truncate-lines t)
 261   (setq buffer-read-only t)
 262   (if (featurep 'xemacs)
 263       (put 'gnus-server-mode 'font-lock-defaults '(gnus-server-font-lock-keywords t))
 264     (set (make-local-variable 'font-lock-defaults)
 265          '(gnus-server-font-lock-keywords t)))
 266   (gnus-run-hooks 'gnus-server-mode-hook))
 267
 268 (defun gnus-server-insert-server-line (gnus-tmp-name method)
 269   (let* ((gnus-tmp-how (car method))
 270          (gnus-tmp-where (nth 1 method))
 271          (elem (assoc method gnus-opened-servers))
 272          (gnus-tmp-status
 273           (cond
 274            ((eq (nth 1 elem) 'denied) "(denied)")
 275            ((eq (nth 1 elem) 'offline) "(offline)")
 276            (t
 277             (condition-case nil
 278                 (if (or (gnus-server-opened method)
 279                         (eq (nth 1 elem) 'ok))
 280                     "(opened)"
 281                   "(closed)")
 282               ((error) "(error)")))))
 283          (gnus-tmp-agent (if (and gnus-agent
 284                                   (member method
 285                                           gnus-agent-covered-methods))
 286                              " (agent)"
 287                            "")))
 288     (beginning-of-line)
 289     (gnus-add-text-properties
 290      (point)
 291      (prog1 (1+ (point))
 292        ;; Insert the text.
 293        (eval gnus-server-line-format-spec))
 294      (list 'gnus-server (intern gnus-tmp-name)))))
 295
 296 (defun gnus-enter-server-buffer ()
 297   "Set up the server buffer."
 298   (gnus-server-setup-buffer)
 299   (gnus-configure-windows 'server)
 300   (gnus-server-prepare))
 301
 302 (defun gnus-server-setup-buffer ()
 303   "Initialize the server buffer."
 304   (unless (get-buffer gnus-server-buffer)
 305     (save-excursion
 306       (set-buffer (gnus-get-buffer-create gnus-server-buffer))
 307       (gnus-server-mode)
 308       (when gnus-carpal
 309         (gnus-carpal-setup-buffer 'server)))))
 310
 311 (defun gnus-server-prepare ()
 312   (gnus-set-format 'server-mode)
 313   (gnus-set-format 'server t)
 314   (let ((alist gnus-server-alist)
 315         (buffer-read-only nil)
 316         (opened gnus-opened-servers)
 317         done server op-ser)
 318     (erase-buffer)
 319     (setq gnus-inserted-opened-servers nil)
 320     ;; First we do the real list of servers.
 321     (while alist
 322       (unless (member (cdar alist) done)
 323         (push (cdar alist) done)
 324         (setq server (pop alist))
 325         (when (and server (car server) (cdr server))
 326           (gnus-server-insert-server-line (car server) (cdr server))))
 327       (when (member (cdar alist) done)
 328         (pop alist)))
 329     ;; Then we insert the list of servers that have been opened in
 330     ;; this session.
 331     (while opened
 332       (when (and (not (member (caar opened) done))
 333                  ;; Just ignore ephemeral servers.
 334                  (not (member (caar opened) gnus-ephemeral-servers)))
 335         (push (caar opened) done)
 336         (gnus-server-insert-server-line
 337          (setq op-ser (format "%s:%s" (caaar opened) (nth 1 (caar opened))))
 338          (caar opened))
 339         (push (list op-ser (caar opened)) gnus-inserted-opened-servers))
 340       (setq opened (cdr opened))))
 341   (goto-char (point-min))
 342   (gnus-server-position-point))
 343
 344 (defun gnus-server-server-name ()
 345   (let ((server (get-text-property (gnus-point-at-bol) 'gnus-server)))
 346     (and server (symbol-name server))))
 347
 348 (defalias 'gnus-server-position-point 'gnus-goto-colon)
 349
 350 (defconst gnus-server-edit-buffer "*Gnus edit server*")
 351
 352 (defun gnus-server-update-server (server)
 353   (save-excursion
 354     (set-buffer gnus-server-buffer)
 355     (let* ((buffer-read-only nil)
 356            (entry (assoc server gnus-server-alist))
 357            (oentry (assoc (gnus-server-to-method server)
 358                           gnus-opened-servers)))
 359       (when entry
 360         (gnus-dribble-enter
 361          (concat "(gnus-server-set-info \"" server "\" '"
 362                  (gnus-prin1-to-string (cdr entry)) ")\n")))
 363       (when (or entry oentry)
 364         ;; Buffer may be narrowed.
 365         (save-restriction
 366           (widen)
 367           (when (gnus-server-goto-server server)
 368             (gnus-delete-line))
 369           (if entry
 370               (gnus-server-insert-server-line (car entry) (cdr entry))
 371             (gnus-server-insert-server-line
 372              (format "%s:%s" (caar oentry) (nth 1 (car oentry)))
 373              (car oentry)))
 374           (gnus-server-position-point))))))
 375
 376 (defun gnus-server-set-info (server info)
 377   ;; Enter a select method into the virtual server alist.
 378   (when (and server info)
 379     (gnus-dribble-enter
 380      (concat "(gnus-server-set-info \"" server "\" '"
 381              (gnus-prin1-to-string info) ")"))
 382     (let* ((server (nth 1 info))
 383            (entry (assoc server gnus-server-alist))
 384            (cached (assoc server gnus-server-method-cache)))
 385       (if cached
 386           (setq gnus-server-method-cache
 387                 (delq cached gnus-server-method-cache)))
 388       (if entry (setcdr entry info)
 389         (setq gnus-server-alist
 390               (nconc gnus-server-alist (list (cons server info))))))))
 391
 392 ;;; Interactive server functions.
 393
 394 (defun gnus-server-kill-server (server)
 395   "Kill the server on the current line."
 396   (interactive (list (gnus-server-server-name)))
 397   (unless (gnus-server-goto-server server)
 398     (if server (error "No such server: %s" server)
 399       (error "No server on the current line")))
 400   (unless (assoc server gnus-server-alist)
 401     (error "Read-only server %s" server))
 402   (gnus-dribble-touch)
 403   (let ((buffer-read-only nil))
 404     (gnus-delete-line))
 405   (push (assoc server gnus-server-alist) gnus-server-killed-servers)
 406   (setq gnus-server-alist (delq (car gnus-server-killed-servers)
 407                                 gnus-server-alist))
 408   (let ((groups (gnus-groups-from-server server)))
 409     (when (and groups
 410                (gnus-yes-or-no-p
 411                 (format "Kill all %s groups from this server? "
 412                         (length groups))))
 413       (dolist (group groups)
 414         (setq gnus-newsrc-alist
 415               (delq (assoc group gnus-newsrc-alist)
 416                     gnus-newsrc-alist))
 417         (when gnus-group-change-level-function
 418           (funcall gnus-group-change-level-function
 419                    group gnus-level-killed 3)))))
 420   (gnus-server-position-point))
 421
 422 (defun gnus-server-yank-server ()
 423   "Yank the previously killed server."
 424   (interactive)
 425   (unless gnus-server-killed-servers
 426     (error "No killed servers to be yanked"))
 427   (let ((alist gnus-server-alist)
 428         (server (gnus-server-server-name))
 429         (killed (car gnus-server-killed-servers)))
 430     (if (not server)
 431         (setq gnus-server-alist (nconc gnus-server-alist (list killed)))
 432       (if (string= server (caar gnus-server-alist))
 433           (push killed gnus-server-alist)
 434         (while (and (cdr alist)
 435                     (not (string= server (caadr alist))))
 436           (setq alist (cdr alist)))
 437         (if alist
 438             (setcdr alist (cons killed (cdr alist)))
 439           (setq gnus-server-alist (list killed)))))
 440     (gnus-server-update-server (car killed))
 441     (setq gnus-server-killed-servers (cdr gnus-server-killed-servers))
 442     (gnus-server-position-point)))
 443
 444 (defun gnus-server-exit ()
 445   "Return to the group buffer."
 446   (interactive)
 447   (gnus-run-hooks 'gnus-server-exit-hook)
 448   (gnus-kill-buffer (current-buffer))
 449   (gnus-configure-windows 'group t))
 450
 451 (defun gnus-server-list-servers ()
 452   "List all available servers."
 453   (interactive)
 454   (let ((cur (gnus-server-server-name)))
 455     (gnus-server-prepare)
 456     (if cur (gnus-server-goto-server cur)
 457       (goto-char (point-max))
 458       (forward-line -1))
 459     (gnus-server-position-point)))
 460
 461 (defun gnus-server-set-status (method status)
 462   "Make METHOD have STATUS."
 463   (let ((entry (assoc method gnus-opened-servers)))
 464     (if entry
 465         (setcar (cdr entry) status)
 466       (push (list method status) gnus-opened-servers))))
 467
 468 (defun gnus-opened-servers-remove (method)
 469   "Remove METHOD from the list of opened servers."
 470   (setq gnus-opened-servers (delq (assoc method gnus-opened-servers)
 471                                   gnus-opened-servers)))
 472
 473 (defun gnus-server-open-server (server)
 474   "Force an open of SERVER."
 475   (interactive (list (gnus-server-server-name)))
 476   (let ((method (gnus-server-to-method server)))
 477     (unless method
 478       (error "No such server: %s" server))
 479     (gnus-server-set-status method 'ok)
 480     (prog1
 481         (or (gnus-open-server method)
 482             (progn (message "Couldn't open %s" server) nil))
 483       (gnus-server-update-server server)
 484       (gnus-server-position-point))))
 485
 486 (defun gnus-server-open-all-servers ()
 487   "Open all servers."
 488   (interactive)
 489   (let ((servers gnus-inserted-opened-servers))
 490     (while servers
 491       (gnus-server-open-server (car (pop servers))))))
 492
 493 (defun gnus-server-close-server (server)
 494   "Close SERVER."
 495   (interactive (list (gnus-server-server-name)))
 496   (let ((method (gnus-server-to-method server)))
 497     (unless method
 498       (error "No such server: %s" server))
 499     (gnus-server-set-status method 'closed)
 500     (prog1
 501         (gnus-close-server method)
 502       (gnus-server-update-server server)
 503       (gnus-server-position-point))))
 504
 505 (defun gnus-server-offline-server (server)
 506   "Set SERVER to offline."
 507   (interactive (list (gnus-server-server-name)))
 508   (let ((method (gnus-server-to-method server)))
 509     (unless method
 510       (error "No such server: %s" server))
 511     (prog1
 512         (gnus-close-server method)
 513       (gnus-server-set-status method 'offline)
 514       (gnus-server-update-server server)
 515       (gnus-server-position-point))))
 516
 517 (defun gnus-server-close-all-servers ()
 518   "Close all servers."
 519   (interactive)
 520   (dolist (server gnus-inserted-opened-servers)
 521     (gnus-server-close-server (car server))))
 522
 523 (defun gnus-server-deny-server (server)
 524   "Make sure SERVER will never be attempted opened."
 525   (interactive (list (gnus-server-server-name)))
 526   (let ((method (gnus-server-to-method server)))
 527     (unless method
 528       (error "No such server: %s" server))
 529     (gnus-server-set-status method 'denied))
 530   (gnus-server-update-server server)
 531   (gnus-server-position-point)
 532   t)
 533
 534 (defun gnus-server-remove-denials ()
 535   "Make all denied servers into closed servers."
 536   (interactive)
 537   (dolist (server gnus-opened-servers)
 538     (when (eq (nth 1 server) 'denied)
 539       (setcar (nthcdr 1 server) 'closed)))
 540   (gnus-server-list-servers))
 541
 542 (defun gnus-server-copy-server (from to)
 543   (interactive
 544    (list
 545     (or (gnus-server-server-name)
 546         (error "No server on the current line"))
 547     (read-string "Copy to: ")))
 548   (unless from
 549     (error "No server on current line"))
 550   (unless (and to (not (string= to "")))
 551     (error "No name to copy to"))
 552   (when (assoc to gnus-server-alist)
 553     (error "%s already exists" to))
 554   (unless (gnus-server-to-method from)
 555     (error "%s: no such server" from))
 556   (let ((to-entry (cons from (gnus-copy-sequence
 557                               (gnus-server-to-method from)))))
 558     (setcar to-entry to)
 559     (setcar (nthcdr 2 to-entry) to)
 560     (push to-entry gnus-server-killed-servers)
 561     (gnus-server-yank-server)))
 562
 563 (defun gnus-server-add-server (how where)
 564   (interactive
 565    (list (intern (completing-read "Server method: "
 566                                   gnus-valid-select-methods nil t))
 567          (read-string "Server name: ")))
 568   (when (assq where gnus-server-alist)
 569     (error "Server with that name already defined"))
 570   (push (list where how where) gnus-server-killed-servers)
 571   (gnus-server-yank-server))
 572
 573 (defun gnus-server-goto-server (server)
 574   "Jump to a server line."
 575   (interactive
 576    (list (completing-read "Goto server: " gnus-server-alist nil t)))
 577   (let ((to (text-property-any (point-min) (point-max)
 578                                'gnus-server (intern server))))
 579     (when to
 580       (goto-char to)
 581       (gnus-server-position-point))))
 582
 583 (defun gnus-server-edit-server (server)
 584   "Edit the server on the current line."
 585   (interactive (list (gnus-server-server-name)))
 586   (unless server
 587     (error "No server on current line"))
 588   (unless (assoc server gnus-server-alist)
 589     (error "This server can't be edited"))
 590   (let ((info (cdr (assoc server gnus-server-alist))))
 591     (gnus-close-server info)
 592     (gnus-edit-form
 593      info "Editing the server."
 594      `(lambda (form)
 595         (gnus-server-set-info ,server form)
 596         (gnus-server-list-servers)
 597         (gnus-server-position-point)))))
 598
 599 (defun gnus-server-scan-server (server)
 600   "Request a scan from the current server."
 601   (interactive (list (gnus-server-server-name)))
 602   (let ((method (gnus-server-to-method server)))
 603     (if (not (gnus-get-function method 'request-scan))
 604         (error "Server %s can't scan" (car method))
 605       (gnus-message 3 "Scanning %s..." server)
 606       (gnus-request-scan nil method)
 607       (gnus-message 3 "Scanning %s...done" server))))
 608
 609 (defun gnus-server-read-server-in-server-buffer (server)
 610   "Browse a server in server buffer."
 611   (interactive (list (gnus-server-server-name)))
 612   (let (gnus-server-browse-in-group-buffer)
 613     (gnus-server-read-server server)))
 614
 615 (defun gnus-server-read-server (server)
 616   "Browse a server."
 617   (interactive (list (gnus-server-server-name)))
 618   (let ((buf (current-buffer)))
 619     (prog1
 620         (gnus-browse-foreign-server server buf)
 621       (save-excursion
 622         (set-buffer buf)
 623         (gnus-server-update-server (gnus-server-server-name))
 624         (gnus-server-position-point)))))
 625
 626 (defun gnus-server-pick-server (e)
 627   (interactive "e")
 628   (mouse-set-point e)
 629   (gnus-server-read-server (gnus-server-server-name)))
 630
 631 \f
 632 ;;;
 633 ;;; Browse Server Mode
 634 ;;;
 635
 636 (defvar gnus-browse-menu-hook nil
 637   "*Hook run after the creation of the browse mode menu.")
 638
 639 (defvar gnus-browse-mode-hook nil)
 640 (defvar gnus-browse-mode-map nil)
 641 (put 'gnus-browse-mode 'mode-class 'special)
 642
 643 (unless gnus-browse-mode-map
 644   (setq gnus-browse-mode-map (make-keymap))
 645   (suppress-keymap gnus-browse-mode-map)
 646
 647   (gnus-define-keys
 648       gnus-browse-mode-map
 649     " " gnus-browse-read-group
 650     "=" gnus-browse-select-group
 651     "n" gnus-browse-next-group
 652     "p" gnus-browse-prev-group
 653     "\177" gnus-browse-prev-group
 654     [delete] gnus-browse-prev-group
 655     "N" gnus-browse-next-group
 656     "P" gnus-browse-prev-group
 657     "\M-n" gnus-browse-next-group
 658     "\M-p" gnus-browse-prev-group
 659     "\r" gnus-browse-select-group
 660     "u" gnus-browse-unsubscribe-current-group
 661     "l" gnus-browse-exit
 662     "L" gnus-browse-exit
 663     "q" gnus-browse-exit
 664     "Q" gnus-browse-exit
 665     "d" gnus-browse-describe-group
 666     "\C-c\C-c" gnus-browse-exit
 667     "?" gnus-browse-describe-briefly
 668
 669     "\C-c\C-i" gnus-info-find-node
 670     "\C-c\C-b" gnus-bug))
 671
 672 (defun gnus-browse-make-menu-bar ()
 673   (gnus-turn-off-edit-menu 'browse)
 674   (unless (boundp 'gnus-browse-menu)
 675     (easy-menu-define
 676      gnus-browse-menu gnus-browse-mode-map ""
 677      '("Browse"
 678        ["Subscribe" gnus-browse-unsubscribe-current-group t]
 679        ["Read" gnus-browse-read-group t]
 680        ["Select" gnus-browse-select-group t]
 681        ["Describe" gnus-browse-describe-groups t]
 682        ["Next" gnus-browse-next-group t]
 683        ["Prev" gnus-browse-prev-group t]
 684        ["Exit" gnus-browse-exit t]))
 685     (gnus-run-hooks 'gnus-browse-menu-hook)))
 686
 687 (defvar gnus-browse-current-method nil)
 688 (defvar gnus-browse-return-buffer nil)
 689
 690 (defvar gnus-browse-buffer "*Gnus Browse Server*")
 691
 692 (defun gnus-browse-foreign-server (server &optional return-buffer)
 693   "Browse the server SERVER."
 694   (setq gnus-browse-current-method (gnus-server-to-method server))
 695   (setq gnus-browse-return-buffer return-buffer)
 696   (let* ((method gnus-browse-current-method)
 697          (orig-select-method gnus-select-method)
 698          (gnus-select-method method)
 699          groups group)
 700     (gnus-message 5 "Connecting to %s..." (nth 1 method))
 701     (cond
 702      ((not (gnus-check-server method))
 703       (gnus-message
 704        1 "Unable to contact server %s: %s" (nth 1 method)
 705        (gnus-status-message method))
 706       nil)
 707      ((not
 708        (prog2
 709            (gnus-message 6 "Reading active file...")
 710            (gnus-request-list method)
 711          (gnus-message 6 "Reading active file...done")))
 712       (gnus-message
 713        1 "Couldn't request list: %s" (gnus-status-message method))
 714       nil)
 715      (t
 716       (save-excursion
 717         (set-buffer nntp-server-buffer)
 718         (let ((cur (current-buffer)))
 719           (goto-char (point-min))
 720           (unless (string= gnus-ignored-newsgroups "")
 721             (delete-matching-lines gnus-ignored-newsgroups))
 722           (while (not (eobp))
 723             (ignore-errors
 724               (push (cons
 725                      (if (eq (char-after) ?\")
 726                          (read cur)
 727                        (let ((p (point)) (name ""))
 728                          (skip-chars-forward "^ \t\\\\")
 729                          (setq name (buffer-substring p (point)))
 730                          (while (eq (char-after) ?\\)
 731                            (setq p (1+ (point)))
 732                            (forward-char 2)
 733                            (skip-chars-forward "^ \t\\\\")
 734                            (setq name (concat name (buffer-substring
 735                                                     p (point)))))
 736                          name))
 737                      (let ((last (read cur)))
 738                        (cons (read cur) last)))
 739                     groups))
 740             (forward-line))))
 741       (setq groups (sort groups
 742                          (lambda (l1 l2)
 743                            (string< (car l1) (car l2)))))
 744       (if gnus-server-browse-in-group-buffer
 745           (let* ((gnus-select-method orig-select-method)
 746                  (gnus-group-listed-groups
 747                   (mapcar (lambda (group)
 748                             (let ((name
 749                                    (gnus-group-prefixed-name
 750                                     (car group) method)))
 751                               (gnus-set-active name (cdr group))
 752                               name))
 753                           groups)))
 754             (gnus-configure-windows 'group)
 755             (funcall gnus-group-prepare-function
 756                      gnus-level-killed 'ignore 1 'ignore))
 757         (gnus-get-buffer-create gnus-browse-buffer)
 758         (when gnus-carpal
 759           (gnus-carpal-setup-buffer 'browse))
 760         (gnus-configure-windows 'browse)
 761         (buffer-disable-undo)
 762         (let ((buffer-read-only nil))
 763           (erase-buffer))
 764         (gnus-browse-mode)
 765         (setq mode-line-buffer-identification
 766               (list
 767                (format
 768                 "Gnus: %%b {%s:%s}" (car method) (cadr method))))
 769         (let ((buffer-read-only nil)
 770               name
 771               (prefix (let ((gnus-select-method orig-select-method))
 772                         (gnus-group-prefixed-name "" method))))
 773           (while (setq group (pop groups))
 774             (gnus-add-text-properties
 775              (point)
 776              (prog1 (1+ (point))
 777                (insert
 778                 (format "%c%7d: %s\n"
 779                         (let ((level (gnus-group-level
 780                                       (concat prefix (setq name (car group))))))
 781                               (cond
 782                                ((<= level gnus-level-subscribed) ? )
 783                                ((<= level gnus-level-unsubscribed) ?U)
 784                                ((= level gnus-level-zombie) ?Z)
 785                                (t ?K)))
 786                         (max 0 (- (1+ (cddr group)) (cadr group)))
 787                         (mm-decode-coding-string
 788                          name
 789                          (inline (gnus-group-name-charset method name))))))
 790              (list 'gnus-group name))))
 791         (switch-to-buffer (current-buffer)))
 792       (goto-char (point-min))
 793       (gnus-group-position-point)
 794       (gnus-message 5 "Connecting to %s...done" (nth 1 method))
 795       t))))
 796
 797 (defun gnus-browse-mode ()
 798   "Major mode for browsing a foreign server.
 799
 800 All normal editing commands are switched off.
 801
 802 \\<gnus-browse-mode-map>
 803 The only things you can do in this buffer is
 804
 805 1) `\\[gnus-browse-unsubscribe-current-group]' to subscribe to a group.
 806 The group will be inserted into the group buffer upon exit from this
 807 buffer.
 808
 809 2) `\\[gnus-browse-read-group]' to read a group ephemerally.
 810
 811 3) `\\[gnus-browse-exit]' to return to the group buffer."
 812   (interactive)
 813   (kill-all-local-variables)
 814   (when (gnus-visual-p 'browse-menu 'menu)
 815     (gnus-browse-make-menu-bar))
 816   (gnus-simplify-mode-line)
 817   (setq major-mode 'gnus-browse-mode)
 818   (setq mode-name "Browse Server")
 819   (setq mode-line-process nil)
 820   (use-local-map gnus-browse-mode-map)
 821   (buffer-disable-undo)
 822   (setq truncate-lines t)
 823   (gnus-set-default-directory)
 824   (setq buffer-read-only t)
 825   (gnus-run-hooks 'gnus-browse-mode-hook))
 826
 827 (defun gnus-browse-read-group (&optional no-article)
 828   "Enter the group at the current line."
 829   (interactive)
 830   (let ((group (gnus-browse-group-name)))
 831     (if (or (not (gnus-get-info group))
 832             (gnus-ephemeral-group-p group))
 833         (unless (gnus-group-read-ephemeral-group
 834                  (gnus-group-real-name group) gnus-browse-current-method nil
 835                  (cons (current-buffer) 'browse))
 836           (error "Couldn't enter %s" group))
 837       (unless (gnus-group-read-group nil no-article group)
 838         (error "Couldn't enter %s" group)))))
 839
 840 (defun gnus-browse-select-group ()
 841   "Select the current group."
 842   (interactive)
 843   (gnus-browse-read-group 'no))
 844
 845 (defun gnus-browse-next-group (n)
 846   "Go to the next group."
 847   (interactive "p")
 848   (prog1
 849       (forward-line n)
 850     (gnus-group-position-point)))
 851
 852 (defun gnus-browse-prev-group (n)
 853   "Go to the next group."
 854   (interactive "p")
 855   (gnus-browse-next-group (- n)))
 856
 857 (defun gnus-browse-unsubscribe-current-group (arg)
 858   "(Un)subscribe to the next ARG groups."
 859   (interactive "p")
 860   (when (eobp)
 861     (error "No group at current line"))
 862   (let ((ward (if (< arg 0) -1 1))
 863         (arg (abs arg)))
 864     (while (and (> arg 0)
 865                 (not (eobp))
 866                 (gnus-browse-unsubscribe-group)
 867                 (zerop (gnus-browse-next-group ward)))
 868       (decf arg))
 869     (gnus-group-position-point)
 870     (when (/= 0 arg)
 871       (gnus-message 7 "No more newsgroups"))
 872     arg))
 873
 874 (defun gnus-browse-group-name ()
 875   (save-excursion
 876     (beginning-of-line)
 877     (let ((name (get-text-property (point) 'gnus-group)))
 878       (when (re-search-forward ": \\(.*\\)$" (gnus-point-at-eol) t)
 879         (gnus-group-prefixed-name
 880          (or name
 881              (match-string-no-properties 1))
 882          gnus-browse-current-method)))))
 883
 884 (defun gnus-browse-describe-group (group)
 885   "Describe the current group."
 886   (interactive (list (gnus-browse-group-name)))
 887   (gnus-group-describe-group nil group))
 888
 889 (defun gnus-browse-unsubscribe-group ()
 890   "Toggle subscription of the current group in the browse buffer."
 891   (let ((sub nil)
 892         (buffer-read-only nil)
 893         group)
 894     (save-excursion
 895       (beginning-of-line)
 896       ;; If this group it killed, then we want to subscribe it.
 897       (unless (eq (char-after) ? )
 898         (setq sub t))
 899       (setq group (gnus-browse-group-name))
 900       (if sub
 901           (progn
 902             ;; Make sure the group has been properly removed before we
 903             ;; subscribe to it.
 904             (gnus-kill-ephemeral-group group)
 905             (gnus-group-change-level
 906              (list t group gnus-level-default-subscribed
 907                    nil nil (if (gnus-server-equal
 908                                 gnus-browse-current-method "native")
 909                                nil
 910                              (gnus-method-simplify
 911                               gnus-browse-current-method)))
 912              gnus-level-default-subscribed (gnus-group-level group)
 913              (and (car (nth 1 gnus-newsrc-alist))
 914                   (gnus-gethash (car (nth 1 gnus-newsrc-alist))
 915                                 gnus-newsrc-hashtb))
 916              t)
 917             (delete-char 1)
 918             (insert ? ))
 919         (gnus-group-change-level
 920          group gnus-level-unsubscribed gnus-level-default-subscribed)
 921         (delete-char 1)
 922         (insert ?U)))
 923     t))
 924
 925 (defun gnus-browse-exit ()
 926   "Quit browsing and return to the group buffer."
 927   (interactive)
 928   (when (eq major-mode 'gnus-browse-mode)
 929     (gnus-kill-buffer (current-buffer)))
 930   ;; Insert the newly subscribed groups in the group buffer.
 931   (save-excursion
 932     (set-buffer gnus-group-buffer)
 933     (gnus-group-list-groups nil))
 934   (if gnus-browse-return-buffer
 935       (gnus-configure-windows 'server 'force)
 936     (gnus-configure-windows 'group 'force)))
 937
 938 (defun gnus-browse-describe-briefly ()
 939   "Give a one line description of the group mode commands."
 940   (interactive)
 941   (gnus-message 6
 942                 (substitute-command-keys "\\<gnus-browse-mode-map>\\[gnus-group-next-group]:Forward  \\[gnus-group-prev-group]:Backward  \\[gnus-browse-exit]:Exit  \\[gnus-info-find-node]:Run Info  \\[gnus-browse-describe-briefly]:This help")))
 943
 944 (defun gnus-server-regenerate-server ()
 945   "Issue a command to the server to regenerate all its data structures."
 946   (interactive)
 947   (let ((server (gnus-server-server-name)))
 948     (unless server
 949       (error "No server on the current line"))
 950     (condition-case ()
 951         (gnus-get-function (gnus-server-to-method server)
 952                            'request-regenerate)
 953       (error
 954         (error "This backend doesn't support regeneration")))
 955     (gnus-message 5 "Requesting regeneration of %s..." server)
 956     (unless (gnus-open-server server)
 957       (error "Couldn't open server"))
 958     (if (gnus-request-regenerate server)
 959         (gnus-message 5 "Requesting regeneration of %s...done" server)
 960       (gnus-message 5 "Couldn't regenerate %s" server))))
 961
 962 (provide 'gnus-srvr)
 963
 964 ;;; gnus-srvr.el ends here