cgit.sxemacs.org Git - gnus/blob - lisp/gnus-range.el

   1 ;;; gnus-range.el --- range and sequence functions for Gnus
   2 ;; Copyright (C) 1996,97,98 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   5 ;; Keywords: news
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  22 ;; Boston, MA 02111-1307, USA.
  23
  24 ;;; Commentary:
  25
  26 ;;; Code:
  27
  28 (eval-when-compile (require 'cl))
  29
  30 ;;; List and range functions
  31
  32 (defun gnus-last-element (list)
  33   "Return last element of LIST."
  34   (while (cdr list)
  35     (setq list (cdr list)))
  36   (car list))
  37
  38 (defun gnus-copy-sequence (list)
  39   "Do a complete, total copy of a list."
  40   (let (out)
  41     (while (consp list)
  42       (if (consp (car list))
  43           (push (gnus-copy-sequence (pop list)) out)
  44         (push (pop list) out)))
  45     (if list
  46         (nconc (nreverse out) list)
  47       (nreverse out))))
  48
  49 (defun gnus-set-difference (list1 list2)
  50   "Return a list of elements of LIST1 that do not appear in LIST2."
  51   (let ((list1 (copy-sequence list1)))
  52     (while list2
  53       (setq list1 (delq (car list2) list1))
  54       (setq list2 (cdr list2)))
  55     list1))
  56
  57 (defun gnus-sorted-complement (list1 list2)
  58   "Return a list of elements that are in LIST1 or LIST2 but not both.
  59 Both lists have to be sorted over <."
  60   (let (out)
  61     (if (or (null list1) (null list2))
  62         (or list1 list2)
  63       (while (and list1 list2)
  64         (cond ((= (car list1) (car list2))
  65                (setq list1 (cdr list1)
  66                      list2 (cdr list2)))
  67               ((< (car list1) (car list2))
  68                (setq out (cons (car list1) out))
  69                (setq list1 (cdr list1)))
  70               (t
  71                (setq out (cons (car list2) out))
  72                (setq list2 (cdr list2)))))
  73       (nconc (nreverse out) (or list1 list2)))))
  74
  75 (defun gnus-intersection (list1 list2)
  76   (let ((result nil))
  77     (while list2
  78       (when (memq (car list2) list1)
  79         (setq result (cons (car list2) result)))
  80       (setq list2 (cdr list2)))
  81     result))
  82
  83 (defun gnus-sorted-intersection (list1 list2)
  84   ;; LIST1 and LIST2 have to be sorted over <.
  85   (let (out)
  86     (while (and list1 list2)
  87       (cond ((= (car list1) (car list2))
  88              (setq out (cons (car list1) out)
  89                    list1 (cdr list1)
  90                    list2 (cdr list2)))
  91             ((< (car list1) (car list2))
  92              (setq list1 (cdr list1)))
  93             (t
  94              (setq list2 (cdr list2)))))
  95     (nreverse out)))
  96
  97 (defun gnus-set-sorted-intersection (list1 list2)
  98   ;; LIST1 and LIST2 have to be sorted over <.
  99   ;; This function modifies LIST1.
 100   (let* ((top (cons nil list1))
 101          (prev top))
 102     (while (and list1 list2)
 103       (cond ((= (car list1) (car list2))
 104              (setq prev list1
 105                    list1 (cdr list1)
 106                    list2 (cdr list2)))
 107             ((< (car list1) (car list2))
 108              (setcdr prev (cdr list1))
 109              (setq list1 (cdr list1)))
 110             (t
 111              (setq list2 (cdr list2)))))
 112     (setcdr prev nil)
 113     (cdr top)))
 114
 115 (defun gnus-compress-sequence (numbers &optional always-list)
 116   "Convert list of numbers to a list of ranges or a single range.
 117 If ALWAYS-LIST is non-nil, this function will always release a list of
 118 ranges."
 119   (let* ((first (car numbers))
 120          (last (car numbers))
 121          result)
 122     (if (null numbers)
 123         nil
 124       (if (not (listp (cdr numbers)))
 125           numbers
 126         (while numbers
 127           (cond ((= last (car numbers)) nil) ;Omit duplicated number
 128                 ((= (1+ last) (car numbers)) ;Still in sequence
 129                  (setq last (car numbers)))
 130                 (t                      ;End of one sequence
 131                  (setq result
 132                        (cons (if (= first last) first
 133                                (cons first last))
 134                              result))
 135                  (setq first (car numbers))
 136                  (setq last  (car numbers))))
 137           (setq numbers (cdr numbers)))
 138         (if (and (not always-list) (null result))
 139             (if (= first last) (list first) (cons first last))
 140           (nreverse (cons (if (= first last) first (cons first last))
 141                           result)))))))
 142
 143 (defalias 'gnus-uncompress-sequence 'gnus-uncompress-range)
 144 (defun gnus-uncompress-range (ranges)
 145   "Expand a list of ranges into a list of numbers.
 146 RANGES is either a single range on the form `(num . num)' or a list of
 147 these ranges."
 148   (let (first last result)
 149     (cond
 150      ((null ranges)
 151       nil)
 152      ((not (listp (cdr ranges)))
 153       (setq first (car ranges))
 154       (setq last (cdr ranges))
 155       (while (<= first last)
 156         (setq result (cons first result))
 157         (setq first (1+ first)))
 158       (nreverse result))
 159      (t
 160       (while ranges
 161         (if (atom (car ranges))
 162             (when (numberp (car ranges))
 163               (setq result (cons (car ranges) result)))
 164           (setq first (caar ranges))
 165           (setq last  (cdar ranges))
 166           (while (<= first last)
 167             (setq result (cons first result))
 168             (setq first (1+ first))))
 169         (setq ranges (cdr ranges)))
 170       (nreverse result)))))
 171
 172 (defun gnus-add-to-range (ranges list)
 173   "Return a list of ranges that has all articles from both RANGES and LIST.
 174 Note: LIST has to be sorted over `<'."
 175   (if (not ranges)
 176       (gnus-compress-sequence list t)
 177     (setq list (copy-sequence list))
 178     (unless (listp (cdr ranges))
 179       (setq ranges (list ranges)))
 180     (let ((out ranges)
 181           ilist lowest highest temp)
 182       (while (and ranges list)
 183         (setq ilist list)
 184         (setq lowest (or (and (atom (car ranges)) (car ranges))
 185                          (caar ranges)))
 186         (while (and list (cdr list) (< (cadr list) lowest))
 187           (setq list (cdr list)))
 188         (when (< (car ilist) lowest)
 189           (setq temp list)
 190           (setq list (cdr list))
 191           (setcdr temp nil)
 192           (setq out (nconc (gnus-compress-sequence ilist t) out)))
 193         (setq highest (or (and (atom (car ranges)) (car ranges))
 194                           (cdar ranges)))
 195         (while (and list (<= (car list) highest))
 196           (setq list (cdr list)))
 197         (setq ranges (cdr ranges)))
 198       (when list
 199         (setq out (nconc (gnus-compress-sequence list t) out)))
 200       (setq out (sort out (lambda (r1 r2)
 201                             (< (or (and (atom r1) r1) (car r1))
 202                                (or (and (atom r2) r2) (car r2))))))
 203       (setq ranges out)
 204       (while ranges
 205         (if (atom (car ranges))
 206             (when (cdr ranges)
 207               (if (atom (cadr ranges))
 208                   (when (= (1+ (car ranges)) (cadr ranges))
 209                     (setcar ranges (cons (car ranges)
 210                                          (cadr ranges)))
 211                     (setcdr ranges (cddr ranges)))
 212                 (when (= (1+ (car ranges)) (caadr ranges))
 213                   (setcar (cadr ranges) (car ranges))
 214                   (setcar ranges (cadr ranges))
 215                   (setcdr ranges (cddr ranges)))))
 216           (when (cdr ranges)
 217             (if (atom (cadr ranges))
 218                 (when (= (1+ (cdar ranges)) (cadr ranges))
 219                   (setcdr (car ranges) (cadr ranges))
 220                   (setcdr ranges (cddr ranges)))
 221               (when (= (1+ (cdar ranges)) (caadr ranges))
 222                 (setcdr (car ranges) (cdadr ranges))
 223                 (setcdr ranges (cddr ranges))))))
 224         (setq ranges (cdr ranges)))
 225       out)))
 226
 227 (defun gnus-remove-from-range (range1 range2)
 228   "Return a range that has all articles from RANGE2 removed from
 229 RANGE1. The returned range is always a list."
 230   (if (or (null range1) (null range2))
 231       range1
 232     (let (out r1 r2 r1_min r1_max r2_min r2_max)
 233       (setq range1 (if (listp (cdr range1)) range1 (list range1))
 234             range2 (if (listp (cdr range2)) range2 (list range2))
 235             r1 (car range1)
 236             r2 (car range2)
 237             r1_min (if (consp r1) (car r1) r1)
 238             r1_max (if (consp r1) (cdr r1) r1)
 239             r2_min (if (consp r2) (car r2) r2)
 240             r2_max (if (consp r2) (cdr r2) r2))
 241       (while (and range1 range2)
 242         (cond ((< r2_max r1_min)                           ; r2 < r1
 243                (pop range2)
 244                (setq r2 (car range2)
 245                      r2_min (if (consp r2) (car r2) r2)
 246                      r2_max (if (consp r2) (cdr r2) r2)))
 247               ((and (<= r2_min r1_min) (<= r1_max r2_max)) ; r2 overlap r1
 248                (pop range1)
 249                (setq r1 (car range1)
 250                      r1_min (if (consp r1) (car r1) r1)
 251                      r1_max (if (consp r1) (cdr r1) r1)))
 252               ((and (<= r2_min r1_min) (<= r2_max r1_max)) ; r2 overlap min r1
 253                (pop range2)
 254                (setq r1_min (1+ r2_max)
 255                      r2 (car range2)
 256                      r2_min (if (consp r2) (car r2) r2)
 257                      r2_max (if (consp r2) (cdr r2) r2)))
 258               ((and (<= r1_min r2_min) (<= r2_max r1_max)) ; r2 contained in r1
 259                (if (eq r1_min (1- r2_min))
 260                    (push r1_min out)
 261                  (push (cons r1_min (1- r2_min)) out))
 262                (pop range2)
 263                (if (< r2_max r1_max) ; finished with r1?
 264                    (setq r1_min (1+ r2_max))
 265                  (pop range1)
 266                  (setq r1 (car range1)
 267                        r1_min (if (consp r1) (car r1) r1)
 268                        r1_max (if (consp r1) (cdr r1) r1)))
 269                (setq r2 (car range2)
 270                      r2_min (if (consp r2) (car r2) r2)
 271                      r2_max (if (consp r2) (cdr r2) r2)))
 272               ((and (<= r2_min r1_max) (<= r1_max r2_max)) ; r2 overlap max r1
 273                (if (eq r1_min (1- r2_min))
 274                    (push r1_min out)
 275                  (push (cons r1_min (1- r2_min)) out))
 276                (pop range1)
 277                (setq r1 (car range1)
 278                      r1_min (if (consp r1) (car r1) r1)
 279                      r1_max (if (consp r1) (cdr r1) r1)))
 280               ((< r1_max r2_min)                           ; r2 > r1
 281                (pop range1)
 282                (if (eq r1_min r1_max)
 283                    (push r1_min out)
 284                  (push (cons r1_min r1_max) out))
 285                (setq r1 (car range1)
 286                      r1_min (if (consp r1) (car r1) r1)
 287                      r1_max (if (consp r1) (cdr r1) r1)))))
 288       (when r1
 289         (if (eq r1_min r1_max)
 290             (push r1_min out)
 291           (push (cons r1_min r1_max) out))
 292         (pop range1))
 293       (while range1
 294         (push (pop range1) out))
 295       (nreverse out))))
 296
 297 (defun gnus-member-of-range (number ranges)
 298   (if (not (listp (cdr ranges)))
 299       (and (>= number (car ranges))
 300            (<= number (cdr ranges)))
 301     (let ((not-stop t))
 302       (while (and ranges
 303                   (if (numberp (car ranges))
 304                       (>= number (car ranges))
 305                     (>= number (caar ranges)))
 306                   not-stop)
 307         (when (if (numberp (car ranges))
 308                   (= number (car ranges))
 309                 (and (>= number (caar ranges))
 310                      (<= number (cdar ranges))))
 311           (setq not-stop nil))
 312         (setq ranges (cdr ranges)))
 313       (not not-stop))))
 314
 315 (defun gnus-range-length (range)
 316   "Return the length RANGE would have if uncompressed."
 317   (length (gnus-uncompress-range range)))
 318
 319 (defun gnus-sublist-p (list sublist)
 320   "Test whether all elements in SUBLIST are members of LIST."
 321   (let ((sublistp t))
 322     (while sublist
 323       (unless (memq (pop sublist) list)
 324         (setq sublistp nil
 325               sublist nil)))
 326     sublistp))
 327
 328 (defun gnus-range-add (range1 range2)
 329   "Add RANGE2 to RANGE1 destructively."
 330   (cond
 331    ;; If either are nil, then the job is quite easy.
 332    ((or (null range1) (null range2))
 333     (or range1 range2))
 334    (t
 335     ;; I don't like thinking.
 336     (gnus-compress-sequence
 337      (sort
 338       (nconc
 339        (gnus-uncompress-range range1)
 340        (gnus-uncompress-range range2))
 341       '<)))))
 342
 343 (provide 'gnus-range)
 344
 345 ;;; gnus-range.el ends here