cgit.sxemacs.org Git - gnus/blob - lisp/gnus-srvr.el

   1 ;;; gnus-srvr.el --- virtual server support for Gnus
   2 ;; Copyright (C) 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003, 2004
   3 ;;        Free Software Foundation, Inc.
   4
   5 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   6 ;; Keywords: news
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;;; Code:
  28
  29 (eval-when-compile (require 'cl))
  30
  31 (require 'gnus)
  32 (require 'gnus-spec)
  33 (require 'gnus-group)
  34 (require 'gnus-int)
  35 (require 'gnus-range)
  36
  37 (defcustom gnus-server-mode-hook nil
  38   "Hook run in `gnus-server-mode' buffers."
  39   :group 'gnus-server
  40   :type 'hook)
  41
  42 (defcustom gnus-server-exit-hook nil
  43   "Hook run when exiting the server buffer."
  44   :group 'gnus-server
  45   :type 'hook)
  46
  47 (defcustom gnus-server-line-format "     {%(%h:%w%)} %s%a\n"
  48   "Format of server lines.
  49 It works along the same lines as a normal formatting string,
  50 with some simple extensions.
  51
  52 The following specs are understood:
  53
  54 %h back end
  55 %n name
  56 %w address
  57 %s status
  58 %a agent covered
  59
  60 General format specifiers can also be used.
  61 See Info node `(gnus)Formatting Variables'."
  62   :link '(custom-manual "(gnus)Formatting Variables")
  63   :group 'gnus-server-visual
  64   :type 'string)
  65
  66 (defcustom gnus-server-mode-line-format "Gnus: %%b"
  67   "The format specification for the server mode line."
  68   :group 'gnus-server-visual
  69   :type 'string)
  70
  71 (defcustom gnus-server-browse-in-group-buffer nil
  72   "Whether server browsing should take place in the group buffer.
  73 If nil, a faster, but more primitive, buffer is used instead."
  74   :version "21.4"
  75   :group 'gnus-server-visual
  76   :type 'boolean)
  77
  78 ;;; Internal variables.
  79
  80 (defvar gnus-inserted-opened-servers nil)
  81
  82 (defvar gnus-server-line-format-alist
  83   `((?h gnus-tmp-how ?s)
  84     (?n gnus-tmp-name ?s)
  85     (?w gnus-tmp-where ?s)
  86     (?s gnus-tmp-status ?s)
  87     (?a gnus-tmp-agent ?s)))
  88
  89 (defvar gnus-server-mode-line-format-alist
  90   `((?S gnus-tmp-news-server ?s)
  91     (?M gnus-tmp-news-method ?s)
  92     (?u gnus-tmp-user-defined ?s)))
  93
  94 (defvar gnus-server-line-format-spec nil)
  95 (defvar gnus-server-mode-line-format-spec nil)
  96 (defvar gnus-server-killed-servers nil)
  97
  98 (defvar gnus-server-mode-map)
  99
 100 (defvar gnus-server-menu-hook nil
 101   "*Hook run after the creation of the server mode menu.")
 102
 103 (defun gnus-server-make-menu-bar ()
 104   (gnus-turn-off-edit-menu 'server)
 105   (unless (boundp 'gnus-server-server-menu)
 106     (easy-menu-define
 107      gnus-server-server-menu gnus-server-mode-map ""
 108      '("Server"
 109        ["Add..." gnus-server-add-server t]
 110        ["Browse" gnus-server-read-server t]
 111        ["Scan" gnus-server-scan-server t]
 112        ["List" gnus-server-list-servers t]
 113        ["Kill" gnus-server-kill-server t]
 114        ["Yank" gnus-server-yank-server t]
 115        ["Copy" gnus-server-copy-server t]
 116        ["Edit" gnus-server-edit-server t]
 117        ["Regenerate" gnus-server-regenerate-server t]
 118        ["Exit" gnus-server-exit t]))
 119
 120     (easy-menu-define
 121      gnus-server-connections-menu gnus-server-mode-map ""
 122      '("Connections"
 123        ["Open" gnus-server-open-server t]
 124        ["Close" gnus-server-close-server t]
 125        ["Offline" gnus-server-offline-server t]
 126        ["Deny" gnus-server-deny-server t]
 127        "---"
 128        ["Open All" gnus-server-open-all-servers t]
 129        ["Close All" gnus-server-close-all-servers t]
 130        ["Reset All" gnus-server-remove-denials t]))
 131
 132     (gnus-run-hooks 'gnus-server-menu-hook)))
 133
 134 (defvar gnus-server-mode-map nil)
 135 (put 'gnus-server-mode 'mode-class 'special)
 136
 137 (unless gnus-server-mode-map
 138   (setq gnus-server-mode-map (make-sparse-keymap))
 139   (suppress-keymap gnus-server-mode-map)
 140
 141   (gnus-define-keys gnus-server-mode-map
 142     " " gnus-server-read-server-in-server-buffer
 143     "\r" gnus-server-read-server
 144     gnus-mouse-2 gnus-server-pick-server
 145     "q" gnus-server-exit
 146     "l" gnus-server-list-servers
 147     "k" gnus-server-kill-server
 148     "y" gnus-server-yank-server
 149     "c" gnus-server-copy-server
 150     "a" gnus-server-add-server
 151     "e" gnus-server-edit-server
 152     "s" gnus-server-scan-server
 153
 154     "O" gnus-server-open-server
 155     "\M-o" gnus-server-open-all-servers
 156     "C" gnus-server-close-server
 157     "\M-c" gnus-server-close-all-servers
 158     "D" gnus-server-deny-server
 159     "L" gnus-server-offline-server
 160     "R" gnus-server-remove-denials
 161
 162     "n" next-line
 163     "p" previous-line
 164
 165     "g" gnus-server-regenerate-server
 166
 167     "\C-c\C-i" gnus-info-find-node
 168     "\C-c\C-b" gnus-bug))
 169
 170 (defface gnus-server-agent-face
 171   '((((class color) (background light)) (:foreground "PaleTurquoise" :bold t))
 172     (((class color) (background dark)) (:foreground "PaleTurquoise" :bold t))
 173     (t (:bold t)))
 174   "Face used for displaying AGENTIZED servers"
 175   :group 'gnus-server-visual)
 176
 177 (defface gnus-server-opened-face
 178   '((((class color) (background light)) (:foreground "Green3" :bold t))
 179     (((class color) (background dark)) (:foreground "Green1" :bold t))
 180     (t (:bold t)))
 181   "Face used for displaying OPENED servers"
 182   :group 'gnus-server-visual)
 183
 184 (defface gnus-server-closed-face
 185   '((((class color) (background light)) (:foreground "Steel Blue" :italic t))
 186     (((class color) (background dark))
 187      (:foreground "Light Steel Blue" :italic t))
 188     (t (:italic t)))
 189   "Face used for displaying CLOSED servers"
 190   :group 'gnus-server-visual)
 191
 192 (defface gnus-server-denied-face
 193   '((((class color) (background light)) (:foreground "Red" :bold t))
 194     (((class color) (background dark)) (:foreground "Pink" :bold t))
 195     (t (:inverse-video t :bold t)))
 196   "Face used for displaying DENIED servers"
 197   :group 'gnus-server-visual)
 198
 199 (defface gnus-server-offline-face
 200   '((((class color) (background light)) (:foreground "Orange" :bold t))
 201     (((class color) (background dark)) (:foreground "Yellow" :bold t))
 202     (t (:inverse-video t :bold t)))
 203   "Face used for displaying OFFLINE servers"
 204   :group 'gnus-server-visual)
 205
 206 (defcustom gnus-server-agent-face 'gnus-server-agent-face
 207   "Face name to use on AGENTIZED servers."
 208   :group 'gnus-server-visual
 209   :type 'face)
 210
 211 (defcustom gnus-server-opened-face 'gnus-server-opened-face
 212   "Face name to use on OPENED servers."
 213   :group 'gnus-server-visual
 214   :type 'face)
 215
 216 (defcustom gnus-server-closed-face 'gnus-server-closed-face
 217   "Face name to use on CLOSED servers."
 218   :group 'gnus-server-visual
 219   :type 'face)
 220
 221 (defcustom gnus-server-denied-face 'gnus-server-denied-face
 222   "Face name to use on DENIED servers."
 223   :group 'gnus-server-visual
 224   :type 'face)
 225
 226 (defcustom gnus-server-offline-face 'gnus-server-offline-face
 227   "Face name to use on OFFLINE servers."
 228   :version "21.4"
 229   :group 'gnus-server-visual
 230   :type 'face)
 231
 232 (defvar gnus-server-font-lock-keywords
 233   (list
 234    '("(\\(agent\\))" 1 gnus-server-agent-face)
 235    '("(\\(opened\\))" 1 gnus-server-opened-face)
 236    '("(\\(closed\\))" 1 gnus-server-closed-face)
 237    '("(\\(offline\\))" 1 gnus-server-offline-face)
 238    '("(\\(denied\\))" 1 gnus-server-denied-face)))
 239
 240 (defun gnus-server-mode ()
 241   "Major mode for listing and editing servers.
 242
 243 All normal editing commands are switched off.
 244 \\<gnus-server-mode-map>
 245 For more in-depth information on this mode, read the manual
 246 \(`\\[gnus-info-find-node]').
 247
 248 The following commands are available:
 249
 250 \\{gnus-server-mode-map}"
 251   (interactive)
 252   (when (gnus-visual-p 'server-menu 'menu)
 253     (gnus-server-make-menu-bar))
 254   (kill-all-local-variables)
 255   (gnus-simplify-mode-line)
 256   (setq major-mode 'gnus-server-mode)
 257   (setq mode-name "Server")
 258   (gnus-set-default-directory)
 259   (setq mode-line-process nil)
 260   (use-local-map gnus-server-mode-map)
 261   (buffer-disable-undo)
 262   (setq truncate-lines t)
 263   (setq buffer-read-only t)
 264   (if (featurep 'xemacs)
 265       (put 'gnus-server-mode 'font-lock-defaults '(gnus-server-font-lock-keywords t))
 266     (set (make-local-variable 'font-lock-defaults)
 267          '(gnus-server-font-lock-keywords t)))
 268   (gnus-run-hooks 'gnus-server-mode-hook))
 269
 270 (defun gnus-server-insert-server-line (gnus-tmp-name method)
 271   (let* ((gnus-tmp-how (car method))
 272          (gnus-tmp-where (nth 1 method))
 273          (elem (assoc method gnus-opened-servers))
 274          (gnus-tmp-status
 275           (cond
 276            ((eq (nth 1 elem) 'denied) "(denied)")
 277            ((eq (nth 1 elem) 'offline) "(offline)")
 278            (t
 279             (condition-case nil
 280                 (if (or (gnus-server-opened method)
 281                         (eq (nth 1 elem) 'ok))
 282                     "(opened)"
 283                   "(closed)")
 284               ((error) "(error)")))))
 285          (gnus-tmp-agent (if (and gnus-agent
 286                                   (gnus-agent-method-p method))
 287                              " (agent)"
 288                            "")))
 289     (beginning-of-line)
 290     (gnus-add-text-properties
 291      (point)
 292      (prog1 (1+ (point))
 293        ;; Insert the text.
 294        (eval gnus-server-line-format-spec))
 295      (list 'gnus-server (intern gnus-tmp-name)
 296            'gnus-named-server (intern (gnus-method-to-server method))))))
 297
 298 (defun gnus-enter-server-buffer ()
 299   "Set up the server buffer."
 300   (gnus-server-setup-buffer)
 301   (gnus-configure-windows 'server)
 302   (gnus-server-prepare))
 303
 304 (defun gnus-server-setup-buffer ()
 305   "Initialize the server buffer."
 306   (unless (get-buffer gnus-server-buffer)
 307     (save-excursion
 308       (set-buffer (gnus-get-buffer-create gnus-server-buffer))
 309       (gnus-server-mode)
 310       (when gnus-carpal
 311         (gnus-carpal-setup-buffer 'server)))))
 312
 313 (defun gnus-server-prepare ()
 314   (gnus-set-format 'server-mode)
 315   (gnus-set-format 'server t)
 316   (let ((alist gnus-server-alist)
 317         (buffer-read-only nil)
 318         done server op-ser)
 319     (erase-buffer)
 320     (setq gnus-inserted-opened-servers nil)
 321     ;; First we do the real list of servers.
 322     (while alist
 323       (unless (member (cdar alist) done)
 324         (push (cdar alist) done)
 325         (setq server (pop alist))
 326         (when (and server (car server) (cdr server))
 327           (gnus-server-insert-server-line (car server) (cdr server))))
 328       (when (member (cdar alist) done)
 329         (pop alist)))
 330     ;; Then we insert the list of servers that have been opened in
 331     ;; this session.
 332     (dolist (open gnus-opened-servers)
 333       (when (and (not (member (car open) done))
 334                  ;; Just ignore ephemeral servers.
 335                  (not (member (car open) gnus-ephemeral-servers)))
 336         (push (car open) done)
 337         (gnus-server-insert-server-line
 338          (setq op-ser (format "%s:%s" (caar open) (nth 1 (car open))))
 339          (car open))
 340         (push (list op-ser (car open)) gnus-inserted-opened-servers))))
 341   (goto-char (point-min))
 342   (gnus-server-position-point))
 343
 344 (defun gnus-server-server-name ()
 345   (let ((server (get-text-property (point-at-bol) 'gnus-server)))
 346     (and server (symbol-name server))))
 347
 348 (defun gnus-server-named-server ()
 349   "Return a server name that matches one of the names returned by
 350 `gnus-method-to-server'."
 351   (let ((server (get-text-property (point-at-bol) 'gnus-named-server)))
 352     (and server (symbol-name server))))
 353
 354 (defalias 'gnus-server-position-point 'gnus-goto-colon)
 355
 356 (defconst gnus-server-edit-buffer "*Gnus edit server*")
 357
 358 (defun gnus-server-update-server (server)
 359   (save-excursion
 360     (set-buffer gnus-server-buffer)
 361     (let* ((buffer-read-only nil)
 362            (entry (assoc server gnus-server-alist))
 363            (oentry (assoc (gnus-server-to-method server)
 364                           gnus-opened-servers)))
 365       (when entry
 366         (gnus-dribble-enter
 367          (concat "(gnus-server-set-info \"" server "\" '"
 368                  (gnus-prin1-to-string (cdr entry)) ")\n")))
 369       (when (or entry oentry)
 370         ;; Buffer may be narrowed.
 371         (save-restriction
 372           (widen)
 373           (when (gnus-server-goto-server server)
 374             (gnus-delete-line))
 375           (if entry
 376               (gnus-server-insert-server-line (car entry) (cdr entry))
 377             (gnus-server-insert-server-line
 378              (format "%s:%s" (caar oentry) (nth 1 (car oentry)))
 379              (car oentry)))
 380           (gnus-server-position-point))))))
 381
 382 (defun gnus-server-set-info (server info)
 383   ;; Enter a select method into the virtual server alist.
 384   (when (and server info)
 385     (gnus-dribble-enter
 386      (concat "(gnus-server-set-info \"" server "\" '"
 387              (gnus-prin1-to-string info) ")"))
 388     (let* ((server (nth 1 info))
 389            (entry (assoc server gnus-server-alist))
 390            (cached (assoc server gnus-server-method-cache)))
 391       (if cached
 392           (setq gnus-server-method-cache
 393                 (delq cached gnus-server-method-cache)))
 394       (if entry
 395           (progn
 396             ;; Remove the server from `gnus-opened-servers' since
 397             ;; it has never been opened with the new `info' yet.
 398             (gnus-opened-servers-remove (cdr entry))
 399             ;; Don't make a new Lisp object.
 400             (setcar (cdr entry) (car info))
 401             (setcdr (cdr entry) (cdr info)))
 402         (setq gnus-server-alist
 403               (nconc gnus-server-alist (list (cons server info))))))))
 404
 405 ;;; Interactive server functions.
 406
 407 (defun gnus-server-kill-server (server)
 408   "Kill the server on the current line."
 409   (interactive (list (gnus-server-server-name)))
 410   (unless (gnus-server-goto-server server)
 411     (if server (error "No such server: %s" server)
 412       (error "No server on the current line")))
 413   (unless (assoc server gnus-server-alist)
 414     (error "Read-only server %s" server))
 415   (gnus-dribble-touch)
 416   (let ((buffer-read-only nil))
 417     (gnus-delete-line))
 418   (push (assoc server gnus-server-alist) gnus-server-killed-servers)
 419   (setq gnus-server-alist (delq (car gnus-server-killed-servers)
 420                                 gnus-server-alist))
 421   (let ((groups (gnus-groups-from-server server)))
 422     (when (and groups
 423                (gnus-yes-or-no-p
 424                 (format "Kill all %s groups from this server? "
 425                         (length groups))))
 426       (dolist (group groups)
 427         (setq gnus-newsrc-alist
 428               (delq (assoc group gnus-newsrc-alist)
 429                     gnus-newsrc-alist))
 430         (when gnus-group-change-level-function
 431           (funcall gnus-group-change-level-function
 432                    group gnus-level-killed 3)))))
 433   (gnus-server-position-point))
 434
 435 (defun gnus-server-yank-server ()
 436   "Yank the previously killed server."
 437   (interactive)
 438   (unless gnus-server-killed-servers
 439     (error "No killed servers to be yanked"))
 440   (let ((alist gnus-server-alist)
 441         (server (gnus-server-server-name))
 442         (killed (car gnus-server-killed-servers)))
 443     (if (not server)
 444         (setq gnus-server-alist (nconc gnus-server-alist (list killed)))
 445       (if (string= server (caar gnus-server-alist))
 446           (push killed gnus-server-alist)
 447         (while (and (cdr alist)
 448                     (not (string= server (caadr alist))))
 449           (setq alist (cdr alist)))
 450         (if alist
 451             (setcdr alist (cons killed (cdr alist)))
 452           (setq gnus-server-alist (list killed)))))
 453     (gnus-server-update-server (car killed))
 454     (setq gnus-server-killed-servers (cdr gnus-server-killed-servers))
 455     (gnus-server-position-point)))
 456
 457 (defun gnus-server-exit ()
 458   "Return to the group buffer."
 459   (interactive)
 460   (gnus-run-hooks 'gnus-server-exit-hook)
 461   (gnus-kill-buffer (current-buffer))
 462   (gnus-configure-windows 'group t))
 463
 464 (defun gnus-server-list-servers ()
 465   "List all available servers."
 466   (interactive)
 467   (let ((cur (gnus-server-server-name)))
 468     (gnus-server-prepare)
 469     (if cur (gnus-server-goto-server cur)
 470       (goto-char (point-max))
 471       (forward-line -1))
 472     (gnus-server-position-point)))
 473
 474 (defun gnus-server-set-status (method status)
 475   "Make METHOD have STATUS."
 476   (let ((entry (assoc method gnus-opened-servers)))
 477     (if entry
 478         (setcar (cdr entry) status)
 479       (push (list method status) gnus-opened-servers))))
 480
 481 (defun gnus-opened-servers-remove (method)
 482   "Remove METHOD from the list of opened servers."
 483   (setq gnus-opened-servers (delq (assoc method gnus-opened-servers)
 484                                   gnus-opened-servers)))
 485
 486 (defun gnus-server-open-server (server)
 487   "Force an open of SERVER."
 488   (interactive (list (gnus-server-server-name)))
 489   (let ((method (gnus-server-to-method server)))
 490     (unless method
 491       (error "No such server: %s" server))
 492     (gnus-server-set-status method 'ok)
 493     (prog1
 494         (or (gnus-open-server method)
 495             (progn (message "Couldn't open %s" server) nil))
 496       (gnus-server-update-server server)
 497       (gnus-server-position-point))))
 498
 499 (defun gnus-server-open-all-servers ()
 500   "Open all servers."
 501   (interactive)
 502   (dolist (server gnus-inserted-opened-servers)
 503     (gnus-server-open-server (car server))))
 504
 505 (defun gnus-server-close-server (server)
 506   "Close SERVER."
 507   (interactive (list (gnus-server-server-name)))
 508   (let ((method (gnus-server-to-method server)))
 509     (unless method
 510       (error "No such server: %s" server))
 511     (gnus-server-set-status method 'closed)
 512     (prog1
 513         (gnus-close-server method)
 514       (gnus-server-update-server server)
 515       (gnus-server-position-point))))
 516
 517 (defun gnus-server-offline-server (server)
 518   "Set SERVER to offline."
 519   (interactive (list (gnus-server-server-name)))
 520   (let ((method (gnus-server-to-method server)))
 521     (unless method
 522       (error "No such server: %s" server))
 523     (prog1
 524         (gnus-close-server method)
 525       (gnus-server-set-status method 'offline)
 526       (gnus-server-update-server server)
 527       (gnus-server-position-point))))
 528
 529 (defun gnus-server-close-all-servers ()
 530   "Close all servers."
 531   (interactive)
 532   (dolist (server gnus-inserted-opened-servers)
 533     (gnus-server-close-server (car server))))
 534
 535 (defun gnus-server-deny-server (server)
 536   "Make sure SERVER will never be attempted opened."
 537   (interactive (list (gnus-server-server-name)))
 538   (let ((method (gnus-server-to-method server)))
 539     (unless method
 540       (error "No such server: %s" server))
 541     (gnus-server-set-status method 'denied))
 542   (gnus-server-update-server server)
 543   (gnus-server-position-point)
 544   t)
 545
 546 (defun gnus-server-remove-denials ()
 547   "Make all denied servers into closed servers."
 548   (interactive)
 549   (dolist (server gnus-opened-servers)
 550     (when (eq (nth 1 server) 'denied)
 551       (setcar (nthcdr 1 server) 'closed)))
 552   (gnus-server-list-servers))
 553
 554 (defun gnus-server-copy-server (from to)
 555   (interactive
 556    (list
 557     (or (gnus-server-server-name)
 558         (error "No server on the current line"))
 559     (read-string "Copy to: ")))
 560   (unless from
 561     (error "No server on current line"))
 562   (unless (and to (not (string= to "")))
 563     (error "No name to copy to"))
 564   (when (assoc to gnus-server-alist)
 565     (error "%s already exists" to))
 566   (unless (gnus-server-to-method from)
 567     (error "%s: no such server" from))
 568   (let ((to-entry (cons from (gnus-copy-sequence
 569                               (gnus-server-to-method from)))))
 570     (setcar to-entry to)
 571     (setcar (nthcdr 2 to-entry) to)
 572     (push to-entry gnus-server-killed-servers)
 573     (gnus-server-yank-server)))
 574
 575 (defun gnus-server-add-server (how where)
 576   (interactive
 577    (list (intern (completing-read "Server method: "
 578                                   gnus-valid-select-methods nil t))
 579          (read-string "Server name: ")))
 580   (when (assq where gnus-server-alist)
 581     (error "Server with that name already defined"))
 582   (push (list where how where) gnus-server-killed-servers)
 583   (gnus-server-yank-server))
 584
 585 (defun gnus-server-goto-server (server)
 586   "Jump to a server line."
 587   (interactive
 588    (list (completing-read "Goto server: " gnus-server-alist nil t)))
 589   (let ((to (text-property-any (point-min) (point-max)
 590                                'gnus-server (intern server))))
 591     (when to
 592       (goto-char to)
 593       (gnus-server-position-point))))
 594
 595 (defun gnus-server-edit-server (server)
 596   "Edit the server on the current line."
 597   (interactive (list (gnus-server-server-name)))
 598   (unless server
 599     (error "No server on current line"))
 600   (unless (assoc server gnus-server-alist)
 601     (error "This server can't be edited"))
 602   (let ((info (cdr (assoc server gnus-server-alist))))
 603     (gnus-close-server info)
 604     (gnus-edit-form
 605      info "Editing the server."
 606      `(lambda (form)
 607         (gnus-server-set-info ,server form)
 608         (gnus-server-list-servers)
 609         (gnus-server-position-point)))))
 610
 611 (defun gnus-server-scan-server (server)
 612   "Request a scan from the current server."
 613   (interactive (list (gnus-server-server-name)))
 614   (let ((method (gnus-server-to-method server)))
 615     (if (not (gnus-get-function method 'request-scan))
 616         (error "Server %s can't scan" (car method))
 617       (gnus-message 3 "Scanning %s..." server)
 618       (gnus-request-scan nil method)
 619       (gnus-message 3 "Scanning %s...done" server))))
 620
 621 (defun gnus-server-read-server-in-server-buffer (server)
 622   "Browse a server in server buffer."
 623   (interactive (list (gnus-server-server-name)))
 624   (let (gnus-server-browse-in-group-buffer)
 625     (gnus-server-read-server server)))
 626
 627 (defun gnus-server-read-server (server)
 628   "Browse a server."
 629   (interactive (list (gnus-server-server-name)))
 630   (let ((buf (current-buffer)))
 631     (prog1
 632         (gnus-browse-foreign-server server buf)
 633       (save-excursion
 634         (set-buffer buf)
 635         (gnus-server-update-server (gnus-server-server-name))
 636         (gnus-server-position-point)))))
 637
 638 (defun gnus-server-pick-server (e)
 639   (interactive "e")
 640   (mouse-set-point e)
 641   (gnus-server-read-server (gnus-server-server-name)))
 642
 643 \f
 644 ;;;
 645 ;;; Browse Server Mode
 646 ;;;
 647
 648 (defvar gnus-browse-menu-hook nil
 649   "*Hook run after the creation of the browse mode menu.")
 650
 651 (defvar gnus-browse-mode-hook nil)
 652 (defvar gnus-browse-mode-map nil)
 653 (put 'gnus-browse-mode 'mode-class 'special)
 654
 655 (unless gnus-browse-mode-map
 656   (setq gnus-browse-mode-map (make-keymap))
 657   (suppress-keymap gnus-browse-mode-map)
 658
 659   (gnus-define-keys
 660       gnus-browse-mode-map
 661     " " gnus-browse-read-group
 662     "=" gnus-browse-select-group
 663     "n" gnus-browse-next-group
 664     "p" gnus-browse-prev-group
 665     "\177" gnus-browse-prev-group
 666     [delete] gnus-browse-prev-group
 667     "N" gnus-browse-next-group
 668     "P" gnus-browse-prev-group
 669     "\M-n" gnus-browse-next-group
 670     "\M-p" gnus-browse-prev-group
 671     "\r" gnus-browse-select-group
 672     "u" gnus-browse-unsubscribe-current-group
 673     "l" gnus-browse-exit
 674     "L" gnus-browse-exit
 675     "q" gnus-browse-exit
 676     "Q" gnus-browse-exit
 677     "d" gnus-browse-describe-group
 678     "\C-c\C-c" gnus-browse-exit
 679     "?" gnus-browse-describe-briefly
 680
 681     "\C-c\C-i" gnus-info-find-node
 682     "\C-c\C-b" gnus-bug))
 683
 684 (defun gnus-browse-make-menu-bar ()
 685   (gnus-turn-off-edit-menu 'browse)
 686   (unless (boundp 'gnus-browse-menu)
 687     (easy-menu-define
 688      gnus-browse-menu gnus-browse-mode-map ""
 689      '("Browse"
 690        ["Subscribe" gnus-browse-unsubscribe-current-group t]
 691        ["Read" gnus-browse-read-group t]
 692        ["Select" gnus-browse-select-group t]
 693        ["Describe" gnus-browse-describe-group t]
 694        ["Next" gnus-browse-next-group t]
 695        ["Prev" gnus-browse-prev-group t]
 696        ["Exit" gnus-browse-exit t]))
 697     (gnus-run-hooks 'gnus-browse-menu-hook)))
 698
 699 (defvar gnus-browse-current-method nil)
 700 (defvar gnus-browse-return-buffer nil)
 701
 702 (defvar gnus-browse-buffer "*Gnus Browse Server*")
 703
 704 (defun gnus-browse-foreign-server (server &optional return-buffer)
 705   "Browse the server SERVER."
 706   (setq gnus-browse-current-method (gnus-server-to-method server))
 707   (setq gnus-browse-return-buffer return-buffer)
 708   (let* ((method gnus-browse-current-method)
 709          (orig-select-method gnus-select-method)
 710          (gnus-select-method method)
 711          groups group)
 712     (gnus-message 5 "Connecting to %s..." (nth 1 method))
 713     (cond
 714      ((not (gnus-check-server method))
 715       (gnus-message
 716        1 "Unable to contact server %s: %s" (nth 1 method)
 717        (gnus-status-message method))
 718       nil)
 719      ((not
 720        (prog2
 721            (gnus-message 6 "Reading active file...")
 722            (gnus-request-list method)
 723          (gnus-message 6 "Reading active file...done")))
 724       (gnus-message
 725        1 "Couldn't request list: %s" (gnus-status-message method))
 726       nil)
 727      (t
 728       (with-current-buffer nntp-server-buffer
 729         (let ((cur (current-buffer)))
 730           (goto-char (point-min))
 731           (unless (string= gnus-ignored-newsgroups "")
 732             (delete-matching-lines gnus-ignored-newsgroups))
 733           ;; We treat NNTP as a special case to avoid problems with
 734           ;; garbage group names like `"foo' that appear in some badly
 735           ;; managed active files. -jh.
 736           (if (eq (car method) 'nntp)
 737               (while (not (eobp))
 738                 (ignore-errors
 739                   (push (cons
 740                          (buffer-substring
 741                           (point)
 742                           (progn
 743                             (skip-chars-forward "^ \t")
 744                             (point)))
 745                          (let ((last (read cur)))
 746                            (cons (read cur) last)))
 747                         groups))
 748                 (forward-line))
 749             (while (not (eobp))
 750               (ignore-errors
 751                 (push (cons
 752                        (if (eq (char-after) ?\")
 753                            (read cur)
 754                          (let ((p (point)) (name ""))
 755                            (skip-chars-forward "^ \t\\\\")
 756                            (setq name (buffer-substring p (point)))
 757                            (while (eq (char-after) ?\\)
 758                              (setq p (1+ (point)))
 759                              (forward-char 2)
 760                              (skip-chars-forward "^ \t\\\\")
 761                              (setq name (concat name (buffer-substring
 762                                                       p (point)))))
 763                            name))
 764                        (let ((last (read cur)))
 765                          (cons (read cur) last)))
 766                       groups))
 767               (forward-line)))))
 768       (setq groups (sort groups
 769                          (lambda (l1 l2)
 770                            (string< (car l1) (car l2)))))
 771       (if gnus-server-browse-in-group-buffer
 772           (let* ((gnus-select-method orig-select-method)
 773                  (gnus-group-listed-groups
 774                   (mapcar (lambda (group)
 775                             (let ((name
 776                                    (gnus-group-prefixed-name
 777                                     (car group) method)))
 778                               (gnus-set-active name (cdr group))
 779                               name))
 780                           groups)))
 781             (gnus-configure-windows 'group)
 782             (funcall gnus-group-prepare-function
 783                      gnus-level-killed 'ignore 1 'ignore))
 784         (gnus-get-buffer-create gnus-browse-buffer)
 785         (when gnus-carpal
 786           (gnus-carpal-setup-buffer 'browse))
 787         (gnus-configure-windows 'browse)
 788         (buffer-disable-undo)
 789         (let ((buffer-read-only nil))
 790           (erase-buffer))
 791         (gnus-browse-mode)
 792         (setq mode-line-buffer-identification
 793               (list
 794                (format
 795                 "Gnus: %%b {%s:%s}" (car method) (cadr method))))
 796         (let ((buffer-read-only nil)
 797               name
 798               (prefix (let ((gnus-select-method orig-select-method))
 799                         (gnus-group-prefixed-name "" method))))
 800           (while (setq group (pop groups))
 801             (gnus-add-text-properties
 802              (point)
 803              (prog1 (1+ (point))
 804                (insert
 805                 (format "%c%7d: %s\n"
 806                         (let ((level
 807                                (if (string= prefix "")
 808                                    (gnus-group-level (setq name (car group)))
 809                                  (gnus-group-level
 810                                   (concat prefix (setq name (car group)))))))
 811                           (cond
 812                            ((<= level gnus-level-subscribed) ? )
 813                            ((<= level gnus-level-unsubscribed) ?U)
 814                            ((= level gnus-level-zombie) ?Z)
 815                            (t ?K)))
 816                         (max 0 (- (1+ (cddr group)) (cadr group)))
 817                         ;; Don't decode if name is ASCII
 818                         (if (and (fboundp 'detect-coding-string)
 819                                  (eq (detect-coding-string name t) 'undecided))
 820                             name
 821                           (mm-decode-coding-string
 822                            name
 823                            (inline (gnus-group-name-charset method name)))))))
 824              (list 'gnus-group name)
 825              )))
 826         (switch-to-buffer (current-buffer)))
 827       (goto-char (point-min))
 828       (gnus-group-position-point)
 829       (gnus-message 5 "Connecting to %s...done" (nth 1 method))
 830       t))))
 831
 832 (defun gnus-browse-mode ()
 833   "Major mode for browsing a foreign server.
 834
 835 All normal editing commands are switched off.
 836
 837 \\<gnus-browse-mode-map>
 838 The only things you can do in this buffer is
 839
 840 1) `\\[gnus-browse-unsubscribe-current-group]' to subscribe to a group.
 841 The group will be inserted into the group buffer upon exit from this
 842 buffer.
 843
 844 2) `\\[gnus-browse-read-group]' to read a group ephemerally.
 845
 846 3) `\\[gnus-browse-exit]' to return to the group buffer."
 847   (interactive)
 848   (kill-all-local-variables)
 849   (when (gnus-visual-p 'browse-menu 'menu)
 850     (gnus-browse-make-menu-bar))
 851   (gnus-simplify-mode-line)
 852   (setq major-mode 'gnus-browse-mode)
 853   (setq mode-name "Browse Server")
 854   (setq mode-line-process nil)
 855   (use-local-map gnus-browse-mode-map)
 856   (buffer-disable-undo)
 857   (setq truncate-lines t)
 858   (gnus-set-default-directory)
 859   (setq buffer-read-only t)
 860   (gnus-run-hooks 'gnus-browse-mode-hook))
 861
 862 (defun gnus-browse-read-group (&optional no-article)
 863   "Enter the group at the current line."
 864   (interactive)
 865   (let ((group (gnus-browse-group-name)))
 866     (if (or (not (gnus-get-info group))
 867             (gnus-ephemeral-group-p group))
 868         (unless (gnus-group-read-ephemeral-group
 869                  group gnus-browse-current-method nil
 870                  (cons (current-buffer) 'browse))
 871           (error "Couldn't enter %s" group))
 872       (unless (gnus-group-read-group nil no-article group)
 873         (error "Couldn't enter %s" group)))))
 874
 875 (defun gnus-browse-select-group ()
 876   "Select the current group."
 877   (interactive)
 878   (gnus-browse-read-group 'no))
 879
 880 (defun gnus-browse-next-group (n)
 881   "Go to the next group."
 882   (interactive "p")
 883   (prog1
 884       (forward-line n)
 885     (gnus-group-position-point)))
 886
 887 (defun gnus-browse-prev-group (n)
 888   "Go to the next group."
 889   (interactive "p")
 890   (gnus-browse-next-group (- n)))
 891
 892 (defun gnus-browse-unsubscribe-current-group (arg)
 893   "(Un)subscribe to the next ARG groups."
 894   (interactive "p")
 895   (when (eobp)
 896     (error "No group at current line"))
 897   (let ((ward (if (< arg 0) -1 1))
 898         (arg (abs arg)))
 899     (while (and (> arg 0)
 900                 (not (eobp))
 901                 (gnus-browse-unsubscribe-group)
 902                 (zerop (gnus-browse-next-group ward)))
 903       (decf arg))
 904     (gnus-group-position-point)
 905     (when (/= 0 arg)
 906       (gnus-message 7 "No more newsgroups"))
 907     arg))
 908
 909 (defun gnus-browse-group-name ()
 910   (save-excursion
 911     (beginning-of-line)
 912     (let ((name (get-text-property (point) 'gnus-group)))
 913       (when (re-search-forward ": \\(.*\\)$" (point-at-eol) t)
 914         (concat (gnus-method-to-server-name gnus-browse-current-method) ":"
 915                 (or name
 916                     (match-string-no-properties 1)))))))
 917
 918 (defun gnus-browse-describe-group (group)
 919   "Describe the current group."
 920   (interactive (list (gnus-browse-group-name)))
 921   (gnus-group-describe-group nil group))
 922
 923 (defun gnus-browse-unsubscribe-group ()
 924   "Toggle subscription of the current group in the browse buffer."
 925   (let ((sub nil)
 926         (buffer-read-only nil)
 927         group)
 928     (save-excursion
 929       (beginning-of-line)
 930       ;; If this group it killed, then we want to subscribe it.
 931       (unless (eq (char-after) ? )
 932         (setq sub t))
 933       (setq group (gnus-browse-group-name))
 934       (when (gnus-server-equal gnus-browse-current-method "native")
 935         (setq group (gnus-group-real-name group)))
 936       (if sub
 937           (progn
 938             ;; Make sure the group has been properly removed before we
 939             ;; subscribe to it.
 940             (gnus-kill-ephemeral-group group)
 941             (gnus-group-change-level
 942              (list t group gnus-level-default-subscribed
 943                    nil nil (if (gnus-server-equal
 944                                 gnus-browse-current-method "native")
 945                                nil
 946                              (gnus-method-simplify
 947                               gnus-browse-current-method)))
 948              gnus-level-default-subscribed (gnus-group-level group)
 949              (and (car (nth 1 gnus-newsrc-alist))
 950                   (gnus-group-entry (car (nth 1 gnus-newsrc-alist))))
 951              t)
 952             (delete-char 1)
 953             (insert ? ))
 954         (gnus-group-change-level
 955          group gnus-level-unsubscribed gnus-level-default-subscribed)
 956         (delete-char 1)
 957         (insert ?U)))
 958     t))
 959
 960 (defun gnus-browse-exit ()
 961   "Quit browsing and return to the group buffer."
 962   (interactive)
 963   (when (eq major-mode 'gnus-browse-mode)
 964     (gnus-kill-buffer (current-buffer)))
 965   ;; Insert the newly subscribed groups in the group buffer.
 966   (save-excursion
 967     (set-buffer gnus-group-buffer)
 968     (gnus-group-list-groups nil))
 969   (if gnus-browse-return-buffer
 970       (gnus-configure-windows 'server 'force)
 971     (gnus-configure-windows 'group 'force)))
 972
 973 (defun gnus-browse-describe-briefly ()
 974   "Give a one line description of the group mode commands."
 975   (interactive)
 976   (gnus-message 6
 977                 (substitute-command-keys "\\<gnus-browse-mode-map>\\[gnus-group-next-group]:Forward  \\[gnus-group-prev-group]:Backward  \\[gnus-browse-exit]:Exit  \\[gnus-info-find-node]:Run Info  \\[gnus-browse-describe-briefly]:This help")))
 978
 979 (defun gnus-server-regenerate-server ()
 980   "Issue a command to the server to regenerate all its data structures."
 981   (interactive)
 982   (let ((server (gnus-server-server-name)))
 983     (unless server
 984       (error "No server on the current line"))
 985     (condition-case ()
 986         (gnus-get-function (gnus-server-to-method server)
 987                            'request-regenerate)
 988       (error
 989         (error "This back end doesn't support regeneration")))
 990     (gnus-message 5 "Requesting regeneration of %s..." server)
 991     (unless (gnus-open-server server)
 992       (error "Couldn't open server"))
 993     (if (gnus-request-regenerate server)
 994         (gnus-message 5 "Requesting regeneration of %s...done" server)
 995       (gnus-message 5 "Couldn't regenerate %s" server))))
 996
 997 (provide 'gnus-srvr)
 998
 999 ;;; arch-tag: c0117f64-27ca-475d-9406-8da6854c7a25
1000 ;;; gnus-srvr.el ends here