cgit.sxemacs.org Git - gnus/blob - lisp/gnus-srvr.el

   1 ;;; gnus-srvr.el --- virtual server support for Gnus
   2 ;; Copyright (C) 1995-2000 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   5 ;; Keywords: news
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  22 ;; Boston, MA 02111-1307, USA.
  23
  24 ;;; Commentary:
  25
  26 ;;; Code:
  27
  28 (eval-when-compile (require 'cl))
  29
  30 (require 'gnus)
  31 (require 'gnus-spec)
  32 (require 'gnus-group)
  33 (require 'gnus-int)
  34 (require 'gnus-range)
  35
  36 (defvar gnus-server-mode-hook nil
  37   "Hook run in `gnus-server-mode' buffers.")
  38
  39 (defconst gnus-server-line-format "     {%(%h:%w%)} %s\n"
  40   "Format of server lines.
  41 It works along the same lines as a normal formatting string,
  42 with some simple extensions.
  43
  44 The following specs are understood:
  45
  46 %h backend
  47 %n name
  48 %w address
  49 %s status")
  50
  51 (defvar gnus-server-mode-line-format "Gnus: %%b"
  52   "The format specification for the server mode line.")
  53
  54 (defvar gnus-server-exit-hook nil
  55   "*Hook run when exiting the server buffer.")
  56
  57 ;;; Internal variables.
  58
  59 (defvar gnus-inserted-opened-servers nil)
  60
  61 (defvar gnus-server-line-format-alist
  62   `((?h gnus-tmp-how ?s)
  63     (?n gnus-tmp-name ?s)
  64     (?w gnus-tmp-where ?s)
  65     (?s gnus-tmp-status ?s)))
  66
  67 (defvar gnus-server-mode-line-format-alist
  68   `((?S gnus-tmp-news-server ?s)
  69     (?M gnus-tmp-news-method ?s)
  70     (?u gnus-tmp-user-defined ?s)))
  71
  72 (defvar gnus-server-line-format-spec nil)
  73 (defvar gnus-server-mode-line-format-spec nil)
  74 (defvar gnus-server-killed-servers nil)
  75
  76 (defvar gnus-server-mode-map)
  77
  78 (defvar gnus-server-menu-hook nil
  79   "*Hook run after the creation of the server mode menu.")
  80
  81 (defun gnus-server-make-menu-bar ()
  82   (gnus-turn-off-edit-menu 'server)
  83   (unless (boundp 'gnus-server-server-menu)
  84     (easy-menu-define
  85      gnus-server-server-menu gnus-server-mode-map ""
  86      '("Server"
  87        ["Add" gnus-server-add-server t]
  88        ["Browse" gnus-server-read-server t]
  89        ["Scan" gnus-server-scan-server t]
  90        ["List" gnus-server-list-servers t]
  91        ["Kill" gnus-server-kill-server t]
  92        ["Yank" gnus-server-yank-server t]
  93        ["Copy" gnus-server-copy-server t]
  94        ["Edit" gnus-server-edit-server t]
  95        ["Regenerate" gnus-server-regenerate-server t]
  96        ["Exit" gnus-server-exit t]))
  97
  98     (easy-menu-define
  99      gnus-server-connections-menu gnus-server-mode-map ""
 100      '("Connections"
 101        ["Open" gnus-server-open-server t]
 102        ["Close" gnus-server-close-server t]
 103        ["Deny" gnus-server-deny-server t]
 104        "---"
 105        ["Open All" gnus-server-open-all-servers t]
 106        ["Close All" gnus-server-close-all-servers t]
 107        ["Reset All" gnus-server-remove-denials t]))
 108
 109     (gnus-run-hooks 'gnus-server-menu-hook)))
 110
 111 (defvar gnus-server-mode-map nil)
 112 (put 'gnus-server-mode 'mode-class 'special)
 113
 114 (unless gnus-server-mode-map
 115   (setq gnus-server-mode-map (make-sparse-keymap))
 116   (suppress-keymap gnus-server-mode-map)
 117
 118   (gnus-define-keys gnus-server-mode-map
 119     " " gnus-server-read-server
 120     "\r" gnus-server-read-server
 121     gnus-mouse-2 gnus-server-pick-server
 122     "q" gnus-server-exit
 123     "l" gnus-server-list-servers
 124     "k" gnus-server-kill-server
 125     "y" gnus-server-yank-server
 126     "c" gnus-server-copy-server
 127     "a" gnus-server-add-server
 128     "e" gnus-server-edit-server
 129     "s" gnus-server-scan-server
 130
 131     "O" gnus-server-open-server
 132     "\M-o" gnus-server-open-all-servers
 133     "C" gnus-server-close-server
 134     "\M-c" gnus-server-close-all-servers
 135     "D" gnus-server-deny-server
 136     "R" gnus-server-remove-denials
 137
 138     "n" next-line
 139     "p" previous-line
 140
 141     "g" gnus-server-regenerate-server
 142
 143     "\C-c\C-i" gnus-info-find-node
 144     "\C-c\C-b" gnus-bug))
 145
 146 (defun gnus-server-mode ()
 147   "Major mode for listing and editing servers.
 148
 149 All normal editing commands are switched off.
 150 \\<gnus-server-mode-map>
 151 For more in-depth information on this mode, read the manual
 152 (`\\[gnus-info-find-node]').
 153
 154 The following commands are available:
 155
 156 \\{gnus-server-mode-map}"
 157   (interactive)
 158   (when (gnus-visual-p 'server-menu 'menu)
 159     (gnus-server-make-menu-bar))
 160   (kill-all-local-variables)
 161   (gnus-simplify-mode-line)
 162   (setq major-mode 'gnus-server-mode)
 163   (setq mode-name "Server")
 164   (gnus-set-default-directory)
 165   (setq mode-line-process nil)
 166   (use-local-map gnus-server-mode-map)
 167   (buffer-disable-undo)
 168   (setq truncate-lines t)
 169   (setq buffer-read-only t)
 170   (gnus-run-hooks 'gnus-server-mode-hook))
 171
 172 (defun gnus-server-insert-server-line (gnus-tmp-name method)
 173   (let* ((gnus-tmp-how (car method))
 174          (gnus-tmp-where (nth 1 method))
 175          (elem (assoc method gnus-opened-servers))
 176          (gnus-tmp-status (cond ((eq (nth 1 elem) 'denied)
 177                                  "(denied)")
 178                                 ((or (gnus-server-opened method)
 179                                      (eq (nth 1 elem) 'ok))
 180                                  "(opened)")
 181                                 (t
 182                                  "(closed)"))))
 183     (beginning-of-line)
 184     (gnus-add-text-properties
 185      (point)
 186      (prog1 (1+ (point))
 187        ;; Insert the text.
 188        (eval gnus-server-line-format-spec))
 189      (list 'gnus-server (intern gnus-tmp-name)))))
 190
 191 (defun gnus-enter-server-buffer ()
 192   "Set up the server buffer."
 193   (gnus-server-setup-buffer)
 194   (gnus-configure-windows 'server)
 195   (gnus-server-prepare))
 196
 197 (defun gnus-server-setup-buffer ()
 198   "Initialize the server buffer."
 199   (unless (get-buffer gnus-server-buffer)
 200     (save-excursion
 201       (set-buffer (gnus-get-buffer-create gnus-server-buffer))
 202       (gnus-server-mode)
 203       (when gnus-carpal
 204         (gnus-carpal-setup-buffer 'server)))))
 205
 206 (defun gnus-server-prepare ()
 207   (gnus-set-format 'server-mode)
 208   (gnus-set-format 'server t)
 209   (let ((alist gnus-server-alist)
 210         (buffer-read-only nil)
 211         (opened gnus-opened-servers)
 212         done server op-ser)
 213     (erase-buffer)
 214     (setq gnus-inserted-opened-servers nil)
 215     ;; First we do the real list of servers.
 216     (while alist
 217       (unless (member (cdar alist) done)
 218         (push (cdar alist) done)
 219         (cdr (setq server (pop alist)))
 220         (when (and server (car server) (cdr server))
 221           (gnus-server-insert-server-line (car server) (cdr server))))
 222       (when (member (cdar alist) done)
 223         (pop alist)))
 224     ;; Then we insert the list of servers that have been opened in
 225     ;; this session.
 226     (while opened
 227       (when (and (not (member (caar opened) done))
 228                  ;; Just ignore ephemeral servers.
 229                  (not (member (caar opened) gnus-ephemeral-servers)))
 230         (push (caar opened) done)
 231         (gnus-server-insert-server-line
 232          (setq op-ser (format "%s:%s" (caaar opened) (nth 1 (caar opened))))
 233          (caar opened))
 234         (push (list op-ser (caar opened)) gnus-inserted-opened-servers))
 235       (setq opened (cdr opened))))
 236   (goto-char (point-min))
 237   (gnus-server-position-point))
 238
 239 (defun gnus-server-server-name ()
 240   (let ((server (get-text-property (gnus-point-at-bol) 'gnus-server)))
 241     (and server (symbol-name server))))
 242
 243 (defalias 'gnus-server-position-point 'gnus-goto-colon)
 244
 245 (defconst gnus-server-edit-buffer "*Gnus edit server*")
 246
 247 (defun gnus-server-update-server (server)
 248   (save-excursion
 249     (set-buffer gnus-server-buffer)
 250     (let* ((buffer-read-only nil)
 251            (entry (assoc server gnus-server-alist))
 252            (oentry (assoc (gnus-server-to-method server)
 253                           gnus-opened-servers)))
 254       (when entry
 255         (gnus-dribble-enter
 256          (concat "(gnus-server-set-info \"" server "\" '"
 257                  (prin1-to-string (cdr entry)) ")\n")))
 258       (when (or entry oentry)
 259         ;; Buffer may be narrowed.
 260         (save-restriction
 261           (widen)
 262           (when (gnus-server-goto-server server)
 263             (gnus-delete-line))
 264           (if entry
 265               (gnus-server-insert-server-line (car entry) (cdr entry))
 266             (gnus-server-insert-server-line
 267              (format "%s:%s" (caar oentry) (nth 1 (car oentry)))
 268              (car oentry)))
 269           (gnus-server-position-point))))))
 270
 271 (defun gnus-server-set-info (server info)
 272   ;; Enter a select method into the virtual server alist.
 273   (when (and server info)
 274     (gnus-dribble-enter
 275      (concat "(gnus-server-set-info \"" server "\" '"
 276              (prin1-to-string info) ")"))
 277     (let* ((server (nth 1 info))
 278            (entry (assoc server gnus-server-alist)))
 279       (if entry (setcdr entry info)
 280         (setq gnus-server-alist
 281               (nconc gnus-server-alist (list (cons server info))))))))
 282
 283 ;;; Interactive server functions.
 284
 285 (defun gnus-server-kill-server (server)
 286   "Kill the server on the current line."
 287   (interactive (list (gnus-server-server-name)))
 288   (unless (gnus-server-goto-server server)
 289     (if server (error "No such server: %s" server)
 290       (error "No server on the current line")))
 291   (unless (assoc server gnus-server-alist)
 292     (error "Read-only server %s" server))
 293   (gnus-dribble-touch)
 294   (let ((buffer-read-only nil))
 295     (gnus-delete-line))
 296   (push (assoc server gnus-server-alist) gnus-server-killed-servers)
 297   (setq gnus-server-alist (delq (car gnus-server-killed-servers)
 298                                 gnus-server-alist))
 299   (let ((groups (gnus-groups-from-server server)))
 300     (when (and groups
 301                (gnus-yes-or-no-p
 302                 (format "Kill all %s groups from this server? "
 303                         (length groups))))
 304       (dolist (group groups)
 305         (setq gnus-newsrc-alist
 306               (delq (assoc group gnus-newsrc-alist)
 307                     gnus-newsrc-alist))
 308         (when gnus-group-change-level-function
 309           (funcall gnus-group-change-level-function
 310                    group gnus-level-killed 3)))))
 311   (gnus-server-position-point))
 312
 313 (defun gnus-server-yank-server ()
 314   "Yank the previously killed server."
 315   (interactive)
 316   (unless gnus-server-killed-servers
 317     (error "No killed servers to be yanked"))
 318   (let ((alist gnus-server-alist)
 319         (server (gnus-server-server-name))
 320         (killed (car gnus-server-killed-servers)))
 321     (if (not server)
 322         (setq gnus-server-alist (nconc gnus-server-alist (list killed)))
 323       (if (string= server (caar gnus-server-alist))
 324           (push killed gnus-server-alist)
 325         (while (and (cdr alist)
 326                     (not (string= server (caadr alist))))
 327           (setq alist (cdr alist)))
 328         (if alist
 329             (setcdr alist (cons killed (cdr alist)))
 330           (setq gnus-server-alist (list killed)))))
 331     (gnus-server-update-server (car killed))
 332     (setq gnus-server-killed-servers (cdr gnus-server-killed-servers))
 333     (gnus-server-position-point)))
 334
 335 (defun gnus-server-exit ()
 336   "Return to the group buffer."
 337   (interactive)
 338   (gnus-run-hooks 'gnus-server-exit-hook)
 339   (kill-buffer (current-buffer))
 340   (gnus-configure-windows 'group t))
 341
 342 (defun gnus-server-list-servers ()
 343   "List all available servers."
 344   (interactive)
 345   (let ((cur (gnus-server-server-name)))
 346     (gnus-server-prepare)
 347     (if cur (gnus-server-goto-server cur)
 348       (goto-char (point-max))
 349       (forward-line -1))
 350     (gnus-server-position-point)))
 351
 352 (defun gnus-server-set-status (method status)
 353   "Make METHOD have STATUS."
 354   (let ((entry (assoc method gnus-opened-servers)))
 355     (if entry
 356         (setcar (cdr entry) status)
 357       (push (list method status) gnus-opened-servers))))
 358
 359 (defun gnus-opened-servers-remove (method)
 360   "Remove METHOD from the list of opened servers."
 361   (setq gnus-opened-servers (delq (assoc method gnus-opened-servers)
 362                                   gnus-opened-servers)))
 363
 364 (defun gnus-server-open-server (server)
 365   "Force an open of SERVER."
 366   (interactive (list (gnus-server-server-name)))
 367   (let ((method (gnus-server-to-method server)))
 368     (unless method
 369       (error "No such server: %s" server))
 370     (gnus-server-set-status method 'ok)
 371     (prog1
 372         (or (gnus-open-server method)
 373             (progn (message "Couldn't open %s" server) nil))
 374       (gnus-server-update-server server)
 375       (gnus-server-position-point))))
 376
 377 (defun gnus-server-open-all-servers ()
 378   "Open all servers."
 379   (interactive)
 380   (let ((servers gnus-inserted-opened-servers))
 381     (while servers
 382       (gnus-server-open-server (car (pop servers))))))
 383
 384 (defun gnus-server-close-server (server)
 385   "Close SERVER."
 386   (interactive (list (gnus-server-server-name)))
 387   (let ((method (gnus-server-to-method server)))
 388     (unless method
 389       (error "No such server: %s" server))
 390     (gnus-server-set-status method 'closed)
 391     (prog1
 392         (gnus-close-server method)
 393       (gnus-server-update-server server)
 394       (gnus-server-position-point))))
 395
 396 (defun gnus-server-close-all-servers ()
 397   "Close all servers."
 398   (interactive)
 399   (let ((servers gnus-inserted-opened-servers))
 400     (while servers
 401       (gnus-server-close-server (car (pop servers))))))
 402
 403 (defun gnus-server-deny-server (server)
 404   "Make sure SERVER will never be attempted opened."
 405   (interactive (list (gnus-server-server-name)))
 406   (let ((method (gnus-server-to-method server)))
 407     (unless method
 408       (error "No such server: %s" server))
 409     (gnus-server-set-status method 'denied))
 410   (gnus-server-update-server server)
 411   (gnus-server-position-point)
 412   t)
 413
 414 (defun gnus-server-remove-denials ()
 415   "Make all denied servers into closed servers."
 416   (interactive)
 417   (let ((servers gnus-opened-servers))
 418     (while servers
 419       (when (eq (nth 1 (car servers)) 'denied)
 420         (setcar (nthcdr 1 (car servers)) 'closed))
 421       (setq servers (cdr servers))))
 422   (gnus-server-list-servers))
 423
 424 (defun gnus-server-copy-server (from to)
 425   (interactive
 426    (list
 427     (or (gnus-server-server-name)
 428         (error "No server on the current line"))
 429     (read-string "Copy to: ")))
 430   (unless from
 431     (error "No server on current line"))
 432   (unless (and to (not (string= to "")))
 433     (error "No name to copy to"))
 434   (when (assoc to gnus-server-alist)
 435     (error "%s already exists" to))
 436   (unless (gnus-server-to-method from)
 437     (error "%s: no such server" from))
 438   (let ((to-entry (cons from (gnus-copy-sequence
 439                               (gnus-server-to-method from)))))
 440     (setcar to-entry to)
 441     (setcar (nthcdr 2 to-entry) to)
 442     (push to-entry gnus-server-killed-servers)
 443     (gnus-server-yank-server)))
 444
 445 (defun gnus-server-add-server (how where)
 446   (interactive
 447    (list (intern (completing-read "Server method: "
 448                                   gnus-valid-select-methods nil t))
 449          (read-string "Server name: ")))
 450   (when (assq where gnus-server-alist)
 451     (error "Server with that name already defined"))
 452   (push (list where how where) gnus-server-killed-servers)
 453   (gnus-server-yank-server))
 454
 455 (defun gnus-server-goto-server (server)
 456   "Jump to a server line."
 457   (interactive
 458    (list (completing-read "Goto server: " gnus-server-alist nil t)))
 459   (let ((to (text-property-any (point-min) (point-max)
 460                                'gnus-server (intern server))))
 461     (when to
 462       (goto-char to)
 463       (gnus-server-position-point))))
 464
 465 (defun gnus-server-edit-server (server)
 466   "Edit the server on the current line."
 467   (interactive (list (gnus-server-server-name)))
 468   (unless server
 469     (error "No server on current line"))
 470   (unless (assoc server gnus-server-alist)
 471     (error "This server can't be edited"))
 472   (let ((info (cdr (assoc server gnus-server-alist))))
 473     (gnus-close-server info)
 474     (gnus-edit-form
 475      info "Editing the server."
 476      `(lambda (form)
 477         (gnus-server-set-info ,server form)
 478         (gnus-server-list-servers)
 479         (gnus-server-position-point)))))
 480
 481 (defun gnus-server-scan-server (server)
 482   "Request a scan from the current server."
 483   (interactive (list (gnus-server-server-name)))
 484   (let ((method (gnus-server-to-method server)))
 485     (if (not (gnus-get-function method 'request-scan))
 486         (error "Server %s can't scan" (car method))
 487       (gnus-message 3 "Scanning %s..." server)
 488       (gnus-request-scan nil method)
 489       (gnus-message 3 "Scanning %s...done" server))))
 490
 491 (defun gnus-server-read-server (server)
 492   "Browse a server."
 493   (interactive (list (gnus-server-server-name)))
 494   (let ((buf (current-buffer)))
 495     (prog1
 496         (gnus-browse-foreign-server server buf)
 497       (save-excursion
 498         (set-buffer buf)
 499         (gnus-server-update-server (gnus-server-server-name))
 500         (gnus-server-position-point)))))
 501
 502 (defun gnus-server-pick-server (e)
 503   (interactive "e")
 504   (mouse-set-point e)
 505   (gnus-server-read-server (gnus-server-server-name)))
 506
 507 \f
 508 ;;;
 509 ;;; Browse Server Mode
 510 ;;;
 511
 512 (defvar gnus-browse-menu-hook nil
 513   "*Hook run after the creation of the browse mode menu.")
 514
 515 (defvar gnus-browse-mode-hook nil)
 516 (defvar gnus-browse-mode-map nil)
 517 (put 'gnus-browse-mode 'mode-class 'special)
 518
 519 (unless gnus-browse-mode-map
 520   (setq gnus-browse-mode-map (make-keymap))
 521   (suppress-keymap gnus-browse-mode-map)
 522
 523   (gnus-define-keys
 524       gnus-browse-mode-map
 525     " " gnus-browse-read-group
 526     "=" gnus-browse-select-group
 527     "n" gnus-browse-next-group
 528     "p" gnus-browse-prev-group
 529     "\177" gnus-browse-prev-group
 530     [delete] gnus-browse-prev-group
 531     "N" gnus-browse-next-group
 532     "P" gnus-browse-prev-group
 533     "\M-n" gnus-browse-next-group
 534     "\M-p" gnus-browse-prev-group
 535     "\r" gnus-browse-select-group
 536     "u" gnus-browse-unsubscribe-current-group
 537     "l" gnus-browse-exit
 538     "L" gnus-browse-exit
 539     "q" gnus-browse-exit
 540     "Q" gnus-browse-exit
 541     "\C-c\C-c" gnus-browse-exit
 542     "?" gnus-browse-describe-briefly
 543
 544     "\C-c\C-i" gnus-info-find-node
 545     "\C-c\C-b" gnus-bug))
 546
 547 (defun gnus-browse-make-menu-bar ()
 548   (gnus-turn-off-edit-menu 'browse)
 549   (unless (boundp 'gnus-browse-menu)
 550     (easy-menu-define
 551      gnus-browse-menu gnus-browse-mode-map ""
 552      '("Browse"
 553        ["Subscribe" gnus-browse-unsubscribe-current-group t]
 554        ["Read" gnus-browse-read-group t]
 555        ["Select" gnus-browse-select-group t]
 556        ["Next" gnus-browse-next-group t]
 557        ["Prev" gnus-browse-next-group t]
 558        ["Exit" gnus-browse-exit t]))
 559     (gnus-run-hooks 'gnus-browse-menu-hook)))
 560
 561 (defvar gnus-browse-current-method nil)
 562 (defvar gnus-browse-return-buffer nil)
 563
 564 (defvar gnus-browse-buffer "*Gnus Browse Server*")
 565
 566 (defun gnus-browse-foreign-server (server &optional return-buffer)
 567   "Browse the server SERVER."
 568   (setq gnus-browse-current-method (gnus-server-to-method server))
 569   (setq gnus-browse-return-buffer return-buffer)
 570   (let* ((method gnus-browse-current-method)
 571          (gnus-select-method method)
 572          groups group)
 573     (gnus-message 5 "Connecting to %s..." (nth 1 method))
 574     (cond
 575      ((not (gnus-check-server method))
 576       (gnus-message
 577        1 "Unable to contact server %s: %s" (nth 1 method)
 578        (gnus-status-message method))
 579       nil)
 580      ((not
 581        (prog2
 582            (gnus-message 6 "Reading active file...")
 583            (gnus-request-list method)
 584          (gnus-message 6 "Reading active file...done")))
 585       (gnus-message
 586        1 "Couldn't request list: %s" (gnus-status-message method))
 587       nil)
 588      (t
 589       (gnus-get-buffer-create gnus-browse-buffer)
 590       (when gnus-carpal
 591         (gnus-carpal-setup-buffer 'browse))
 592       (gnus-configure-windows 'browse)
 593       (buffer-disable-undo)
 594       (let ((buffer-read-only nil))
 595         (erase-buffer))
 596       (gnus-browse-mode)
 597       (setq mode-line-buffer-identification
 598             (list
 599              (format
 600               "Gnus: %%b {%s:%s}" (car method) (cadr method))))
 601       (save-excursion
 602         (set-buffer nntp-server-buffer)
 603         (let ((cur (current-buffer)))
 604           (goto-char (point-min))
 605           (unless (string= gnus-ignored-newsgroups "")
 606             (delete-matching-lines gnus-ignored-newsgroups))
 607           (while (not (eobp))
 608             (ignore-errors
 609               (push (cons
 610                      (if (eq (char-after) ?\")
 611                          (read cur)
 612                        (let ((p (point)) (name ""))
 613                          (skip-chars-forward "^ \t\\\\")
 614                          (setq name (buffer-substring p (point)))
 615                          (while (eq (char-after) ?\\)
 616                            (setq p (1+ (point)))
 617                            (forward-char 2)
 618                            (skip-chars-forward "^ \t\\\\")
 619                            (setq name (concat name (buffer-substring
 620                                                     p (point)))))
 621                          name))
 622                      (max 0 (- (1+ (read cur)) (read cur))))
 623                     groups))
 624             (forward-line))))
 625       (setq groups (sort groups
 626                          (lambda (l1 l2)
 627                            (string< (car l1) (car l2)))))
 628       (let ((buffer-read-only nil))
 629         (while groups
 630           (setq group (car groups))
 631           (insert
 632            (format "K%7d: %s\n" (cdr group) (car group)))
 633           (setq groups (cdr groups))))
 634       (switch-to-buffer (current-buffer))
 635       (goto-char (point-min))
 636       (gnus-group-position-point)
 637       (gnus-message 5 "Connecting to %s...done" (nth 1 method))
 638       t))))
 639
 640 (defun gnus-browse-mode ()
 641   "Major mode for browsing a foreign server.
 642
 643 All normal editing commands are switched off.
 644
 645 \\<gnus-browse-mode-map>
 646 The only things you can do in this buffer is
 647
 648 1) `\\[gnus-browse-unsubscribe-current-group]' to subscribe to a group.
 649 The group will be inserted into the group buffer upon exit from this
 650 buffer.
 651
 652 2) `\\[gnus-browse-read-group]' to read a group ephemerally.
 653
 654 3) `\\[gnus-browse-exit]' to return to the group buffer."
 655   (interactive)
 656   (kill-all-local-variables)
 657   (when (gnus-visual-p 'browse-menu 'menu)
 658     (gnus-browse-make-menu-bar))
 659   (gnus-simplify-mode-line)
 660   (setq major-mode 'gnus-browse-mode)
 661   (setq mode-name "Browse Server")
 662   (setq mode-line-process nil)
 663   (use-local-map gnus-browse-mode-map)
 664   (buffer-disable-undo)
 665   (setq truncate-lines t)
 666   (gnus-set-default-directory)
 667   (setq buffer-read-only t)
 668   (gnus-run-hooks 'gnus-browse-mode-hook))
 669
 670 (defun gnus-browse-read-group (&optional no-article)
 671   "Enter the group at the current line."
 672   (interactive)
 673   (let ((group (gnus-browse-group-name)))
 674     (if (or (not (gnus-get-info group))
 675             (gnus-ephemeral-group-p group))
 676         (unless (gnus-group-read-ephemeral-group
 677                  group gnus-browse-current-method nil
 678                  (cons (current-buffer) 'browse))
 679           (error "Couldn't enter %s" group))
 680       (unless (gnus-group-read-group nil no-article group)
 681         (error "Couldn't enter %s" group)))))
 682
 683 (defun gnus-browse-select-group ()
 684   "Select the current group."
 685   (interactive)
 686   (gnus-browse-read-group 'no))
 687
 688 (defun gnus-browse-next-group (n)
 689   "Go to the next group."
 690   (interactive "p")
 691   (prog1
 692       (forward-line n)
 693     (gnus-group-position-point)))
 694
 695 (defun gnus-browse-prev-group (n)
 696   "Go to the next group."
 697   (interactive "p")
 698   (gnus-browse-next-group (- n)))
 699
 700 (defun gnus-browse-unsubscribe-current-group (arg)
 701   "(Un)subscribe to the next ARG groups."
 702   (interactive "p")
 703   (when (eobp)
 704     (error "No group at current line"))
 705   (let ((ward (if (< arg 0) -1 1))
 706         (arg (abs arg)))
 707     (while (and (> arg 0)
 708                 (not (eobp))
 709                 (gnus-browse-unsubscribe-group)
 710                 (zerop (gnus-browse-next-group ward)))
 711       (decf arg))
 712     (gnus-group-position-point)
 713     (when (/= 0 arg)
 714       (gnus-message 7 "No more newsgroups"))
 715     arg))
 716
 717 (defun gnus-browse-group-name ()
 718   (save-excursion
 719     (beginning-of-line)
 720     (when (re-search-forward ": \\(.*\\)$" (gnus-point-at-eol) t)
 721       (gnus-group-prefixed-name
 722        ;; Remove text props.
 723        (format "%s" (match-string 1))
 724        gnus-browse-current-method))))
 725
 726 (defun gnus-browse-unsubscribe-group ()
 727   "Toggle subscription of the current group in the browse buffer."
 728   (let ((sub nil)
 729         (buffer-read-only nil)
 730         group)
 731     (save-excursion
 732       (beginning-of-line)
 733       ;; If this group it killed, then we want to subscribe it.
 734       (when (eq (char-after) ?K)
 735         (setq sub t))
 736       (setq group (gnus-browse-group-name))
 737       (when (and sub
 738                  (cadr (gnus-gethash group gnus-newsrc-hashtb)))
 739         (error "Group already subscribed"))
 740       (delete-char 1)
 741       (if sub
 742           (progn
 743             ;; Make sure the group has been properly removed before we
 744             ;; subscribe to it.
 745             (gnus-kill-ephemeral-group group)
 746             (gnus-group-change-level
 747              (list t group gnus-level-default-subscribed
 748                    nil nil (if (gnus-server-equal
 749                                 gnus-browse-current-method "native")
 750                                nil
 751                              (gnus-method-simplify
 752                               gnus-browse-current-method)))
 753              gnus-level-default-subscribed gnus-level-killed
 754              (and (car (nth 1 gnus-newsrc-alist))
 755                   (gnus-gethash (car (nth 1 gnus-newsrc-alist))
 756                                 gnus-newsrc-hashtb))
 757              t)
 758             (insert ? ))
 759         (gnus-group-change-level
 760          group gnus-level-killed gnus-level-default-subscribed)
 761         (insert ?K)))
 762     t))
 763
 764 (defun gnus-browse-exit ()
 765   "Quit browsing and return to the group buffer."
 766   (interactive)
 767   (when (eq major-mode 'gnus-browse-mode)
 768     (kill-buffer (current-buffer)))
 769   ;; Insert the newly subscribed groups in the group buffer.
 770   (save-excursion
 771     (set-buffer gnus-group-buffer)
 772     (gnus-group-list-groups nil))
 773   (if gnus-browse-return-buffer
 774       (gnus-configure-windows 'server 'force)
 775     (gnus-configure-windows 'group 'force)))
 776
 777 (defun gnus-browse-describe-briefly ()
 778   "Give a one line description of the group mode commands."
 779   (interactive)
 780   (gnus-message 6
 781                 (substitute-command-keys "\\<gnus-browse-mode-map>\\[gnus-group-next-group]:Forward  \\[gnus-group-prev-group]:Backward  \\[gnus-browse-exit]:Exit  \\[gnus-info-find-node]:Run Info  \\[gnus-browse-describe-briefly]:This help")))
 782
 783 (defun gnus-server-regenerate-server ()
 784   "Issue a command to the server to regenerate all its data structures."
 785   (interactive)
 786   (let ((server (gnus-server-server-name)))
 787     (unless server
 788       (error "No server on the current line"))
 789     (if (not (gnus-check-backend-function
 790               'request-regenerate (car (gnus-server-to-method server))))
 791         (error "This backend doesn't support regeneration")
 792       (gnus-message 5 "Requesting regeneration of %s..." server)
 793       (unless (gnus-open-server server)
 794         (error "Couldn't open server"))
 795       (if (gnus-request-regenerate server)
 796           (gnus-message 5 "Requesting regeneration of %s...done" server)
 797         (gnus-message 5 "Couldn't regenerate %s" server)))))
 798
 799 (provide 'gnus-srvr)
 800
 801 ;;; gnus-srvr.el ends here.