cgit.sxemacs.org Git - gnus/blob - lisp/gnus-msg.el

   1 ;;; gnus-msg.el --- mail and post interface for Gnus
   2 ;; Copyright (C) 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003
   3 ;;        Free Software Foundation, Inc.
   4
   5 ;; Author: Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>
   6 ;;      Lars Magne Ingebrigtsen <larsi@gnus.org>
   7 ;; Keywords: news
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;;; Code:
  29
  30 (eval-when-compile (require 'cl))
  31
  32 (require 'gnus)
  33 (require 'gnus-ems)
  34 (require 'message)
  35 (require 'gnus-art)
  36 (require 'gnus-util)
  37
  38 (defcustom gnus-post-method 'current
  39   "*Preferred method for posting USENET news.
  40
  41 If this variable is `current' (which is the default), Gnus will use
  42 the \"current\" select method when posting.  If it is `native', Gnus
  43 will use the native select method when posting.
  44
  45 This method will not be used in mail groups and the like, only in
  46 \"real\" newsgroups.
  47
  48 If not `native' nor `current', the value must be a valid method as discussed
  49 in the documentation of `gnus-select-method'.  It can also be a list of
  50 methods.  If that is the case, the user will be queried for what select
  51 method to use when posting."
  52   :group 'gnus-group-foreign
  53   :link '(custom-manual "(gnus)Posting Server")
  54   :type `(choice (const native)
  55                  (const current)
  56                  (sexp :tag "Methods" ,gnus-select-method)))
  57
  58 (defcustom gnus-outgoing-message-group nil
  59   "*All outgoing messages will be put in this group.
  60 If you want to store all your outgoing mail and articles in the group
  61 \"nnml:archive\", you set this variable to that value.  This variable
  62 can also be a list of group names.
  63
  64 If you want to have greater control over what group to put each
  65 message in, you can set this variable to a function that checks the
  66 current newsgroup name and then returns a suitable group name (or list
  67 of names)."
  68   :group 'gnus-message
  69   :type '(choice (string :tag "Group")
  70                  (function)))
  71
  72 (defcustom gnus-mailing-list-groups nil
  73   "*If non-nil a regexp matching groups that are really mailing lists.
  74 This is useful when you're reading a mailing list that has been
  75 gatewayed to a newsgroup, and you want to followup to an article in
  76 the group."
  77   :group 'gnus-message
  78   :type '(choice (regexp)
  79                  (const nil)))
  80
  81 (defcustom gnus-add-to-list nil
  82   "*If non-nil, add a `to-list' parameter automatically."
  83   :group 'gnus-message
  84   :type 'boolean)
  85
  86 (defcustom gnus-crosspost-complaint
  87   "Hi,
  88
  89 You posted the article below with the following Newsgroups header:
  90
  91 Newsgroups: %s
  92
  93 The %s group, at least, was an inappropriate recipient
  94 of this message.  Please trim your Newsgroups header to exclude this
  95 group before posting in the future.
  96
  97 Thank you.
  98
  99 "
 100   "Format string to be inserted when complaining about crossposts.
 101 The first %s will be replaced by the Newsgroups header;
 102 the second with the current group name."
 103   :group 'gnus-message
 104   :type 'string)
 105
 106 (defcustom gnus-message-setup-hook nil
 107   "Hook run after setting up a message buffer."
 108   :group 'gnus-message
 109   :type 'hook)
 110
 111 (defcustom gnus-bug-create-help-buffer t
 112   "*Should we create the *Gnus Help Bug* buffer?"
 113   :group 'gnus-message
 114   :type 'boolean)
 115
 116 (defcustom gnus-posting-styles nil
 117   "*Alist of styles to use when posting.
 118 See Info node `(gnus)Posting Styles'."
 119   :group 'gnus-message
 120   :link '(custom-manual "(gnus)Posting Styles")
 121   :type '(repeat (cons (choice (regexp)
 122                                (variable)
 123                                (list (const header)
 124                                      (string :tag "Header")
 125                                      (regexp :tag "Regexp"))
 126                                (function)
 127                                (sexp))
 128                        (repeat (list
 129                                 (choice (const signature)
 130                                         (const signature-file)
 131                                         (const organization)
 132                                         (const address)
 133                                         (const x-face-file)
 134                                         (const name)
 135                                         (const body)
 136                                         (symbol)
 137                                         (string :tag "Header"))
 138                                 (choice (string)
 139                                         (function)
 140                                         (variable)
 141                                         (sexp)))))))
 142
 143 (defcustom gnus-gcc-mark-as-read nil
 144   "If non-nil, automatically mark Gcc articles as read."
 145   :version "21.1"
 146   :group 'gnus-message
 147   :type 'boolean)
 148
 149 (make-obsolete-variable 'gnus-inews-mark-gcc-as-read
 150                         'gnus-gcc-mark-as-read)
 151
 152 (defcustom gnus-gcc-externalize-attachments nil
 153   "Should local-file attachments be included as external parts in Gcc copies?
 154 If it is `all', attach files as external parts;
 155 if a regexp and matches the Gcc group name, attach files as external parts;
 156 if nil, attach files as normal parts."
 157   :version "21.1"
 158   :group 'gnus-message
 159   :type '(choice (const nil :tag "None")
 160                  (const all :tag "Any")
 161                  (string :tag "Regexp")))
 162
 163 (gnus-define-group-parameter
 164  posting-charset-alist
 165  :type list
 166  :function-document
 167  "Return the permitted unencoded charsets for posting of GROUP."
 168  :variable gnus-group-posting-charset-alist
 169  :variable-default
 170   '(("^\\(no\\|fr\\)\\.[^,]*\\(,[ \t\n]*\\(no\\|fr\\)\\.[^,]*\\)*$" iso-8859-1 (iso-8859-1))
 171     ("^\\(fido7\\|relcom\\)\\.[^,]*\\(,[ \t\n]*\\(fido7\\|relcom\\)\\.[^,]*\\)*$" koi8-r (koi8-r))
 172     (message-this-is-mail nil nil)
 173     (message-this-is-news nil t))
 174  :variable-document
 175   "Alist of regexps and permitted unencoded charsets for posting.
 176 Each element of the alist has the form (TEST HEADER BODY-LIST), where
 177 TEST is either a regular expression matching the newsgroup header or a
 178 variable to query,
 179 HEADER is the charset which may be left unencoded in the header (nil
 180 means encode all charsets),
 181 BODY-LIST is a list of charsets which may be encoded using 8bit
 182 content-transfer encoding in the body, or one of the special values
 183 nil (always encode using quoted-printable) or t (always use 8bit).
 184
 185 Note that any value other than nil for HEADER infringes some RFCs, so
 186 use this option with care."
 187  :variable-group gnus-charset
 188  :variable-type
 189  '(repeat (list :tag "Permitted unencoded charsets"
 190                 (choice :tag "Where"
 191                         (regexp :tag "Group")
 192                         (const :tag "Mail message" :value message-this-is-mail)
 193                         (const :tag "News article" :value message-this-is-news))
 194                 (choice :tag "Header"
 195                         (const :tag "None" nil)
 196                         (symbol :tag "Charset"))
 197                 (choice :tag "Body"
 198                         (const :tag "Any" :value t)
 199                         (const :tag "None" :value nil)
 200                         (repeat :tag "Charsets"
 201                                 (symbol :tag "Charset")))))
 202  :parameter-type '(choice :tag "Permitted unencoded charsets"
 203                           :value nil
 204                           (repeat (symbol)))
 205  :parameter-document       "\
 206 List of charsets that are permitted to be unencoded.")
 207
 208 (defcustom gnus-debug-files
 209   '("gnus.el" "gnus-sum.el" "gnus-group.el"
 210     "gnus-art.el" "gnus-start.el" "gnus-async.el"
 211     "gnus-msg.el" "gnus-score.el" "gnus-win.el" "gnus-topic.el"
 212     "gnus-agent.el" "gnus-cache.el" "gnus-srvr.el"
 213     "mm-util.el" "mm-decode.el" "nnmail.el" "message.el")
 214   "Files whose variables will be reported in `gnus-bug'."
 215   :version "21.1"
 216   :group 'gnus-message
 217   :type '(repeat (string :tag "File")))
 218
 219 (defcustom gnus-debug-exclude-variables
 220   '(mm-mime-mule-charset-alist
 221     nnmail-split-fancy message-minibuffer-local-map)
 222   "Variables that should not be reported in `gnus-bug'."
 223   :version "21.1"
 224   :group 'gnus-message
 225   :type '(repeat (symbol :tag "Variable")))
 226
 227 (defcustom gnus-discouraged-post-methods
 228   '(nndraft nnml nnimap nnmaildir nnmh nnfolder nndir)
 229   "A list of back ends that are not used in \"real\" newsgroups.
 230 This variable is used only when `gnus-post-method' is `current'."
 231   :version "21.3"
 232   :group 'gnus-group-foreign
 233   :type '(repeat (symbol :tag "Back end")))
 234
 235 (defcustom gnus-message-replysign
 236   nil
 237   "Automatically sign replies to signed messages.
 238 See also the `mml-default-sign-method' variable."
 239   :group 'gnus-message
 240   :type 'boolean)
 241
 242 (defcustom gnus-message-replyencrypt
 243   nil
 244   "Automatically encrypt replies to encrypted messages.
 245 See also the `mml-default-encrypt-method' variable."
 246   :group 'gnus-message
 247   :type 'boolean)
 248
 249 (defcustom gnus-message-replysignencrypted
 250   t
 251   "Setting this causes automatically encrypted messages to also be signed."
 252   :group 'gnus-message
 253   :type 'boolean)
 254
 255 (defcustom gnus-confirm-mail-reply-to-news nil
 256   "If non-nil, Gnus requests confirmation when replying to news.
 257 This is done because new users often reply by mistake when reading
 258 news.
 259 This can also be a function receiving the group name as the only
 260 parameter which should return non-nil iff a confirmation is needed, or
 261 a regexp, in which case a confirmation is asked for iff the group name
 262 matches the regexp."
 263   :group 'gnus-message
 264   :type '(choice (const :tag "No" nil)
 265                  (const :tag "Yes" t)
 266                  (regexp :tag "Iff group matches regexp")
 267                  (function :tag "Iff function evaluates to non-nil")))
 268
 269 (defcustom gnus-confirm-treat-mail-like-news
 270   nil
 271   "If non-nil, Gnus will treat mail like news with regard to confirmation
 272 when replying by mail.  See the `gnus-confirm-mail-reply-to-news' variable
 273 for fine-tuning this.
 274 If nil, Gnus will never ask for confirmation if replying to mail."
 275   :group 'gnus-message
 276   :type 'boolean)
 277
 278 (defcustom gnus-summary-resend-default-address t
 279   "If non-nil, Gnus tries to suggest a default address to resend to.
 280 If nil, the address field will always be empty after invoking
 281 `gnus-summary-resend-message'."
 282   :group 'gnus-message
 283   :type 'boolean)
 284
 285 (defcustom gnus-user-agent 'emacs-gnus-type
 286   "Which information should be exposed in the User-Agent header.
 287
 288 It can be one of the symbols `gnus' \(show only Gnus version\), `emacs-gnus'
 289 \(show only Emacs and Gnus versions\), `emacs-gnus-config' \(same as
 290 `emacs-gnus' plus system configuration\), `emacs-gnus-type' \(same as
 291 `emacs-gnus' plus system type\) or a custom string.  If you set it to a
 292 string, be sure to use a valid format, see RFC 2616."
 293   :group 'gnus-message
 294   :type '(choice
 295           (item :tag "Show Gnus and Emacs versions and system type"
 296                 emacs-gnus-type)
 297           (item :tag "Show Gnus and Emacs versions and system configuration"
 298                 emacs-gnus-config)
 299           (item :tag "Show Gnus and Emacs versions" emacs-gnus)
 300           (item :tag "Show only Gnus version" gnus)
 301           (string :tag "Other")))
 302
 303 ;;; Internal variables.
 304
 305 (defvar gnus-inhibit-posting-styles nil
 306   "Inhibit the use of posting styles.")
 307
 308 (defvar gnus-article-yanked-articles nil)
 309 (defvar gnus-message-buffer "*Mail Gnus*")
 310 (defvar gnus-article-copy nil)
 311 (defvar gnus-check-before-posting nil)
 312 (defvar gnus-last-posting-server nil)
 313 (defvar gnus-message-group-art nil)
 314
 315 (defvar gnus-msg-force-broken-reply-to nil)
 316
 317 (defconst gnus-bug-message
 318   "Sending a bug report to the Gnus Towers.
 319 ========================================
 320
 321 The buffer below is a mail buffer.  When you press `C-c C-c', it will
 322 be sent to the Gnus Bug Exterminators.
 323
 324 The thing near the bottom of the buffer is how the environment
 325 settings will be included in the mail.  Please do not delete that.
 326 They will tell the Bug People what your environment is, so that it
 327 will be easier to locate the bugs.
 328
 329 If you have found a bug that makes Emacs go \"beep\", set
 330 debug-on-error to t (`M-x set-variable RET debug-on-error RET t RET')
 331 and include the backtrace in your bug report.
 332
 333 Please describe the bug in annoying, painstaking detail.
 334
 335 Thank you for your help in stamping out bugs.
 336 ")
 337
 338 (eval-and-compile
 339   (autoload 'gnus-uu-post-news "gnus-uu" nil t)
 340   (autoload 'news-setup "rnewspost")
 341   (autoload 'news-reply-mode "rnewspost")
 342   (autoload 'rmail-dont-reply-to "mail-utils")
 343   (autoload 'rmail-output "rmailout"))
 344
 345 \f
 346 ;;;
 347 ;;; Gnus Posting Functions
 348 ;;;
 349
 350 (gnus-define-keys (gnus-summary-send-map "S" gnus-summary-mode-map)
 351   "p" gnus-summary-post-news
 352   "i" gnus-summary-news-other-window
 353   "f" gnus-summary-followup
 354   "F" gnus-summary-followup-with-original
 355   "c" gnus-summary-cancel-article
 356   "s" gnus-summary-supersede-article
 357   "r" gnus-summary-reply
 358   "y" gnus-summary-yank-message
 359   "R" gnus-summary-reply-with-original
 360   "w" gnus-summary-wide-reply
 361   "W" gnus-summary-wide-reply-with-original
 362   "v" gnus-summary-very-wide-reply
 363   "V" gnus-summary-very-wide-reply-with-original
 364   "n" gnus-summary-followup-to-mail
 365   "N" gnus-summary-followup-to-mail-with-original
 366   "m" gnus-summary-mail-other-window
 367   "u" gnus-uu-post-news
 368   "\M-c" gnus-summary-mail-crosspost-complaint
 369   "Br" gnus-summary-reply-broken-reply-to
 370   "BR" gnus-summary-reply-broken-reply-to-with-original
 371   "om" gnus-summary-mail-forward
 372   "op" gnus-summary-post-forward
 373   "Om" gnus-uu-digest-mail-forward
 374   "Op" gnus-uu-digest-post-forward)
 375
 376 (gnus-define-keys (gnus-send-bounce-map "D" gnus-summary-send-map)
 377   "b" gnus-summary-resend-bounced-mail
 378   ;; "c" gnus-summary-send-draft
 379   "r" gnus-summary-resend-message
 380   "e" gnus-summary-resend-message-edit)
 381
 382 ;;; Internal functions.
 383
 384 (defun gnus-inews-make-draft ()
 385   `(lambda ()
 386      (gnus-inews-make-draft-meta-information
 387       ,gnus-newsgroup-name ',gnus-article-reply)))
 388
 389 (defvar gnus-article-reply nil)
 390 (defmacro gnus-setup-message (config &rest forms)
 391   (let ((winconf (make-symbol "gnus-setup-message-winconf"))
 392         (buffer (make-symbol "gnus-setup-message-buffer"))
 393         (article (make-symbol "gnus-setup-message-article"))
 394         (yanked (make-symbol "gnus-setup-yanked-articles"))
 395         (group (make-symbol "gnus-setup-message-group")))
 396     `(let ((,winconf (current-window-configuration))
 397            (,buffer (buffer-name (current-buffer)))
 398            (,article gnus-article-reply)
 399            (,yanked gnus-article-yanked-articles)
 400            (,group gnus-newsgroup-name)
 401            (message-header-setup-hook
 402             (copy-sequence message-header-setup-hook))
 403            (mbl mml-buffer-list)
 404            (message-mode-hook (copy-sequence message-mode-hook)))
 405        (setq mml-buffer-list nil)
 406        (add-hook 'message-header-setup-hook 'gnus-inews-insert-gcc)
 407        (add-hook 'message-header-setup-hook 'gnus-inews-insert-archive-gcc)
 408        ;; #### FIXME: for a reason that I did not manage to identify yet,
 409        ;; the variable `gnus-newsgroup-name' does not honor a dynamically
 410        ;; scoped or setq'ed value from a caller like `C-u gnus-summary-mail'.
 411        ;; After evaluation of @forms below, it gets the value we actually want
 412        ;; to override, and the posting styles are used. For that reason, I've
 413        ;; added an optional argument to `gnus-configure-posting-styles' to
 414        ;; make sure that the correct value for the group name is used. -- drv
 415        (add-hook 'message-mode-hook
 416                  (lambda ()
 417                    (gnus-configure-posting-styles ,group)))
 418        (gnus-pull ',(intern gnus-draft-meta-information-header)
 419                   message-required-headers)
 420        (when (and ,group
 421                   (not (string= ,group "")))
 422          (push (cons
 423                 (intern gnus-draft-meta-information-header)
 424                 (gnus-inews-make-draft))
 425                message-required-headers))
 426        (unwind-protect
 427            (progn
 428              ,@forms)
 429          (gnus-inews-add-send-actions ,winconf ,buffer ,article ,config
 430                                       ,yanked)
 431          (setq gnus-message-buffer (current-buffer))
 432          (set (make-local-variable 'gnus-message-group-art)
 433               (cons ,group ,article))
 434          (set (make-local-variable 'gnus-newsgroup-name) ,group)
 435          (gnus-run-hooks 'gnus-message-setup-hook)
 436          (if (eq major-mode 'message-mode)
 437              (let ((mbl1 mml-buffer-list))
 438                (setq mml-buffer-list mbl)  ;; Global value
 439                (set (make-local-variable 'mml-buffer-list) mbl1);; Local value
 440                (gnus-make-local-hook 'kill-buffer-hook)
 441                (gnus-make-local-hook 'change-major-mode-hook)
 442                (add-hook 'change-major-mode-hook 'mml-destroy-buffers nil t)
 443                (add-hook 'kill-buffer-hook 'mml-destroy-buffers t t))
 444            (mml-destroy-buffers)
 445            (setq mml-buffer-list mbl)))
 446        (message-hide-headers)
 447        (gnus-add-buffer)
 448        (gnus-configure-windows ,config t)
 449        (run-hooks 'post-command-hook)
 450        (set-buffer-modified-p nil))))
 451
 452 (defun gnus-inews-make-draft-meta-information (group article)
 453   (concat "(\"" group "\" "
 454           (if article (number-to-string
 455                        (if (listp article)
 456                            (car article)
 457                          article)) "\"\"")
 458           ")"))
 459
 460 ;;;###autoload
 461 (defun gnus-msg-mail (&optional to subject other-headers continue
 462                                 switch-action yank-action send-actions)
 463   "Start editing a mail message to be sent.
 464 Like `message-mail', but with Gnus paraphernalia, particularly the
 465 Gcc: header for archiving purposes."
 466   (interactive)
 467   (let ((buf (current-buffer))
 468         mail-buf)
 469     (gnus-setup-message 'message
 470       (message-mail to subject other-headers continue
 471                     nil yank-action send-actions))
 472     (when switch-action
 473       (setq mail-buf (current-buffer))
 474       (switch-to-buffer buf)
 475       (apply switch-action mail-buf nil)))
 476   ;; COMPOSEFUNC should return t if succeed.  Undocumented ???
 477   t)
 478
 479 (defvar save-selected-window-window)
 480
 481 ;;;###autoload
 482 (defun gnus-button-mailto (address)
 483   "Mail to ADDRESS."
 484   (set-buffer (gnus-copy-article-buffer))
 485   (gnus-setup-message 'message
 486     (message-reply address))
 487   (and (boundp 'save-selected-window-window)
 488        (not (window-live-p save-selected-window-window))
 489        (setq save-selected-window-window (selected-window))))
 490
 491 ;;;###autoload
 492 (defun gnus-button-reply (&optional to-address wide)
 493   "Like `message-reply'."
 494   (interactive)
 495   (gnus-setup-message 'message
 496     (message-reply to-address wide))
 497   (and (boundp 'save-selected-window-window)
 498        (not (window-live-p save-selected-window-window))
 499        (setq save-selected-window-window (selected-window))))
 500
 501 ;;;###autoload
 502 (define-mail-user-agent 'gnus-user-agent
 503   'gnus-msg-mail 'message-send-and-exit
 504   'message-kill-buffer 'message-send-hook)
 505
 506 (defun gnus-setup-posting-charset (group)
 507   (let ((alist gnus-group-posting-charset-alist)
 508         (group (or group ""))
 509         elem)
 510     (when group
 511       (catch 'found
 512         (while (setq elem (pop alist))
 513           (when (or (and (stringp (car elem))
 514                          (string-match (car elem) group))
 515                     (and (functionp (car elem))
 516                          (funcall (car elem) group))
 517                     (and (symbolp (car elem))
 518                          (symbol-value (car elem))))
 519             (throw 'found (cons (cadr elem) (caddr elem)))))))))
 520
 521 (defun gnus-inews-add-send-actions (winconf buffer article
 522                                             &optional config yanked)
 523   (gnus-make-local-hook 'message-sent-hook)
 524   (add-hook 'message-sent-hook (if gnus-agent 'gnus-agent-possibly-do-gcc
 525                                  'gnus-inews-do-gcc) nil t)
 526   (when gnus-agent
 527     (gnus-make-local-hook 'message-header-hook)
 528     (add-hook 'message-header-hook 'gnus-agent-possibly-save-gcc nil t))
 529   (setq message-post-method
 530         `(lambda (arg)
 531            (gnus-post-method arg ,gnus-newsgroup-name)))
 532   (setq message-newsreader (setq message-mailer (gnus-extended-version)))
 533   (message-add-action
 534    `(when (gnus-buffer-exists-p ,buffer)
 535       (set-window-configuration ,winconf))
 536    'exit 'postpone 'kill)
 537   (let ((to-be-marked (cond
 538                        (yanked
 539                         (mapcar
 540                          (lambda (x) (if (listp x) (car x) x)) yanked))
 541                        (article (if (listp article) article (list article)))
 542                        (t nil))))
 543     (message-add-action
 544      `(when (gnus-buffer-exists-p ,buffer)
 545         (save-excursion
 546           (set-buffer ,buffer)
 547           ,(when to-be-marked
 548              (if (eq config 'forward)
 549                  `(gnus-summary-mark-article-as-forwarded ',to-be-marked)
 550                `(gnus-summary-mark-article-as-replied ',to-be-marked)))))
 551      'send)))
 552
 553 (put 'gnus-setup-message 'lisp-indent-function 1)
 554 (put 'gnus-setup-message 'edebug-form-spec '(form body))
 555
 556 ;;; Post news commands of Gnus group mode and summary mode
 557
 558 (defun gnus-group-mail (&optional arg)
 559   "Start composing a mail.
 560 If ARG, use the group under the point to find a posting style.
 561 If ARG is 1, prompt for a group name to find the posting style."
 562   (interactive "P")
 563   ;; We can't `let' gnus-newsgroup-name here, since that leads
 564   ;; to local variables leaking.
 565   (let ((group gnus-newsgroup-name)
 566         ;; make sure last viewed article doesn't affect posting styles:
 567         (gnus-article-copy)
 568         (buffer (current-buffer)))
 569     (unwind-protect
 570         (progn
 571           (setq gnus-newsgroup-name
 572                 (if arg
 573                     (if (= 1 (prefix-numeric-value arg))
 574                         (completing-read "Use posting style of group: "
 575                                          gnus-active-hashtb nil
 576                                          (gnus-read-active-file-p))
 577                       (gnus-group-group-name))
 578                   ""))
 579           ;; #### see comment in gnus-setup-message -- drv
 580           (gnus-setup-message 'message (message-mail)))
 581       (save-excursion
 582         (set-buffer buffer)
 583         (setq gnus-newsgroup-name group)))))
 584
 585 (defun gnus-group-news (&optional arg)
 586   "Start composing a news.
 587 If ARG, post to group under point.
 588 If ARG is 1, prompt for group name to post to.
 589
 590 This function prepares a news even when using mail groups.  This is useful
 591 for posting messages to mail groups without actually sending them over the
 592 network.  The corresponding back end must have a 'request-post method."
 593   (interactive "P")
 594   ;; We can't `let' gnus-newsgroup-name here, since that leads
 595   ;; to local variables leaking.
 596   (let ((group gnus-newsgroup-name)
 597         ;; make sure last viewed article doesn't affect posting styles:
 598         (gnus-article-copy)
 599         (buffer (current-buffer)))
 600     (unwind-protect
 601         (progn
 602           (setq gnus-newsgroup-name
 603                 (if arg
 604                     (if (= 1 (prefix-numeric-value arg))
 605                         (completing-read "Use group: "
 606                                          gnus-active-hashtb nil
 607                                          (gnus-read-active-file-p))
 608                       (gnus-group-group-name))
 609                   ""))
 610           ;; #### see comment in gnus-setup-message -- drv
 611           (gnus-setup-message 'message
 612             (message-news (gnus-group-real-name gnus-newsgroup-name))))
 613       (save-excursion
 614         (set-buffer buffer)
 615         (setq gnus-newsgroup-name group)))))
 616
 617 (defun gnus-group-post-news (&optional arg)
 618   "Start composing a message (a news by default).
 619 If ARG, post to group under point.  If ARG is 1, prompt for group name.
 620 Depending on the selected group, the message might be either a mail or
 621 a news."
 622   (interactive "P")
 623   ;; Bind this variable here to make message mode hooks work ok.
 624   (let ((gnus-newsgroup-name
 625          (if arg
 626              (if (= 1 (prefix-numeric-value arg))
 627                  (completing-read "Newsgroup: " gnus-active-hashtb nil
 628                                   (gnus-read-active-file-p))
 629                (gnus-group-group-name))
 630            ""))
 631         ;; make sure last viewed article doesn't affect posting styles:
 632         (gnus-article-copy))
 633     (gnus-post-news 'post gnus-newsgroup-name nil nil nil nil
 634                     (string= gnus-newsgroup-name ""))))
 635
 636 (defun gnus-summary-mail-other-window (&optional arg)
 637   "Start composing a mail in another window.
 638 Use the posting of the current group by default.
 639 If ARG, don't do that.  If ARG is 1, prompt for group name to find the
 640 posting style."
 641   (interactive "P")
 642   ;; We can't `let' gnus-newsgroup-name here, since that leads
 643   ;; to local variables leaking.
 644   (let ((group gnus-newsgroup-name)
 645         ;; make sure last viewed article doesn't affect posting styles:
 646         (gnus-article-copy)
 647         (buffer (current-buffer)))
 648     (unwind-protect
 649         (progn
 650           (setq gnus-newsgroup-name
 651                 (if arg
 652                     (if (= 1 (prefix-numeric-value arg))
 653                         (completing-read "Use group: "
 654                                          gnus-active-hashtb nil
 655                                          (gnus-read-active-file-p))
 656                       "")
 657                   gnus-newsgroup-name))
 658           ;; #### see comment in gnus-setup-message -- drv
 659           (gnus-setup-message 'message (message-mail)))
 660       (save-excursion
 661         (set-buffer buffer)
 662         (setq gnus-newsgroup-name group)))))
 663
 664 (defun gnus-summary-news-other-window (&optional arg)
 665   "Start composing a news in another window.
 666 Post to the current group by default.
 667 If ARG, don't do that.  If ARG is 1, prompt for group name to post to.
 668
 669 This function prepares a news even when using mail groups.  This is useful
 670 for posting messages to mail groups without actually sending them over the
 671 network.  The corresponding back end must have a 'request-post method."
 672   (interactive "P")
 673   ;; We can't `let' gnus-newsgroup-name here, since that leads
 674   ;; to local variables leaking.
 675   (let ((group gnus-newsgroup-name)
 676         ;; make sure last viewed article doesn't affect posting styles:
 677         (gnus-article-copy)
 678         (buffer (current-buffer)))
 679     (unwind-protect
 680         (progn
 681           (setq gnus-newsgroup-name
 682                 (if arg
 683                     (if (= 1 (prefix-numeric-value arg))
 684                         (completing-read "Use group: "
 685                                          gnus-active-hashtb nil
 686                                          (gnus-read-active-file-p))
 687                       "")
 688                   gnus-newsgroup-name))
 689           ;; #### see comment in gnus-setup-message -- drv
 690           (gnus-setup-message 'message
 691             (progn
 692               (message-news (gnus-group-real-name gnus-newsgroup-name))
 693               (set (make-local-variable 'gnus-discouraged-post-methods)
 694                    (delq
 695                     (car (gnus-find-method-for-group gnus-newsgroup-name))
 696                     (copy-sequence gnus-discouraged-post-methods))))))
 697       (save-excursion
 698         (set-buffer buffer)
 699         (setq gnus-newsgroup-name group)))))
 700
 701 (defun gnus-summary-post-news (&optional arg)
 702   "Start composing a message.  Post to the current group by default.
 703 If ARG, don't do that.  If ARG is 1, prompt for a group name to post to.
 704 Depending on the selected group, the message might be either a mail or
 705 a news."
 706   (interactive "P")
 707   ;; Bind this variable here to make message mode hooks work ok.
 708   (let ((gnus-newsgroup-name
 709          (if arg
 710              (if (= 1 (prefix-numeric-value arg))
 711                  (completing-read "Newsgroup: " gnus-active-hashtb nil
 712                                   (gnus-read-active-file-p))
 713                "")
 714            gnus-newsgroup-name))
 715         ;; make sure last viewed article doesn't affect posting styles:
 716         (gnus-article-copy))
 717     (gnus-post-news 'post gnus-newsgroup-name)))
 718
 719
 720 (defun gnus-summary-followup (yank &optional force-news)
 721   "Compose a followup to an article.
 722 If prefix argument YANK is non-nil, the original article is yanked
 723 automatically.
 724 YANK is a list of elements, where the car of each element is the
 725 article number, and the cdr is the string to be yanked."
 726   (interactive
 727    (list (and current-prefix-arg
 728               (gnus-summary-work-articles 1))))
 729   (when yank
 730     (gnus-summary-goto-subject
 731      (if (listp (car yank))
 732          (caar yank)
 733        (car yank))))
 734   (save-window-excursion
 735     (gnus-summary-select-article))
 736   (let ((headers (gnus-summary-article-header (gnus-summary-article-number)))
 737         (gnus-newsgroup-name gnus-newsgroup-name))
 738     ;; Send a followup.
 739     (gnus-post-news nil gnus-newsgroup-name
 740                     headers gnus-article-buffer
 741                     yank nil force-news)
 742     (gnus-summary-handle-replysign)))
 743
 744 (defun gnus-summary-followup-with-original (n &optional force-news)
 745   "Compose a followup to an article and include the original article."
 746   (interactive "P")
 747   (gnus-summary-followup (gnus-summary-work-articles n) force-news))
 748
 749 (defun gnus-summary-followup-to-mail (&optional arg)
 750   "Followup to the current mail message via news."
 751   (interactive
 752    (list (and current-prefix-arg
 753               (gnus-summary-work-articles 1))))
 754   (gnus-summary-followup arg t))
 755
 756 (defun gnus-summary-followup-to-mail-with-original (&optional arg)
 757   "Followup to the current mail message via news."
 758   (interactive "P")
 759   (gnus-summary-followup (gnus-summary-work-articles arg) t))
 760
 761 (defun gnus-inews-yank-articles (articles)
 762   (let (beg article yank-string)
 763     (message-goto-body)
 764     (while (setq article (pop articles))
 765       (when (listp article)
 766         (setq yank-string (nth 1 article)
 767               article (nth 0 article)))
 768       (save-window-excursion
 769         (set-buffer gnus-summary-buffer)
 770         (gnus-summary-select-article nil nil nil article)
 771         (gnus-summary-remove-process-mark article))
 772       (gnus-copy-article-buffer nil yank-string)
 773       (let ((message-reply-buffer gnus-article-copy)
 774             (message-reply-headers
 775              ;; The headers are decoded.
 776              (with-current-buffer gnus-article-copy
 777                (save-restriction
 778                  (nnheader-narrow-to-headers)
 779                  (nnheader-parse-naked-head)))))
 780         (message-yank-original)
 781         (setq beg (or beg (mark t))))
 782       (when articles
 783         (insert "\n")))
 784     (push-mark)
 785     (goto-char beg)))
 786
 787 (defun gnus-summary-cancel-article (&optional n symp)
 788   "Cancel an article you posted.
 789 Uses the process-prefix convention.  If given the symbolic
 790 prefix `a', cancel using the standard posting method; if not
 791 post using the current select method."
 792   (interactive (gnus-interactive "P\ny"))
 793   (let ((articles (gnus-summary-work-articles n))
 794         (message-post-method
 795          `(lambda (arg)
 796             (gnus-post-method (eq ',symp 'a) ,gnus-newsgroup-name)))
 797         article)
 798     (while (setq article (pop articles))
 799       (when (gnus-summary-select-article t nil nil article)
 800         (when (gnus-eval-in-buffer-window gnus-original-article-buffer
 801                 (message-cancel-news))
 802           (gnus-summary-mark-as-read article gnus-canceled-mark)
 803           (gnus-cache-remove-article 1))
 804         (gnus-article-hide-headers-if-wanted))
 805       (gnus-summary-remove-process-mark article))))
 806
 807 (defun gnus-summary-supersede-article ()
 808   "Compose an article that will supersede a previous article.
 809 This is done simply by taking the old article and adding a Supersedes
 810 header line with the old Message-ID."
 811   (interactive)
 812   (let ((article (gnus-summary-article-number)))
 813     (gnus-setup-message 'reply-yank
 814       (gnus-summary-select-article t)
 815       (set-buffer gnus-original-article-buffer)
 816       (message-supersede)
 817       (push
 818        `((lambda ()
 819            (when (gnus-buffer-exists-p ,gnus-summary-buffer)
 820              (save-excursion
 821                (set-buffer ,gnus-summary-buffer)
 822                (gnus-cache-possibly-remove-article ,article nil nil nil t)
 823                (gnus-summary-mark-as-read ,article gnus-canceled-mark)))))
 824        message-send-actions))))
 825
 826 \f
 827
 828 (defun gnus-copy-article-buffer (&optional article-buffer yank-string)
 829   ;; make a copy of the article buffer with all text properties removed
 830   ;; this copy is in the buffer gnus-article-copy.
 831   ;; if ARTICLE-BUFFER is nil, gnus-article-buffer is used
 832   ;; this buffer should be passed to all mail/news reply/post routines.
 833   (setq gnus-article-copy (gnus-get-buffer-create " *gnus article copy*"))
 834   (save-excursion
 835     (set-buffer gnus-article-copy)
 836     (mm-enable-multibyte))
 837   (let ((article-buffer (or article-buffer gnus-article-buffer))
 838         end beg)
 839     (if (not (and (get-buffer article-buffer)
 840                   (gnus-buffer-exists-p article-buffer)))
 841         (error "Can't find any article buffer")
 842       (save-excursion
 843         (set-buffer article-buffer)
 844         (let ((gnus-newsgroup-charset (or gnus-article-charset
 845                                           gnus-newsgroup-charset))
 846               (gnus-newsgroup-ignored-charsets
 847                (or gnus-article-ignored-charsets
 848                    gnus-newsgroup-ignored-charsets)))
 849           (save-restriction
 850             ;; Copy over the (displayed) article buffer, delete
 851             ;; hidden text and remove text properties.
 852             (widen)
 853             (copy-to-buffer gnus-article-copy (point-min) (point-max))
 854             (set-buffer gnus-article-copy)
 855             (when yank-string
 856               (message-goto-body)
 857               (delete-region (point) (point-max))
 858               (insert yank-string))
 859             (gnus-article-delete-text-of-type 'annotation)
 860             (gnus-remove-text-with-property 'gnus-prev)
 861             (gnus-remove-text-with-property 'gnus-next)
 862             (gnus-remove-text-with-property 'gnus-decoration)
 863             (insert
 864              (prog1
 865                  (buffer-substring-no-properties (point-min) (point-max))
 866                (erase-buffer)))
 867             ;; Find the original headers.
 868             (set-buffer gnus-original-article-buffer)
 869             (goto-char (point-min))
 870             (while (looking-at message-unix-mail-delimiter)
 871               (forward-line 1))
 872             (let ((mail-header-separator ""))
 873               (setq beg (point)
 874                     end (or (message-goto-body)
 875                             ;; There may be just a header.
 876                             (point-max))))
 877             ;; Delete the headers from the displayed articles.
 878             (set-buffer gnus-article-copy)
 879             (let ((mail-header-separator ""))
 880               (delete-region (goto-char (point-min))
 881                              (or (message-goto-body) (point-max))))
 882             ;; Insert the original article headers.
 883             (insert-buffer-substring gnus-original-article-buffer beg end)
 884             ;; Decode charsets.
 885             (let ((gnus-article-decode-hook
 886                    (delq 'article-decode-charset
 887                          (copy-sequence gnus-article-decode-hook))))
 888               (run-hooks 'gnus-article-decode-hook)))))
 889       gnus-article-copy)))
 890
 891 (defun gnus-post-news (post &optional group header article-buffer yank subject
 892                             force-news)
 893   (when article-buffer
 894     (gnus-copy-article-buffer))
 895   (let ((gnus-article-reply (and article-buffer (gnus-summary-article-number)))
 896         (gnus-article-yanked-articles yank)
 897         (add-to-list gnus-add-to-list))
 898     (gnus-setup-message (cond (yank 'reply-yank)
 899                               (article-buffer 'reply)
 900                               (t 'message))
 901       (let* ((group (or group gnus-newsgroup-name))
 902              (charset (gnus-group-name-charset nil group))
 903              (pgroup group)
 904              to-address to-group mailing-list to-list
 905              newsgroup-p)
 906         (when group
 907           (setq to-address (gnus-parameter-to-address group)
 908                 to-group (gnus-group-find-parameter group 'to-group)
 909                 to-list (gnus-parameter-to-list group)
 910                 newsgroup-p (gnus-group-find-parameter group 'newsgroup)
 911                 mailing-list (when gnus-mailing-list-groups
 912                                (string-match gnus-mailing-list-groups group))
 913                 group (gnus-group-name-decode (gnus-group-real-name group)
 914                                               charset)))
 915         (if (or (and to-group
 916                      (gnus-news-group-p to-group))
 917                 newsgroup-p
 918                 force-news
 919                 (and (gnus-news-group-p
 920                       (or pgroup gnus-newsgroup-name)
 921                       (or header gnus-current-article))
 922                      (not mailing-list)
 923                      (not to-list)
 924                      (not to-address)))
 925             ;; This is news.
 926             (if post
 927                 (message-news (or to-group group))
 928               (set-buffer gnus-article-copy)
 929               (gnus-msg-treat-broken-reply-to)
 930               (message-followup (if (or newsgroup-p force-news)
 931                                     (if (save-restriction
 932                                           (article-narrow-to-head)
 933                                           (message-fetch-field "newsgroups"))
 934                                         nil
 935                                       "")
 936                                   to-group)))
 937           ;; The is mail.
 938           (if post
 939               (progn
 940                 (message-mail (or to-address to-list))
 941                 ;; Arrange for mail groups that have no `to-address' to
 942                 ;; get that when the user sends off the mail.
 943                 (when (and (not to-list)
 944                            (not to-address)
 945                            add-to-list)
 946                   (push (list 'gnus-inews-add-to-address pgroup)
 947                         message-send-actions)))
 948             (set-buffer gnus-article-copy)
 949             (gnus-msg-treat-broken-reply-to)
 950             (message-wide-reply to-address)))
 951         (when yank
 952           (gnus-inews-yank-articles yank))))))
 953
 954 (defun gnus-msg-treat-broken-reply-to (&optional force)
 955   "Remove the Reply-to header if broken-reply-to."
 956   (when (or force
 957             (gnus-group-find-parameter
 958              gnus-newsgroup-name 'broken-reply-to))
 959     (save-restriction
 960       (message-narrow-to-head)
 961       (message-remove-header "reply-to"))))
 962
 963 (defun gnus-post-method (arg group &optional silent)
 964   "Return the posting method based on GROUP and ARG.
 965 If SILENT, don't prompt the user."
 966   (let ((gnus-post-method (or (gnus-parameter-post-method group)
 967                               gnus-post-method))
 968         (group-method (gnus-find-method-for-group group)))
 969     (cond
 970      ;; If the group-method is nil (which shouldn't happen) we use
 971      ;; the default method.
 972      ((null group-method)
 973       (or (and (listp gnus-post-method) ;If not current/native/nil
 974                (not (listp (car gnus-post-method))) ; and not a list of methods
 975                gnus-post-method)        ;then use it.
 976           gnus-select-method
 977           message-post-method))
 978      ;; We want the inverse of the default
 979      ((and arg (not (eq arg 0)))
 980       (if (eq gnus-post-method 'current)
 981           gnus-select-method
 982         group-method))
 983      ;; We query the user for a post method.
 984      ((or arg
 985           (and (listp gnus-post-method)
 986                (listp (car gnus-post-method))))
 987       (let* ((methods
 988               ;; Collect all methods we know about.
 989               (append
 990                (when (listp gnus-post-method)
 991                  (if (listp (car gnus-post-method))
 992                      gnus-post-method
 993                    (list gnus-post-method)))
 994                gnus-secondary-select-methods
 995                (mapcar 'cdr gnus-server-alist)
 996                (mapcar 'car gnus-opened-servers)
 997                (list gnus-select-method)
 998                (list group-method)))
 999              method-alist post-methods method)
1000         ;; Weed out all mail methods.
1001         (while methods
1002           (setq method (gnus-server-get-method "" (pop methods)))
1003           (when (and (or (gnus-method-option-p method 'post)
1004                          (gnus-method-option-p method 'post-mail))
1005                      (not (member method post-methods)))
1006             (push method post-methods)))
1007         ;; Create a name-method alist.
1008         (setq method-alist
1009               (mapcar
1010                (lambda (m)
1011                  (if (equal (cadr m) "")
1012                      (list (symbol-name (car m)) m)
1013                    (list (concat (cadr m) " (" (symbol-name (car m)) ")") m)))
1014                post-methods))
1015         ;; Query the user.
1016         (cadr
1017          (assoc
1018           (setq gnus-last-posting-server
1019                 (if (and silent
1020                          gnus-last-posting-server)
1021                     ;; Just use the last value.
1022                     gnus-last-posting-server
1023                   (completing-read
1024                    "Posting method: " method-alist nil t
1025                    (cons (or gnus-last-posting-server "") 0))))
1026           method-alist))))
1027      ;; Override normal method.
1028      ((and (eq gnus-post-method 'current)
1029            (not (memq (car group-method) gnus-discouraged-post-methods))
1030            (gnus-get-function group-method 'request-post t))
1031       (assert (not arg))
1032       group-method)
1033      ;; Use gnus-post-method.
1034      ((listp gnus-post-method)          ;A method...
1035       (assert (not (listp (car gnus-post-method)))) ;... not a list of methods.
1036       gnus-post-method)
1037      ;; Use the normal select method (nil or native).
1038      (t gnus-select-method))))
1039
1040 \f
1041
1042 (defun gnus-extended-version ()
1043   "Stringified Gnus version and Emacs version.
1044 See the variable `gnus-user-agent'."
1045   (interactive)
1046   (let* ((float-output-format nil)
1047          (gnus-v
1048           (concat "Gnus/"
1049                   (prin1-to-string (gnus-continuum-version gnus-version) t)
1050                   " (" gnus-version ")"))
1051          (emacs-v (gnus-emacs-version)))
1052     (if (stringp gnus-user-agent)
1053         gnus-user-agent
1054       (concat gnus-v
1055               (when emacs-v
1056                 (concat " " emacs-v))))))
1057
1058 \f
1059 ;;;
1060 ;;; Gnus Mail Functions
1061 ;;;
1062
1063 ;;; Mail reply commands of Gnus summary mode
1064
1065 (defun gnus-summary-reply (&optional yank wide very-wide)
1066   "Start composing a mail reply to the current message.
1067 If prefix argument YANK is non-nil, the original article is yanked
1068 automatically.
1069 If WIDE, make a wide reply.
1070 If VERY-WIDE, make a very wide reply."
1071   (interactive
1072    (list (and current-prefix-arg
1073               (gnus-summary-work-articles 1))))
1074   ;; Allow user to require confirmation before replying by mail to the
1075   ;; author of a news article (or mail message).
1076   (when (or
1077             (not (or (gnus-news-group-p gnus-newsgroup-name)
1078                      gnus-confirm-treat-mail-like-news))
1079             (not (cond ((stringp gnus-confirm-mail-reply-to-news)
1080                         (string-match gnus-confirm-mail-reply-to-news
1081                                       gnus-newsgroup-name))
1082                        ((functionp gnus-confirm-mail-reply-to-news)
1083                         (funcall gnus-confirm-mail-reply-to-news gnus-newsgroup-name))
1084                        (t gnus-confirm-mail-reply-to-news)))
1085             (y-or-n-p "Really reply by mail to article author? "))
1086     (let* ((article
1087             (if (listp (car yank))
1088                 (caar yank)
1089               (car yank)))
1090            (gnus-article-reply (or article (gnus-summary-article-number)))
1091            (gnus-article-yanked-articles yank)
1092            (headers ""))
1093       ;; Stripping headers should be specified with mail-yank-ignored-headers.
1094       (when yank
1095         (gnus-summary-goto-subject article))
1096       (gnus-setup-message (if yank 'reply-yank 'reply)
1097         (if (not very-wide)
1098             (gnus-summary-select-article)
1099           (dolist (article very-wide)
1100             (gnus-summary-select-article nil nil nil article)
1101             (save-excursion
1102               (set-buffer (gnus-copy-article-buffer))
1103               (gnus-msg-treat-broken-reply-to)
1104               (save-restriction
1105                 (message-narrow-to-head)
1106                 (setq headers (concat headers (buffer-string)))))))
1107         (set-buffer (gnus-copy-article-buffer))
1108         (gnus-msg-treat-broken-reply-to gnus-msg-force-broken-reply-to)
1109         (save-restriction
1110           (message-narrow-to-head)
1111           (when very-wide
1112             (erase-buffer)
1113             (insert headers))
1114           (goto-char (point-max)))
1115         (mml-quote-region (point) (point-max))
1116         (message-reply nil wide)
1117         (when yank
1118           (gnus-inews-yank-articles yank))
1119         (gnus-summary-handle-replysign)))))
1120
1121 (defun gnus-summary-handle-replysign ()
1122   "Check the various replysign variables and take action accordingly."
1123   (when (or gnus-message-replysign gnus-message-replyencrypt)
1124     (let (signed encrypted)
1125       (save-excursion
1126         (set-buffer gnus-article-buffer)
1127         (setq signed (memq 'signed gnus-article-wash-types))
1128         (setq encrypted (memq 'encrypted gnus-article-wash-types)))
1129       (cond ((and gnus-message-replyencrypt encrypted)
1130              (mml-secure-message mml-default-encrypt-method
1131                                  (if gnus-message-replysignencrypted
1132                                      'signencrypt
1133                                    'encrypt)))
1134             ((and gnus-message-replysign signed)
1135              (mml-secure-message mml-default-sign-method 'sign))))))
1136
1137 (defun gnus-summary-reply-with-original (n &optional wide)
1138   "Start composing a reply mail to the current message.
1139 The original article will be yanked."
1140   (interactive "P")
1141   (gnus-summary-reply (gnus-summary-work-articles n) wide))
1142
1143 (defun gnus-summary-reply-broken-reply-to (&optional yank wide very-wide)
1144   "Like `gnus-summary-reply' except removing reply-to field.
1145 If prefix argument YANK is non-nil, the original article is yanked
1146 automatically.
1147 If WIDE, make a wide reply.
1148 If VERY-WIDE, make a very wide reply."
1149   (interactive
1150    (list (and current-prefix-arg
1151               (gnus-summary-work-articles 1))))
1152   (let ((gnus-msg-force-broken-reply-to t))
1153     (gnus-summary-reply yank wide very-wide)))
1154
1155 (defun gnus-summary-reply-broken-reply-to-with-original (n &optional wide)
1156   "Like `gnus-summary-reply-with-original' except removing reply-to field.
1157 The original article will be yanked."
1158   (interactive "P")
1159   (gnus-summary-reply-broken-reply-to (gnus-summary-work-articles n) wide))
1160
1161 (defun gnus-summary-wide-reply (&optional yank)
1162   "Start composing a wide reply mail to the current message.
1163 If prefix argument YANK is non-nil, the original article is yanked
1164 automatically."
1165   (interactive
1166    (list (and current-prefix-arg
1167               (gnus-summary-work-articles 1))))
1168   (gnus-summary-reply yank t))
1169
1170 (defun gnus-summary-wide-reply-with-original (n)
1171   "Start composing a wide reply mail to the current message.
1172 The original article will be yanked.
1173 Uses the process/prefix convention."
1174   (interactive "P")
1175   (gnus-summary-reply-with-original n t))
1176
1177 (defun gnus-summary-very-wide-reply (&optional yank)
1178   "Start composing a very wide reply mail to the current message.
1179 If prefix argument YANK is non-nil, the original article is yanked
1180 automatically."
1181   (interactive
1182    (list (and current-prefix-arg
1183               (gnus-summary-work-articles 1))))
1184   (gnus-summary-reply yank t (gnus-summary-work-articles yank)))
1185
1186 (defun gnus-summary-very-wide-reply-with-original (n)
1187   "Start composing a very wide reply mail to the current message.
1188 The original article will be yanked."
1189   (interactive "P")
1190   (gnus-summary-reply
1191    (gnus-summary-work-articles n) t (gnus-summary-work-articles n)))
1192
1193 (defun gnus-summary-mail-forward (&optional arg post)
1194   "Forward the current message(s) to another user.
1195 If process marks exist, forward all marked messages;
1196 if ARG is nil, see `message-forward-as-mime' and `message-forward-show-mml';
1197 if ARG is 1, decode the message and forward directly inline;
1198 if ARG is 2, forward message as an rfc822 MIME section;
1199 if ARG is 3, decode message and forward as an rfc822 MIME section;
1200 if ARG is 4, forward message directly inline;
1201 otherwise, use flipped `message-forward-as-mime'.
1202 If POST, post instead of mail.
1203 For the `inline' alternatives, also see the variable
1204 `message-forward-ignored-headers'."
1205   (interactive "P")
1206   (if (cdr (gnus-summary-work-articles nil))
1207       ;; Process marks are given.
1208       (gnus-uu-digest-mail-forward arg post)
1209     ;; No process marks.
1210     (let ((message-forward-as-mime message-forward-as-mime)
1211           (message-forward-show-mml message-forward-show-mml))
1212       (cond
1213        ((null arg))
1214        ((eq arg 1)
1215         (setq message-forward-as-mime nil
1216               message-forward-show-mml t))
1217        ((eq arg 2)
1218         (setq message-forward-as-mime t
1219               message-forward-show-mml nil))
1220        ((eq arg 3)
1221         (setq message-forward-as-mime t
1222               message-forward-show-mml t))
1223        ((eq arg 4)
1224         (setq message-forward-as-mime nil
1225               message-forward-show-mml nil))
1226        (t
1227         (setq message-forward-as-mime (not message-forward-as-mime))))
1228       (let* ((gnus-article-reply (gnus-summary-article-number))
1229              (gnus-article-yanked-articles (list gnus-article-reply)))
1230         (gnus-setup-message 'forward
1231           (gnus-summary-select-article)
1232           (let ((mail-parse-charset
1233                  (or (and (gnus-buffer-live-p gnus-article-buffer)
1234                           (with-current-buffer gnus-article-buffer
1235                             gnus-article-charset))
1236                      gnus-newsgroup-charset))
1237                 (mail-parse-ignored-charsets
1238                  gnus-newsgroup-ignored-charsets))
1239             (set-buffer gnus-original-article-buffer)
1240             (message-forward post)))))))
1241
1242 (defun gnus-summary-resend-message (address n)
1243   "Resend the current article to ADDRESS."
1244   (interactive
1245    (list (message-read-from-minibuffer
1246           "Resend message(s) to: "
1247           (when (and gnus-summary-resend-default-address
1248                      (gnus-buffer-live-p gnus-original-article-buffer))
1249             ;; If some other article is currently selected, the
1250             ;; initial-contents is wrong. Whatever, it is just the
1251             ;; initial-contents.
1252             (with-current-buffer gnus-original-article-buffer
1253               (nnmail-fetch-field "to"))))
1254          current-prefix-arg))
1255   (let ((articles (gnus-summary-work-articles n))
1256         article)
1257     (while (setq article (pop articles))
1258       (gnus-summary-select-article nil nil nil article)
1259       (save-excursion
1260         (set-buffer gnus-original-article-buffer)
1261         (message-resend address))
1262       (gnus-summary-mark-article-as-forwarded article))))
1263
1264 ;; From: Matthieu Moy <Matthieu.Moy@imag.fr>
1265 (defun gnus-summary-resend-message-edit ()
1266   "Resend an article that has already been sent.
1267 A new buffer will be created to allow the user to modify body and
1268 contents of the message, and then, everything will happen as when
1269 composing a new message."
1270   (interactive)
1271   (let ((article (gnus-summary-article-number)))
1272     (gnus-setup-message 'reply-yank
1273       (gnus-summary-select-article t)
1274       (set-buffer gnus-original-article-buffer)
1275       (let ((cur (current-buffer))
1276             (to (message-fetch-field "to")))
1277         ;; Get a normal message buffer.
1278         (message-pop-to-buffer (message-buffer-name "Resend" to))
1279         (insert-buffer-substring cur)
1280         (message-narrow-to-head-1)
1281         ;; Gnus will generate a new one when sending.
1282         (message-remove-header "Message-ID")
1283         (message-remove-header message-ignored-resent-headers t)
1284         ;; Remove unwanted headers.
1285         (goto-char (point-max))
1286         (insert mail-header-separator)
1287         (goto-char (point-min))
1288         (when (re-search-forward "^To:\\|^Newsgroups:" nil 'move)
1289           (forward-char 1))
1290         (widen)))))
1291
1292 (defun gnus-summary-post-forward (&optional arg)
1293   "Forward the current article to a newsgroup.
1294 See `gnus-summary-mail-forward' for ARG."
1295   (interactive "P")
1296   (gnus-summary-mail-forward arg t))
1297
1298 (defvar gnus-nastygram-message
1299   "The following article was inappropriately posted to %s.\n\n"
1300   "Format string to insert in nastygrams.
1301 The current group name will be inserted at \"%s\".")
1302
1303 (defun gnus-summary-mail-nastygram (n)
1304   "Send a nastygram to the author of the current article."
1305   (interactive "P")
1306   (when (or gnus-expert-user
1307             (gnus-y-or-n-p
1308              "Really send a nastygram to the author of the current article? "))
1309     (let ((group gnus-newsgroup-name))
1310       (gnus-summary-reply-with-original n)
1311       (set-buffer gnus-message-buffer)
1312       (message-goto-body)
1313       (insert (format gnus-nastygram-message group))
1314       (message-send-and-exit))))
1315
1316 (defun gnus-summary-mail-crosspost-complaint (n)
1317   "Send a complaint about crossposting to the current article(s)."
1318   (interactive "P")
1319   (let ((articles (gnus-summary-work-articles n))
1320         article)
1321     (while (setq article (pop articles))
1322       (set-buffer gnus-summary-buffer)
1323       (gnus-summary-goto-subject article)
1324       (let ((group (gnus-group-real-name gnus-newsgroup-name))
1325             newsgroups followup-to)
1326         (gnus-summary-select-article)
1327         (set-buffer gnus-original-article-buffer)
1328         (if (and (<= (length (message-tokenize-header
1329                               (setq newsgroups
1330                                     (mail-fetch-field "newsgroups"))
1331                               ", "))
1332                      1)
1333                  (or (not (setq followup-to (mail-fetch-field "followup-to")))
1334                      (not (member group (message-tokenize-header
1335                                          followup-to ", ")))))
1336             (if followup-to
1337                 (gnus-message 1 "Followup-to restricted")
1338               (gnus-message 1 "Not a crossposted article"))
1339           (set-buffer gnus-summary-buffer)
1340           (gnus-summary-reply-with-original 1)
1341           (set-buffer gnus-message-buffer)
1342           (message-goto-body)
1343           (insert (format gnus-crosspost-complaint newsgroups group))
1344           (message-goto-subject)
1345           (re-search-forward " *$")
1346           (replace-match " (crosspost notification)" t t)
1347           (gnus-deactivate-mark)
1348           (when (gnus-y-or-n-p "Send this complaint? ")
1349             (message-send-and-exit)))))))
1350
1351 (defun gnus-mail-parse-comma-list ()
1352   (let (accumulated
1353         beg)
1354     (skip-chars-forward " ")
1355     (while (not (eobp))
1356       (setq beg (point))
1357       (skip-chars-forward "^,")
1358       (while (zerop
1359               (save-excursion
1360                 (save-restriction
1361                   (let ((i 0))
1362                     (narrow-to-region beg (point))
1363                     (goto-char beg)
1364                     (logand (progn
1365                               (while (search-forward "\"" nil t)
1366                                 (incf i))
1367                               (if (zerop i) 2 i))
1368                             2)))))
1369         (skip-chars-forward ",")
1370         (skip-chars-forward "^,"))
1371       (skip-chars-backward " ")
1372       (push (buffer-substring beg (point))
1373             accumulated)
1374       (skip-chars-forward "^,")
1375       (skip-chars-forward ", "))
1376     accumulated))
1377
1378 (defun gnus-inews-add-to-address (group)
1379   (let ((to-address (mail-fetch-field "to")))
1380     (when (and to-address
1381                (gnus-alive-p))
1382       ;; This mail group doesn't have a `to-list', so we add one
1383       ;; here.  Magic!
1384       (when (gnus-y-or-n-p
1385              (format "Do you want to add this as `to-list': %s? " to-address))
1386         (gnus-group-add-parameter group (cons 'to-list to-address))))))
1387
1388 (defun gnus-put-message ()
1389   "Put the current message in some group and return to Gnus."
1390   (interactive)
1391   (let ((reply gnus-article-reply)
1392         (winconf gnus-prev-winconf)
1393         (group gnus-newsgroup-name))
1394     (unless (and group
1395                  (not (gnus-group-read-only-p group)))
1396       (setq group (read-string "Put in group: " nil (gnus-writable-groups))))
1397
1398     (when (gnus-gethash group gnus-newsrc-hashtb)
1399       (error "No such group: %s" group))
1400     (save-excursion
1401       (save-restriction
1402         (widen)
1403         (message-narrow-to-headers)
1404         (let ((gnus-deletable-headers nil))
1405           (message-generate-headers
1406            (if (message-news-p)
1407                message-required-news-headers
1408              message-required-mail-headers)))
1409         (goto-char (point-max))
1410         (if (string-match " " group)
1411             (insert "Gcc: \"" group "\"\n")
1412           (insert "Gcc: " group "\n"))
1413         (widen)))
1414     (gnus-inews-do-gcc)
1415     (when (and (get-buffer gnus-group-buffer)
1416                (gnus-buffer-exists-p (car-safe reply))
1417                (cdr reply))
1418       (set-buffer (car reply))
1419       (gnus-summary-mark-article-as-replied (cdr reply)))
1420     (when winconf
1421       (set-window-configuration winconf))))
1422
1423 (defun gnus-article-mail (yank)
1424   "Send a reply to the address near point.
1425 If YANK is non-nil, include the original article."
1426   (interactive "P")
1427   (let ((address
1428          (buffer-substring
1429           (save-excursion (re-search-backward "[ \t\n]" nil t) (1+ (point)))
1430           (save-excursion (re-search-forward "[ \t\n]" nil t) (1- (point))))))
1431     (when address
1432       (gnus-msg-mail address)
1433       (when yank
1434         (gnus-inews-yank-articles (list (cdr gnus-article-current)))))))
1435
1436 (defvar nntp-server-type)
1437 (defun gnus-bug ()
1438   "Send a bug report to the Gnus maintainers."
1439   (interactive)
1440   (unless (gnus-alive-p)
1441     (error "Gnus has been shut down"))
1442   (gnus-setup-message (if (message-mail-user-agent) 'message 'bug)
1443     (unless (message-mail-user-agent)
1444       (delete-other-windows)
1445       (when gnus-bug-create-help-buffer
1446         (switch-to-buffer "*Gnus Help Bug*")
1447         (erase-buffer)
1448         (insert gnus-bug-message)
1449         (goto-char (point-min)))
1450       (message-pop-to-buffer "*Gnus Bug*"))
1451     (let ((message-this-is-mail t))
1452       (message-setup `((To . ,gnus-maintainer) (Subject . ""))))
1453     (when gnus-bug-create-help-buffer
1454       (push `(gnus-bug-kill-buffer) message-send-actions))
1455     (goto-char (point-min))
1456     (re-search-forward (concat "^" (regexp-quote mail-header-separator) "$"))
1457     (forward-line 1)
1458     (insert (gnus-version) "\n"
1459             (emacs-version) "\n")
1460     (when (and (boundp 'nntp-server-type)
1461                (stringp nntp-server-type))
1462       (insert nntp-server-type))
1463     (insert "\n\n\n\n\n")
1464     (let (text)
1465       (save-excursion
1466         (set-buffer (gnus-get-buffer-create " *gnus environment info*"))
1467         (erase-buffer)
1468         (gnus-debug)
1469         (setq text (buffer-string)))
1470       (insert "<#part type=application/emacs-lisp disposition=inline description=\"User settings\">\n" text "\n<#/part>"))
1471     (goto-char (point-min))
1472     (search-forward "Subject: " nil t)
1473     (message "")))
1474
1475 (defun gnus-bug-kill-buffer ()
1476   (when (get-buffer "*Gnus Help Bug*")
1477     (kill-buffer "*Gnus Help Bug*")))
1478
1479 (defun gnus-summary-yank-message (buffer n)
1480   "Yank the current article into a composed message."
1481   (interactive
1482    (list (completing-read "Buffer: " (mapcar 'list (message-buffers)) nil t)
1483          current-prefix-arg))
1484   (gnus-summary-iterate n
1485     (let ((gnus-inhibit-treatment t))
1486       (gnus-summary-select-article))
1487     (save-excursion
1488       (set-buffer buffer)
1489       (message-yank-buffer gnus-article-buffer))))
1490
1491 (defun gnus-debug ()
1492   "Attempts to go through the Gnus source file and report what variables have been changed.
1493 The source file has to be in the Emacs load path."
1494   (interactive)
1495   (let ((files gnus-debug-files)
1496         (point (point))
1497         file expr olist sym)
1498     (gnus-message 4 "Please wait while we snoop your variables...")
1499     (sit-for 0)
1500     ;; Go through all the files looking for non-default values for variables.
1501     (save-excursion
1502       (set-buffer (gnus-get-buffer-create " *gnus bug info*"))
1503       (while files
1504         (erase-buffer)
1505         (when (and (setq file (locate-library (pop files)))
1506                    (file-exists-p file))
1507           (insert-file-contents file)
1508           (goto-char (point-min))
1509           (if (not (re-search-forward "^;;* *Internal variables" nil t))
1510               (gnus-message 4 "Malformed sources in file %s" file)
1511             (narrow-to-region (point-min) (point))
1512             (goto-char (point-min))
1513             (while (setq expr (ignore-errors (read (current-buffer))))
1514               (ignore-errors
1515                 (and (or (eq (car expr) 'defvar)
1516                          (eq (car expr) 'defcustom))
1517                      (stringp (nth 3 expr))
1518                      (not (memq (nth 1 expr) gnus-debug-exclude-variables))
1519                      (or (not (boundp (nth 1 expr)))
1520                          (not (equal (eval (nth 2 expr))
1521                                      (symbol-value (nth 1 expr)))))
1522                      (push (nth 1 expr) olist)))))))
1523       (kill-buffer (current-buffer)))
1524     (when (setq olist (nreverse olist))
1525       (insert "------------------ Environment follows ------------------\n\n"))
1526     (while olist
1527       (if (boundp (car olist))
1528           (ignore-errors
1529             (pp `(setq ,(car olist)
1530                        ,(if (or (consp (setq sym (symbol-value (car olist))))
1531                                 (and (symbolp sym)
1532                                      (not (or (eq sym nil)
1533                                               (eq sym t)))))
1534                             (list 'quote (symbol-value (car olist)))
1535                           (symbol-value (car olist))))
1536                 (current-buffer)))
1537         (insert ";; (makeunbound '" (symbol-name (car olist)) ")\n"))
1538       (setq olist (cdr olist)))
1539     (insert "\n\n")
1540     ;; Remove any control chars - they seem to cause trouble for some
1541     ;; mailers.  (Byte-compiled output from the stuff above.)
1542     (goto-char point)
1543     (while (re-search-forward "[\000-\010\013-\037\200-\237]" nil t)
1544       (replace-match (format "\\%03o" (string-to-char (match-string 0)))
1545                      t t))))
1546
1547 ;;; Treatment of rejected articles.
1548 ;;; Bounced mail.
1549
1550 (defun gnus-summary-resend-bounced-mail (&optional fetch)
1551   "Re-mail the current message.
1552 This only makes sense if the current message is a bounce message that
1553 contains some mail you have written which has been bounced back to
1554 you.
1555 If FETCH, try to fetch the article that this is a reply to, if indeed
1556 this is a reply."
1557   (interactive "P")
1558   (gnus-summary-select-article t)
1559   (set-buffer gnus-original-article-buffer)
1560   (gnus-setup-message 'compose-bounce
1561     (let* ((references (mail-fetch-field "references"))
1562            (parent (and references (gnus-parent-id references))))
1563       (message-bounce)
1564       ;; If there are references, we fetch the article we answered to.
1565       (and fetch parent
1566            (gnus-summary-refer-article parent)
1567            (gnus-summary-show-all-headers)))))
1568
1569 ;;; Gcc handling.
1570
1571 (defun gnus-inews-group-method (group)
1572   (cond
1573    ;; If the group doesn't exist, we assume
1574    ;; it's an archive group...
1575    ((and (null (gnus-get-info group))
1576          (eq (car (gnus-server-to-method gnus-message-archive-method))
1577              (car (gnus-server-to-method (gnus-group-method group)))))
1578     gnus-message-archive-method)
1579    ;; Use the method.
1580    ((gnus-info-method (gnus-get-info group))
1581     (gnus-info-method (gnus-get-info group)))
1582    ;; Find the method.
1583    (t (gnus-server-to-method (gnus-group-method group)))))
1584
1585 ;; Do Gcc handling, which copied the message over to some group.
1586 (defun gnus-inews-do-gcc (&optional gcc)
1587   (interactive)
1588   (save-excursion
1589     (save-restriction
1590       (message-narrow-to-headers)
1591       (let ((gcc (or gcc (mail-fetch-field "gcc" nil t)))
1592             (cur (current-buffer))
1593             groups group method group-art
1594             mml-externalize-attachments)
1595         (when gcc
1596           (message-remove-header "gcc")
1597           (widen)
1598           (setq groups (message-unquote-tokens
1599                         (message-tokenize-header gcc " ,")))
1600           ;; Copy the article over to some group(s).
1601           (while (setq group (pop groups))
1602             (unless (gnus-check-server
1603                      (setq method (gnus-inews-group-method group)))
1604               (error "Can't open server %s" (if (stringp method) method
1605                                               (car method))))
1606             (unless (gnus-request-group group nil method)
1607               (gnus-request-create-group group method))
1608             (setq mml-externalize-attachments
1609                   (if (stringp gnus-gcc-externalize-attachments)
1610                       (string-match gnus-gcc-externalize-attachments group)
1611                     gnus-gcc-externalize-attachments))
1612             (save-excursion
1613               (nnheader-set-temp-buffer " *acc*")
1614               (insert-buffer-substring cur)
1615               (message-encode-message-body)
1616               (save-restriction
1617                 (message-narrow-to-headers)
1618                 (let* ((mail-parse-charset message-default-charset)
1619                        (newsgroups-field (save-restriction
1620                                            (message-narrow-to-headers-or-head)
1621                                            (message-fetch-field "Newsgroups")))
1622                        (followup-field (save-restriction
1623                                          (message-narrow-to-headers-or-head)
1624                                          (message-fetch-field "Followup-To")))
1625                        ;; BUG: We really need to get the charset for
1626                        ;; each name in the Newsgroups and Followup-To
1627                        ;; lines to allow crossposting between group
1628                        ;; namess with incompatible character sets.
1629                        ;; -- Per Abrahamsen <abraham@dina.kvl.dk> 2001-10-08.
1630                        (group-field-charset
1631                         (gnus-group-name-charset
1632                          method (or newsgroups-field "")))
1633                        (followup-field-charset
1634                         (gnus-group-name-charset
1635                          method (or followup-field "")))
1636                        (rfc2047-header-encoding-alist
1637                         (append
1638                          (when group-field-charset
1639                            (list (cons "Newsgroups" group-field-charset)))
1640                          (when followup-field-charset
1641                            (list (cons "Followup-To" followup-field-charset)))
1642                          rfc2047-header-encoding-alist)))
1643                   (mail-encode-encoded-word-buffer)))
1644               (goto-char (point-min))
1645               (when (re-search-forward
1646                      (concat "^" (regexp-quote mail-header-separator) "$")
1647                      nil t)
1648                 (replace-match "" t t ))
1649               (unless (setq group-art
1650                             (gnus-request-accept-article group method t t))
1651                 (gnus-message 1 "Couldn't store article in group %s: %s"
1652                               group (gnus-status-message method))
1653                 (sit-for 2))
1654               (when (and group-art
1655                          ;; FIXME: Should gcc-mark-as-read work when
1656                          ;; Gnus is not running?
1657                          (gnus-alive-p)
1658                          (or gnus-gcc-mark-as-read
1659                              (and
1660                               (boundp 'gnus-inews-mark-gcc-as-read)
1661                               (symbol-value 'gnus-inews-mark-gcc-as-read))))
1662                 (gnus-group-mark-article-read group (cdr group-art)))
1663               (kill-buffer (current-buffer)))))))))
1664
1665 (defun gnus-inews-insert-gcc ()
1666   "Insert Gcc headers based on `gnus-outgoing-message-group'."
1667   (save-excursion
1668     (save-restriction
1669       (message-narrow-to-headers)
1670       (let* ((group gnus-outgoing-message-group)
1671              (gcc (cond
1672                    ((functionp group)
1673                     (funcall group))
1674                    ((or (stringp group) (list group))
1675                     group))))
1676         (when gcc
1677           (insert "Gcc: "
1678                   (if (stringp gcc)
1679                       (if (string-match " " gcc)
1680                           (concat "\"" gcc "\"")
1681                         gcc)
1682                     (mapconcat (lambda (group)
1683                                  (if (string-match " " group)
1684                                      (concat "\"" group "\"")
1685                                    group))
1686                                gcc " "))
1687                   "\n"))))))
1688
1689 (defun gnus-inews-insert-archive-gcc (&optional group)
1690   "Insert the Gcc to say where the article is to be archived."
1691   (let* ((var gnus-message-archive-group)
1692          (group (or group gnus-newsgroup-name ""))
1693          (gcc-self-val
1694           (and gnus-newsgroup-name
1695                (not (equal gnus-newsgroup-name ""))
1696                (gnus-group-find-parameter
1697                 gnus-newsgroup-name 'gcc-self)))
1698          result
1699          (groups
1700           (cond
1701            ((null gnus-message-archive-method)
1702             ;; Ignore.
1703             nil)
1704            ((stringp var)
1705             ;; Just a single group.
1706             (list var))
1707            ((null var)
1708             ;; We don't want this.
1709             nil)
1710            ((and (listp var) (stringp (car var)))
1711             ;; A list of groups.
1712             var)
1713            ((functionp var)
1714             ;; A function.
1715             (funcall var group))
1716            (t
1717             ;; An alist of regexps/functions/forms.
1718             (while (and var
1719                         (not
1720                          (setq result
1721                                (cond
1722                                 ((stringp (caar var))
1723                                  ;; Regexp.
1724                                  (when (string-match (caar var) group)
1725                                    (cdar var)))
1726                                 ((functionp (car var))
1727                                  ;; Function.
1728                                  (funcall (car var) group))
1729                                 (t
1730                                  (eval (car var)))))))
1731               (setq var (cdr var)))
1732             result)))
1733          name)
1734     (when (or groups gcc-self-val)
1735       (when (stringp groups)
1736         (setq groups (list groups)))
1737       (save-excursion
1738         (save-restriction
1739           (message-narrow-to-headers)
1740           (goto-char (point-max))
1741           (insert "Gcc: ")
1742           (if gcc-self-val
1743               ;; Use the `gcc-self' param value instead.
1744               (progn
1745                 (insert
1746                  (if (stringp gcc-self-val)
1747                      (if (string-match " " gcc-self-val)
1748                          (concat "\"" gcc-self-val "\"")
1749                        gcc-self-val)
1750                    ;; In nndoc groups, we use the parent group name
1751                    ;; instead of the current group.
1752                    (let ((group (or (gnus-group-find-parameter
1753                                      gnus-newsgroup-name 'parent-group)
1754                                     group)))
1755                      (if (string-match " " group)
1756                          (concat "\"" group "\"")
1757                        group))))
1758                 (if (not (eq gcc-self-val 'none))
1759                     (insert "\n")
1760                   (gnus-delete-line)))
1761             ;; Use the list of groups.
1762             (while (setq name (pop groups))
1763               (let ((str (if (string-match ":" name)
1764                              name
1765                            (gnus-group-prefixed-name
1766                             name gnus-message-archive-method))))
1767                 (insert (if (string-match " " str)
1768                             (concat "\"" str "\"")
1769                           str)))
1770               (when groups
1771                 (insert " ")))
1772             (insert "\n")))))))
1773
1774 (defun gnus-mailing-list-followup-to ()
1775   "Look at the headers in the current buffer and return a Mail-Followup-To address."
1776   (let ((x-been-there (gnus-fetch-original-field "x-beenthere"))
1777         (list-post (gnus-fetch-original-field "list-post")))
1778     (when (and list-post
1779                (string-match "mailto:\\([^>]+\\)" list-post))
1780       (setq list-post (match-string 1 list-post)))
1781     (or list-post
1782         x-been-there)))
1783
1784 ;;; Posting styles.
1785
1786 (defun gnus-configure-posting-styles (&optional group-name)
1787   "Configure posting styles according to `gnus-posting-styles'."
1788   (unless gnus-inhibit-posting-styles
1789     (let ((group (or group-name gnus-newsgroup-name ""))
1790           (styles gnus-posting-styles)
1791           style match attribute value v results
1792           filep name address element)
1793       ;; If the group has a posting-style parameter, add it at the end with a
1794       ;; regexp matching everything, to be sure it takes precedence over all
1795       ;; the others.
1796       (when gnus-newsgroup-name
1797         (let ((tmp-style (gnus-group-find-parameter group 'posting-style t)))
1798           (when tmp-style
1799             (setq styles (append styles (list (cons ".*" tmp-style)))))))
1800       ;; Go through all styles and look for matches.
1801       (dolist (style styles)
1802         (setq match (pop style))
1803         (goto-char (point-min))
1804         (when (cond
1805                ((stringp match)
1806                 ;; Regexp string match on the group name.
1807                 (string-match match group))
1808                ((eq match 'header)
1809                 ;; Obsolete format of header match.
1810                 (and (gnus-buffer-live-p gnus-article-copy)
1811                      (with-current-buffer gnus-article-copy
1812                        (let ((header (message-fetch-field (pop style))))
1813                          (and header
1814                               (string-match (pop style) header))))))
1815                ((or (symbolp match)
1816                     (functionp match))
1817                 (cond
1818                  ((functionp match)
1819                   ;; Function to be called.
1820                   (funcall match))
1821                  ((boundp match)
1822                   ;; Variable to be checked.
1823                   (symbol-value match))))
1824                ((listp match)
1825                 (cond
1826                  ((eq (car match) 'header)
1827                   ;; New format of header match.
1828                   (and (gnus-buffer-live-p gnus-article-copy)
1829                        (with-current-buffer gnus-article-copy
1830                          (let ((header (message-fetch-field (nth 1 match))))
1831                            (and header
1832                                 (string-match (nth 2 match) header))))))
1833                  (t
1834                   ;; This is a form to be evaled.
1835                   (eval match)))))
1836           ;; We have a match, so we set the variables.
1837           (dolist (attribute style)
1838             (setq element (pop attribute)
1839                   filep nil)
1840             (setq value
1841                   (cond
1842                    ((eq (car attribute) :file)
1843                     (setq filep t)
1844                     (cadr attribute))
1845                    ((eq (car attribute) :value)
1846                     (cadr attribute))
1847                    (t
1848                     (car attribute))))
1849             ;; We get the value.
1850             (setq v
1851                   (cond
1852                    ((stringp value)
1853                     value)
1854                    ((or (symbolp value)
1855                         (functionp value))
1856                     (cond ((functionp value)
1857                            (funcall value))
1858                           ((boundp value)
1859                            (symbol-value value))))
1860                    ((listp value)
1861                     (eval value))))
1862             ;; Translate obsolescent value.
1863             (cond
1864              ((eq element 'signature-file)
1865               (setq element 'signature
1866                     filep t))
1867              ((eq element 'x-face-file)
1868               (setq element 'x-face
1869                     filep t)))
1870             ;; Get the contents of file elems.
1871             (when (and filep v)
1872               (setq v (with-temp-buffer
1873                         (insert-file-contents v)
1874                         (goto-char (point-max))
1875                         (while (bolp)
1876                           (delete-char -1))
1877                         (buffer-string))))
1878             (setq results (delq (assoc element results) results))
1879             (push (cons element v) results))))
1880       ;; Now we have all the styles, so we insert them.
1881       (setq name (assq 'name results)
1882             address (assq 'address results))
1883       (setq results (delq name (delq address results)))
1884       (gnus-make-local-hook 'message-setup-hook)
1885       (setq results (sort results (lambda (x y)
1886                                     (string-lessp (car x) (car y)))))
1887       (dolist (result results)
1888         (add-hook 'message-setup-hook
1889                   (cond
1890                    ((eq 'eval (car result))
1891                     'ignore)
1892                    ((eq 'body (car result))
1893                     `(lambda ()
1894                        (save-excursion
1895                          (message-goto-body)
1896                          (insert ,(cdr result)))))
1897                    ((eq 'signature (car result))
1898                     (set (make-local-variable 'message-signature) nil)
1899                     (set (make-local-variable 'message-signature-file) nil)
1900                     (if (not (cdr result))
1901                         'ignore
1902                       `(lambda ()
1903                          (save-excursion
1904                            (let ((message-signature ,(cdr result)))
1905                              (when message-signature
1906                                (message-insert-signature)))))))
1907                    (t
1908                     (let ((header
1909                            (if (symbolp (car result))
1910                                (capitalize (symbol-name (car result)))
1911                              (car result))))
1912                       `(lambda ()
1913                          (save-excursion
1914                            (message-remove-header ,header)
1915                            (let ((value ,(cdr result)))
1916                              (when value
1917                                (message-goto-eoh)
1918                                (insert ,header ": " value)
1919                                (unless (bolp)
1920                                  (insert "\n")))))))))
1921                   nil 'local))
1922       (when (or name address)
1923         (add-hook 'message-setup-hook
1924                   `(lambda ()
1925                      (set (make-local-variable 'user-mail-address)
1926                           ,(or (cdr address) user-mail-address))
1927                      (let ((user-full-name ,(or (cdr name) (user-full-name)))
1928                            (user-mail-address
1929                             ,(or (cdr address) user-mail-address)))
1930                        (save-excursion
1931                          (message-remove-header "From")
1932                          (message-goto-eoh)
1933                          (insert "From: " (message-make-from) "\n"))))
1934                   nil 'local)))))
1935
1936 ;;; Allow redefinition of functions.
1937
1938 (gnus-ems-redefine)
1939
1940 (provide 'gnus-msg)
1941
1942 ;;; gnus-msg.el ends here