cgit.sxemacs.org Git - gnus/blob - lisp/gnus-picon.el

   1 ;;; gnus-picon.el --- displaying pretty icons in Gnus
   2 ;; Copyright (C) 1996,97,98 Free Software Foundation, Inc.
   3
   4 ;; Author: Wes Hardaker <hardaker@ece.ucdavis.edu>
   5 ;; Keywords: news xpm annotation glyph faces
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  22 ;; Boston, MA 02111-1307, USA.
  23
  24 ;;; Commentary:
  25
  26 ;;; Code:
  27
  28 (require 'gnus)
  29 (require 'xpm)
  30 (require 'annotations)
  31 (require 'custom)
  32 (require 'gnus-art)
  33 (require 'gnus-win)
  34
  35 ;;; User variables:
  36
  37 (defgroup picons nil
  38   "Show pictures of people, domains, and newsgroups (XEmacs).
  39 For this to work, you must add gnus-group-display-picons to the
  40 gnus-summary-display-hook or to the gnus-article-display-hook
  41 depending on what gnus-picons-display-where is set to.  You must
  42 also add gnus-article-display-picons to gnus-article-display-hook."
  43   :group 'gnus-visual)
  44
  45 (defcustom gnus-picons-display-where 'picons
  46   "Where to display the group and article icons.
  47 Legal values are `article' and `picons'."
  48   :type '(choice symbol string)
  49   :group 'picons)
  50
  51 (defcustom gnus-picons-has-modeline-p t
  52   "*Whether the picons window should have a modeline.
  53 This is only useful if `gnus-picons-display-where' is `picons'."
  54   :type 'boolean
  55   :group 'picons)
  56
  57 (defcustom gnus-picons-database "/usr/local/faces"
  58   "*Defines the location of the faces database.
  59 For information on obtaining this database of pretty pictures, please
  60 see http://www.cs.indiana.edu/picons/ftp/index.html"
  61   :type 'directory
  62   :group 'picons)
  63
  64 (defcustom gnus-picons-news-directories '("news")
  65   "*List of directories to search for newsgroups faces."
  66   :type '(repeat string)
  67   :group 'picons)
  68 (define-obsolete-variable-alias 'gnus-picons-news-directory
  69   'gnus-picons-news-directories)
  70
  71 (defcustom gnus-picons-user-directories '("local" "users" "usenix" "misc")
  72   "*List of directories to search for user faces."
  73   :type '(repeat string)
  74   :group 'picons)
  75
  76 (defcustom gnus-picons-domain-directories '("domains")
  77   "*List of directories to search for domain faces.
  78 Some people may want to add \"unknown\" to this list."
  79   :type '(repeat string)
  80   :group 'picons)
  81
  82 (defcustom gnus-picons-refresh-before-display nil
  83   "*If non-nil, display the article buffer before computing the picons."
  84   :type 'boolean
  85   :group 'picons)
  86
  87 (defcustom gnus-picons-group-excluded-groups nil
  88   "*If this regexp matches the group name, group picons will be disabled."
  89   :type 'regexp
  90   :group 'picons)
  91
  92 (defcustom gnus-picons-x-face-file-name
  93   (format "/tmp/picon-xface.%s.xbm" (user-login-name))
  94   "*The name of the file in which to store the converted X-face header."
  95   :type 'string
  96   :group 'picons)
  97
  98 (defcustom gnus-picons-convert-x-face (format "{ echo '/* Width=48, Height=48 */'; uncompface; } | icontopbm | pbmtoxbm > %s" gnus-picons-x-face-file-name)
  99   "*Command to convert the x-face header into a xbm file."
 100   :type 'string
 101   :group 'picons)
 102
 103 (defcustom gnus-picons-display-as-address t
 104   "*If t display textual email addresses along with pictures."
 105   :type 'boolean
 106   :group 'picons)
 107
 108 (defcustom gnus-picons-file-suffixes
 109   (when (featurep 'x)
 110     (let ((types (list "xbm")))
 111       (when (featurep 'gif)
 112         (push "gif" types))
 113       (when (featurep 'xpm)
 114         (push "xpm" types))
 115       types))
 116   "*List of suffixes on picon file names to try."
 117   :type '(repeat string)
 118   :group 'picons)
 119
 120 (defcustom gnus-picons-display-article-move-p t
 121   "*Whether to move point to first empty line when displaying picons.
 122 This has only an effect if `gnus-picons-display-where' has value `article'."
 123   :type 'boolean
 124   :group 'picons)
 125
 126 (defcustom gnus-picons-clear-cache-on-shutdown t
 127   "*Whether to clear the picons cache when exiting gnus.
 128 Gnus caches every picons it finds while it is running.  This saves
 129 some time in the search process but eats some memory.  If this
 130 variable is set to nil, Gnus will never clear the cache itself; you
 131 will have to manually call `gnus-picons-clear-cache' to clear it.
 132 Otherwise the cache will be cleared every time you exit Gnus."
 133   :type 'boolean
 134   :group 'picons)
 135
 136 (defcustom gnus-picons-piconsearch-url nil
 137   "*The url to query for picons.  Setting this to nil will disable it.
 138 The only publicly available address currently known is
 139 http://www.cs.indiana.edu:800/piconsearch.  If you know of any other,
 140 please tell me so that we can list it."
 141   :type '(choice (const :tag "Disable" :value nil)
 142                  (const :tag "www.cs.indiana.edu"
 143                         :value "http://www.cs.indiana.edu:800/piconsearch")
 144                  (string))
 145   :group 'picons)
 146
 147 (defface gnus-picons-xbm-face '((t (:foreground "black" :background "white")))
 148   "Face to show X face"
 149   :group 'picons)
 150
 151 ;;; Internal variables:
 152
 153 (defvar gnus-picons-processes-alist nil
 154   "Picons processes currently running and their environment.")
 155 (defvar gnus-picons-glyph-alist nil
 156   "Picons glyphs cache.
 157 List of pairs (KEY . GLYPH) where KEY is either a filename or an URL.")
 158 (defvar gnus-picons-url-alist nil
 159   "Picons file names cache.
 160 List of pairs (KEY . NAME) where KEY is (USER HOST DBS) and NAME is an URL.")
 161
 162 (defvar gnus-picons-jobs-alist nil
 163   "List of jobs that still need be done.
 164 This is a list of (SYM-ANN TAG ARGS...) where SYM-ANN three annotations list,
 165 TAG is one of `picon' or `search' indicating that the job should query a
 166 picon or do a search for picons file names, and ARGS is some additionnal
 167 arguments necessary for the job.")
 168
 169 (defvar gnus-picons-job-already-running nil
 170   "Lock to ensure only one stream of http requests is running.")
 171
 172 ;;; Functions:
 173
 174 (defun gnus-picons-remove-all ()
 175   "Removes all picons from the Gnus display(s)."
 176   (interactive)
 177   (map-extents (function (lambda (ext unused) (delete-annotation ext) nil))
 178                nil nil nil nil nil 'gnus-picon)
 179   (setq gnus-picons-jobs-alist '())
 180   ;; notify running job that it may have been preempted
 181   (if (and (listp gnus-picons-job-already-running)
 182            gnus-picons-job-already-running)
 183       (setq gnus-picons-job-already-running t)))
 184
 185 (defun gnus-get-buffer-name (variable)
 186   "Returns the buffer name associated with the contents of a variable."
 187   (cond ((symbolp variable) (let ((newvar (cdr (assq variable
 188                                                      gnus-window-to-buffer))))
 189                               (cond ((symbolp newvar)
 190                                      (symbol-value newvar))
 191                                     ((stringp newvar) newvar))))
 192         ((stringp variable) variable)))
 193
 194 (defun gnus-picons-set-buffer ()
 195   (set-buffer
 196    (get-buffer-create (gnus-get-buffer-name gnus-picons-display-where)))
 197   (gnus-add-current-to-buffer-list)
 198   (goto-char (point-min))
 199   (if (and (eq gnus-picons-display-where 'article)
 200            gnus-picons-display-article-move-p)
 201       (if (search-forward "\n\n" nil t)
 202           (forward-line -1)
 203         (goto-char (point-max)))
 204     (setq buffer-read-only t)
 205     (unless gnus-picons-has-modeline-p
 206       (set-specifier has-modeline-p
 207                      (list (list (current-buffer)
 208                                  (cons nil gnus-picons-has-modeline-p)))))))
 209
 210 (defun gnus-picons-prepare-for-annotations ()
 211   "Prepare picons buffer for putting annotations."
 212   ;; let drawing catch up
 213   (when gnus-picons-refresh-before-display
 214     (sit-for 0))
 215   (gnus-picons-set-buffer)
 216   (gnus-picons-remove-all))
 217
 218 (defun gnus-picons-make-annotation (&rest args)
 219   (let ((annot (apply 'make-annotation args)))
 220     (set-extent-property annot 'gnus-picon t)
 221     (set-extent-property annot 'duplicable t)
 222     annot))
 223
 224 (defun gnus-picons-article-display-x-face ()
 225   "Display the x-face header bitmap in the 'gnus-picons-display-where buffer."
 226   (let ((gnus-article-x-face-command 'gnus-picons-display-x-face))
 227     (gnus-article-display-x-face)))
 228
 229 (defun gnus-picons-x-face-sentinel (process event)
 230   (when (memq process gnus-picons-processes-alist)
 231     (setq gnus-picons-processes-alist
 232           (delq process gnus-picons-processes-alist))
 233     (gnus-picons-set-buffer)
 234     (gnus-picons-make-annotation (make-glyph gnus-picons-x-face-file-name)
 235                                  nil 'text)
 236     (delete-file gnus-picons-x-face-file-name)))
 237
 238 (defun gnus-picons-display-x-face (beg end)
 239   "Function to display the x-face header in the picons window.
 240 To use:  (setq gnus-article-x-face-command 'gnus-picons-display-x-face)"
 241   (interactive)
 242   (if (featurep 'xface)
 243       ;; Use builtin support
 244       (save-excursion
 245         (gnus-picons-set-buffer)
 246         (gnus-picons-make-annotation
 247          (vector 'xface
 248                  :data (concat "X-Face: " (buffer-substring beg end)))
 249          nil 'text))
 250     ;; convert the x-face header to a .xbm file
 251     (let* ((process-connection-type nil)
 252            (process (start-process-shell-command "gnus-x-face" nil
 253                                                  gnus-picons-convert-x-face)))
 254       (push process gnus-picons-processes-alist)
 255       (process-kill-without-query process)
 256       (set-process-sentinel process 'gnus-picons-x-face-sentinel)
 257       (process-send-region process beg end)
 258       (process-send-eof process))))
 259
 260 (defun gnus-article-display-picons ()
 261   "Display faces for an author and her domain in gnus-picons-display-where."
 262   (interactive)
 263   (let (from at-idx)
 264     (when (and (featurep 'xpm)
 265                (or (not (fboundp 'device-type)) (equal (device-type) 'x))
 266                (setq from (mail-fetch-field "from"))
 267                (setq from (downcase (or (cadr (mail-extract-address-components
 268                                                from))
 269                                         "")))
 270                (or (setq at-idx (string-match "@" from))
 271                    (setq at-idx (length from))))
 272       (save-excursion
 273         (let ((username (downcase (substring from 0 at-idx)))
 274               (addrs (if (eq at-idx (length from))
 275                          (if gnus-local-domain
 276                              (message-tokenize-header gnus-local-domain "."))
 277                        (message-tokenize-header (substring from (1+ at-idx))
 278                                                 "."))))
 279           (gnus-picons-prepare-for-annotations)
 280           (gnus-group-display-picons)
 281           (if (null gnus-picons-piconsearch-url)
 282               (progn
 283                 (gnus-picons-display-pairs (gnus-picons-lookup-pairs
 284                                             addrs
 285                                             gnus-picons-domain-directories)
 286                                            gnus-picons-display-as-address
 287                                            "." t)
 288                 (if (and gnus-picons-display-as-address addrs)
 289                     (gnus-picons-make-annotation
 290                      [string :data "@"] nil 'text nil nil nil t))
 291                 (gnus-picons-display-picon-or-name
 292                  (gnus-picons-lookup-user username addrs)
 293                  username t))
 294             (push (list 'gnus-article-annotations 'search username addrs
 295                         gnus-picons-domain-directories t)
 296                   gnus-picons-jobs-alist)
 297             (gnus-picons-next-job)))))))
 298
 299 (defun gnus-group-display-picons ()
 300   "Display icons for the group in the `gnus-picons-display-where' buffer."
 301   (interactive)
 302   (when (and (featurep 'xpm)
 303              (or (not (fboundp 'device-type)) (equal (device-type) 'x))
 304              (or (null gnus-picons-group-excluded-groups)
 305                  (not (string-match gnus-picons-group-excluded-groups
 306                                     gnus-newsgroup-name))))
 307     (save-excursion
 308       (gnus-picons-prepare-for-annotations)
 309       (if (null gnus-picons-piconsearch-url)
 310           (gnus-picons-display-pairs
 311                  (gnus-picons-lookup-pairs
 312                   (reverse (message-tokenize-header
 313                             (gnus-group-real-name gnus-newsgroup-name)
 314                             "."))
 315                   gnus-picons-news-directories)
 316                  t ".")
 317         (push (list 'gnus-group-annotations 'search nil
 318                     (message-tokenize-header
 319                      (gnus-group-real-name gnus-newsgroup-name) ".")
 320                     (if (listp gnus-picons-news-directories)
 321                         gnus-picons-news-directories
 322                       (list gnus-picons-news-directories))
 323                     nil)
 324               gnus-picons-jobs-alist)
 325         (gnus-picons-next-job))
 326
 327       (add-hook 'gnus-summary-exit-hook 'gnus-picons-remove-all))))
 328
 329 (defun gnus-picons-lookup-internal (addrs dir)
 330   (setq dir (expand-file-name dir gnus-picons-database))
 331   (gnus-picons-try-face (dolist (part (reverse addrs) dir)
 332                           (setq dir (expand-file-name part dir)))))
 333
 334 (defun gnus-picons-lookup (addrs dirs)
 335   "Lookup the picon for ADDRS in databases DIRS.
 336 Returns the picon filename or NIL if none found."
 337   (let (result)
 338     (while (and dirs (null result))
 339       (setq result (gnus-picons-lookup-internal addrs (pop dirs))))
 340     result))
 341
 342 (defun gnus-picons-lookup-user-internal (user domains)
 343   (let ((dirs gnus-picons-user-directories)
 344         domains-tmp dir picon)
 345     (while (and dirs (null picon))
 346       (setq domains-tmp domains
 347             dir (pop dirs))
 348       (while (and domains-tmp
 349                   (null (setq picon (gnus-picons-lookup-internal
 350                                      (cons user domains-tmp) dir))))
 351         (pop domains-tmp))
 352       ;; Also make a try in MISC subdir
 353       (unless picon
 354         (setq picon (gnus-picons-lookup-internal (list user "MISC") dir))))
 355     picon))
 356
 357 (defun gnus-picons-lookup-user (user domains)
 358   "Lookup the picon for USER at DOMAINS.
 359 USER is a string containing a name.
 360 DOMAINS is a list of strings from the fully qualified domain name."
 361   (or (gnus-picons-lookup-user-internal user domains)
 362       (gnus-picons-lookup-user-internal "unknown" domains)))
 363
 364 (defun gnus-picons-lookup-pairs (domains directories)
 365   "Lookup picons for DOMAINS and all its parents in DIRECTORIES.
 366 Returns a list of PAIRS whose CAR is the picon filename or NIL if
 367 none, and whose CDR is the corresponding element of DOMAINS."
 368   (let (picons)
 369     (setq directories (if (listp directories)
 370                           directories
 371                         (list directories)))
 372     (while domains
 373       (push (list (gnus-picons-lookup (cons "unknown" domains) directories)
 374                   (pop domains))
 375             picons))
 376     picons))
 377
 378 (defun gnus-picons-display-picon-or-name (picon name &optional right-p)
 379   (cond (picon (gnus-picons-display-glyph picon name right-p))
 380         (gnus-picons-display-as-address (list (gnus-picons-make-annotation
 381                                                (vector 'string :data name)
 382                                                nil 'text
 383                                                nil nil nil right-p)))))
 384
 385 (defun gnus-picons-display-pairs (pairs &optional bar-p dot-p right-p)
 386   "Display picons in list PAIRS."
 387   (let ((domain-p (and gnus-picons-display-as-address dot-p))
 388         pair picons)
 389     (when (and bar-p domain-p right-p)
 390       (setq picons (gnus-picons-display-glyph
 391                     (let ((gnus-picons-file-suffixes '("xbm")))
 392                       (gnus-picons-try-face
 393                        gnus-xmas-glyph-directory "bar."))
 394                     nil right-p)))
 395     (while (setq pair (pop pairs))
 396       (setq picons (nconc picons
 397                           (gnus-picons-display-picon-or-name
 398                            (car pair) (cadr pair) right-p)
 399                           (if (and domain-p pairs)
 400                               (list (gnus-picons-make-annotation
 401                                      (vector 'string :data dot-p)
 402                                      nil 'text nil nil nil right-p))))))
 403     picons))
 404
 405 (defun gnus-picons-try-face (dir &optional filebase)
 406   (let* ((dir (file-name-as-directory dir))
 407          (filebase (or filebase "face."))
 408          (key (concat dir filebase))
 409          (glyph (cdr (assoc key gnus-picons-glyph-alist)))
 410          (suffixes gnus-picons-file-suffixes)
 411          f suf)
 412     (while (setq suf (pop suffixes))
 413       (when (file-exists-p (setq f (expand-file-name
 414                                     (concat filebase suf)
 415                                     dir)))
 416         (setq suffixes nil
 417               glyph (make-glyph f))
 418         (when (equal suf "xbm")
 419           (set-glyph-face glyph 'gnus-picons-xbm-face))
 420         (push (cons key glyph) gnus-picons-glyph-alist)))
 421     glyph))
 422
 423 (defun gnus-picons-display-glyph (glyph &optional part rightp)
 424   (let ((new (gnus-picons-make-annotation
 425               glyph (point) 'text nil nil nil rightp)))
 426     (when (and part gnus-picons-display-as-address)
 427       (set-annotation-data
 428        new (cons new (make-glyph (vector 'string :data part))))
 429       (set-annotation-action new 'gnus-picons-action-toggle))
 430     (nconc
 431      (list new)
 432      (if (and (eq major-mode 'gnus-article-mode)
 433               (not gnus-picons-display-as-address)
 434               (not part))
 435          (list (gnus-picons-make-annotation [string :data " "] (point)
 436                                             'text nil nil nil rightp))))))
 437
 438 (defun gnus-picons-action-toggle (data)
 439   "Toggle annotation"
 440   (interactive "e")
 441   (let* ((annot (car data))
 442          (glyph (annotation-glyph annot)))
 443     (set-annotation-glyph annot (cdr data))
 444     (set-annotation-data annot (cons annot glyph))))
 445
 446 (defun gnus-picons-clear-cache ()
 447   "Clear the picons cache"
 448   (interactive)
 449   (setq gnus-picons-glyph-alist nil
 450         gnus-picons-url-alist nil))
 451
 452 (gnus-add-shutdown 'gnus-picons-close 'gnus)
 453
 454 (defun gnus-picons-close ()
 455   "Shut down the picons."
 456   (if gnus-picons-clear-cache-on-shutdown
 457       (gnus-picons-clear-cache)))
 458
 459 ;;; Query a remote DB.  This requires some stuff from w3 !
 460
 461 (require 'url)
 462 (require 'w3-forms)
 463
 464 (defun gnus-picons-url-retrieve (url fn arg)
 465   (let ((old-asynch (default-value 'url-be-asynchronous))
 466         (url-working-buffer (generate-new-buffer " *picons*"))
 467         (url-package-name "Gnus")
 468         (url-package-version gnus-version-number)
 469         url-request-method)
 470     (setq-default url-be-asynchronous t)
 471     (save-excursion
 472       (set-buffer url-working-buffer)
 473       (setq url-be-asynchronous t
 474             url-current-callback-data arg
 475             url-current-callback-func fn)
 476       (url-retrieve url t))
 477     (setq-default url-be-asynchronous old-asynch)))
 478
 479 (defun gnus-picons-make-glyph (type)
 480   "Make a TYPE glyph using current buffer as data.  Handles xbm nicely."
 481   (cond ((null type) nil)
 482         ((eq type 'xbm) (let ((fname (make-temp-name "/tmp/picon")))
 483                           (write-region (point-min) (point-max) fname
 484                                         nil 'quiet)
 485                           (prog1 (make-glyph (vector 'xbm :file fname))
 486                             (delete-file fname))))
 487         (t (make-glyph (vector type :data (buffer-string))))))
 488
 489 ;;; Parsing of piconsearch result page.
 490
 491 ;; Assumes:
 492 ;; 1 - each value field has the form: "<strong>key</strong> = <kbd>value</kbd>"
 493 ;; 2 - a "<p>" separates the keywords from the results
 494 ;; 3 - every results begins by the path within the database at the beginning
 495 ;;     of the line in raw text.
 496 ;; 3b - and the href following it is the preferred image type.
 497
 498 ;; if 1 or 2 is not met, it will probably cause an error.  The other
 499 ;; will go undetected
 500
 501 (defun gnus-picons-parse-value (name)
 502   (goto-char (point-min))
 503   (re-search-forward (concat "<strong>"
 504                              (regexp-quote name)
 505                              "</strong> *= *<kbd> *\\([^ <][^<]*\\) *</kbd>"))
 506   (buffer-substring (match-beginning 1) (match-end 1)))
 507
 508 (defun gnus-picons-parse-filenames ()
 509   ;; returns an alist of ((USER ADDRS DB) . URL)
 510   (let* ((case-fold-search t)
 511          (user (gnus-picons-parse-value "user"))
 512          (host (gnus-picons-parse-value "host"))
 513          (dbs (message-tokenize-header (gnus-picons-parse-value "db") " "))
 514          (start-re
 515           (concat
 516            ;; dbs
 517            "^\\(" (mapconcat 'identity dbs "\\|") "\\)/"
 518            ;; host
 519            "\\(\\(" (replace-in-string host "\\." "/\\|" t) "/\\|MISC/\\)*\\)"
 520            ;; user
 521            "\\(" (regexp-quote user) "\\|unknown\\)/"
 522            "face\\."))
 523          cur-db cur-host cur-user types res)
 524     ;; now point will be somewhere in the header.  Find beginning of
 525     ;; entries
 526     (re-search-forward "<p>[ \t\n]*")
 527     (while (re-search-forward start-re nil t)
 528       (setq cur-db (buffer-substring (match-beginning 1) (match-end 1))
 529             cur-host (buffer-substring (match-beginning 2) (match-end 2))
 530             cur-user (buffer-substring (match-beginning 4) (match-end 4))
 531             cur-host (nreverse (message-tokenize-header cur-host "/")))
 532       ;; XXX - KLUDGE: there is a blank picon in news/MISC/unknown
 533       (unless (and (string-equal cur-db "news")
 534                    (string-equal cur-user "unknown")
 535                    (equal cur-host '("MISC")))
 536         ;; ok now we have found an entry (USER HOST DB), find the
 537         ;; corresponding picon URL
 538         (save-restriction
 539           ;; restrict region to this entry
 540           (narrow-to-region (point) (search-forward "<br>"))
 541           (goto-char (point-min))
 542           (setq types gnus-picons-file-suffixes)
 543           (while (and types
 544                       (not (re-search-forward
 545                             (concat "<a[ \t\n]+href=\"\\([^\"]*\\."
 546                                     (regexp-quote (car types)) "\\)\"")
 547                             nil t)))
 548             (pop types))
 549           (push (cons (list cur-user cur-host cur-db)
 550                       (buffer-substring (match-beginning 1) (match-end 1)))
 551                 res))))
 552     (nreverse res)))
 553
 554 ;;; picon network display functions :
 555
 556 (defun gnus-picons-network-display-internal (sym-ann glyph part right-p)
 557   (gnus-picons-set-buffer)
 558   (gnus-picons-display-picon-or-name glyph part right-p)
 559   (gnus-picons-next-job-internal))
 560
 561 (defun gnus-picons-network-display-callback (url part sym-ann right-p)
 562   (let ((glyph (gnus-picons-make-glyph (cdr (assoc url-current-mime-type
 563                                                    w3-image-mappings)))))
 564     (kill-buffer (current-buffer))
 565     (push (cons url glyph) gnus-picons-glyph-alist)
 566     ;; only do the job if it has not been preempted.
 567     (if (equal gnus-picons-job-already-running
 568                (list sym-ann 'picon url part right-p))
 569         (gnus-picons-network-display-internal sym-ann glyph part right-p)
 570       (gnus-picons-next-job-internal))))
 571
 572 (defun gnus-picons-network-display (url part sym-ann right-p)
 573   (let ((cache (assoc url gnus-picons-glyph-alist)))
 574     (if (or cache (null url))
 575         (gnus-picons-network-display-internal sym-ann (cdr cache) part right-p)
 576       (gnus-picons-url-retrieve url 'gnus-picons-network-display-callback
 577                                 (list url part sym-ann right-p)))))
 578
 579 ;;; search job functions
 580
 581 (defun gnus-picons-network-search-internal (user addrs dbs sym-ann right-p
 582                                                  &optional fnames)
 583   (let (curkey dom pfx url dbs-tmp cache new-jobs)
 584     ;; First do the domain search
 585     (dolist (part (if right-p
 586                       (reverse addrs)
 587                     addrs))
 588       (setq pfx (nconc (list part) pfx)
 589             dom (cond ((and dom right-p) (concat part "." dom))
 590                       (dom (concat dom "." part))
 591                       (t part))
 592             curkey (list "unknown" dom dbs))
 593       (when (null (setq cache (assoc curkey gnus-picons-url-alist)))
 594         ;; This one is not yet in the cache, create a new entry
 595         ;; Search for an entry
 596         (setq dbs-tmp dbs
 597               url nil)
 598         (while (and dbs-tmp (null url))
 599           (setq url (or (cdr (assoc (list "unknown" pfx (car dbs-tmp)) fnames))
 600                         (and (eq dom part)
 601                              ;; This is the first component.  Try the
 602                              ;; catch-all MISC component
 603                              (cdr (assoc (list "unknown"
 604                                                '("MISC")
 605                                                (car dbs-tmp))
 606                                          fnames)))))
 607           (pop dbs-tmp))
 608         (push (setq cache (cons curkey url)) gnus-picons-url-alist))
 609       ;; Put this glyph in the job list
 610       (if (and (not (eq dom part)) gnus-picons-display-as-address)
 611           (push (list sym-ann "." right-p) new-jobs))
 612       (push (list sym-ann 'picon (cdr cache) part right-p) new-jobs))
 613     ;; next, the user search
 614     (when user
 615       (setq curkey (list user dom gnus-picons-user-directories))
 616       (if (null (setq cache (assoc curkey gnus-picons-url-alist)))
 617           (let ((users (list user "unknown"))
 618                 dirs usr domains-tmp dir picon)
 619             (while (and users (null picon))
 620               (setq dirs gnus-picons-user-directories
 621                     usr (pop users))
 622               (while (and dirs (null picon))
 623                 (setq domains-tmp addrs
 624                       dir (pop dirs))
 625                 (while (and domains-tmp
 626                             (null (setq picon (assoc (list usr domains-tmp dir)
 627                                                      fnames))))
 628                   (pop domains-tmp))
 629                 (unless picon
 630                   (setq picon (assoc (list usr '("MISC") dir) fnames)))))
 631             (push (setq cache (cons curkey (cdr picon)))
 632                   gnus-picons-url-alist)))
 633       (if (and gnus-picons-display-as-address new-jobs)
 634           (push (list sym-ann "@" right-p) new-jobs))
 635       (push (list sym-ann 'picon (cdr cache) user right-p) new-jobs))
 636     (if (and gnus-picons-display-as-address (not right-p))
 637         (push (list sym-ann 'bar right-p) new-jobs))
 638     ;; only put the jobs in the queue if this job has not been preempted.
 639     (if (equal gnus-picons-job-already-running
 640                (list sym-ann 'search user addrs dbs right-p))
 641         (setq gnus-picons-jobs-alist
 642               (nconc (if (and gnus-picons-display-as-address right-p)
 643                          (list (list sym-ann 'bar right-p)))
 644                      (nreverse new-jobs)
 645                      gnus-picons-jobs-alist)))
 646     (gnus-picons-next-job-internal)))
 647
 648 (defun gnus-picons-network-search-callback (user addrs dbs sym-ann right-p)
 649   (gnus-picons-network-search-internal user addrs dbs sym-ann right-p
 650                                        (prog1 (gnus-picons-parse-filenames)
 651                                          (kill-buffer (current-buffer)))))
 652
 653 ;; Initiate a query on the picon database
 654 (defun gnus-picons-network-search (user addrs dbs sym-ann right-p)
 655   (let* ((host (mapconcat 'identity addrs "."))
 656          (key (list (or user "unknown") host (if user
 657                                                   gnus-picons-user-directories
 658                                                 dbs)))
 659          (cache (assoc key gnus-picons-url-alist)))
 660     (if (null cache)
 661         (gnus-picons-url-retrieve
 662          (concat gnus-picons-piconsearch-url
 663                  "?user=" (w3-form-encode-xwfu (or user "unknown"))
 664                  "&host=" (w3-form-encode-xwfu host)
 665                  "&db=" (mapconcat 'w3-form-encode-xwfu
 666                                    (if user
 667                                        (append dbs
 668                                                gnus-picons-user-directories)
 669                                      dbs)
 670                                    "+"))
 671          'gnus-picons-network-search-callback
 672          (list user addrs dbs sym-ann right-p))
 673       (gnus-picons-network-search-internal user addrs dbs sym-ann right-p))))
 674
 675 ;;; Main jobs dispatcher function
 676
 677 (defun gnus-picons-next-job-internal ()
 678   (if (setq gnus-picons-job-already-running (pop gnus-picons-jobs-alist))
 679       (let* ((job gnus-picons-job-already-running)
 680              (sym-ann (pop job))
 681              (tag (pop job)))
 682         (if tag
 683             (cond ((stringp tag);; (SYM-ANN "..." RIGHT-P)
 684                    (gnus-picons-network-display-internal sym-ann nil tag
 685                                                          (pop job)))
 686                   ((eq 'bar tag)
 687                    (gnus-picons-network-display-internal
 688                     sym-ann
 689                     (let ((gnus-picons-file-suffixes '("xbm")))
 690                       (gnus-picons-try-face
 691                        gnus-xmas-glyph-directory "bar."))
 692                     nil (pop job)))
 693                   ((eq 'search tag);; (SYM-ANN 'search USER ADDRS DBS RIGHT-P)
 694                    (gnus-picons-network-search
 695                     (pop job) (pop job) (pop job) sym-ann (pop job)))
 696                   ((eq 'picon tag);; (SYM-ANN 'picon URL PART RIGHT-P)
 697                    (gnus-picons-network-display
 698                     (pop job) (pop job) sym-ann (pop job)))
 699                   (t (setq gnus-picons-job-already-running nil)
 700                      (error "Unknown picon job tag %s" tag)))))))
 701
 702 (defun gnus-picons-next-job ()
 703   "Start processing the job queue if it is not in progress"
 704   (unless gnus-picons-job-already-running
 705     (gnus-picons-next-job-internal)))
 706
 707 (provide 'gnus-picon)
 708
 709 ;;; gnus-picon.el ends here