cgit.sxemacs.org Git - gnus/blob - lisp/gnus-msg.el

   1 ;;; gnus-msg.el --- mail and post interface for Gnus
   2
   3 ;; Copyright (C) 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003,
   4 ;;   2004, 2005, 2006, 2007 Free Software Foundation, Inc.
   5
   6 ;; Author: Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>
   7 ;;      Lars Magne Ingebrigtsen <larsi@gnus.org>
   8 ;; Keywords: news
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 2, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  25 ;; Boston, MA 02110-1301, USA.
  26
  27 ;;; Commentary:
  28
  29 ;;; Code:
  30
  31 (eval-when-compile (require 'cl))
  32
  33 (require 'gnus)
  34 (require 'gnus-ems)
  35 (require 'message)
  36 (require 'gnus-art)
  37 (require 'gnus-util)
  38
  39 (defcustom gnus-post-method 'current
  40   "*Preferred method for posting USENET news.
  41
  42 If this variable is `current' (which is the default), Gnus will use
  43 the \"current\" select method when posting.  If it is `native', Gnus
  44 will use the native select method when posting.
  45
  46 This method will not be used in mail groups and the like, only in
  47 \"real\" newsgroups.
  48
  49 If not `native' nor `current', the value must be a valid method as discussed
  50 in the documentation of `gnus-select-method'.  It can also be a list of
  51 methods.  If that is the case, the user will be queried for what select
  52 method to use when posting."
  53   :group 'gnus-group-foreign
  54   :link '(custom-manual "(gnus)Posting Server")
  55   :type `(choice (const native)
  56                  (const current)
  57                  (sexp :tag "Methods" ,gnus-select-method)))
  58
  59 (defcustom gnus-outgoing-message-group nil
  60   "*All outgoing messages will be put in this group.
  61 If you want to store all your outgoing mail and articles in the group
  62 \"nnml:archive\", you set this variable to that value.  This variable
  63 can also be a list of group names.
  64
  65 If you want to have greater control over what group to put each
  66 message in, you can set this variable to a function that checks the
  67 current newsgroup name and then returns a suitable group name (or list
  68 of names)."
  69   :group 'gnus-message
  70   :type '(choice (const nil)
  71                  (function)
  72                  (string :tag "Group")
  73                  (repeat :tag "List of groups" (string :tag "Group"))))
  74
  75 (defcustom gnus-mailing-list-groups nil
  76   "*If non-nil a regexp matching groups that are really mailing lists.
  77 This is useful when you're reading a mailing list that has been
  78 gatewayed to a newsgroup, and you want to followup to an article in
  79 the group."
  80   :group 'gnus-message
  81   :type '(choice (regexp)
  82                  (const nil)))
  83
  84 (defcustom gnus-add-to-list nil
  85   "*If non-nil, add a `to-list' parameter automatically."
  86   :group 'gnus-message
  87   :type 'boolean)
  88
  89 (defcustom gnus-crosspost-complaint
  90   "Hi,
  91
  92 You posted the article below with the following Newsgroups header:
  93
  94 Newsgroups: %s
  95
  96 The %s group, at least, was an inappropriate recipient
  97 of this message.  Please trim your Newsgroups header to exclude this
  98 group before posting in the future.
  99
 100 Thank you.
 101
 102 "
 103   "Format string to be inserted when complaining about crossposts.
 104 The first %s will be replaced by the Newsgroups header;
 105 the second with the current group name."
 106   :group 'gnus-message
 107   :type 'string)
 108
 109 (defcustom gnus-message-setup-hook nil
 110   "Hook run after setting up a message buffer."
 111   :group 'gnus-message
 112   :type 'hook)
 113
 114 (defcustom gnus-bug-create-help-buffer t
 115   "*Should we create the *Gnus Help Bug* buffer?"
 116   :group 'gnus-message
 117   :type 'boolean)
 118
 119 (defcustom gnus-posting-styles nil
 120   "*Alist of styles to use when posting.
 121 See Info node `(gnus)Posting Styles'."
 122   :group 'gnus-message
 123   :link '(custom-manual "(gnus)Posting Styles")
 124   :type '(repeat (cons (choice (regexp)
 125                                (variable)
 126                                (list (const header)
 127                                      (string :tag "Header")
 128                                      (regexp :tag "Regexp"))
 129                                (function)
 130                                (sexp))
 131                        (repeat (list
 132                                 (choice (const signature)
 133                                         (const signature-file)
 134                                         (const organization)
 135                                         (const address)
 136                                         (const x-face-file)
 137                                         (const name)
 138                                         (const body)
 139                                         (symbol)
 140                                         (string :tag "Header"))
 141                                 (choice (string)
 142                                         (function)
 143                                         (variable)
 144                                         (sexp)))))))
 145
 146 (defcustom gnus-gcc-mark-as-read nil
 147   "If non-nil, automatically mark Gcc articles as read."
 148   :version "22.1"
 149   :group 'gnus-message
 150   :type 'boolean)
 151
 152 (make-obsolete-variable 'gnus-inews-mark-gcc-as-read
 153                         'gnus-gcc-mark-as-read)
 154
 155 (defcustom gnus-gcc-externalize-attachments nil
 156   "Should local-file attachments be included as external parts in Gcc copies?
 157 If it is `all', attach files as external parts;
 158 if a regexp and matches the Gcc group name, attach files as external parts;
 159 if nil, attach files as normal parts."
 160   :version "22.1"
 161   :group 'gnus-message
 162   :type '(choice (const nil :tag "None")
 163                  (const all :tag "Any")
 164                  (string :tag "Regexp")))
 165
 166 (gnus-define-group-parameter
 167  posting-charset-alist
 168  :type list
 169  :function-document
 170  "Return the permitted unencoded charsets for posting of GROUP."
 171  :variable gnus-group-posting-charset-alist
 172  :variable-default
 173   '(("^\\(no\\|fr\\)\\.[^,]*\\(,[ \t\n]*\\(no\\|fr\\)\\.[^,]*\\)*$" iso-8859-1 (iso-8859-1))
 174     ("^\\(fido7\\|relcom\\)\\.[^,]*\\(,[ \t\n]*\\(fido7\\|relcom\\)\\.[^,]*\\)*$" koi8-r (koi8-r))
 175     (message-this-is-mail nil nil)
 176     (message-this-is-news nil t))
 177  :variable-document
 178   "Alist of regexps and permitted unencoded charsets for posting.
 179 Each element of the alist has the form (TEST HEADER BODY-LIST), where
 180 TEST is either a regular expression matching the newsgroup header or a
 181 variable to query,
 182 HEADER is the charset which may be left unencoded in the header (nil
 183 means encode all charsets),
 184 BODY-LIST is a list of charsets which may be encoded using 8bit
 185 content-transfer encoding in the body, or one of the special values
 186 nil (always encode using quoted-printable) or t (always use 8bit).
 187
 188 Note that any value other than nil for HEADER infringes some RFCs, so
 189 use this option with care."
 190  :variable-group gnus-charset
 191  :variable-type
 192  '(repeat (list :tag "Permitted unencoded charsets"
 193                 (choice :tag "Where"
 194                         (regexp :tag "Group")
 195                         (const :tag "Mail message" :value message-this-is-mail)
 196                         (const :tag "News article" :value message-this-is-news))
 197                 (choice :tag "Header"
 198                         (const :tag "None" nil)
 199                         (symbol :tag "Charset"))
 200                 (choice :tag "Body"
 201                         (const :tag "Any" :value t)
 202                         (const :tag "None" :value nil)
 203                         (repeat :tag "Charsets"
 204                                 (symbol :tag "Charset")))))
 205  :parameter-type '(choice :tag "Permitted unencoded charsets"
 206                           :value nil
 207                           (repeat (symbol)))
 208  :parameter-document       "\
 209 List of charsets that are permitted to be unencoded.")
 210
 211 (defcustom gnus-debug-files
 212   '("gnus.el" "gnus-sum.el" "gnus-group.el"
 213     "gnus-art.el" "gnus-start.el" "gnus-async.el"
 214     "gnus-msg.el" "gnus-score.el" "gnus-win.el" "gnus-topic.el"
 215     "gnus-agent.el" "gnus-cache.el" "gnus-srvr.el"
 216     "mm-util.el" "mm-decode.el" "nnmail.el" "message.el")
 217   "Files whose variables will be reported in `gnus-bug'."
 218   :version "22.1"
 219   :group 'gnus-message
 220   :type '(repeat (string :tag "File")))
 221
 222 (defcustom gnus-debug-exclude-variables
 223   '(mm-mime-mule-charset-alist
 224     nnmail-split-fancy message-minibuffer-local-map)
 225   "Variables that should not be reported in `gnus-bug'."
 226   :version "22.1"
 227   :group 'gnus-message
 228   :type '(repeat (symbol :tag "Variable")))
 229
 230 (defcustom gnus-discouraged-post-methods
 231   '(nndraft nnml nnimap nnmaildir nnmh nnfolder nndir)
 232   "A list of back ends that are not used in \"real\" newsgroups.
 233 This variable is used only when `gnus-post-method' is `current'."
 234   :version "22.1"
 235   :group 'gnus-group-foreign
 236   :type '(repeat (symbol :tag "Back end")))
 237
 238 (defcustom gnus-message-replysign
 239   nil
 240   "Automatically sign replies to signed messages.
 241 See also the `mml-default-sign-method' variable."
 242   :group 'gnus-message
 243   :type 'boolean)
 244
 245 (defcustom gnus-message-replyencrypt
 246   nil
 247   "Automatically encrypt replies to encrypted messages.
 248 See also the `mml-default-encrypt-method' variable."
 249   :group 'gnus-message
 250   :type 'boolean)
 251
 252 (defcustom gnus-message-replysignencrypted
 253   t
 254   "Setting this causes automatically encrypted messages to also be signed."
 255   :group 'gnus-message
 256   :type 'boolean)
 257
 258 (defcustom gnus-confirm-mail-reply-to-news (and gnus-novice-user
 259                                                 (not gnus-expert-user))
 260   "If non-nil, Gnus requests confirmation when replying to news.
 261 This is done because new users often reply by mistake when reading
 262 news.
 263 This can also be a function receiving the group name as the only
 264 parameter which should return non-nil iff a confirmation is needed, or
 265 a regexp, in which case a confirmation is asked for iff the group name
 266 matches the regexp."
 267   :version "22.1"
 268   :group 'gnus-message
 269   :type '(choice (const :tag "No" nil)
 270                  (const :tag "Yes" t)
 271                  (regexp :tag "Iff group matches regexp")
 272                  (function :tag "Iff function evaluates to non-nil")))
 273
 274 (defcustom gnus-confirm-treat-mail-like-news
 275   nil
 276   "If non-nil, Gnus will treat mail like news with regard to confirmation
 277 when replying by mail.  See the `gnus-confirm-mail-reply-to-news' variable
 278 for fine-tuning this.
 279 If nil, Gnus will never ask for confirmation if replying to mail."
 280   :version "22.1"
 281   :group 'gnus-message
 282   :type 'boolean)
 283
 284 (defcustom gnus-summary-resend-default-address t
 285   "If non-nil, Gnus tries to suggest a default address to resend to.
 286 If nil, the address field will always be empty after invoking
 287 `gnus-summary-resend-message'."
 288   :version "22.1"
 289   :group 'gnus-message
 290   :type 'boolean)
 291
 292 (defcustom gnus-message-highlight-citation
 293   t ;; gnus-treat-highlight-citation ;; gnus-cite dependency
 294   "Enable highlighting of different citation levels in message-mode."
 295   :version "23.0" ;; No Gnus
 296   :group 'gnus-cite
 297   :group 'gnus-message
 298   :type 'boolean)
 299
 300 (autoload 'gnus-message-citation-mode "gnus-cite" nil t)
 301
 302 ;;; Internal variables.
 303
 304 (defvar gnus-inhibit-posting-styles nil
 305   "Inhibit the use of posting styles.")
 306
 307 (defvar gnus-article-yanked-articles nil)
 308 (defvar gnus-message-buffer "*Mail Gnus*")
 309 (defvar gnus-article-copy nil)
 310 (defvar gnus-check-before-posting nil)
 311 (defvar gnus-last-posting-server nil)
 312 (defvar gnus-message-group-art nil)
 313
 314 (defvar gnus-msg-force-broken-reply-to nil)
 315
 316 (defconst gnus-bug-message
 317   "Sending a bug report to the Gnus Towers.
 318 ========================================
 319
 320 The buffer below is a mail buffer.  When you press `C-c C-c', it will
 321 be sent to the Gnus Bug Exterminators.
 322
 323 The thing near the bottom of the buffer is how the environment
 324 settings will be included in the mail.  Please do not delete that.
 325 They will tell the Bug People what your environment is, so that it
 326 will be easier to locate the bugs.
 327
 328 If you have found a bug that makes Emacs go \"beep\", set
 329 debug-on-error to t (`M-x set-variable RET debug-on-error RET t RET')
 330 and include the backtrace in your bug report.
 331
 332 Please describe the bug in annoying, painstaking detail.
 333
 334 Thank you for your help in stamping out bugs.
 335 ")
 336
 337 (eval-and-compile
 338   (autoload 'gnus-uu-post-news "gnus-uu" nil t))
 339
 340 \f
 341 ;;;
 342 ;;; Gnus Posting Functions
 343 ;;;
 344
 345 (gnus-define-keys (gnus-summary-send-map "S" gnus-summary-mode-map)
 346   "p" gnus-summary-post-news
 347   "i" gnus-summary-news-other-window
 348   "f" gnus-summary-followup
 349   "F" gnus-summary-followup-with-original
 350   "c" gnus-summary-cancel-article
 351   "s" gnus-summary-supersede-article
 352   "r" gnus-summary-reply
 353   "y" gnus-summary-yank-message
 354   "R" gnus-summary-reply-with-original
 355   "w" gnus-summary-wide-reply
 356   "W" gnus-summary-wide-reply-with-original
 357   "v" gnus-summary-very-wide-reply
 358   "V" gnus-summary-very-wide-reply-with-original
 359   "n" gnus-summary-followup-to-mail
 360   "N" gnus-summary-followup-to-mail-with-original
 361   "m" gnus-summary-mail-other-window
 362   "u" gnus-uu-post-news
 363   "\M-c" gnus-summary-mail-crosspost-complaint
 364   "Br" gnus-summary-reply-broken-reply-to
 365   "BR" gnus-summary-reply-broken-reply-to-with-original
 366   "om" gnus-summary-mail-forward
 367   "op" gnus-summary-post-forward
 368   "Om" gnus-uu-digest-mail-forward
 369   "Op" gnus-uu-digest-post-forward)
 370
 371 (gnus-define-keys (gnus-send-bounce-map "D" gnus-summary-send-map)
 372   "b" gnus-summary-resend-bounced-mail
 373   ;; "c" gnus-summary-send-draft
 374   "r" gnus-summary-resend-message
 375   "e" gnus-summary-resend-message-edit)
 376
 377 ;;; Internal functions.
 378
 379 (defun gnus-inews-make-draft (articles)
 380   `(lambda ()
 381      (gnus-inews-make-draft-meta-information
 382       ,gnus-newsgroup-name ',articles)))
 383
 384 (defvar gnus-article-reply nil)
 385 (defmacro gnus-setup-message (config &rest forms)
 386   (let ((winconf (make-symbol "gnus-setup-message-winconf"))
 387         (buffer (make-symbol "gnus-setup-message-buffer"))
 388         (article (make-symbol "gnus-setup-message-article"))
 389         (yanked (make-symbol "gnus-setup-yanked-articles"))
 390         (group (make-symbol "gnus-setup-message-group")))
 391     `(let ((,winconf (current-window-configuration))
 392            (,buffer (buffer-name (current-buffer)))
 393            (,article gnus-article-reply)
 394            (,yanked gnus-article-yanked-articles)
 395            (,group gnus-newsgroup-name)
 396            (message-header-setup-hook
 397             (copy-sequence message-header-setup-hook))
 398            (mbl mml-buffer-list)
 399            (message-mode-hook (copy-sequence message-mode-hook)))
 400        (setq mml-buffer-list nil)
 401        (add-hook 'message-header-setup-hook 'gnus-inews-insert-gcc)
 402        (add-hook 'message-header-setup-hook 'gnus-inews-insert-archive-gcc)
 403        ;; message-newsreader and message-mailer were formerly set in
 404        ;; gnus-inews-add-send-actions, but this is too late when
 405        ;; message-generate-headers-first is used. --ansel
 406        (add-hook 'message-mode-hook
 407                  (lambda nil
 408                    (setq message-newsreader
 409                          (setq message-mailer (gnus-extended-version)))))
 410        ;; #### FIXME: for a reason that I did not manage to identify yet,
 411        ;; the variable `gnus-newsgroup-name' does not honor a dynamically
 412        ;; scoped or setq'ed value from a caller like `C-u gnus-summary-mail'.
 413        ;; After evaluation of @forms below, it gets the value we actually want
 414        ;; to override, and the posting styles are used. For that reason, I've
 415        ;; added an optional argument to `gnus-configure-posting-styles' to
 416        ;; make sure that the correct value for the group name is used. -- drv
 417        (add-hook 'message-mode-hook
 418                  (if (memq ,config '(reply-yank reply))
 419                      (lambda ()
 420                        (gnus-configure-posting-styles ,group))
 421                    (lambda ()
 422                      ;; There may be an old " *gnus article copy*" buffer.
 423                      (let (gnus-article-copy)
 424                        (gnus-configure-posting-styles ,group)))))
 425        (gnus-pull ',(intern gnus-draft-meta-information-header)
 426                   message-required-headers)
 427        (when (and ,group
 428                   (not (string= ,group "")))
 429          (push (cons
 430                 (intern gnus-draft-meta-information-header)
 431                 (gnus-inews-make-draft (or ,yanked ,article)))
 432                message-required-headers))
 433        (unwind-protect
 434            (progn
 435              ,@forms)
 436          (gnus-inews-add-send-actions ,winconf ,buffer ,article ,config
 437                                       ,yanked)
 438          (setq gnus-message-buffer (current-buffer))
 439          (set (make-local-variable 'gnus-message-group-art)
 440               (cons ,group ,article))
 441          (set (make-local-variable 'gnus-newsgroup-name) ,group)
 442          ;; Enable highlighting of different citation levels
 443          (when gnus-message-highlight-citation
 444            (gnus-message-citation-mode 1))
 445          (gnus-run-hooks 'gnus-message-setup-hook)
 446          (if (eq major-mode 'message-mode)
 447              (let ((mbl1 mml-buffer-list))
 448                (setq mml-buffer-list mbl)  ;; Global value
 449                (set (make-local-variable 'mml-buffer-list) mbl1);; Local value
 450                (gnus-make-local-hook 'kill-buffer-hook)
 451                (gnus-make-local-hook 'change-major-mode-hook)
 452                (add-hook 'change-major-mode-hook 'mml-destroy-buffers nil t)
 453                (add-hook 'kill-buffer-hook 'mml-destroy-buffers t t))
 454            (mml-destroy-buffers)
 455            (setq mml-buffer-list mbl)))
 456        (message-hide-headers)
 457        (gnus-add-buffer)
 458        (gnus-configure-windows ,config t)
 459        (run-hooks 'post-command-hook)
 460        (set-buffer-modified-p nil))))
 461
 462 (defun gnus-inews-make-draft-meta-information (group articles)
 463   (when (numberp articles)
 464     (setq articles (list articles)))
 465   (concat "(\"" group "\""
 466           (if articles
 467               (concat " "
 468                       (mapconcat
 469                        (lambda (elem)
 470                          (number-to-string
 471                           (if (consp elem)
 472                               (car elem)
 473                             elem)))
 474                        articles " "))
 475             "")
 476           ")"))
 477
 478 ;;;###autoload
 479 (defun gnus-msg-mail (&optional to subject other-headers continue
 480                                 switch-action yank-action send-actions)
 481   "Start editing a mail message to be sent.
 482 Like `message-mail', but with Gnus paraphernalia, particularly the
 483 Gcc: header for archiving purposes."
 484   (interactive)
 485   (let ((buf (current-buffer))
 486         mail-buf)
 487     (gnus-setup-message 'message
 488       (message-mail to subject other-headers continue
 489                     nil yank-action send-actions))
 490     (when switch-action
 491       (setq mail-buf (current-buffer))
 492       (switch-to-buffer buf)
 493       (apply switch-action mail-buf nil)))
 494   ;; COMPOSEFUNC should return t if succeed.  Undocumented ???
 495   t)
 496
 497 ;;;###autoload
 498 (defun gnus-button-mailto (address)
 499   "Mail to ADDRESS."
 500   (set-buffer (gnus-copy-article-buffer))
 501   (gnus-setup-message 'message
 502     (message-reply address)))
 503
 504 ;;;###autoload
 505 (defun gnus-button-reply (&optional to-address wide)
 506   "Like `message-reply'."
 507   (interactive)
 508   (gnus-setup-message 'message
 509     (message-reply to-address wide)))
 510
 511 ;;;###autoload
 512 (define-mail-user-agent 'gnus-user-agent
 513   'gnus-msg-mail 'message-send-and-exit
 514   'message-kill-buffer 'message-send-hook)
 515
 516 (defun gnus-setup-posting-charset (group)
 517   (let ((alist gnus-group-posting-charset-alist)
 518         (group (or group ""))
 519         elem)
 520     (when group
 521       (catch 'found
 522         (while (setq elem (pop alist))
 523           (when (or (and (stringp (car elem))
 524                          (string-match (car elem) group))
 525                     (and (functionp (car elem))
 526                          (funcall (car elem) group))
 527                     (and (symbolp (car elem))
 528                          (symbol-value (car elem))))
 529             (throw 'found (cons (cadr elem) (caddr elem)))))))))
 530
 531 (defun gnus-inews-add-send-actions (winconf buffer article
 532                                             &optional config yanked)
 533   (gnus-make-local-hook 'message-sent-hook)
 534   (add-hook 'message-sent-hook (if gnus-agent 'gnus-agent-possibly-do-gcc
 535                                  'gnus-inews-do-gcc) nil t)
 536   (when gnus-agent
 537     (gnus-make-local-hook 'message-header-hook)
 538     (add-hook 'message-header-hook 'gnus-agent-possibly-save-gcc nil t))
 539   (setq message-post-method
 540         `(lambda (&optional arg)
 541            (gnus-post-method arg ,gnus-newsgroup-name)))
 542   (message-add-action
 543    `(when (gnus-buffer-exists-p ,buffer)
 544       (set-window-configuration ,winconf))
 545    'exit 'postpone 'kill)
 546   (let ((to-be-marked (cond
 547                        (yanked
 548                         (mapcar
 549                          (lambda (x) (if (listp x) (car x) x)) yanked))
 550                        (article (if (listp article) article (list article)))
 551                        (t nil))))
 552     (message-add-action
 553      `(when (gnus-buffer-exists-p ,buffer)
 554         (save-excursion
 555           (set-buffer ,buffer)
 556           ,(when to-be-marked
 557              (if (eq config 'forward)
 558                  `(gnus-summary-mark-article-as-forwarded ',to-be-marked)
 559                `(gnus-summary-mark-article-as-replied ',to-be-marked)))))
 560      'send)))
 561
 562 (put 'gnus-setup-message 'lisp-indent-function 1)
 563 (put 'gnus-setup-message 'edebug-form-spec '(form body))
 564
 565 ;;; Post news commands of Gnus group mode and summary mode
 566
 567 (defun gnus-group-mail (&optional arg)
 568   "Start composing a mail.
 569 If ARG, use the group under the point to find a posting style.
 570 If ARG is 1, prompt for a group name to find the posting style."
 571   (interactive "P")
 572   ;; We can't `let' gnus-newsgroup-name here, since that leads
 573   ;; to local variables leaking.
 574   (let ((group gnus-newsgroup-name)
 575         ;; make sure last viewed article doesn't affect posting styles:
 576         (gnus-article-copy)
 577         (buffer (current-buffer)))
 578     (unwind-protect
 579         (progn
 580           (setq gnus-newsgroup-name
 581                 (if arg
 582                     (if (= 1 (prefix-numeric-value arg))
 583                         (completing-read "Use posting style of group: "
 584                                          gnus-active-hashtb nil
 585                                          (gnus-read-active-file-p))
 586                       (gnus-group-group-name))
 587                   ""))
 588           ;; #### see comment in gnus-setup-message -- drv
 589           (gnus-setup-message 'message (message-mail)))
 590       (save-excursion
 591         (set-buffer buffer)
 592         (setq gnus-newsgroup-name group)))))
 593
 594 (defun gnus-group-news (&optional arg)
 595   "Start composing a news.
 596 If ARG, post to group under point.
 597 If ARG is 1, prompt for group name to post to.
 598
 599 This function prepares a news even when using mail groups.  This is useful
 600 for posting messages to mail groups without actually sending them over the
 601 network.  The corresponding back end must have a 'request-post method."
 602   (interactive "P")
 603   ;; We can't `let' gnus-newsgroup-name here, since that leads
 604   ;; to local variables leaking.
 605   (let ((group gnus-newsgroup-name)
 606         ;; make sure last viewed article doesn't affect posting styles:
 607         (gnus-article-copy)
 608         (buffer (current-buffer)))
 609     (unwind-protect
 610         (progn
 611           (setq gnus-newsgroup-name
 612                 (if arg
 613                     (if (= 1 (prefix-numeric-value arg))
 614                         (completing-read "Use group: "
 615                                          gnus-active-hashtb nil
 616                                          (gnus-read-active-file-p))
 617                       (gnus-group-group-name))
 618                   ""))
 619           ;; #### see comment in gnus-setup-message -- drv
 620           (gnus-setup-message 'message
 621             (message-news (gnus-group-real-name gnus-newsgroup-name))))
 622       (save-excursion
 623         (set-buffer buffer)
 624         (setq gnus-newsgroup-name group)))))
 625
 626 (defun gnus-group-post-news (&optional arg)
 627   "Start composing a message (a news by default).
 628 If ARG, post to group under point.  If ARG is 1, prompt for group name.
 629 Depending on the selected group, the message might be either a mail or
 630 a news."
 631   (interactive "P")
 632   ;; Bind this variable here to make message mode hooks work ok.
 633   (let ((gnus-newsgroup-name
 634          (if arg
 635              (if (= 1 (prefix-numeric-value arg))
 636                  (completing-read "Newsgroup: " gnus-active-hashtb nil
 637                                   (gnus-read-active-file-p))
 638                (gnus-group-group-name))
 639            ""))
 640         ;; make sure last viewed article doesn't affect posting styles:
 641         (gnus-article-copy))
 642     (gnus-post-news 'post gnus-newsgroup-name nil nil nil nil
 643                     (string= gnus-newsgroup-name ""))))
 644
 645 (defun gnus-summary-mail-other-window (&optional arg)
 646   "Start composing a mail in another window.
 647 Use the posting of the current group by default.
 648 If ARG, don't do that.  If ARG is 1, prompt for group name to find the
 649 posting style."
 650   (interactive "P")
 651   ;; We can't `let' gnus-newsgroup-name here, since that leads
 652   ;; to local variables leaking.
 653   (let ((group gnus-newsgroup-name)
 654         ;; make sure last viewed article doesn't affect posting styles:
 655         (gnus-article-copy)
 656         (buffer (current-buffer)))
 657     (unwind-protect
 658         (progn
 659           (setq gnus-newsgroup-name
 660                 (if arg
 661                     (if (= 1 (prefix-numeric-value arg))
 662                         (completing-read "Use group: "
 663                                          gnus-active-hashtb nil
 664                                          (gnus-read-active-file-p))
 665                       "")
 666                   gnus-newsgroup-name))
 667           ;; #### see comment in gnus-setup-message -- drv
 668           (gnus-setup-message 'message (message-mail)))
 669       (save-excursion
 670         (set-buffer buffer)
 671         (setq gnus-newsgroup-name group)))))
 672
 673 (defun gnus-summary-news-other-window (&optional arg)
 674   "Start composing a news in another window.
 675 Post to the current group by default.
 676 If ARG, don't do that.  If ARG is 1, prompt for group name to post to.
 677
 678 This function prepares a news even when using mail groups.  This is useful
 679 for posting messages to mail groups without actually sending them over the
 680 network.  The corresponding back end must have a 'request-post method."
 681   (interactive "P")
 682   ;; We can't `let' gnus-newsgroup-name here, since that leads
 683   ;; to local variables leaking.
 684   (let ((group gnus-newsgroup-name)
 685         ;; make sure last viewed article doesn't affect posting styles:
 686         (gnus-article-copy)
 687         (buffer (current-buffer)))
 688     (unwind-protect
 689         (progn
 690           (setq gnus-newsgroup-name
 691                 (if arg
 692                     (if (= 1 (prefix-numeric-value arg))
 693                         (completing-read "Use group: "
 694                                          gnus-active-hashtb nil
 695                                          (gnus-read-active-file-p))
 696                       "")
 697                   gnus-newsgroup-name))
 698           ;; #### see comment in gnus-setup-message -- drv
 699           (gnus-setup-message 'message
 700             (progn
 701               (message-news (gnus-group-real-name gnus-newsgroup-name))
 702               (set (make-local-variable 'gnus-discouraged-post-methods)
 703                    (remove
 704                     (car (gnus-find-method-for-group gnus-newsgroup-name))
 705                     gnus-discouraged-post-methods)))))
 706       (save-excursion
 707         (set-buffer buffer)
 708         (setq gnus-newsgroup-name group)))))
 709
 710 (defun gnus-summary-post-news (&optional arg)
 711   "Start composing a message.  Post to the current group by default.
 712 If ARG, don't do that.  If ARG is 1, prompt for a group name to post to.
 713 Depending on the selected group, the message might be either a mail or
 714 a news."
 715   (interactive "P")
 716   ;; Bind this variable here to make message mode hooks work ok.
 717   (let ((gnus-newsgroup-name
 718          (if arg
 719              (if (= 1 (prefix-numeric-value arg))
 720                  (completing-read "Newsgroup: " gnus-active-hashtb nil
 721                                   (gnus-read-active-file-p))
 722                "")
 723            gnus-newsgroup-name))
 724         ;; make sure last viewed article doesn't affect posting styles:
 725         (gnus-article-copy))
 726     (gnus-post-news 'post gnus-newsgroup-name)))
 727
 728
 729 (defun gnus-summary-followup (yank &optional force-news)
 730   "Compose a followup to an article.
 731 If prefix argument YANK is non-nil, the original article is yanked
 732 automatically.
 733 YANK is a list of elements, where the car of each element is the
 734 article number, and the cdr is the string to be yanked."
 735   (interactive
 736    (list (and current-prefix-arg
 737               (gnus-summary-work-articles 1))))
 738   (when yank
 739     (gnus-summary-goto-subject
 740      (if (listp (car yank))
 741          (caar yank)
 742        (car yank))))
 743   (save-window-excursion
 744     (gnus-summary-select-article))
 745   (let ((headers (gnus-summary-article-header (gnus-summary-article-number)))
 746         (gnus-newsgroup-name gnus-newsgroup-name))
 747     ;; Send a followup.
 748     (gnus-post-news nil gnus-newsgroup-name
 749                     headers gnus-article-buffer
 750                     yank nil force-news)
 751     (gnus-summary-handle-replysign)))
 752
 753 (defun gnus-summary-followup-with-original (n &optional force-news)
 754   "Compose a followup to an article and include the original article.
 755 The text in the region will be yanked.  If the region isn't
 756 active, the entire article will be yanked."
 757   (interactive "P")
 758   (gnus-summary-followup (gnus-summary-work-articles n) force-news))
 759
 760 (defun gnus-summary-followup-to-mail (&optional arg)
 761   "Followup to the current mail message via news."
 762   (interactive
 763    (list (and current-prefix-arg
 764               (gnus-summary-work-articles 1))))
 765   (gnus-summary-followup arg t))
 766
 767 (defun gnus-summary-followup-to-mail-with-original (&optional arg)
 768   "Followup to the current mail message via news."
 769   (interactive "P")
 770   (gnus-summary-followup (gnus-summary-work-articles arg) t))
 771
 772 (defun gnus-inews-yank-articles (articles)
 773   (let (beg article yank-string)
 774     (message-goto-body)
 775     (while (setq article (pop articles))
 776       (when (listp article)
 777         (setq yank-string (nth 1 article)
 778               article (nth 0 article)))
 779       (save-window-excursion
 780         (set-buffer gnus-summary-buffer)
 781         (gnus-summary-select-article nil nil nil article)
 782         (gnus-summary-remove-process-mark article))
 783       (gnus-copy-article-buffer nil yank-string)
 784       (let ((message-reply-buffer gnus-article-copy)
 785             (message-reply-headers
 786              ;; The headers are decoded.
 787              (with-current-buffer gnus-article-copy
 788                (save-restriction
 789                  (nnheader-narrow-to-headers)
 790                  (nnheader-parse-naked-head)))))
 791         (message-yank-original)
 792         (message-exchange-point-and-mark)
 793         (setq beg (or beg (mark t))))
 794       (when articles
 795         (insert "\n")))
 796     (push-mark)
 797     (goto-char beg)))
 798
 799 (defun gnus-summary-cancel-article (&optional n symp)
 800   "Cancel an article you posted.
 801 Uses the process-prefix convention.  If given the symbolic
 802 prefix `a', cancel using the standard posting method; if not
 803 post using the current select method."
 804   (interactive (gnus-interactive "P\ny"))
 805   (let ((message-post-method
 806          `(lambda (arg)
 807             (gnus-post-method (eq ',symp 'a) ,gnus-newsgroup-name))))
 808     (dolist (article (gnus-summary-work-articles n))
 809       (when (gnus-summary-select-article t nil nil article)
 810         (when (gnus-eval-in-buffer-window gnus-original-article-buffer
 811                 (message-cancel-news))
 812           (gnus-summary-mark-as-read article gnus-canceled-mark)
 813           (gnus-cache-remove-article 1))
 814         (gnus-article-hide-headers-if-wanted))
 815       (gnus-summary-remove-process-mark article))))
 816
 817 (defun gnus-summary-supersede-article ()
 818   "Compose an article that will supersede a previous article.
 819 This is done simply by taking the old article and adding a Supersedes
 820 header line with the old Message-ID."
 821   (interactive)
 822   (let ((article (gnus-summary-article-number)))
 823     (gnus-setup-message 'reply-yank
 824       (gnus-summary-select-article t)
 825       (set-buffer gnus-original-article-buffer)
 826       (message-supersede)
 827       (push
 828        `((lambda ()
 829            (when (gnus-buffer-exists-p ,gnus-summary-buffer)
 830              (save-excursion
 831                (set-buffer ,gnus-summary-buffer)
 832                (gnus-cache-possibly-remove-article ,article nil nil nil t)
 833                (gnus-summary-mark-as-read ,article gnus-canceled-mark)))))
 834        message-send-actions)
 835       (gnus-inews-insert-archive-gcc)
 836       (gnus-inews-insert-gcc))))
 837
 838 \f
 839
 840 (defun gnus-copy-article-buffer (&optional article-buffer yank-string)
 841   ;; make a copy of the article buffer with all text properties removed
 842   ;; this copy is in the buffer gnus-article-copy.
 843   ;; if ARTICLE-BUFFER is nil, gnus-article-buffer is used
 844   ;; this buffer should be passed to all mail/news reply/post routines.
 845   (setq gnus-article-copy (gnus-get-buffer-create " *gnus article copy*"))
 846   (save-excursion
 847     (set-buffer gnus-article-copy)
 848     (mm-enable-multibyte))
 849   (let ((article-buffer (or article-buffer gnus-article-buffer))
 850         end beg)
 851     (if (not (and (get-buffer article-buffer)
 852                   (gnus-buffer-exists-p article-buffer)))
 853         (error "Can't find any article buffer")
 854       (save-excursion
 855         (set-buffer article-buffer)
 856         (let ((gnus-newsgroup-charset (or gnus-article-charset
 857                                           gnus-newsgroup-charset))
 858               (gnus-newsgroup-ignored-charsets
 859                (or gnus-article-ignored-charsets
 860                    gnus-newsgroup-ignored-charsets)))
 861           (save-restriction
 862             ;; Copy over the (displayed) article buffer, delete
 863             ;; hidden text and remove text properties.
 864             (widen)
 865             (copy-to-buffer gnus-article-copy (point-min) (point-max))
 866             (set-buffer gnus-article-copy)
 867             (when yank-string
 868               (message-goto-body)
 869               (delete-region (point) (point-max))
 870               (insert yank-string))
 871             (gnus-article-delete-text-of-type 'annotation)
 872             (gnus-article-delete-text-of-type 'multipart)
 873             (gnus-remove-text-with-property 'gnus-prev)
 874             (gnus-remove-text-with-property 'gnus-next)
 875             (gnus-remove-text-with-property 'gnus-decoration)
 876             (insert
 877              (prog1
 878                  (buffer-substring-no-properties (point-min) (point-max))
 879                (erase-buffer)))
 880             ;; Find the original headers.
 881             (set-buffer gnus-original-article-buffer)
 882             (goto-char (point-min))
 883             (while (looking-at message-unix-mail-delimiter)
 884               (forward-line 1))
 885             (let ((mail-header-separator ""))
 886               (setq beg (point)
 887                     end (or (message-goto-body)
 888                             ;; There may be just a header.
 889                             (point-max))))
 890             ;; Delete the headers from the displayed articles.
 891             (set-buffer gnus-article-copy)
 892             (let ((mail-header-separator ""))
 893               (delete-region (goto-char (point-min))
 894                              (or (message-goto-body) (point-max))))
 895             ;; Insert the original article headers.
 896             (insert-buffer-substring gnus-original-article-buffer beg end)
 897             ;; Decode charsets.
 898             (let ((gnus-article-decode-hook
 899                    (delq 'article-decode-charset
 900                          (copy-sequence gnus-article-decode-hook)))
 901                   (rfc2047-quote-decoded-words-containing-tspecials t))
 902               (run-hooks 'gnus-article-decode-hook)))))
 903       gnus-article-copy)))
 904
 905 (defun gnus-post-news (post &optional group header article-buffer yank subject
 906                             force-news)
 907   (when article-buffer
 908     (gnus-copy-article-buffer))
 909   (let ((gnus-article-reply (and article-buffer (gnus-summary-article-number)))
 910         (gnus-article-yanked-articles yank)
 911         (add-to-list gnus-add-to-list))
 912     (gnus-setup-message (cond (yank 'reply-yank)
 913                               (article-buffer 'reply)
 914                               (t 'message))
 915       (let* ((group (or group gnus-newsgroup-name))
 916              (charset (gnus-group-name-charset nil group))
 917              (pgroup group)
 918              to-address to-group mailing-list to-list
 919              newsgroup-p)
 920         (when group
 921           (setq to-address (gnus-parameter-to-address group)
 922                 to-group (gnus-group-find-parameter group 'to-group)
 923                 to-list (gnus-parameter-to-list group)
 924                 newsgroup-p (gnus-group-find-parameter group 'newsgroup)
 925                 mailing-list (when gnus-mailing-list-groups
 926                                (string-match gnus-mailing-list-groups group))
 927                 group (gnus-group-name-decode (gnus-group-real-name group)
 928                                               charset)))
 929         (if (or (and to-group
 930                      (gnus-news-group-p to-group))
 931                 newsgroup-p
 932                 force-news
 933                 (and (gnus-news-group-p
 934                       (or pgroup gnus-newsgroup-name)
 935                       (or header gnus-current-article))
 936                      (not mailing-list)
 937                      (not to-list)
 938                      (not to-address)))
 939             ;; This is news.
 940             (if post
 941                 (message-news
 942                  (or to-group
 943                      (and (not (gnus-virtual-group-p pgroup)) group)))
 944               (set-buffer gnus-article-copy)
 945               (gnus-msg-treat-broken-reply-to)
 946               (message-followup (if (or newsgroup-p force-news)
 947                                     (if (save-restriction
 948                                           (article-narrow-to-head)
 949                                           (message-fetch-field "newsgroups"))
 950                                         nil
 951                                       "")
 952                                   to-group)))
 953           ;; The is mail.
 954           (if post
 955               (progn
 956                 (message-mail (or to-address to-list))
 957                 ;; Arrange for mail groups that have no `to-address' to
 958                 ;; get that when the user sends off the mail.
 959                 (when (and (not to-list)
 960                            (not to-address)
 961                            add-to-list)
 962                   (push (list 'gnus-inews-add-to-address pgroup)
 963                         message-send-actions)))
 964             (set-buffer gnus-article-copy)
 965             (gnus-msg-treat-broken-reply-to)
 966             (message-wide-reply to-address)))
 967         (when yank
 968           (gnus-inews-yank-articles yank))))))
 969
 970 (defun gnus-msg-treat-broken-reply-to (&optional force)
 971   "Remove the Reply-to header if broken-reply-to."
 972   (when (or force
 973             (gnus-group-find-parameter
 974              gnus-newsgroup-name 'broken-reply-to))
 975     (save-restriction
 976       (message-narrow-to-head)
 977       (message-remove-header "reply-to"))))
 978
 979 (defun gnus-post-method (arg group &optional silent)
 980   "Return the posting method based on GROUP and ARG.
 981 If SILENT, don't prompt the user."
 982   (let ((gnus-post-method (or (gnus-parameter-post-method group)
 983                               gnus-post-method))
 984         (group-method (gnus-find-method-for-group group)))
 985     (cond
 986      ;; If the group-method is nil (which shouldn't happen) we use
 987      ;; the default method.
 988      ((null group-method)
 989       (or (and (listp gnus-post-method) ;If not current/native/nil
 990                (not (listp (car gnus-post-method))) ; and not a list of methods
 991                gnus-post-method)        ;then use it.
 992           gnus-select-method
 993           message-post-method))
 994      ;; We want the inverse of the default
 995      ((and arg (not (eq arg 0)))
 996       (if (eq gnus-post-method 'current)
 997           gnus-select-method
 998         group-method))
 999      ;; We query the user for a post method.
1000      ((or arg
1001           (and (listp gnus-post-method)
1002                (listp (car gnus-post-method))))
1003       (let* ((methods
1004               ;; Collect all methods we know about.
1005               (append
1006                (when (listp gnus-post-method)
1007                  (if (listp (car gnus-post-method))
1008                      gnus-post-method
1009                    (list gnus-post-method)))
1010                gnus-secondary-select-methods
1011                (mapcar 'cdr gnus-server-alist)
1012                (mapcar 'car gnus-opened-servers)
1013                (list gnus-select-method)
1014                (list group-method)))
1015              method-alist post-methods method)
1016         ;; Weed out all mail methods.
1017         (while methods
1018           (setq method (gnus-server-get-method "" (pop methods)))
1019           (when (and (or (gnus-method-option-p method 'post)
1020                          (gnus-method-option-p method 'post-mail))
1021                      (not (member method post-methods)))
1022             (push method post-methods)))
1023         ;; Create a name-method alist.
1024         (setq method-alist
1025               (mapcar
1026                (lambda (m)
1027                  (if (equal (cadr m) "")
1028                      (list (symbol-name (car m)) m)
1029                    (list (concat (cadr m) " (" (symbol-name (car m)) ")") m)))
1030                post-methods))
1031         ;; Query the user.
1032         (cadr
1033          (assoc
1034           (setq gnus-last-posting-server
1035                 (if (and silent
1036                          gnus-last-posting-server)
1037                     ;; Just use the last value.
1038                     gnus-last-posting-server
1039                   (completing-read
1040                    "Posting method: " method-alist nil t
1041                    (cons (or gnus-last-posting-server "") 0))))
1042           method-alist))))
1043      ;; Override normal method.
1044      ((and (eq gnus-post-method 'current)
1045            (not (memq (car group-method) gnus-discouraged-post-methods))
1046            (gnus-get-function group-method 'request-post t))
1047       (assert (not arg))
1048       group-method)
1049      ;; Use gnus-post-method.
1050      ((listp gnus-post-method)          ;A method...
1051       (assert (not (listp (car gnus-post-method)))) ;... not a list of methods.
1052       gnus-post-method)
1053      ;; Use the normal select method (nil or native).
1054      (t gnus-select-method))))
1055
1056 \f
1057
1058 (defun gnus-extended-version ()
1059   "Stringified Gnus version and Emacs version.
1060 See the variable `gnus-user-agent'."
1061   (interactive)
1062   (if (stringp gnus-user-agent)
1063       gnus-user-agent
1064     ;; `gnus-user-agent' is a list:
1065     (let* ((float-output-format nil)
1066            (gnus-v
1067             (when (memq 'gnus gnus-user-agent)
1068               (concat "Gnus/"
1069                       (prin1-to-string (gnus-continuum-version gnus-version) t)
1070                       " (" gnus-version ")")))
1071            (emacs-v (gnus-emacs-version)))
1072       (concat gnus-v (when (and gnus-v emacs-v) " ")
1073               emacs-v))))
1074
1075 \f
1076 ;;;
1077 ;;; Gnus Mail Functions
1078 ;;;
1079
1080 ;;; Mail reply commands of Gnus summary mode
1081
1082 (defun gnus-summary-reply (&optional yank wide very-wide)
1083   "Start composing a mail reply to the current message.
1084 If prefix argument YANK is non-nil, the original article is yanked
1085 automatically.
1086 If WIDE, make a wide reply.
1087 If VERY-WIDE, make a very wide reply."
1088   (interactive
1089    (list (and current-prefix-arg
1090               (gnus-summary-work-articles 1))))
1091   ;; Allow user to require confirmation before replying by mail to the
1092   ;; author of a news article (or mail message).
1093   (when (or
1094             (not (or (gnus-news-group-p gnus-newsgroup-name)
1095                      gnus-confirm-treat-mail-like-news))
1096             (not (cond ((stringp gnus-confirm-mail-reply-to-news)
1097                         (string-match gnus-confirm-mail-reply-to-news
1098                                       gnus-newsgroup-name))
1099                        ((functionp gnus-confirm-mail-reply-to-news)
1100                         (funcall gnus-confirm-mail-reply-to-news gnus-newsgroup-name))
1101                        (t gnus-confirm-mail-reply-to-news)))
1102             (y-or-n-p "Really reply by mail to article author? "))
1103     (let* ((article
1104             (if (listp (car yank))
1105                 (caar yank)
1106               (car yank)))
1107            (gnus-article-reply (or article (gnus-summary-article-number)))
1108            (gnus-article-yanked-articles yank)
1109            (headers ""))
1110       ;; Stripping headers should be specified with mail-yank-ignored-headers.
1111       (when yank
1112         (gnus-summary-goto-subject article))
1113       (gnus-setup-message (if yank 'reply-yank 'reply)
1114         (if (not very-wide)
1115             (gnus-summary-select-article)
1116           (dolist (article very-wide)
1117             (gnus-summary-select-article nil nil nil article)
1118             (save-excursion
1119               (set-buffer (gnus-copy-article-buffer))
1120               (gnus-msg-treat-broken-reply-to)
1121               (save-restriction
1122                 (message-narrow-to-head)
1123                 (setq headers (concat headers (buffer-string)))))))
1124         (set-buffer (gnus-copy-article-buffer))
1125         (gnus-msg-treat-broken-reply-to gnus-msg-force-broken-reply-to)
1126         (save-restriction
1127           (message-narrow-to-head)
1128           (when very-wide
1129             (erase-buffer)
1130             (insert headers))
1131           (goto-char (point-max)))
1132         (mml-quote-region (point) (point-max))
1133         (message-reply nil wide)
1134         (when yank
1135           (gnus-inews-yank-articles yank))
1136         (gnus-summary-handle-replysign)))))
1137
1138 (defun gnus-summary-handle-replysign ()
1139   "Check the various replysign variables and take action accordingly."
1140   (when (or gnus-message-replysign gnus-message-replyencrypt)
1141     (let (signed encrypted)
1142       (save-excursion
1143         (set-buffer gnus-article-buffer)
1144         (setq signed (memq 'signed gnus-article-wash-types))
1145         (setq encrypted (memq 'encrypted gnus-article-wash-types)))
1146       (cond ((and gnus-message-replyencrypt encrypted)
1147              (mml-secure-message mml-default-encrypt-method
1148                                  (if gnus-message-replysignencrypted
1149                                      'signencrypt
1150                                    'encrypt)))
1151             ((and gnus-message-replysign signed)
1152              (mml-secure-message mml-default-sign-method 'sign))))))
1153
1154 (defun gnus-summary-reply-with-original (n &optional wide)
1155   "Start composing a reply mail to the current message.
1156 The original article will be yanked."
1157   (interactive "P")
1158   (gnus-summary-reply (gnus-summary-work-articles n) wide))
1159
1160 (defun gnus-summary-reply-broken-reply-to (&optional yank wide very-wide)
1161   "Like `gnus-summary-reply' except removing reply-to field.
1162 If prefix argument YANK is non-nil, the original article is yanked
1163 automatically.
1164 If WIDE, make a wide reply.
1165 If VERY-WIDE, make a very wide reply."
1166   (interactive
1167    (list (and current-prefix-arg
1168               (gnus-summary-work-articles 1))))
1169   (let ((gnus-msg-force-broken-reply-to t))
1170     (gnus-summary-reply yank wide very-wide)))
1171
1172 (defun gnus-summary-reply-broken-reply-to-with-original (n &optional wide)
1173   "Like `gnus-summary-reply-with-original' except removing reply-to field.
1174 The original article will be yanked."
1175   (interactive "P")
1176   (gnus-summary-reply-broken-reply-to (gnus-summary-work-articles n) wide))
1177
1178 (defun gnus-summary-wide-reply (&optional yank)
1179   "Start composing a wide reply mail to the current message.
1180 If prefix argument YANK is non-nil, the original article is yanked
1181 automatically."
1182   (interactive
1183    (list (and current-prefix-arg
1184               (gnus-summary-work-articles 1))))
1185   (gnus-summary-reply yank t))
1186
1187 (defun gnus-summary-wide-reply-with-original (n)
1188   "Start composing a wide reply mail to the current message.
1189 The original article will be yanked.
1190 Uses the process/prefix convention."
1191   (interactive "P")
1192   (gnus-summary-reply-with-original n t))
1193
1194 (defun gnus-summary-very-wide-reply (&optional yank)
1195   "Start composing a very wide reply mail to the current message.
1196 If prefix argument YANK is non-nil, the original article is yanked
1197 automatically."
1198   (interactive
1199    (list (and current-prefix-arg
1200               (gnus-summary-work-articles 1))))
1201   (gnus-summary-reply yank t (gnus-summary-work-articles yank)))
1202
1203 (defun gnus-summary-very-wide-reply-with-original (n)
1204   "Start composing a very wide reply mail to the current message.
1205 The original article will be yanked."
1206   (interactive "P")
1207   (gnus-summary-reply
1208    (gnus-summary-work-articles n) t (gnus-summary-work-articles n)))
1209
1210 (defun gnus-summary-mail-forward (&optional arg post)
1211   "Forward the current message(s) to another user.
1212 If process marks exist, forward all marked messages;
1213 if ARG is nil, see `message-forward-as-mime' and `message-forward-show-mml';
1214 if ARG is 1, decode the message and forward directly inline;
1215 if ARG is 2, forward message as an rfc822 MIME section;
1216 if ARG is 3, decode message and forward as an rfc822 MIME section;
1217 if ARG is 4, forward message directly inline;
1218 otherwise, use flipped `message-forward-as-mime'.
1219 If POST, post instead of mail.
1220 For the `inline' alternatives, also see the variable
1221 `message-forward-ignored-headers'."
1222   (interactive "P")
1223   (if (cdr (gnus-summary-work-articles nil))
1224       ;; Process marks are given.
1225       (gnus-uu-digest-mail-forward arg post)
1226     ;; No process marks.
1227     (let ((message-forward-as-mime message-forward-as-mime)
1228           (message-forward-show-mml message-forward-show-mml))
1229       (cond
1230        ((null arg))
1231        ((eq arg 1)
1232         (setq message-forward-as-mime nil
1233               message-forward-show-mml t))
1234        ((eq arg 2)
1235         (setq message-forward-as-mime t
1236               message-forward-show-mml nil))
1237        ((eq arg 3)
1238         (setq message-forward-as-mime t
1239               message-forward-show-mml t))
1240        ((eq arg 4)
1241         (setq message-forward-as-mime nil
1242               message-forward-show-mml nil))
1243        (t
1244         (setq message-forward-as-mime (not message-forward-as-mime))))
1245       (let* ((gnus-article-reply (gnus-summary-article-number))
1246              (gnus-article-yanked-articles (list gnus-article-reply)))
1247         (gnus-setup-message 'forward
1248           (gnus-summary-select-article)
1249           (let ((mail-parse-charset
1250                  (or (and (gnus-buffer-live-p gnus-article-buffer)
1251                           (with-current-buffer gnus-article-buffer
1252                             gnus-article-charset))
1253                      gnus-newsgroup-charset))
1254                 (mail-parse-ignored-charsets
1255                  gnus-newsgroup-ignored-charsets))
1256             (set-buffer gnus-original-article-buffer)
1257             (message-forward post)))))))
1258
1259 (defun gnus-summary-resend-message (address n)
1260   "Resend the current article to ADDRESS."
1261   (interactive
1262    (list (message-read-from-minibuffer
1263           "Resend message(s) to: "
1264           (when (and gnus-summary-resend-default-address
1265                      (gnus-buffer-live-p gnus-original-article-buffer))
1266             ;; If some other article is currently selected, the
1267             ;; initial-contents is wrong. Whatever, it is just the
1268             ;; initial-contents.
1269             (with-current-buffer gnus-original-article-buffer
1270               (nnmail-fetch-field "to"))))
1271          current-prefix-arg))
1272   (dolist (article (gnus-summary-work-articles n))
1273     (gnus-summary-select-article nil nil nil article)
1274     (save-excursion
1275       (set-buffer gnus-original-article-buffer)
1276       (message-resend address))
1277     (gnus-summary-mark-article-as-forwarded article)))
1278
1279 ;; From: Matthieu Moy <Matthieu.Moy@imag.fr>
1280 (defun gnus-summary-resend-message-edit ()
1281   "Resend an article that has already been sent.
1282 A new buffer will be created to allow the user to modify body and
1283 contents of the message, and then, everything will happen as when
1284 composing a new message."
1285   (interactive)
1286   (let ((article (gnus-summary-article-number)))
1287     (gnus-setup-message 'reply-yank
1288       (gnus-summary-select-article t)
1289       (set-buffer gnus-original-article-buffer)
1290       (let ((cur (current-buffer))
1291             (to (message-fetch-field "to")))
1292         ;; Get a normal message buffer.
1293         (message-pop-to-buffer (message-buffer-name "Resend" to))
1294         (insert-buffer-substring cur)
1295         (mime-to-mml)
1296         (message-narrow-to-head-1)
1297         ;; Gnus will generate a new one when sending.
1298         (message-remove-header "Message-ID")
1299         (message-remove-header message-ignored-resent-headers t)
1300         ;; Remove unwanted headers.
1301         (goto-char (point-max))
1302         (insert mail-header-separator)
1303         (goto-char (point-min))
1304         (when (re-search-forward "^To:\\|^Newsgroups:" nil 'move)
1305           (forward-char 1))
1306         (widen)))))
1307
1308 (defun gnus-summary-post-forward (&optional arg)
1309   "Forward the current article to a newsgroup.
1310 See `gnus-summary-mail-forward' for ARG."
1311   (interactive "P")
1312   (gnus-summary-mail-forward arg t))
1313
1314 (defvar gnus-nastygram-message
1315   "The following article was inappropriately posted to %s.\n\n"
1316   "Format string to insert in nastygrams.
1317 The current group name will be inserted at \"%s\".")
1318
1319 (defun gnus-summary-mail-nastygram (n)
1320   "Send a nastygram to the author of the current article."
1321   (interactive "P")
1322   (when (or gnus-expert-user
1323             (gnus-y-or-n-p
1324              "Really send a nastygram to the author of the current article? "))
1325     (let ((group gnus-newsgroup-name))
1326       (gnus-summary-reply-with-original n)
1327       (set-buffer gnus-message-buffer)
1328       (message-goto-body)
1329       (insert (format gnus-nastygram-message group))
1330       (message-send-and-exit))))
1331
1332 (defun gnus-summary-mail-crosspost-complaint (n)
1333   "Send a complaint about crossposting to the current article(s)."
1334   (interactive "P")
1335   (dolist (article (gnus-summary-work-articles n))
1336     (set-buffer gnus-summary-buffer)
1337     (gnus-summary-goto-subject article)
1338     (let ((group (gnus-group-real-name gnus-newsgroup-name))
1339           newsgroups followup-to)
1340       (gnus-summary-select-article)
1341       (set-buffer gnus-original-article-buffer)
1342       (if (and (<= (length (message-tokenize-header
1343                             (setq newsgroups
1344                                   (mail-fetch-field "newsgroups"))
1345                             ", "))
1346                    1)
1347                (or (not (setq followup-to (mail-fetch-field "followup-to")))
1348                    (not (member group (message-tokenize-header
1349                                        followup-to ", ")))))
1350           (if followup-to
1351               (gnus-message 1 "Followup-to restricted")
1352             (gnus-message 1 "Not a crossposted article"))
1353         (set-buffer gnus-summary-buffer)
1354         (gnus-summary-reply-with-original 1)
1355         (set-buffer gnus-message-buffer)
1356         (message-goto-body)
1357         (insert (format gnus-crosspost-complaint newsgroups group))
1358         (message-goto-subject)
1359         (re-search-forward " *$")
1360         (replace-match " (crosspost notification)" t t)
1361         (gnus-deactivate-mark)
1362         (when (gnus-y-or-n-p "Send this complaint? ")
1363           (message-send-and-exit))))))
1364
1365 (defun gnus-mail-parse-comma-list ()
1366   (let (accumulated
1367         beg)
1368     (skip-chars-forward " ")
1369     (while (not (eobp))
1370       (setq beg (point))
1371       (skip-chars-forward "^,")
1372       (while (zerop
1373               (save-excursion
1374                 (save-restriction
1375                   (let ((i 0))
1376                     (narrow-to-region beg (point))
1377                     (goto-char beg)
1378                     (logand (progn
1379                               (while (search-forward "\"" nil t)
1380                                 (incf i))
1381                               (if (zerop i) 2 i))
1382                             2)))))
1383         (skip-chars-forward ",")
1384         (skip-chars-forward "^,"))
1385       (skip-chars-backward " ")
1386       (push (buffer-substring beg (point))
1387             accumulated)
1388       (skip-chars-forward "^,")
1389       (skip-chars-forward ", "))
1390     accumulated))
1391
1392 (defun gnus-inews-add-to-address (group)
1393   (let ((to-address (mail-fetch-field "to")))
1394     (when (and to-address
1395                (gnus-alive-p))
1396       ;; This mail group doesn't have a `to-list', so we add one
1397       ;; here.  Magic!
1398       (when (gnus-y-or-n-p
1399              (format "Do you want to add this as `to-list': %s? " to-address))
1400         (gnus-group-add-parameter group (cons 'to-list to-address))))))
1401
1402 (defun gnus-put-message ()
1403   "Put the current message in some group and return to Gnus."
1404   (interactive)
1405   (let ((reply gnus-article-reply)
1406         (winconf gnus-prev-winconf)
1407         (group gnus-newsgroup-name))
1408     (unless (and group
1409                  (not (gnus-group-read-only-p group)))
1410       (setq group (read-string "Put in group: " nil (gnus-writable-groups))))
1411
1412     (when (gnus-group-entry group)
1413       (error "No such group: %s" group))
1414     (save-excursion
1415       (save-restriction
1416         (widen)
1417         (message-narrow-to-headers)
1418         (let ((gnus-deletable-headers nil))
1419           (message-generate-headers
1420            (if (message-news-p)
1421                message-required-news-headers
1422              message-required-mail-headers)))
1423         (goto-char (point-max))
1424         (if (string-match " " group)
1425             (insert "Gcc: \"" group "\"\n")
1426           (insert "Gcc: " group "\n"))
1427         (widen)))
1428     (gnus-inews-do-gcc)
1429     (when (and (get-buffer gnus-group-buffer)
1430                (gnus-buffer-exists-p (car-safe reply))
1431                (cdr reply))
1432       (set-buffer (car reply))
1433       (gnus-summary-mark-article-as-replied (cdr reply)))
1434     (when winconf
1435       (set-window-configuration winconf))))
1436
1437 (defun gnus-article-mail (yank)
1438   "Send a reply to the address near point.
1439 If YANK is non-nil, include the original article."
1440   (interactive "P")
1441   (let ((address
1442          (buffer-substring
1443           (save-excursion (re-search-backward "[ \t\n]" nil t) (1+ (point)))
1444           (save-excursion (re-search-forward "[ \t\n]" nil t) (1- (point))))))
1445     (when address
1446       (gnus-msg-mail address)
1447       (when yank
1448         (gnus-inews-yank-articles (list (cdr gnus-article-current)))))))
1449
1450 (defvar nntp-server-type)
1451 (defun gnus-bug ()
1452   "Send a bug report to the Gnus maintainers."
1453   (interactive)
1454   (unless (gnus-alive-p)
1455     (error "Gnus has been shut down"))
1456   (gnus-setup-message (if (message-mail-user-agent) 'message 'bug)
1457     (unless (message-mail-user-agent)
1458       (delete-other-windows)
1459       (when gnus-bug-create-help-buffer
1460         (switch-to-buffer "*Gnus Help Bug*")
1461         (erase-buffer)
1462         (insert gnus-bug-message)
1463         (goto-char (point-min)))
1464       (message-pop-to-buffer "*Gnus Bug*"))
1465     (let ((message-this-is-mail t))
1466       (message-setup `((To . ,gnus-maintainer) (Subject . ""))))
1467     (when gnus-bug-create-help-buffer
1468       (push `(gnus-bug-kill-buffer) message-send-actions))
1469     (goto-char (point-min))
1470     (re-search-forward (concat "^" (regexp-quote mail-header-separator) "$"))
1471     (forward-line 1)
1472     (insert (gnus-version) "\n"
1473             (emacs-version) "\n")
1474     (when (and (boundp 'nntp-server-type)
1475                (stringp nntp-server-type))
1476       (insert nntp-server-type))
1477     (insert "\n\n\n\n\n")
1478     (let (text)
1479       (save-excursion
1480         (set-buffer (gnus-get-buffer-create " *gnus environment info*"))
1481         (erase-buffer)
1482         (gnus-debug)
1483         (setq text (buffer-string)))
1484       (insert "<#part type=application/emacs-lisp disposition=inline description=\"User settings\">\n" text "\n<#/part>"))
1485     (goto-char (point-min))
1486     (search-forward "Subject: " nil t)
1487     (message "")))
1488
1489 (defun gnus-bug-kill-buffer ()
1490   (when (get-buffer "*Gnus Help Bug*")
1491     (kill-buffer "*Gnus Help Bug*")))
1492
1493 (defun gnus-summary-yank-message (buffer n)
1494   "Yank the current article into a composed message."
1495   (interactive
1496    (list (completing-read "Buffer: " (mapcar 'list (message-buffers)) nil t)
1497          current-prefix-arg))
1498   (gnus-summary-iterate n
1499     (let ((gnus-inhibit-treatment t))
1500       (gnus-summary-select-article))
1501     (save-excursion
1502       (set-buffer buffer)
1503       (message-yank-buffer gnus-article-buffer))))
1504
1505 (defun gnus-debug ()
1506   "Attempts to go through the Gnus source file and report what variables have been changed.
1507 The source file has to be in the Emacs load path."
1508   (interactive)
1509   (let ((files gnus-debug-files)
1510         (point (point))
1511         file expr olist sym)
1512     (gnus-message 4 "Please wait while we snoop your variables...")
1513     (sit-for 0)
1514     ;; Go through all the files looking for non-default values for variables.
1515     (save-excursion
1516       (set-buffer (gnus-get-buffer-create " *gnus bug info*"))
1517       (while files
1518         (erase-buffer)
1519         (when (and (setq file (locate-library (pop files)))
1520                    (file-exists-p file))
1521           (insert-file-contents file)
1522           (goto-char (point-min))
1523           (if (not (re-search-forward "^;;* *Internal variables" nil t))
1524               (gnus-message 4 "Malformed sources in file %s" file)
1525             (narrow-to-region (point-min) (point))
1526             (goto-char (point-min))
1527             (while (setq expr (ignore-errors (read (current-buffer))))
1528               (ignore-errors
1529                 (and (or (eq (car expr) 'defvar)
1530                          (eq (car expr) 'defcustom))
1531                      (stringp (nth 3 expr))
1532                      (not (memq (nth 1 expr) gnus-debug-exclude-variables))
1533                      (or (not (boundp (nth 1 expr)))
1534                          (not (equal (eval (nth 2 expr))
1535                                      (symbol-value (nth 1 expr)))))
1536                      (push (nth 1 expr) olist)))))))
1537       (kill-buffer (current-buffer)))
1538     (when (setq olist (nreverse olist))
1539       (insert "------------------ Environment follows ------------------\n\n"))
1540     (while olist
1541       (if (boundp (car olist))
1542           (ignore-errors
1543            (gnus-pp
1544             `(setq ,(car olist)
1545                    ,(if (or (consp (setq sym (symbol-value (car olist))))
1546                             (and (symbolp sym)
1547                                  (not (or (eq sym nil)
1548                                           (eq sym t)))))
1549                         (list 'quote (symbol-value (car olist)))
1550                       (symbol-value (car olist))))))
1551         (insert ";; (makeunbound '" (symbol-name (car olist)) ")\n"))
1552       (setq olist (cdr olist)))
1553     (insert "\n\n")
1554     ;; Remove any control chars - they seem to cause trouble for some
1555     ;; mailers.  (Byte-compiled output from the stuff above.)
1556     (goto-char point)
1557     (while (re-search-forward (mm-string-as-multibyte
1558                                "[\000-\010\013-\037\200-\237]") nil t)
1559       (replace-match (format "\\%03o" (string-to-char (match-string 0)))
1560                      t t))))
1561
1562 ;;; Treatment of rejected articles.
1563 ;;; Bounced mail.
1564
1565 (defun gnus-summary-resend-bounced-mail (&optional fetch)
1566   "Re-mail the current message.
1567 This only makes sense if the current message is a bounce message that
1568 contains some mail you have written which has been bounced back to
1569 you.
1570 If FETCH, try to fetch the article that this is a reply to, if indeed
1571 this is a reply."
1572   (interactive "P")
1573   (gnus-summary-select-article t)
1574   (set-buffer gnus-original-article-buffer)
1575   (gnus-setup-message 'compose-bounce
1576     (let* ((references (mail-fetch-field "references"))
1577            (parent (and references (gnus-parent-id references))))
1578       (message-bounce)
1579       ;; If there are references, we fetch the article we answered to.
1580       (and fetch parent
1581            (gnus-summary-refer-article parent)
1582            (gnus-summary-show-all-headers)))))
1583
1584 ;;; Gcc handling.
1585
1586 (defun gnus-inews-group-method (group)
1587   (cond
1588    ;; If the group doesn't exist, we assume
1589    ;; it's an archive group...
1590    ((and (null (gnus-get-info group))
1591          (eq (car (gnus-server-to-method gnus-message-archive-method))
1592              (car (gnus-server-to-method (gnus-group-method group)))))
1593     gnus-message-archive-method)
1594    ;; Use the method.
1595    ((gnus-info-method (gnus-get-info group))
1596     (gnus-info-method (gnus-get-info group)))
1597    ;; Find the method.
1598    (t (gnus-server-to-method (gnus-group-method group)))))
1599
1600 ;; Do Gcc handling, which copied the message over to some group.
1601 (defun gnus-inews-do-gcc (&optional gcc)
1602   (interactive)
1603   (save-excursion
1604     (save-restriction
1605       (message-narrow-to-headers)
1606       (let ((gcc (or gcc (mail-fetch-field "gcc" nil t)))
1607             (cur (current-buffer))
1608             groups group method group-art
1609             mml-externalize-attachments)
1610         (when gcc
1611           (message-remove-header "gcc")
1612           (widen)
1613           (setq groups (message-unquote-tokens
1614                         (message-tokenize-header gcc " ,")))
1615           ;; Copy the article over to some group(s).
1616           (while (setq group (pop groups))
1617             (unless (gnus-check-server
1618                      (setq method (gnus-inews-group-method group)))
1619               (error "Can't open server %s" (if (stringp method) method
1620                                               (car method))))
1621             (unless (gnus-request-group group nil method)
1622               (gnus-request-create-group group method))
1623             (setq mml-externalize-attachments
1624                   (if (stringp gnus-gcc-externalize-attachments)
1625                       (string-match gnus-gcc-externalize-attachments group)
1626                     gnus-gcc-externalize-attachments))
1627             (save-excursion
1628               (nnheader-set-temp-buffer " *acc*")
1629               (insert-buffer-substring cur)
1630               (message-encode-message-body)
1631               (save-restriction
1632                 (message-narrow-to-headers)
1633                 (let* ((mail-parse-charset message-default-charset)
1634                        (newsgroups-field (save-restriction
1635                                            (message-narrow-to-headers-or-head)
1636                                            (message-fetch-field "Newsgroups")))
1637                        (followup-field (save-restriction
1638                                          (message-narrow-to-headers-or-head)
1639                                          (message-fetch-field "Followup-To")))
1640                        ;; BUG: We really need to get the charset for
1641                        ;; each name in the Newsgroups and Followup-To
1642                        ;; lines to allow crossposting between group
1643                        ;; namess with incompatible character sets.
1644                        ;; -- Per Abrahamsen <abraham@dina.kvl.dk> 2001-10-08.
1645                        (group-field-charset
1646                         (gnus-group-name-charset
1647                          method (or newsgroups-field "")))
1648                        (followup-field-charset
1649                         (gnus-group-name-charset
1650                          method (or followup-field "")))
1651                        (rfc2047-header-encoding-alist
1652                         (append
1653                          (when group-field-charset
1654                            (list (cons "Newsgroups" group-field-charset)))
1655                          (when followup-field-charset
1656                            (list (cons "Followup-To" followup-field-charset)))
1657                          rfc2047-header-encoding-alist)))
1658                   (mail-encode-encoded-word-buffer)))
1659               (goto-char (point-min))
1660               (when (re-search-forward
1661                      (concat "^" (regexp-quote mail-header-separator) "$")
1662                      nil t)
1663                 (replace-match "" t t ))
1664               (when (or (not (gnus-check-backend-function
1665                               'request-accept-article group))
1666                         (not (setq group-art
1667                                    (gnus-request-accept-article
1668                                     group method t t))))
1669                 (gnus-message 1 "Couldn't store article in group %s: %s"
1670                               group (gnus-status-message method)))
1671               (when (and group-art
1672                          ;; FIXME: Should gcc-mark-as-read work when
1673                          ;; Gnus is not running?
1674                          (gnus-alive-p)
1675                          (or gnus-gcc-mark-as-read
1676                              (and
1677                               (boundp 'gnus-inews-mark-gcc-as-read)
1678                               (symbol-value 'gnus-inews-mark-gcc-as-read))))
1679                 (gnus-group-mark-article-read group (cdr group-art)))
1680               (kill-buffer (current-buffer)))))))))
1681
1682 (defun gnus-inews-insert-gcc ()
1683   "Insert Gcc headers based on `gnus-outgoing-message-group'."
1684   (save-excursion
1685     (save-restriction
1686       (message-narrow-to-headers)
1687       (let* ((group gnus-outgoing-message-group)
1688              (gcc (cond
1689                    ((functionp group)
1690                     (funcall group))
1691                    ((or (stringp group) (listp group))
1692                     group))))
1693         (when gcc
1694           (insert "Gcc: "
1695                   (if (stringp gcc)
1696                       (if (string-match " " gcc)
1697                           (concat "\"" gcc "\"")
1698                         gcc)
1699                     (mapconcat (lambda (group)
1700                                  (if (string-match " " group)
1701                                      (concat "\"" group "\"")
1702                                    group))
1703                                gcc " "))
1704                   "\n"))))))
1705
1706 (defun gnus-inews-insert-archive-gcc (&optional group)
1707   "Insert the Gcc to say where the article is to be archived."
1708   (let* ((var gnus-message-archive-group)
1709          (group (or group gnus-newsgroup-name ""))
1710          (gcc-self-val
1711           (and gnus-newsgroup-name
1712                (not (equal gnus-newsgroup-name ""))
1713                (gnus-group-find-parameter
1714                 gnus-newsgroup-name 'gcc-self)))
1715          result
1716          (groups
1717           (cond
1718            ((null gnus-message-archive-method)
1719             ;; Ignore.
1720             nil)
1721            ((stringp var)
1722             ;; Just a single group.
1723             (list var))
1724            ((null var)
1725             ;; We don't want this.
1726             nil)
1727            ((and (listp var) (stringp (car var)))
1728             ;; A list of groups.
1729             var)
1730            ((functionp var)
1731             ;; A function.
1732             (funcall var group))
1733            (t
1734             ;; An alist of regexps/functions/forms.
1735             (while (and var
1736                         (not
1737                          (setq result
1738                                (cond
1739                                 ((stringp (caar var))
1740                                  ;; Regexp.
1741                                  (when (string-match (caar var) group)
1742                                    (cdar var)))
1743                                 ((functionp (car var))
1744                                  ;; Function.
1745                                  (funcall (car var) group))
1746                                 (t
1747                                  (eval (car var)))))))
1748               (setq var (cdr var)))
1749             result)))
1750          name)
1751     (when (or groups gcc-self-val)
1752       (when (stringp groups)
1753         (setq groups (list groups)))
1754       (save-excursion
1755         (save-restriction
1756           (message-narrow-to-headers)
1757           (goto-char (point-max))
1758           (insert "Gcc: ")
1759           (if gcc-self-val
1760               ;; Use the `gcc-self' param value instead.
1761               (progn
1762                 (insert
1763                  (if (stringp gcc-self-val)
1764                      (if (string-match " " gcc-self-val)
1765                          (concat "\"" gcc-self-val "\"")
1766                        gcc-self-val)
1767                    ;; In nndoc groups, we use the parent group name
1768                    ;; instead of the current group.
1769                    (let ((group (or (gnus-group-find-parameter
1770                                      gnus-newsgroup-name 'parent-group)
1771                                     group)))
1772                      (if (string-match " " group)
1773                          (concat "\"" group "\"")
1774                        group))))
1775                 (if (not (eq gcc-self-val 'none))
1776                     (insert "\n")
1777                   (gnus-delete-line)))
1778             ;; Use the list of groups.
1779             (while (setq name (pop groups))
1780               (let ((str (if (string-match ":" name)
1781                              name
1782                            (gnus-group-prefixed-name
1783                             name gnus-message-archive-method))))
1784                 (insert (if (string-match " " str)
1785                             (concat "\"" str "\"")
1786                           str)))
1787               (when groups
1788                 (insert " ")))
1789             (insert "\n")))))))
1790
1791 (defun gnus-mailing-list-followup-to ()
1792   "Look at the headers in the current buffer and return a Mail-Followup-To address."
1793   (let ((x-been-there (gnus-fetch-original-field "x-beenthere"))
1794         (list-post (gnus-fetch-original-field "list-post")))
1795     (when (and list-post
1796                (string-match "mailto:\\([^>]+\\)" list-post))
1797       (setq list-post (match-string 1 list-post)))
1798     (or list-post
1799         x-been-there)))
1800
1801 ;;; Posting styles.
1802
1803 (defun gnus-configure-posting-styles (&optional group-name)
1804   "Configure posting styles according to `gnus-posting-styles'."
1805   (unless gnus-inhibit-posting-styles
1806     (let ((group (or group-name gnus-newsgroup-name ""))
1807           (styles gnus-posting-styles)
1808           style match attribute value v results
1809           filep name address element)
1810       ;; If the group has a posting-style parameter, add it at the end with a
1811       ;; regexp matching everything, to be sure it takes precedence over all
1812       ;; the others.
1813       (when gnus-newsgroup-name
1814         (let ((tmp-style (gnus-group-find-parameter group 'posting-style t)))
1815           (when tmp-style
1816             (setq styles (append styles (list (cons ".*" tmp-style)))))))
1817       ;; Go through all styles and look for matches.
1818       (dolist (style styles)
1819         (setq match (pop style))
1820         (goto-char (point-min))
1821         (when (cond
1822                ((stringp match)
1823                 ;; Regexp string match on the group name.
1824                 (string-match match group))
1825                ((eq match 'header)
1826                 ;; Obsolete format of header match.
1827                 (and (gnus-buffer-live-p gnus-article-copy)
1828                      (with-current-buffer gnus-article-copy
1829                        (save-restriction
1830                          (nnheader-narrow-to-headers)
1831                          (let ((header (message-fetch-field (pop style))))
1832                            (and header
1833                                 (string-match (pop style) header)))))))
1834                ((or (symbolp match)
1835                     (functionp match))
1836                 (cond
1837                  ((functionp match)
1838                   ;; Function to be called.
1839                   (funcall match))
1840                  ((boundp match)
1841                   ;; Variable to be checked.
1842                   (symbol-value match))))
1843                ((listp match)
1844                 (cond
1845                  ((eq (car match) 'header)
1846                   ;; New format of header match.
1847                   (and (gnus-buffer-live-p gnus-article-copy)
1848                        (with-current-buffer gnus-article-copy
1849                          (save-restriction
1850                            (nnheader-narrow-to-headers)
1851                            (let ((header (message-fetch-field (nth 1 match))))
1852                              (and header
1853                                   (string-match (nth 2 match) header)))))))
1854                  (t
1855                   ;; This is a form to be evaled.
1856                   (eval match)))))
1857           ;; We have a match, so we set the variables.
1858           (dolist (attribute style)
1859             (setq element (pop attribute)
1860                   filep nil)
1861             (setq value
1862                   (cond
1863                    ((eq (car attribute) :file)
1864                     (setq filep t)
1865                     (cadr attribute))
1866                    ((eq (car attribute) :value)
1867                     (cadr attribute))
1868                    (t
1869                     (car attribute))))
1870             ;; We get the value.
1871             (setq v
1872                   (cond
1873                    ((stringp value)
1874                     value)
1875                    ((or (symbolp value)
1876                         (functionp value))
1877                     (cond ((functionp value)
1878                            (funcall value))
1879                           ((boundp value)
1880                            (symbol-value value))))
1881                    ((listp value)
1882                     (eval value))))
1883             ;; Translate obsolescent value.
1884             (cond
1885              ((eq element 'signature-file)
1886               (setq element 'signature
1887                     filep t))
1888              ((eq element 'x-face-file)
1889               (setq element 'x-face
1890                     filep t)))
1891             ;; Post-processing for the signature posting-style:
1892             (and (eq element 'signature) filep
1893                  message-signature-directory
1894                  ;; don't actually use the signature directory
1895                  ;; if message-signature-file contains a path.
1896                  (not (file-name-directory v))
1897                  (setq v (nnheader-concat message-signature-directory v)))
1898             ;; Get the contents of file elems.
1899             (when (and filep v)
1900               (setq v (with-temp-buffer
1901                         (insert-file-contents v)
1902                         (buffer-substring
1903                          (point-min)
1904                          (progn
1905                            (goto-char (point-max))
1906                            (if (zerop (skip-chars-backward "\n"))
1907                                (point)
1908                              (1+ (point))))))))
1909             (setq results (delq (assoc element results) results))
1910             (push (cons element v) results))))
1911       ;; Now we have all the styles, so we insert them.
1912       (setq name (assq 'name results)
1913             address (assq 'address results))
1914       (setq results (delq name (delq address results)))
1915       (gnus-make-local-hook 'message-setup-hook)
1916       (setq results (sort results (lambda (x y)
1917                                     (string-lessp (car x) (car y)))))
1918       (dolist (result results)
1919         (add-hook 'message-setup-hook
1920                   (cond
1921                    ((eq 'eval (car result))
1922                     'ignore)
1923                    ((eq 'body (car result))
1924                     `(lambda ()
1925                        (save-excursion
1926                          (message-goto-body)
1927                          (insert ,(cdr result)))))
1928                    ((eq 'signature (car result))
1929                     (set (make-local-variable 'message-signature) nil)
1930                     (set (make-local-variable 'message-signature-file) nil)
1931                     (if (not (cdr result))
1932                         'ignore
1933                       `(lambda ()
1934                          (save-excursion
1935                            (let ((message-signature ,(cdr result)))
1936                              (when message-signature
1937                                (message-insert-signature)))))))
1938                    (t
1939                     (let ((header
1940                            (if (symbolp (car result))
1941                                (capitalize (symbol-name (car result)))
1942                              (car result))))
1943                       `(lambda ()
1944                          (save-excursion
1945                            (message-remove-header ,header)
1946                            (let ((value ,(cdr result)))
1947                              (when value
1948                                (message-goto-eoh)
1949                                (insert ,header ": " value)
1950                                (unless (bolp)
1951                                  (insert "\n")))))))))
1952                   nil 'local))
1953       (when (or name address)
1954         (add-hook 'message-setup-hook
1955                   `(lambda ()
1956                      (set (make-local-variable 'user-mail-address)
1957                           ,(or (cdr address) user-mail-address))
1958                      (let ((user-full-name ,(or (cdr name) (user-full-name)))
1959                            (user-mail-address
1960                             ,(or (cdr address) user-mail-address)))
1961                        (save-excursion
1962                          (message-remove-header "From")
1963                          (message-goto-eoh)
1964                          (insert "From: " (message-make-from) "\n"))))
1965                   nil 'local)))))
1966
1967 ;;; Allow redefinition of functions.
1968
1969 (gnus-ems-redefine)
1970
1971 (provide 'gnus-msg)
1972
1973 ;;; arch-tag: 9f22b2f5-1c0a-49de-916e-4c88e984852b
1974 ;;; gnus-msg.el ends here