cgit.sxemacs.org Git - gnus/blob - lisp/gnus-salt.el

   1 ;;; gnus-salt.el --- alternate summary mode interfaces for Gnus
   2 ;; Copyright (C) 1996 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@ifi.uio.no>
   5
   6 ;; This file is part of GNU Emacs.
   7
   8 ;; GNU Emacs is free software; you can redistribute it and/or modify
   9 ;; it under the terms of the GNU General Public License as published by
  10 ;; the Free Software Foundation; either version 2, or (at your option)
  11 ;; any later version.
  12
  13 ;; GNU Emacs is distributed in the hope that it will be useful,
  14 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 ;; GNU General Public License for more details.
  17
  18 ;; You should have received a copy of the GNU General Public License
  19 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  20 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  21 ;; Boston, MA 02111-1307, USA.
  22
  23 ;;; Commentary:
  24
  25 ;;; Code:
  26
  27 (require 'gnus-load)
  28 (require 'gnus-sum)
  29
  30 ;;;
  31 ;;; gnus-pick-mode
  32 ;;;
  33
  34 (defvar gnus-pick-mode nil
  35   "Minor mode for providing a pick-and-read interface in Gnus summary buffers.")
  36
  37 (defvar gnus-pick-display-summary nil
  38   "*Display summary while reading.")
  39
  40 (defvar gnus-pick-mode-hook nil
  41   "Hook run in summary pick mode buffers.")
  42
  43 (defvar gnus-mark-unpicked-articles-as-read nil
  44   "*If non-nil, mark all unpicked articles as read.")
  45
  46 (defvar gnus-pick-elegant-flow t
  47   "If non-nil, gnus-pick-start-reading will run gnus-summary-next-group when no articles have been picked.")
  48
  49 (defvar gnus-summary-pick-line-format
  50   "%-5P %U\%R\%z\%I\%(%[%4L: %-20,20n%]%) %s\n"
  51   "*The format specification of the lines in pick buffers.
  52 It accepts the same format specs that `gnus-summary-line-format' does.")
  53
  54 ;;; Internal variables.
  55
  56 (defvar gnus-pick-mode-map nil)
  57
  58 (unless gnus-pick-mode-map
  59   (setq gnus-pick-mode-map (make-sparse-keymap))
  60
  61   (gnus-define-keys
  62    gnus-pick-mode-map
  63    "t" gnus-uu-mark-thread
  64    "T" gnus-uu-unmark-thread
  65    " " gnus-pick-next-page
  66    "u" gnus-summary-unmark-as-processable
  67    "U" gnus-summary-unmark-all-processable
  68    "v" gnus-uu-mark-over
  69    "r" gnus-uu-mark-region
  70    "R" gnus-uu-unmark-region
  71    "e" gnus-uu-mark-by-regexp
  72    "E" gnus-uu-mark-by-regexp
  73    "b" gnus-uu-mark-buffer
  74    "B" gnus-uu-unmark-buffer
  75    "." gnus-pick-article
  76    gnus-down-mouse-2 gnus-pick-mouse-pick-region
  77    ;;gnus-mouse-2 gnus-pick-mouse-pick
  78    "\r" gnus-pick-start-reading))
  79
  80 (defun gnus-pick-make-menu-bar ()
  81   (unless (boundp 'gnus-pick-menu)
  82     (easy-menu-define
  83      gnus-pick-menu gnus-pick-mode-map ""
  84      '("Pick"
  85        ("Pick"
  86         ["Article" gnus-summary-mark-as-processable t]
  87         ["Thread" gnus-uu-mark-thread t]
  88         ["Region" gnus-uu-mark-region t]
  89         ["Regexp" gnus-uu-mark-regexp t]
  90         ["Buffer" gnus-uu-mark-buffer t])
  91        ("Unpick"
  92         ["Article" gnus-summary-unmark-as-processable t]
  93         ["Thread" gnus-uu-unmark-thread t]
  94         ["Region" gnus-uu-unmark-region t]
  95         ["Regexp" gnus-uu-unmark-regexp t]
  96         ["Buffer" gnus-uu-unmark-buffer t])
  97        ["Start reading" gnus-pick-start-reading t]
  98        ["Switch pick mode off" gnus-pick-mode gnus-pick-mode]))))
  99
 100 (defun gnus-pick-mode (&optional arg)
 101   "Minor mode for providing a pick-and-read interface in Gnus summary buffers.
 102
 103 \\{gnus-pick-mode-map}"
 104   (interactive "P")
 105   (when (eq major-mode 'gnus-summary-mode)
 106     (when (set (make-local-variable 'gnus-pick-mode)
 107                (if (null arg) (not gnus-pick-mode)
 108                  (> (prefix-numeric-value arg) 0)))
 109       ;; Make sure that we don't select any articles upon group entry.
 110       (set (make-local-variable 'gnus-auto-select-first) nil)
 111       ;; Change line format.
 112       (setq gnus-summary-line-format gnus-summary-pick-line-format)
 113       (setq gnus-summary-line-format-spec nil)
 114       (gnus-update-format-specifications nil 'summary)
 115       (gnus-update-summary-mark-positions)
 116       (set (make-local-variable 'gnus-summary-goto-unread) 'never)
 117       ;; Set up the menu.
 118       (when (and menu-bar-mode
 119                  (gnus-visual-p 'pick-menu 'menu))
 120         (gnus-pick-make-menu-bar))
 121       (unless (assq 'gnus-pick-mode minor-mode-alist)
 122         (push '(gnus-pick-mode " Pick") minor-mode-alist))
 123       (unless (assq 'gnus-pick-mode minor-mode-map-alist)
 124         (push (cons 'gnus-pick-mode gnus-pick-mode-map)
 125               minor-mode-map-alist))
 126       (run-hooks 'gnus-pick-mode-hook))))
 127
 128 (defvar gnus-pick-line-number 1)
 129 (defun gnus-pick-line-number ()
 130   "Return the current line number."
 131   (if (bobp)
 132       (setq gnus-pick-line-number 1)
 133     (incf gnus-pick-line-number)))
 134
 135 (defun gnus-pick-start-reading (&optional catch-up)
 136   "Start reading the picked articles.
 137 If given a prefix, mark all unpicked articles as read."
 138   (interactive "P")
 139   (if gnus-newsgroup-processable
 140       (progn
 141         (gnus-summary-limit-to-articles nil)
 142         (when (or catch-up gnus-mark-unpicked-articles-as-read)
 143           (gnus-summary-limit-mark-excluded-as-read))
 144         (gnus-summary-first-unread-article)
 145         (gnus-configure-windows
 146          (if gnus-pick-display-summary 'article 'pick) t))
 147     (if gnus-pick-elegant-flow
 148         (gnus-summary-next-group)
 149       (error "No articles have been picked"))))
 150
 151 (defun gnus-pick-article (&optional arg)
 152   "Pick the article on the current line.
 153 If ARG, pick the article on that line instead."
 154   (interactive "P")
 155   (when arg
 156     (let (pos)
 157       (save-excursion
 158         (goto-char (point-min))
 159         (when (zerop (forward-line (1- (prefix-numeric-value arg))))
 160           (setq pos (point))))
 161       (if (not pos)
 162           (gnus-error 2 "No such line: %s" arg)
 163         (goto-char pos))))
 164   (gnus-summary-mark-as-processable 1))
 165
 166 (defun gnus-pick-mouse-pick (e)
 167   (interactive "e")
 168   (mouse-set-point e)
 169   (save-excursion
 170     (gnus-summary-mark-as-processable 1)))
 171
 172 (defun gnus-pick-mouse-pick-region (start-event)
 173   "Pick articles that the mouse is dragged over.
 174 This must be bound to a button-down mouse event."
 175   (interactive "e")
 176   (mouse-minibuffer-check start-event)
 177   (let* ((echo-keystrokes 0)
 178          (start-posn (event-start start-event))
 179          (start-point (posn-point start-posn))
 180          (start-line (1+ (count-lines 1 start-point)))
 181          (start-window (posn-window start-posn))
 182          (start-frame (window-frame start-window))
 183          (bounds (window-edges start-window))
 184          (top (nth 1 bounds))
 185          (bottom (if (window-minibuffer-p start-window)
 186                      (nth 3 bounds)
 187                    ;; Don't count the mode line.
 188                    (1- (nth 3 bounds))))
 189          (click-count (1- (event-click-count start-event))))
 190     (setq mouse-selection-click-count click-count)
 191     (setq mouse-selection-click-count-buffer (current-buffer))
 192     (mouse-set-point start-event)
 193     ;; In case the down click is in the middle of some intangible text,
 194     ;; use the end of that text, and put it in START-POINT.
 195     (if (< (point) start-point)
 196         (goto-char start-point))
 197     (gnus-pick-article)
 198     (setq start-point (point))
 199     ;; end-of-range is used only in the single-click case.
 200     ;; It is the place where the drag has reached so far
 201     ;; (but not outside the window where the drag started).
 202     (let (event end end-point last-end-point (end-of-range (point)))
 203       (track-mouse
 204         (while (progn
 205                  (setq event (read-event))
 206                  (or (mouse-movement-p event)
 207                      (eq (car-safe event) 'switch-frame)))
 208           (if (eq (car-safe event) 'switch-frame)
 209               nil
 210             (setq end (event-end event)
 211                   end-point (posn-point end))
 212             (if end-point
 213                 (setq last-end-point end-point))
 214
 215             (cond
 216              ;; Are we moving within the original window?
 217              ((and (eq (posn-window end) start-window)
 218                    (integer-or-marker-p end-point))
 219               ;; Go to START-POINT first, so that when we move to END-POINT,
 220               ;; if it's in the middle of intangible text,
 221               ;; point jumps in the direction away from START-POINT.
 222               (goto-char start-point)
 223               (goto-char end-point)
 224               (gnus-pick-article)
 225               ;; In case the user moved his mouse really fast, pick
 226               ;; articles on the line between this one and the last one.
 227               (let* ((this-line (1+ (count-lines 1 end-point)))
 228                      (min-line (min this-line start-line))
 229                      (max-line (max this-line start-line)))
 230                 (while (< min-line max-line)
 231                   (goto-line min-line)
 232                   (gnus-pick-article)
 233                   (setq min-line (1+ min-line)))
 234                 (setq start-line this-line))
 235               (if (zerop (% click-count 3))
 236                   (setq end-of-range (point))))
 237              (t
 238               (let ((mouse-row (cdr (cdr (mouse-position)))))
 239                 (cond
 240                  ((null mouse-row))
 241                  ((< mouse-row top)
 242                   (mouse-scroll-subr start-window (- mouse-row top)))
 243                  ((>= mouse-row bottom)
 244                   (mouse-scroll-subr start-window
 245                                      (1+ (- mouse-row bottom)))))))))))
 246       (if (consp event)
 247           (let ((fun (key-binding (vector (car event)))))
 248             ;; Run the binding of the terminating up-event, if possible.
 249             ;; In the case of a multiple click, it gives the wrong results,
 250             ;; because it would fail to set up a region.
 251             (if nil ;; (and (= (mod mouse-selection-click-count 3) 0) (fboundp fun))
 252                 ;; In this case, we can just let the up-event execute normally.
 253                 (let ((end (event-end event)))
 254                   ;; Set the position in the event before we replay it,
 255                   ;; because otherwise it may have a position in the wrong
 256                   ;; buffer.
 257                   (setcar (cdr end) end-of-range)
 258                   ;; Delete the overlay before calling the function,
 259                   ;; because delete-overlay increases buffer-modified-tick.
 260                   (setq unread-command-events
 261                         (cons event unread-command-events)))))))))
 262
 263 (defun gnus-pick-next-page ()
 264   "Go to the next page.  If at the end of the buffer, start reading articles."
 265   (interactive)
 266   (condition-case nil
 267       (scroll-up)
 268     (end-of-buffer (gnus-pick-start-reading))))
 269
 270 ;;;
 271 ;;; gnus-binary-mode
 272 ;;;
 273
 274 (defvar gnus-binary-mode nil
 275   "Minor mode for providing a binary group interface in Gnus summary buffers.")
 276
 277 (defvar gnus-binary-mode-hook nil
 278   "Hook run in summary binary mode buffers.")
 279
 280 (defvar gnus-binary-mode-map nil)
 281
 282 (unless gnus-binary-mode-map
 283   (setq gnus-binary-mode-map (make-sparse-keymap))
 284
 285   (gnus-define-keys
 286    gnus-binary-mode-map
 287    "g" gnus-binary-show-article))
 288
 289 (defun gnus-binary-make-menu-bar ()
 290   (unless (boundp 'gnus-binary-menu)
 291     (easy-menu-define
 292      gnus-binary-menu gnus-binary-mode-map ""
 293      '("Pick"
 294        ["Switch binary mode off" gnus-binary-mode t]))))
 295
 296 (defun gnus-binary-mode (&optional arg)
 297   "Minor mode for providing a binary group interface in Gnus summary buffers."
 298   (interactive "P")
 299   (when (eq major-mode 'gnus-summary-mode)
 300     (make-local-variable 'gnus-binary-mode)
 301     (setq gnus-binary-mode
 302           (if (null arg) (not gnus-binary-mode)
 303             (> (prefix-numeric-value arg) 0)))
 304     (when gnus-binary-mode
 305       ;; Make sure that we don't select any articles upon group entry.
 306       (make-local-variable 'gnus-auto-select-first)
 307       (setq gnus-auto-select-first nil)
 308       (make-local-variable 'gnus-summary-display-article-function)
 309       (setq gnus-summary-display-article-function 'gnus-binary-display-article)
 310       ;; Set up the menu.
 311       (when (and menu-bar-mode
 312                  (gnus-visual-p 'binary-menu 'menu))
 313         (gnus-binary-make-menu-bar))
 314       (unless (assq 'gnus-binary-mode minor-mode-alist)
 315         (push '(gnus-binary-mode " Binary") minor-mode-alist))
 316       (unless (assq 'gnus-binary-mode minor-mode-map-alist)
 317         (push (cons 'gnus-binary-mode gnus-binary-mode-map)
 318               minor-mode-map-alist))
 319       (run-hooks 'gnus-binary-mode-hook))))
 320
 321 (defun gnus-binary-display-article (article &optional all-header)
 322   "Run ARTICLE through the binary decode functions."
 323   (when (gnus-summary-goto-subject article)
 324     (let ((gnus-view-pseudos 'automatic))
 325       (gnus-uu-decode-uu))))
 326
 327 (defun gnus-binary-show-article (&optional arg)
 328   "Bypass the binary functions and show the article."
 329   (interactive "P")
 330   (let (gnus-summary-display-article-function)
 331     (gnus-summary-show-article arg)))
 332
 333 ;;;
 334 ;;; gnus-tree-mode
 335 ;;;
 336
 337 (defvar gnus-tree-line-format "%(%[%3,3n%]%)"
 338   "Format of tree elements.")
 339
 340 (defvar gnus-tree-minimize-window t
 341   "If non-nil, minimize the tree buffer window.
 342 If a number, never let the tree buffer grow taller than that number of
 343 lines.")
 344
 345 (defvar gnus-selected-tree-face 'modeline
 346   "*Face used for highlighting selected articles in the thread tree.")
 347
 348 (defvar gnus-tree-brackets '((?\[ . ?\]) (?\( . ?\))
 349                              (?\{ . ?\}) (?< . ?>))
 350   "Brackets used in tree nodes.")
 351
 352 (defvar gnus-tree-parent-child-edges '(?- ?\\ ?|)
 353   "Characters used to connect parents with children.")
 354
 355 (defvar gnus-tree-mode-line-format "Gnus: %%b %S %Z"
 356   "*The format specification for the tree mode line.")
 357
 358 (defvar gnus-generate-tree-function 'gnus-generate-vertical-tree
 359   "*Function for generating a thread tree.
 360 Two predefined functions are available:
 361 `gnus-generate-horizontal-tree' and `gnus-generate-vertical-tree'.")
 362
 363 (defvar gnus-tree-mode-hook nil
 364   "*Hook run in tree mode buffers.")
 365
 366 ;;; Internal variables.
 367
 368 (defvar gnus-tree-line-format-alist
 369   `((?n gnus-tmp-name ?s)
 370     (?f gnus-tmp-from ?s)
 371     (?N gnus-tmp-number ?d)
 372     (?\[ gnus-tmp-open-bracket ?c)
 373     (?\] gnus-tmp-close-bracket ?c)
 374     (?s gnus-tmp-subject ?s)))
 375
 376 (defvar gnus-tree-mode-line-format-alist gnus-summary-mode-line-format-alist)
 377
 378 (defvar gnus-tree-mode-line-format-spec nil)
 379 (defvar gnus-tree-line-format-spec nil)
 380
 381 (defvar gnus-tree-node-length nil)
 382 (defvar gnus-selected-tree-overlay nil)
 383
 384 (defvar gnus-tree-displayed-thread nil)
 385
 386 (defvar gnus-tree-mode-map nil)
 387 (put 'gnus-tree-mode 'mode-class 'special)
 388
 389 (unless gnus-tree-mode-map
 390   (setq gnus-tree-mode-map (make-keymap))
 391   (suppress-keymap gnus-tree-mode-map)
 392   (gnus-define-keys
 393    gnus-tree-mode-map
 394    "\r" gnus-tree-select-article
 395    gnus-mouse-2 gnus-tree-pick-article
 396    "\C-?" gnus-tree-read-summary-keys
 397
 398    "\C-c\C-i" gnus-info-find-node)
 399
 400   (substitute-key-definition
 401    'undefined 'gnus-tree-read-summary-keys gnus-tree-mode-map))
 402
 403 (defun gnus-tree-make-menu-bar ()
 404   (unless (boundp 'gnus-tree-menu)
 405     (easy-menu-define
 406      gnus-tree-menu gnus-tree-mode-map ""
 407      '("Tree"
 408        ["Select article" gnus-tree-select-article t]))))
 409
 410 (defun gnus-tree-mode ()
 411   "Major mode for displaying thread trees."
 412   (interactive)
 413   (setq gnus-tree-mode-line-format-spec
 414         (gnus-parse-format gnus-tree-mode-line-format
 415                            gnus-summary-mode-line-format-alist))
 416   (setq gnus-tree-line-format-spec
 417         (gnus-parse-format gnus-tree-line-format
 418                            gnus-tree-line-format-alist t))
 419   (when (and menu-bar-mode
 420              (gnus-visual-p 'tree-menu 'menu))
 421     (gnus-tree-make-menu-bar))
 422   (kill-all-local-variables)
 423   (gnus-simplify-mode-line)
 424   (setq mode-name "Tree")
 425   (setq major-mode 'gnus-tree-mode)
 426   (use-local-map gnus-tree-mode-map)
 427   (buffer-disable-undo (current-buffer))
 428   (setq buffer-read-only t)
 429   (setq truncate-lines t)
 430   (save-excursion
 431     (gnus-set-work-buffer)
 432     (gnus-tree-node-insert (make-mail-header "") nil)
 433     (setq gnus-tree-node-length (1- (point))))
 434   (run-hooks 'gnus-tree-mode-hook))
 435
 436 (defun gnus-tree-read-summary-keys (&optional arg)
 437   "Read a summary buffer key sequence and execute it."
 438   (interactive "P")
 439   (let ((buf (current-buffer))
 440         win)
 441     (gnus-article-read-summary-keys arg nil t)
 442     (when (setq win (get-buffer-window buf))
 443       (select-window win)
 444       (when gnus-selected-tree-overlay
 445         (goto-char (or (gnus-overlay-end gnus-selected-tree-overlay) 1)))
 446       (gnus-tree-minimize))))
 447
 448 (defun gnus-tree-select-article (article)
 449   "Select the article under point, if any."
 450   (interactive (list (gnus-tree-article-number)))
 451   (let ((buf (current-buffer)))
 452     (when article
 453       (save-excursion
 454         (set-buffer gnus-summary-buffer)
 455         (gnus-summary-goto-article article))
 456       (select-window (get-buffer-window buf)))))
 457
 458 (defun gnus-tree-pick-article (e)
 459   "Select the article under the mouse pointer."
 460   (interactive "e")
 461   (mouse-set-point e)
 462   (gnus-tree-select-article (gnus-tree-article-number)))
 463
 464 (defun gnus-tree-article-number ()
 465   (get-text-property (point) 'gnus-number))
 466
 467 (defun gnus-tree-article-region (article)
 468   "Return a cons with BEG and END of the article region."
 469   (let ((pos (text-property-any (point-min) (point-max) 'gnus-number article)))
 470     (when pos
 471       (cons pos (next-single-property-change pos 'gnus-number)))))
 472
 473 (defun gnus-tree-goto-article (article)
 474   (let ((pos (text-property-any (point-min) (point-max) 'gnus-number article)))
 475     (when pos
 476       (goto-char pos))))
 477
 478 (defun gnus-tree-recenter ()
 479   "Center point in the tree window."
 480   (let ((selected (selected-window))
 481         (tree-window (get-buffer-window gnus-tree-buffer t)))
 482     (when tree-window
 483       (select-window tree-window)
 484       (when gnus-selected-tree-overlay
 485         (goto-char (or (gnus-overlay-end gnus-selected-tree-overlay) 1)))
 486       (let* ((top (cond ((< (window-height) 4) 0)
 487                         ((< (window-height) 7) 1)
 488                         (t 2)))
 489              (height (1- (window-height)))
 490              (bottom (save-excursion (goto-char (point-max))
 491                                      (forward-line (- height))
 492                                      (point))))
 493         ;; Set the window start to either `bottom', which is the biggest
 494         ;; possible valid number, or the second line from the top,
 495         ;; whichever is the least.
 496         (set-window-start
 497          tree-window (min bottom (save-excursion
 498                                    (forward-line (- top)) (point)))))
 499       (select-window selected))))
 500
 501 (defun gnus-get-tree-buffer ()
 502   "Return the tree buffer properly initialized."
 503   (save-excursion
 504     (set-buffer (get-buffer-create gnus-tree-buffer))
 505     (unless (eq major-mode 'gnus-tree-mode)
 506       (gnus-add-current-to-buffer-list)
 507       (gnus-tree-mode))
 508     (current-buffer)))
 509
 510 (defun gnus-tree-minimize ()
 511   (when (and gnus-tree-minimize-window
 512              (not (one-window-p)))
 513     (let ((windows 0)
 514           tot-win-height)
 515       (walk-windows (lambda (window) (incf windows)))
 516       (setq tot-win-height
 517             (- (frame-height)
 518                (* window-min-height (1- windows))
 519                2))
 520       (let* ((window-min-height 2)
 521              (height (count-lines (point-min) (point-max)))
 522              (min (max (1- window-min-height) height))
 523              (tot (if (numberp gnus-tree-minimize-window)
 524                       (min gnus-tree-minimize-window min)
 525                     min))
 526              (win (get-buffer-window (current-buffer)))
 527              (wh (and win (1- (window-height win)))))
 528         (setq tot (min tot tot-win-height))
 529         (when (and win
 530                    (not (eq tot wh)))
 531           (let ((selected (selected-window)))
 532             (select-window win)
 533             (enlarge-window (- tot wh))
 534             (select-window selected)))))))
 535
 536 ;;; Generating the tree.
 537
 538 (defun gnus-tree-node-insert (header sparse &optional adopted)
 539   (let* ((dummy (stringp header))
 540          (header (if (vectorp header) header
 541                    (progn
 542                      (setq header (make-mail-header "*****"))
 543                      (mail-header-set-number header 0)
 544                      (mail-header-set-lines header 0)
 545                      (mail-header-set-chars header 0)
 546                      header)))
 547          (gnus-tmp-from (mail-header-from header))
 548          (gnus-tmp-subject (mail-header-subject header))
 549          (gnus-tmp-number (mail-header-number header))
 550          (gnus-tmp-name
 551           (cond
 552            ((string-match "(.+)" gnus-tmp-from)
 553             (substring gnus-tmp-from
 554                        (1+ (match-beginning 0)) (1- (match-end 0))))
 555            ((string-match "<[^>]+> *$" gnus-tmp-from)
 556             (let ((beg (match-beginning 0)))
 557               (or (and (string-match "^\"[^\"]*\"" gnus-tmp-from)
 558                        (substring gnus-tmp-from (1+ (match-beginning 0))
 559                                   (1- (match-end 0))))
 560                   (substring gnus-tmp-from 0 beg))))
 561            ((memq gnus-tmp-number sparse)
 562             "***")
 563            (t gnus-tmp-from)))
 564          (gnus-tmp-open-bracket
 565           (cond ((memq gnus-tmp-number sparse)
 566                  (caadr gnus-tree-brackets))
 567                 (dummy (caaddr gnus-tree-brackets))
 568                 (adopted (car (nth 3 gnus-tree-brackets)))
 569                 (t (caar gnus-tree-brackets))))
 570          (gnus-tmp-close-bracket
 571           (cond ((memq gnus-tmp-number sparse)
 572                  (cdadr gnus-tree-brackets))
 573                 (adopted (cdr (nth 3 gnus-tree-brackets)))
 574                 (dummy
 575                  (cdaddr gnus-tree-brackets))
 576                 (t (cdar gnus-tree-brackets))))
 577          (buffer-read-only nil)
 578          beg end)
 579     (gnus-add-text-properties
 580      (setq beg (point))
 581      (setq end (progn (eval gnus-tree-line-format-spec) (point)))
 582      (list 'gnus-number gnus-tmp-number))
 583     (when (or t (gnus-visual-p 'tree-highlight 'highlight))
 584       (gnus-tree-highlight-node gnus-tmp-number beg end))))
 585
 586 (defun gnus-tree-highlight-node (article beg end)
 587   "Highlight current line according to `gnus-summary-highlight'."
 588   (let ((list gnus-summary-highlight)
 589         face)
 590     (save-excursion
 591       (set-buffer gnus-summary-buffer)
 592       (let* ((score (or (cdr (assq article gnus-newsgroup-scored))
 593                         gnus-summary-default-score 0))
 594              (default gnus-summary-default-score)
 595              (mark (or (gnus-summary-article-mark article) gnus-unread-mark)))
 596         ;; Eval the cars of the lists until we find a match.
 597         (while (and list
 598                     (not (eval (caar list))))
 599           (setq list (cdr list)))))
 600     (unless (eq (setq face (cdar list)) (get-text-property beg 'face))
 601       (gnus-put-text-property
 602        beg end 'face
 603        (if (boundp face) (symbol-value face) face)))))
 604
 605 (defun gnus-tree-indent (level)
 606   (insert (make-string (1- (* (1+ gnus-tree-node-length) level)) ? )))
 607
 608 (defvar gnus-tmp-limit)
 609 (defvar gnus-tmp-sparse)
 610 (defvar gnus-tmp-indent)
 611
 612 (defun gnus-generate-tree (thread)
 613   "Generate a thread tree for THREAD."
 614   (save-excursion
 615     (set-buffer (gnus-get-tree-buffer))
 616     (let ((buffer-read-only nil)
 617           (gnus-tmp-indent 0))
 618       (erase-buffer)
 619       (funcall gnus-generate-tree-function thread 0)
 620       (gnus-set-mode-line 'tree)
 621       (goto-char (point-min))
 622       (gnus-tree-minimize)
 623       (gnus-tree-recenter)
 624       (let ((selected (selected-window)))
 625         (when (get-buffer-window (set-buffer gnus-tree-buffer) t)
 626           (select-window (get-buffer-window (set-buffer gnus-tree-buffer) t))
 627           (gnus-horizontal-recenter)
 628           (select-window selected))))))
 629
 630 (defun gnus-generate-horizontal-tree (thread level &optional dummyp adopted)
 631   "Generate a horizontal tree."
 632   (let* ((dummy (stringp (car thread)))
 633          (do (or dummy
 634                  (memq (mail-header-number (car thread)) gnus-tmp-limit)))
 635          col beg)
 636     (if (not do)
 637         ;; We don't want this article.
 638         (setq thread (cdr thread))
 639       (if (not (bolp))
 640           ;; Not the first article on the line, so we insert a "-".
 641           (insert (car gnus-tree-parent-child-edges))
 642         ;; If the level isn't zero, then we insert some indentation.
 643         (unless (zerop level)
 644           (gnus-tree-indent level)
 645           (insert (cadr gnus-tree-parent-child-edges))
 646           (setq col (- (setq beg (point)) (gnus-point-at-bol) 1))
 647           ;; Draw "|" lines upwards.
 648           (while (progn
 649                    (forward-line -1)
 650                    (forward-char col)
 651                    (= (following-char) ? ))
 652             (delete-char 1)
 653             (insert (caddr gnus-tree-parent-child-edges)))
 654           (goto-char beg)))
 655       (setq dummyp nil)
 656       ;; Insert the article node.
 657       (gnus-tree-node-insert (pop thread) gnus-tmp-sparse adopted))
 658     (if (null thread)
 659         ;; End of the thread, so we go to the next line.
 660         (unless (bolp)
 661           (insert "\n"))
 662       ;; Recurse downwards in all children of this article.
 663       (while thread
 664         (gnus-generate-horizontal-tree
 665          (pop thread) (if do (1+ level) level)
 666          (or dummyp dummy) dummy)))))
 667
 668 (defsubst gnus-tree-indent-vertical ()
 669   (let ((len (- (* (1+ gnus-tree-node-length) gnus-tmp-indent)
 670                 (- (point) (gnus-point-at-bol)))))
 671     (when (> len 0)
 672       (insert (make-string len ? )))))
 673
 674 (defsubst gnus-tree-forward-line (n)
 675   (while (>= (decf n) 0)
 676     (unless (zerop (forward-line 1))
 677       (end-of-line)
 678       (insert "\n")))
 679   (end-of-line))
 680
 681 (defun gnus-generate-vertical-tree (thread level &optional dummyp adopted)
 682   "Generate a vertical tree."
 683   (let* ((dummy (stringp (car thread)))
 684          (do (or dummy
 685                  (memq (mail-header-number (car thread)) gnus-tmp-limit)))
 686          beg)
 687     (if (not do)
 688         ;; We don't want this article.
 689         (setq thread (cdr thread))
 690       (if (not (save-excursion (beginning-of-line) (bobp)))
 691           ;; Not the first article on the line, so we insert a "-".
 692           (progn
 693             (gnus-tree-indent-vertical)
 694             (insert (make-string (/ gnus-tree-node-length 2) ? ))
 695             (insert (caddr gnus-tree-parent-child-edges))
 696             (gnus-tree-forward-line 1))
 697         ;; If the level isn't zero, then we insert some indentation.
 698         (unless (zerop gnus-tmp-indent)
 699           (gnus-tree-forward-line (1- (* 2 level)))
 700           (gnus-tree-indent-vertical)
 701           (delete-char -1)
 702           (insert (cadr gnus-tree-parent-child-edges))
 703           (setq beg (point))
 704           ;; Draw "-" lines leftwards.
 705           (while (progn
 706                    (forward-char -2)
 707                    (= (following-char) ? ))
 708             (delete-char 1)
 709             (insert (car gnus-tree-parent-child-edges)))
 710           (goto-char beg)
 711           (gnus-tree-forward-line 1)))
 712       (setq dummyp nil)
 713       ;; Insert the article node.
 714       (gnus-tree-indent-vertical)
 715       (gnus-tree-node-insert (pop thread) gnus-tmp-sparse adopted)
 716       (gnus-tree-forward-line 1))
 717     (if (null thread)
 718         ;; End of the thread, so we go to the next line.
 719         (progn
 720           (goto-char (point-min))
 721           (end-of-line)
 722           (incf gnus-tmp-indent))
 723       ;; Recurse downwards in all children of this article.
 724       (while thread
 725         (gnus-generate-vertical-tree
 726          (pop thread) (if do (1+ level) level)
 727          (or dummyp dummy) dummy)))))
 728
 729 ;;; Interface functions.
 730
 731 (defun gnus-possibly-generate-tree (article &optional force)
 732   "Generate the thread tree for ARTICLE if it isn't displayed already."
 733   (when (save-excursion
 734           (set-buffer gnus-summary-buffer)
 735           (and gnus-use-trees
 736                gnus-show-threads
 737                (vectorp (gnus-summary-article-header article))))
 738     (save-excursion
 739       (let ((top (save-excursion
 740                    (set-buffer gnus-summary-buffer)
 741                    (gnus-cut-thread
 742                     (gnus-remove-thread
 743                      (mail-header-id
 744                       (gnus-summary-article-header article)) t))))
 745             (gnus-tmp-limit gnus-newsgroup-limit)
 746             (gnus-tmp-sparse gnus-newsgroup-sparse))
 747         (when (or force
 748                   (not (eq top gnus-tree-displayed-thread)))
 749           (gnus-generate-tree top)
 750           (setq gnus-tree-displayed-thread top))))))
 751
 752 (defun gnus-tree-open (group)
 753   (gnus-get-tree-buffer))
 754
 755 (defun gnus-tree-close (group)
 756                                         ;(gnus-kill-buffer gnus-tree-buffer)
 757   )
 758
 759 (defun gnus-highlight-selected-tree (article)
 760   "Highlight the selected article in the tree."
 761   (let ((buf (current-buffer))
 762         region)
 763     (set-buffer gnus-tree-buffer)
 764     (when (setq region (gnus-tree-article-region article))
 765       (when (or (not gnus-selected-tree-overlay)
 766                 (gnus-extent-detached-p gnus-selected-tree-overlay))
 767         ;; Create a new overlay.
 768         (gnus-overlay-put
 769          (setq gnus-selected-tree-overlay (gnus-make-overlay 1 2))
 770          'face gnus-selected-tree-face))
 771       ;; Move the overlay to the article.
 772       (gnus-move-overlay
 773        gnus-selected-tree-overlay (goto-char (car region)) (cdr region))
 774       (gnus-tree-minimize)
 775       (gnus-tree-recenter)
 776       (let ((selected (selected-window)))
 777         (when (get-buffer-window (set-buffer gnus-tree-buffer) t)
 778           (select-window (get-buffer-window (set-buffer gnus-tree-buffer) t))
 779           (gnus-horizontal-recenter)
 780           (select-window selected))))
 781     ;; If we remove this save-excursion, it updates the wrong mode lines?!?
 782     (save-excursion
 783       (set-buffer gnus-tree-buffer)
 784       (gnus-set-mode-line 'tree))
 785     (set-buffer buf)))
 786
 787 (defun gnus-tree-highlight-article (article face)
 788   (save-excursion
 789     (set-buffer (gnus-get-tree-buffer))
 790     (let (region)
 791       (when (setq region (gnus-tree-article-region article))
 792         (gnus-put-text-property (car region) (cdr region) 'face face)
 793         (set-window-point
 794          (get-buffer-window (current-buffer) t) (cdr region))))))
 795
 796 ;;;
 797 ;;; gnus-carpal
 798 ;;;
 799
 800 (defvar gnus-carpal-group-buffer-buttons
 801   '(("next" . gnus-group-next-unread-group)
 802     ("prev" . gnus-group-prev-unread-group)
 803     ("read" . gnus-group-read-group)
 804     ("select" . gnus-group-select-group)
 805     ("catch-up" . gnus-group-catchup-current)
 806     ("new-news" . gnus-group-get-new-news-this-group)
 807     ("toggle-sub" . gnus-group-unsubscribe-current-group)
 808     ("subscribe" . gnus-group-unsubscribe-group)
 809     ("kill" . gnus-group-kill-group)
 810     ("yank" . gnus-group-yank-group)
 811     ("describe" . gnus-group-describe-group)
 812     "list"
 813     ("subscribed" . gnus-group-list-groups)
 814     ("all" . gnus-group-list-all-groups)
 815     ("killed" . gnus-group-list-killed)
 816     ("zombies" . gnus-group-list-zombies)
 817     ("matching" . gnus-group-list-matching)
 818     ("post" . gnus-group-post-news)
 819     ("mail" . gnus-group-mail)
 820     ("rescan" . gnus-group-get-new-news)
 821     ("browse-foreign" . gnus-group-browse-foreign)
 822     ("exit" . gnus-group-exit)))
 823
 824 (defvar gnus-carpal-summary-buffer-buttons
 825   '("mark"
 826     ("read" . gnus-summary-mark-as-read-forward)
 827     ("tick" . gnus-summary-tick-article-forward)
 828     ("clear" . gnus-summary-clear-mark-forward)
 829     ("expirable" . gnus-summary-mark-as-expirable)
 830     "move"
 831     ("scroll" . gnus-summary-next-page)
 832     ("next-unread" . gnus-summary-next-unread-article)
 833     ("prev-unread" . gnus-summary-prev-unread-article)
 834     ("first" . gnus-summary-first-unread-article)
 835     ("best" . gnus-summary-best-unread-article)
 836     "article"
 837     ("headers" . gnus-summary-toggle-header)
 838     ("uudecode" . gnus-uu-decode-uu)
 839     ("enter-digest" . gnus-summary-enter-digest-group)
 840     ("fetch-parent" . gnus-summary-refer-parent-article)
 841     "mail"
 842     ("move" . gnus-summary-move-article)
 843     ("copy" . gnus-summary-copy-article)
 844     ("respool" . gnus-summary-respool-article)
 845     "threads"
 846     ("lower" . gnus-summary-lower-thread)
 847     ("kill" . gnus-summary-kill-thread)
 848     "post"
 849     ("post" . gnus-summary-post-news)
 850     ("mail" . gnus-summary-mail)
 851     ("followup" . gnus-summary-followup-with-original)
 852     ("reply" . gnus-summary-reply-with-original)
 853     ("cancel" . gnus-summary-cancel-article)
 854     "misc"
 855     ("exit" . gnus-summary-exit)
 856     ("fed-up" . gnus-summary-catchup-and-goto-next-group)))
 857
 858 (defvar gnus-carpal-server-buffer-buttons
 859   '(("add" . gnus-server-add-server)
 860     ("browse" . gnus-server-browse-server)
 861     ("list" . gnus-server-list-servers)
 862     ("kill" . gnus-server-kill-server)
 863     ("yank" . gnus-server-yank-server)
 864     ("copy" . gnus-server-copy-server)
 865     ("exit" . gnus-server-exit)))
 866
 867 (defvar gnus-carpal-browse-buffer-buttons
 868   '(("subscribe" . gnus-browse-unsubscribe-current-group)
 869     ("exit" . gnus-browse-exit)))
 870
 871 (defvar gnus-carpal-group-buffer "*Carpal Group*")
 872 (defvar gnus-carpal-summary-buffer "*Carpal Summary*")
 873 (defvar gnus-carpal-server-buffer "*Carpal Server*")
 874 (defvar gnus-carpal-browse-buffer "*Carpal Browse*")
 875
 876 (defvar gnus-carpal-attached-buffer nil)
 877
 878 (defvar gnus-carpal-mode-hook nil
 879   "*Hook run in carpal mode buffers.")
 880
 881 (defvar gnus-carpal-button-face 'bold
 882   "*Face used on carpal buttons.")
 883
 884 (defvar gnus-carpal-header-face 'bold-italic
 885   "*Face used on carpal buffer headers.")
 886
 887 (defvar gnus-carpal-mode-map nil)
 888 (put 'gnus-carpal-mode 'mode-class 'special)
 889
 890 (if gnus-carpal-mode-map
 891     nil
 892   (setq gnus-carpal-mode-map (make-keymap))
 893   (suppress-keymap gnus-carpal-mode-map)
 894   (define-key gnus-carpal-mode-map " " 'gnus-carpal-select)
 895   (define-key gnus-carpal-mode-map "\r" 'gnus-carpal-select)
 896   (define-key gnus-carpal-mode-map gnus-mouse-2 'gnus-carpal-mouse-select))
 897
 898 (defun gnus-carpal-mode ()
 899   "Major mode for clicking buttons.
 900
 901 All normal editing commands are switched off.
 902 \\<gnus-carpal-mode-map>
 903 The following commands are available:
 904
 905 \\{gnus-carpal-mode-map}"
 906   (interactive)
 907   (kill-all-local-variables)
 908   (setq mode-line-modified "-- ")
 909   (setq major-mode 'gnus-carpal-mode)
 910   (setq mode-name "Gnus Carpal")
 911   (setq mode-line-process nil)
 912   (use-local-map gnus-carpal-mode-map)
 913   (buffer-disable-undo (current-buffer))
 914   (setq buffer-read-only t)
 915   (make-local-variable 'gnus-carpal-attached-buffer)
 916   (run-hooks 'gnus-carpal-mode-hook))
 917
 918 (defun gnus-carpal-setup-buffer (type)
 919   (let ((buffer (symbol-value (intern (format "gnus-carpal-%s-buffer" type)))))
 920     (if (get-buffer buffer)
 921         ()
 922       (save-excursion
 923         (set-buffer (get-buffer-create buffer))
 924         (gnus-carpal-mode)
 925         (setq gnus-carpal-attached-buffer
 926               (intern (format "gnus-%s-buffer" type)))
 927         (gnus-add-current-to-buffer-list)
 928         (let ((buttons (symbol-value
 929                         (intern (format "gnus-carpal-%s-buffer-buttons"
 930                                         type))))
 931               (buffer-read-only nil)
 932               button)
 933           (while buttons
 934             (setq button (car buttons)
 935                   buttons (cdr buttons))
 936             (if (stringp button)
 937                 (gnus-set-text-properties
 938                  (point)
 939                  (prog2 (insert button) (point) (insert " "))
 940                  (list 'face gnus-carpal-header-face))
 941               (gnus-set-text-properties
 942                (point)
 943                (prog2 (insert (car button)) (point) (insert " "))
 944                (list 'gnus-callback (cdr button)
 945                      'face gnus-carpal-button-face
 946                      gnus-mouse-face-prop 'highlight))))
 947           (let ((fill-column (- (window-width) 2)))
 948             (fill-region (point-min) (point-max)))
 949           (set-window-point (get-buffer-window (current-buffer))
 950                             (point-min)))))))
 951
 952 (defun gnus-carpal-select ()
 953   "Select the button under point."
 954   (interactive)
 955   (let ((func (get-text-property (point) 'gnus-callback)))
 956     (if (null func)
 957         ()
 958       (pop-to-buffer (symbol-value gnus-carpal-attached-buffer))
 959       (call-interactively func))))
 960
 961 (defun gnus-carpal-mouse-select (event)
 962   "Select the button under the mouse pointer."
 963   (interactive "e")
 964   (mouse-set-point event)
 965   (gnus-carpal-select))
 966
 967 ;;; Allow redefinition of functions.
 968 (gnus-ems-redefine)
 969
 970 (provide 'gnus-salt)
 971
 972 ;;; gnus-salt.el ends here