cgit.sxemacs.org Git - gnus/blob - lisp/gnus-nocem.el

   1 ;;; gnus-nocem.el --- NoCeM pseudo-cancellation treatment
   2 ;; Copyright (C) 1995,96,97 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@ifi.uio.no>
   5 ;; Keywords: news
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  22 ;; Boston, MA 02111-1307, USA.
  23
  24 ;;; Commentary:
  25
  26 ;;; Code:
  27
  28 (require 'gnus)
  29 (require 'nnmail)
  30 (require 'gnus-art)
  31 (require 'gnus-sum)
  32 (require 'gnus-range)
  33
  34 (defgroup gnus-nocem nil
  35   "NoCeM pseudo-cancellation treatment"
  36   :group 'gnus-score)
  37
  38 (defcustom gnus-nocem-groups
  39   '("news.lists.filters" "news.admin.net-abuse.bulletins"
  40     "alt.nocem.misc" "news.admin.net-abuse.announce")
  41   "List of groups that will be searched for NoCeM messages."
  42   :group 'gnus-nocem
  43   :type '(repeat (string :tag "Group")))
  44
  45 (defcustom gnus-nocem-issuers
  46  '("AutoMoose-1" "Automoose-1"   ; CancelMoose[tm]
  47    "rbraver@ohww.norman.ok.us"   ; Robert Braver
  48    "clewis@ferret.ocunix.on.ca;" ; Chris Lewis
  49    "jem@xpat.com;"               ; Despammer from Korea
  50    "snowhare@xmission.com"       ; Benjamin "Snowhare" Franz
  51    "red@redpoll.mrfs.oh.us (Richard E. Depew)" ; ARMM! ARMM!
  52    )
  53   "List of NoCeM issuers to pay attention to."
  54   :group 'gnus-nocem
  55   :type '(repeat string))
  56
  57 (defcustom gnus-nocem-directory
  58   (nnheader-concat gnus-article-save-directory "NoCeM/")
  59   "*Directory where NoCeM files will be stored."
  60   :group 'gnus-nocem
  61   :type 'directory)
  62
  63 (defcustom gnus-nocem-expiry-wait 15
  64   "*Number of days to keep NoCeM headers in the cache."
  65   :group 'gnus-nocem
  66   :type 'integer)
  67
  68 (defcustom gnus-nocem-verifyer 'mc-verify
  69   "*Function called to verify that the NoCeM message is valid.
  70 One likely value is `mc-verify'.  If the function in this variable
  71 isn't bound, the message will be used unconditionally."
  72   :group 'gnus-nocem
  73   :type '(radio (function-item mc-verify)
  74                 (function :tag "other")))
  75
  76 (defcustom gnus-nocem-liberal-fetch nil
  77   "*If t try to fetch all messages which have @@NCM in the subject.
  78 Otherwise don't fetch messages which have references or whose message-id
  79 matches an previously scanned and verified nocem message."
  80   :group 'gnus-nocem
  81   :type 'boolean)
  82
  83 ;;; Internal variables
  84
  85 (defvar gnus-nocem-active nil)
  86 (defvar gnus-nocem-alist nil)
  87 (defvar gnus-nocem-touched-alist nil)
  88 (defvar gnus-nocem-hashtb nil)
  89 (defvar gnus-nocem-seen-message-ids nil)
  90
  91 ;;; Functions
  92
  93 (defun gnus-nocem-active-file ()
  94   (concat (file-name-as-directory gnus-nocem-directory) "active"))
  95
  96 (defun gnus-nocem-cache-file ()
  97   (concat (file-name-as-directory gnus-nocem-directory) "cache"))
  98
  99 (defun gnus-nocem-scan-groups ()
 100   "Scan all NoCeM groups for new NoCeM messages."
 101   (interactive)
 102   (let ((groups gnus-nocem-groups)
 103         (gnus-inhibit-demon t)
 104         group active gactive articles)
 105     (gnus-make-directory gnus-nocem-directory)
 106     ;; Load any previous NoCeM headers.
 107     (gnus-nocem-load-cache)
 108     ;; Read the active file if it hasn't been read yet.
 109     (and (file-exists-p (gnus-nocem-active-file))
 110          (not gnus-nocem-active)
 111          (ignore-errors
 112            (load (gnus-nocem-active-file) t t t)))
 113     ;; Go through all groups and see whether new articles have
 114     ;; arrived.
 115     (while (setq group (pop groups))
 116       (if (not (setq gactive (gnus-activate-group group)))
 117           ()                            ; This group doesn't exist.
 118         (setq active (nth 1 (assoc group gnus-nocem-active)))
 119         (when (and (not (< (cdr gactive) (car gactive))) ; Empty group.
 120                    (or (not active)
 121                        (< (cdr active) (cdr gactive))))
 122           ;; Ok, there are new articles in this group, se we fetch the
 123           ;; headers.
 124           (save-excursion
 125             (let ((dependencies (make-vector 10 nil))
 126                   headers header)
 127               (nnheader-temp-write nil
 128                 (setq headers
 129                       (if (eq 'nov
 130                               (gnus-retrieve-headers
 131                                (setq articles
 132                                      (gnus-uncompress-range
 133                                       (cons
 134                                        (if active (1+ (cdr active))
 135                                          (car gactive))
 136                                        (cdr gactive))))
 137                                group))
 138                           (gnus-get-newsgroup-headers-xover
 139                            articles nil dependencies)
 140                         (gnus-get-newsgroup-headers dependencies)))
 141                 (while (setq header (pop headers))
 142                   ;; We take a closer look on all articles that have
 143                   ;; "@@NCM" in the subject.  Unless we already read
 144                   ;; this cross posted message.  Nocem messages
 145                   ;; are not allowed to have references, so we can
 146                   ;; ignore scanning followups.
 147                   (and (string-match "@@NCM" (mail-header-subject header))
 148                        (or gnus-nocem-liberal-fetch
 149                            (and (or (string= "" (mail-header-references
 150                                                  header))
 151                                     (null (mail-header-references header)))
 152                                 (not (member (mail-header-message-id header)
 153                                              gnus-nocem-seen-message-ids))))
 154                        (gnus-nocem-check-article group header)))))))
 155         (setq gnus-nocem-active
 156               (cons (list group gactive)
 157                     (delq (assoc group gnus-nocem-active)
 158                           gnus-nocem-active)))))
 159     ;; Save the results, if any.
 160     (gnus-nocem-save-cache)
 161     (gnus-nocem-save-active)))
 162
 163 (defun gnus-nocem-check-article (group header)
 164   "Check whether the current article is an NCM article and that we want it."
 165   ;; Get the article.
 166   (gnus-message 7 "Checking article %d in %s for NoCeM..."
 167                 (mail-header-number header) group)
 168   (let ((date (mail-header-date header))
 169         issuer b e)
 170     (when (or (not date)
 171               (nnmail-time-less
 172                (nnmail-time-since (nnmail-date-to-time date))
 173                (nnmail-days-to-time gnus-nocem-expiry-wait)))
 174       (gnus-request-article-this-buffer (mail-header-number header) group)
 175       (goto-char (point-min))
 176       (when (re-search-forward "-----BEGIN PGP MESSAGE-----" nil t)
 177         (delete-region (point-min) (match-beginning 0)))
 178       (when (re-search-forward "-----END PGP MESSAGE-----\n?" nil t)
 179         (delete-region (match-end 0) (point-max)))
 180       (goto-char (point-min))
 181       ;; The article has to have proper NoCeM headers.
 182       (when (and (setq b (search-forward "\n@@BEGIN NCM HEADERS\n" nil t))
 183                  (setq e (search-forward "\n@@BEGIN NCM BODY\n" nil t)))
 184         ;; We get the name of the issuer.
 185         (narrow-to-region b e)
 186         (setq issuer (mail-fetch-field "issuer"))
 187         (widen)
 188         (and (member issuer gnus-nocem-issuers) ; We like her....
 189              (gnus-nocem-verify-issuer issuer) ; She is who she says she is...
 190              (gnus-nocem-enter-article) ; We gobble the message..
 191              (push (mail-header-message-id header) ; But don't come back for
 192                    gnus-nocem-seen-message-ids)))))) ; second helpings.
 193
 194 (defun gnus-nocem-verify-issuer (person)
 195   "Verify using PGP that the canceler is who she says she is."
 196   (if (fboundp gnus-nocem-verifyer)
 197       (ignore-errors
 198         (funcall gnus-nocem-verifyer))
 199     ;; If we don't have Mailcrypt, then we use the message anyway.
 200     t))
 201
 202 (defun gnus-nocem-enter-article ()
 203   "Enter the current article into the NoCeM cache."
 204   (goto-char (point-min))
 205   (let ((b (search-forward "\n@@BEGIN NCM BODY\n" nil t))
 206         (e (search-forward "\n@@END NCM BODY\n" nil t))
 207         (buf (current-buffer))
 208         ncm id group)
 209     (when (and b e)
 210       (narrow-to-region b (1+ (match-beginning 0)))
 211       (goto-char (point-min))
 212       (while (search-forward "\t" nil t)
 213         (cond
 214          ((not (ignore-errors
 215                  (setq group (let ((obarray gnus-active-hashtb)) (read buf)))))
 216           ;; An error.
 217           )
 218          ((not (symbolp group))
 219           ;; Ignore invalid entries.
 220           )
 221          ((not (boundp group))
 222           ;; Make sure all entries in the hashtb are bound.
 223           (set group nil))
 224          (t
 225           (when (gnus-gethash (symbol-name group) gnus-newsrc-hashtb)
 226             ;; Valid group.
 227             (beginning-of-line)
 228             (while (= (char-after (point)) ?\t)
 229               (forward-line -1))
 230             (setq id (buffer-substring (point) (1- (search-forward "\t"))))
 231             (unless (gnus-gethash id gnus-nocem-hashtb)
 232               ;; only store if not already present
 233               (gnus-sethash id t gnus-nocem-hashtb)
 234               (push id ncm))
 235             (forward-line 1)
 236             (while (= (char-after (point)) ?\t)
 237               (forward-line 1))))))
 238       (when ncm
 239         (setq gnus-nocem-touched-alist t)
 240         (push (cons (let ((time (current-time))) (setcdr (cdr time) nil) time)
 241                     ncm)
 242               gnus-nocem-alist))
 243       t)))
 244
 245 (defun gnus-nocem-load-cache ()
 246   "Load the NoCeM cache."
 247   (interactive)
 248   (unless gnus-nocem-alist
 249     ;; The buffer doesn't exist, so we create it and load the NoCeM
 250     ;; cache.
 251     (when (file-exists-p (gnus-nocem-cache-file))
 252       (load (gnus-nocem-cache-file) t t t)
 253       (gnus-nocem-alist-to-hashtb))))
 254
 255 (defun gnus-nocem-save-cache ()
 256   "Save the NoCeM cache."
 257   (when (and gnus-nocem-alist
 258              gnus-nocem-touched-alist)
 259     (nnheader-temp-write (gnus-nocem-cache-file)
 260       (gnus-prin1 `(setq gnus-nocem-alist ',gnus-nocem-alist)))
 261     (setq gnus-nocem-touched-alist nil)))
 262
 263 (defun gnus-nocem-save-active ()
 264   "Save the NoCeM active file."
 265   (nnheader-temp-write (gnus-nocem-active-file)
 266     (gnus-prin1 `(setq gnus-nocem-active ',gnus-nocem-active))))
 267
 268 (defun gnus-nocem-alist-to-hashtb ()
 269   "Create a hashtable from the Message-IDs we have."
 270   (let* ((alist gnus-nocem-alist)
 271          (pprev (cons nil alist))
 272          (prev pprev)
 273          (expiry (nnmail-days-to-time gnus-nocem-expiry-wait))
 274          entry)
 275     (setq gnus-nocem-hashtb (gnus-make-hashtable (* (length alist) 51)))
 276     (while (setq entry (car alist))
 277       (if (not (nnmail-time-less (nnmail-time-since (car entry)) expiry))
 278           ;; This entry has expired, so we remove it.
 279           (setcdr prev (cdr alist))
 280         (setq prev alist)
 281         ;; This is ok, so we enter it into the hashtable.
 282         (setq entry (cdr entry))
 283         (while entry
 284           (gnus-sethash (car entry) t gnus-nocem-hashtb)
 285           (setq entry (cdr entry))))
 286       (setq alist (cdr alist)))))
 287
 288 (gnus-add-shutdown 'gnus-nocem-close 'gnus)
 289
 290 (defun gnus-nocem-close ()
 291   "Clear internal NoCeM variables."
 292   (setq gnus-nocem-alist nil
 293         gnus-nocem-hashtb nil
 294         gnus-nocem-active nil
 295         gnus-nocem-touched-alist nil
 296         gnus-nocem-seen-message-ids nil))
 297
 298 (defun gnus-nocem-unwanted-article-p (id)
 299   "Say whether article ID in the current group is wanted."
 300   (gnus-gethash id gnus-nocem-hashtb))
 301
 302 (provide 'gnus-nocem)
 303
 304 ;;; gnus-nocem.el ends here