cgit.sxemacs.org Git - gnus/blob - lisp/gnus-srvr.el

   1 ;;; gnus-srvr.el --- virtual server support for Gnus
   2
   3 ;; Copyright (C) 1995-2014 Free Software Foundation, Inc.
   4
   5 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   6 ;; Keywords: news
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;;; Code:
  26
  27 (eval-when-compile (require 'cl))
  28
  29 (require 'gnus)
  30 (require 'gnus-start)
  31 (require 'gnus-spec)
  32 (require 'gnus-group)
  33 (require 'gnus-int)
  34 (require 'gnus-range)
  35
  36 (autoload 'gnus-group-make-nnir-group "nnir")
  37
  38 (defcustom gnus-server-mode-hook nil
  39   "Hook run in `gnus-server-mode' buffers."
  40   :group 'gnus-server
  41   :type 'hook)
  42
  43 (defcustom gnus-server-exit-hook nil
  44   "Hook run when exiting the server buffer."
  45   :group 'gnus-server
  46   :type 'hook)
  47
  48 (defcustom gnus-server-line-format "     {%(%h:%w%)} %s%a%c\n"
  49   "Format of server lines.
  50 It works along the same lines as a normal formatting string,
  51 with some simple extensions.
  52
  53 The following specs are understood:
  54
  55 %h back end
  56 %n name
  57 %w address
  58 %s status
  59 %a agent covered
  60
  61 General format specifiers can also be used.
  62 See Info node `(gnus)Formatting Variables'."
  63   :link '(custom-manual "(gnus)Formatting Variables")
  64   :group 'gnus-server-visual
  65   :type 'string)
  66
  67 (defcustom gnus-server-mode-line-format "Gnus: %%b"
  68   "The format specification for the server mode line."
  69   :group 'gnus-server-visual
  70   :type 'string)
  71
  72 (defcustom gnus-server-browse-in-group-buffer nil
  73   "Whether server browsing should take place in the group buffer.
  74 If nil, a faster, but more primitive, buffer is used instead."
  75   :version "22.1"
  76   :group 'gnus-server-visual
  77   :type 'boolean)
  78
  79 ;;; Internal variables.
  80
  81 (defvar gnus-inserted-opened-servers nil)
  82
  83 (defvar gnus-server-line-format-alist
  84   `((?h gnus-tmp-how ?s)
  85     (?n gnus-tmp-name ?s)
  86     (?w gnus-tmp-where ?s)
  87     (?s gnus-tmp-status ?s)
  88     (?a gnus-tmp-agent ?s)
  89     (?c gnus-tmp-cloud ?s)))
  90
  91 (defvar gnus-server-mode-line-format-alist
  92   `((?S gnus-tmp-news-server ?s)
  93     (?M gnus-tmp-news-method ?s)
  94     (?u gnus-tmp-user-defined ?s)))
  95
  96 (defvar gnus-server-line-format-spec nil)
  97 (defvar gnus-server-mode-line-format-spec nil)
  98 (defvar gnus-server-killed-servers nil)
  99
 100 (defvar gnus-server-mode-map)
 101
 102 (defvar gnus-server-menu-hook nil
 103   "*Hook run after the creation of the server mode menu.")
 104
 105 (defun gnus-server-make-menu-bar ()
 106   (gnus-turn-off-edit-menu 'server)
 107   (unless (boundp 'gnus-server-server-menu)
 108     (easy-menu-define
 109      gnus-server-server-menu gnus-server-mode-map ""
 110      '("Server"
 111        ["Add..." gnus-server-add-server t]
 112        ["Browse" gnus-server-read-server t]
 113        ["Scan" gnus-server-scan-server t]
 114        ["List" gnus-server-list-servers t]
 115        ["Kill" gnus-server-kill-server t]
 116        ["Yank" gnus-server-yank-server t]
 117        ["Copy" gnus-server-copy-server t]
 118        ["Show" gnus-server-show-server t]
 119        ["Edit" gnus-server-edit-server t]
 120        ["Regenerate" gnus-server-regenerate-server t]
 121        ["Compact" gnus-server-compact-server t]
 122        ["Exit" gnus-server-exit t]))
 123
 124     (easy-menu-define
 125      gnus-server-connections-menu gnus-server-mode-map ""
 126      '("Connections"
 127        ["Open" gnus-server-open-server t]
 128        ["Close" gnus-server-close-server t]
 129        ["Offline" gnus-server-offline-server t]
 130        ["Deny" gnus-server-deny-server t]
 131        ["Toggle Cloud" gnus-server-toggle-cloud-server t]
 132        "---"
 133        ["Open All" gnus-server-open-all-servers t]
 134        ["Close All" gnus-server-close-all-servers t]
 135        ["Reset All" gnus-server-remove-denials t]))
 136
 137     (gnus-run-hooks 'gnus-server-menu-hook)))
 138
 139 (defvar gnus-server-mode-map nil)
 140 (put 'gnus-server-mode 'mode-class 'special)
 141
 142 (unless gnus-server-mode-map
 143   (setq gnus-server-mode-map (make-sparse-keymap))
 144   (suppress-keymap gnus-server-mode-map)
 145
 146   (gnus-define-keys gnus-server-mode-map
 147     " " gnus-server-read-server-in-server-buffer
 148     "\r" gnus-server-read-server
 149     gnus-mouse-2 gnus-server-pick-server
 150     "q" gnus-server-exit
 151     "l" gnus-server-list-servers
 152     "k" gnus-server-kill-server
 153     "y" gnus-server-yank-server
 154     "c" gnus-server-copy-server
 155     "a" gnus-server-add-server
 156     "e" gnus-server-edit-server
 157     "S" gnus-server-show-server
 158     "s" gnus-server-scan-server
 159
 160     "O" gnus-server-open-server
 161     "\M-o" gnus-server-open-all-servers
 162     "C" gnus-server-close-server
 163     "\M-c" gnus-server-close-all-servers
 164     "D" gnus-server-deny-server
 165     "L" gnus-server-offline-server
 166     "R" gnus-server-remove-denials
 167
 168     "n" next-line
 169     "p" previous-line
 170
 171     "g" gnus-server-regenerate-server
 172
 173     "G" gnus-group-make-nnir-group
 174
 175     "z" gnus-server-compact-server
 176
 177     "i" gnus-server-toggle-cloud-server
 178
 179     "\C-c\C-i" gnus-info-find-node
 180     "\C-c\C-b" gnus-bug))
 181
 182 (defface gnus-server-agent
 183   '((((class color) (background light)) (:foreground "PaleTurquoise" :bold t))
 184     (((class color) (background dark)) (:foreground "PaleTurquoise" :bold t))
 185     (t (:bold t)))
 186   "Face used for displaying AGENTIZED servers"
 187   :group 'gnus-server-visual)
 188 ;; backward-compatibility alias
 189 (put 'gnus-server-agent-face 'face-alias 'gnus-server-agent)
 190 (put 'gnus-server-agent-face 'obsolete-face "22.1")
 191
 192 (defface gnus-server-cloud
 193   '((((class color) (background light)) (:foreground "ForestGreen" :bold t))
 194     (((class color) (background dark)) (:foreground "PaleGreen" :bold t))
 195     (t (:bold t)))
 196   "Face used for displaying AGENTIZED servers"
 197   :group 'gnus-server-visual)
 198
 199 (defface gnus-server-opened
 200   '((((class color) (background light)) (:foreground "Green3" :bold t))
 201     (((class color) (background dark)) (:foreground "Green1" :bold t))
 202     (t (:bold t)))
 203   "Face used for displaying OPENED servers"
 204   :group 'gnus-server-visual)
 205 ;; backward-compatibility alias
 206 (put 'gnus-server-opened-face 'face-alias 'gnus-server-opened)
 207 (put 'gnus-server-opened-face 'obsolete-face "22.1")
 208
 209 (defface gnus-server-closed
 210   '((((class color) (background light)) (:foreground "Steel Blue" :italic t))
 211     (((class color) (background dark))
 212      (:foreground "LightBlue" :italic t))
 213     (t (:italic t)))
 214   "Face used for displaying CLOSED servers"
 215   :group 'gnus-server-visual)
 216 ;; backward-compatibility alias
 217 (put 'gnus-server-closed-face 'face-alias 'gnus-server-closed)
 218 (put 'gnus-server-closed-face 'obsolete-face "22.1")
 219
 220 (defface gnus-server-denied
 221   '((((class color) (background light)) (:foreground "Red" :bold t))
 222     (((class color) (background dark)) (:foreground "Pink" :bold t))
 223     (t (:inverse-video t :bold t)))
 224   "Face used for displaying DENIED servers"
 225   :group 'gnus-server-visual)
 226 ;; backward-compatibility alias
 227 (put 'gnus-server-denied-face 'face-alias 'gnus-server-denied)
 228 (put 'gnus-server-denied-face 'obsolete-face "22.1")
 229
 230 (defface gnus-server-offline
 231   '((((class color) (background light)) (:foreground "Orange" :bold t))
 232     (((class color) (background dark)) (:foreground "Yellow" :bold t))
 233     (t (:inverse-video t :bold t)))
 234   "Face used for displaying OFFLINE servers"
 235   :group 'gnus-server-visual)
 236 ;; backward-compatibility alias
 237 (put 'gnus-server-offline-face 'face-alias 'gnus-server-offline)
 238 (put 'gnus-server-offline-face 'obsolete-face "22.1")
 239
 240 (defvar gnus-server-font-lock-keywords
 241   '(("(\\(agent\\))" 1 'gnus-server-agent)
 242     ("(\\(cloud\\))" 1 'gnus-server-cloud)
 243     ("(\\(opened\\))" 1 'gnus-server-opened)
 244     ("(\\(closed\\))" 1 'gnus-server-closed)
 245     ("(\\(offline\\))" 1 'gnus-server-offline)
 246     ("(\\(denied\\))" 1 'gnus-server-denied)))
 247
 248 (defun gnus-server-mode ()
 249   "Major mode for listing and editing servers.
 250
 251 All normal editing commands are switched off.
 252 \\<gnus-server-mode-map>
 253 For more in-depth information on this mode, read the manual
 254 \(`\\[gnus-info-find-node]').
 255
 256 The following commands are available:
 257
 258 \\{gnus-server-mode-map}"
 259   ;; FIXME: Use define-derived-mode.
 260   (interactive)
 261   (when (gnus-visual-p 'server-menu 'menu)
 262     (gnus-server-make-menu-bar))
 263   (kill-all-local-variables)
 264   (gnus-simplify-mode-line)
 265   (setq major-mode 'gnus-server-mode)
 266   (setq mode-name "Server")
 267   (gnus-set-default-directory)
 268   (setq mode-line-process nil)
 269   (use-local-map gnus-server-mode-map)
 270   (buffer-disable-undo)
 271   (setq truncate-lines t)
 272   (setq buffer-read-only t)
 273   (if (featurep 'xemacs)
 274       (put 'gnus-server-mode 'font-lock-defaults '(gnus-server-font-lock-keywords t))
 275     (set (make-local-variable 'font-lock-defaults)
 276          '(gnus-server-font-lock-keywords t)))
 277   (gnus-run-mode-hooks 'gnus-server-mode-hook))
 278
 279 (defun gnus-server-insert-server-line (gnus-tmp-name method)
 280   (let* ((gnus-tmp-how (car method))
 281          (gnus-tmp-where (nth 1 method))
 282          (elem (assoc method gnus-opened-servers))
 283          (gnus-tmp-status
 284           (cond
 285            ((eq (nth 1 elem) 'denied) "(denied)")
 286            ((eq (nth 1 elem) 'offline) "(offline)")
 287            (t
 288             (condition-case nil
 289                 (if (or (gnus-server-opened method)
 290                         (eq (nth 1 elem) 'ok))
 291                     "(opened)"
 292                   "(closed)")
 293               ((error) "(error)")))))
 294          (gnus-tmp-agent (if (and gnus-agent
 295                                   (gnus-agent-method-p method))
 296                              " (agent)"
 297                            ""))
 298          (gnus-tmp-cloud (if (gnus-cloud-server-p gnus-tmp-name)
 299                              " (cloud)"
 300                            "")))
 301     (beginning-of-line)
 302     (gnus-add-text-properties
 303      (point)
 304      (prog1 (1+ (point))
 305        ;; Insert the text.
 306        (eval gnus-server-line-format-spec))
 307      (list 'gnus-server (intern gnus-tmp-name)
 308            'gnus-named-server (intern (gnus-method-to-server method t))))))
 309
 310 (defun gnus-enter-server-buffer ()
 311   "Set up the server buffer."
 312   (gnus-server-setup-buffer)
 313   (gnus-configure-windows 'server)
 314   ;; Usually `gnus-configure-windows' will finish with the
 315   ;; `gnus-server-buffer' selected as the current buffer, but not always (I
 316   ;; bumped into it when starting from a dedicated *Group* frame, and
 317   ;; gnus-configure-windows opened *Server* into its own dedicated frame).
 318   (with-current-buffer (get-buffer gnus-server-buffer)
 319     (gnus-server-prepare)))
 320
 321 (defun gnus-server-setup-buffer ()
 322   "Initialize the server buffer."
 323   (unless (get-buffer gnus-server-buffer)
 324     (with-current-buffer (gnus-get-buffer-create gnus-server-buffer)
 325       (gnus-server-mode))))
 326
 327 (defun gnus-server-prepare ()
 328   (gnus-set-format 'server-mode)
 329   (gnus-set-format 'server t)
 330   (let ((alist gnus-server-alist)
 331         (buffer-read-only nil)
 332         done server op-ser)
 333     (erase-buffer)
 334     (setq gnus-inserted-opened-servers nil)
 335     ;; First we do the real list of servers.
 336     (while alist
 337       (unless (member (cdar alist) done)
 338         (push (cdar alist) done)
 339         (setq server (pop alist))
 340         (when (and server (car server) (cdr server))
 341           (gnus-server-insert-server-line (car server) (cdr server))))
 342       (when (member (cdar alist) done)
 343         (pop alist)))
 344     ;; Then we insert the list of servers that have been opened in
 345     ;; this session.
 346     (dolist (open gnus-opened-servers)
 347       (when (and (not (member (car open) done))
 348                  ;; Just ignore ephemeral servers.
 349                  (not (gnus-method-ephemeral-p (car open))))
 350         (push (car open) done)
 351         (gnus-server-insert-server-line
 352          (setq op-ser (format "%s:%s" (caar open) (nth 1 (car open))))
 353          (car open))
 354         (push (list op-ser (car open)) gnus-inserted-opened-servers))))
 355   (goto-char (point-min))
 356   (gnus-server-position-point))
 357
 358 (defun gnus-server-server-name ()
 359   (let ((server (get-text-property (point-at-bol) 'gnus-server)))
 360     (and server (symbol-name server))))
 361
 362 (defun gnus-server-named-server ()
 363   "Return a server name that matches one of the names returned by
 364 `gnus-method-to-server'."
 365   (let ((server (get-text-property (point-at-bol) 'gnus-named-server)))
 366     (and server (symbol-name server))))
 367
 368 (defalias 'gnus-server-position-point 'gnus-goto-colon)
 369
 370 (defconst gnus-server-edit-buffer "*Gnus edit server*")
 371
 372 (defun gnus-server-update-server (server)
 373   (with-current-buffer gnus-server-buffer
 374     (let* ((buffer-read-only nil)
 375            (entry (assoc server gnus-server-alist))
 376            (oentry (assoc (gnus-server-to-method server)
 377                           gnus-opened-servers)))
 378       (when entry
 379         (gnus-dribble-enter
 380          (concat "(gnus-server-set-info \"" server "\" '"
 381                  (gnus-prin1-to-string (cdr entry)) ")\n")
 382          (concat "^(gnus-server-set-info \"" (regexp-quote server) "\"")))
 383       (when (or entry oentry)
 384         ;; Buffer may be narrowed.
 385         (save-restriction
 386           (widen)
 387           (when (gnus-server-goto-server server)
 388             (gnus-delete-line))
 389           (if entry
 390               (gnus-server-insert-server-line (car entry) (cdr entry))
 391             (gnus-server-insert-server-line
 392              (format "%s:%s" (caar oentry) (nth 1 (car oentry)))
 393              (car oentry)))
 394           (gnus-server-position-point))))))
 395
 396 (defun gnus-server-set-info (server info)
 397   ;; Enter a select method into the virtual server alist.
 398   (when (and server info)
 399     (gnus-dribble-enter
 400      (concat "(gnus-server-set-info \"" server "\" '"
 401              (gnus-prin1-to-string info) ")")
 402      (concat "^(gnus-server-set-info \"" (regexp-quote server) "\""))
 403     (let* ((server (nth 1 info))
 404            (entry (assoc server gnus-server-alist))
 405            (cached (assoc server gnus-server-method-cache)))
 406       (if cached
 407           (setq gnus-server-method-cache
 408                 (delq cached gnus-server-method-cache)))
 409       (if entry
 410           (progn
 411             ;; Remove the server from `gnus-opened-servers' since
 412             ;; it has never been opened with the new `info' yet.
 413             (gnus-opened-servers-remove (cdr entry))
 414             ;; Don't make a new Lisp object.
 415             (setcar (cdr entry) (car info))
 416             (setcdr (cdr entry) (cdr info)))
 417         (setq gnus-server-alist
 418               (nconc gnus-server-alist (list (cons server info))))))))
 419
 420 ;;; Interactive server functions.
 421
 422 (defun gnus-server-kill-server (server)
 423   "Kill the server on the current line."
 424   (interactive (list (gnus-server-server-name)))
 425   (unless (gnus-server-goto-server server)
 426     (if server (error "No such server: %s" server)
 427       (error "No server on the current line")))
 428   (unless (assoc server gnus-server-alist)
 429     (error "Read-only server %s" server))
 430   (gnus-dribble-touch)
 431   (let ((buffer-read-only nil))
 432     (gnus-delete-line))
 433   (push (assoc server gnus-server-alist) gnus-server-killed-servers)
 434   (setq gnus-server-alist (delq (car gnus-server-killed-servers)
 435                                 gnus-server-alist))
 436   (let ((groups (gnus-groups-from-server server)))
 437     (when (and groups
 438                (gnus-yes-or-no-p
 439                 (format "Kill all %s groups from this server? "
 440                         (length groups))))
 441       (dolist (group groups)
 442         (setq gnus-newsrc-alist
 443               (delq (assoc group gnus-newsrc-alist)
 444                     gnus-newsrc-alist))
 445         (when gnus-group-change-level-function
 446           (funcall gnus-group-change-level-function
 447                    group gnus-level-killed 3)))))
 448   (gnus-server-position-point))
 449
 450 (defun gnus-server-yank-server ()
 451   "Yank the previously killed server."
 452   (interactive)
 453   (unless gnus-server-killed-servers
 454     (error "No killed servers to be yanked"))
 455   (let ((alist gnus-server-alist)
 456         (server (gnus-server-server-name))
 457         (killed (car gnus-server-killed-servers)))
 458     (if (not server)
 459         (setq gnus-server-alist (nconc gnus-server-alist (list killed)))
 460       (if (string= server (caar gnus-server-alist))
 461           (push killed gnus-server-alist)
 462         (while (and (cdr alist)
 463                     (not (string= server (caadr alist))))
 464           (setq alist (cdr alist)))
 465         (if alist
 466             (setcdr alist (cons killed (cdr alist)))
 467           (setq gnus-server-alist (list killed)))))
 468     (gnus-server-update-server (car killed))
 469     (setq gnus-server-killed-servers (cdr gnus-server-killed-servers))
 470     (gnus-server-position-point)))
 471
 472 (defun gnus-server-exit ()
 473   "Return to the group buffer."
 474   (interactive)
 475   (gnus-run-hooks 'gnus-server-exit-hook)
 476   (gnus-kill-buffer (current-buffer))
 477   (gnus-configure-windows 'group t))
 478
 479 (defun gnus-server-list-servers ()
 480   "List all available servers."
 481   (interactive)
 482   (let ((cur (gnus-server-server-name)))
 483     (gnus-server-prepare)
 484     (if cur (gnus-server-goto-server cur)
 485       (goto-char (point-max))
 486       (forward-line -1))
 487     (gnus-server-position-point)))
 488
 489 (defun gnus-server-set-status (method status)
 490   "Make METHOD have STATUS."
 491   (let ((entry (assoc method gnus-opened-servers)))
 492     (if entry
 493         (setcar (cdr entry) status)
 494       (push (list method status) gnus-opened-servers))))
 495
 496 (defun gnus-opened-servers-remove (method)
 497   "Remove METHOD from the list of opened servers."
 498   (setq gnus-opened-servers (delq (assoc method gnus-opened-servers)
 499                                   gnus-opened-servers)))
 500
 501 (defun gnus-server-open-server (server)
 502   "Force an open of SERVER."
 503   (interactive (list (gnus-server-server-name)))
 504   (let ((method (gnus-server-to-method server)))
 505     (unless method
 506       (error "No such server: %s" server))
 507     (gnus-server-set-status method 'ok)
 508     (prog1
 509         (gnus-open-server method)
 510       (gnus-server-update-server server)
 511       (gnus-server-position-point))))
 512
 513 (defun gnus-server-open-all-servers ()
 514   "Open all servers."
 515   (interactive)
 516   (dolist (server gnus-inserted-opened-servers)
 517     (gnus-server-open-server (car server))))
 518
 519 (defun gnus-server-close-server (server)
 520   "Close SERVER."
 521   (interactive (list (gnus-server-server-name)))
 522   (let ((method (gnus-server-to-method server)))
 523     (unless method
 524       (error "No such server: %s" server))
 525     (gnus-server-set-status method 'closed)
 526     (prog1
 527         (gnus-close-server method)
 528       (gnus-server-update-server server)
 529       (gnus-server-position-point))))
 530
 531 (defun gnus-server-offline-server (server)
 532   "Set SERVER to offline."
 533   (interactive (list (gnus-server-server-name)))
 534   (let ((method (gnus-server-to-method server)))
 535     (unless method
 536       (error "No such server: %s" server))
 537     (prog1
 538         (gnus-close-server method)
 539       (gnus-server-set-status method 'offline)
 540       (gnus-server-update-server server)
 541       (gnus-server-position-point))))
 542
 543 (defun gnus-server-close-all-servers ()
 544   "Close all servers."
 545   (interactive)
 546   (dolist (server gnus-inserted-opened-servers)
 547     (gnus-server-close-server (car server)))
 548   (dolist (server gnus-server-alist)
 549     (gnus-server-close-server (car server))))
 550
 551 (defun gnus-server-deny-server (server)
 552   "Make sure SERVER will never be attempted opened."
 553   (interactive (list (gnus-server-server-name)))
 554   (let ((method (gnus-server-to-method server)))
 555     (unless method
 556       (error "No such server: %s" server))
 557     (gnus-server-set-status method 'denied))
 558   (gnus-server-update-server server)
 559   (gnus-server-position-point)
 560   t)
 561
 562 (defun gnus-server-remove-denials ()
 563   "Make all denied servers into closed servers."
 564   (interactive)
 565   (dolist (server gnus-opened-servers)
 566     (when (eq (nth 1 server) 'denied)
 567       (setcar (nthcdr 1 server) 'closed)))
 568   (gnus-server-list-servers))
 569
 570 (defun gnus-server-copy-server (from to)
 571   "Copy a server definition to a new name."
 572   (interactive
 573    (list
 574     (or (gnus-server-server-name)
 575         (error "No server on the current line"))
 576     (read-string "Copy to: ")))
 577   (unless from
 578     (error "No server on current line"))
 579   (unless (and to (not (string= to "")))
 580     (error "No name to copy to"))
 581   (when (assoc to gnus-server-alist)
 582     (error "%s already exists" to))
 583   (unless (gnus-server-to-method from)
 584     (error "%s: no such server" from))
 585   (let ((to-entry (cons from (gnus-copy-sequence
 586                               (gnus-server-to-method from)))))
 587     (setcar to-entry to)
 588     (setcar (nthcdr 2 to-entry) to)
 589     (push to-entry gnus-server-killed-servers)
 590     (gnus-server-yank-server)))
 591
 592 (defun gnus-server-add-server (how where)
 593   (interactive
 594    (list (intern (gnus-completing-read "Server method"
 595                                        (mapcar 'car gnus-valid-select-methods)
 596                                        t))
 597          (read-string "Server name: ")))
 598   (when (assq where gnus-server-alist)
 599     (error "Server with that name already defined"))
 600   (push (list where how where) gnus-server-killed-servers)
 601   (gnus-server-yank-server))
 602
 603 (defun gnus-server-goto-server (server)
 604   "Jump to a server line."
 605   (interactive
 606    (list (gnus-completing-read "Goto server" (mapcar 'car gnus-server-alist) t)))
 607   (let ((to (text-property-any (point-min) (point-max)
 608                                'gnus-server (intern server))))
 609     (when to
 610       (goto-char to)
 611       (gnus-server-position-point))))
 612
 613 (defun gnus-server-edit-server (server)
 614   "Edit the server on the current line."
 615   (interactive (list (gnus-server-server-name)))
 616   (unless server
 617     (error "No server on current line"))
 618   (unless (assoc server gnus-server-alist)
 619     (error "This server can't be edited"))
 620   (let ((info (cdr (assoc server gnus-server-alist))))
 621     (gnus-close-server info)
 622     (gnus-edit-form
 623      info "Editing the server."
 624      `(lambda (form)
 625         (gnus-server-set-info ,server form)
 626         (gnus-server-list-servers)
 627         (gnus-server-position-point))
 628      'edit-server)))
 629
 630 (defun gnus-server-show-server (server)
 631   "Show the definition of the server on the current line."
 632   (interactive (list (gnus-server-server-name)))
 633   (unless server
 634     (error "No server on current line"))
 635   (let ((info (gnus-server-to-method server)))
 636     (gnus-edit-form
 637      info "Showing the server."
 638      `(lambda (form)
 639         (gnus-server-position-point))
 640      'edit-server)))
 641
 642 (defun gnus-server-scan-server (server)
 643   "Request a scan from the current server."
 644   (interactive (list (gnus-server-server-name)))
 645   (let ((method (gnus-server-to-method server)))
 646     (if (not (gnus-get-function method 'request-scan))
 647         (error "Server %s can't scan" (car method))
 648       (gnus-message 3 "Scanning %s..." server)
 649       (gnus-request-scan nil method)
 650       (gnus-message 3 "Scanning %s...done" server))))
 651
 652 (defun gnus-server-read-server-in-server-buffer (server)
 653   "Browse a server in server buffer."
 654   (interactive (list (gnus-server-server-name)))
 655   (let (gnus-server-browse-in-group-buffer)
 656     (gnus-server-read-server server)))
 657
 658 (defun gnus-server-read-server (server)
 659   "Browse a server."
 660   (interactive (list (gnus-server-server-name)))
 661   (let ((buf (current-buffer)))
 662     (prog1
 663         (gnus-browse-foreign-server server buf)
 664       (with-current-buffer buf
 665         (gnus-server-update-server (gnus-server-server-name))
 666         (gnus-server-position-point)))))
 667
 668 (defun gnus-server-pick-server (e)
 669   (interactive "e")
 670   (mouse-set-point e)
 671   (gnus-server-read-server (gnus-server-server-name)))
 672
 673 \f
 674 ;;;
 675 ;;; Browse Server Mode
 676 ;;;
 677
 678 (defvar gnus-browse-menu-hook nil
 679   "*Hook run after the creation of the browse mode menu.")
 680
 681 (defcustom gnus-browse-subscribe-newsgroup-method
 682   'gnus-subscribe-alphabetically
 683   "Function(s) called when subscribing groups in the Browse Server Buffer
 684 A few pre-made functions are supplied: `gnus-subscribe-randomly'
 685 inserts new groups at the beginning of the list of groups;
 686 `gnus-subscribe-alphabetically' inserts new groups in strict
 687 alphabetic order; `gnus-subscribe-hierarchically' inserts new groups
 688 in hierarchical newsgroup order; `gnus-subscribe-interactively' asks
 689 for your decision; `gnus-subscribe-killed' kills all new groups;
 690 `gnus-subscribe-zombies' will make all new groups into zombies;
 691 `gnus-subscribe-topics' will enter groups into the topics that
 692 claim them."
 693   :version "24.1"
 694   :group 'gnus-server
 695   :type '(radio (function-item gnus-subscribe-randomly)
 696                 (function-item gnus-subscribe-alphabetically)
 697                 (function-item gnus-subscribe-hierarchically)
 698                 (function-item gnus-subscribe-interactively)
 699                 (function-item gnus-subscribe-killed)
 700                 (function-item gnus-subscribe-zombies)
 701                 (function-item gnus-subscribe-topics)
 702                 function
 703                 (repeat function)))
 704
 705 (defvar gnus-browse-mode-hook nil)
 706 (defvar gnus-browse-mode-map nil)
 707 (put 'gnus-browse-mode 'mode-class 'special)
 708
 709 (unless gnus-browse-mode-map
 710   (setq gnus-browse-mode-map (make-keymap))
 711   (suppress-keymap gnus-browse-mode-map)
 712
 713   (gnus-define-keys
 714       gnus-browse-mode-map
 715     " " gnus-browse-read-group
 716     "=" gnus-browse-select-group
 717     "n" gnus-browse-next-group
 718     "p" gnus-browse-prev-group
 719     "\177" gnus-browse-prev-group
 720     [delete] gnus-browse-prev-group
 721     "N" gnus-browse-next-group
 722     "P" gnus-browse-prev-group
 723     "\M-n" gnus-browse-next-group
 724     "\M-p" gnus-browse-prev-group
 725     "\r" gnus-browse-select-group
 726     "u" gnus-browse-unsubscribe-current-group
 727     "l" gnus-browse-exit
 728     "L" gnus-browse-exit
 729     "q" gnus-browse-exit
 730     "Q" gnus-browse-exit
 731     "d" gnus-browse-describe-group
 732     [delete] gnus-browse-delete-group
 733     "\C-c\C-c" gnus-browse-exit
 734     "?" gnus-browse-describe-briefly
 735
 736     "\C-c\C-i" gnus-info-find-node
 737     "\C-c\C-b" gnus-bug))
 738
 739 (defun gnus-browse-make-menu-bar ()
 740   (gnus-turn-off-edit-menu 'browse)
 741   (unless (boundp 'gnus-browse-menu)
 742     (easy-menu-define
 743      gnus-browse-menu gnus-browse-mode-map ""
 744      '("Browse"
 745        ["Subscribe" gnus-browse-unsubscribe-current-group t]
 746        ["Read" gnus-browse-read-group t]
 747        ["Select" gnus-browse-select-group t]
 748        ["Describe" gnus-browse-describe-group t]
 749        ["Next" gnus-browse-next-group t]
 750        ["Prev" gnus-browse-prev-group t]
 751        ["Exit" gnus-browse-exit t]))
 752     (gnus-run-hooks 'gnus-browse-menu-hook)))
 753
 754 (defvar gnus-browse-current-method nil)
 755 (defvar gnus-browse-return-buffer nil)
 756
 757 (defvar gnus-browse-buffer "*Gnus Browse Server*")
 758
 759 (defun gnus-browse-foreign-server (server &optional return-buffer)
 760   "Browse the server SERVER."
 761   (setq gnus-browse-current-method (gnus-server-to-method server))
 762   (setq gnus-browse-return-buffer return-buffer)
 763   (let* ((method gnus-browse-current-method)
 764          (orig-select-method gnus-select-method)
 765          (gnus-select-method method)
 766          groups group)
 767     (gnus-message 5 "Connecting to %s..." (nth 1 method))
 768     (cond
 769      ((not (gnus-check-server method))
 770       (gnus-message
 771        1 "Unable to contact server %s: %s" (nth 1 method)
 772        (gnus-status-message method))
 773       nil)
 774      ((not
 775        (prog2
 776            (gnus-message 6 "Reading active file...")
 777            (gnus-request-list method)
 778          (gnus-message 6 "Reading active file...done")))
 779       (gnus-message
 780        1 "Couldn't request list: %s" (gnus-status-message method))
 781       nil)
 782      (t
 783       (with-current-buffer nntp-server-buffer
 784         (let ((cur (current-buffer)))
 785           (goto-char (point-min))
 786          (unless (or (null gnus-ignored-newsgroups)
 787                      (string= gnus-ignored-newsgroups ""))
 788             (delete-matching-lines gnus-ignored-newsgroups))
 789           ;; We treat NNTP as a special case to avoid problems with
 790           ;; garbage group names like `"foo' that appear in some badly
 791           ;; managed active files. -jh.
 792           (if (eq (car method) 'nntp)
 793               (while (not (eobp))
 794                 (ignore-errors
 795                   (push (cons
 796                          (mm-string-as-unibyte
 797                           (buffer-substring
 798                            (point)
 799                            (progn
 800                              (skip-chars-forward "^ \t")
 801                              (point))))
 802                          (let ((last (read cur)))
 803                            (cons (read cur) last)))
 804                         groups))
 805                 (forward-line))
 806             (while (not (eobp))
 807               (ignore-errors
 808                 (push (cons
 809                        (mm-string-as-unibyte
 810                         (if (eq (char-after) ?\")
 811                             (read cur)
 812                           (let ((p (point)) (name ""))
 813                             (skip-chars-forward "^ \t\\\\")
 814                             (setq name (buffer-substring p (point)))
 815                             (while (eq (char-after) ?\\)
 816                               (setq p (1+ (point)))
 817                               (forward-char 2)
 818                               (skip-chars-forward "^ \t\\\\")
 819                               (setq name (concat name (buffer-substring
 820                                                        p (point)))))
 821                             name)))
 822                        (let ((last (read cur)))
 823                          (cons (read cur) last)))
 824                       groups))
 825               (forward-line)))))
 826       (setq groups (sort groups
 827                          (lambda (l1 l2)
 828                            (string< (car l1) (car l2)))))
 829       (if gnus-server-browse-in-group-buffer
 830           (let* ((gnus-select-method orig-select-method)
 831                  (gnus-group-listed-groups
 832                   (mapcar (lambda (group)
 833                             (let ((name
 834                                    (gnus-group-prefixed-name
 835                                     (car group) method)))
 836                               (gnus-set-active name (cdr group))
 837                               name))
 838                           groups)))
 839             (gnus-configure-windows 'group)
 840             (funcall gnus-group-prepare-function
 841                      gnus-level-killed 'ignore 1 'ignore))
 842         (gnus-get-buffer-create gnus-browse-buffer)
 843         (gnus-configure-windows 'browse)
 844         (buffer-disable-undo)
 845         (let ((buffer-read-only nil))
 846           (erase-buffer))
 847         (gnus-browse-mode)
 848         (setq mode-line-buffer-identification
 849               (list
 850                (format
 851                 "Gnus: %%b {%s:%s}" (car method) (cadr method))))
 852         (let ((buffer-read-only nil)
 853               name
 854               (prefix (let ((gnus-select-method orig-select-method))
 855                         (gnus-group-prefixed-name "" method))))
 856           (while (setq group (pop groups))
 857             (gnus-add-text-properties
 858              (point)
 859              (prog1 (1+ (point))
 860                (insert
 861                 (format "%c%7d: %s\n"
 862                         (let ((level
 863                                (if (string= prefix "")
 864                                    (gnus-group-level (setq name (car group)))
 865                                  (gnus-group-level
 866                                   (concat prefix (setq name (car group)))))))
 867                           (cond
 868                            ((<= level gnus-level-subscribed) ? )
 869                            ((<= level gnus-level-unsubscribed) ?U)
 870                            ((= level gnus-level-zombie) ?Z)
 871                            (t ?K)))
 872                         (max 0 (- (1+ (cddr group)) (cadr group)))
 873                         ;; Don't decode if name is ASCII
 874                         (if (and (fboundp 'detect-coding-string)
 875                                  (eq (detect-coding-string name t) 'undecided))
 876                             name
 877                           (mm-decode-coding-string
 878                            name
 879                            (inline (gnus-group-name-charset method name)))))))
 880              (list 'gnus-group name)
 881              )))
 882         (switch-to-buffer (current-buffer)))
 883       (goto-char (point-min))
 884       (gnus-group-position-point)
 885       (gnus-message 5 "Connecting to %s...done" (nth 1 method))
 886       t))))
 887
 888 (define-derived-mode gnus-browse-mode fundamental-mode "Browse Server"
 889   "Major mode for browsing a foreign server.
 890
 891 All normal editing commands are switched off.
 892
 893 \\<gnus-browse-mode-map>
 894 The only things you can do in this buffer is
 895
 896 1) `\\[gnus-browse-unsubscribe-current-group]' to subscribe to a group.
 897 The group will be inserted into the group buffer upon exit from this
 898 buffer.
 899
 900 2) `\\[gnus-browse-read-group]' to read a group ephemerally.
 901
 902 3) `\\[gnus-browse-exit]' to return to the group buffer."
 903   (when (gnus-visual-p 'browse-menu 'menu)
 904     (gnus-browse-make-menu-bar))
 905   (gnus-simplify-mode-line)
 906   (setq mode-line-process nil)
 907   (buffer-disable-undo)
 908   (setq truncate-lines t)
 909   (gnus-set-default-directory)
 910   (setq buffer-read-only t))
 911
 912 (defun gnus-browse-read-group (&optional no-article number)
 913   "Enter the group at the current line.
 914 If NUMBER, fetch this number of articles."
 915   (interactive "P")
 916   (let ((group (gnus-browse-group-name)))
 917     (if (or (not (gnus-get-info group))
 918             (gnus-ephemeral-group-p group))
 919         (unless (gnus-group-read-ephemeral-group
 920                  group gnus-browse-current-method nil
 921                  (cons (current-buffer) 'browse)
 922                  nil nil nil number)
 923           (error "Couldn't enter %s" group))
 924       (unless (gnus-group-read-group nil no-article group)
 925         (error "Couldn't enter %s" group)))))
 926
 927 (defun gnus-browse-select-group (&optional number)
 928   "Select the current group.
 929 If NUMBER, fetch this number of articles."
 930   (interactive "P")
 931   (gnus-browse-read-group 'no number))
 932
 933 (defun gnus-browse-next-group (n)
 934   "Go to the next group."
 935   (interactive "p")
 936   (prog1
 937       (forward-line n)
 938     (gnus-group-position-point)))
 939
 940 (defun gnus-browse-prev-group (n)
 941   "Go to the next group."
 942   (interactive "p")
 943   (gnus-browse-next-group (- n)))
 944
 945 (defun gnus-browse-unsubscribe-current-group (arg)
 946   "(Un)subscribe to the next ARG groups.
 947 The variable `gnus-browse-subscribe-newsgroup-method' determines
 948 how new groups will be entered into the group buffer."
 949   (interactive "p")
 950   (when (eobp)
 951     (error "No group at current line"))
 952   (let ((ward (if (< arg 0) -1 1))
 953         (arg (abs arg)))
 954     (while (and (> arg 0)
 955                 (not (eobp))
 956                 (gnus-browse-unsubscribe-group)
 957                 (zerop (gnus-browse-next-group ward)))
 958       (decf arg))
 959     (gnus-group-position-point)
 960     (when (/= 0 arg)
 961       (gnus-message 7 "No more newsgroups"))
 962     arg))
 963
 964 (defun gnus-browse-group-name ()
 965   (save-excursion
 966     (beginning-of-line)
 967     (let ((name (get-text-property (point) 'gnus-group)))
 968       (when (re-search-forward ": \\(.*\\)$" (point-at-eol) t)
 969         (concat (gnus-method-to-server-name gnus-browse-current-method) ":"
 970                 (or name
 971                     (match-string-no-properties 1)))))))
 972
 973 (defun gnus-browse-describe-group (group)
 974   "Describe the current group."
 975   (interactive (list (gnus-browse-group-name)))
 976   (gnus-group-describe-group nil group))
 977
 978 (defun gnus-browse-delete-group (group force)
 979   "Delete the current group.  Only meaningful with editable groups.
 980 If FORCE (the prefix) is non-nil, all the articles in the group will
 981 be deleted.  This is \"deleted\" as in \"removed forever from the face
 982 of the Earth\".  There is no undo.  The user will be prompted before
 983 doing the deletion."
 984   (interactive (list (gnus-browse-group-name)
 985                      current-prefix-arg))
 986   (gnus-group-delete-group group force))
 987
 988 (defun gnus-browse-unsubscribe-group ()
 989   "Toggle subscription of the current group in the browse buffer."
 990   (let ((sub nil)
 991         (buffer-read-only nil)
 992         group)
 993     (save-excursion
 994       (beginning-of-line)
 995       ;; If this group it killed, then we want to subscribe it.
 996       (unless (eq (char-after) ? )
 997         (setq sub t))
 998       (setq group (gnus-browse-group-name))
 999       (when (gnus-server-equal gnus-browse-current-method "native")
1000         (setq group (gnus-group-real-name group)))
1001       (if sub
1002           (progn
1003             ;; Make sure the group has been properly removed before we
1004             ;; subscribe to it.
1005             (if (gnus-ephemeral-group-p group)
1006                 (gnus-kill-ephemeral-group group))
1007             (let ((entry (gnus-group-entry group)))
1008               (if entry
1009                   ;; Just change the subscription level if it is an
1010                   ;; unsubscribed group.
1011                   (gnus-group-change-level entry
1012                                            gnus-level-default-subscribed)
1013                 ;; If it is a killed group or a zombie, feed it to the
1014                 ;; mechanism for new group subscription.
1015                 (gnus-call-subscribe-functions
1016                  gnus-browse-subscribe-newsgroup-method
1017                  group)
1018                 (gnus-request-update-group-status group 'subscribe)))
1019             (delete-char 1)
1020             (insert (let ((lvl (gnus-group-level group)))
1021                       (cond
1022                        ((< lvl gnus-level-unsubscribed) ? )
1023                        ((< lvl gnus-level-zombie) ?U)
1024                        ((< lvl gnus-level-killed) ?Z)
1025                        (t ?K)))))
1026         (gnus-group-change-level
1027          group gnus-level-unsubscribed gnus-level-default-subscribed)
1028         (delete-char 1)
1029         (insert ?U)))
1030     t))
1031
1032 (defun gnus-browse-exit ()
1033   "Quit browsing and return to the group buffer."
1034   (interactive)
1035   (when (derived-mode-p 'gnus-browse-mode)
1036     (gnus-kill-buffer (current-buffer)))
1037   ;; Insert the newly subscribed groups in the group buffer.
1038   (with-current-buffer gnus-group-buffer
1039     (gnus-group-list-groups nil))
1040   (if gnus-browse-return-buffer
1041       (gnus-configure-windows 'server 'force)
1042     (gnus-configure-windows 'group 'force)))
1043
1044 (defun gnus-browse-describe-briefly ()
1045   "Give a one line description of the group mode commands."
1046   (interactive)
1047   (gnus-message 6 "%s"
1048                 (substitute-command-keys "\\<gnus-browse-mode-map>\\[gnus-group-next-group]:Forward  \\[gnus-group-prev-group]:Backward  \\[gnus-browse-exit]:Exit  \\[gnus-info-find-node]:Run Info  \\[gnus-browse-describe-briefly]:This help")))
1049
1050 (defun gnus-server-regenerate-server ()
1051   "Issue a command to the server to regenerate all its data structures."
1052   (interactive)
1053   (let ((server (gnus-server-server-name)))
1054     (unless server
1055       (error "No server on the current line"))
1056     (condition-case ()
1057         (gnus-get-function (gnus-server-to-method server)
1058                            'request-regenerate)
1059       (error
1060         (error "This back end doesn't support regeneration")))
1061     (gnus-message 5 "Requesting regeneration of %s..." server)
1062     (unless (gnus-open-server server)
1063       (error "Couldn't open server"))
1064     (if (gnus-request-regenerate server)
1065         (gnus-message 5 "Requesting regeneration of %s...done" server)
1066       (gnus-message 5 "Couldn't regenerate %s" server))))
1067
1068
1069 ;;;
1070 ;;; Server compaction. -- dvl
1071 ;;;
1072
1073 ;; #### FIXME: this function currently fails to update the Group buffer's
1074 ;; #### appearance.
1075 (defun gnus-server-compact-server ()
1076   "Issue a command to the server to compact all its groups.
1077
1078 Note: currently only implemented in nnml."
1079   (interactive)
1080   (let ((server (gnus-server-server-name)))
1081     (unless server
1082       (error "No server on the current line"))
1083     (condition-case ()
1084         (gnus-get-function (gnus-server-to-method server)
1085                            'request-compact)
1086       (error
1087        (error "This back end doesn't support compaction")))
1088     (gnus-message 5 "\
1089 Requesting compaction of %s... (this may take a long time)"
1090                   server)
1091     (unless (gnus-open-server server)
1092       (error "Couldn't open server"))
1093     (if (not (gnus-request-compact server))
1094         (gnus-message 5 "Couldn't compact %s" server)
1095       (gnus-message 5 "Requesting compaction of %s...done" server)
1096       ;; Invalidate the original article buffer which might be out of date.
1097       ;; #### NOTE: Yes, this might be a bit rude, but since compaction
1098       ;; #### will not happen very often, I think this is acceptable.
1099       (let ((original (get-buffer gnus-original-article-buffer)))
1100         (and original (gnus-kill-buffer original))))))
1101
1102 (defun gnus-server-toggle-cloud-server ()
1103   "Make the server under point be replicated in the Emacs Cloud."
1104   (interactive)
1105   (let ((server (gnus-server-server-name)))
1106     (unless server
1107       (error "No server on the current line"))
1108
1109     (if (gnus-cloud-server-p server)
1110         (setq gnus-cloud-covered-servers
1111               (delete server gnus-cloud-covered-servers))
1112       (push server gnus-cloud-covered-servers))
1113
1114     (gnus-server-update-server server)
1115     (gnus-message 1 (if (gnus-cloud-server-p server)
1116                         "Replication of %s in the cloud will start"
1117                       "Replication of %s in the cloud will stop")
1118                   server)))
1119
1120 (provide 'gnus-srvr)
1121
1122 ;;; gnus-srvr.el ends here