cgit.sxemacs.org Git - gnus/blob - lisp/gnus-msg.el

   1 ;;; gnus-msg.el --- mail and post interface for Gnus
   2 ;; Copyright (C) 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003, 2004
   3 ;;        Free Software Foundation, Inc.
   4
   5 ;; Author: Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>
   6 ;;      Lars Magne Ingebrigtsen <larsi@gnus.org>
   7 ;; Keywords: news
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;;; Code:
  29
  30 (eval-when-compile (require 'cl))
  31
  32 (require 'gnus)
  33 (require 'gnus-ems)
  34 (require 'message)
  35 (require 'gnus-art)
  36 (require 'gnus-util)
  37
  38 (defcustom gnus-post-method 'current
  39   "*Preferred method for posting USENET news.
  40
  41 If this variable is `current' (which is the default), Gnus will use
  42 the \"current\" select method when posting.  If it is `native', Gnus
  43 will use the native select method when posting.
  44
  45 This method will not be used in mail groups and the like, only in
  46 \"real\" newsgroups.
  47
  48 If not `native' nor `current', the value must be a valid method as discussed
  49 in the documentation of `gnus-select-method'.  It can also be a list of
  50 methods.  If that is the case, the user will be queried for what select
  51 method to use when posting."
  52   :group 'gnus-group-foreign
  53   :link '(custom-manual "(gnus)Posting Server")
  54   :type `(choice (const native)
  55                  (const current)
  56                  (sexp :tag "Methods" ,gnus-select-method)))
  57
  58 (defcustom gnus-outgoing-message-group nil
  59   "*All outgoing messages will be put in this group.
  60 If you want to store all your outgoing mail and articles in the group
  61 \"nnml:archive\", you set this variable to that value.  This variable
  62 can also be a list of group names.
  63
  64 If you want to have greater control over what group to put each
  65 message in, you can set this variable to a function that checks the
  66 current newsgroup name and then returns a suitable group name (or list
  67 of names)."
  68   :group 'gnus-message
  69   :type '(choice (string :tag "Group")
  70                  (function)))
  71
  72 (defcustom gnus-mailing-list-groups nil
  73   "*If non-nil a regexp matching groups that are really mailing lists.
  74 This is useful when you're reading a mailing list that has been
  75 gatewayed to a newsgroup, and you want to followup to an article in
  76 the group."
  77   :group 'gnus-message
  78   :type '(choice (regexp)
  79                  (const nil)))
  80
  81 (defcustom gnus-add-to-list nil
  82   "*If non-nil, add a `to-list' parameter automatically."
  83   :group 'gnus-message
  84   :type 'boolean)
  85
  86 (defcustom gnus-crosspost-complaint
  87   "Hi,
  88
  89 You posted the article below with the following Newsgroups header:
  90
  91 Newsgroups: %s
  92
  93 The %s group, at least, was an inappropriate recipient
  94 of this message.  Please trim your Newsgroups header to exclude this
  95 group before posting in the future.
  96
  97 Thank you.
  98
  99 "
 100   "Format string to be inserted when complaining about crossposts.
 101 The first %s will be replaced by the Newsgroups header;
 102 the second with the current group name."
 103   :group 'gnus-message
 104   :type 'string)
 105
 106 (defcustom gnus-message-setup-hook nil
 107   "Hook run after setting up a message buffer."
 108   :group 'gnus-message
 109   :type 'hook)
 110
 111 (defcustom gnus-bug-create-help-buffer t
 112   "*Should we create the *Gnus Help Bug* buffer?"
 113   :group 'gnus-message
 114   :type 'boolean)
 115
 116 (defcustom gnus-posting-styles nil
 117   "*Alist of styles to use when posting.
 118 See Info node `(gnus)Posting Styles'."
 119   :group 'gnus-message
 120   :link '(custom-manual "(gnus)Posting Styles")
 121   :type '(repeat (cons (choice (regexp)
 122                                (variable)
 123                                (list (const header)
 124                                      (string :tag "Header")
 125                                      (regexp :tag "Regexp"))
 126                                (function)
 127                                (sexp))
 128                        (repeat (list
 129                                 (choice (const signature)
 130                                         (const signature-file)
 131                                         (const organization)
 132                                         (const address)
 133                                         (const x-face-file)
 134                                         (const name)
 135                                         (const body)
 136                                         (symbol)
 137                                         (string :tag "Header"))
 138                                 (choice (string)
 139                                         (function)
 140                                         (variable)
 141                                         (sexp)))))))
 142
 143 (defcustom gnus-gcc-mark-as-read nil
 144   "If non-nil, automatically mark Gcc articles as read."
 145   :version "21.4"
 146   :group 'gnus-message
 147   :type 'boolean)
 148
 149 (make-obsolete-variable 'gnus-inews-mark-gcc-as-read
 150                         'gnus-gcc-mark-as-read)
 151
 152 (defcustom gnus-gcc-externalize-attachments nil
 153   "Should local-file attachments be included as external parts in Gcc copies?
 154 If it is `all', attach files as external parts;
 155 if a regexp and matches the Gcc group name, attach files as external parts;
 156 if nil, attach files as normal parts."
 157   :version "21.4"
 158   :group 'gnus-message
 159   :type '(choice (const nil :tag "None")
 160                  (const all :tag "Any")
 161                  (string :tag "Regexp")))
 162
 163 (gnus-define-group-parameter
 164  posting-charset-alist
 165  :type list
 166  :function-document
 167  "Return the permitted unencoded charsets for posting of GROUP."
 168  :variable gnus-group-posting-charset-alist
 169  :variable-default
 170   '(("^\\(no\\|fr\\)\\.[^,]*\\(,[ \t\n]*\\(no\\|fr\\)\\.[^,]*\\)*$" iso-8859-1 (iso-8859-1))
 171     ("^\\(fido7\\|relcom\\)\\.[^,]*\\(,[ \t\n]*\\(fido7\\|relcom\\)\\.[^,]*\\)*$" koi8-r (koi8-r))
 172     (message-this-is-mail nil nil)
 173     (message-this-is-news nil t))
 174  :variable-document
 175   "Alist of regexps and permitted unencoded charsets for posting.
 176 Each element of the alist has the form (TEST HEADER BODY-LIST), where
 177 TEST is either a regular expression matching the newsgroup header or a
 178 variable to query,
 179 HEADER is the charset which may be left unencoded in the header (nil
 180 means encode all charsets),
 181 BODY-LIST is a list of charsets which may be encoded using 8bit
 182 content-transfer encoding in the body, or one of the special values
 183 nil (always encode using quoted-printable) or t (always use 8bit).
 184
 185 Note that any value other than nil for HEADER infringes some RFCs, so
 186 use this option with care."
 187  :variable-group gnus-charset
 188  :variable-type
 189  '(repeat (list :tag "Permitted unencoded charsets"
 190                 (choice :tag "Where"
 191                         (regexp :tag "Group")
 192                         (const :tag "Mail message" :value message-this-is-mail)
 193                         (const :tag "News article" :value message-this-is-news))
 194                 (choice :tag "Header"
 195                         (const :tag "None" nil)
 196                         (symbol :tag "Charset"))
 197                 (choice :tag "Body"
 198                         (const :tag "Any" :value t)
 199                         (const :tag "None" :value nil)
 200                         (repeat :tag "Charsets"
 201                                 (symbol :tag "Charset")))))
 202  :parameter-type '(choice :tag "Permitted unencoded charsets"
 203                           :value nil
 204                           (repeat (symbol)))
 205  :parameter-document       "\
 206 List of charsets that are permitted to be unencoded.")
 207
 208 (defcustom gnus-debug-files
 209   '("gnus.el" "gnus-sum.el" "gnus-group.el"
 210     "gnus-art.el" "gnus-start.el" "gnus-async.el"
 211     "gnus-msg.el" "gnus-score.el" "gnus-win.el" "gnus-topic.el"
 212     "gnus-agent.el" "gnus-cache.el" "gnus-srvr.el"
 213     "mm-util.el" "mm-decode.el" "nnmail.el" "message.el")
 214   "Files whose variables will be reported in `gnus-bug'."
 215   :version "21.4"
 216   :group 'gnus-message
 217   :type '(repeat (string :tag "File")))
 218
 219 (defcustom gnus-debug-exclude-variables
 220   '(mm-mime-mule-charset-alist
 221     nnmail-split-fancy message-minibuffer-local-map)
 222   "Variables that should not be reported in `gnus-bug'."
 223   :version "21.4"
 224   :group 'gnus-message
 225   :type '(repeat (symbol :tag "Variable")))
 226
 227 (defcustom gnus-discouraged-post-methods
 228   '(nndraft nnml nnimap nnmaildir nnmh nnfolder nndir)
 229   "A list of back ends that are not used in \"real\" newsgroups.
 230 This variable is used only when `gnus-post-method' is `current'."
 231   :version "21.4"
 232   :group 'gnus-group-foreign
 233   :type '(repeat (symbol :tag "Back end")))
 234
 235 (defcustom gnus-message-replysign
 236   nil
 237   "Automatically sign replies to signed messages.
 238 See also the `mml-default-sign-method' variable."
 239   :group 'gnus-message
 240   :type 'boolean)
 241
 242 (defcustom gnus-message-replyencrypt
 243   nil
 244   "Automatically encrypt replies to encrypted messages.
 245 See also the `mml-default-encrypt-method' variable."
 246   :group 'gnus-message
 247   :type 'boolean)
 248
 249 (defcustom gnus-message-replysignencrypted
 250   t
 251   "Setting this causes automatically encrypted messages to also be signed."
 252   :group 'gnus-message
 253   :type 'boolean)
 254
 255 (defcustom gnus-confirm-mail-reply-to-news nil
 256   "If non-nil, Gnus requests confirmation when replying to news.
 257 This is done because new users often reply by mistake when reading
 258 news.
 259 This can also be a function receiving the group name as the only
 260 parameter which should return non-nil iff a confirmation is needed, or
 261 a regexp, in which case a confirmation is asked for iff the group name
 262 matches the regexp."
 263   :version "21.4"
 264   :group 'gnus-message
 265   :type '(choice (const :tag "No" nil)
 266                  (const :tag "Yes" t)
 267                  (regexp :tag "Iff group matches regexp")
 268                  (function :tag "Iff function evaluates to non-nil")))
 269
 270 (defcustom gnus-confirm-treat-mail-like-news
 271   nil
 272   "If non-nil, Gnus will treat mail like news with regard to confirmation
 273 when replying by mail.  See the `gnus-confirm-mail-reply-to-news' variable
 274 for fine-tuning this.
 275 If nil, Gnus will never ask for confirmation if replying to mail."
 276   :version "21.4"
 277   :group 'gnus-message
 278   :type 'boolean)
 279
 280 (defcustom gnus-summary-resend-default-address t
 281   "If non-nil, Gnus tries to suggest a default address to resend to.
 282 If nil, the address field will always be empty after invoking
 283 `gnus-summary-resend-message'."
 284   :group 'gnus-message
 285   :type 'boolean)
 286
 287 ;;; Internal variables.
 288
 289 (defvar gnus-inhibit-posting-styles nil
 290   "Inhibit the use of posting styles.")
 291
 292 (defvar gnus-article-yanked-articles nil)
 293 (defvar gnus-message-buffer "*Mail Gnus*")
 294 (defvar gnus-article-copy nil)
 295 (defvar gnus-check-before-posting nil)
 296 (defvar gnus-last-posting-server nil)
 297 (defvar gnus-message-group-art nil)
 298
 299 (defvar gnus-msg-force-broken-reply-to nil)
 300
 301 (defconst gnus-bug-message
 302   "Sending a bug report to the Gnus Towers.
 303 ========================================
 304
 305 The buffer below is a mail buffer.  When you press `C-c C-c', it will
 306 be sent to the Gnus Bug Exterminators.
 307
 308 The thing near the bottom of the buffer is how the environment
 309 settings will be included in the mail.  Please do not delete that.
 310 They will tell the Bug People what your environment is, so that it
 311 will be easier to locate the bugs.
 312
 313 If you have found a bug that makes Emacs go \"beep\", set
 314 debug-on-error to t (`M-x set-variable RET debug-on-error RET t RET')
 315 and include the backtrace in your bug report.
 316
 317 Please describe the bug in annoying, painstaking detail.
 318
 319 Thank you for your help in stamping out bugs.
 320 ")
 321
 322 (eval-and-compile
 323   (autoload 'gnus-uu-post-news "gnus-uu" nil t))
 324
 325 \f
 326 ;;;
 327 ;;; Gnus Posting Functions
 328 ;;;
 329
 330 (gnus-define-keys (gnus-summary-send-map "S" gnus-summary-mode-map)
 331   "p" gnus-summary-post-news
 332   "i" gnus-summary-news-other-window
 333   "f" gnus-summary-followup
 334   "F" gnus-summary-followup-with-original
 335   "c" gnus-summary-cancel-article
 336   "s" gnus-summary-supersede-article
 337   "r" gnus-summary-reply
 338   "y" gnus-summary-yank-message
 339   "R" gnus-summary-reply-with-original
 340   "w" gnus-summary-wide-reply
 341   "W" gnus-summary-wide-reply-with-original
 342   "v" gnus-summary-very-wide-reply
 343   "V" gnus-summary-very-wide-reply-with-original
 344   "n" gnus-summary-followup-to-mail
 345   "N" gnus-summary-followup-to-mail-with-original
 346   "m" gnus-summary-mail-other-window
 347   "u" gnus-uu-post-news
 348   "\M-c" gnus-summary-mail-crosspost-complaint
 349   "Br" gnus-summary-reply-broken-reply-to
 350   "BR" gnus-summary-reply-broken-reply-to-with-original
 351   "om" gnus-summary-mail-forward
 352   "op" gnus-summary-post-forward
 353   "Om" gnus-uu-digest-mail-forward
 354   "Op" gnus-uu-digest-post-forward)
 355
 356 (gnus-define-keys (gnus-send-bounce-map "D" gnus-summary-send-map)
 357   "b" gnus-summary-resend-bounced-mail
 358   ;; "c" gnus-summary-send-draft
 359   "r" gnus-summary-resend-message
 360   "e" gnus-summary-resend-message-edit)
 361
 362 ;;; Internal functions.
 363
 364 (defun gnus-inews-make-draft (articles)
 365   `(lambda ()
 366      (gnus-inews-make-draft-meta-information
 367       ,gnus-newsgroup-name ',articles)))
 368
 369 (defvar gnus-article-reply nil)
 370 (defmacro gnus-setup-message (config &rest forms)
 371   (let ((winconf (make-symbol "gnus-setup-message-winconf"))
 372         (buffer (make-symbol "gnus-setup-message-buffer"))
 373         (article (make-symbol "gnus-setup-message-article"))
 374         (yanked (make-symbol "gnus-setup-yanked-articles"))
 375         (group (make-symbol "gnus-setup-message-group")))
 376     `(let ((,winconf (current-window-configuration))
 377            (,buffer (buffer-name (current-buffer)))
 378            (,article gnus-article-reply)
 379            (,yanked gnus-article-yanked-articles)
 380            (,group gnus-newsgroup-name)
 381            (message-header-setup-hook
 382             (copy-sequence message-header-setup-hook))
 383            (mbl mml-buffer-list)
 384            (message-mode-hook (copy-sequence message-mode-hook)))
 385        (setq mml-buffer-list nil)
 386        (add-hook 'message-header-setup-hook 'gnus-inews-insert-gcc)
 387        (add-hook 'message-header-setup-hook 'gnus-inews-insert-archive-gcc)
 388        ;; #### FIXME: for a reason that I did not manage to identify yet,
 389        ;; the variable `gnus-newsgroup-name' does not honor a dynamically
 390        ;; scoped or setq'ed value from a caller like `C-u gnus-summary-mail'.
 391        ;; After evaluation of @forms below, it gets the value we actually want
 392        ;; to override, and the posting styles are used. For that reason, I've
 393        ;; added an optional argument to `gnus-configure-posting-styles' to
 394        ;; make sure that the correct value for the group name is used. -- drv
 395        (add-hook 'message-mode-hook
 396                  (if (memq ,config '(reply-yank reply))
 397                      (lambda ()
 398                        (gnus-configure-posting-styles ,group))
 399                    (lambda ()
 400                      ;; There may be an old " *gnus article copy*" buffer.
 401                      (let (gnus-article-copy)
 402                        (gnus-configure-posting-styles ,group)))))
 403        (gnus-pull ',(intern gnus-draft-meta-information-header)
 404                   message-required-headers)
 405        (when (and ,group
 406                   (not (string= ,group "")))
 407          (push (cons
 408                 (intern gnus-draft-meta-information-header)
 409                 (gnus-inews-make-draft ,yanked))
 410                message-required-headers))
 411        (unwind-protect
 412            (progn
 413              ,@forms)
 414          (gnus-inews-add-send-actions ,winconf ,buffer ,article ,config
 415                                       ,yanked)
 416          (setq gnus-message-buffer (current-buffer))
 417          (set (make-local-variable 'gnus-message-group-art)
 418               (cons ,group ,article))
 419          (set (make-local-variable 'gnus-newsgroup-name) ,group)
 420          (gnus-run-hooks 'gnus-message-setup-hook)
 421          (if (eq major-mode 'message-mode)
 422              (let ((mbl1 mml-buffer-list))
 423                (setq mml-buffer-list mbl)  ;; Global value
 424                (set (make-local-variable 'mml-buffer-list) mbl1);; Local value
 425                (gnus-make-local-hook 'kill-buffer-hook)
 426                (gnus-make-local-hook 'change-major-mode-hook)
 427                (add-hook 'change-major-mode-hook 'mml-destroy-buffers nil t)
 428                (add-hook 'kill-buffer-hook 'mml-destroy-buffers t t))
 429            (mml-destroy-buffers)
 430            (setq mml-buffer-list mbl)))
 431        (message-hide-headers)
 432        (gnus-add-buffer)
 433        (gnus-configure-windows ,config t)
 434        (run-hooks 'post-command-hook)
 435        (set-buffer-modified-p nil))))
 436
 437 (defun gnus-inews-make-draft-meta-information (group articles)
 438   (when (numberp articles)
 439     (setq articles (list articles)))
 440   (concat "(\"" group "\" "
 441           (if articles
 442               (mapconcat
 443                (lambda (elem)
 444                  (number-to-string
 445                   (if (consp elem)
 446                       (car elem)
 447                     elem)))
 448                articles " ")
 449             "")
 450           ")"))
 451
 452 ;;;###autoload
 453 (defun gnus-msg-mail (&optional to subject other-headers continue
 454                                 switch-action yank-action send-actions)
 455   "Start editing a mail message to be sent.
 456 Like `message-mail', but with Gnus paraphernalia, particularly the
 457 Gcc: header for archiving purposes."
 458   (interactive)
 459   (let ((buf (current-buffer))
 460         mail-buf)
 461     (gnus-setup-message 'message
 462       (message-mail to subject other-headers continue
 463                     nil yank-action send-actions))
 464     (when switch-action
 465       (setq mail-buf (current-buffer))
 466       (switch-to-buffer buf)
 467       (apply switch-action mail-buf nil)))
 468   ;; COMPOSEFUNC should return t if succeed.  Undocumented ???
 469   t)
 470
 471 (defvar save-selected-window-window)
 472
 473 ;;;###autoload
 474 (defun gnus-button-mailto (address)
 475   "Mail to ADDRESS."
 476   (set-buffer (gnus-copy-article-buffer))
 477   (gnus-setup-message 'message
 478     (message-reply address))
 479   (and (boundp 'save-selected-window-window)
 480        (not (window-live-p save-selected-window-window))
 481        (setq save-selected-window-window (selected-window))))
 482
 483 ;;;###autoload
 484 (defun gnus-button-reply (&optional to-address wide)
 485   "Like `message-reply'."
 486   (interactive)
 487   (gnus-setup-message 'message
 488     (message-reply to-address wide))
 489   (and (boundp 'save-selected-window-window)
 490        (not (window-live-p save-selected-window-window))
 491        (setq save-selected-window-window (selected-window))))
 492
 493 ;;;###autoload
 494 (define-mail-user-agent 'gnus-user-agent
 495   'gnus-msg-mail 'message-send-and-exit
 496   'message-kill-buffer 'message-send-hook)
 497
 498 (defun gnus-setup-posting-charset (group)
 499   (let ((alist gnus-group-posting-charset-alist)
 500         (group (or group ""))
 501         elem)
 502     (when group
 503       (catch 'found
 504         (while (setq elem (pop alist))
 505           (when (or (and (stringp (car elem))
 506                          (string-match (car elem) group))
 507                     (and (functionp (car elem))
 508                          (funcall (car elem) group))
 509                     (and (symbolp (car elem))
 510                          (symbol-value (car elem))))
 511             (throw 'found (cons (cadr elem) (caddr elem)))))))))
 512
 513 (defun gnus-inews-add-send-actions (winconf buffer article
 514                                             &optional config yanked)
 515   (gnus-make-local-hook 'message-sent-hook)
 516   (add-hook 'message-sent-hook (if gnus-agent 'gnus-agent-possibly-do-gcc
 517                                  'gnus-inews-do-gcc) nil t)
 518   (when gnus-agent
 519     (gnus-make-local-hook 'message-header-hook)
 520     (add-hook 'message-header-hook 'gnus-agent-possibly-save-gcc nil t))
 521   (setq message-post-method
 522         `(lambda (arg)
 523            (gnus-post-method arg ,gnus-newsgroup-name)))
 524   (setq message-newsreader (setq message-mailer (gnus-extended-version)))
 525   (message-add-action
 526    `(when (gnus-buffer-exists-p ,buffer)
 527       (set-window-configuration ,winconf))
 528    'exit 'postpone 'kill)
 529   (let ((to-be-marked (cond
 530                        (yanked
 531                         (mapcar
 532                          (lambda (x) (if (listp x) (car x) x)) yanked))
 533                        (article (if (listp article) article (list article)))
 534                        (t nil))))
 535     (message-add-action
 536      `(when (gnus-buffer-exists-p ,buffer)
 537         (save-excursion
 538           (set-buffer ,buffer)
 539           ,(when to-be-marked
 540              (if (eq config 'forward)
 541                  `(gnus-summary-mark-article-as-forwarded ',to-be-marked)
 542                `(gnus-summary-mark-article-as-replied ',to-be-marked)))))
 543      'send)))
 544
 545 (put 'gnus-setup-message 'lisp-indent-function 1)
 546 (put 'gnus-setup-message 'edebug-form-spec '(form body))
 547
 548 ;;; Post news commands of Gnus group mode and summary mode
 549
 550 (defun gnus-group-mail (&optional arg)
 551   "Start composing a mail.
 552 If ARG, use the group under the point to find a posting style.
 553 If ARG is 1, prompt for a group name to find the posting style."
 554   (interactive "P")
 555   ;; We can't `let' gnus-newsgroup-name here, since that leads
 556   ;; to local variables leaking.
 557   (let ((group gnus-newsgroup-name)
 558         ;; make sure last viewed article doesn't affect posting styles:
 559         (gnus-article-copy)
 560         (buffer (current-buffer)))
 561     (unwind-protect
 562         (progn
 563           (setq gnus-newsgroup-name
 564                 (if arg
 565                     (if (= 1 (prefix-numeric-value arg))
 566                         (completing-read "Use posting style of group: "
 567                                          gnus-active-hashtb nil
 568                                          (gnus-read-active-file-p))
 569                       (gnus-group-group-name))
 570                   ""))
 571           ;; #### see comment in gnus-setup-message -- drv
 572           (gnus-setup-message 'message (message-mail)))
 573       (save-excursion
 574         (set-buffer buffer)
 575         (setq gnus-newsgroup-name group)))))
 576
 577 (defun gnus-group-news (&optional arg)
 578   "Start composing a news.
 579 If ARG, post to group under point.
 580 If ARG is 1, prompt for group name to post to.
 581
 582 This function prepares a news even when using mail groups.  This is useful
 583 for posting messages to mail groups without actually sending them over the
 584 network.  The corresponding back end must have a 'request-post method."
 585   (interactive "P")
 586   ;; We can't `let' gnus-newsgroup-name here, since that leads
 587   ;; to local variables leaking.
 588   (let ((group gnus-newsgroup-name)
 589         ;; make sure last viewed article doesn't affect posting styles:
 590         (gnus-article-copy)
 591         (buffer (current-buffer)))
 592     (unwind-protect
 593         (progn
 594           (setq gnus-newsgroup-name
 595                 (if arg
 596                     (if (= 1 (prefix-numeric-value arg))
 597                         (completing-read "Use group: "
 598                                          gnus-active-hashtb nil
 599                                          (gnus-read-active-file-p))
 600                       (gnus-group-group-name))
 601                   ""))
 602           ;; #### see comment in gnus-setup-message -- drv
 603           (gnus-setup-message 'message
 604             (message-news (gnus-group-real-name gnus-newsgroup-name))))
 605       (save-excursion
 606         (set-buffer buffer)
 607         (setq gnus-newsgroup-name group)))))
 608
 609 (defun gnus-group-post-news (&optional arg)
 610   "Start composing a message (a news by default).
 611 If ARG, post to group under point.  If ARG is 1, prompt for group name.
 612 Depending on the selected group, the message might be either a mail or
 613 a news."
 614   (interactive "P")
 615   ;; Bind this variable here to make message mode hooks work ok.
 616   (let ((gnus-newsgroup-name
 617          (if arg
 618              (if (= 1 (prefix-numeric-value arg))
 619                  (completing-read "Newsgroup: " gnus-active-hashtb nil
 620                                   (gnus-read-active-file-p))
 621                (gnus-group-group-name))
 622            ""))
 623         ;; make sure last viewed article doesn't affect posting styles:
 624         (gnus-article-copy))
 625     (gnus-post-news 'post gnus-newsgroup-name nil nil nil nil
 626                     (string= gnus-newsgroup-name ""))))
 627
 628 (defun gnus-summary-mail-other-window (&optional arg)
 629   "Start composing a mail in another window.
 630 Use the posting of the current group by default.
 631 If ARG, don't do that.  If ARG is 1, prompt for group name to find the
 632 posting style."
 633   (interactive "P")
 634   ;; We can't `let' gnus-newsgroup-name here, since that leads
 635   ;; to local variables leaking.
 636   (let ((group gnus-newsgroup-name)
 637         ;; make sure last viewed article doesn't affect posting styles:
 638         (gnus-article-copy)
 639         (buffer (current-buffer)))
 640     (unwind-protect
 641         (progn
 642           (setq gnus-newsgroup-name
 643                 (if arg
 644                     (if (= 1 (prefix-numeric-value arg))
 645                         (completing-read "Use group: "
 646                                          gnus-active-hashtb nil
 647                                          (gnus-read-active-file-p))
 648                       "")
 649                   gnus-newsgroup-name))
 650           ;; #### see comment in gnus-setup-message -- drv
 651           (gnus-setup-message 'message (message-mail)))
 652       (save-excursion
 653         (set-buffer buffer)
 654         (setq gnus-newsgroup-name group)))))
 655
 656 (defun gnus-summary-news-other-window (&optional arg)
 657   "Start composing a news in another window.
 658 Post to the current group by default.
 659 If ARG, don't do that.  If ARG is 1, prompt for group name to post to.
 660
 661 This function prepares a news even when using mail groups.  This is useful
 662 for posting messages to mail groups without actually sending them over the
 663 network.  The corresponding back end must have a 'request-post method."
 664   (interactive "P")
 665   ;; We can't `let' gnus-newsgroup-name here, since that leads
 666   ;; to local variables leaking.
 667   (let ((group gnus-newsgroup-name)
 668         ;; make sure last viewed article doesn't affect posting styles:
 669         (gnus-article-copy)
 670         (buffer (current-buffer)))
 671     (unwind-protect
 672         (progn
 673           (setq gnus-newsgroup-name
 674                 (if arg
 675                     (if (= 1 (prefix-numeric-value arg))
 676                         (completing-read "Use group: "
 677                                          gnus-active-hashtb nil
 678                                          (gnus-read-active-file-p))
 679                       "")
 680                   gnus-newsgroup-name))
 681           ;; #### see comment in gnus-setup-message -- drv
 682           (gnus-setup-message 'message
 683             (progn
 684               (message-news (gnus-group-real-name gnus-newsgroup-name))
 685               (set (make-local-variable 'gnus-discouraged-post-methods)
 686                    (remove
 687                     (car (gnus-find-method-for-group gnus-newsgroup-name))
 688                     gnus-discouraged-post-methods)))))
 689       (save-excursion
 690         (set-buffer buffer)
 691         (setq gnus-newsgroup-name group)))))
 692
 693 (defun gnus-summary-post-news (&optional arg)
 694   "Start composing a message.  Post to the current group by default.
 695 If ARG, don't do that.  If ARG is 1, prompt for a group name to post to.
 696 Depending on the selected group, the message might be either a mail or
 697 a news."
 698   (interactive "P")
 699   ;; Bind this variable here to make message mode hooks work ok.
 700   (let ((gnus-newsgroup-name
 701          (if arg
 702              (if (= 1 (prefix-numeric-value arg))
 703                  (completing-read "Newsgroup: " gnus-active-hashtb nil
 704                                   (gnus-read-active-file-p))
 705                "")
 706            gnus-newsgroup-name))
 707         ;; make sure last viewed article doesn't affect posting styles:
 708         (gnus-article-copy))
 709     (gnus-post-news 'post gnus-newsgroup-name)))
 710
 711
 712 (defun gnus-summary-followup (yank &optional force-news)
 713   "Compose a followup to an article.
 714 If prefix argument YANK is non-nil, the original article is yanked
 715 automatically.
 716 YANK is a list of elements, where the car of each element is the
 717 article number, and the cdr is the string to be yanked."
 718   (interactive
 719    (list (and current-prefix-arg
 720               (gnus-summary-work-articles 1))))
 721   (when yank
 722     (gnus-summary-goto-subject
 723      (if (listp (car yank))
 724          (caar yank)
 725        (car yank))))
 726   (save-window-excursion
 727     (gnus-summary-select-article))
 728   (let ((headers (gnus-summary-article-header (gnus-summary-article-number)))
 729         (gnus-newsgroup-name gnus-newsgroup-name))
 730     ;; Send a followup.
 731     (gnus-post-news nil gnus-newsgroup-name
 732                     headers gnus-article-buffer
 733                     yank nil force-news)
 734     (gnus-summary-handle-replysign)))
 735
 736 (defun gnus-summary-followup-with-original (n &optional force-news)
 737   "Compose a followup to an article and include the original article.
 738 The text in the region will be yanked.  If the region isn't
 739 active, the entire article will be yanked."
 740   (interactive "P")
 741   (gnus-summary-followup (gnus-summary-work-articles n) force-news))
 742
 743 (defun gnus-summary-followup-to-mail (&optional arg)
 744   "Followup to the current mail message via news."
 745   (interactive
 746    (list (and current-prefix-arg
 747               (gnus-summary-work-articles 1))))
 748   (gnus-summary-followup arg t))
 749
 750 (defun gnus-summary-followup-to-mail-with-original (&optional arg)
 751   "Followup to the current mail message via news."
 752   (interactive "P")
 753   (gnus-summary-followup (gnus-summary-work-articles arg) t))
 754
 755 (defun gnus-inews-yank-articles (articles)
 756   (let (beg article yank-string)
 757     (message-goto-body)
 758     (while (setq article (pop articles))
 759       (when (listp article)
 760         (setq yank-string (nth 1 article)
 761               article (nth 0 article)))
 762       (save-window-excursion
 763         (set-buffer gnus-summary-buffer)
 764         (gnus-summary-select-article nil nil nil article)
 765         (gnus-summary-remove-process-mark article))
 766       (gnus-copy-article-buffer nil yank-string)
 767       (let ((message-reply-buffer gnus-article-copy)
 768             (message-reply-headers
 769              ;; The headers are decoded.
 770              (with-current-buffer gnus-article-copy
 771                (save-restriction
 772                  (nnheader-narrow-to-headers)
 773                  (nnheader-parse-naked-head)))))
 774         (message-yank-original)
 775         (setq beg (or beg (mark t))))
 776       (when articles
 777         (insert "\n")))
 778     (push-mark)
 779     (goto-char beg)))
 780
 781 (defun gnus-summary-cancel-article (&optional n symp)
 782   "Cancel an article you posted.
 783 Uses the process-prefix convention.  If given the symbolic
 784 prefix `a', cancel using the standard posting method; if not
 785 post using the current select method."
 786   (interactive (gnus-interactive "P\ny"))
 787   (let ((articles (gnus-summary-work-articles n))
 788         (message-post-method
 789          `(lambda (arg)
 790             (gnus-post-method (eq ',symp 'a) ,gnus-newsgroup-name)))
 791         article)
 792     (while (setq article (pop articles))
 793       (when (gnus-summary-select-article t nil nil article)
 794         (when (gnus-eval-in-buffer-window gnus-original-article-buffer
 795                 (message-cancel-news))
 796           (gnus-summary-mark-as-read article gnus-canceled-mark)
 797           (gnus-cache-remove-article 1))
 798         (gnus-article-hide-headers-if-wanted))
 799       (gnus-summary-remove-process-mark article))))
 800
 801 (defun gnus-summary-supersede-article ()
 802   "Compose an article that will supersede a previous article.
 803 This is done simply by taking the old article and adding a Supersedes
 804 header line with the old Message-ID."
 805   (interactive)
 806   (let ((article (gnus-summary-article-number)))
 807     (gnus-setup-message 'reply-yank
 808       (gnus-summary-select-article t)
 809       (set-buffer gnus-original-article-buffer)
 810       (message-supersede)
 811       (push
 812        `((lambda ()
 813            (when (gnus-buffer-exists-p ,gnus-summary-buffer)
 814              (save-excursion
 815                (set-buffer ,gnus-summary-buffer)
 816                (gnus-cache-possibly-remove-article ,article nil nil nil t)
 817                (gnus-summary-mark-as-read ,article gnus-canceled-mark)))))
 818        message-send-actions))))
 819
 820 \f
 821
 822 (defun gnus-copy-article-buffer (&optional article-buffer yank-string)
 823   ;; make a copy of the article buffer with all text properties removed
 824   ;; this copy is in the buffer gnus-article-copy.
 825   ;; if ARTICLE-BUFFER is nil, gnus-article-buffer is used
 826   ;; this buffer should be passed to all mail/news reply/post routines.
 827   (setq gnus-article-copy (gnus-get-buffer-create " *gnus article copy*"))
 828   (save-excursion
 829     (set-buffer gnus-article-copy)
 830     (mm-enable-multibyte))
 831   (let ((article-buffer (or article-buffer gnus-article-buffer))
 832         end beg)
 833     (if (not (and (get-buffer article-buffer)
 834                   (gnus-buffer-exists-p article-buffer)))
 835         (error "Can't find any article buffer")
 836       (save-excursion
 837         (set-buffer article-buffer)
 838         (let ((gnus-newsgroup-charset (or gnus-article-charset
 839                                           gnus-newsgroup-charset))
 840               (gnus-newsgroup-ignored-charsets
 841                (or gnus-article-ignored-charsets
 842                    gnus-newsgroup-ignored-charsets)))
 843           (save-restriction
 844             ;; Copy over the (displayed) article buffer, delete
 845             ;; hidden text and remove text properties.
 846             (widen)
 847             (copy-to-buffer gnus-article-copy (point-min) (point-max))
 848             (set-buffer gnus-article-copy)
 849             (when yank-string
 850               (message-goto-body)
 851               (delete-region (point) (point-max))
 852               (insert yank-string))
 853             (gnus-article-delete-text-of-type 'annotation)
 854             (gnus-remove-text-with-property 'gnus-prev)
 855             (gnus-remove-text-with-property 'gnus-next)
 856             (gnus-remove-text-with-property 'gnus-decoration)
 857             (insert
 858              (prog1
 859                  (buffer-substring-no-properties (point-min) (point-max))
 860                (erase-buffer)))
 861             ;; Find the original headers.
 862             (set-buffer gnus-original-article-buffer)
 863             (goto-char (point-min))
 864             (while (looking-at message-unix-mail-delimiter)
 865               (forward-line 1))
 866             (let ((mail-header-separator ""))
 867               (setq beg (point)
 868                     end (or (message-goto-body)
 869                             ;; There may be just a header.
 870                             (point-max))))
 871             ;; Delete the headers from the displayed articles.
 872             (set-buffer gnus-article-copy)
 873             (let ((mail-header-separator ""))
 874               (delete-region (goto-char (point-min))
 875                              (or (message-goto-body) (point-max))))
 876             ;; Insert the original article headers.
 877             (insert-buffer-substring gnus-original-article-buffer beg end)
 878             ;; Decode charsets.
 879             (let ((gnus-article-decode-hook
 880                    (delq 'article-decode-charset
 881                          (copy-sequence gnus-article-decode-hook))))
 882               (run-hooks 'gnus-article-decode-hook)))))
 883       gnus-article-copy)))
 884
 885 (defun gnus-post-news (post &optional group header article-buffer yank subject
 886                             force-news)
 887   (when article-buffer
 888     (gnus-copy-article-buffer))
 889   (let ((gnus-article-reply (and article-buffer (gnus-summary-article-number)))
 890         (gnus-article-yanked-articles yank)
 891         (add-to-list gnus-add-to-list))
 892     (gnus-setup-message (cond (yank 'reply-yank)
 893                               (article-buffer 'reply)
 894                               (t 'message))
 895       (let* ((group (or group gnus-newsgroup-name))
 896              (charset (gnus-group-name-charset nil group))
 897              (pgroup group)
 898              to-address to-group mailing-list to-list
 899              newsgroup-p)
 900         (when group
 901           (setq to-address (gnus-parameter-to-address group)
 902                 to-group (gnus-group-find-parameter group 'to-group)
 903                 to-list (gnus-parameter-to-list group)
 904                 newsgroup-p (gnus-group-find-parameter group 'newsgroup)
 905                 mailing-list (when gnus-mailing-list-groups
 906                                (string-match gnus-mailing-list-groups group))
 907                 group (gnus-group-name-decode (gnus-group-real-name group)
 908                                               charset)))
 909         (if (or (and to-group
 910                      (gnus-news-group-p to-group))
 911                 newsgroup-p
 912                 force-news
 913                 (and (gnus-news-group-p
 914                       (or pgroup gnus-newsgroup-name)
 915                       (or header gnus-current-article))
 916                      (not mailing-list)
 917                      (not to-list)
 918                      (not to-address)))
 919             ;; This is news.
 920             (if post
 921                 (message-news
 922                  (or to-group
 923                      (and (not (gnus-virtual-group-p pgroup)) group)))
 924               (set-buffer gnus-article-copy)
 925               (gnus-msg-treat-broken-reply-to)
 926               (message-followup (if (or newsgroup-p force-news)
 927                                     (if (save-restriction
 928                                           (article-narrow-to-head)
 929                                           (message-fetch-field "newsgroups"))
 930                                         nil
 931                                       "")
 932                                   to-group)))
 933           ;; The is mail.
 934           (if post
 935               (progn
 936                 (message-mail (or to-address to-list))
 937                 ;; Arrange for mail groups that have no `to-address' to
 938                 ;; get that when the user sends off the mail.
 939                 (when (and (not to-list)
 940                            (not to-address)
 941                            add-to-list)
 942                   (push (list 'gnus-inews-add-to-address pgroup)
 943                         message-send-actions)))
 944             (set-buffer gnus-article-copy)
 945             (gnus-msg-treat-broken-reply-to)
 946             (message-wide-reply to-address)))
 947         (when yank
 948           (gnus-inews-yank-articles yank))))))
 949
 950 (defun gnus-msg-treat-broken-reply-to (&optional force)
 951   "Remove the Reply-to header if broken-reply-to."
 952   (when (or force
 953             (gnus-group-find-parameter
 954              gnus-newsgroup-name 'broken-reply-to))
 955     (save-restriction
 956       (message-narrow-to-head)
 957       (message-remove-header "reply-to"))))
 958
 959 (defun gnus-post-method (arg group &optional silent)
 960   "Return the posting method based on GROUP and ARG.
 961 If SILENT, don't prompt the user."
 962   (let ((gnus-post-method (or (gnus-parameter-post-method group)
 963                               gnus-post-method))
 964         (group-method (gnus-find-method-for-group group)))
 965     (cond
 966      ;; If the group-method is nil (which shouldn't happen) we use
 967      ;; the default method.
 968      ((null group-method)
 969       (or (and (listp gnus-post-method) ;If not current/native/nil
 970                (not (listp (car gnus-post-method))) ; and not a list of methods
 971                gnus-post-method)        ;then use it.
 972           gnus-select-method
 973           message-post-method))
 974      ;; We want the inverse of the default
 975      ((and arg (not (eq arg 0)))
 976       (if (eq gnus-post-method 'current)
 977           gnus-select-method
 978         group-method))
 979      ;; We query the user for a post method.
 980      ((or arg
 981           (and (listp gnus-post-method)
 982                (listp (car gnus-post-method))))
 983       (let* ((methods
 984               ;; Collect all methods we know about.
 985               (append
 986                (when (listp gnus-post-method)
 987                  (if (listp (car gnus-post-method))
 988                      gnus-post-method
 989                    (list gnus-post-method)))
 990                gnus-secondary-select-methods
 991                (mapcar 'cdr gnus-server-alist)
 992                (mapcar 'car gnus-opened-servers)
 993                (list gnus-select-method)
 994                (list group-method)))
 995              method-alist post-methods method)
 996         ;; Weed out all mail methods.
 997         (while methods
 998           (setq method (gnus-server-get-method "" (pop methods)))
 999           (when (and (or (gnus-method-option-p method 'post)
1000                          (gnus-method-option-p method 'post-mail))
1001                      (not (member method post-methods)))
1002             (push method post-methods)))
1003         ;; Create a name-method alist.
1004         (setq method-alist
1005               (mapcar
1006                (lambda (m)
1007                  (if (equal (cadr m) "")
1008                      (list (symbol-name (car m)) m)
1009                    (list (concat (cadr m) " (" (symbol-name (car m)) ")") m)))
1010                post-methods))
1011         ;; Query the user.
1012         (cadr
1013          (assoc
1014           (setq gnus-last-posting-server
1015                 (if (and silent
1016                          gnus-last-posting-server)
1017                     ;; Just use the last value.
1018                     gnus-last-posting-server
1019                   (completing-read
1020                    "Posting method: " method-alist nil t
1021                    (cons (or gnus-last-posting-server "") 0))))
1022           method-alist))))
1023      ;; Override normal method.
1024      ((and (eq gnus-post-method 'current)
1025            (not (memq (car group-method) gnus-discouraged-post-methods))
1026            (gnus-get-function group-method 'request-post t))
1027       (assert (not arg))
1028       group-method)
1029      ;; Use gnus-post-method.
1030      ((listp gnus-post-method)          ;A method...
1031       (assert (not (listp (car gnus-post-method)))) ;... not a list of methods.
1032       gnus-post-method)
1033      ;; Use the normal select method (nil or native).
1034      (t gnus-select-method))))
1035
1036 \f
1037
1038 (defun gnus-extended-version ()
1039   "Stringified Gnus version and Emacs version.
1040 See the variable `gnus-user-agent'."
1041   (interactive)
1042   (let* ((float-output-format nil)
1043          (gnus-v
1044           (concat "Gnus/"
1045                   (prin1-to-string (gnus-continuum-version gnus-version) t)
1046                   " (" gnus-version ")"))
1047          (emacs-v (gnus-emacs-version)))
1048     (if (stringp gnus-user-agent)
1049         gnus-user-agent
1050       (concat gnus-v
1051               (when emacs-v
1052                 (concat " " emacs-v))))))
1053
1054 \f
1055 ;;;
1056 ;;; Gnus Mail Functions
1057 ;;;
1058
1059 ;;; Mail reply commands of Gnus summary mode
1060
1061 (defun gnus-summary-reply (&optional yank wide very-wide)
1062   "Start composing a mail reply to the current message.
1063 If prefix argument YANK is non-nil, the original article is yanked
1064 automatically.
1065 If WIDE, make a wide reply.
1066 If VERY-WIDE, make a very wide reply."
1067   (interactive
1068    (list (and current-prefix-arg
1069               (gnus-summary-work-articles 1))))
1070   ;; Allow user to require confirmation before replying by mail to the
1071   ;; author of a news article (or mail message).
1072   (when (or
1073             (not (or (gnus-news-group-p gnus-newsgroup-name)
1074                      gnus-confirm-treat-mail-like-news))
1075             (not (cond ((stringp gnus-confirm-mail-reply-to-news)
1076                         (string-match gnus-confirm-mail-reply-to-news
1077                                       gnus-newsgroup-name))
1078                        ((functionp gnus-confirm-mail-reply-to-news)
1079                         (funcall gnus-confirm-mail-reply-to-news gnus-newsgroup-name))
1080                        (t gnus-confirm-mail-reply-to-news)))
1081             (y-or-n-p "Really reply by mail to article author? "))
1082     (let* ((article
1083             (if (listp (car yank))
1084                 (caar yank)
1085               (car yank)))
1086            (gnus-article-reply (or article (gnus-summary-article-number)))
1087            (gnus-article-yanked-articles yank)
1088            (headers ""))
1089       ;; Stripping headers should be specified with mail-yank-ignored-headers.
1090       (when yank
1091         (gnus-summary-goto-subject article))
1092       (gnus-setup-message (if yank 'reply-yank 'reply)
1093         (if (not very-wide)
1094             (gnus-summary-select-article)
1095           (dolist (article very-wide)
1096             (gnus-summary-select-article nil nil nil article)
1097             (save-excursion
1098               (set-buffer (gnus-copy-article-buffer))
1099               (gnus-msg-treat-broken-reply-to)
1100               (save-restriction
1101                 (message-narrow-to-head)
1102                 (setq headers (concat headers (buffer-string)))))))
1103         (set-buffer (gnus-copy-article-buffer))
1104         (gnus-msg-treat-broken-reply-to gnus-msg-force-broken-reply-to)
1105         (save-restriction
1106           (message-narrow-to-head)
1107           (when very-wide
1108             (erase-buffer)
1109             (insert headers))
1110           (goto-char (point-max)))
1111         (mml-quote-region (point) (point-max))
1112         (message-reply nil wide)
1113         (when yank
1114           (gnus-inews-yank-articles yank))
1115         (gnus-summary-handle-replysign)))))
1116
1117 (defun gnus-summary-handle-replysign ()
1118   "Check the various replysign variables and take action accordingly."
1119   (when (or gnus-message-replysign gnus-message-replyencrypt)
1120     (let (signed encrypted)
1121       (save-excursion
1122         (set-buffer gnus-article-buffer)
1123         (setq signed (memq 'signed gnus-article-wash-types))
1124         (setq encrypted (memq 'encrypted gnus-article-wash-types)))
1125       (cond ((and gnus-message-replyencrypt encrypted)
1126              (mml-secure-message mml-default-encrypt-method
1127                                  (if gnus-message-replysignencrypted
1128                                      'signencrypt
1129                                    'encrypt)))
1130             ((and gnus-message-replysign signed)
1131              (mml-secure-message mml-default-sign-method 'sign))))))
1132
1133 (defun gnus-summary-reply-with-original (n &optional wide)
1134   "Start composing a reply mail to the current message.
1135 The original article will be yanked."
1136   (interactive "P")
1137   (gnus-summary-reply (gnus-summary-work-articles n) wide))
1138
1139 (defun gnus-summary-reply-broken-reply-to (&optional yank wide very-wide)
1140   "Like `gnus-summary-reply' except removing reply-to field.
1141 If prefix argument YANK is non-nil, the original article is yanked
1142 automatically.
1143 If WIDE, make a wide reply.
1144 If VERY-WIDE, make a very wide reply."
1145   (interactive
1146    (list (and current-prefix-arg
1147               (gnus-summary-work-articles 1))))
1148   (let ((gnus-msg-force-broken-reply-to t))
1149     (gnus-summary-reply yank wide very-wide)))
1150
1151 (defun gnus-summary-reply-broken-reply-to-with-original (n &optional wide)
1152   "Like `gnus-summary-reply-with-original' except removing reply-to field.
1153 The original article will be yanked."
1154   (interactive "P")
1155   (gnus-summary-reply-broken-reply-to (gnus-summary-work-articles n) wide))
1156
1157 (defun gnus-summary-wide-reply (&optional yank)
1158   "Start composing a wide reply mail to the current message.
1159 If prefix argument YANK is non-nil, the original article is yanked
1160 automatically."
1161   (interactive
1162    (list (and current-prefix-arg
1163               (gnus-summary-work-articles 1))))
1164   (gnus-summary-reply yank t))
1165
1166 (defun gnus-summary-wide-reply-with-original (n)
1167   "Start composing a wide reply mail to the current message.
1168 The original article will be yanked.
1169 Uses the process/prefix convention."
1170   (interactive "P")
1171   (gnus-summary-reply-with-original n t))
1172
1173 (defun gnus-summary-very-wide-reply (&optional yank)
1174   "Start composing a very wide reply mail to the current message.
1175 If prefix argument YANK is non-nil, the original article is yanked
1176 automatically."
1177   (interactive
1178    (list (and current-prefix-arg
1179               (gnus-summary-work-articles 1))))
1180   (gnus-summary-reply yank t (gnus-summary-work-articles yank)))
1181
1182 (defun gnus-summary-very-wide-reply-with-original (n)
1183   "Start composing a very wide reply mail to the current message.
1184 The original article will be yanked."
1185   (interactive "P")
1186   (gnus-summary-reply
1187    (gnus-summary-work-articles n) t (gnus-summary-work-articles n)))
1188
1189 (defun gnus-summary-mail-forward (&optional arg post)
1190   "Forward the current message(s) to another user.
1191 If process marks exist, forward all marked messages;
1192 if ARG is nil, see `message-forward-as-mime' and `message-forward-show-mml';
1193 if ARG is 1, decode the message and forward directly inline;
1194 if ARG is 2, forward message as an rfc822 MIME section;
1195 if ARG is 3, decode message and forward as an rfc822 MIME section;
1196 if ARG is 4, forward message directly inline;
1197 otherwise, use flipped `message-forward-as-mime'.
1198 If POST, post instead of mail.
1199 For the `inline' alternatives, also see the variable
1200 `message-forward-ignored-headers'."
1201   (interactive "P")
1202   (if (cdr (gnus-summary-work-articles nil))
1203       ;; Process marks are given.
1204       (gnus-uu-digest-mail-forward arg post)
1205     ;; No process marks.
1206     (let ((message-forward-as-mime message-forward-as-mime)
1207           (message-forward-show-mml message-forward-show-mml))
1208       (cond
1209        ((null arg))
1210        ((eq arg 1)
1211         (setq message-forward-as-mime nil
1212               message-forward-show-mml t))
1213        ((eq arg 2)
1214         (setq message-forward-as-mime t
1215               message-forward-show-mml nil))
1216        ((eq arg 3)
1217         (setq message-forward-as-mime t
1218               message-forward-show-mml t))
1219        ((eq arg 4)
1220         (setq message-forward-as-mime nil
1221               message-forward-show-mml nil))
1222        (t
1223         (setq message-forward-as-mime (not message-forward-as-mime))))
1224       (let* ((gnus-article-reply (gnus-summary-article-number))
1225              (gnus-article-yanked-articles (list gnus-article-reply)))
1226         (gnus-setup-message 'forward
1227           (gnus-summary-select-article)
1228           (let ((mail-parse-charset
1229                  (or (and (gnus-buffer-live-p gnus-article-buffer)
1230                           (with-current-buffer gnus-article-buffer
1231                             gnus-article-charset))
1232                      gnus-newsgroup-charset))
1233                 (mail-parse-ignored-charsets
1234                  gnus-newsgroup-ignored-charsets))
1235             (set-buffer gnus-original-article-buffer)
1236             (message-forward post)))))))
1237
1238 (defun gnus-summary-resend-message (address n)
1239   "Resend the current article to ADDRESS."
1240   (interactive
1241    (list (message-read-from-minibuffer
1242           "Resend message(s) to: "
1243           (when (and gnus-summary-resend-default-address
1244                      (gnus-buffer-live-p gnus-original-article-buffer))
1245             ;; If some other article is currently selected, the
1246             ;; initial-contents is wrong. Whatever, it is just the
1247             ;; initial-contents.
1248             (with-current-buffer gnus-original-article-buffer
1249               (nnmail-fetch-field "to"))))
1250          current-prefix-arg))
1251   (let ((articles (gnus-summary-work-articles n))
1252         article)
1253     (while (setq article (pop articles))
1254       (gnus-summary-select-article nil nil nil article)
1255       (save-excursion
1256         (set-buffer gnus-original-article-buffer)
1257         (message-resend address))
1258       (gnus-summary-mark-article-as-forwarded article))))
1259
1260 ;; From: Matthieu Moy <Matthieu.Moy@imag.fr>
1261 (defun gnus-summary-resend-message-edit ()
1262   "Resend an article that has already been sent.
1263 A new buffer will be created to allow the user to modify body and
1264 contents of the message, and then, everything will happen as when
1265 composing a new message."
1266   (interactive)
1267   (let ((article (gnus-summary-article-number)))
1268     (gnus-setup-message 'reply-yank
1269       (gnus-summary-select-article t)
1270       (set-buffer gnus-original-article-buffer)
1271       (let ((cur (current-buffer))
1272             (to (message-fetch-field "to")))
1273         ;; Get a normal message buffer.
1274         (message-pop-to-buffer (message-buffer-name "Resend" to))
1275         (insert-buffer-substring cur)
1276         (mime-to-mml)
1277         (message-narrow-to-head-1)
1278         ;; Gnus will generate a new one when sending.
1279         (message-remove-header "Message-ID")
1280         (message-remove-header message-ignored-resent-headers t)
1281         ;; Remove unwanted headers.
1282         (goto-char (point-max))
1283         (insert mail-header-separator)
1284         (goto-char (point-min))
1285         (when (re-search-forward "^To:\\|^Newsgroups:" nil 'move)
1286           (forward-char 1))
1287         (widen)))))
1288
1289 (defun gnus-summary-post-forward (&optional arg)
1290   "Forward the current article to a newsgroup.
1291 See `gnus-summary-mail-forward' for ARG."
1292   (interactive "P")
1293   (gnus-summary-mail-forward arg t))
1294
1295 (defvar gnus-nastygram-message
1296   "The following article was inappropriately posted to %s.\n\n"
1297   "Format string to insert in nastygrams.
1298 The current group name will be inserted at \"%s\".")
1299
1300 (defun gnus-summary-mail-nastygram (n)
1301   "Send a nastygram to the author of the current article."
1302   (interactive "P")
1303   (when (or gnus-expert-user
1304             (gnus-y-or-n-p
1305              "Really send a nastygram to the author of the current article? "))
1306     (let ((group gnus-newsgroup-name))
1307       (gnus-summary-reply-with-original n)
1308       (set-buffer gnus-message-buffer)
1309       (message-goto-body)
1310       (insert (format gnus-nastygram-message group))
1311       (message-send-and-exit))))
1312
1313 (defun gnus-summary-mail-crosspost-complaint (n)
1314   "Send a complaint about crossposting to the current article(s)."
1315   (interactive "P")
1316   (let ((articles (gnus-summary-work-articles n))
1317         article)
1318     (while (setq article (pop articles))
1319       (set-buffer gnus-summary-buffer)
1320       (gnus-summary-goto-subject article)
1321       (let ((group (gnus-group-real-name gnus-newsgroup-name))
1322             newsgroups followup-to)
1323         (gnus-summary-select-article)
1324         (set-buffer gnus-original-article-buffer)
1325         (if (and (<= (length (message-tokenize-header
1326                               (setq newsgroups
1327                                     (mail-fetch-field "newsgroups"))
1328                               ", "))
1329                      1)
1330                  (or (not (setq followup-to (mail-fetch-field "followup-to")))
1331                      (not (member group (message-tokenize-header
1332                                          followup-to ", ")))))
1333             (if followup-to
1334                 (gnus-message 1 "Followup-to restricted")
1335               (gnus-message 1 "Not a crossposted article"))
1336           (set-buffer gnus-summary-buffer)
1337           (gnus-summary-reply-with-original 1)
1338           (set-buffer gnus-message-buffer)
1339           (message-goto-body)
1340           (insert (format gnus-crosspost-complaint newsgroups group))
1341           (message-goto-subject)
1342           (re-search-forward " *$")
1343           (replace-match " (crosspost notification)" t t)
1344           (gnus-deactivate-mark)
1345           (when (gnus-y-or-n-p "Send this complaint? ")
1346             (message-send-and-exit)))))))
1347
1348 (defun gnus-mail-parse-comma-list ()
1349   (let (accumulated
1350         beg)
1351     (skip-chars-forward " ")
1352     (while (not (eobp))
1353       (setq beg (point))
1354       (skip-chars-forward "^,")
1355       (while (zerop
1356               (save-excursion
1357                 (save-restriction
1358                   (let ((i 0))
1359                     (narrow-to-region beg (point))
1360                     (goto-char beg)
1361                     (logand (progn
1362                               (while (search-forward "\"" nil t)
1363                                 (incf i))
1364                               (if (zerop i) 2 i))
1365                             2)))))
1366         (skip-chars-forward ",")
1367         (skip-chars-forward "^,"))
1368       (skip-chars-backward " ")
1369       (push (buffer-substring beg (point))
1370             accumulated)
1371       (skip-chars-forward "^,")
1372       (skip-chars-forward ", "))
1373     accumulated))
1374
1375 (defun gnus-inews-add-to-address (group)
1376   (let ((to-address (mail-fetch-field "to")))
1377     (when (and to-address
1378                (gnus-alive-p))
1379       ;; This mail group doesn't have a `to-list', so we add one
1380       ;; here.  Magic!
1381       (when (gnus-y-or-n-p
1382              (format "Do you want to add this as `to-list': %s? " to-address))
1383         (gnus-group-add-parameter group (cons 'to-list to-address))))))
1384
1385 (defun gnus-put-message ()
1386   "Put the current message in some group and return to Gnus."
1387   (interactive)
1388   (let ((reply gnus-article-reply)
1389         (winconf gnus-prev-winconf)
1390         (group gnus-newsgroup-name))
1391     (unless (and group
1392                  (not (gnus-group-read-only-p group)))
1393       (setq group (read-string "Put in group: " nil (gnus-writable-groups))))
1394
1395     (when (gnus-group-entry group)
1396       (error "No such group: %s" group))
1397     (save-excursion
1398       (save-restriction
1399         (widen)
1400         (message-narrow-to-headers)
1401         (let ((gnus-deletable-headers nil))
1402           (message-generate-headers
1403            (if (message-news-p)
1404                message-required-news-headers
1405              message-required-mail-headers)))
1406         (goto-char (point-max))
1407         (if (string-match " " group)
1408             (insert "Gcc: \"" group "\"\n")
1409           (insert "Gcc: " group "\n"))
1410         (widen)))
1411     (gnus-inews-do-gcc)
1412     (when (and (get-buffer gnus-group-buffer)
1413                (gnus-buffer-exists-p (car-safe reply))
1414                (cdr reply))
1415       (set-buffer (car reply))
1416       (gnus-summary-mark-article-as-replied (cdr reply)))
1417     (when winconf
1418       (set-window-configuration winconf))))
1419
1420 (defun gnus-article-mail (yank)
1421   "Send a reply to the address near point.
1422 If YANK is non-nil, include the original article."
1423   (interactive "P")
1424   (let ((address
1425          (buffer-substring
1426           (save-excursion (re-search-backward "[ \t\n]" nil t) (1+ (point)))
1427           (save-excursion (re-search-forward "[ \t\n]" nil t) (1- (point))))))
1428     (when address
1429       (gnus-msg-mail address)
1430       (when yank
1431         (gnus-inews-yank-articles (list (cdr gnus-article-current)))))))
1432
1433 (defvar nntp-server-type)
1434 (defun gnus-bug ()
1435   "Send a bug report to the Gnus maintainers."
1436   (interactive)
1437   (unless (gnus-alive-p)
1438     (error "Gnus has been shut down"))
1439   (gnus-setup-message (if (message-mail-user-agent) 'message 'bug)
1440     (unless (message-mail-user-agent)
1441       (delete-other-windows)
1442       (when gnus-bug-create-help-buffer
1443         (switch-to-buffer "*Gnus Help Bug*")
1444         (erase-buffer)
1445         (insert gnus-bug-message)
1446         (goto-char (point-min)))
1447       (message-pop-to-buffer "*Gnus Bug*"))
1448     (let ((message-this-is-mail t))
1449       (message-setup `((To . ,gnus-maintainer) (Subject . ""))))
1450     (when gnus-bug-create-help-buffer
1451       (push `(gnus-bug-kill-buffer) message-send-actions))
1452     (goto-char (point-min))
1453     (re-search-forward (concat "^" (regexp-quote mail-header-separator) "$"))
1454     (forward-line 1)
1455     (insert (gnus-version) "\n"
1456             (emacs-version) "\n")
1457     (when (and (boundp 'nntp-server-type)
1458                (stringp nntp-server-type))
1459       (insert nntp-server-type))
1460     (insert "\n\n\n\n\n")
1461     (let (text)
1462       (save-excursion
1463         (set-buffer (gnus-get-buffer-create " *gnus environment info*"))
1464         (erase-buffer)
1465         (gnus-debug)
1466         (setq text (buffer-string)))
1467       (insert "<#part type=application/emacs-lisp disposition=inline description=\"User settings\">\n" text "\n<#/part>"))
1468     (goto-char (point-min))
1469     (search-forward "Subject: " nil t)
1470     (message "")))
1471
1472 (defun gnus-bug-kill-buffer ()
1473   (when (get-buffer "*Gnus Help Bug*")
1474     (kill-buffer "*Gnus Help Bug*")))
1475
1476 (defun gnus-summary-yank-message (buffer n)
1477   "Yank the current article into a composed message."
1478   (interactive
1479    (list (completing-read "Buffer: " (mapcar 'list (message-buffers)) nil t)
1480          current-prefix-arg))
1481   (gnus-summary-iterate n
1482     (let ((gnus-inhibit-treatment t))
1483       (gnus-summary-select-article))
1484     (save-excursion
1485       (set-buffer buffer)
1486       (message-yank-buffer gnus-article-buffer))))
1487
1488 (defun gnus-debug ()
1489   "Attempts to go through the Gnus source file and report what variables have been changed.
1490 The source file has to be in the Emacs load path."
1491   (interactive)
1492   (let ((files gnus-debug-files)
1493         (point (point))
1494         file expr olist sym)
1495     (gnus-message 4 "Please wait while we snoop your variables...")
1496     (sit-for 0)
1497     ;; Go through all the files looking for non-default values for variables.
1498     (save-excursion
1499       (set-buffer (gnus-get-buffer-create " *gnus bug info*"))
1500       (while files
1501         (erase-buffer)
1502         (when (and (setq file (locate-library (pop files)))
1503                    (file-exists-p file))
1504           (insert-file-contents file)
1505           (goto-char (point-min))
1506           (if (not (re-search-forward "^;;* *Internal variables" nil t))
1507               (gnus-message 4 "Malformed sources in file %s" file)
1508             (narrow-to-region (point-min) (point))
1509             (goto-char (point-min))
1510             (while (setq expr (ignore-errors (read (current-buffer))))
1511               (ignore-errors
1512                 (and (or (eq (car expr) 'defvar)
1513                          (eq (car expr) 'defcustom))
1514                      (stringp (nth 3 expr))
1515                      (not (memq (nth 1 expr) gnus-debug-exclude-variables))
1516                      (or (not (boundp (nth 1 expr)))
1517                          (not (equal (eval (nth 2 expr))
1518                                      (symbol-value (nth 1 expr)))))
1519                      (push (nth 1 expr) olist)))))))
1520       (kill-buffer (current-buffer)))
1521     (when (setq olist (nreverse olist))
1522       (insert "------------------ Environment follows ------------------\n\n"))
1523     (while olist
1524       (if (boundp (car olist))
1525           (ignore-errors
1526            (gnus-pp
1527             `(setq ,(car olist)
1528                    ,(if (or (consp (setq sym (symbol-value (car olist))))
1529                             (and (symbolp sym)
1530                                  (not (or (eq sym nil)
1531                                           (eq sym t)))))
1532                         (list 'quote (symbol-value (car olist)))
1533                       (symbol-value (car olist))))))
1534         (insert ";; (makeunbound '" (symbol-name (car olist)) ")\n"))
1535       (setq olist (cdr olist)))
1536     (insert "\n\n")
1537     ;; Remove any control chars - they seem to cause trouble for some
1538     ;; mailers.  (Byte-compiled output from the stuff above.)
1539     (goto-char point)
1540     (while (re-search-forward "[\000-\010\013-\037\200-\237]" nil t)
1541       (replace-match (format "\\%03o" (string-to-char (match-string 0)))
1542                      t t))))
1543
1544 ;;; Treatment of rejected articles.
1545 ;;; Bounced mail.
1546
1547 (defun gnus-summary-resend-bounced-mail (&optional fetch)
1548   "Re-mail the current message.
1549 This only makes sense if the current message is a bounce message that
1550 contains some mail you have written which has been bounced back to
1551 you.
1552 If FETCH, try to fetch the article that this is a reply to, if indeed
1553 this is a reply."
1554   (interactive "P")
1555   (gnus-summary-select-article t)
1556   (set-buffer gnus-original-article-buffer)
1557   (gnus-setup-message 'compose-bounce
1558     (let* ((references (mail-fetch-field "references"))
1559            (parent (and references (gnus-parent-id references))))
1560       (message-bounce)
1561       ;; If there are references, we fetch the article we answered to.
1562       (and fetch parent
1563            (gnus-summary-refer-article parent)
1564            (gnus-summary-show-all-headers)))))
1565
1566 ;;; Gcc handling.
1567
1568 (defun gnus-inews-group-method (group)
1569   (cond
1570    ;; If the group doesn't exist, we assume
1571    ;; it's an archive group...
1572    ((and (null (gnus-get-info group))
1573          (eq (car (gnus-server-to-method gnus-message-archive-method))
1574              (car (gnus-server-to-method (gnus-group-method group)))))
1575     gnus-message-archive-method)
1576    ;; Use the method.
1577    ((gnus-info-method (gnus-get-info group))
1578     (gnus-info-method (gnus-get-info group)))
1579    ;; Find the method.
1580    (t (gnus-server-to-method (gnus-group-method group)))))
1581
1582 ;; Do Gcc handling, which copied the message over to some group.
1583 (defun gnus-inews-do-gcc (&optional gcc)
1584   (interactive)
1585   (save-excursion
1586     (save-restriction
1587       (message-narrow-to-headers)
1588       (let ((gcc (or gcc (mail-fetch-field "gcc" nil t)))
1589             (cur (current-buffer))
1590             groups group method group-art
1591             mml-externalize-attachments)
1592         (when gcc
1593           (message-remove-header "gcc")
1594           (widen)
1595           (setq groups (message-unquote-tokens
1596                         (message-tokenize-header gcc " ,")))
1597           ;; Copy the article over to some group(s).
1598           (while (setq group (pop groups))
1599             (unless (gnus-check-server
1600                      (setq method (gnus-inews-group-method group)))
1601               (error "Can't open server %s" (if (stringp method) method
1602                                               (car method))))
1603             (unless (gnus-request-group group nil method)
1604               (gnus-request-create-group group method))
1605             (setq mml-externalize-attachments
1606                   (if (stringp gnus-gcc-externalize-attachments)
1607                       (string-match gnus-gcc-externalize-attachments group)
1608                     gnus-gcc-externalize-attachments))
1609             (save-excursion
1610               (nnheader-set-temp-buffer " *acc*")
1611               (insert-buffer-substring cur)
1612               (message-encode-message-body)
1613               (save-restriction
1614                 (message-narrow-to-headers)
1615                 (let* ((mail-parse-charset message-default-charset)
1616                        (newsgroups-field (save-restriction
1617                                            (message-narrow-to-headers-or-head)
1618                                            (message-fetch-field "Newsgroups")))
1619                        (followup-field (save-restriction
1620                                          (message-narrow-to-headers-or-head)
1621                                          (message-fetch-field "Followup-To")))
1622                        ;; BUG: We really need to get the charset for
1623                        ;; each name in the Newsgroups and Followup-To
1624                        ;; lines to allow crossposting between group
1625                        ;; namess with incompatible character sets.
1626                        ;; -- Per Abrahamsen <abraham@dina.kvl.dk> 2001-10-08.
1627                        (group-field-charset
1628                         (gnus-group-name-charset
1629                          method (or newsgroups-field "")))
1630                        (followup-field-charset
1631                         (gnus-group-name-charset
1632                          method (or followup-field "")))
1633                        (rfc2047-header-encoding-alist
1634                         (append
1635                          (when group-field-charset
1636                            (list (cons "Newsgroups" group-field-charset)))
1637                          (when followup-field-charset
1638                            (list (cons "Followup-To" followup-field-charset)))
1639                          rfc2047-header-encoding-alist)))
1640                   (mail-encode-encoded-word-buffer)))
1641               (goto-char (point-min))
1642               (when (re-search-forward
1643                      (concat "^" (regexp-quote mail-header-separator) "$")
1644                      nil t)
1645                 (replace-match "" t t ))
1646               (when (or (not (gnus-check-backend-function
1647                               'request-accept-article group))
1648                         (not (setq group-art
1649                                    (gnus-request-accept-article
1650                                     group method t t))))
1651                 (gnus-message 1 "Couldn't store article in group %s: %s"
1652                               group (gnus-status-message method)))
1653               (when (and group-art
1654                          ;; FIXME: Should gcc-mark-as-read work when
1655                          ;; Gnus is not running?
1656                          (gnus-alive-p)
1657                          (or gnus-gcc-mark-as-read
1658                              (and
1659                               (boundp 'gnus-inews-mark-gcc-as-read)
1660                               (symbol-value 'gnus-inews-mark-gcc-as-read))))
1661                 (gnus-group-mark-article-read group (cdr group-art)))
1662               (kill-buffer (current-buffer)))))))))
1663
1664 (defun gnus-inews-insert-gcc ()
1665   "Insert Gcc headers based on `gnus-outgoing-message-group'."
1666   (save-excursion
1667     (save-restriction
1668       (message-narrow-to-headers)
1669       (let* ((group gnus-outgoing-message-group)
1670              (gcc (cond
1671                    ((functionp group)
1672                     (funcall group))
1673                    ((or (stringp group) (list group))
1674                     group))))
1675         (when gcc
1676           (insert "Gcc: "
1677                   (if (stringp gcc)
1678                       (if (string-match " " gcc)
1679                           (concat "\"" gcc "\"")
1680                         gcc)
1681                     (mapconcat (lambda (group)
1682                                  (if (string-match " " group)
1683                                      (concat "\"" group "\"")
1684                                    group))
1685                                gcc " "))
1686                   "\n"))))))
1687
1688 (defun gnus-inews-insert-archive-gcc (&optional group)
1689   "Insert the Gcc to say where the article is to be archived."
1690   (let* ((var gnus-message-archive-group)
1691          (group (or group gnus-newsgroup-name ""))
1692          (gcc-self-val
1693           (and gnus-newsgroup-name
1694                (not (equal gnus-newsgroup-name ""))
1695                (gnus-group-find-parameter
1696                 gnus-newsgroup-name 'gcc-self)))
1697          result
1698          (groups
1699           (cond
1700            ((null gnus-message-archive-method)
1701             ;; Ignore.
1702             nil)
1703            ((stringp var)
1704             ;; Just a single group.
1705             (list var))
1706            ((null var)
1707             ;; We don't want this.
1708             nil)
1709            ((and (listp var) (stringp (car var)))
1710             ;; A list of groups.
1711             var)
1712            ((functionp var)
1713             ;; A function.
1714             (funcall var group))
1715            (t
1716             ;; An alist of regexps/functions/forms.
1717             (while (and var
1718                         (not
1719                          (setq result
1720                                (cond
1721                                 ((stringp (caar var))
1722                                  ;; Regexp.
1723                                  (when (string-match (caar var) group)
1724                                    (cdar var)))
1725                                 ((functionp (car var))
1726                                  ;; Function.
1727                                  (funcall (car var) group))
1728                                 (t
1729                                  (eval (car var)))))))
1730               (setq var (cdr var)))
1731             result)))
1732          name)
1733     (when (or groups gcc-self-val)
1734       (when (stringp groups)
1735         (setq groups (list groups)))
1736       (save-excursion
1737         (save-restriction
1738           (message-narrow-to-headers)
1739           (goto-char (point-max))
1740           (insert "Gcc: ")
1741           (if gcc-self-val
1742               ;; Use the `gcc-self' param value instead.
1743               (progn
1744                 (insert
1745                  (if (stringp gcc-self-val)
1746                      (if (string-match " " gcc-self-val)
1747                          (concat "\"" gcc-self-val "\"")
1748                        gcc-self-val)
1749                    ;; In nndoc groups, we use the parent group name
1750                    ;; instead of the current group.
1751                    (let ((group (or (gnus-group-find-parameter
1752                                      gnus-newsgroup-name 'parent-group)
1753                                     group)))
1754                      (if (string-match " " group)
1755                          (concat "\"" group "\"")
1756                        group))))
1757                 (if (not (eq gcc-self-val 'none))
1758                     (insert "\n")
1759                   (gnus-delete-line)))
1760             ;; Use the list of groups.
1761             (while (setq name (pop groups))
1762               (let ((str (if (string-match ":" name)
1763                              name
1764                            (gnus-group-prefixed-name
1765                             name gnus-message-archive-method))))
1766                 (insert (if (string-match " " str)
1767                             (concat "\"" str "\"")
1768                           str)))
1769               (when groups
1770                 (insert " ")))
1771             (insert "\n")))))))
1772
1773 (defun gnus-mailing-list-followup-to ()
1774   "Look at the headers in the current buffer and return a Mail-Followup-To address."
1775   (let ((x-been-there (gnus-fetch-original-field "x-beenthere"))
1776         (list-post (gnus-fetch-original-field "list-post")))
1777     (when (and list-post
1778                (string-match "mailto:\\([^>]+\\)" list-post))
1779       (setq list-post (match-string 1 list-post)))
1780     (or list-post
1781         x-been-there)))
1782
1783 ;;; Posting styles.
1784
1785 (defun gnus-configure-posting-styles (&optional group-name)
1786   "Configure posting styles according to `gnus-posting-styles'."
1787   (unless gnus-inhibit-posting-styles
1788     (let ((group (or group-name gnus-newsgroup-name ""))
1789           (styles gnus-posting-styles)
1790           style match attribute value v results
1791           filep name address element)
1792       ;; If the group has a posting-style parameter, add it at the end with a
1793       ;; regexp matching everything, to be sure it takes precedence over all
1794       ;; the others.
1795       (when gnus-newsgroup-name
1796         (let ((tmp-style (gnus-group-find-parameter group 'posting-style t)))
1797           (when tmp-style
1798             (setq styles (append styles (list (cons ".*" tmp-style)))))))
1799       ;; Go through all styles and look for matches.
1800       (dolist (style styles)
1801         (setq match (pop style))
1802         (goto-char (point-min))
1803         (when (cond
1804                ((stringp match)
1805                 ;; Regexp string match on the group name.
1806                 (string-match match group))
1807                ((eq match 'header)
1808                 ;; Obsolete format of header match.
1809                 (and (gnus-buffer-live-p gnus-article-copy)
1810                      (with-current-buffer gnus-article-copy
1811                        (let ((header (message-fetch-field (pop style))))
1812                          (and header
1813                               (string-match (pop style) header))))))
1814                ((or (symbolp match)
1815                     (functionp match))
1816                 (cond
1817                  ((functionp match)
1818                   ;; Function to be called.
1819                   (funcall match))
1820                  ((boundp match)
1821                   ;; Variable to be checked.
1822                   (symbol-value match))))
1823                ((listp match)
1824                 (cond
1825                  ((eq (car match) 'header)
1826                   ;; New format of header match.
1827                   (and (gnus-buffer-live-p gnus-article-copy)
1828                        (with-current-buffer gnus-article-copy
1829                          (let ((header (message-fetch-field (nth 1 match))))
1830                            (and header
1831                                 (string-match (nth 2 match) header))))))
1832                  (t
1833                   ;; This is a form to be evaled.
1834                   (eval match)))))
1835           ;; We have a match, so we set the variables.
1836           (dolist (attribute style)
1837             (setq element (pop attribute)
1838                   filep nil)
1839             (setq value
1840                   (cond
1841                    ((eq (car attribute) :file)
1842                     (setq filep t)
1843                     (cadr attribute))
1844                    ((eq (car attribute) :value)
1845                     (cadr attribute))
1846                    (t
1847                     (car attribute))))
1848             ;; We get the value.
1849             (setq v
1850                   (cond
1851                    ((stringp value)
1852                     value)
1853                    ((or (symbolp value)
1854                         (functionp value))
1855                     (cond ((functionp value)
1856                            (funcall value))
1857                           ((boundp value)
1858                            (symbol-value value))))
1859                    ((listp value)
1860                     (eval value))))
1861             ;; Translate obsolescent value.
1862             (cond
1863              ((eq element 'signature-file)
1864               (setq element 'signature
1865                     filep t))
1866              ((eq element 'x-face-file)
1867               (setq element 'x-face
1868                     filep t)))
1869             ;; Get the contents of file elems.
1870             (when (and filep v)
1871               (setq v (with-temp-buffer
1872                         (insert-file-contents v)
1873                         (goto-char (point-max))
1874                         (while (bolp)
1875                           (delete-char -1))
1876                         (buffer-string))))
1877             (setq results (delq (assoc element results) results))
1878             (push (cons element v) results))))
1879       ;; Now we have all the styles, so we insert them.
1880       (setq name (assq 'name results)
1881             address (assq 'address results))
1882       (setq results (delq name (delq address results)))
1883       (gnus-make-local-hook 'message-setup-hook)
1884       (setq results (sort results (lambda (x y)
1885                                     (string-lessp (car x) (car y)))))
1886       (dolist (result results)
1887         (add-hook 'message-setup-hook
1888                   (cond
1889                    ((eq 'eval (car result))
1890                     'ignore)
1891                    ((eq 'body (car result))
1892                     `(lambda ()
1893                        (save-excursion
1894                          (message-goto-body)
1895                          (insert ,(cdr result)))))
1896                    ((eq 'signature (car result))
1897                     (set (make-local-variable 'message-signature) nil)
1898                     (set (make-local-variable 'message-signature-file) nil)
1899                     (if (not (cdr result))
1900                         'ignore
1901                       `(lambda ()
1902                          (save-excursion
1903                            (let ((message-signature ,(cdr result)))
1904                              (when message-signature
1905                                (message-insert-signature)))))))
1906                    (t
1907                     (let ((header
1908                            (if (symbolp (car result))
1909                                (capitalize (symbol-name (car result)))
1910                              (car result))))
1911                       `(lambda ()
1912                          (save-excursion
1913                            (message-remove-header ,header)
1914                            (let ((value ,(cdr result)))
1915                              (when value
1916                                (message-goto-eoh)
1917                                (insert ,header ": " value)
1918                                (unless (bolp)
1919                                  (insert "\n")))))))))
1920                   nil 'local))
1921       (when (or name address)
1922         (add-hook 'message-setup-hook
1923                   `(lambda ()
1924                      (set (make-local-variable 'user-mail-address)
1925                           ,(or (cdr address) user-mail-address))
1926                      (let ((user-full-name ,(or (cdr name) (user-full-name)))
1927                            (user-mail-address
1928                             ,(or (cdr address) user-mail-address)))
1929                        (save-excursion
1930                          (message-remove-header "From")
1931                          (message-goto-eoh)
1932                          (insert "From: " (message-make-from) "\n"))))
1933                   nil 'local)))))
1934
1935 ;;; Allow redefinition of functions.
1936
1937 (gnus-ems-redefine)
1938
1939 (provide 'gnus-msg)
1940
1941 ;;; arch-tag: 9f22b2f5-1c0a-49de-916e-4c88e984852b
1942 ;;; gnus-msg.el ends here