cgit.sxemacs.org Git - gnus/blob - lisp/gnus-srvr.el

   1 ;;; gnus-srvr.el --- virtual server support for Gnus
   2 ;; Copyright (C) 1995,96,97,98 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@ifi.uio.no>
   5 ;; Keywords: news
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  22 ;; Boston, MA 02111-1307, USA.
  23
  24 ;;; Commentary:
  25
  26 ;;; Code:
  27
  28 (eval-when-compile (require 'cl))
  29
  30 (require 'gnus)
  31 (require 'gnus-spec)
  32 (require 'gnus-group)
  33 (require 'gnus-int)
  34 (require 'gnus-range)
  35
  36 (defvar gnus-server-mode-hook nil
  37   "Hook run in `gnus-server-mode' buffers.")
  38
  39 (defconst gnus-server-line-format "     {%(%h:%w%)} %s\n"
  40   "Format of server lines.
  41 It works along the same lines as a normal formatting string,
  42 with some simple extensions.
  43
  44 The following specs are understood:
  45
  46 %h backend
  47 %n name
  48 %w address
  49 %s status")
  50
  51 (defvar gnus-server-mode-line-format "Gnus: %%b"
  52   "The format specification for the server mode line.")
  53
  54 (defvar gnus-server-exit-hook nil
  55   "*Hook run when exiting the server buffer.")
  56
  57 ;;; Internal variables.
  58
  59 (defvar gnus-inserted-opened-servers nil)
  60
  61 (defvar gnus-server-line-format-alist
  62   `((?h how ?s)
  63     (?n name ?s)
  64     (?w where ?s)
  65     (?s status ?s)))
  66
  67 (defvar gnus-server-mode-line-format-alist
  68   `((?S news-server ?s)
  69     (?M news-method ?s)
  70     (?u user-defined ?s)))
  71
  72 (defvar gnus-server-line-format-spec nil)
  73 (defvar gnus-server-mode-line-format-spec nil)
  74 (defvar gnus-server-killed-servers nil)
  75
  76 (defvar gnus-server-mode-map)
  77
  78 (defvar gnus-server-menu-hook nil
  79   "*Hook run after the creation of the server mode menu.")
  80
  81 (defun gnus-server-make-menu-bar ()
  82   (gnus-turn-off-edit-menu 'server)
  83   (unless (boundp 'gnus-server-server-menu)
  84     (easy-menu-define
  85      gnus-server-server-menu gnus-server-mode-map ""
  86      '("Server"
  87        ["Add" gnus-server-add-server t]
  88        ["Browse" gnus-server-read-server t]
  89        ["Scan" gnus-server-scan-server t]
  90        ["List" gnus-server-list-servers t]
  91        ["Kill" gnus-server-kill-server t]
  92        ["Yank" gnus-server-yank-server t]
  93        ["Copy" gnus-server-copy-server t]
  94        ["Edit" gnus-server-edit-server t]
  95        ["Regenerate" gnus-server-regenerate-server t]
  96        ["Exit" gnus-server-exit t]))
  97
  98     (easy-menu-define
  99      gnus-server-connections-menu gnus-server-mode-map ""
 100      '("Connections"
 101        ["Open" gnus-server-open-server t]
 102        ["Close" gnus-server-close-server t]
 103        ["Deny" gnus-server-deny-server t]
 104        "---"
 105        ["Open All" gnus-server-open-all-servers t]
 106        ["Close All" gnus-server-close-all-servers t]
 107        ["Reset All" gnus-server-remove-denials t]))
 108
 109     (gnus-run-hooks 'gnus-server-menu-hook)))
 110
 111 (defvar gnus-server-mode-map nil)
 112 (put 'gnus-server-mode 'mode-class 'special)
 113
 114 (unless gnus-server-mode-map
 115   (setq gnus-server-mode-map (make-sparse-keymap))
 116   (suppress-keymap gnus-server-mode-map)
 117
 118   (gnus-define-keys gnus-server-mode-map
 119     " " gnus-server-read-server
 120     "\r" gnus-server-read-server
 121     gnus-mouse-2 gnus-server-pick-server
 122     "q" gnus-server-exit
 123     "l" gnus-server-list-servers
 124     "k" gnus-server-kill-server
 125     "y" gnus-server-yank-server
 126     "c" gnus-server-copy-server
 127     "a" gnus-server-add-server
 128     "e" gnus-server-edit-server
 129     "s" gnus-server-scan-server
 130
 131     "O" gnus-server-open-server
 132     "\M-o" gnus-server-open-all-servers
 133     "C" gnus-server-close-server
 134     "\M-c" gnus-server-close-all-servers
 135     "D" gnus-server-deny-server
 136     "R" gnus-server-remove-denials
 137
 138     "g" gnus-server-regenerate-server
 139
 140     "\C-c\C-i" gnus-info-find-node
 141     "\C-c\C-b" gnus-bug))
 142
 143 (defun gnus-server-mode ()
 144   "Major mode for listing and editing servers.
 145
 146 All normal editing commands are switched off.
 147 \\<gnus-server-mode-map>
 148 For more in-depth information on this mode, read the manual
 149 (`\\[gnus-info-find-node]').
 150
 151 The following commands are available:
 152
 153 \\{gnus-server-mode-map}"
 154   (interactive)
 155   (when (gnus-visual-p 'server-menu 'menu)
 156     (gnus-server-make-menu-bar))
 157   (kill-all-local-variables)
 158   (gnus-simplify-mode-line)
 159   (setq major-mode 'gnus-server-mode)
 160   (setq mode-name "Server")
 161   (gnus-set-default-directory)
 162   (setq mode-line-process nil)
 163   (use-local-map gnus-server-mode-map)
 164   (buffer-disable-undo (current-buffer))
 165   (setq truncate-lines t)
 166   (setq buffer-read-only t)
 167   (gnus-run-hooks 'gnus-server-mode-hook))
 168
 169 (defun gnus-server-insert-server-line (name method)
 170   (let* ((how (car method))
 171          (where (nth 1 method))
 172          (elem (assoc method gnus-opened-servers))
 173          (status (cond ((eq (nth 1 elem) 'denied)
 174                         "(denied)")
 175                        ((or (gnus-server-opened method)
 176                             (eq (nth 1 elem) 'ok))
 177                         "(opened)")
 178                        (t
 179                         "(closed)"))))
 180     (beginning-of-line)
 181     (gnus-add-text-properties
 182      (point)
 183      (prog1 (1+ (point))
 184        ;; Insert the text.
 185        (eval gnus-server-line-format-spec))
 186      (list 'gnus-server (intern name)))))
 187
 188 (defun gnus-enter-server-buffer ()
 189   "Set up the server buffer."
 190   (gnus-server-setup-buffer)
 191   (gnus-configure-windows 'server)
 192   (gnus-server-prepare))
 193
 194 (defun gnus-server-setup-buffer ()
 195   "Initialize the server buffer."
 196   (unless (get-buffer gnus-server-buffer)
 197     (save-excursion
 198       (set-buffer (get-buffer-create gnus-server-buffer))
 199       (gnus-server-mode)
 200       (when gnus-carpal
 201         (gnus-carpal-setup-buffer 'server)))))
 202
 203 (defun gnus-server-prepare ()
 204   (gnus-set-format 'server-mode)
 205   (gnus-set-format 'server t)
 206   (let ((alist gnus-server-alist)
 207         (buffer-read-only nil)
 208         (opened gnus-opened-servers)
 209         done server op-ser)
 210     (erase-buffer)
 211     (setq gnus-inserted-opened-servers nil)
 212     ;; First we do the real list of servers.
 213     (while alist
 214       (unless (member (cdar alist) done)
 215         (push (cdar alist) done)
 216         (cdr (setq server (pop alist)))
 217         (when (and server (car server) (cdr server))
 218           (gnus-server-insert-server-line (car server) (cdr server))))
 219       (when (member (cdar alist) done)
 220         (pop alist)))
 221     ;; Then we insert the list of servers that have been opened in
 222     ;; this session.
 223     (while opened
 224       (unless (member (caar opened) done)
 225         (push (caar opened) done)
 226         (gnus-server-insert-server-line
 227          (setq op-ser (format "%s:%s" (caaar opened) (nth 1 (caar opened))))
 228          (caar opened))
 229         (push (list op-ser (caar opened)) gnus-inserted-opened-servers))
 230       (setq opened (cdr opened))))
 231   (goto-char (point-min))
 232   (gnus-server-position-point))
 233
 234 (defun gnus-server-server-name ()
 235   (let ((server (get-text-property (gnus-point-at-bol) 'gnus-server)))
 236     (and server (symbol-name server))))
 237
 238 (defalias 'gnus-server-position-point 'gnus-goto-colon)
 239
 240 (defconst gnus-server-edit-buffer "*Gnus edit server*")
 241
 242 (defun gnus-server-update-server (server)
 243   (save-excursion
 244     (set-buffer gnus-server-buffer)
 245     (let* ((buffer-read-only nil)
 246            (entry (assoc server gnus-server-alist))
 247            (oentry (assoc (gnus-server-to-method server)
 248                           gnus-opened-servers)))
 249       (when entry
 250         (gnus-dribble-enter
 251          (concat "(gnus-server-set-info \"" server "\" '"
 252                  (prin1-to-string (cdr entry)) ")\n")))
 253       (when (or entry oentry)
 254         ;; Buffer may be narrowed.
 255         (save-restriction
 256           (widen)
 257           (when (gnus-server-goto-server server)
 258             (gnus-delete-line))
 259           (if entry
 260               (gnus-server-insert-server-line (car entry) (cdr entry))
 261             (gnus-server-insert-server-line
 262              (format "%s:%s" (caar oentry) (nth 1 (car oentry)))
 263              (car oentry)))
 264           (gnus-server-position-point))))))
 265
 266 (defun gnus-server-set-info (server info)
 267   ;; Enter a select method into the virtual server alist.
 268   (when (and server info)
 269     (gnus-dribble-enter
 270      (concat "(gnus-server-set-info \"" server "\" '"
 271              (prin1-to-string info) ")"))
 272     (let* ((server (nth 1 info))
 273            (entry (assoc server gnus-server-alist)))
 274       (if entry (setcdr entry info)
 275         (setq gnus-server-alist
 276               (nconc gnus-server-alist (list (cons server info))))))))
 277
 278 ;;; Interactive server functions.
 279
 280 (defun gnus-server-kill-server (server)
 281   "Kill the server on the current line."
 282   (interactive (list (gnus-server-server-name)))
 283   (unless (gnus-server-goto-server server)
 284     (if server (error "No such server: %s" server)
 285       (error "No server on the current line")))
 286   (unless (assoc server gnus-server-alist)
 287     (error "Read-only server %s" server))
 288   (gnus-dribble-enter "")
 289   (let ((buffer-read-only nil))
 290     (gnus-delete-line))
 291   (push (assoc server gnus-server-alist) gnus-server-killed-servers)
 292   (setq gnus-server-alist (delq (car gnus-server-killed-servers)
 293                                 gnus-server-alist))
 294   (gnus-server-position-point))
 295
 296 (defun gnus-server-yank-server ()
 297   "Yank the previously killed server."
 298   (interactive)
 299   (unless gnus-server-killed-servers
 300     (error "No killed servers to be yanked"))
 301   (let ((alist gnus-server-alist)
 302         (server (gnus-server-server-name))
 303         (killed (car gnus-server-killed-servers)))
 304     (if (not server)
 305         (setq gnus-server-alist (nconc gnus-server-alist (list killed)))
 306       (if (string= server (caar gnus-server-alist))
 307           (push killed gnus-server-alist)
 308         (while (and (cdr alist)
 309                     (not (string= server (caadr alist))))
 310           (setq alist (cdr alist)))
 311         (if alist
 312             (setcdr alist (cons killed (cdr alist)))
 313           (setq gnus-server-alist (list killed)))))
 314     (gnus-server-update-server (car killed))
 315     (setq gnus-server-killed-servers (cdr gnus-server-killed-servers))
 316     (gnus-server-position-point)))
 317
 318 (defun gnus-server-exit ()
 319   "Return to the group buffer."
 320   (interactive)
 321   (gnus-run-hooks 'gnus-server-exit-hook)
 322   (kill-buffer (current-buffer))
 323   (gnus-configure-windows 'group t))
 324
 325 (defun gnus-server-list-servers ()
 326   "List all available servers."
 327   (interactive)
 328   (let ((cur (gnus-server-server-name)))
 329     (gnus-server-prepare)
 330     (if cur (gnus-server-goto-server cur)
 331       (goto-char (point-max))
 332       (forward-line -1))
 333     (gnus-server-position-point)))
 334
 335 (defun gnus-server-set-status (method status)
 336   "Make METHOD have STATUS."
 337   (let ((entry (assoc method gnus-opened-servers)))
 338     (if entry
 339         (setcar (cdr entry) status)
 340       (push (list method status) gnus-opened-servers))))
 341
 342 (defun gnus-opened-servers-remove (method)
 343   "Remove METHOD from the list of opened servers."
 344   (setq gnus-opened-servers (delq (assoc method gnus-opened-servers)
 345                                   gnus-opened-servers)))
 346
 347 (defun gnus-server-open-server (server)
 348   "Force an open of SERVER."
 349   (interactive (list (gnus-server-server-name)))
 350   (let ((method (gnus-server-to-method server)))
 351     (unless method
 352       (error "No such server: %s" server))
 353     (gnus-server-set-status method 'ok)
 354     (prog1
 355         (or (gnus-open-server method)
 356             (progn (message "Couldn't open %s" server) nil))
 357       (gnus-server-update-server server)
 358       (gnus-server-position-point))))
 359
 360 (defun gnus-server-open-all-servers ()
 361   "Open all servers."
 362   (interactive)
 363   (let ((servers gnus-inserted-opened-servers))
 364     (while servers
 365       (gnus-server-open-server (car (pop servers))))))
 366
 367 (defun gnus-server-close-server (server)
 368   "Close SERVER."
 369   (interactive (list (gnus-server-server-name)))
 370   (let ((method (gnus-server-to-method server)))
 371     (unless method
 372       (error "No such server: %s" server))
 373     (gnus-server-set-status method 'closed)
 374     (prog1
 375         (gnus-close-server method)
 376       (gnus-server-update-server server)
 377       (gnus-server-position-point))))
 378
 379 (defun gnus-server-close-all-servers ()
 380   "Close all servers."
 381   (interactive)
 382   (let ((servers gnus-inserted-opened-servers))
 383     (while servers
 384       (gnus-server-close-server (car (pop servers))))))
 385
 386 (defun gnus-server-deny-server (server)
 387   "Make sure SERVER will never be attempted opened."
 388   (interactive (list (gnus-server-server-name)))
 389   (let ((method (gnus-server-to-method server)))
 390     (unless method
 391       (error "No such server: %s" server))
 392     (gnus-server-set-status method 'denied))
 393   (gnus-server-update-server server)
 394   (gnus-server-position-point)
 395   t)
 396
 397 (defun gnus-server-remove-denials ()
 398   "Make all denied servers into closed servers."
 399   (interactive)
 400   (let ((servers gnus-opened-servers))
 401     (while servers
 402       (when (eq (nth 1 (car servers)) 'denied)
 403         (setcar (nthcdr 1 (car servers)) 'closed))
 404       (setq servers (cdr servers))))
 405   (gnus-server-list-servers))
 406
 407 (defun gnus-server-copy-server (from to)
 408   (interactive
 409    (list
 410     (or (gnus-server-server-name)
 411         (error "No server on the current line"))
 412     (read-string "Copy to: ")))
 413   (unless from
 414     (error "No server on current line"))
 415   (unless (and to (not (string= to "")))
 416     (error "No name to copy to"))
 417   (when (assoc to gnus-server-alist)
 418     (error "%s already exists" to))
 419   (unless (gnus-server-to-method from)
 420     (error "%s: no such server" from))
 421   (let ((to-entry (cons from (gnus-copy-sequence
 422                               (gnus-server-to-method from)))))
 423     (setcar to-entry to)
 424     (setcar (nthcdr 2 to-entry) to)
 425     (push to-entry gnus-server-killed-servers)
 426     (gnus-server-yank-server)))
 427
 428 (defun gnus-server-add-server (how where)
 429   (interactive
 430    (list (intern (completing-read "Server method: "
 431                                   gnus-valid-select-methods nil t))
 432          (read-string "Server name: ")))
 433   (when (assq where gnus-server-alist)
 434     (error "Server with that name already defined"))
 435   (push (list where how where) gnus-server-killed-servers)
 436   (gnus-server-yank-server))
 437
 438 (defun gnus-server-goto-server (server)
 439   "Jump to a server line."
 440   (interactive
 441    (list (completing-read "Goto server: " gnus-server-alist nil t)))
 442   (let ((to (text-property-any (point-min) (point-max)
 443                                'gnus-server (intern server))))
 444     (when to
 445       (goto-char to)
 446       (gnus-server-position-point))))
 447
 448 (defun gnus-server-edit-server (server)
 449   "Edit the server on the current line."
 450   (interactive (list (gnus-server-server-name)))
 451   (unless server
 452     (error "No server on current line"))
 453   (unless (assoc server gnus-server-alist)
 454     (error "This server can't be edited"))
 455   (let ((info (cdr (assoc server gnus-server-alist))))
 456     (gnus-close-server info)
 457     (gnus-edit-form
 458      info "Editing the server."
 459      `(lambda (form)
 460         (gnus-server-set-info ,server form)
 461         (gnus-server-list-servers)
 462         (gnus-server-position-point)))))
 463
 464 (defun gnus-server-scan-server (server)
 465   "Request a scan from the current server."
 466   (interactive (list (gnus-server-server-name)))
 467   (gnus-message 3 "Scanning %s...done" server)
 468   (gnus-request-scan nil (gnus-server-to-method server))
 469   (gnus-message 3 "Scanning %s...done" server))
 470
 471 (defun gnus-server-read-server (server)
 472   "Browse a server."
 473   (interactive (list (gnus-server-server-name)))
 474   (let ((buf (current-buffer)))
 475     (prog1
 476         (gnus-browse-foreign-server server buf)
 477       (save-excursion
 478         (set-buffer buf)
 479         (gnus-server-update-server (gnus-server-server-name))
 480         (gnus-server-position-point)))))
 481
 482 (defun gnus-server-pick-server (e)
 483   (interactive "e")
 484   (mouse-set-point e)
 485   (gnus-server-read-server (gnus-server-server-name)))
 486
 487 \f
 488 ;;;
 489 ;;; Browse Server Mode
 490 ;;;
 491
 492 (defvar gnus-browse-menu-hook nil
 493   "*Hook run after the creation of the browse mode menu.")
 494
 495 (defvar gnus-browse-mode-hook nil)
 496 (defvar gnus-browse-mode-map nil)
 497 (put 'gnus-browse-mode 'mode-class 'special)
 498
 499 (unless gnus-browse-mode-map
 500   (setq gnus-browse-mode-map (make-keymap))
 501   (suppress-keymap gnus-browse-mode-map)
 502
 503   (gnus-define-keys
 504    gnus-browse-mode-map
 505    " " gnus-browse-read-group
 506    "=" gnus-browse-select-group
 507    "n" gnus-browse-next-group
 508    "p" gnus-browse-prev-group
 509    "\177" gnus-browse-prev-group
 510    [delete] gnus-browse-prev-group
 511    "N" gnus-browse-next-group
 512    "P" gnus-browse-prev-group
 513    "\M-n" gnus-browse-next-group
 514    "\M-p" gnus-browse-prev-group
 515    "\r" gnus-browse-select-group
 516    "u" gnus-browse-unsubscribe-current-group
 517    "l" gnus-browse-exit
 518    "L" gnus-browse-exit
 519    "q" gnus-browse-exit
 520    "Q" gnus-browse-exit
 521    "\C-c\C-c" gnus-browse-exit
 522    "?" gnus-browse-describe-briefly
 523
 524    "\C-c\C-i" gnus-info-find-node
 525    "\C-c\C-b" gnus-bug))
 526
 527 (defun gnus-browse-make-menu-bar ()
 528   (gnus-turn-off-edit-menu 'browse)
 529   (unless (boundp 'gnus-browse-menu)
 530     (easy-menu-define
 531      gnus-browse-menu gnus-browse-mode-map ""
 532      '("Browse"
 533        ["Subscribe" gnus-browse-unsubscribe-current-group t]
 534        ["Read" gnus-browse-read-group t]
 535        ["Select" gnus-browse-read-group t]
 536        ["Next" gnus-browse-next-group t]
 537        ["Prev" gnus-browse-next-group t]
 538        ["Exit" gnus-browse-exit t]))
 539     (gnus-run-hooks 'gnus-browse-menu-hook)))
 540
 541 (defvar gnus-browse-current-method nil)
 542 (defvar gnus-browse-return-buffer nil)
 543
 544 (defvar gnus-browse-buffer "*Gnus Browse Server*")
 545
 546 (defun gnus-browse-foreign-server (server &optional return-buffer)
 547   "Browse the server SERVER."
 548   (setq gnus-browse-current-method server)
 549   (setq gnus-browse-return-buffer return-buffer)
 550   (let* ((method (gnus-server-to-method server))
 551          (gnus-select-method method)
 552          groups group)
 553     (gnus-message 5 "Connecting to %s..." (nth 1 method))
 554     (cond
 555      ((not (gnus-check-server method))
 556       (gnus-message
 557        1 "Unable to contact server %s: %s" (nth 1 method)
 558        (gnus-status-message method))
 559       nil)
 560      ((not
 561        (prog2
 562            (gnus-message 6 "Reading active file...")
 563            (gnus-request-list method)
 564          (gnus-message 6 "Reading active file...done")))
 565       (gnus-message
 566        1 "Couldn't request list: %s" (gnus-status-message method))
 567       nil)
 568      (t
 569       (get-buffer-create gnus-browse-buffer)
 570       (gnus-add-current-to-buffer-list)
 571       (when gnus-carpal
 572         (gnus-carpal-setup-buffer 'browse))
 573       (gnus-configure-windows 'browse)
 574       (buffer-disable-undo (current-buffer))
 575       (let ((buffer-read-only nil))
 576         (erase-buffer))
 577       (gnus-browse-mode)
 578       (setq mode-line-buffer-identification
 579             (list
 580              (format
 581               "Gnus: %%b {%s:%s}" (car method) (cadr method))))
 582       (save-excursion
 583         (set-buffer nntp-server-buffer)
 584         (let ((cur (current-buffer)))
 585           (goto-char (point-min))
 586           (unless (string= gnus-ignored-newsgroups "")
 587             (delete-matching-lines gnus-ignored-newsgroups))
 588           (while (re-search-forward
 589                   "\\(^[^ \t]+\\)[ \t]+[0-9]+[ \t]+[0-9]+" nil t)
 590             (goto-char (match-end 1))
 591             (push (cons (match-string 1)
 592                         (max 0 (- (1+ (read cur)) (read cur))))
 593                   groups))))
 594       (setq groups (sort groups
 595                          (lambda (l1 l2)
 596                            (string< (car l1) (car l2)))))
 597       (let ((buffer-read-only nil))
 598         (while groups
 599           (setq group (car groups))
 600           (insert
 601            (format "K%7d: %s\n" (cdr group) (car group)))
 602           (setq groups (cdr groups))))
 603       (switch-to-buffer (current-buffer))
 604       (goto-char (point-min))
 605       (gnus-group-position-point)
 606       (gnus-message 5 "Connecting to %s...done" (nth 1 method))
 607       t))))
 608
 609 (defun gnus-browse-mode ()
 610   "Major mode for browsing a foreign server.
 611
 612 All normal editing commands are switched off.
 613
 614 \\<gnus-browse-mode-map>
 615 The only things you can do in this buffer is
 616
 617 1) `\\[gnus-browse-unsubscribe-current-group]' to subscribe to a group.
 618 The group will be inserted into the group buffer upon exit from this
 619 buffer.
 620
 621 2) `\\[gnus-browse-read-group]' to read a group ephemerally.
 622
 623 3) `\\[gnus-browse-exit]' to return to the group buffer."
 624   (interactive)
 625   (kill-all-local-variables)
 626   (when (gnus-visual-p 'browse-menu 'menu)
 627     (gnus-browse-make-menu-bar))
 628   (gnus-simplify-mode-line)
 629   (setq major-mode 'gnus-browse-mode)
 630   (setq mode-name "Browse Server")
 631   (setq mode-line-process nil)
 632   (use-local-map gnus-browse-mode-map)
 633   (buffer-disable-undo (current-buffer))
 634   (setq truncate-lines t)
 635   (gnus-set-default-directory)
 636   (setq buffer-read-only t)
 637   (gnus-run-hooks 'gnus-browse-mode-hook))
 638
 639 (defun gnus-browse-read-group (&optional no-article)
 640   "Enter the group at the current line."
 641   (interactive)
 642   (let ((group (gnus-browse-group-name)))
 643     (unless (gnus-group-read-ephemeral-group
 644              group gnus-browse-current-method nil
 645              (cons (current-buffer) 'browse))
 646       (error "Couldn't enter %s" group))))
 647
 648 (defun gnus-browse-select-group ()
 649   "Select the current group."
 650   (interactive)
 651   (gnus-browse-read-group 'no))
 652
 653 (defun gnus-browse-next-group (n)
 654   "Go to the next group."
 655   (interactive "p")
 656   (prog1
 657       (forward-line n)
 658     (gnus-group-position-point)))
 659
 660 (defun gnus-browse-prev-group (n)
 661   "Go to the next group."
 662   (interactive "p")
 663   (gnus-browse-next-group (- n)))
 664
 665 (defun gnus-browse-unsubscribe-current-group (arg)
 666   "(Un)subscribe to the next ARG groups."
 667   (interactive "p")
 668   (when (eobp)
 669     (error "No group at current line"))
 670   (let ((ward (if (< arg 0) -1 1))
 671         (arg (abs arg)))
 672     (while (and (> arg 0)
 673                 (not (eobp))
 674                 (gnus-browse-unsubscribe-group)
 675                 (zerop (gnus-browse-next-group ward)))
 676       (decf arg))
 677     (gnus-group-position-point)
 678     (when (/= 0 arg)
 679       (gnus-message 7 "No more newsgroups"))
 680     arg))
 681
 682 (defun gnus-browse-group-name ()
 683   (save-excursion
 684     (beginning-of-line)
 685     (when (re-search-forward ": \\(.*\\)$" (gnus-point-at-eol) t)
 686       (gnus-group-prefixed-name
 687        ;; Remove text props.
 688        (format "%s" (match-string 1))
 689        gnus-browse-current-method))))
 690
 691 (defun gnus-browse-unsubscribe-group ()
 692   "Toggle subscription of the current group in the browse buffer."
 693   (let ((sub nil)
 694         (buffer-read-only nil)
 695         group)
 696     (save-excursion
 697       (beginning-of-line)
 698       ;; If this group it killed, then we want to subscribe it.
 699       (when (= (following-char) ?K)
 700         (setq sub t))
 701       (when (cadr (gnus-gethash (setq group (gnus-browse-group-name))
 702                           gnus-newsrc-hashtb))
 703         (error "Group already subscribed"))
 704       ;; Make sure the group has been properly removed before we
 705       ;; subscribe to it.
 706       (gnus-kill-ephemeral-group group)
 707       (delete-char 1)
 708       (if sub
 709           (progn
 710             (gnus-group-change-level
 711              (list t group gnus-level-default-subscribed
 712                    nil nil (if (gnus-server-equal
 713                                 gnus-browse-current-method "native")
 714                                nil
 715                              gnus-browse-current-method))
 716              gnus-level-default-subscribed gnus-level-killed
 717              (and (car (nth 1 gnus-newsrc-alist))
 718                   (gnus-gethash (car (nth 1 gnus-newsrc-alist))
 719                                 gnus-newsrc-hashtb))
 720              t)
 721             (insert ? ))
 722         (gnus-group-change-level
 723          group gnus-level-killed gnus-level-default-subscribed)
 724         (insert ?K)))
 725     t))
 726
 727 (defun gnus-browse-exit ()
 728   "Quit browsing and return to the group buffer."
 729   (interactive)
 730   (when (eq major-mode 'gnus-browse-mode)
 731     (kill-buffer (current-buffer)))
 732   ;; Insert the newly subscribed groups in the group buffer.
 733   (save-excursion
 734     (set-buffer gnus-group-buffer)
 735     (gnus-group-list-groups nil))
 736   (if gnus-browse-return-buffer
 737       (gnus-configure-windows 'server 'force)
 738     (gnus-configure-windows 'group 'force)))
 739
 740 (defun gnus-browse-describe-briefly ()
 741   "Give a one line description of the group mode commands."
 742   (interactive)
 743   (gnus-message 6
 744                 (substitute-command-keys "\\<gnus-browse-mode-map>\\[gnus-group-next-group]:Forward  \\[gnus-group-prev-group]:Backward  \\[gnus-browse-exit]:Exit  \\[gnus-info-find-node]:Run Info  \\[gnus-browse-describe-briefly]:This help")))
 745
 746 (defun gnus-server-regenerate-server ()
 747   "Issue a command to the server to regenerate all its data structures."
 748   (interactive)
 749   (let ((server (gnus-server-server-name)))
 750     (unless server
 751       (error "No server on the current line"))
 752     (if (not (gnus-check-backend-function
 753               'request-regenerate (car (gnus-server-to-method server))))
 754         (error "This backend doesn't support regeneration")
 755       (gnus-message 5 "Requesting regeneration of %s..." server)
 756       (unless (gnus-open-server server)
 757         (error "Couldn't open server"))
 758       (if (gnus-request-regenerate server)
 759           (gnus-message 5 "Requesting regeneration of %s...done" server)
 760         (gnus-message 5 "Couldn't regenerate %s" server)))))
 761
 762 (provide 'gnus-srvr)
 763
 764 ;;; gnus-srvr.el ends here.