cgit.sxemacs.org Git - gnus/blob - lisp/gnus-msg.el

   1 ;;; gnus-msg.el --- mail and post interface for Gnus
   2 ;; Copyright (C) 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003
   3 ;;        Free Software Foundation, Inc.
   4
   5 ;; Author: Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>
   6 ;;      Lars Magne Ingebrigtsen <larsi@gnus.org>
   7 ;; Keywords: news
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;;; Code:
  29
  30 (eval-when-compile (require 'cl))
  31
  32 (require 'gnus)
  33 (require 'gnus-ems)
  34 (require 'message)
  35 (require 'gnus-art)
  36 (require 'gnus-util)
  37
  38 (defcustom gnus-post-method 'current
  39   "*Preferred method for posting USENET news.
  40
  41 If this variable is `current' (which is the default), Gnus will use
  42 the \"current\" select method when posting.  If it is `native', Gnus
  43 will use the native select method when posting.
  44
  45 This method will not be used in mail groups and the like, only in
  46 \"real\" newsgroups.
  47
  48 If not `native' nor `current', the value must be a valid method as discussed
  49 in the documentation of `gnus-select-method'.  It can also be a list of
  50 methods.  If that is the case, the user will be queried for what select
  51 method to use when posting."
  52   :group 'gnus-group-foreign
  53   :link '(custom-manual "(gnus)Posting Server")
  54   :type `(choice (const native)
  55                  (const current)
  56                  (sexp :tag "Methods" ,gnus-select-method)))
  57
  58 (defcustom gnus-outgoing-message-group nil
  59   "*All outgoing messages will be put in this group.
  60 If you want to store all your outgoing mail and articles in the group
  61 \"nnml:archive\", you set this variable to that value.  This variable
  62 can also be a list of group names.
  63
  64 If you want to have greater control over what group to put each
  65 message in, you can set this variable to a function that checks the
  66 current newsgroup name and then returns a suitable group name (or list
  67 of names)."
  68   :group 'gnus-message
  69   :type '(choice (string :tag "Group")
  70                  (function)))
  71
  72 (defcustom gnus-mailing-list-groups nil
  73   "*If non-nil a regexp matching groups that are really mailing lists.
  74 This is useful when you're reading a mailing list that has been
  75 gatewayed to a newsgroup, and you want to followup to an article in
  76 the group."
  77   :group 'gnus-message
  78   :type '(choice (regexp)
  79                  (const nil)))
  80
  81 (defcustom gnus-add-to-list nil
  82   "*If non-nil, add a `to-list' parameter automatically."
  83   :group 'gnus-message
  84   :type 'boolean)
  85
  86 (defcustom gnus-crosspost-complaint
  87   "Hi,
  88
  89 You posted the article below with the following Newsgroups header:
  90
  91 Newsgroups: %s
  92
  93 The %s group, at least, was an inappropriate recipient
  94 of this message.  Please trim your Newsgroups header to exclude this
  95 group before posting in the future.
  96
  97 Thank you.
  98
  99 "
 100   "Format string to be inserted when complaining about crossposts.
 101 The first %s will be replaced by the Newsgroups header;
 102 the second with the current group name."
 103   :group 'gnus-message
 104   :type 'string)
 105
 106 (defcustom gnus-message-setup-hook nil
 107   "Hook run after setting up a message buffer."
 108   :group 'gnus-message
 109   :type 'hook)
 110
 111 (defcustom gnus-bug-create-help-buffer t
 112   "*Should we create the *Gnus Help Bug* buffer?"
 113   :group 'gnus-message
 114   :type 'boolean)
 115
 116 (defcustom gnus-posting-styles nil
 117   "*Alist of styles to use when posting.
 118 See Info node `(gnus)Posting Styles'."
 119   :group 'gnus-message
 120   :link '(custom-manual "(gnus)Posting Styles")
 121   :type '(repeat (cons (choice (regexp)
 122                                (variable)
 123                                (list (const header)
 124                                      (string :tag "Header")
 125                                      (regexp :tag "Regexp"))
 126                                (function)
 127                                (sexp))
 128                        (repeat (list
 129                                 (choice (const signature)
 130                                         (const signature-file)
 131                                         (const organization)
 132                                         (const address)
 133                                         (const x-face-file)
 134                                         (const name)
 135                                         (const body)
 136                                         (symbol)
 137                                         (string :tag "Header"))
 138                                 (choice (string)
 139                                         (function)
 140                                         (variable)
 141                                         (sexp)))))))
 142
 143 (defcustom gnus-gcc-mark-as-read nil
 144   "If non-nil, automatically mark Gcc articles as read."
 145   :version "21.1"
 146   :group 'gnus-message
 147   :type 'boolean)
 148
 149 (make-obsolete-variable 'gnus-inews-mark-gcc-as-read
 150                         'gnus-gcc-mark-as-read)
 151
 152 (defcustom gnus-gcc-externalize-attachments nil
 153   "Should local-file attachments be included as external parts in Gcc copies?
 154 If it is `all', attach files as external parts;
 155 if a regexp and matches the Gcc group name, attach files as external parts;
 156 if nil, attach files as normal parts."
 157   :version "21.1"
 158   :group 'gnus-message
 159   :type '(choice (const nil :tag "None")
 160                  (const all :tag "Any")
 161                  (string :tag "Regexp")))
 162
 163 (gnus-define-group-parameter
 164  posting-charset-alist
 165  :type list
 166  :function-document
 167  "Return the permitted unencoded charsets for posting of GROUP."
 168  :variable gnus-group-posting-charset-alist
 169  :variable-default
 170   '(("^\\(no\\|fr\\)\\.[^,]*\\(,[ \t\n]*\\(no\\|fr\\)\\.[^,]*\\)*$" iso-8859-1 (iso-8859-1))
 171     ("^\\(fido7\\|relcom\\)\\.[^,]*\\(,[ \t\n]*\\(fido7\\|relcom\\)\\.[^,]*\\)*$" koi8-r (koi8-r))
 172     (message-this-is-mail nil nil)
 173     (message-this-is-news nil t))
 174  :variable-document
 175   "Alist of regexps and permitted unencoded charsets for posting.
 176 Each element of the alist has the form (TEST HEADER BODY-LIST), where
 177 TEST is either a regular expression matching the newsgroup header or a
 178 variable to query,
 179 HEADER is the charset which may be left unencoded in the header (nil
 180 means encode all charsets),
 181 BODY-LIST is a list of charsets which may be encoded using 8bit
 182 content-transfer encoding in the body, or one of the special values
 183 nil (always encode using quoted-printable) or t (always use 8bit).
 184
 185 Note that any value other than nil for HEADER infringes some RFCs, so
 186 use this option with care."
 187  :variable-group gnus-charset
 188  :variable-type
 189  '(repeat (list :tag "Permitted unencoded charsets"
 190                 (choice :tag "Where"
 191                         (regexp :tag "Group")
 192                         (const :tag "Mail message" :value message-this-is-mail)
 193                         (const :tag "News article" :value message-this-is-news))
 194                 (choice :tag "Header"
 195                         (const :tag "None" nil)
 196                         (symbol :tag "Charset"))
 197                 (choice :tag "Body"
 198                         (const :tag "Any" :value t)
 199                         (const :tag "None" :value nil)
 200                         (repeat :tag "Charsets"
 201                                 (symbol :tag "Charset")))))
 202  :parameter-type '(choice :tag "Permitted unencoded charsets"
 203                           :value nil
 204                           (repeat (symbol)))
 205  :parameter-document       "\
 206 List of charsets that are permitted to be unencoded.")
 207
 208 (defcustom gnus-debug-files
 209   '("gnus.el" "gnus-sum.el" "gnus-group.el"
 210     "gnus-art.el" "gnus-start.el" "gnus-async.el"
 211     "gnus-msg.el" "gnus-score.el" "gnus-win.el" "gnus-topic.el"
 212     "gnus-agent.el" "gnus-cache.el" "gnus-srvr.el"
 213     "mm-util.el" "mm-decode.el" "nnmail.el" "message.el")
 214   "Files whose variables will be reported in `gnus-bug'."
 215   :version "21.1"
 216   :group 'gnus-message
 217   :type '(repeat (string :tag "File")))
 218
 219 (defcustom gnus-debug-exclude-variables
 220   '(mm-mime-mule-charset-alist
 221     nnmail-split-fancy message-minibuffer-local-map)
 222   "Variables that should not be reported in `gnus-bug'."
 223   :version "21.1"
 224   :group 'gnus-message
 225   :type '(repeat (symbol :tag "Variable")))
 226
 227 (defcustom gnus-discouraged-post-methods
 228   '(nndraft nnml nnimap nnmaildir nnmh nnfolder nndir)
 229   "A list of back ends that are not used in \"real\" newsgroups.
 230 This variable is used only when `gnus-post-method' is `current'."
 231   :version "21.3"
 232   :group 'gnus-group-foreign
 233   :type '(repeat (symbol :tag "Back end")))
 234
 235 (defcustom gnus-message-replysign
 236   nil
 237   "Automatically sign replies to signed messages.
 238 See also the `mml-default-sign-method' variable."
 239   :group 'gnus-message
 240   :type 'boolean)
 241
 242 (defcustom gnus-message-replyencrypt
 243   nil
 244   "Automatically encrypt replies to encrypted messages.
 245 See also the `mml-default-encrypt-method' variable."
 246   :group 'gnus-message
 247   :type 'boolean)
 248
 249 (defcustom gnus-message-replysignencrypted
 250   t
 251   "Setting this causes automatically encrypted messages to also be signed."
 252   :group 'gnus-message
 253   :type 'boolean)
 254
 255 (defcustom gnus-confirm-mail-reply-to-news nil
 256   "If non-nil, Gnus requests confirmation when replying to news.
 257 This is done because new users often reply by mistake when reading
 258 news.
 259 This can also be a function receiving the group name as the only
 260 parameter which should return non-nil iff a confirmation is needed, or
 261 a regexp, in which case a confirmation is asked for iff the group name
 262 matches the regexp."
 263   :group 'gnus-message
 264   :type '(choice (const :tag "No" nil)
 265                  (const :tag "Yes" t)
 266                  (regexp :tag "Iff group matches regexp")
 267                  (function :tag "Iff function evaluates to non-nil")))
 268
 269 (defcustom gnus-confirm-treat-mail-like-news
 270   nil
 271   "If non-nil, Gnus will treat mail like news with regard to confirmation
 272 when replying by mail.  See the `gnus-confirm-mail-reply-to-news' variable
 273 for fine-tuning this.
 274 If nil, Gnus will never ask for confirmation if replying to mail."
 275   :group 'gnus-message
 276   :type 'boolean)
 277
 278 (defcustom gnus-summary-resend-default-address t
 279   "If non-nil, Gnus tries to suggest a default address to resend to.
 280 If nil, the address field will always be empty after invoking
 281 `gnus-summary-resend-message'."
 282   :group 'gnus-message
 283   :type 'boolean)
 284
 285 (defcustom gnus-user-agent 'emacs-gnus-type
 286   "Which information should be exposed in the User-Agent header.
 287
 288 It can be one of the symbols `gnus' \(show only Gnus version\), `emacs-gnus'
 289 \(show only Emacs and Gnus versions\), `emacs-gnus-config' \(same as
 290 `emacs-gnus' plus system configuration\), `emacs-gnus-type' \(same as
 291 `emacs-gnus' plus system type\) or a custom string.  If you set it to a
 292 string, be sure to use a valid format, see RFC 2616."
 293   :group 'gnus-message
 294   :type '(choice
 295           (item :tag "Show Gnus and Emacs versions and system type"
 296                 emacs-gnus-type)
 297           (item :tag "Show Gnus and Emacs versions and system configuration"
 298                 emacs-gnus-config)
 299           (item :tag "Show Gnus and Emacs versions" emacs-gnus)
 300           (item :tag "Show only Gnus version" gnus)
 301           (string :tag "Other")))
 302
 303 ;;; Internal variables.
 304
 305 (defvar gnus-inhibit-posting-styles nil
 306   "Inhibit the use of posting styles.")
 307
 308 (defvar gnus-article-yanked-articles nil)
 309 (defvar gnus-message-buffer "*Mail Gnus*")
 310 (defvar gnus-article-copy nil)
 311 (defvar gnus-check-before-posting nil)
 312 (defvar gnus-last-posting-server nil)
 313 (defvar gnus-message-group-art nil)
 314
 315 (defvar gnus-msg-force-broken-reply-to nil)
 316
 317 (defconst gnus-bug-message
 318   "Sending a bug report to the Gnus Towers.
 319 ========================================
 320
 321 The buffer below is a mail buffer.  When you press `C-c C-c', it will
 322 be sent to the Gnus Bug Exterminators.
 323
 324 The thing near the bottom of the buffer is how the environment
 325 settings will be included in the mail.  Please do not delete that.
 326 They will tell the Bug People what your environment is, so that it
 327 will be easier to locate the bugs.
 328
 329 If you have found a bug that makes Emacs go \"beep\", set
 330 debug-on-error to t (`M-x set-variable RET debug-on-error RET t RET')
 331 and include the backtrace in your bug report.
 332
 333 Please describe the bug in annoying, painstaking detail.
 334
 335 Thank you for your help in stamping out bugs.
 336 ")
 337
 338 (eval-and-compile
 339   (autoload 'gnus-uu-post-news "gnus-uu" nil t)
 340   (autoload 'news-setup "rnewspost")
 341   (autoload 'news-reply-mode "rnewspost")
 342   (autoload 'rmail-dont-reply-to "mail-utils")
 343   (autoload 'rmail-output "rmailout"))
 344
 345 \f
 346 ;;;
 347 ;;; Gnus Posting Functions
 348 ;;;
 349
 350 (gnus-define-keys (gnus-summary-send-map "S" gnus-summary-mode-map)
 351   "p" gnus-summary-post-news
 352   "i" gnus-summary-news-other-window
 353   "f" gnus-summary-followup
 354   "F" gnus-summary-followup-with-original
 355   "c" gnus-summary-cancel-article
 356   "s" gnus-summary-supersede-article
 357   "r" gnus-summary-reply
 358   "y" gnus-summary-yank-message
 359   "R" gnus-summary-reply-with-original
 360   "w" gnus-summary-wide-reply
 361   "W" gnus-summary-wide-reply-with-original
 362   "v" gnus-summary-very-wide-reply
 363   "V" gnus-summary-very-wide-reply-with-original
 364   "n" gnus-summary-followup-to-mail
 365   "N" gnus-summary-followup-to-mail-with-original
 366   "m" gnus-summary-mail-other-window
 367   "u" gnus-uu-post-news
 368   "\M-c" gnus-summary-mail-crosspost-complaint
 369   "Br" gnus-summary-reply-broken-reply-to
 370   "BR" gnus-summary-reply-broken-reply-to-with-original
 371   "om" gnus-summary-mail-forward
 372   "op" gnus-summary-post-forward
 373   "Om" gnus-uu-digest-mail-forward
 374   "Op" gnus-uu-digest-post-forward)
 375
 376 (gnus-define-keys (gnus-send-bounce-map "D" gnus-summary-send-map)
 377   "b" gnus-summary-resend-bounced-mail
 378   ;; "c" gnus-summary-send-draft
 379   "r" gnus-summary-resend-message
 380   "e" gnus-summary-resend-message-edit)
 381
 382 ;;; Internal functions.
 383
 384 (defun gnus-inews-make-draft ()
 385   `(lambda ()
 386      (gnus-inews-make-draft-meta-information
 387       ,gnus-newsgroup-name ',gnus-article-reply)))
 388
 389 (defvar gnus-article-reply nil)
 390 (defmacro gnus-setup-message (config &rest forms)
 391   (let ((winconf (make-symbol "gnus-setup-message-winconf"))
 392         (buffer (make-symbol "gnus-setup-message-buffer"))
 393         (article (make-symbol "gnus-setup-message-article"))
 394         (yanked (make-symbol "gnus-setup-yanked-articles"))
 395         (group (make-symbol "gnus-setup-message-group")))
 396     `(let ((,winconf (current-window-configuration))
 397            (,buffer (buffer-name (current-buffer)))
 398            (,article gnus-article-reply)
 399            (,yanked gnus-article-yanked-articles)
 400            (,group gnus-newsgroup-name)
 401            (message-header-setup-hook
 402             (copy-sequence message-header-setup-hook))
 403            (mbl mml-buffer-list)
 404            (message-mode-hook (copy-sequence message-mode-hook)))
 405        (setq mml-buffer-list nil)
 406        (add-hook 'message-header-setup-hook 'gnus-inews-insert-gcc)
 407        (add-hook 'message-header-setup-hook 'gnus-inews-insert-archive-gcc)
 408        ;; #### FIXME: for a reason that I did not manage to identify yet,
 409        ;; the variable `gnus-newsgroup-name' does not honor a dynamically
 410        ;; scoped or setq'ed value from a caller like `C-u gnus-summary-mail'.
 411        ;; After evaluation of @forms below, it gets the value we actually want
 412        ;; to override, and the posting styles are used. For that reason, I've
 413        ;; added an optional argument to `gnus-configure-posting-styles' to
 414        ;; make sure that the correct value for the group name is used. -- drv
 415        (add-hook 'message-mode-hook
 416                  (lambda ()
 417                    (gnus-configure-posting-styles ,group)))
 418        (gnus-pull ',(intern gnus-draft-meta-information-header)
 419                   message-required-headers)
 420        (when (and ,group
 421                   (not (string= ,group "")))
 422          (push (cons
 423                 (intern gnus-draft-meta-information-header)
 424                 (gnus-inews-make-draft))
 425                message-required-headers))
 426        (unwind-protect
 427            (progn
 428              ,@forms)
 429          (gnus-inews-add-send-actions ,winconf ,buffer ,article ,config
 430                                       ,yanked)
 431          (setq gnus-message-buffer (current-buffer))
 432          (set (make-local-variable 'gnus-message-group-art)
 433               (cons ,group ,article))
 434          (set (make-local-variable 'gnus-newsgroup-name) ,group)
 435          (gnus-run-hooks 'gnus-message-setup-hook)
 436          (if (eq major-mode 'message-mode)
 437              (let ((mbl1 mml-buffer-list))
 438                (setq mml-buffer-list mbl)  ;; Global value
 439                (set (make-local-variable 'mml-buffer-list) mbl1);; Local value
 440                (gnus-make-local-hook 'kill-buffer-hook)
 441                (gnus-make-local-hook 'change-major-mode-hook)
 442                (add-hook 'change-major-mode-hook 'mml-destroy-buffers nil t)
 443                (add-hook 'kill-buffer-hook 'mml-destroy-buffers t t))
 444            (mml-destroy-buffers)
 445            (setq mml-buffer-list mbl)))
 446        (message-hide-headers)
 447        (gnus-add-buffer)
 448        (gnus-configure-windows ,config t)
 449        (run-hooks 'post-command-hook)
 450        (set-buffer-modified-p nil))))
 451
 452 (defun gnus-inews-make-draft-meta-information (group article)
 453   (concat "(\"" group "\" "
 454           (if article (number-to-string
 455                        (if (listp article)
 456                            (car article)
 457                          article)) "\"\"")
 458           ")"))
 459
 460 ;;;###autoload
 461 (defun gnus-msg-mail (&optional to subject other-headers continue
 462                                 switch-action yank-action send-actions)
 463   "Start editing a mail message to be sent.
 464 Like `message-mail', but with Gnus paraphernalia, particularly the
 465 Gcc: header for archiving purposes."
 466   (interactive)
 467   (let ((buf (current-buffer))
 468         mail-buf)
 469     (gnus-setup-message 'message
 470       (message-mail to subject other-headers continue
 471                     nil yank-action send-actions))
 472     (when switch-action
 473       (setq mail-buf (current-buffer))
 474       (switch-to-buffer buf)
 475       (apply switch-action mail-buf nil)))
 476   ;; COMPOSEFUNC should return t if succeed.  Undocumented ???
 477   t)
 478
 479 (defvar save-selected-window-window)
 480
 481 ;;;###autoload
 482 (defun gnus-button-mailto (address)
 483   "Mail to ADDRESS."
 484   (set-buffer (gnus-copy-article-buffer))
 485   (gnus-setup-message 'message
 486     (message-reply address))
 487   (and (boundp 'save-selected-window-window)
 488        (not (window-live-p save-selected-window-window))
 489        (setq save-selected-window-window (selected-window))))
 490
 491 ;;;###autoload
 492 (defun gnus-button-reply (&optional to-address wide)
 493   "Like `message-reply'."
 494   (interactive)
 495   (gnus-setup-message 'message
 496     (message-reply to-address wide))
 497   (and (boundp 'save-selected-window-window)
 498        (not (window-live-p save-selected-window-window))
 499        (setq save-selected-window-window (selected-window))))
 500
 501 ;;;###autoload
 502 (define-mail-user-agent 'gnus-user-agent
 503   'gnus-msg-mail 'message-send-and-exit
 504   'message-kill-buffer 'message-send-hook)
 505
 506 (defun gnus-setup-posting-charset (group)
 507   (let ((alist gnus-group-posting-charset-alist)
 508         (group (or group ""))
 509         elem)
 510     (when group
 511       (catch 'found
 512         (while (setq elem (pop alist))
 513           (when (or (and (stringp (car elem))
 514                          (string-match (car elem) group))
 515                     (and (functionp (car elem))
 516                          (funcall (car elem) group))
 517                     (and (symbolp (car elem))
 518                          (symbol-value (car elem))))
 519             (throw 'found (cons (cadr elem) (caddr elem)))))))))
 520
 521 (defun gnus-inews-add-send-actions (winconf buffer article
 522                                             &optional config yanked)
 523   (gnus-make-local-hook 'message-sent-hook)
 524   (add-hook 'message-sent-hook (if gnus-agent 'gnus-agent-possibly-do-gcc
 525                                  'gnus-inews-do-gcc) nil t)
 526   (when gnus-agent
 527     (gnus-make-local-hook 'message-header-hook)
 528     (add-hook 'message-header-hook 'gnus-agent-possibly-save-gcc nil t))
 529   (setq message-post-method
 530         `(lambda (arg)
 531            (gnus-post-method arg ,gnus-newsgroup-name)))
 532   (setq message-newsreader (setq message-mailer (gnus-extended-version)))
 533   (message-add-action
 534    `(when (gnus-buffer-exists-p ,buffer)
 535       (set-window-configuration ,winconf))
 536    'exit 'postpone 'kill)
 537   (let ((to-be-marked (cond
 538                        (yanked yanked)
 539                        (article (if (listp article) article (list article)))
 540                        (t nil))))
 541     (message-add-action
 542      `(when (gnus-buffer-exists-p ,buffer)
 543         (save-excursion
 544           (set-buffer ,buffer)
 545           ,(when to-be-marked
 546              (if (eq config 'forward)
 547                  `(gnus-summary-mark-article-as-forwarded ',to-be-marked)
 548                `(gnus-summary-mark-article-as-replied ',to-be-marked)))))
 549      'send)))
 550
 551 (put 'gnus-setup-message 'lisp-indent-function 1)
 552 (put 'gnus-setup-message 'edebug-form-spec '(form body))
 553
 554 ;;; Post news commands of Gnus group mode and summary mode
 555
 556 (defun gnus-group-mail (&optional arg)
 557   "Start composing a mail.
 558 If ARG, use the group under the point to find a posting style.
 559 If ARG is 1, prompt for a group name to find the posting style."
 560   (interactive "P")
 561   ;; We can't `let' gnus-newsgroup-name here, since that leads
 562   ;; to local variables leaking.
 563   (let ((group gnus-newsgroup-name)
 564         ;; make sure last viewed article doesn't affect posting styles:
 565         (gnus-article-copy)
 566         (buffer (current-buffer)))
 567     (unwind-protect
 568         (progn
 569           (setq gnus-newsgroup-name
 570                 (if arg
 571                     (if (= 1 (prefix-numeric-value arg))
 572                         (completing-read "Use posting style of group: "
 573                                          gnus-active-hashtb nil
 574                                          (gnus-read-active-file-p))
 575                       (gnus-group-group-name))
 576                   ""))
 577           ;; #### see comment in gnus-setup-message -- drv
 578           (gnus-setup-message 'message (message-mail)))
 579       (save-excursion
 580         (set-buffer buffer)
 581         (setq gnus-newsgroup-name group)))))
 582
 583 (defun gnus-group-news (&optional arg)
 584   "Start composing a news.
 585 If ARG, post to group under point.
 586 If ARG is 1, prompt for group name to post to.
 587
 588 This function prepares a news even when using mail groups.  This is useful
 589 for posting messages to mail groups without actually sending them over the
 590 network.  The corresponding back end must have a 'request-post method."
 591   (interactive "P")
 592   ;; We can't `let' gnus-newsgroup-name here, since that leads
 593   ;; to local variables leaking.
 594   (let ((group gnus-newsgroup-name)
 595         ;; make sure last viewed article doesn't affect posting styles:
 596         (gnus-article-copy)
 597         (buffer (current-buffer)))
 598     (unwind-protect
 599         (progn
 600           (setq gnus-newsgroup-name
 601                 (if arg
 602                     (if (= 1 (prefix-numeric-value arg))
 603                         (completing-read "Use group: "
 604                                          gnus-active-hashtb nil
 605                                          (gnus-read-active-file-p))
 606                       (gnus-group-group-name))
 607                   ""))
 608           ;; #### see comment in gnus-setup-message -- drv
 609           (gnus-setup-message 'message
 610             (message-news (gnus-group-real-name gnus-newsgroup-name))))
 611       (save-excursion
 612         (set-buffer buffer)
 613         (setq gnus-newsgroup-name group)))))
 614
 615 (defun gnus-group-post-news (&optional arg)
 616   "Start composing a message (a news by default).
 617 If ARG, post to group under point.  If ARG is 1, prompt for group name.
 618 Depending on the selected group, the message might be either a mail or
 619 a news."
 620   (interactive "P")
 621   ;; Bind this variable here to make message mode hooks work ok.
 622   (let ((gnus-newsgroup-name
 623          (if arg
 624              (if (= 1 (prefix-numeric-value arg))
 625                  (completing-read "Newsgroup: " gnus-active-hashtb nil
 626                                   (gnus-read-active-file-p))
 627                (gnus-group-group-name))
 628            ""))
 629         ;; make sure last viewed article doesn't affect posting styles:
 630         (gnus-article-copy))
 631     (gnus-post-news 'post gnus-newsgroup-name nil nil nil nil
 632                     (string= gnus-newsgroup-name ""))))
 633
 634 (defun gnus-summary-mail-other-window (&optional arg)
 635   "Start composing a mail in another window.
 636 Use the posting of the current group by default.
 637 If ARG, don't do that.  If ARG is 1, prompt for group name to find the
 638 posting style."
 639   (interactive "P")
 640   ;; We can't `let' gnus-newsgroup-name here, since that leads
 641   ;; to local variables leaking.
 642   (let ((group gnus-newsgroup-name)
 643         ;; make sure last viewed article doesn't affect posting styles:
 644         (gnus-article-copy)
 645         (buffer (current-buffer)))
 646     (unwind-protect
 647         (progn
 648           (setq gnus-newsgroup-name
 649                 (if arg
 650                     (if (= 1 (prefix-numeric-value arg))
 651                         (completing-read "Use group: "
 652                                          gnus-active-hashtb nil
 653                                          (gnus-read-active-file-p))
 654                       "")
 655                   gnus-newsgroup-name))
 656           ;; #### see comment in gnus-setup-message -- drv
 657           (gnus-setup-message 'message (message-mail)))
 658       (save-excursion
 659         (set-buffer buffer)
 660         (setq gnus-newsgroup-name group)))))
 661
 662 (defun gnus-summary-news-other-window (&optional arg)
 663   "Start composing a news in another window.
 664 Post to the current group by default.
 665 If ARG, don't do that.  If ARG is 1, prompt for group name to post to.
 666
 667 This function prepares a news even when using mail groups.  This is useful
 668 for posting messages to mail groups without actually sending them over the
 669 network.  The corresponding back end must have a 'request-post method."
 670   (interactive "P")
 671   ;; We can't `let' gnus-newsgroup-name here, since that leads
 672   ;; to local variables leaking.
 673   (let ((group gnus-newsgroup-name)
 674         ;; make sure last viewed article doesn't affect posting styles:
 675         (gnus-article-copy)
 676         (buffer (current-buffer)))
 677     (unwind-protect
 678         (progn
 679           (setq gnus-newsgroup-name
 680                 (if arg
 681                     (if (= 1 (prefix-numeric-value arg))
 682                         (completing-read "Use group: "
 683                                          gnus-active-hashtb nil
 684                                          (gnus-read-active-file-p))
 685                       "")
 686                   gnus-newsgroup-name))
 687           ;; #### see comment in gnus-setup-message -- drv
 688           (gnus-setup-message 'message
 689             (progn
 690               (message-news (gnus-group-real-name gnus-newsgroup-name))
 691               (set (make-local-variable 'gnus-discouraged-post-methods)
 692                    (delq
 693                     (car (gnus-find-method-for-group gnus-newsgroup-name))
 694                     (copy-sequence gnus-discouraged-post-methods))))))
 695       (save-excursion
 696         (set-buffer buffer)
 697         (setq gnus-newsgroup-name group)))))
 698
 699 (defun gnus-summary-post-news (&optional arg)
 700   "Start composing a message.  Post to the current group by default.
 701 If ARG, don't do that.  If ARG is 1, prompt for a group name to post to.
 702 Depending on the selected group, the message might be either a mail or
 703 a news."
 704   (interactive "P")
 705   ;; Bind this variable here to make message mode hooks work ok.
 706   (let ((gnus-newsgroup-name
 707          (if arg
 708              (if (= 1 (prefix-numeric-value arg))
 709                  (completing-read "Newsgroup: " gnus-active-hashtb nil
 710                                   (gnus-read-active-file-p))
 711                "")
 712            gnus-newsgroup-name))
 713         ;; make sure last viewed article doesn't affect posting styles:
 714         (gnus-article-copy))
 715     (gnus-post-news 'post gnus-newsgroup-name)))
 716
 717
 718 (defun gnus-summary-followup (yank &optional force-news)
 719   "Compose a followup to an article.
 720 If prefix argument YANK is non-nil, the original article is yanked
 721 automatically.
 722 YANK is a list of elements, where the car of each element is the
 723 article number, and the two following numbers is the region to be
 724 yanked."
 725   (interactive
 726    (list (and current-prefix-arg
 727               (gnus-summary-work-articles 1))))
 728   (when yank
 729     (gnus-summary-goto-subject
 730      (if (listp (car yank))
 731          (caar yank)
 732        (car yank))))
 733   (save-window-excursion
 734     (gnus-summary-select-article))
 735   (let ((headers (gnus-summary-article-header (gnus-summary-article-number)))
 736         (gnus-newsgroup-name gnus-newsgroup-name))
 737     ;; Send a followup.
 738     (gnus-post-news nil gnus-newsgroup-name
 739                     headers gnus-article-buffer
 740                     yank nil force-news)
 741     (gnus-summary-handle-replysign)))
 742
 743 (defun gnus-summary-followup-with-original (n &optional force-news)
 744   "Compose a followup to an article and include the original article."
 745   (interactive "P")
 746   (gnus-summary-followup (gnus-summary-work-articles n) force-news))
 747
 748 (defun gnus-summary-followup-to-mail (&optional arg)
 749   "Followup to the current mail message via news."
 750   (interactive
 751    (list (and current-prefix-arg
 752               (gnus-summary-work-articles 1))))
 753   (gnus-summary-followup arg t))
 754
 755 (defun gnus-summary-followup-to-mail-with-original (&optional arg)
 756   "Followup to the current mail message via news."
 757   (interactive "P")
 758   (gnus-summary-followup (gnus-summary-work-articles arg) t))
 759
 760 (defun gnus-inews-yank-articles (articles)
 761   (let (beg article yank-string)
 762     (message-goto-body)
 763     (while (setq article (pop articles))
 764       (when (listp article)
 765         (setq yank-string (nth 1 article)
 766               article (nth 0 article)))
 767       (save-window-excursion
 768         (set-buffer gnus-summary-buffer)
 769         (gnus-summary-select-article nil nil nil article)
 770         (gnus-summary-remove-process-mark article))
 771       (gnus-copy-article-buffer nil yank-string)
 772       (let ((message-reply-buffer gnus-article-copy)
 773             (message-reply-headers
 774              ;; The headers are decoded.
 775              (with-current-buffer gnus-article-copy
 776                (save-restriction
 777                  (nnheader-narrow-to-headers)
 778                  (nnheader-parse-naked-head)))))
 779         (message-yank-original)
 780         (setq beg (or beg (mark t))))
 781       (when articles
 782         (insert "\n")))
 783     (push-mark)
 784     (goto-char beg)))
 785
 786 (defun gnus-summary-cancel-article (&optional n symp)
 787   "Cancel an article you posted.
 788 Uses the process-prefix convention.  If given the symbolic
 789 prefix `a', cancel using the standard posting method; if not
 790 post using the current select method."
 791   (interactive (gnus-interactive "P\ny"))
 792   (let ((articles (gnus-summary-work-articles n))
 793         (message-post-method
 794          `(lambda (arg)
 795             (gnus-post-method (eq ',symp 'a) ,gnus-newsgroup-name)))
 796         article)
 797     (while (setq article (pop articles))
 798       (when (gnus-summary-select-article t nil nil article)
 799         (when (gnus-eval-in-buffer-window gnus-original-article-buffer
 800                 (message-cancel-news))
 801           (gnus-summary-mark-as-read article gnus-canceled-mark)
 802           (gnus-cache-remove-article 1))
 803         (gnus-article-hide-headers-if-wanted))
 804       (gnus-summary-remove-process-mark article))))
 805
 806 (defun gnus-summary-supersede-article ()
 807   "Compose an article that will supersede a previous article.
 808 This is done simply by taking the old article and adding a Supersedes
 809 header line with the old Message-ID."
 810   (interactive)
 811   (let ((article (gnus-summary-article-number)))
 812     (gnus-setup-message 'reply-yank
 813       (gnus-summary-select-article t)
 814       (set-buffer gnus-original-article-buffer)
 815       (message-supersede)
 816       (push
 817        `((lambda ()
 818            (when (gnus-buffer-exists-p ,gnus-summary-buffer)
 819              (save-excursion
 820                (set-buffer ,gnus-summary-buffer)
 821                (gnus-cache-possibly-remove-article ,article nil nil nil t)
 822                (gnus-summary-mark-as-read ,article gnus-canceled-mark)))))
 823        message-send-actions))))
 824
 825 \f
 826
 827 (defun gnus-copy-article-buffer (&optional article-buffer yank-string)
 828   ;; make a copy of the article buffer with all text properties removed
 829   ;; this copy is in the buffer gnus-article-copy.
 830   ;; if ARTICLE-BUFFER is nil, gnus-article-buffer is used
 831   ;; this buffer should be passed to all mail/news reply/post routines.
 832   (setq gnus-article-copy (gnus-get-buffer-create " *gnus article copy*"))
 833   (save-excursion
 834     (set-buffer gnus-article-copy)
 835     (mm-enable-multibyte))
 836   (let ((article-buffer (or article-buffer gnus-article-buffer))
 837         end beg)
 838     (if (not (and (get-buffer article-buffer)
 839                   (gnus-buffer-exists-p article-buffer)))
 840         (error "Can't find any article buffer")
 841       (save-excursion
 842         (set-buffer article-buffer)
 843         (let ((gnus-newsgroup-charset (or gnus-article-charset
 844                                           gnus-newsgroup-charset))
 845               (gnus-newsgroup-ignored-charsets
 846                (or gnus-article-ignored-charsets
 847                    gnus-newsgroup-ignored-charsets)))
 848           (save-restriction
 849             ;; Copy over the (displayed) article buffer, delete
 850             ;; hidden text and remove text properties.
 851             (widen)
 852             (copy-to-buffer gnus-article-copy (point-min) (point-max))
 853             (set-buffer gnus-article-copy)
 854             (when yank-string
 855               (message-goto-body)
 856               (delete-region (point) (point-max))
 857               (insert yank-string))
 858             (gnus-article-delete-text-of-type 'annotation)
 859             (gnus-remove-text-with-property 'gnus-prev)
 860             (gnus-remove-text-with-property 'gnus-next)
 861             (gnus-remove-text-with-property 'gnus-decoration)
 862             (insert
 863              (prog1
 864                  (buffer-substring-no-properties (point-min) (point-max))
 865                (erase-buffer)))
 866             ;; Find the original headers.
 867             (set-buffer gnus-original-article-buffer)
 868             (goto-char (point-min))
 869             (while (looking-at message-unix-mail-delimiter)
 870               (forward-line 1))
 871             (let ((mail-header-separator ""))
 872               (setq beg (point)
 873                     end (or (message-goto-body)
 874                             ;; There may be just a header.
 875                             (point-max))))
 876             ;; Delete the headers from the displayed articles.
 877             (set-buffer gnus-article-copy)
 878             (let ((mail-header-separator ""))
 879               (delete-region (goto-char (point-min))
 880                              (or (message-goto-body) (point-max))))
 881             ;; Insert the original article headers.
 882             (insert-buffer-substring gnus-original-article-buffer beg end)
 883             ;; Decode charsets.
 884             (let ((gnus-article-decode-hook
 885                    (delq 'article-decode-charset
 886                          (copy-sequence gnus-article-decode-hook))))
 887               (run-hooks 'gnus-article-decode-hook)))))
 888       gnus-article-copy)))
 889
 890 (defun gnus-post-news (post &optional group header article-buffer yank subject
 891                             force-news)
 892   (when article-buffer
 893     (gnus-copy-article-buffer))
 894   (let ((gnus-article-reply (and article-buffer (gnus-summary-article-number)))
 895         (gnus-article-yanked-articles yank)
 896         (add-to-list gnus-add-to-list))
 897     (gnus-setup-message (cond (yank 'reply-yank)
 898                               (article-buffer 'reply)
 899                               (t 'message))
 900       (let* ((group (or group gnus-newsgroup-name))
 901              (charset (gnus-group-name-charset nil group))
 902              (pgroup group)
 903              to-address to-group mailing-list to-list
 904              newsgroup-p)
 905         (when group
 906           (setq to-address (gnus-parameter-to-address group)
 907                 to-group (gnus-group-find-parameter group 'to-group)
 908                 to-list (gnus-parameter-to-list group)
 909                 newsgroup-p (gnus-group-find-parameter group 'newsgroup)
 910                 mailing-list (when gnus-mailing-list-groups
 911                                (string-match gnus-mailing-list-groups group))
 912                 group (gnus-group-name-decode (gnus-group-real-name group)
 913                                               charset)))
 914         (if (or (and to-group
 915                      (gnus-news-group-p to-group))
 916                 newsgroup-p
 917                 force-news
 918                 (and (gnus-news-group-p
 919                       (or pgroup gnus-newsgroup-name)
 920                       (or header gnus-current-article))
 921                      (not mailing-list)
 922                      (not to-list)
 923                      (not to-address)))
 924             ;; This is news.
 925             (if post
 926                 (message-news (or to-group group))
 927               (set-buffer gnus-article-copy)
 928               (gnus-msg-treat-broken-reply-to)
 929               (message-followup (if (or newsgroup-p force-news)
 930                                     (if (save-restriction
 931                                           (article-narrow-to-head)
 932                                           (message-fetch-field "newsgroups"))
 933                                         nil
 934                                       "")
 935                                   to-group)))
 936           ;; The is mail.
 937           (if post
 938               (progn
 939                 (message-mail (or to-address to-list))
 940                 ;; Arrange for mail groups that have no `to-address' to
 941                 ;; get that when the user sends off the mail.
 942                 (when (and (not to-list)
 943                            (not to-address)
 944                            add-to-list)
 945                   (push (list 'gnus-inews-add-to-address pgroup)
 946                         message-send-actions)))
 947             (set-buffer gnus-article-copy)
 948             (gnus-msg-treat-broken-reply-to)
 949             (message-wide-reply to-address)))
 950         (when yank
 951           (gnus-inews-yank-articles yank))))))
 952
 953 (defun gnus-msg-treat-broken-reply-to (&optional force)
 954   "Remove the Reply-to header if broken-reply-to."
 955   (when (or force
 956             (gnus-group-find-parameter
 957              gnus-newsgroup-name 'broken-reply-to))
 958     (save-restriction
 959       (message-narrow-to-head)
 960       (message-remove-header "reply-to"))))
 961
 962 (defun gnus-post-method (arg group &optional silent)
 963   "Return the posting method based on GROUP and ARG.
 964 If SILENT, don't prompt the user."
 965   (let ((gnus-post-method (or (gnus-parameter-post-method group)
 966                               gnus-post-method))
 967         (group-method (gnus-find-method-for-group group)))
 968     (cond
 969      ;; If the group-method is nil (which shouldn't happen) we use
 970      ;; the default method.
 971      ((null group-method)
 972       (or (and (listp gnus-post-method) ;If not current/native/nil
 973                (not (listp (car gnus-post-method))) ; and not a list of methods
 974                gnus-post-method)        ;then use it.
 975           gnus-select-method
 976           message-post-method))
 977      ;; We want the inverse of the default
 978      ((and arg (not (eq arg 0)))
 979       (if (eq gnus-post-method 'current)
 980           gnus-select-method
 981         group-method))
 982      ;; We query the user for a post method.
 983      ((or arg
 984           (and (listp gnus-post-method)
 985                (listp (car gnus-post-method))))
 986       (let* ((methods
 987               ;; Collect all methods we know about.
 988               (append
 989                (when (listp gnus-post-method)
 990                  (if (listp (car gnus-post-method))
 991                      gnus-post-method
 992                    (list gnus-post-method)))
 993                gnus-secondary-select-methods
 994                (mapcar 'cdr gnus-server-alist)
 995                (mapcar 'car gnus-opened-servers)
 996                (list gnus-select-method)
 997                (list group-method)))
 998              method-alist post-methods method)
 999         ;; Weed out all mail methods.
1000         (while methods
1001           (setq method (gnus-server-get-method "" (pop methods)))
1002           (when (and (or (gnus-method-option-p method 'post)
1003                          (gnus-method-option-p method 'post-mail))
1004                      (not (member method post-methods)))
1005             (push method post-methods)))
1006         ;; Create a name-method alist.
1007         (setq method-alist
1008               (mapcar
1009                (lambda (m)
1010                  (if (equal (cadr m) "")
1011                      (list (symbol-name (car m)) m)
1012                    (list (concat (cadr m) " (" (symbol-name (car m)) ")") m)))
1013                post-methods))
1014         ;; Query the user.
1015         (cadr
1016          (assoc
1017           (setq gnus-last-posting-server
1018                 (if (and silent
1019                          gnus-last-posting-server)
1020                     ;; Just use the last value.
1021                     gnus-last-posting-server
1022                   (completing-read
1023                    "Posting method: " method-alist nil t
1024                    (cons (or gnus-last-posting-server "") 0))))
1025           method-alist))))
1026      ;; Override normal method.
1027      ((and (eq gnus-post-method 'current)
1028            (not (memq (car group-method) gnus-discouraged-post-methods))
1029            (gnus-get-function group-method 'request-post t))
1030       (assert (not arg))
1031       group-method)
1032      ;; Use gnus-post-method.
1033      ((listp gnus-post-method)          ;A method...
1034       (assert (not (listp (car gnus-post-method)))) ;... not a list of methods.
1035       gnus-post-method)
1036      ;; Use the normal select method (nil or native).
1037      (t gnus-select-method))))
1038
1039 \f
1040
1041 ;; Dummies to avoid byte-compile warning.
1042 (eval-when-compile
1043   (defvar nnspool-rejected-article-hook)
1044   (defvar xemacs-codename))
1045
1046 (defun gnus-extended-version ()
1047   "Stringified Gnus version and Emacs version.
1048 See the variable `gnus-user-agent'."
1049   (interactive)
1050   (let* ((gnus-v
1051           (concat "Gnus/"
1052                   (prin1-to-string (gnus-continuum-version gnus-version) t)
1053                   " (" gnus-version ")"))
1054          (system-v
1055           (cond
1056            ((eq gnus-user-agent 'emacs-gnus-config)
1057             system-configuration)
1058            ((eq gnus-user-agent 'emacs-gnus-type)
1059             (symbol-name system-type))
1060            (t nil)))
1061          (emacs-v
1062           (cond
1063            ((eq gnus-user-agent 'gnus)
1064             nil)
1065            ((string-match "^\\(\\([.0-9]+\\)*\\)\\.[0-9]+$" emacs-version)
1066             (concat "Emacs/" (match-string 1 emacs-version)
1067                     (if system-v
1068                         (concat " (" system-v ")")
1069                       "")))
1070            ((string-match
1071              "\\([A-Z]*[Mm][Aa][Cc][Ss]\\)[^(]*\\(\\((beta.*)\\|'\\)\\)?"
1072              emacs-version)
1073             (concat
1074              (match-string 1 emacs-version)
1075              (format "/%d.%d" emacs-major-version emacs-minor-version)
1076              (if (match-beginning 3)
1077                  (match-string 3 emacs-version)
1078                "")
1079              (if (boundp 'xemacs-codename)
1080                  (concat
1081                   " (" xemacs-codename
1082                   (if system-v
1083                       (concat ", " system-v ")")
1084                     ")"))
1085                "")))
1086            (t emacs-version))))
1087     (if (stringp gnus-user-agent)
1088         gnus-user-agent
1089       (concat gnus-v
1090               (when emacs-v
1091                 (concat " " emacs-v))))))
1092
1093 \f
1094 ;;;
1095 ;;; Gnus Mail Functions
1096 ;;;
1097
1098 ;;; Mail reply commands of Gnus summary mode
1099
1100 (defun gnus-summary-reply (&optional yank wide very-wide)
1101   "Start composing a mail reply to the current message.
1102 If prefix argument YANK is non-nil, the original article is yanked
1103 automatically.
1104 If WIDE, make a wide reply.
1105 If VERY-WIDE, make a very wide reply."
1106   (interactive
1107    (list (and current-prefix-arg
1108               (gnus-summary-work-articles 1))))
1109   ;; Allow user to require confirmation before replying by mail to the
1110   ;; author of a news article (or mail message).
1111   (when (or
1112             (not (or (gnus-news-group-p gnus-newsgroup-name)
1113                      gnus-confirm-treat-mail-like-news))
1114             (not (cond ((stringp gnus-confirm-mail-reply-to-news)
1115                         (string-match gnus-confirm-mail-reply-to-news
1116                                       gnus-newsgroup-name))
1117                        ((functionp gnus-confirm-mail-reply-to-news)
1118                         (funcall gnus-confirm-mail-reply-to-news gnus-newsgroup-name))
1119                        (t gnus-confirm-mail-reply-to-news)))
1120             (y-or-n-p "Really reply by mail to article author? "))
1121     (let* ((article
1122             (if (listp (car yank))
1123                 (caar yank)
1124               (car yank)))
1125            (gnus-article-reply (or article (gnus-summary-article-number)))
1126            (gnus-article-yanked-articles yank)
1127            (headers ""))
1128       ;; Stripping headers should be specified with mail-yank-ignored-headers.
1129       (when yank
1130         (gnus-summary-goto-subject article))
1131       (gnus-setup-message (if yank 'reply-yank 'reply)
1132         (if (not very-wide)
1133             (gnus-summary-select-article)
1134           (dolist (article very-wide)
1135             (gnus-summary-select-article nil nil nil article)
1136             (save-excursion
1137               (set-buffer (gnus-copy-article-buffer))
1138               (gnus-msg-treat-broken-reply-to)
1139               (save-restriction
1140                 (message-narrow-to-head)
1141                 (setq headers (concat headers (buffer-string)))))))
1142         (set-buffer (gnus-copy-article-buffer))
1143         (gnus-msg-treat-broken-reply-to gnus-msg-force-broken-reply-to)
1144         (save-restriction
1145           (message-narrow-to-head)
1146           (when very-wide
1147             (erase-buffer)
1148             (insert headers))
1149           (goto-char (point-max)))
1150         (mml-quote-region (point) (point-max))
1151         (message-reply nil wide)
1152         (when yank
1153           (gnus-inews-yank-articles yank))
1154         (gnus-summary-handle-replysign)))))
1155
1156 (defun gnus-summary-handle-replysign ()
1157   "Check the various replysign variables and take action accordingly."
1158   (when (or gnus-message-replysign gnus-message-replyencrypt)
1159     (let (signed encrypted)
1160       (save-excursion
1161         (set-buffer gnus-article-buffer)
1162         (setq signed (memq 'signed gnus-article-wash-types))
1163         (setq encrypted (memq 'encrypted gnus-article-wash-types)))
1164       (cond ((and gnus-message-replyencrypt encrypted)
1165              (mml-secure-message mml-default-encrypt-method
1166                                  (if gnus-message-replysignencrypted
1167                                      'signencrypt
1168                                    'encrypt)))
1169             ((and gnus-message-replysign signed)
1170              (mml-secure-message mml-default-sign-method 'sign))))))
1171
1172 (defun gnus-summary-reply-with-original (n &optional wide)
1173   "Start composing a reply mail to the current message.
1174 The original article will be yanked."
1175   (interactive "P")
1176   (gnus-summary-reply (gnus-summary-work-articles n) wide))
1177
1178 (defun gnus-summary-reply-broken-reply-to (&optional yank wide very-wide)
1179   "Like `gnus-summary-reply' except removing reply-to field.
1180 If prefix argument YANK is non-nil, the original article is yanked
1181 automatically.
1182 If WIDE, make a wide reply.
1183 If VERY-WIDE, make a very wide reply."
1184   (interactive
1185    (list (and current-prefix-arg
1186               (gnus-summary-work-articles 1))))
1187   (let ((gnus-msg-force-broken-reply-to t))
1188     (gnus-summary-reply yank wide very-wide)))
1189
1190 (defun gnus-summary-reply-broken-reply-to-with-original (n &optional wide)
1191   "Like `gnus-summary-reply-with-original' except removing reply-to field.
1192 The original article will be yanked."
1193   (interactive "P")
1194   (gnus-summary-reply-broken-reply-to (gnus-summary-work-articles n) wide))
1195
1196 (defun gnus-summary-wide-reply (&optional yank)
1197   "Start composing a wide reply mail to the current message.
1198 If prefix argument YANK is non-nil, the original article is yanked
1199 automatically."
1200   (interactive
1201    (list (and current-prefix-arg
1202               (gnus-summary-work-articles 1))))
1203   (gnus-summary-reply yank t))
1204
1205 (defun gnus-summary-wide-reply-with-original (n)
1206   "Start composing a wide reply mail to the current message.
1207 The original article will be yanked.
1208 Uses the process/prefix convention."
1209   (interactive "P")
1210   (gnus-summary-reply-with-original n t))
1211
1212 (defun gnus-summary-very-wide-reply (&optional yank)
1213   "Start composing a very wide reply mail to the current message.
1214 If prefix argument YANK is non-nil, the original article is yanked
1215 automatically."
1216   (interactive
1217    (list (and current-prefix-arg
1218               (gnus-summary-work-articles 1))))
1219   (gnus-summary-reply yank t (gnus-summary-work-articles yank)))
1220
1221 (defun gnus-summary-very-wide-reply-with-original (n)
1222   "Start composing a very wide reply mail to the current message.
1223 The original article will be yanked."
1224   (interactive "P")
1225   (gnus-summary-reply
1226    (gnus-summary-work-articles n) t (gnus-summary-work-articles n)))
1227
1228 (defun gnus-summary-mail-forward (&optional arg post)
1229   "Forward the current message(s) to another user.
1230 If process marks exist, forward all marked messages;
1231 if ARG is nil, see `message-forward-as-mime' and `message-forward-show-mml';
1232 if ARG is 1, decode the message and forward directly inline;
1233 if ARG is 2, forward message as an rfc822 MIME section;
1234 if ARG is 3, decode message and forward as an rfc822 MIME section;
1235 if ARG is 4, forward message directly inline;
1236 otherwise, use flipped `message-forward-as-mime'.
1237 If POST, post instead of mail.
1238 For the `inline' alternatives, also see the variable
1239 `message-forward-ignored-headers'."
1240   (interactive "P")
1241   (if (cdr (gnus-summary-work-articles nil))
1242       ;; Process marks are given.
1243       (gnus-uu-digest-mail-forward arg post)
1244     ;; No process marks.
1245     (let ((message-forward-as-mime message-forward-as-mime)
1246           (message-forward-show-mml message-forward-show-mml))
1247       (cond
1248        ((null arg))
1249        ((eq arg 1)
1250         (setq message-forward-as-mime nil
1251               message-forward-show-mml t))
1252        ((eq arg 2)
1253         (setq message-forward-as-mime t
1254               message-forward-show-mml nil))
1255        ((eq arg 3)
1256         (setq message-forward-as-mime t
1257               message-forward-show-mml t))
1258        ((eq arg 4)
1259         (setq message-forward-as-mime nil
1260               message-forward-show-mml nil))
1261        (t
1262         (setq message-forward-as-mime (not message-forward-as-mime))))
1263       (let* ((gnus-article-reply (gnus-summary-article-number))
1264              (gnus-article-yanked-articles (list gnus-article-reply)))
1265         (gnus-setup-message 'forward
1266           (gnus-summary-select-article)
1267           (let ((mail-parse-charset
1268                  (or (and (gnus-buffer-live-p gnus-article-buffer)
1269                           (with-current-buffer gnus-article-buffer
1270                             gnus-article-charset))
1271                      gnus-newsgroup-charset))
1272                 (mail-parse-ignored-charsets
1273                  gnus-newsgroup-ignored-charsets))
1274             (set-buffer gnus-original-article-buffer)
1275             (message-forward post)))))))
1276
1277 (defun gnus-summary-resend-message (address n)
1278   "Resend the current article to ADDRESS."
1279   (interactive
1280    (list (message-read-from-minibuffer
1281           "Resend message(s) to: "
1282           (when (and gnus-summary-resend-default-address
1283                      (gnus-buffer-live-p gnus-original-article-buffer))
1284             ;; If some other article is currently selected, the
1285             ;; initial-contents is wrong. Whatever, it is just the
1286             ;; initial-contents.
1287             (with-current-buffer gnus-original-article-buffer
1288               (nnmail-fetch-field "to"))))
1289          current-prefix-arg))
1290   (let ((articles (gnus-summary-work-articles n))
1291         article)
1292     (while (setq article (pop articles))
1293       (gnus-summary-select-article nil nil nil article)
1294       (save-excursion
1295         (set-buffer gnus-original-article-buffer)
1296         (message-resend address))
1297       (gnus-summary-mark-article-as-forwarded article))))
1298
1299 ;; From: Matthieu Moy <Matthieu.Moy@imag.fr>
1300 (defun gnus-summary-resend-message-edit ()
1301   "Resend an article that has already been sent.
1302 A new buffer will be created to allow the user to modify body and
1303 contents of the message, and then, everything will happen as when
1304 composing a new message."
1305   (interactive)
1306   (let ((article (gnus-summary-article-number)))
1307     (gnus-setup-message 'reply-yank
1308       (gnus-summary-select-article t)
1309       (set-buffer gnus-original-article-buffer)
1310       (let ((cur (current-buffer))
1311             (to (message-fetch-field "to")))
1312         ;; Get a normal message buffer.
1313         (message-pop-to-buffer (message-buffer-name "Resend" to))
1314         (insert-buffer-substring cur)
1315         (mime-to-mml)
1316         (message-narrow-to-head-1)
1317         ;; Gnus will generate a new one when sending.
1318         (message-remove-header "Message-ID")
1319         (message-remove-header message-ignored-resent-headers t)
1320         ;; Remove unwanted headers.
1321         (goto-char (point-max))
1322         (insert mail-header-separator)
1323         (goto-char (point-min))
1324         (re-search-forward "^To:\\|^Newsgroups:" nil 'move)
1325         (forward-char 1)
1326         (widen)))))
1327
1328 (defun gnus-summary-post-forward (&optional arg)
1329   "Forward the current article to a newsgroup.
1330 See `gnus-summary-mail-forward' for ARG."
1331   (interactive "P")
1332   (gnus-summary-mail-forward arg t))
1333
1334 (defvar gnus-nastygram-message
1335   "The following article was inappropriately posted to %s.\n\n"
1336   "Format string to insert in nastygrams.
1337 The current group name will be inserted at \"%s\".")
1338
1339 (defun gnus-summary-mail-nastygram (n)
1340   "Send a nastygram to the author of the current article."
1341   (interactive "P")
1342   (when (or gnus-expert-user
1343             (gnus-y-or-n-p
1344              "Really send a nastygram to the author of the current article? "))
1345     (let ((group gnus-newsgroup-name))
1346       (gnus-summary-reply-with-original n)
1347       (set-buffer gnus-message-buffer)
1348       (message-goto-body)
1349       (insert (format gnus-nastygram-message group))
1350       (message-send-and-exit))))
1351
1352 (defun gnus-summary-mail-crosspost-complaint (n)
1353   "Send a complaint about crossposting to the current article(s)."
1354   (interactive "P")
1355   (let ((articles (gnus-summary-work-articles n))
1356         article)
1357     (while (setq article (pop articles))
1358       (set-buffer gnus-summary-buffer)
1359       (gnus-summary-goto-subject article)
1360       (let ((group (gnus-group-real-name gnus-newsgroup-name))
1361             newsgroups followup-to)
1362         (gnus-summary-select-article)
1363         (set-buffer gnus-original-article-buffer)
1364         (if (and (<= (length (message-tokenize-header
1365                               (setq newsgroups
1366                                     (mail-fetch-field "newsgroups"))
1367                               ", "))
1368                      1)
1369                  (or (not (setq followup-to (mail-fetch-field "followup-to")))
1370                      (not (member group (message-tokenize-header
1371                                          followup-to ", ")))))
1372             (if followup-to
1373                 (gnus-message 1 "Followup-to restricted")
1374               (gnus-message 1 "Not a crossposted article"))
1375           (set-buffer gnus-summary-buffer)
1376           (gnus-summary-reply-with-original 1)
1377           (set-buffer gnus-message-buffer)
1378           (message-goto-body)
1379           (insert (format gnus-crosspost-complaint newsgroups group))
1380           (message-goto-subject)
1381           (re-search-forward " *$")
1382           (replace-match " (crosspost notification)" t t)
1383           (gnus-deactivate-mark)
1384           (when (gnus-y-or-n-p "Send this complaint? ")
1385             (message-send-and-exit)))))))
1386
1387 (defun gnus-mail-parse-comma-list ()
1388   (let (accumulated
1389         beg)
1390     (skip-chars-forward " ")
1391     (while (not (eobp))
1392       (setq beg (point))
1393       (skip-chars-forward "^,")
1394       (while (zerop
1395               (save-excursion
1396                 (save-restriction
1397                   (let ((i 0))
1398                     (narrow-to-region beg (point))
1399                     (goto-char beg)
1400                     (logand (progn
1401                               (while (search-forward "\"" nil t)
1402                                 (incf i))
1403                               (if (zerop i) 2 i))
1404                             2)))))
1405         (skip-chars-forward ",")
1406         (skip-chars-forward "^,"))
1407       (skip-chars-backward " ")
1408       (push (buffer-substring beg (point))
1409             accumulated)
1410       (skip-chars-forward "^,")
1411       (skip-chars-forward ", "))
1412     accumulated))
1413
1414 (defun gnus-inews-add-to-address (group)
1415   (let ((to-address (mail-fetch-field "to")))
1416     (when (and to-address
1417                (gnus-alive-p))
1418       ;; This mail group doesn't have a `to-list', so we add one
1419       ;; here.  Magic!
1420       (when (gnus-y-or-n-p
1421              (format "Do you want to add this as `to-list': %s? " to-address))
1422         (gnus-group-add-parameter group (cons 'to-list to-address))))))
1423
1424 (defun gnus-put-message ()
1425   "Put the current message in some group and return to Gnus."
1426   (interactive)
1427   (let ((reply gnus-article-reply)
1428         (winconf gnus-prev-winconf)
1429         (group gnus-newsgroup-name))
1430     (unless (and group
1431                  (not (gnus-group-read-only-p group)))
1432       (setq group (read-string "Put in group: " nil (gnus-writable-groups))))
1433
1434     (when (gnus-gethash group gnus-newsrc-hashtb)
1435       (error "No such group: %s" group))
1436     (save-excursion
1437       (save-restriction
1438         (widen)
1439         (message-narrow-to-headers)
1440         (let ((gnus-deletable-headers nil))
1441           (message-generate-headers
1442            (if (message-news-p)
1443                message-required-news-headers
1444              message-required-mail-headers)))
1445         (goto-char (point-max))
1446         (if (string-match " " group)
1447             (insert "Gcc: \"" group "\"\n")
1448           (insert "Gcc: " group "\n"))
1449         (widen)))
1450     (gnus-inews-do-gcc)
1451     (when (and (get-buffer gnus-group-buffer)
1452                (gnus-buffer-exists-p (car-safe reply))
1453                (cdr reply))
1454       (set-buffer (car reply))
1455       (gnus-summary-mark-article-as-replied (cdr reply)))
1456     (when winconf
1457       (set-window-configuration winconf))))
1458
1459 (defun gnus-article-mail (yank)
1460   "Send a reply to the address near point.
1461 If YANK is non-nil, include the original article."
1462   (interactive "P")
1463   (let ((address
1464          (buffer-substring
1465           (save-excursion (re-search-backward "[ \t\n]" nil t) (1+ (point)))
1466           (save-excursion (re-search-forward "[ \t\n]" nil t) (1- (point))))))
1467     (when address
1468       (gnus-msg-mail address)
1469       (when yank
1470         (gnus-inews-yank-articles (list (cdr gnus-article-current)))))))
1471
1472 (defvar nntp-server-type)
1473 (defun gnus-bug ()
1474   "Send a bug report to the Gnus maintainers."
1475   (interactive)
1476   (unless (gnus-alive-p)
1477     (error "Gnus has been shut down"))
1478   (gnus-setup-message (if (message-mail-user-agent) 'message 'bug)
1479     (unless (message-mail-user-agent)
1480       (delete-other-windows)
1481       (when gnus-bug-create-help-buffer
1482         (switch-to-buffer "*Gnus Help Bug*")
1483         (erase-buffer)
1484         (insert gnus-bug-message)
1485         (goto-char (point-min)))
1486       (message-pop-to-buffer "*Gnus Bug*"))
1487     (let ((message-this-is-mail t))
1488       (message-setup `((To . ,gnus-maintainer) (Subject . ""))))
1489     (when gnus-bug-create-help-buffer
1490       (push `(gnus-bug-kill-buffer) message-send-actions))
1491     (goto-char (point-min))
1492     (re-search-forward (concat "^" (regexp-quote mail-header-separator) "$"))
1493     (forward-line 1)
1494     (insert (gnus-version) "\n"
1495             (emacs-version) "\n")
1496     (when (and (boundp 'nntp-server-type)
1497                (stringp nntp-server-type))
1498       (insert nntp-server-type))
1499     (insert "\n\n\n\n\n")
1500     (let (text)
1501       (save-excursion
1502         (set-buffer (gnus-get-buffer-create " *gnus environment info*"))
1503         (erase-buffer)
1504         (gnus-debug)
1505         (setq text (buffer-string)))
1506       (insert "<#part type=application/emacs-lisp disposition=inline description=\"User settings\">\n" text "\n<#/part>"))
1507     (goto-char (point-min))
1508     (search-forward "Subject: " nil t)
1509     (message "")))
1510
1511 (defun gnus-bug-kill-buffer ()
1512   (when (get-buffer "*Gnus Help Bug*")
1513     (kill-buffer "*Gnus Help Bug*")))
1514
1515 (defun gnus-summary-yank-message (buffer n)
1516   "Yank the current article into a composed message."
1517   (interactive
1518    (list (completing-read "Buffer: " (mapcar 'list (message-buffers)) nil t)
1519          current-prefix-arg))
1520   (gnus-summary-iterate n
1521     (let ((gnus-display-mime-function nil)
1522           (gnus-inhibit-treatment t))
1523       (gnus-summary-select-article))
1524     (save-excursion
1525       (set-buffer buffer)
1526       (message-yank-buffer gnus-article-buffer))))
1527
1528 (defun gnus-debug ()
1529   "Attempts to go through the Gnus source file and report what variables have been changed.
1530 The source file has to be in the Emacs load path."
1531   (interactive)
1532   (let ((files gnus-debug-files)
1533         (point (point))
1534         file expr olist sym)
1535     (gnus-message 4 "Please wait while we snoop your variables...")
1536     (sit-for 0)
1537     ;; Go through all the files looking for non-default values for variables.
1538     (save-excursion
1539       (set-buffer (gnus-get-buffer-create " *gnus bug info*"))
1540       (while files
1541         (erase-buffer)
1542         (when (and (setq file (locate-library (pop files)))
1543                    (file-exists-p file))
1544           (insert-file-contents file)
1545           (goto-char (point-min))
1546           (if (not (re-search-forward "^;;* *Internal variables" nil t))
1547               (gnus-message 4 "Malformed sources in file %s" file)
1548             (narrow-to-region (point-min) (point))
1549             (goto-char (point-min))
1550             (while (setq expr (ignore-errors (read (current-buffer))))
1551               (ignore-errors
1552                 (and (or (eq (car expr) 'defvar)
1553                          (eq (car expr) 'defcustom))
1554                      (stringp (nth 3 expr))
1555                      (not (memq (nth 1 expr) gnus-debug-exclude-variables))
1556                      (or (not (boundp (nth 1 expr)))
1557                          (not (equal (eval (nth 2 expr))
1558                                      (symbol-value (nth 1 expr)))))
1559                      (push (nth 1 expr) olist)))))))
1560       (kill-buffer (current-buffer)))
1561     (when (setq olist (nreverse olist))
1562       (insert "------------------ Environment follows ------------------\n\n"))
1563     (while olist
1564       (if (boundp (car olist))
1565           (ignore-errors
1566             (pp `(setq ,(car olist)
1567                        ,(if (or (consp (setq sym (symbol-value (car olist))))
1568                                 (and (symbolp sym)
1569                                      (not (or (eq sym nil)
1570                                               (eq sym t)))))
1571                             (list 'quote (symbol-value (car olist)))
1572                           (symbol-value (car olist))))
1573                 (current-buffer)))
1574         (insert ";; (makeunbound '" (symbol-name (car olist)) ")\n"))
1575       (setq olist (cdr olist)))
1576     (insert "\n\n")
1577     ;; Remove any control chars - they seem to cause trouble for some
1578     ;; mailers.  (Byte-compiled output from the stuff above.)
1579     (goto-char point)
1580     (while (re-search-forward "[\000-\010\013-\037\200-\237]" nil t)
1581       (replace-match (format "\\%03o" (string-to-char (match-string 0)))
1582                      t t))))
1583
1584 ;;; Treatment of rejected articles.
1585 ;;; Bounced mail.
1586
1587 (defun gnus-summary-resend-bounced-mail (&optional fetch)
1588   "Re-mail the current message.
1589 This only makes sense if the current message is a bounce message than
1590 contains some mail you have written which has been bounced back to
1591 you.
1592 If FETCH, try to fetch the article that this is a reply to, if indeed
1593 this is a reply."
1594   (interactive "P")
1595   (gnus-summary-select-article t)
1596   (set-buffer gnus-original-article-buffer)
1597   (gnus-setup-message 'compose-bounce
1598     (let* ((references (mail-fetch-field "references"))
1599            (parent (and references (gnus-parent-id references))))
1600       (message-bounce)
1601       ;; If there are references, we fetch the article we answered to.
1602       (and fetch parent
1603            (gnus-summary-refer-article parent)
1604            (gnus-summary-show-all-headers)))))
1605
1606 ;;; Gcc handling.
1607
1608 (defun gnus-inews-group-method (group)
1609   (cond
1610    ;; If the group doesn't exist, we assume
1611    ;; it's an archive group...
1612    ((and (null (gnus-get-info group))
1613          (eq (car (gnus-server-to-method gnus-message-archive-method))
1614              (car (gnus-server-to-method (gnus-group-method group)))))
1615     gnus-message-archive-method)
1616    ;; Use the method.
1617    ((gnus-info-method (gnus-get-info group))
1618     (gnus-info-method (gnus-get-info group)))
1619    ;; Find the method.
1620    (t (gnus-server-to-method (gnus-group-method group)))))
1621
1622 ;; Do Gcc handling, which copied the message over to some group.
1623 (defun gnus-inews-do-gcc (&optional gcc)
1624   (interactive)
1625   (save-excursion
1626     (save-restriction
1627       (message-narrow-to-headers)
1628       (let ((gcc (or gcc (mail-fetch-field "gcc" nil t)))
1629             (cur (current-buffer))
1630             groups group method group-art
1631             mml-externalize-attachments)
1632         (when gcc
1633           (message-remove-header "gcc")
1634           (widen)
1635           (setq groups (message-unquote-tokens
1636                         (message-tokenize-header gcc " ,")))
1637           ;; Copy the article over to some group(s).
1638           (while (setq group (pop groups))
1639             (unless (gnus-check-server
1640                      (setq method (gnus-inews-group-method group)))
1641               (error "Can't open server %s" (if (stringp method) method
1642                                               (car method))))
1643             (unless (gnus-request-group group nil method)
1644               (gnus-request-create-group group method))
1645             (setq mml-externalize-attachments
1646                   (if (stringp gnus-gcc-externalize-attachments)
1647                       (string-match gnus-gcc-externalize-attachments group)
1648                     gnus-gcc-externalize-attachments))
1649             (save-excursion
1650               (nnheader-set-temp-buffer " *acc*")
1651               (insert-buffer-substring cur)
1652               (message-encode-message-body)
1653               (save-restriction
1654                 (message-narrow-to-headers)
1655                 (let* ((mail-parse-charset message-default-charset)
1656                        (newsgroups-field (save-restriction
1657                                            (message-narrow-to-headers-or-head)
1658                                            (message-fetch-field "Newsgroups")))
1659                        (followup-field (save-restriction
1660                                          (message-narrow-to-headers-or-head)
1661                                          (message-fetch-field "Followup-To")))
1662                        ;; BUG: We really need to get the charset for
1663                        ;; each name in the Newsgroups and Followup-To
1664                        ;; lines to allow crossposting between group
1665                        ;; namess with incompatible character sets.
1666                        ;; -- Per Abrahamsen <abraham@dina.kvl.dk> 2001-10-08.
1667                        (group-field-charset
1668                         (gnus-group-name-charset
1669                          method (or newsgroups-field "")))
1670                        (followup-field-charset
1671                         (gnus-group-name-charset
1672                          method (or followup-field "")))
1673                        (rfc2047-header-encoding-alist
1674                         (append
1675                          (when group-field-charset
1676                            (list (cons "Newsgroups" group-field-charset)))
1677                          (when followup-field-charset
1678                            (list (cons "Followup-To" followup-field-charset)))
1679                          rfc2047-header-encoding-alist)))
1680                   (mail-encode-encoded-word-buffer)))
1681               (goto-char (point-min))
1682               (when (re-search-forward
1683                      (concat "^" (regexp-quote mail-header-separator) "$")
1684                      nil t)
1685                 (replace-match "" t t ))
1686               (unless (setq group-art
1687                             (gnus-request-accept-article group method t t))
1688                 (gnus-message 1 "Couldn't store article in group %s: %s"
1689                               group (gnus-status-message method))
1690                 (sit-for 2))
1691               (when (and group-art
1692                          ;; FIXME: Should gcc-mark-as-read work when
1693                          ;; Gnus is not running?
1694                          (gnus-alive-p)
1695                          (or gnus-gcc-mark-as-read
1696                              (and
1697                               (boundp 'gnus-inews-mark-gcc-as-read)
1698                               (symbol-value 'gnus-inews-mark-gcc-as-read))))
1699                 (gnus-group-mark-article-read group (cdr group-art)))
1700               (kill-buffer (current-buffer)))))))))
1701
1702 (defun gnus-inews-insert-gcc ()
1703   "Insert Gcc headers based on `gnus-outgoing-message-group'."
1704   (save-excursion
1705     (save-restriction
1706       (message-narrow-to-headers)
1707       (let* ((group gnus-outgoing-message-group)
1708              (gcc (cond
1709                    ((functionp group)
1710                     (funcall group))
1711                    ((or (stringp group) (list group))
1712                     group))))
1713         (when gcc
1714           (insert "Gcc: "
1715                   (if (stringp gcc)
1716                       (if (string-match " " gcc)
1717                           (concat "\"" gcc "\"")
1718                         gcc)
1719                     (mapconcat (lambda (group)
1720                                  (if (string-match " " group)
1721                                      (concat "\"" group "\"")
1722                                    group))
1723                                gcc " "))
1724                   "\n"))))))
1725
1726 (defun gnus-inews-insert-archive-gcc (&optional group)
1727   "Insert the Gcc to say where the article is to be archived."
1728   (let* ((var gnus-message-archive-group)
1729          (group (or group gnus-newsgroup-name ""))
1730          (gcc-self-val
1731           (and gnus-newsgroup-name
1732                (not (equal gnus-newsgroup-name ""))
1733                (gnus-group-find-parameter
1734                 gnus-newsgroup-name 'gcc-self)))
1735          result
1736          (groups
1737           (cond
1738            ((null gnus-message-archive-method)
1739             ;; Ignore.
1740             nil)
1741            ((stringp var)
1742             ;; Just a single group.
1743             (list var))
1744            ((null var)
1745             ;; We don't want this.
1746             nil)
1747            ((and (listp var) (stringp (car var)))
1748             ;; A list of groups.
1749             var)
1750            ((functionp var)
1751             ;; A function.
1752             (funcall var group))
1753            (t
1754             ;; An alist of regexps/functions/forms.
1755             (while (and var
1756                         (not
1757                          (setq result
1758                                (cond
1759                                 ((stringp (caar var))
1760                                  ;; Regexp.
1761                                  (when (string-match (caar var) group)
1762                                    (cdar var)))
1763                                 ((functionp (car var))
1764                                  ;; Function.
1765                                  (funcall (car var) group))
1766                                 (t
1767                                  (eval (car var)))))))
1768               (setq var (cdr var)))
1769             result)))
1770          name)
1771     (when (or groups gcc-self-val)
1772       (when (stringp groups)
1773         (setq groups (list groups)))
1774       (save-excursion
1775         (save-restriction
1776           (message-narrow-to-headers)
1777           (goto-char (point-max))
1778           (insert "Gcc: ")
1779           (if gcc-self-val
1780               ;; Use the `gcc-self' param value instead.
1781               (progn
1782                 (insert
1783                  (if (stringp gcc-self-val)
1784                      (if (string-match " " gcc-self-val)
1785                          (concat "\"" gcc-self-val "\"")
1786                        gcc-self-val)
1787                    (if (string-match " " group)
1788                        (concat "\"" group "\"")
1789                      group)))
1790                 (if (not (eq gcc-self-val 'none))
1791                     (insert "\n")
1792                   (gnus-delete-line)))
1793             ;; Use the list of groups.
1794             (while (setq name (pop groups))
1795               (let ((str (if (string-match ":" name)
1796                              name
1797                            (gnus-group-prefixed-name
1798                             name gnus-message-archive-method))))
1799                 (insert (if (string-match " " str)
1800                             (concat "\"" str "\"")
1801                           str)))
1802               (when groups
1803                 (insert " ")))
1804             (insert "\n")))))))
1805
1806 (defun gnus-mailing-list-followup-to ()
1807   "Look at the headers in the current buffer and return a Mail-Followup-To address."
1808   (let ((x-been-there (gnus-fetch-original-field "x-beenthere"))
1809         (list-post (gnus-fetch-original-field "list-post")))
1810     (when (and list-post
1811                (string-match "mailto:\\([^>]+\\)" list-post))
1812       (setq list-post (match-string 1 list-post)))
1813     (or list-post
1814         x-been-there)))
1815
1816 ;;; Posting styles.
1817
1818 (defun gnus-configure-posting-styles (&optional group-name)
1819   "Configure posting styles according to `gnus-posting-styles'."
1820   (unless gnus-inhibit-posting-styles
1821     (let ((group (or group-name gnus-newsgroup-name ""))
1822           (styles gnus-posting-styles)
1823           style match attribute value v results
1824           filep name address element)
1825       ;; If the group has a posting-style parameter, add it at the end with a
1826       ;; regexp matching everything, to be sure it takes precedence over all
1827       ;; the others.
1828       (when gnus-newsgroup-name
1829         (let ((tmp-style (gnus-group-find-parameter group 'posting-style t)))
1830           (when tmp-style
1831             (setq styles (append styles (list (cons ".*" tmp-style)))))))
1832       ;; Go through all styles and look for matches.
1833       (dolist (style styles)
1834         (setq match (pop style))
1835         (goto-char (point-min))
1836         (when (cond
1837                ((stringp match)
1838                 ;; Regexp string match on the group name.
1839                 (string-match match group))
1840                ((eq match 'header)
1841                 ;; Obsolete format of header match.
1842                 (and (gnus-buffer-live-p gnus-article-copy)
1843                      (with-current-buffer gnus-article-copy
1844                        (let ((header (message-fetch-field (pop style))))
1845                          (and header
1846                               (string-match (pop style) header))))))
1847                ((or (symbolp match)
1848                     (functionp match))
1849                 (cond
1850                  ((functionp match)
1851                   ;; Function to be called.
1852                   (funcall match))
1853                  ((boundp match)
1854                   ;; Variable to be checked.
1855                   (symbol-value match))))
1856                ((listp match)
1857                 (cond
1858                  ((eq (car match) 'header)
1859                   ;; New format of header match.
1860                   (and (gnus-buffer-live-p gnus-article-copy)
1861                        (with-current-buffer gnus-article-copy
1862                          (let ((header (message-fetch-field (nth 1 match))))
1863                            (and header
1864                                 (string-match (nth 2 match) header))))))
1865                  (t
1866                   ;; This is a form to be evaled.
1867                   (eval match)))))
1868           ;; We have a match, so we set the variables.
1869           (dolist (attribute style)
1870             (setq element (pop attribute)
1871                   filep nil)
1872             (setq value
1873                   (cond
1874                    ((eq (car attribute) :file)
1875                     (setq filep t)
1876                     (cadr attribute))
1877                    ((eq (car attribute) :value)
1878                     (cadr attribute))
1879                    (t
1880                     (car attribute))))
1881             ;; We get the value.
1882             (setq v
1883                   (cond
1884                    ((stringp value)
1885                     value)
1886                    ((or (symbolp value)
1887                         (functionp value))
1888                     (cond ((functionp value)
1889                            (funcall value))
1890                           ((boundp value)
1891                            (symbol-value value))))
1892                    ((listp value)
1893                     (eval value))))
1894             ;; Translate obsolescent value.
1895             (cond
1896              ((eq element 'signature-file)
1897               (setq element 'signature
1898                     filep t))
1899              ((eq element 'x-face-file)
1900               (setq element 'x-face
1901                     filep t)))
1902             ;; Get the contents of file elems.
1903             (when (and filep v)
1904               (setq v (with-temp-buffer
1905                         (insert-file-contents v)
1906                         (goto-char (point-max))
1907                         (while (bolp)
1908                           (delete-char -1))
1909                         (buffer-string))))
1910             (setq results (delq (assoc element results) results))
1911             (push (cons element v) results))))
1912       ;; Now we have all the styles, so we insert them.
1913       (setq name (assq 'name results)
1914             address (assq 'address results))
1915       (setq results (delq name (delq address results)))
1916       (gnus-make-local-hook 'message-setup-hook)
1917       (setq results (sort results (lambda (x y)
1918                                     (string-lessp (car x) (car y)))))
1919       (dolist (result results)
1920         (add-hook 'message-setup-hook
1921                   (cond
1922                    ((eq 'eval (car result))
1923                     'ignore)
1924                    ((eq 'body (car result))
1925                     `(lambda ()
1926                        (save-excursion
1927                          (message-goto-body)
1928                          (insert ,(cdr result)))))
1929                    ((eq 'signature (car result))
1930                     (set (make-local-variable 'message-signature) nil)
1931                     (set (make-local-variable 'message-signature-file) nil)
1932                     (if (not (cdr result))
1933                         'ignore
1934                       `(lambda ()
1935                          (save-excursion
1936                            (let ((message-signature ,(cdr result)))
1937                              (when message-signature
1938                                (message-insert-signature)))))))
1939                    (t
1940                     (let ((header
1941                            (if (symbolp (car result))
1942                                (capitalize (symbol-name (car result)))
1943                              (car result))))
1944                       `(lambda ()
1945                          (save-excursion
1946                            (message-remove-header ,header)
1947                            (let ((value ,(cdr result)))
1948                              (when value
1949                                (message-goto-eoh)
1950                                (insert ,header ": " value)
1951                                (unless (bolp)
1952                                  (insert "\n")))))))))
1953                   nil 'local))
1954       (when (or name address)
1955         (add-hook 'message-setup-hook
1956                   `(lambda ()
1957                      (set (make-local-variable 'user-mail-address)
1958                           ,(or (cdr address) user-mail-address))
1959                      (let ((user-full-name ,(or (cdr name) (user-full-name)))
1960                            (user-mail-address
1961                             ,(or (cdr address) user-mail-address)))
1962                        (save-excursion
1963                          (message-remove-header "From")
1964                          (message-goto-eoh)
1965                          (insert "From: " (message-make-from) "\n"))))
1966                   nil 'local)))))
1967
1968 ;;; Allow redefinition of functions.
1969
1970 (gnus-ems-redefine)
1971
1972 (provide 'gnus-msg)
1973
1974 ;;; gnus-msg.el ends here