cgit.sxemacs.org Git - gnus/blob - lisp/gnus-picon.el

   1 ;;; gnus-picon.el --- displaying pretty icons in Gnus
   2 ;; Copyright (C) 1996,97,98 Free Software Foundation, Inc.
   3
   4 ;; Author: Wes Hardaker <hardaker@ece.ucdavis.edu>
   5 ;; Keywords: news xpm annotation glyph faces
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  22 ;; Boston, MA 02111-1307, USA.
  23
  24 ;;; Commentary:
  25
  26 ;;; Code:
  27
  28 (require 'gnus)
  29 ;; (require 'xpm)
  30 (require 'annotations)
  31 (require 'custom)
  32 (require 'gnus-art)
  33 (require 'gnus-win)
  34
  35 ;;; User variables:
  36
  37 (defgroup picons nil
  38   "Show pictures of people, domains, and newsgroups (XEmacs).
  39 For this to work, you must add gnus-group-display-picons to the
  40 gnus-summary-display-hook or to the gnus-article-display-hook
  41 depending on what gnus-picons-display-where is set to.  You must
  42 also add gnus-article-display-picons to gnus-article-display-hook."
  43   :group 'gnus-visual)
  44
  45 (defcustom gnus-picons-display-where 'picons
  46   "Where to display the group and article icons.
  47 Legal values are `article' and `picons'."
  48   :type '(choice symbol string)
  49   :group 'picons)
  50
  51 (defcustom gnus-picons-has-modeline-p t
  52   "*Whether the picons window should have a modeline.
  53 This is only useful if `gnus-picons-display-where' is `picons'."
  54   :type 'boolean
  55   :group 'picons)
  56
  57 (defcustom gnus-picons-database "/usr/local/faces"
  58   "*Defines the location of the faces database.
  59 For information on obtaining this database of pretty pictures, please
  60 see http://www.cs.indiana.edu/picons/ftp/index.html"
  61   :type 'directory
  62   :group 'picons)
  63
  64 (defcustom gnus-picons-news-directories '("news")
  65   "*List of directories to search for newsgroups faces."
  66   :type '(repeat string)
  67   :group 'picons)
  68 (define-obsolete-variable-alias 'gnus-picons-news-directory
  69   'gnus-picons-news-directories)
  70
  71 (defcustom gnus-picons-user-directories '("local" "users" "usenix" "misc")
  72   "*List of directories to search for user faces."
  73   :type '(repeat string)
  74   :group 'picons)
  75
  76 (defcustom gnus-picons-domain-directories '("domains")
  77   "*List of directories to search for domain faces.
  78 Some people may want to add \"unknown\" to this list."
  79   :type '(repeat string)
  80   :group 'picons)
  81
  82 (defcustom gnus-picons-refresh-before-display nil
  83   "*If non-nil, display the article buffer before computing the picons."
  84   :type 'boolean
  85   :group 'picons)
  86
  87 (defcustom gnus-picons-group-excluded-groups nil
  88   "*If this regexp matches the group name, group picons will be disabled."
  89   :type 'regexp
  90   :group 'picons)
  91
  92 (defcustom gnus-picons-x-face-file-name
  93   (format "/tmp/picon-xface.%s.xbm" (user-login-name))
  94   "*The name of the file in which to store the converted X-face header."
  95   :type 'string
  96   :group 'picons)
  97
  98 (defcustom gnus-picons-convert-x-face (format "{ echo '/* Width=48, Height=48 */'; uncompface; } | icontopbm | pbmtoxbm > %s" gnus-picons-x-face-file-name)
  99   "*Command to convert the x-face header into a xbm file."
 100   :type 'string
 101   :group 'picons)
 102
 103 (defcustom gnus-picons-display-as-address t
 104   "*If t display textual email addresses along with pictures."
 105   :type 'boolean
 106   :group 'picons)
 107
 108 (defcustom gnus-picons-file-suffixes
 109   (when (featurep 'x)
 110     (let ((types (list "xbm")))
 111       (when (featurep 'gif)
 112         (push "gif" types))
 113       (when (featurep 'xpm)
 114         (push "xpm" types))
 115       types))
 116   "*List of suffixes on picon file names to try."
 117   :type '(repeat string)
 118   :group 'picons)
 119
 120 (defcustom gnus-picons-display-article-move-p nil
 121   "*Whether to move point to first empty line when displaying picons.
 122 This has only an effect if `gnus-picons-display-where' has value `article'."
 123   :type 'boolean
 124   :group 'picons)
 125
 126 (defcustom gnus-picons-clear-cache-on-shutdown t
 127   "*Whether to clear the picons cache when exiting gnus.
 128 Gnus caches every picons it finds while it is running.  This saves
 129 some time in the search process but eats some memory.  If this
 130 variable is set to nil, Gnus will never clear the cache itself; you
 131 will have to manually call `gnus-picons-clear-cache' to clear it.
 132 Otherwise the cache will be cleared every time you exit Gnus."
 133   :type 'boolean
 134   :group 'picons)
 135
 136 (defcustom gnus-picons-piconsearch-url nil
 137   "*The url to query for picons.  Setting this to nil will disable it.
 138 The only publicly available address currently known is
 139 http://www.cs.indiana.edu:800/piconsearch.  If you know of any other,
 140 please tell me so that we can list it."
 141   :type '(choice (const :tag "Disable" :value nil)
 142                  (const :tag "www.cs.indiana.edu"
 143                         :value "http://www.cs.indiana.edu:800/piconsearch")
 144                  (string))
 145   :group 'picons)
 146
 147 (defface gnus-picons-xbm-face '((t (:foreground "black" :background "white")))
 148   "Face to show xbm picons in."
 149   :group 'picons)
 150
 151 (defface gnus-picons-face '((t (:foreground "black" :background "white")))
 152   "Face to show picons in."
 153   :group 'picons)
 154
 155 (defcustom gnus-picons-setup-hook nil
 156   "Hook run in Picons buffers."
 157   :group 'picons
 158   :type 'hook)
 159
 160 ;;; Internal variables:
 161
 162 (defvar gnus-picons-processes-alist nil
 163   "Picons processes currently running and their environment.")
 164 (defvar gnus-picons-glyph-alist nil
 165   "Picons glyphs cache.
 166 List of pairs (KEY . GLYPH) where KEY is either a filename or an URL.")
 167 (defvar gnus-picons-url-alist nil
 168   "Picons file names cache.
 169 List of pairs (KEY . NAME) where KEY is (USER HOST DBS) and NAME is an URL.")
 170
 171 (defvar gnus-picons-jobs-alist nil
 172   "List of jobs that still need be done.
 173 This is a list of (SYM-ANN TAG ARGS...) where SYM-ANN three annotations list,
 174 TAG is one of `picon' or `search' indicating that the job should query a
 175 picon or do a search for picons file names, and ARGS is some additionnal
 176 arguments necessary for the job.")
 177
 178 (defvar gnus-picons-job-already-running nil
 179   "Lock to ensure only one stream of http requests is running.")
 180
 181 ;;; Functions:
 182
 183 (defun gnus-picons-remove-all ()
 184   "Removes all picons from the Gnus display(s)."
 185   (interactive)
 186   (map-extents (function (lambda (ext unused) (delete-annotation ext) nil))
 187                nil nil nil nil nil 'gnus-picon)
 188   (setq gnus-picons-jobs-alist '())
 189   ;; notify running job that it may have been preempted
 190   (if (and (listp gnus-picons-job-already-running)
 191            gnus-picons-job-already-running)
 192       (setq gnus-picons-job-already-running t)))
 193
 194 (defun gnus-get-buffer-name (variable)
 195   "Returns the buffer name associated with the contents of a variable."
 196   (let ((buf (gnus-get-buffer-create
 197               (gnus-window-to-buffer-helper
 198                (cdr (assq variable gnus-window-to-buffer))))))
 199     (and buf
 200          (buffer-name buf))))
 201
 202 (defun gnus-picons-buffer-name ()
 203   (cond ((or (stringp gnus-picons-display-where)
 204              (bufferp gnus-picons-display-where))
 205          gnus-picons-display-where)
 206         ((eq gnus-picons-display-where 'picons)
 207          (if gnus-single-article-buffer
 208              "*Picons*"
 209            (concat "*Picons " gnus-newsgroup-name "*")))
 210         (t
 211          (gnus-get-buffer-name gnus-picons-display-where))))
 212
 213 (defun gnus-picons-kill-buffer ()
 214   (let ((buf (get-buffer (gnus-picons-buffer-name))))
 215     (when (buffer-live-p buf)
 216       (kill-buffer buf))))
 217
 218 (defun gnus-picons-setup-buffer ()
 219   (let ((name (gnus-picons-buffer-name)))
 220     (save-excursion
 221       (if (and (get-buffer name)
 222                (with-current-buffer name
 223                  (eq major-mode 'gnus-picons-mode)))
 224           (set-buffer name)
 225         (set-buffer (gnus-get-buffer-create name))
 226         (buffer-disable-undo)
 227         (setq buffer-read-only t)
 228         (run-hooks 'gnus-picons-setup-hook)
 229         (setq major-mode 'gnus-picons-mode)
 230         (add-hook 'gnus-summary-prepare-exit-hook 'gnus-picons-kill-buffer))
 231       (current-buffer))))
 232
 233 (defun gnus-picons-set-buffer ()
 234   (set-buffer (gnus-picons-setup-buffer))
 235   (goto-char (point-min))
 236   (if (and (eq gnus-picons-display-where 'article)
 237            gnus-picons-display-article-move-p)
 238       (if (search-forward "\n\n" nil t)
 239           (forward-line -1)
 240         (goto-char (point-max)))
 241     (setq buffer-read-only t)
 242     (unless gnus-picons-has-modeline-p
 243       (set-specifier has-modeline-p
 244                      (list (list (current-buffer)
 245                                  (cons nil gnus-picons-has-modeline-p)))))))
 246
 247 (defun gnus-picons-prepare-for-annotations ()
 248   "Prepare picons buffer for putting annotations."
 249   ;; let drawing catch up
 250   (when gnus-picons-refresh-before-display
 251     (sit-for 0))
 252   (gnus-picons-set-buffer)
 253   (gnus-picons-remove-all))
 254
 255 (defun gnus-picons-make-annotation (&rest args)
 256   (let ((annot (apply 'make-annotation args)))
 257     (set-extent-property annot 'gnus-picon t)
 258     (set-extent-property annot 'duplicable t)
 259     annot))
 260
 261 (defun gnus-picons-article-display-x-face ()
 262   "Display the x-face header bitmap in the 'gnus-picons-display-where buffer."
 263   (let ((gnus-article-x-face-command 'gnus-picons-display-x-face))
 264     (gnus-article-display-x-face)))
 265
 266 (defun gnus-picons-x-face-sentinel (process event)
 267   (when (memq process gnus-picons-processes-alist)
 268     (setq gnus-picons-processes-alist
 269           (delq process gnus-picons-processes-alist))
 270     (gnus-picons-set-buffer)
 271     (gnus-picons-make-annotation
 272      (make-glyph gnus-picons-x-face-file-name) nil 'text)
 273     (when (file-exists-p gnus-picons-x-face-file-name)
 274       (delete-file gnus-picons-x-face-file-name))))
 275
 276 (defun gnus-picons-display-x-face (beg end)
 277   "Function to display the x-face header in the picons window.
 278 To use:  (setq gnus-article-x-face-command 'gnus-picons-display-x-face)"
 279   (interactive)
 280   (if (featurep 'xface)
 281       ;; Use builtin support
 282       (save-excursion
 283         ;; Don't remove this binding, it is really needed: when
 284         ;; `gnus-picons-set-buffer' changes buffer (like when it is
 285         ;; set to display picons outside of the article buffer), BEG
 286         ;; and END still refer the buffer current now !
 287         (let ((buf (current-buffer)))
 288           (gnus-picons-set-buffer)
 289           (gnus-picons-make-annotation
 290            (vector 'xface
 291                    :data (concat "X-Face: " (buffer-substring beg end buf)))
 292            nil 'text nil nil nil t)))
 293     ;; convert the x-face header to a .xbm file
 294     (let* ((process-connection-type nil)
 295            (process (start-process-shell-command
 296                      "gnus-x-face" nil gnus-picons-convert-x-face)))
 297       (push process gnus-picons-processes-alist)
 298       (process-kill-without-query process)
 299       (set-process-sentinel process 'gnus-picons-x-face-sentinel)
 300       (process-send-region process beg end)
 301       (process-send-eof process))))
 302
 303 (defun gnus-article-display-picons ()
 304   "Display faces for an author and her domain in gnus-picons-display-where."
 305   (interactive)
 306   (let (from at-idx)
 307     (when (and (featurep 'xpm)
 308                (or (not (fboundp 'device-type)) (equal (device-type) 'x))
 309                (setq from (mail-fetch-field "from"))
 310                (setq from (downcase (or (cadr (mail-extract-address-components
 311                                                from))
 312                                         "")))
 313                (or (setq at-idx (string-match "@" from))
 314                    (setq at-idx (length from))))
 315       (save-excursion
 316         (let ((username (downcase (substring from 0 at-idx)))
 317               (addrs (if (eq at-idx (length from))
 318                          (if gnus-local-domain
 319                              (message-tokenize-header gnus-local-domain "."))
 320                        (message-tokenize-header (substring from (1+ at-idx))
 321                                                 "."))))
 322           (gnus-picons-prepare-for-annotations)
 323           (gnus-group-display-picons)
 324           (unless gnus-picons-display-article-move-p
 325             (save-restriction
 326               (let ((buffer-read-only nil))
 327                 (when (re-search-forward "^From: " nil t)
 328                   (narrow-to-region (point) (gnus-point-at-eol))
 329                   (when (search-forward from nil t)
 330                     (gnus-put-text-property
 331                      (match-beginning 0) (match-end 0)
 332                      'invisible t))))))
 333           (if (null gnus-picons-piconsearch-url)
 334               (progn
 335                 (gnus-picons-display-pairs (gnus-picons-lookup-pairs
 336                                             addrs
 337                                             gnus-picons-domain-directories)
 338                                            gnus-picons-display-as-address
 339                                            "." t)
 340                 (if (and gnus-picons-display-as-address addrs)
 341                     (gnus-picons-make-annotation
 342                      [string :data "@"] nil 'text nil nil nil t))
 343                 (gnus-picons-display-picon-or-name
 344                  (gnus-picons-lookup-user username addrs)
 345                  username t))
 346             (push (list 'gnus-article-annotations 'search username addrs
 347                         gnus-picons-domain-directories t)
 348                   gnus-picons-jobs-alist)
 349             (gnus-picons-next-job)))))))
 350
 351 (defun gnus-group-display-picons ()
 352   "Display icons for the group in the `gnus-picons-display-where' buffer."
 353   (interactive)
 354   (when (and (featurep 'xpm)
 355              (or (not (fboundp 'device-type)) (equal (device-type) 'x))
 356              (or (null gnus-picons-group-excluded-groups)
 357                  (not (string-match gnus-picons-group-excluded-groups
 358                                     gnus-newsgroup-name))))
 359     (let* ((newsgroups (mail-fetch-field "newsgroups"))
 360            (groups
 361             (if (or gnus-picons-display-article-move-p
 362                     (not newsgroups))(mail-fetch-field "newsgroups")
 363                 (list (gnus-group-real-name gnus-newsgroup-name))
 364               (split-string newsgroups ",")))
 365            group)
 366       (save-excursion
 367         (gnus-picons-prepare-for-annotations)
 368         (while (setq group (pop groups))
 369           (unless gnus-picons-display-article-move-p
 370             (save-restriction
 371               (let ((buffer-read-only nil))
 372                 (goto-char (point-min))
 373                 (when (re-search-forward "^Newsgroups:" nil t)
 374                   (narrow-to-region (point) (gnus-point-at-eol))
 375                   (when (search-forward group nil t)
 376                     (gnus-put-text-property
 377                      (match-beginning 0) (match-end 0)
 378                      'invisible t))))))
 379           (if (null gnus-picons-piconsearch-url)
 380               (gnus-picons-display-pairs
 381                (gnus-picons-lookup-pairs
 382                 (reverse (split-string group "\\."))
 383                 gnus-picons-news-directories)
 384                t ".")
 385             (push (list 'gnus-group-annotations 'search nil
 386                         (split-string group "\\.")
 387                         (if (listp gnus-picons-news-directories)
 388                             gnus-picons-news-directories
 389                           (list gnus-picons-news-directories))
 390                         nil)
 391                   gnus-picons-jobs-alist)
 392             (gnus-picons-next-job))
 393
 394           (add-hook 'gnus-summary-exit-hook 'gnus-picons-remove-all))))))
 395
 396 (defun gnus-picons-lookup-internal (addrs dir)
 397   (setq dir (expand-file-name dir gnus-picons-database))
 398   (gnus-picons-try-face (dolist (part (reverse addrs) dir)
 399                           (setq dir (expand-file-name part dir)))))
 400
 401 (defun gnus-picons-lookup (addrs dirs)
 402   "Lookup the picon for ADDRS in databases DIRS.
 403 Returns the picon filename or NIL if none found."
 404   (let (result)
 405     (while (and dirs (null result))
 406       (setq result (gnus-picons-lookup-internal addrs (pop dirs))))
 407     result))
 408
 409 (defun gnus-picons-lookup-user-internal (user domains)
 410   (let ((dirs gnus-picons-user-directories)
 411         domains-tmp dir picon)
 412     (while (and dirs (null picon))
 413       (setq domains-tmp domains
 414             dir (pop dirs))
 415       (while (and domains-tmp
 416                   (null (setq picon (gnus-picons-lookup-internal
 417                                      (cons user domains-tmp) dir))))
 418         (pop domains-tmp))
 419       ;; Also make a try in MISC subdir
 420       (unless picon
 421         (setq picon (gnus-picons-lookup-internal (list user "MISC") dir))))
 422     picon))
 423
 424 (defun gnus-picons-lookup-user (user domains)
 425   "Lookup the picon for USER at DOMAINS.
 426 USER is a string containing a name.
 427 DOMAINS is a list of strings from the fully qualified domain name."
 428   (or (gnus-picons-lookup-user-internal user domains)
 429       (gnus-picons-lookup-user-internal "unknown" domains)))
 430
 431 (defun gnus-picons-lookup-pairs (domains directories)
 432   "Lookup picons for DOMAINS and all its parents in DIRECTORIES.
 433 Returns a list of PAIRS whose CAR is the picon filename or NIL if
 434 none, and whose CDR is the corresponding element of DOMAINS."
 435   (let (picons)
 436     (setq directories (if (listp directories)
 437                           directories
 438                         (list directories)))
 439     (while domains
 440       (push (list (gnus-picons-lookup (cons "unknown" domains) directories)
 441                   (pop domains))
 442             picons))
 443     picons))
 444
 445 (defun gnus-picons-display-picon-or-name (picon name &optional right-p)
 446   (cond (picon (gnus-picons-display-glyph picon name right-p))
 447         (gnus-picons-display-as-address (list (gnus-picons-make-annotation
 448                                                (vector 'string :data name)
 449                                                nil 'text
 450                                                nil nil nil right-p)))))
 451
 452 (defun gnus-picons-display-pairs (pairs &optional bar-p dot-p right-p)
 453   "Display picons in list PAIRS."
 454   (let ((domain-p (and gnus-picons-display-as-address dot-p))
 455         pair picons)
 456     (when (and bar-p domain-p right-p
 457                gnus-picons-display-article-move-p)
 458       (setq picons (gnus-picons-display-glyph
 459                     (let ((gnus-picons-file-suffixes '("xbm")))
 460                       (gnus-picons-try-face
 461                        gnus-xmas-glyph-directory "bar."))
 462                     nil right-p)))
 463     (while (setq pair (pop pairs))
 464       (setq picons (nconc picons
 465                           (gnus-picons-display-picon-or-name
 466                            (car pair) (cadr pair) right-p)
 467                           (if (and domain-p pairs)
 468                               (list (gnus-picons-make-annotation
 469                                      (vector 'string :data dot-p)
 470                                      nil 'text nil nil nil right-p))))))
 471     picons))
 472
 473 (defun gnus-picons-try-face (dir &optional filebase)
 474   (let* ((dir (file-name-as-directory dir))
 475          (filebase (or filebase "face."))
 476          (key (concat dir filebase))
 477          (glyph (cdr (assoc key gnus-picons-glyph-alist)))
 478          (suffixes gnus-picons-file-suffixes)
 479          f suf)
 480     (while (setq suf (pop suffixes))
 481       (when (file-exists-p (setq f (expand-file-name
 482                                     (concat filebase suf)
 483                                     dir)))
 484         (setq suffixes nil
 485               glyph (make-glyph f))
 486         (if (equal suf "xbm")
 487             (set-glyph-face glyph 'gnus-picons-xbm-face)
 488           (set-glyph-face glyph 'gnus-picons-face))
 489         (push (cons key glyph) gnus-picons-glyph-alist)))
 490     glyph))
 491
 492 (defun gnus-picons-display-glyph (glyph &optional part rightp)
 493   (set-glyph-baseline glyph 70)
 494   (let ((new (gnus-picons-make-annotation
 495               glyph (point) 'text nil nil nil rightp)))
 496     (when (and part gnus-picons-display-as-address)
 497       (set-annotation-data
 498        new (cons new (make-glyph (vector 'string :data part))))
 499       (set-annotation-action new 'gnus-picons-action-toggle))
 500     (nconc
 501      (list new)
 502      (if (and (eq major-mode 'gnus-article-mode)
 503               (not gnus-picons-display-as-address)
 504               (not part))
 505          (list (gnus-picons-make-annotation [string :data " "] (point)
 506                                             'text nil nil nil rightp))))))
 507
 508 (defun gnus-picons-action-toggle (data)
 509   "Toggle annotation."
 510   (interactive "e")
 511   (let* ((annot (car data))
 512          (glyph (annotation-glyph annot)))
 513     (set-annotation-glyph annot (cdr data))
 514     (set-annotation-data annot (cons annot glyph))))
 515
 516 (defun gnus-picons-clear-cache ()
 517   "Clear the picons cache."
 518   (interactive)
 519   (setq gnus-picons-glyph-alist nil
 520         gnus-picons-url-alist nil))
 521
 522 (gnus-add-shutdown 'gnus-picons-close 'gnus)
 523
 524 (defun gnus-picons-close ()
 525   "Shut down the picons."
 526   (if gnus-picons-clear-cache-on-shutdown
 527       (gnus-picons-clear-cache)))
 528
 529 ;;; Query a remote DB.  This requires some stuff from w3 !
 530
 531 (eval-and-compile
 532   (ignore-errors
 533     (require 'url)
 534     (require 'w3-forms)))
 535
 536 (defun gnus-picons-url-retrieve (url fn arg)
 537   (let ((old-asynch (default-value 'url-be-asynchronous))
 538         (url-working-buffer (generate-new-buffer " *picons*"))
 539         (url-package-name "Gnus")
 540         (url-package-version gnus-version-number)
 541         url-request-method)
 542     (setq-default url-be-asynchronous t)
 543     (save-excursion
 544       (set-buffer url-working-buffer)
 545       (setq url-be-asynchronous t
 546             url-current-callback-data arg
 547             url-current-callback-func fn)
 548       (url-retrieve url t))
 549     (setq-default url-be-asynchronous old-asynch)))
 550
 551 (defun gnus-picons-make-glyph (type)
 552   "Make a TYPE glyph using current buffer as data.  Handles xbm nicely."
 553   (cond ((null type) nil)
 554         ((eq type 'xbm) (let ((fname (make-temp-name "/tmp/picon")))
 555                           (write-region (point-min) (point-max) fname
 556                                         nil 'quiet)
 557                           (prog1 (make-glyph (vector 'xbm :file fname))
 558                             (delete-file fname))))
 559         (t (make-glyph (vector type :data (buffer-string))))))
 560
 561 ;;; Parsing of piconsearch result page.
 562
 563 ;; Assumes:
 564 ;; 1 - each value field has the form: "<strong>key</strong> = <kbd>value</kbd>"
 565 ;; 2 - a "<p>" separates the keywords from the results
 566 ;; 3 - every results begins by the path within the database at the beginning
 567 ;;     of the line in raw text.
 568 ;; 3b - and the href following it is the preferred image type.
 569
 570 ;; if 1 or 2 is not met, it will probably cause an error.  The other
 571 ;; will go undetected
 572
 573 (defun gnus-picons-parse-value (name)
 574   (goto-char (point-min))
 575   (re-search-forward (concat "<strong>"
 576                              (regexp-quote name)
 577                              "</strong> *= *<kbd> *\\([^ <][^<]*\\) *</kbd>"))
 578   (buffer-substring (match-beginning 1) (match-end 1)))
 579
 580 (defun gnus-picons-parse-filenames ()
 581   ;; returns an alist of ((USER ADDRS DB) . URL)
 582   (let* ((case-fold-search t)
 583          (user (gnus-picons-parse-value "user"))
 584          (host (gnus-picons-parse-value "host"))
 585          (dbs (message-tokenize-header (gnus-picons-parse-value "db") " "))
 586          (start-re
 587           (concat
 588            ;; dbs
 589            "^\\(" (mapconcat 'identity dbs "\\|") "\\)/"
 590            ;; host
 591            "\\(\\(" (replace-in-string host "\\." "/\\|" t) "/\\|MISC/\\)*\\)"
 592            ;; user
 593            "\\(" (regexp-quote user) "\\|unknown\\)/"
 594            "face\\."))
 595          cur-db cur-host cur-user types res)
 596     ;; now point will be somewhere in the header.  Find beginning of
 597     ;; entries
 598     (re-search-forward "<p>[ \t\n]*")
 599     (while (re-search-forward start-re nil t)
 600       (setq cur-db (buffer-substring (match-beginning 1) (match-end 1))
 601             cur-host (buffer-substring (match-beginning 2) (match-end 2))
 602             cur-user (buffer-substring (match-beginning 4) (match-end 4))
 603             cur-host (nreverse (message-tokenize-header cur-host "/")))
 604       ;; XXX - KLUDGE: there is a blank picon in news/MISC/unknown
 605       (unless (and (string-equal cur-db "news")
 606                    (string-equal cur-user "unknown")
 607                    (equal cur-host '("MISC")))
 608         ;; ok now we have found an entry (USER HOST DB), find the
 609         ;; corresponding picon URL
 610         (save-restriction
 611           ;; restrict region to this entry
 612           (narrow-to-region (point) (search-forward "<br>"))
 613           (goto-char (point-min))
 614           (setq types gnus-picons-file-suffixes)
 615           (while (and types
 616                       (not (re-search-forward
 617                             (concat "<a[ \t\n]+href=\"\\([^\"]*\\."
 618                                     (regexp-quote (car types)) "\\)\"")
 619                             nil t)))
 620             (pop types))
 621           (push (cons (list cur-user cur-host cur-db)
 622                       (buffer-substring (match-beginning 1) (match-end 1)))
 623                 res))))
 624     (nreverse res)))
 625
 626 ;;; picon network display functions :
 627
 628 (defun gnus-picons-network-display-internal (sym-ann glyph part right-p)
 629   (gnus-picons-display-picon-or-name glyph part right-p)
 630   (gnus-picons-next-job-internal))
 631
 632 (defun gnus-picons-network-display-callback (url part sym-ann right-p)
 633   (let ((glyph (gnus-picons-make-glyph (cdr (assoc url-current-mime-type
 634                                                    w3-image-mappings)))))
 635     (kill-buffer (current-buffer))
 636     (push (cons url glyph) gnus-picons-glyph-alist)
 637     ;; only do the job if it has not been preempted.
 638     (if (equal gnus-picons-job-already-running
 639                (list sym-ann 'picon url part right-p))
 640         (gnus-picons-network-display-internal sym-ann glyph part right-p)
 641       (gnus-picons-next-job-internal))))
 642
 643 (defun gnus-picons-network-display (url part sym-ann right-p)
 644   (let ((cache (assoc url gnus-picons-glyph-alist)))
 645     (if (or cache (null url))
 646         (gnus-picons-network-display-internal sym-ann (cdr cache) part right-p)
 647       (gnus-picons-url-retrieve url 'gnus-picons-network-display-callback
 648                                 (list url part sym-ann right-p)))))
 649
 650 ;;; search job functions
 651
 652 (defun gnus-picons-network-search-internal (user addrs dbs sym-ann right-p
 653                                                  &optional fnames)
 654   (let (curkey dom pfx url dbs-tmp cache new-jobs)
 655     ;; First do the domain search
 656     (dolist (part (if right-p
 657                       (reverse addrs)
 658                     addrs))
 659       (setq pfx (nconc (list part) pfx)
 660             dom (cond ((and dom right-p) (concat part "." dom))
 661                       (dom (concat dom "." part))
 662                       (t part))
 663             curkey (list "unknown" dom dbs))
 664       (when (null (setq cache (assoc curkey gnus-picons-url-alist)))
 665         ;; This one is not yet in the cache, create a new entry
 666         ;; Search for an entry
 667         (setq dbs-tmp dbs
 668               url nil)
 669         (while (and dbs-tmp (null url))
 670           (setq url (or (cdr (assoc (list "unknown" pfx (car dbs-tmp)) fnames))
 671                         (and (eq dom part)
 672                              ;; This is the first component.  Try the
 673                              ;; catch-all MISC component
 674                              (cdr (assoc (list "unknown"
 675                                                '("MISC")
 676                                                (car dbs-tmp))
 677                                          fnames)))))
 678           (pop dbs-tmp))
 679         (push (setq cache (cons curkey url)) gnus-picons-url-alist))
 680       ;; Put this glyph in the job list
 681       (if (and (not (eq dom part)) gnus-picons-display-as-address)
 682           (push (list sym-ann "." right-p) new-jobs))
 683       (push (list sym-ann 'picon (cdr cache) part right-p) new-jobs))
 684     ;; next, the user search
 685     (when user
 686       (setq curkey (list user dom gnus-picons-user-directories))
 687       (if (null (setq cache (assoc curkey gnus-picons-url-alist)))
 688           (let ((users (list user "unknown"))
 689                 dirs usr domains-tmp dir picon)
 690             (while (and users (null picon))
 691               (setq dirs gnus-picons-user-directories
 692                     usr (pop users))
 693               (while (and dirs (null picon))
 694                 (setq domains-tmp addrs
 695                       dir (pop dirs))
 696                 (while (and domains-tmp
 697                             (null (setq picon (assoc (list usr domains-tmp dir)
 698                                                      fnames))))
 699                   (pop domains-tmp))
 700                 (unless picon
 701                   (setq picon (assoc (list usr '("MISC") dir) fnames)))))
 702             (push (setq cache (cons curkey (cdr picon)))
 703                   gnus-picons-url-alist)))
 704       (if (and gnus-picons-display-as-address new-jobs)
 705           (push (list sym-ann "@" right-p) new-jobs))
 706       (push (list sym-ann 'picon (cdr cache) user right-p) new-jobs))
 707     (if (and gnus-picons-display-as-address (not right-p))
 708         (push (list sym-ann 'bar right-p) new-jobs))
 709     ;; only put the jobs in the queue if this job has not been preempted.
 710     (if (equal gnus-picons-job-already-running
 711                (list sym-ann 'search user addrs dbs right-p))
 712         (setq gnus-picons-jobs-alist
 713               (nconc (if (and gnus-picons-display-as-address right-p)
 714                          (list (list sym-ann 'bar right-p)))
 715                      (nreverse new-jobs)
 716                      gnus-picons-jobs-alist)))
 717     (gnus-picons-next-job-internal)))
 718
 719 (defun gnus-picons-network-search-callback (user addrs dbs sym-ann right-p)
 720   (gnus-picons-network-search-internal user addrs dbs sym-ann right-p
 721                                        (prog1 (gnus-picons-parse-filenames)
 722                                          (kill-buffer (current-buffer)))))
 723
 724 ;; Initiate a query on the picon database
 725 (defun gnus-picons-network-search (user addrs dbs sym-ann right-p)
 726   (let* ((host (mapconcat 'identity addrs "."))
 727          (key (list (or user "unknown") host (if user
 728                                                   gnus-picons-user-directories
 729                                                 dbs)))
 730          (cache (assoc key gnus-picons-url-alist)))
 731     (if (null cache)
 732         (gnus-picons-url-retrieve
 733          (concat gnus-picons-piconsearch-url
 734                  "?user=" (w3-form-encode-xwfu (or user "unknown"))
 735                  "&host=" (w3-form-encode-xwfu host)
 736                  "&db=" (mapconcat 'w3-form-encode-xwfu
 737                                    (if user
 738                                        (append dbs
 739                                                gnus-picons-user-directories)
 740                                      dbs)
 741                                    "+"))
 742          'gnus-picons-network-search-callback
 743          (list user addrs dbs sym-ann right-p))
 744       (gnus-picons-network-search-internal user addrs dbs sym-ann right-p))))
 745
 746 ;;; Main jobs dispatcher function
 747
 748 (defun gnus-picons-next-job-internal ()
 749   (when (setq gnus-picons-job-already-running (pop gnus-picons-jobs-alist))
 750     (let* ((job gnus-picons-job-already-running)
 751            (sym-ann (pop job))
 752            (tag (pop job)))
 753       (when tag
 754         (cond
 755          ((stringp tag);; (SYM-ANN "..." RIGHT-P)
 756           (gnus-picons-network-display-internal
 757            sym-ann nil tag (pop job)))
 758          ((eq 'bar tag)
 759           (gnus-picons-network-display-internal
 760            sym-ann
 761            (let ((gnus-picons-file-suffixes '("xbm")))
 762              (gnus-picons-try-face
 763               gnus-xmas-glyph-directory "bar."))
 764            nil (pop job)))
 765          ((eq 'search tag);; (SYM-ANN 'search USER ADDRS DBS RIGHT-P)
 766           (gnus-picons-network-search
 767            (pop job) (pop job) (pop job) sym-ann (pop job)))
 768          ((eq 'picon tag);; (SYM-ANN 'picon URL PART RIGHT-P)
 769           (gnus-picons-network-display
 770            (pop job) (pop job) sym-ann (pop job)))
 771          (t
 772           (setq gnus-picons-job-already-running nil)
 773           (error "Unknown picon job tag %s" tag)))))))
 774
 775 (defun gnus-picons-next-job ()
 776   "Start processing the job queue if it is not in progress."
 777   (unless gnus-picons-job-already-running
 778     (gnus-picons-next-job-internal)))
 779
 780 (provide 'gnus-picon)
 781
 782 ;;; gnus-picon.el ends here