cgit.sxemacs.org Git - gnus/blob - lisp/gnus-range.el

   1 ;;; gnus-range.el --- range and sequence functions for Gnus
   2
   3 ;; Copyright (C) 1996, 1997, 1998, 1999, 2000, 2001, 2002
   4 ;;        Free Software Foundation, Inc.
   5
   6 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   7 ;; Keywords: news
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;;; Code:
  29
  30 (eval-when-compile (require 'cl))
  31
  32 ;;; List and range functions
  33
  34 (defsubst gnus-range-normalize (range)
  35   "Normalize RANGE.
  36 If RANGE is a single range, return (RANGE). Otherwise, return RANGE."
  37   (if (listp (cdr-safe range)) range (list range)))
  38
  39 (defun gnus-last-element (list)
  40   "Return last element of LIST."
  41   (while (cdr list)
  42     (setq list (cdr list)))
  43   (car list))
  44
  45 (defun gnus-copy-sequence (list)
  46   "Do a complete, total copy of a list."
  47   (let (out)
  48     (while (consp list)
  49       (if (consp (car list))
  50           (push (gnus-copy-sequence (pop list)) out)
  51         (push (pop list) out)))
  52     (if list
  53         (nconc (nreverse out) list)
  54       (nreverse out))))
  55
  56 (defun gnus-set-difference (list1 list2)
  57   "Return a list of elements of LIST1 that do not appear in LIST2."
  58   (let ((list1 (copy-sequence list1)))
  59     (while list2
  60       (setq list1 (delq (car list2) list1))
  61       (setq list2 (cdr list2)))
  62     list1))
  63
  64 (defun gnus-sorted-complement (list1 list2)
  65   "Return a list of elements that are in LIST1 or LIST2 but not both.
  66 Both lists have to be sorted over <."
  67   (let (out)
  68     (if (or (null list1) (null list2))
  69         (or list1 list2)
  70       (while (and list1 list2)
  71         (cond ((= (car list1) (car list2))
  72                (setq list1 (cdr list1)
  73                      list2 (cdr list2)))
  74               ((< (car list1) (car list2))
  75                (setq out (cons (car list1) out))
  76                (setq list1 (cdr list1)))
  77               (t
  78                (setq out (cons (car list2) out))
  79                (setq list2 (cdr list2)))))
  80       (nconc (nreverse out) (or list1 list2)))))
  81
  82 (defun gnus-intersection (list1 list2)
  83   (let ((result nil))
  84     (while list2
  85       (when (memq (car list2) list1)
  86         (setq result (cons (car list2) result)))
  87       (setq list2 (cdr list2)))
  88     result))
  89
  90 (defun gnus-sorted-intersection (list1 list2)
  91   "Return intersection of LIST1 and LIST2.
  92 LIST1 and LIST2 have to be sorted over <."
  93   (let (out)
  94     (while (and list1 list2)
  95       (cond ((= (car list1) (car list2))
  96              (setq out (cons (car list1) out)
  97                    list1 (cdr list1)
  98                    list2 (cdr list2)))
  99             ((< (car list1) (car list2))
 100              (setq list1 (cdr list1)))
 101             (t
 102              (setq list2 (cdr list2)))))
 103     (nreverse out)))
 104
 105 (defun gnus-set-sorted-intersection (list1 list2)
 106   "Return intersection of LIST1 and LIST2 by modifying cdr pointers of LIST1.
 107 LIST1 and LIST2 have to be sorted over <."
 108   (let* ((top (cons nil list1))
 109          (prev top))
 110     (while (and list1 list2)
 111       (cond ((= (car list1) (car list2))
 112              (setq prev list1
 113                    list1 (cdr list1)
 114                    list2 (cdr list2)))
 115             ((< (car list1) (car list2))
 116              (setcdr prev (cdr list1))
 117              (setq list1 (cdr list1)))
 118             (t
 119              (setq list2 (cdr list2)))))
 120     (setcdr prev nil)
 121     (cdr top)))
 122
 123 (defun gnus-sorted-union (list1 list2)
 124   "Return union of LIST1 and LIST2.
 125 LIST1 and LIST2 have to be sorted over <."
 126   (let (out)
 127     (while (and list1 list2)
 128       (cond ((= (car list1) (car list2))
 129              (setq out (cons (car list1) out)
 130                    list1 (cdr list1)
 131                    list2 (cdr list2)))
 132             ((< (car list1) (car list2))
 133              (setq out (cons (car list1) out)
 134                    list1 (cdr list1)))
 135             (t
 136              (setq out (cons (car list2) out)
 137                    list2 (cdr list2)))))
 138     (while list1
 139       (setq out (cons (car list1) out)
 140             list1 (cdr list1)))
 141     (while list2
 142       (setq out (cons (car list2) out)
 143             list2 (cdr list2)))
 144     (nreverse out)))
 145
 146 (defun gnus-set-sorted-union (list1 list2)
 147   "Return union of LIST1 and LIST2 by modifying cdr pointers of LIST1.
 148 LIST1 and LIST2 have to be sorted over <."
 149   (let* ((top (cons nil list1))
 150          (prev top))
 151     (while (and list1 list2)
 152       (cond ((= (car list1) (car list2))
 153              (setq prev list1
 154                    list1 (cdr list1)
 155                    list2 (cdr list2)))
 156             ((< (car list1) (car list2))
 157              (setq prev list1
 158                    list1 (cdr list1)))
 159             (t
 160              (setcdr prev (list (car list2)))
 161              (setq prev (cdr prev)
 162                    list2 (cdr list2))
 163              (setcdr prev list1))))
 164     (while list2
 165       (setcdr prev (list (car list2)))
 166       (setq prev (cdr prev)
 167             list2 (cdr list2)))
 168     (cdr top)))
 169
 170 (defun gnus-compress-sequence (numbers &optional always-list)
 171   "Convert list of numbers to a list of ranges or a single range.
 172 If ALWAYS-LIST is non-nil, this function will always release a list of
 173 ranges."
 174   (let* ((first (car numbers))
 175          (last (car numbers))
 176          result)
 177     (if (null numbers)
 178         nil
 179       (if (not (listp (cdr numbers)))
 180           numbers
 181         (while numbers
 182           (cond ((= last (car numbers)) nil) ;Omit duplicated number
 183                 ((= (1+ last) (car numbers)) ;Still in sequence
 184                  (setq last (car numbers)))
 185                 (t                      ;End of one sequence
 186                  (setq result
 187                        (cons (if (= first last) first
 188                                (cons first last))
 189                              result))
 190                  (setq first (car numbers))
 191                  (setq last  (car numbers))))
 192           (setq numbers (cdr numbers)))
 193         (if (and (not always-list) (null result))
 194             (if (= first last) (list first) (cons first last))
 195           (nreverse (cons (if (= first last) first (cons first last))
 196                           result)))))))
 197
 198 (defalias 'gnus-uncompress-sequence 'gnus-uncompress-range)
 199 (defun gnus-uncompress-range (ranges)
 200   "Expand a list of ranges into a list of numbers.
 201 RANGES is either a single range on the form `(num . num)' or a list of
 202 these ranges."
 203   (let (first last result)
 204     (cond
 205      ((null ranges)
 206       nil)
 207      ((not (listp (cdr ranges)))
 208       (setq first (car ranges))
 209       (setq last (cdr ranges))
 210       (while (<= first last)
 211         (setq result (cons first result))
 212         (setq first (1+ first)))
 213       (nreverse result))
 214      (t
 215       (while ranges
 216         (if (atom (car ranges))
 217             (when (numberp (car ranges))
 218               (setq result (cons (car ranges) result)))
 219           (setq first (caar ranges))
 220           (setq last  (cdar ranges))
 221           (while (<= first last)
 222             (setq result (cons first result))
 223             (setq first (1+ first))))
 224         (setq ranges (cdr ranges)))
 225       (nreverse result)))))
 226
 227 (defun gnus-add-to-range (ranges list)
 228   "Return a list of ranges that has all articles from both RANGES and LIST.
 229 Note: LIST has to be sorted over `<'."
 230   (if (not ranges)
 231       (gnus-compress-sequence list t)
 232     (setq list (copy-sequence list))
 233     (unless (listp (cdr ranges))
 234       (setq ranges (list ranges)))
 235     (let ((out ranges)
 236           ilist lowest highest temp)
 237       (while (and ranges list)
 238         (setq ilist list)
 239         (setq lowest (or (and (atom (car ranges)) (car ranges))
 240                          (caar ranges)))
 241         (while (and list (cdr list) (< (cadr list) lowest))
 242           (setq list (cdr list)))
 243         (when (< (car ilist) lowest)
 244           (setq temp list)
 245           (setq list (cdr list))
 246           (setcdr temp nil)
 247           (setq out (nconc (gnus-compress-sequence ilist t) out)))
 248         (setq highest (or (and (atom (car ranges)) (car ranges))
 249                           (cdar ranges)))
 250         (while (and list (<= (car list) highest))
 251           (setq list (cdr list)))
 252         (setq ranges (cdr ranges)))
 253       (when list
 254         (setq out (nconc (gnus-compress-sequence list t) out)))
 255       (setq out (sort out (lambda (r1 r2)
 256                             (< (or (and (atom r1) r1) (car r1))
 257                                (or (and (atom r2) r2) (car r2))))))
 258       (setq ranges out)
 259       (while ranges
 260         (if (atom (car ranges))
 261             (when (cdr ranges)
 262               (if (atom (cadr ranges))
 263                   (when (= (1+ (car ranges)) (cadr ranges))
 264                     (setcar ranges (cons (car ranges)
 265                                          (cadr ranges)))
 266                     (setcdr ranges (cddr ranges)))
 267                 (when (= (1+ (car ranges)) (caadr ranges))
 268                   (setcar (cadr ranges) (car ranges))
 269                   (setcar ranges (cadr ranges))
 270                   (setcdr ranges (cddr ranges)))))
 271           (when (cdr ranges)
 272             (if (atom (cadr ranges))
 273                 (when (= (1+ (cdar ranges)) (cadr ranges))
 274                   (setcdr (car ranges) (cadr ranges))
 275                   (setcdr ranges (cddr ranges)))
 276               (when (= (1+ (cdar ranges)) (caadr ranges))
 277                 (setcdr (car ranges) (cdadr ranges))
 278                 (setcdr ranges (cddr ranges))))))
 279         (setq ranges (cdr ranges)))
 280       out)))
 281
 282 (defun gnus-remove-from-range (range1 range2)
 283   "Return a range that has all articles from RANGE2 removed from RANGE1.
 284 The returned range is always a list.  RANGE2 can also be a unsorted
 285 list of articles.  RANGE1 is modified by side effects, RANGE2 is not
 286 modified."
 287   (if (or (null range1) (null range2))
 288       range1
 289     (let (out r1 r2 r1_min r1_max r2_min r2_max
 290               (range2 (gnus-copy-sequence range2)))
 291       (setq range1 (if (listp (cdr range1)) range1 (list range1))
 292             range2 (sort (if (listp (cdr range2)) range2 (list range2))
 293                          (lambda (e1 e2)
 294                            (< (if (consp e1) (car e1) e1)
 295                               (if (consp e2) (car e2) e2))))
 296             r1 (car range1)
 297             r2 (car range2)
 298             r1_min (if (consp r1) (car r1) r1)
 299             r1_max (if (consp r1) (cdr r1) r1)
 300             r2_min (if (consp r2) (car r2) r2)
 301             r2_max (if (consp r2) (cdr r2) r2))
 302       (while (and range1 range2)
 303         (cond ((< r2_max r1_min)        ; r2 < r1
 304                (pop range2)
 305                (setq r2 (car range2)
 306                      r2_min (if (consp r2) (car r2) r2)
 307                      r2_max (if (consp r2) (cdr r2) r2)))
 308               ((and (<= r2_min r1_min) (<= r1_max r2_max)) ; r2 overlap r1
 309                (pop range1)
 310                (setq r1 (car range1)
 311                      r1_min (if (consp r1) (car r1) r1)
 312                      r1_max (if (consp r1) (cdr r1) r1)))
 313               ((and (<= r2_min r1_min) (<= r2_max r1_max)) ; r2 overlap min r1
 314                (pop range2)
 315                (setq r1_min (1+ r2_max)
 316                      r2 (car range2)
 317                      r2_min (if (consp r2) (car r2) r2)
 318                      r2_max (if (consp r2) (cdr r2) r2)))
 319               ((and (<= r1_min r2_min) (<= r2_max r1_max)) ; r2 contained in r1
 320                (if (eq r1_min (1- r2_min))
 321                    (push r1_min out)
 322                  (push (cons r1_min (1- r2_min)) out))
 323                (pop range2)
 324                (if (< r2_max r1_max)    ; finished with r1?
 325                    (setq r1_min (1+ r2_max))
 326                  (pop range1)
 327                  (setq r1 (car range1)
 328                        r1_min (if (consp r1) (car r1) r1)
 329                        r1_max (if (consp r1) (cdr r1) r1)))
 330                (setq r2 (car range2)
 331                      r2_min (if (consp r2) (car r2) r2)
 332                      r2_max (if (consp r2) (cdr r2) r2)))
 333               ((and (<= r2_min r1_max) (<= r1_max r2_max)) ; r2 overlap max r1
 334                (if (eq r1_min (1- r2_min))
 335                    (push r1_min out)
 336                  (push (cons r1_min (1- r2_min)) out))
 337                (pop range1)
 338                (setq r1 (car range1)
 339                      r1_min (if (consp r1) (car r1) r1)
 340                      r1_max (if (consp r1) (cdr r1) r1)))
 341               ((< r1_max r2_min)        ; r2 > r1
 342                (pop range1)
 343                (if (eq r1_min r1_max)
 344                    (push r1_min out)
 345                  (push (cons r1_min r1_max) out))
 346                (setq r1 (car range1)
 347                      r1_min (if (consp r1) (car r1) r1)
 348                      r1_max (if (consp r1) (cdr r1) r1)))))
 349       (when r1
 350         (if (eq r1_min r1_max)
 351             (push r1_min out)
 352           (push (cons r1_min r1_max) out))
 353         (pop range1))
 354       (while range1
 355         (push (pop range1) out))
 356       (nreverse out))))
 357
 358 (defun gnus-member-of-range (number ranges)
 359   (if (not (listp (cdr ranges)))
 360       (and (>= number (car ranges))
 361            (<= number (cdr ranges)))
 362     (let ((not-stop t))
 363       (while (and ranges
 364                   (if (numberp (car ranges))
 365                       (>= number (car ranges))
 366                     (>= number (caar ranges)))
 367                   not-stop)
 368         (when (if (numberp (car ranges))
 369                   (= number (car ranges))
 370                 (and (>= number (caar ranges))
 371                      (<= number (cdar ranges))))
 372           (setq not-stop nil))
 373         (setq ranges (cdr ranges)))
 374       (not not-stop))))
 375
 376 (defun gnus-list-range-intersection (list ranges)
 377   "Return a list of numbers in LIST that are members of RANGES.
 378 LIST is a sorted list."
 379   (setq ranges (gnus-range-normalize ranges))
 380   (let (number result)
 381     (while (setq number (pop list))
 382       (while (and ranges
 383                   (if (numberp (car ranges))
 384                       (< (car ranges) number)
 385                     (< (cdar ranges) number)))
 386         (setq ranges (cdr ranges)))
 387       (when (and ranges
 388                  (if (numberp (car ranges))
 389                       (= (car ranges) number)
 390                    ;; (caar ranges) <= number <= (cdar ranges)
 391                    (>= number (caar ranges))))
 392         (push number result)))
 393     (nreverse result)))
 394
 395 (defun gnus-inverse-list-range-intersection (list ranges)
 396   "Return a list of numbers in LIST that are not members of RANGES.
 397 LIST is a sorted list."
 398   (setq ranges (gnus-range-normalize ranges))
 399   (let (number result)
 400     (while (setq number (pop list))
 401       (while (and ranges
 402                   (if (numberp (car ranges))
 403                       (< (car ranges) number)
 404                     (< (cdar ranges) number)))
 405         (setq ranges (cdr ranges)))
 406       (when (or (not ranges)
 407                 (if (numberp (car ranges))
 408                     (not (= (car ranges) number))
 409                   ;; not ((caar ranges) <= number <= (cdar ranges))
 410                   (< number (caar ranges))))
 411         (push number result)))
 412     (nreverse result)))
 413
 414 (defun gnus-range-length (range)
 415   "Return the length RANGE would have if uncompressed."
 416   (length (gnus-uncompress-range range)))
 417
 418 (defun gnus-sublist-p (list sublist)
 419   "Test whether all elements in SUBLIST are members of LIST."
 420   (let ((sublistp t))
 421     (while sublist
 422       (unless (memq (pop sublist) list)
 423         (setq sublistp nil
 424               sublist nil)))
 425     sublistp))
 426
 427 (defun gnus-range-add (range1 range2)
 428   "Add RANGE2 to RANGE1 (nondestructively)."
 429   (unless (listp (cdr range1))
 430     (setq range1 (list range1)))
 431   (unless (listp (cdr range2))
 432     (setq range2 (list range2)))
 433   (let ((item1 (pop range1))
 434         (item2 (pop range2))
 435         range item selector)
 436     (while (or item1 item2)
 437       (setq selector
 438             (cond
 439              ((null item1) nil)
 440              ((null item2) t)
 441              ((and (numberp item1) (numberp item2)) (< item1 item2))
 442              ((numberp item1) (< item1 (car item2)))
 443              ((numberp item2) (< (car item1) item2))
 444              (t (< (car item1) (car item2)))))
 445       (setq item
 446             (or
 447              (let ((tmp1 item) (tmp2 (if selector item1 item2)))
 448                (cond
 449                 ((null tmp1) tmp2)
 450                 ((null tmp2) tmp1)
 451                 ((and (numberp tmp1) (numberp tmp2))
 452                  (cond
 453                   ((eq tmp1 tmp2) tmp1)
 454                   ((eq (1+ tmp1) tmp2) (cons tmp1 tmp2))
 455                   ((eq (1+ tmp2) tmp1) (cons tmp2 tmp1))
 456                   (t nil)))
 457                 ((numberp tmp1)
 458                  (cond
 459                   ((and (>= tmp1 (car tmp2)) (<= tmp1 (cdr tmp2))) tmp2)
 460                   ((eq (1+ tmp1) (car tmp2)) (cons tmp1 (cdr tmp2)))
 461                   ((eq (1- tmp1) (cdr tmp2)) (cons (car tmp2) tmp1))
 462                   (t nil)))
 463                 ((numberp tmp2)
 464                  (cond
 465                   ((and (>= tmp2 (car tmp1)) (<= tmp2 (cdr tmp1))) tmp1)
 466                   ((eq (1+ tmp2) (car tmp1)) (cons tmp2 (cdr tmp1)))
 467                   ((eq (1- tmp2) (cdr tmp1)) (cons (car tmp1) tmp2))
 468                   (t nil)))
 469                 ((< (1+ (cdr tmp1)) (car tmp2)) nil)
 470                 ((< (1+ (cdr tmp2)) (car tmp1)) nil)
 471                 (t (cons (min (car tmp1) (car tmp2))
 472                          (max (cdr tmp1) (cdr tmp2))))))
 473              (progn
 474                (if item (push item range))
 475                (if selector item1 item2))))
 476       (if selector
 477           (setq item1 (pop range1))
 478         (setq item2 (pop range2))))
 479     (if item (push item range))
 480     (reverse range)))
 481
 482 (provide 'gnus-range)
 483
 484 ;;; gnus-range.el ends here