02b98f0e7a7b4f18c92f3acd85f2e64fc1864857
[gnus] / lisp / gnus-registry.el
1 ;;; gnus-registry.el --- article registry for Gnus
2
3 ;; Copyright (C) 2002-2011  Free Software Foundation, Inc.
4
5 ;; Author: Ted Zlatanov <tzz@lifelogs.com>
6 ;; Keywords: news registry
7
8 ;; This file is part of GNU Emacs.
9
10 ;; GNU Emacs is free software: you can redistribute it and/or modify
11 ;; it under the terms of the GNU General Public License as published by
12 ;; the Free Software Foundation, either version 3 of the License, or
13 ;; (at your option) any later version.
14
15 ;; GNU Emacs is distributed in the hope that it will be useful,
16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
18 ;; GNU General Public License for more details.
19
20 ;; You should have received a copy of the GNU General Public License
21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
22
23 ;;; Commentary:
24
25 ;; This is the gnus-registry.el package, which works with all
26 ;; Gnus backends, not just nnmail.  The major issue is that it
27 ;; doesn't go across backends, so for instance if an article is in
28 ;; nnml:sys and you see a reference to it in nnimap splitting, the
29 ;; article will end up in nnimap:sys
30
31 ;; gnus-registry.el intercepts article respooling, moving, deleting,
32 ;; and copying for all backends.  If it doesn't work correctly for
33 ;; you, submit a bug report and I'll be glad to fix it.  It needs
34 ;; documentation in the manual (also on my to-do list).
35
36 ;; Put this in your startup file (~/.gnus.el for instance)
37
38 ;; (setq gnus-registry-max-entries 2500)
39
40 ;; (gnus-registry-initialize)
41
42 ;; Then use this in your fancy-split:
43
44 ;; (: gnus-registry-split-fancy-with-parent)
45
46 ;; You should also consider using the nnregistry backend to look up
47 ;; articles.  See the Gnus manual for more information.
48
49 ;; TODO:
50
51 ;; - get the correct group on spool actions
52
53 ;; - articles that are spooled to a different backend should be moved
54 ;;   after splitting
55
56 ;;; Code:
57
58 (eval-when-compile (require 'cl))
59
60 (eval-when-compile
61   (when (null (require 'ert nil t))
62     (defmacro* ert-deftest (name () &body docstring-keys-and-body))))
63
64 (require 'ert nil t)
65 (require 'gnus)
66 (require 'gnus-int)
67 (require 'gnus-sum)
68 (require 'gnus-art)
69 (require 'gnus-util)
70 (require 'nnmail)
71 (require 'easymenu)
72 (require 'registry)
73
74 (defvar gnus-adaptive-word-syntax-table)
75
76 (defvar gnus-registry-dirty t
77  "Boolean set to t when the registry is modified")
78
79 (defgroup gnus-registry nil
80   "The Gnus registry."
81   :version "22.1"
82   :group 'gnus)
83
84 (defvar gnus-registry-marks
85   '((Important
86      :char ?i
87      :image "summary_important")
88     (Work
89      :char ?w
90      :image "summary_work")
91     (Personal
92      :char ?p
93      :image "summary_personal")
94     (To-Do
95      :char ?t
96      :image "summary_todo")
97     (Later
98      :char ?l
99      :image "summary_later"))
100
101   "List of registry marks and their options.
102
103 `gnus-registry-mark-article' will offer symbols from this list
104 for completion.
105
106 Each entry must have a character to be useful for summary mode
107 line display and for keyboard shortcuts.
108
109 Each entry must have an image string to be useful for visual
110 display.")
111
112 (defcustom gnus-registry-default-mark 'To-Do
113   "The default mark.  Should be a valid key for `gnus-registry-marks'."
114   :group 'gnus-registry
115   :type 'symbol)
116
117 (defcustom gnus-registry-unfollowed-addresses
118   (list (regexp-quote user-mail-address))
119   "List of addresses that gnus-registry-split-fancy-with-parent won't trace.
120 The addresses are matched, they don't have to be fully qualified."
121   :group 'gnus-registry
122   :type '(repeat regexp))
123
124 (defcustom gnus-registry-unfollowed-groups
125   '("delayed$" "drafts$" "queue$" "INBOX$" "^nnmairix:" "archive")
126   "List of groups that gnus-registry-split-fancy-with-parent won't return.
127 The group names are matched, they don't have to be fully
128 qualified.  This parameter tells the Gnus registry 'never split a
129 message into a group that matches one of these, regardless of
130 references.'
131
132 nnmairix groups are specifically excluded because they are ephemeral."
133   :group 'gnus-registry
134   :type '(repeat regexp))
135
136 (defcustom gnus-registry-install 'ask
137   "Whether the registry should be installed."
138   :group 'gnus-registry
139   :type '(choice (const :tag "Never Install" nil)
140                  (const :tag "Always Install" t)
141                  (const :tag "Ask Me" ask)))
142
143 (defvar gnus-summary-misc-menu) ;; Avoid byte compiler warning.
144
145 (defvar gnus-registry-misc-menus nil)   ; ugly way to keep the menus
146
147 (make-obsolete-variable 'gnus-registry-clean-empty nil "23.4")
148 (make-obsolete-variable 'gnus-registry-use-long-group-names nil "23.4")
149 (make-obsolete-variable 'gnus-registry-max-track-groups nil "23.4")
150 (make-obsolete-variable 'gnus-registry-entry-caching nil "23.4")
151 (make-obsolete-variable 'gnus-registry-trim-articles-without-groups nil "23.4")
152
153 (defcustom gnus-registry-track-extra '(subject sender)
154   "Whether the registry should track extra data about a message.
155 The Subject and Sender (From:) headers are tracked this way by
156 default."
157   :group 'gnus-registry
158   :type
159   '(set :tag "Tracking choices"
160     (const :tag "Track by subject (Subject: header)" subject)
161     (const :tag "Track by sender (From: header)"  sender)))
162
163 (defcustom gnus-registry-split-strategy nil
164   "The splitting strategy applied to the keys in `gnus-registry-track-extra'.
165
166 Given a set of unique found groups G and counts for each element
167 of G, and a key K (typically 'sender or 'subject):
168
169 When nil, if G has only one element, use it.  Otherwise give up.
170 This is the fastest but also least useful strategy.
171
172 When 'majority, use the majority by count.  So if there is a
173 group with the most articles counted by K, use that.  Ties are
174 resolved in no particular order, simply the first one found wins.
175 This is the slowest strategy but also the most accurate one.
176
177 When 'first, the first element of G wins.  This is fast and
178 should be OK if your senders and subjects don't \"bleed\" across
179 groups."
180   :group 'gnus-registry
181   :type
182   '(choice :tag "Splitting strategy"
183            (const :tag "Only use single choices, discard multiple matches" nil)
184            (const :tag "Majority of matches wins" majority)
185            (const :tag "First found wins"  first)))
186
187 (defcustom gnus-registry-minimum-subject-length 5
188   "The minimum length of a subject before it's considered trackable."
189   :group 'gnus-registry
190   :type 'integer)
191
192 (defcustom gnus-registry-extra-entries-precious '(mark)
193   "What extra keys are precious, meaning entries with them won't get pruned.
194 By default, 'mark is included, so articles with marks are
195 considered precious.
196
197 Before you save the Gnus registry, it's pruned.  Any entries with
198 keys in this list will not be pruned.  All other entries go to
199 the Bit Bucket."
200   :group 'gnus-registry
201   :type '(repeat symbol))
202
203 (defcustom gnus-registry-cache-file
204   (nnheader-concat
205    (or gnus-dribble-directory gnus-home-directory "~/")
206    ".gnus.registry.eioio")
207   "File where the Gnus registry will be stored."
208   :group 'gnus-registry
209   :type 'file)
210
211 (defcustom gnus-registry-max-entries nil
212   "Maximum number of entries in the registry, nil for unlimited."
213   :group 'gnus-registry
214   :type '(radio (const :format "Unlimited " nil)
215                 (integer :format "Maximum number: %v")))
216
217 (defcustom gnus-registry-max-pruned-entries nil
218   "Maximum number of pruned entries in the registry, nil for unlimited."
219   :group 'gnus-registry
220   :type '(radio (const :format "Unlimited " nil)
221                 (integer :format "Maximum number: %v")))
222
223 (defun gnus-registry-fixup-registry (db)
224   (when db
225     (oset db :precious
226           (append gnus-registry-extra-entries-precious
227                   '()))
228     (oset db :max-hard
229           (or gnus-registry-max-entries
230               most-positive-fixnum))
231     (oset db :max-soft
232           (or gnus-registry-max-pruned-entries
233               most-positive-fixnum))
234     (oset db :tracked
235           (append gnus-registry-track-extra
236                   '(mark group keyword))))
237   db)
238
239 (defun gnus-registry-make-db (&optional file)
240   (interactive "fGnus registry persistence file: \n")
241   (gnus-registry-fixup-registry
242    (registry-db
243     "Gnus Registry"
244     :file (or file gnus-registry-cache-file)
245     ;; these parameters are set in `gnus-registry-fixup-registry'
246     :max-hard most-positive-fixnum
247     :max-soft most-positive-fixnum
248     :precious nil
249     :tracked nil)))
250
251 (defvar gnus-registry-db (gnus-registry-make-db)
252   "*The article registry by Message ID.  See `registry-db'")
253
254 ;; top-level registry data management
255 (defun gnus-registry-remake-db (&optional forsure)
256   "Remake the registry database after customization.
257 This is not required after changing `gnus-registry-cache-file'."
258   (interactive (list (y-or-n-p "Remake and CLEAR the Gnus registry? ")))
259   (when forsure
260     (gnus-message 1 "Remaking the Gnus registry")
261     (setq gnus-registry-db (gnus-registry-make-db))))
262
263 (defun gnus-registry-read ()
264   "Read the registry cache file."
265   (interactive)
266   (let ((file gnus-registry-cache-file))
267     (condition-case nil
268         (progn
269           (gnus-message 5 "Reading Gnus registry from %s..." file)
270           (setq gnus-registry-db (gnus-registry-fixup-registry
271                                   (eieio-persistent-read file)))
272           (gnus-message 5 "Reading Gnus registry from %s...done" file))
273       (error
274        (gnus-message
275         1
276         "The Gnus registry could not be loaded from %s, creating a new one"
277         file)
278        (gnus-registry-remake-db t)))))
279
280 (defun gnus-registry-save (&optional file db)
281   "Save the registry cache file."
282   (interactive)
283   (let ((file (or file gnus-registry-cache-file))
284         (db (or db gnus-registry-db)))
285     (gnus-message 5 "Saving Gnus registry (%d entries) to %s..."
286                   (registry-size db) file)
287     (registry-prune db)
288     ;; TODO: call (gnus-string-remove-all-properties v) on all elements?
289     (eieio-persistent-save db file)
290     (gnus-message 5 "Saving Gnus registry (size %d) to %s...done"
291                   (registry-size db) file)))
292
293 ;; article move/copy/spool/delete actions
294 (defun gnus-registry-action (action data-header from &optional to method)
295   (let* ((id (mail-header-id data-header))
296          (subject (gnus-string-remove-all-properties
297                    (gnus-registry-simplify-subject
298                     (mail-header-subject data-header))))
299          (sender (gnus-string-remove-all-properties
300                   (mail-header-from data-header)))
301          (from (gnus-group-guess-full-name-from-command-method from))
302          (to (if to (gnus-group-guess-full-name-from-command-method to) nil))
303          (to-name (if to to "the Bit Bucket")))
304     (gnus-message 7 "Gnus registry: article %s %s from %s to %s"
305                   id (if method "respooling" "going") from to)
306
307     (gnus-registry-handle-action
308      id
309      ;; unless copying, remove the old "from" group
310      (if (not (equal 'copy action)) from nil)
311      to subject sender)))
312
313 (defun gnus-registry-spool-action (id group &optional subject sender)
314   (let ((to (gnus-group-guess-full-name-from-command-method group)))
315     (when (and (stringp id) (string-match "\r$" id))
316       (setq id (substring id 0 -1)))
317     (gnus-message 7 "Gnus registry: article %s spooled to %s"
318                   id
319                   to)
320     (gnus-registry-handle-action id nil to subject sender)))
321
322 (defun gnus-registry-handle-action (id from to subject sender)
323   (let ((db gnus-registry-db)
324         ;; safe if not found
325         (entry (gnus-registry-get-or-make-entry id)))
326
327     ;; this could be done by calling `gnus-registry-set-id-key'
328     ;; several times but it's better to bunch the transactions
329     ;; together
330
331     (registry-delete db (list id) nil)
332     (when from
333       (setq entry (cons (delete from (assoc 'group entry))
334                         (assq-delete-all 'group entry))))
335
336     (dolist (kv `((group ,to) (sender ,sender) (subject ,subject)))
337       (when (second kv)
338         (let ((new (or (assq (first kv) entry)
339                        (list (first kv)))))
340           (add-to-list 'new (second kv) t)
341           (setq entry (cons new
342                             (assq-delete-all (first kv) entry))))))
343     (gnus-message 10 "Gnus registry: new entry for %s is %S"
344                   id
345                   entry)
346     (registry-insert db id entry)))
347
348 ;; Function for nn{mail|imap}-split-fancy: look up all references in
349 ;; the cache and if a match is found, return that group.
350 (defun gnus-registry-split-fancy-with-parent ()
351   "Split this message into the same group as its parent.  The parent
352 is obtained from the registry.  This function can be used as an entry
353 in `nnmail-split-fancy' or `nnimap-split-fancy', for example like
354 this: (: gnus-registry-split-fancy-with-parent)
355
356 This function tracks ALL backends, unlike
357 `nnmail-split-fancy-with-parent' which tracks only nnmail
358 messages.
359
360 For a message to be split, it looks for the parent message in the
361 References or In-Reply-To header and then looks in the registry
362 to see which group that message was put in.  This group is
363 returned, unless `gnus-registry-follow-group-p' return nil for
364 that group.
365
366 See the Info node `(gnus)Fancy Mail Splitting' for more details."
367   (let* ((refstr (or (message-fetch-field "references") "")) ; guaranteed
368          (reply-to (message-fetch-field "in-reply-to"))      ; may be nil
369          ;; now, if reply-to is valid, append it to the References
370          (refstr (if reply-to
371                      (concat refstr " " reply-to)
372                    refstr))
373          (references (and refstr (gnus-extract-references refstr)))
374          ;; these may not be used, but the code is cleaner having them up here
375          (sender (gnus-string-remove-all-properties
376                   (message-fetch-field "from")))
377          (subject (gnus-string-remove-all-properties
378                    (gnus-registry-simplify-subject
379                     (message-fetch-field "subject"))))
380
381          (nnmail-split-fancy-with-parent-ignore-groups
382           (if (listp nnmail-split-fancy-with-parent-ignore-groups)
383               nnmail-split-fancy-with-parent-ignore-groups
384             (list nnmail-split-fancy-with-parent-ignore-groups))))
385     (gnus-registry--split-fancy-with-parent-internal
386      :references references
387      :refstr refstr
388      :sender sender
389      :subject subject
390      :log-agent "Gnus registry fancy splitting with parent")))
391
392 (defun* gnus-registry--split-fancy-with-parent-internal
393     (&rest spec
394            &key references refstr sender subject log-agent
395            &allow-other-keys)
396   (gnus-message
397    10
398    "gnus-registry--split-fancy-with-parent-internal %S" spec)
399   (let ((db gnus-registry-db)
400         found)
401     ;; this is a big chain of statements.  it uses
402     ;; gnus-registry-post-process-groups to filter the results after
403     ;; every step.
404     ;; the references string must be valid and parse to valid references
405     (when references
406       (gnus-message
407        9
408        "%s is tracing references %s"
409        log-agent refstr)
410       (dolist (reference (nreverse references))
411         (gnus-message 9 "%s is looking up %s" log-agent reference)
412         (loop for group in (gnus-registry-get-id-key reference 'group)
413               when (gnus-registry-follow-group-p group)
414               do (gnus-message 7 "%s traced %s to %s" log-agent reference group)
415               do (push group found)))
416       ;; filter the found groups and return them
417       ;; the found groups are the full groups
418       (setq found (gnus-registry-post-process-groups
419                    "references" refstr found)))
420
421      ;; else: there were no matches, try the extra tracking by sender
422      (when (and (null found)
423                 (memq 'sender gnus-registry-track-extra)
424                 sender
425                 (gnus-grep-in-list
426                  sender
427                  gnus-registry-unfollowed-addresses))
428        (let ((groups (apply
429                       'append
430                       (mapcar
431                        (lambda (reference)
432                          (gnus-registry-get-id-key reference 'group))
433                        (registry-lookup-secondary-value db 'sender sender)))))
434          (setq found
435                (loop for group in groups
436                      when (gnus-registry-follow-group-p group)
437                      do (gnus-message
438                          ;; warn more if gnus-registry-track-extra
439                          (if gnus-registry-track-extra 7 9)
440                          "%s (extra tracking) traced sender '%s' to %s"
441                          log-agent sender group)
442                      collect group)))
443
444        ;; filter the found groups and return them
445        ;; the found groups are NOT the full groups
446        (setq found (gnus-registry-post-process-groups
447                     "sender" sender found)))
448
449      ;; else: there were no matches, now try the extra tracking by subject
450      (when (and (null found)
451                 (memq 'subject gnus-registry-track-extra)
452                 subject
453                 (< gnus-registry-minimum-subject-length (length subject)))
454        (let ((groups (apply
455                       'append
456                       (mapcar
457                        (lambda (reference)
458                          (gnus-registry-get-id-key reference 'group))
459                        (registry-lookup-secondary-value db 'subject subject)))))
460          (setq found
461                (loop for group in groups
462                      when (gnus-registry-follow-group-p group)
463                      do (gnus-message
464                          ;; warn more if gnus-registry-track-extra
465                          (if gnus-registry-track-extra 7 9)
466                          "%s (extra tracking) traced subject '%s' to %s"
467                          log-agent subject group)
468                      collect group))
469          ;; filter the found groups and return them
470          ;; the found groups are NOT the full groups
471          (setq found (gnus-registry-post-process-groups
472                       "subject" subject found))))
473      ;; after the (cond) we extract the actual value safely
474      (car-safe found)))
475
476 (defun gnus-registry-post-process-groups (mode key groups)
477   "Inspects GROUPS found by MODE for KEY to determine which ones to follow.
478
479 MODE can be 'subject' or 'sender' for example.  The KEY is the
480 value by which MODE was searched.
481
482 Transforms each group name to the equivalent short name.
483
484 Checks if the current Gnus method (from `gnus-command-method' or
485 from `gnus-newsgroup-name') is the same as the group's method.
486 Foreign methods are not supported so they are rejected.
487
488 Reduces the list to a single group, or complains if that's not
489 possible.  Uses `gnus-registry-split-strategy'."
490   (let ((log-agent "gnus-registry-post-process-group")
491         (desc (format "%d groups" (length groups)))
492         out chosen)
493     ;; the strategy can be nil, in which case chosen is nil
494     (setq chosen
495           (case gnus-registry-split-strategy
496             ;; default, take only one-element lists into chosen
497             ((nil)
498              (and (= (length groups) 1)
499                   (car-safe groups)))
500
501             ((first)
502              (car-safe groups))
503
504             ((majority)
505              (let ((freq (make-hash-table
506                           :size 256
507                           :test 'equal)))
508                (mapc (lambda (x) (let ((x (gnus-group-short-name x)))
509                               (puthash x (1+ (gethash x freq 0)) freq)))
510                      groups)
511                (setq desc (format "%d groups, %d unique"
512                                   (length groups)
513                                   (hash-table-count freq)))
514                (car-safe
515                 (sort groups
516                       (lambda (a b)
517                         (> (gethash (gnus-group-short-name a) freq 0)
518                            (gethash (gnus-group-short-name b) freq 0)))))))))
519
520     (if chosen
521         (gnus-message
522          9
523          "%s: strategy %s on %s produced %s"
524          log-agent gnus-registry-split-strategy desc chosen)
525       (gnus-message
526        9
527        "%s: strategy %s on %s did not produce an answer"
528        log-agent
529        (or gnus-registry-split-strategy "default")
530        desc))
531
532     (setq groups (and chosen (list chosen)))
533
534     (dolist (group groups)
535       (let ((m1 (gnus-find-method-for-group group))
536             (m2 (or gnus-command-method
537                     (gnus-find-method-for-group gnus-newsgroup-name)))
538             (short-name (gnus-group-short-name group)))
539         (if (gnus-methods-equal-p m1 m2)
540             (progn
541               ;; this is REALLY just for debugging
542               (when (not (equal group short-name))
543                 (gnus-message
544                  10
545                  "%s: stripped group %s to %s"
546                  log-agent group short-name))
547               (add-to-list 'out short-name))
548           ;; else...
549           (gnus-message
550            7
551            "%s: ignored foreign group %s"
552            log-agent group))))
553
554     (setq out (delq nil out))
555
556     (cond
557      ((= (length out) 1) out)
558      ((null out)
559       (gnus-message
560        5
561        "%s: no matches for %s %s."
562        log-agent out mode key)
563       nil)
564      (t (gnus-message
565          5
566          "%s: too many extra matches (%s) for %s %s.  Returning none."
567          log-agent out mode key)
568         nil))))
569
570 (defun gnus-registry-follow-group-p (group)
571   "Determines if a group name should be followed.
572 Consults `gnus-registry-unfollowed-groups' and
573 `nnmail-split-fancy-with-parent-ignore-groups'."
574   (and group
575        (not (or (gnus-grep-in-list
576                  group
577                  gnus-registry-unfollowed-groups)
578                 (gnus-grep-in-list
579                  group
580                  nnmail-split-fancy-with-parent-ignore-groups)))))
581
582 (defun gnus-registry-wash-for-keywords (&optional force)
583   "Get the keywords of the current article.
584 Overrides existing keywords with FORCE set non-nil."
585   (interactive)
586   (let ((id (gnus-registry-fetch-message-id-fast gnus-current-article))
587         word words)
588     (if (or (not (gnus-registry-get-id-key id 'keyword))
589             force)
590         (with-current-buffer gnus-article-buffer
591           (article-goto-body)
592           (save-window-excursion
593             (save-restriction
594               (narrow-to-region (point) (point-max))
595               (with-syntax-table gnus-adaptive-word-syntax-table
596                 (while (re-search-forward "\\b\\w+\\b" nil t)
597                   (setq word (gnus-string-remove-all-properties
598                               (downcase (buffer-substring
599                                          (match-beginning 0) (match-end 0)))))
600                   (if (> (length word) 2)
601                       (push word words))))))
602           (gnus-registry-set-id-key id 'keyword words)))))
603
604 (defun gnus-registry-keywords ()
605   (let ((table (registry-lookup-secondary gnus-registry-db 'keyword)))
606     (when table (maphash (lambda (k v) k) table))))
607
608 (defun gnus-registry-find-keywords (keyword)
609   (interactive (list
610                 (completing-read "Keyword: " (gnus-registry-keywords) nil t)))
611   (registry-lookup-secondary-value gnus-registry-db 'keyword keyword))
612
613 (defun gnus-registry-register-message-ids ()
614   "Register the Message-ID of every article in the group"
615   (unless (gnus-parameter-registry-ignore gnus-newsgroup-name)
616     (dolist (article gnus-newsgroup-articles)
617       (let* ((id (gnus-registry-fetch-message-id-fast article))
618              (groups (gnus-registry-get-id-key id 'group)))
619         (unless (member gnus-newsgroup-name groups)
620           (gnus-message 9 "Registry: Registering article %d with group %s"
621                         article gnus-newsgroup-name)
622           (gnus-registry-handle-action id nil gnus-newsgroup-name
623            (gnus-registry-fetch-simplified-message-subject-fast article)
624            (gnus-registry-fetch-sender-fast article)))))))
625
626 ;; message field fetchers
627 (defun gnus-registry-fetch-message-id-fast (article)
628   "Fetch the Message-ID quickly, using the internal gnus-data-list function"
629   (if (and (numberp article)
630            (assoc article (gnus-data-list nil)))
631       (mail-header-id (gnus-data-header (assoc article (gnus-data-list nil))))
632     nil))
633
634 (defun gnus-registry-simplify-subject (subject)
635   (if (stringp subject)
636       (gnus-simplify-subject subject)
637     nil))
638
639 (defun gnus-registry-fetch-simplified-message-subject-fast (article)
640   "Fetch the Subject quickly, using the internal gnus-data-list function"
641   (if (and (numberp article)
642            (assoc article (gnus-data-list nil)))
643       (gnus-string-remove-all-properties
644        (gnus-registry-simplify-subject
645         (mail-header-subject (gnus-data-header
646                               (assoc article (gnus-data-list nil))))))
647     nil))
648
649 (defun gnus-registry-fetch-sender-fast (article)
650   "Fetch the Sender quickly, using the internal gnus-data-list function"
651   (if (and (numberp article)
652            (assoc article (gnus-data-list nil)))
653       (gnus-string-remove-all-properties
654        (mail-header-from (gnus-data-header
655                           (assoc article (gnus-data-list nil)))))
656     nil))
657
658 ;; registry marks glue
659 (defun gnus-registry-do-marks (type function)
660   "For each known mark, call FUNCTION for each cell of type TYPE.
661
662 FUNCTION should take two parameters, a mark symbol and the cell value."
663   (dolist (mark-info gnus-registry-marks)
664     (let* ((mark (car-safe mark-info))
665            (data (cdr-safe mark-info))
666            (cell-data (plist-get data type)))
667       (when cell-data
668         (funcall function mark cell-data)))))
669
670 ;;; this is ugly code, but I don't know how to do it better
671 (defun gnus-registry-install-shortcuts ()
672   "Install the keyboard shortcuts and menus for the registry.
673 Uses `gnus-registry-marks' to find what shortcuts to install."
674   (let (keys-plist)
675     (setq gnus-registry-misc-menus nil)
676     (gnus-registry-do-marks
677      :char
678      (lambda (mark data)
679        (let ((function-format
680               (format "gnus-registry-%%s-article-%s-mark" mark)))
681
682 ;;; The following generates these functions:
683 ;;; (defun gnus-registry-set-article-Important-mark (&rest articles)
684 ;;;   "Apply the Important mark to process-marked ARTICLES."
685 ;;;   (interactive (gnus-summary-work-articles current-prefix-arg))
686 ;;;   (gnus-registry-set-article-mark-internal 'Important articles nil t))
687 ;;; (defun gnus-registry-remove-article-Important-mark (&rest articles)
688 ;;;   "Apply the Important mark to process-marked ARTICLES."
689 ;;;   (interactive (gnus-summary-work-articles current-prefix-arg))
690 ;;;   (gnus-registry-set-article-mark-internal 'Important articles t t))
691
692          (dolist (remove '(t nil))
693            (let* ((variant-name (if remove "remove" "set"))
694                   (function-name (format function-format variant-name))
695                   (shortcut (format "%c" data))
696                   (shortcut (if remove (upcase shortcut) shortcut)))
697              (unintern function-name obarray)
698              (eval
699               `(defun
700                  ;; function name
701                  ,(intern function-name)
702                  ;; parameter definition
703                  (&rest articles)
704                  ;; documentation
705                  ,(format
706                    "%s the %s mark over process-marked ARTICLES."
707                    (upcase-initials variant-name)
708                    mark)
709                  ;; interactive definition
710                  (interactive
711                   (gnus-summary-work-articles current-prefix-arg))
712                  ;; actual code
713
714                  ;; if this is called and the user doesn't want the
715                  ;; registry enabled, we'll ask anyhow
716                  (when (eq gnus-registry-install nil)
717                    (setq gnus-registry-install 'ask))
718
719                  ;; now the user is asked if gnus-registry-install is 'ask
720                  (when (gnus-registry-install-p)
721                    (gnus-registry-set-article-mark-internal
722                     ;; all this just to get the mark, I must be doing it wrong
723                     (intern ,(symbol-name mark))
724                     articles ,remove t)
725                    (gnus-message
726                     9
727                     "Applying mark %s to %d articles"
728                     ,(symbol-name mark) (length articles))
729                    (dolist (article articles)
730                      (gnus-summary-update-article
731                       article
732                       (assoc article (gnus-data-list nil)))))))
733              (push (intern function-name) keys-plist)
734              (push shortcut keys-plist)
735              (push (vector (format "%s %s"
736                                    (upcase-initials variant-name)
737                                    (symbol-name mark))
738                            (intern function-name) t)
739                    gnus-registry-misc-menus)
740              (gnus-message
741               9
742               "Defined mark handling function %s"
743               function-name))))))
744     (gnus-define-keys-1
745      '(gnus-registry-mark-map "M" gnus-summary-mark-map)
746      keys-plist)
747     (add-hook 'gnus-summary-menu-hook
748               (lambda ()
749                 (easy-menu-add-item
750                  gnus-summary-misc-menu
751                  nil
752                  (cons "Registry Marks" gnus-registry-misc-menus))))))
753
754 ;;; use like this:
755 ;;; (defalias 'gnus-user-format-function-M
756 ;;;           'gnus-registry-user-format-function-M)
757 (defun gnus-registry-user-format-function-M (headers)
758   (let* ((id (mail-header-message-id headers))
759          (marks (when id (gnus-registry-get-id-key id 'mark))))
760     (apply 'concat (mapcar (lambda (mark)
761                              (let ((c
762                                     (plist-get
763                                      (cdr-safe
764                                       (assoc mark gnus-registry-marks))
765                                      :char)))
766                                (if c
767                                    (list c)
768                                  nil)))
769                            marks))))
770
771 (defun gnus-registry-read-mark ()
772   "Read a mark name from the user with completion."
773   (let ((mark (gnus-completing-read
774                "Label"
775                (mapcar 'symbol-name (mapcar 'car gnus-registry-marks))
776                nil nil nil
777                (symbol-name gnus-registry-default-mark))))
778     (when (stringp mark)
779       (intern mark))))
780
781 (defun gnus-registry-set-article-mark (&rest articles)
782   "Apply a mark to process-marked ARTICLES."
783   (interactive (gnus-summary-work-articles current-prefix-arg))
784   (gnus-registry-set-article-mark-internal (gnus-registry-read-mark)
785                                            articles nil t))
786
787 (defun gnus-registry-remove-article-mark (&rest articles)
788   "Remove a mark from process-marked ARTICLES."
789   (interactive (gnus-summary-work-articles current-prefix-arg))
790   (gnus-registry-set-article-mark-internal (gnus-registry-read-mark)
791                                            articles t t))
792
793 (defun gnus-registry-set-article-mark-internal (mark
794                                                 articles
795                                                 &optional remove
796                                                 show-message)
797   "Apply or remove MARK across a list of ARTICLES."
798   (let ((article-id-list
799          (mapcar 'gnus-registry-fetch-message-id-fast articles)))
800     (dolist (id article-id-list)
801       (let* ((marks (delq mark (gnus-registry-get-id-key id 'mark)))
802              (marks (if remove marks (cons mark marks))))
803         (when show-message
804           (gnus-message 1 "%s mark %s with message ID %s, resulting in %S"
805                         (if remove "Removing" "Adding")
806                         mark id marks))
807         (gnus-registry-set-id-key id 'mark marks)))))
808
809 (defun gnus-registry-get-article-marks (&rest articles)
810   "Get the Gnus registry marks for ARTICLES and show them if interactive.
811 Uses process/prefix conventions.  For multiple articles,
812 only the last one's marks are returned."
813   (interactive (gnus-summary-work-articles 1))
814   (let* ((article (last articles))
815          (id (gnus-registry-fetch-message-id-fast article))
816          (marks (when id (gnus-registry-get-id-key id 'mark))))
817     (when (interactive-p)
818       (gnus-message 1 "Marks are %S" marks))
819     marks))
820
821 (defun gnus-registry-group-count (id)
822   "Get the number of groups of a message, based on the message ID."
823   (length (gnus-registry-get-id-key id 'group)))
824
825 (defun gnus-registry-get-or-make-entry (id)
826   (let* ((db gnus-registry-db)
827          ;; safe if not found
828          (entries (registry-lookup db (list id))))
829
830     (when (null entries)
831       (registry-insert db id (list (list 'creation-time (current-time))
832                                    '(group) '(sender) '(subject)))
833       (setq entries (registry-lookup db (list id))))
834
835     (nth 1 (assoc id entries))))
836
837 (defun gnus-registry-delete-entries (idlist)
838   (registry-delete gnus-registry-db idlist nil))
839
840 (defun gnus-registry-get-id-key (id key)
841   (cdr-safe (assq key (gnus-registry-get-or-make-entry id))))
842
843 (defun gnus-registry-set-id-key (id key vals)
844   (let* ((db gnus-registry-db)
845          (entry (gnus-registry-get-or-make-entry id)))
846     (registry-delete db (list id) nil)
847     (setq entry (cons (cons key vals) (assq-delete-all key entry)))
848     (registry-insert db id entry)
849     entry))
850
851 (defun gnus-registry-import-eld (file)
852   (interactive "fOld registry file to import? ")
853   ;; example content:
854   ;;   (setq gnus-registry-alist '(
855   ;; ("<messageID>" ((marks nil)
856   ;;                 (mtime 19365 1776 440496)
857   ;;                 (sender . "root (Cron Daemon)")
858   ;;                 (subject . "Cron"))
859   ;;  "cron" "nnml+private:cron")
860   (load file t)
861   (when (boundp 'gnus-registry-alist)
862     (let* ((old (symbol-value 'gnus-registry-alist))
863            (count 0)
864            (expected (length old))
865            entry)
866       (while (car-safe old)
867         (incf count)
868         ;; don't use progress reporters for backwards compatibility
869         (when (and (< 0 expected)
870                    (= 0 (mod count 100)))
871           (message "importing: %d of %d (%.2f%%)"
872                    count expected (/ (* 100 count) expected)))
873         (setq entry (car-safe old)
874               old (cdr-safe old))
875         (let* ((id (car-safe entry))
876                (new-entry (gnus-registry-get-or-make-entry id))
877                (rest (cdr-safe entry))
878                (groups (loop for p in rest
879                              when (stringp p)
880                              collect p))
881                extra-cell key val)
882           ;; remove all the strings from the entry
883           (delete* nil rest :test (lambda (a b) (stringp b)))
884           (gnus-registry-set-id-key id 'group groups)
885           ;; just use the first extra element
886           (setq rest (car-safe rest))
887           (while (car-safe rest)
888             (setq extra-cell (car-safe rest)
889                   key (car-safe extra-cell)
890                   val (cdr-safe extra-cell)
891                   rest (cdr-safe rest))
892             (when (and val (atom val))
893               (setq val (list val)))
894             (gnus-registry-set-id-key id key val))))
895       (message "Import done, collected %d entries" count))))
896
897 (ert-deftest gnus-registry-usage-test ()
898   (let* ((n 100)
899          (tempfile (make-temp-file "gnus-registry-persist"))
900          (db (gnus-registry-make-db tempfile))
901          (gnus-registry-db db)
902          back size)
903     (message "Adding %d keys to the test Gnus registry" n)
904     (dotimes (i n)
905       (let ((id (number-to-string i)))
906         (gnus-registry-handle-action id
907                                      (if (>= 50 i) "fromgroup" nil)
908                                      "togroup"
909                                      (when (>= 70 i)
910                                        (format "subject %d" (mod i 10)))
911                                      (when (>= 80 i)
912                                        (format "sender %d" (mod i 10))))))
913     (message "Testing Gnus registry size is %d" n)
914     (should (= n (registry-size db)))
915     (message "Looking up individual keys (registry-lookup)")
916     (should (equal (loop for e
917                          in (mapcar 'cadr
918                                     (registry-lookup db '("20" "83" "72")))
919                          collect (assq 'subject e)
920                          collect (assq 'sender e)
921                          collect (assq 'group e))
922                    '((subject "subject 0") (sender "sender 0") (group "togroup")
923                      (subject) (sender) (group "togroup")
924                      (subject) (sender "sender 2") (group "togroup"))))
925
926     (message "Looking up individual keys (gnus-registry-id-key)")
927     (should (equal (gnus-registry-get-id-key "34" 'group) '("togroup")))
928     (should (equal (gnus-registry-get-id-key "34" 'subject) '("subject 4")))
929     (message "Trying to insert a duplicate key")
930     (should-error (registry-insert db "55" '()))
931     (message "Looking up individual keys (gnus-registry-get-or-make-entry)")
932     (should (gnus-registry-get-or-make-entry "22"))
933     (message "Saving the Gnus registry to %s" tempfile)
934     (should (gnus-registry-save tempfile db))
935     (setq size (nth 7 (file-attributes tempfile)))
936     (message "Saving the Gnus registry to %s: size %d" tempfile size)
937     (should (< 0 size))
938     (with-temp-buffer
939       (insert-file-contents-literally tempfile)
940       (should (looking-at (concat ";; Object "
941                                   "Gnus Registry"
942                                   "\n;; EIEIO PERSISTENT OBJECT"))))
943     (message "Reading Gnus registry back")
944     (setq back (eieio-persistent-read tempfile))
945     (should back)
946     (message "Read Gnus registry back: %d keys, expected %d==%d"
947              (registry-size back) n (registry-size db))
948     (should (= (registry-size back) n))
949     (should (= (registry-size back) (registry-size db)))
950     (delete-file tempfile)
951     (message "Pruning Gnus registry to 0 by setting :max-soft")
952     (oset db :max-soft 0)
953     (registry-prune db)
954     (should (= (registry-size db) 0)))
955   (message "Done with Gnus registry usage testing."))
956
957 ;;;###autoload
958 (defun gnus-registry-initialize ()
959 "Initialize the Gnus registry."
960   (interactive)
961   (gnus-message 5 "Initializing the registry")
962   (setq gnus-registry-install t)        ; in case it was 'ask or nil
963   (gnus-registry-install-hooks)
964   (gnus-registry-install-shortcuts)
965   (gnus-registry-read))
966
967 ;;;###autoload
968 (defun gnus-registry-install-hooks ()
969   "Install the registry hooks."
970   (interactive)
971   (add-hook 'gnus-summary-article-move-hook 'gnus-registry-action)
972   (add-hook 'gnus-summary-article-delete-hook 'gnus-registry-action)
973   (add-hook 'gnus-summary-article-expire-hook 'gnus-registry-action)
974   (add-hook 'nnmail-spool-hook 'gnus-registry-spool-action)
975
976   (add-hook 'gnus-save-newsrc-hook 'gnus-registry-save)
977   (add-hook 'gnus-read-newsrc-el-hook 'gnus-registry-read)
978
979   (add-hook 'gnus-summary-prepare-hook 'gnus-registry-register-message-ids))
980
981 (defun gnus-registry-unload-hook ()
982   "Uninstall the registry hooks."
983   (interactive)
984   (remove-hook 'gnus-summary-article-move-hook 'gnus-registry-action)
985   (remove-hook 'gnus-summary-article-delete-hook 'gnus-registry-action)
986   (remove-hook 'gnus-summary-article-expire-hook 'gnus-registry-action)
987   (remove-hook 'nnmail-spool-hook 'gnus-registry-spool-action)
988
989   (remove-hook 'gnus-save-newsrc-hook 'gnus-registry-save)
990   (remove-hook 'gnus-read-newsrc-el-hook 'gnus-registry-read)
991
992   (remove-hook 'gnus-summary-prepare-hook 'gnus-registry-register-message-ids))
993
994 (add-hook 'gnus-registry-unload-hook 'gnus-registry-unload-hook)
995
996 (defun gnus-registry-install-p ()
997   (interactive)
998   (when (eq gnus-registry-install 'ask)
999     (setq gnus-registry-install
1000           (gnus-y-or-n-p
1001            (concat "Enable the Gnus registry?  "
1002                    "See the variable `gnus-registry-install' "
1003                    "to get rid of this query permanently. ")))
1004     (when gnus-registry-install
1005       ;; we just set gnus-registry-install to t, so initialize the registry!
1006       (gnus-registry-initialize)))
1007 ;;; we could call it here: (customize-variable 'gnus-registry-install)
1008   gnus-registry-install)
1009
1010 ;; TODO: a few things
1011
1012 (provide 'gnus-registry)
1013
1014 ;;; gnus-registry.el ends here