cgit.sxemacs.org Git - gnus/blob - lisp/gnus-kill.el

   1 ;;; gnus-kill.el --- kill commands for Gnus
   2 ;; Copyright (C) 1995,96 Free Software Foundation, Inc.
   3
   4 ;; Author: Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>
   5 ;;      Lars Magne Ingebrigtsen <larsi@ifi.uio.no>
   6 ;; Keywords: news
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;;; Code:
  28
  29 (require 'gnus)
  30 (eval-when-compile (require 'cl))
  31
  32 (defvar gnus-kill-file-mode-hook nil
  33   "*A hook for Gnus kill file mode.")
  34
  35 (defvar gnus-kill-expiry-days 7
  36   "*Number of days before expiring unused kill file entries.")
  37
  38 (defvar gnus-kill-save-kill-file nil
  39   "*If non-nil, will save kill files after processing them.")
  40
  41 (defvar gnus-winconf-kill-file nil)
  42
  43 \f
  44
  45 (defmacro gnus-raise (field expression level)
  46   `(gnus-kill ,field ,expression
  47               (function (gnus-summary-raise-score ,level)) t))
  48
  49 (defmacro gnus-lower (field expression level)
  50   `(gnus-kill ,field ,expression
  51               (function (gnus-summary-raise-score (- ,level))) t))
  52
  53 ;;;
  54 ;;; Gnus Kill File Mode
  55 ;;;
  56
  57 (defvar gnus-kill-file-mode-map nil)
  58
  59 (unless gnus-kill-file-mode-map
  60   (gnus-define-keymap
  61    (setq gnus-kill-file-mode-map (copy-keymap emacs-lisp-mode-map))
  62    "\C-c\C-k\C-s" gnus-kill-file-kill-by-subject
  63    "\C-c\C-k\C-a" gnus-kill-file-kill-by-author
  64    "\C-c\C-k\C-t" gnus-kill-file-kill-by-thread
  65    "\C-c\C-k\C-x" gnus-kill-file-kill-by-xref
  66    "\C-c\C-a" gnus-kill-file-apply-buffer
  67    "\C-c\C-e" gnus-kill-file-apply-last-sexp
  68    "\C-c\C-c" gnus-kill-file-exit))
  69
  70 (defun gnus-kill-file-mode ()
  71   "Major mode for editing kill files.
  72
  73 If you are using this mode - you probably shouldn't.  Kill files
  74 perform badly and paint with a pretty broad brush.  Score files, on
  75 the other hand, are vastly faster (40x speedup) and give you more
  76 control over what to do.
  77
  78 In addition to Emacs-Lisp Mode, the following commands are available:
  79
  80 \\{gnus-kill-file-mode-map}
  81
  82   A kill file contains Lisp expressions to be applied to a selected
  83 newsgroup.  The purpose is to mark articles as read on the basis of
  84 some set of regexps.  A global kill file is applied to every newsgroup,
  85 and a local kill file is applied to a specified newsgroup.  Since a
  86 global kill file is applied to every newsgroup, for better performance
  87 use a local one.
  88
  89   A kill file can contain any kind of Emacs Lisp expressions expected
  90 to be evaluated in the Summary buffer.  Writing Lisp programs for this
  91 purpose is not so easy because the internal working of Gnus must be
  92 well-known.  For this reason, Gnus provides a general function which
  93 does this easily for non-Lisp programmers.
  94
  95   The `gnus-kill' function executes commands available in Summary Mode
  96 by their key sequences. `gnus-kill' should be called with FIELD,
  97 REGEXP and optional COMMAND and ALL.  FIELD is a string representing
  98 the header field or an empty string.  If FIELD is an empty string, the
  99 entire article body is searched for.  REGEXP is a string which is
 100 compared with FIELD value. COMMAND is a string representing a valid
 101 key sequence in Summary mode or Lisp expression. COMMAND defaults to
 102 '(gnus-summary-mark-as-read nil \"X\").  Make sure that COMMAND is
 103 executed in the Summary buffer.  If the second optional argument ALL
 104 is non-nil, the COMMAND is applied to articles which are already
 105 marked as read or unread.  Articles which are marked are skipped over
 106 by default.
 107
 108   For example, if you want to mark articles of which subjects contain
 109 the string `AI' as read, a possible kill file may look like:
 110
 111         (gnus-kill \"Subject\" \"AI\")
 112
 113   If you want to mark articles with `D' instead of `X', you can use
 114 the following expression:
 115
 116         (gnus-kill \"Subject\" \"AI\" \"d\")
 117
 118 In this example it is assumed that the command
 119 `gnus-summary-mark-as-read-forward' is assigned to `d' in Summary Mode.
 120
 121   It is possible to delete unnecessary headers which are marked with
 122 `X' in a kill file as follows:
 123
 124         (gnus-expunge \"X\")
 125
 126   If the Summary buffer is empty after applying kill files, Gnus will
 127 exit the selected newsgroup normally.  If headers which are marked
 128 with `D' are deleted in a kill file, it is impossible to read articles
 129 which are marked as read in the previous Gnus sessions.  Marks other
 130 than `D' should be used for articles which should really be deleted.
 131
 132 Entry to this mode calls emacs-lisp-mode-hook and
 133 gnus-kill-file-mode-hook with no arguments, if that value is non-nil."
 134   (interactive)
 135   (kill-all-local-variables)
 136   (use-local-map gnus-kill-file-mode-map)
 137   (set-syntax-table emacs-lisp-mode-syntax-table)
 138   (setq major-mode 'gnus-kill-file-mode)
 139   (setq mode-name "Kill")
 140   (lisp-mode-variables nil)
 141   (run-hooks 'emacs-lisp-mode-hook 'gnus-kill-file-mode-hook))
 142
 143 (defun gnus-kill-file-edit-file (newsgroup)
 144   "Begin editing a kill file for NEWSGROUP.
 145 If NEWSGROUP is nil, the global kill file is selected."
 146   (interactive "sNewsgroup: ")
 147   (let ((file (gnus-newsgroup-kill-file newsgroup)))
 148     (gnus-make-directory (file-name-directory file))
 149     ;; Save current window configuration if this is first invocation.
 150     (or (and (get-file-buffer file)
 151              (get-buffer-window (get-file-buffer file)))
 152         (setq gnus-winconf-kill-file (current-window-configuration)))
 153     ;; Hack windows.
 154     (let ((buffer (find-file-noselect file)))
 155       (cond ((get-buffer-window buffer)
 156              (pop-to-buffer buffer))
 157             ((eq major-mode 'gnus-group-mode)
 158              (gnus-configure-windows 'group) ;Take all windows.
 159              (pop-to-buffer buffer))
 160             ((eq major-mode 'gnus-summary-mode)
 161              (gnus-configure-windows 'article)
 162              (pop-to-buffer gnus-article-buffer)
 163              (bury-buffer gnus-article-buffer)
 164              (switch-to-buffer buffer))
 165             (t                          ;No good rules.
 166              (find-file-other-window file))))
 167     (gnus-kill-file-mode)))
 168
 169 ;; Fix by Sudish Joseph <joseph@cis.ohio-state.edu>.
 170 (defun gnus-kill-set-kill-buffer ()
 171   (let* ((file (gnus-newsgroup-kill-file gnus-newsgroup-name))
 172          (buffer (find-file-noselect file)))
 173     (set-buffer buffer)
 174     (gnus-kill-file-mode)
 175     (bury-buffer buffer)))
 176
 177 (defun gnus-kill-file-enter-kill (field regexp &optional dont-move)
 178   ;; Enter kill file entry.
 179   ;; FIELD: String containing the name of the header field to kill.
 180   ;; REGEXP: The string to kill.
 181   (save-excursion
 182     (let (string)
 183       (or (eq major-mode 'gnus-kill-file-mode)
 184           (gnus-kill-set-kill-buffer))
 185       (unless dont-move
 186         (goto-char (point-max)))
 187       (insert (setq string (format "(gnus-kill %S %S)\n" field regexp)))
 188       (gnus-kill-file-apply-string string))))
 189
 190 (defun gnus-kill-file-kill-by-subject ()
 191   "Kill by subject."
 192   (interactive)
 193   (gnus-kill-file-enter-kill
 194    "Subject"
 195    (if (vectorp gnus-current-headers)
 196        (regexp-quote
 197         (gnus-simplify-subject (mail-header-subject gnus-current-headers)))
 198      "") t))
 199
 200 (defun gnus-kill-file-kill-by-author ()
 201   "Kill by author."
 202   (interactive)
 203   (gnus-kill-file-enter-kill
 204    "From"
 205    (if (vectorp gnus-current-headers)
 206        (regexp-quote (mail-header-from gnus-current-headers))
 207      "") t))
 208
 209 (defun gnus-kill-file-kill-by-thread ()
 210   "Kill by author."
 211   (interactive)
 212   (gnus-kill-file-enter-kill
 213    "References"
 214    (if (vectorp gnus-current-headers)
 215        (regexp-quote (mail-header-id gnus-current-headers))
 216      "")))
 217
 218 (defun gnus-kill-file-kill-by-xref ()
 219   "Kill by Xref."
 220   (interactive)
 221   (let ((xref (and (vectorp gnus-current-headers)
 222                    (mail-header-xref gnus-current-headers)))
 223         (start 0)
 224         group)
 225     (if xref
 226         (while (string-match " \\([^ \t]+\\):" xref start)
 227           (setq start (match-end 0))
 228           (if (not (string=
 229                     (setq group
 230                           (substring xref (match-beginning 1) (match-end 1)))
 231                     gnus-newsgroup-name))
 232               (gnus-kill-file-enter-kill
 233                "Xref" (concat " " (regexp-quote group) ":") t)))
 234       (gnus-kill-file-enter-kill "Xref" "" t))))
 235
 236 (defun gnus-kill-file-raise-followups-to-author (level)
 237   "Raise score for all followups to the current author."
 238   (interactive "p")
 239   (let ((name (mail-header-from gnus-current-headers))
 240         string)
 241     (save-excursion
 242       (gnus-kill-set-kill-buffer)
 243       (goto-char (point-min))
 244       (setq name (read-string (concat "Add " level
 245                                       " to followup articles to: ")
 246                               (regexp-quote name)))
 247       (setq
 248        string
 249        (format
 250         "(gnus-kill %S %S '(gnus-summary-temporarily-raise-by-thread %S))\n"
 251         "From" name level))
 252       (insert string)
 253       (gnus-kill-file-apply-string string))
 254     (gnus-message
 255      6 "Added temporary score file entry for followups to %s." name)))
 256
 257 (defun gnus-kill-file-apply-buffer ()
 258   "Apply current buffer to current newsgroup."
 259   (interactive)
 260   (if (and gnus-current-kill-article
 261            (get-buffer gnus-summary-buffer))
 262       ;; Assume newsgroup is selected.
 263       (gnus-kill-file-apply-string (buffer-string))
 264     (ding) (gnus-message 2 "No newsgroup is selected.")))
 265
 266 (defun gnus-kill-file-apply-string (string)
 267   "Apply STRING to current newsgroup."
 268   (interactive)
 269   (let ((string (concat "(progn \n" string "\n)")))
 270     (save-excursion
 271       (save-window-excursion
 272         (pop-to-buffer gnus-summary-buffer)
 273         (eval (car (read-from-string string)))))))
 274
 275 (defun gnus-kill-file-apply-last-sexp ()
 276   "Apply sexp before point in current buffer to current newsgroup."
 277   (interactive)
 278   (if (and gnus-current-kill-article
 279            (get-buffer gnus-summary-buffer))
 280       ;; Assume newsgroup is selected.
 281       (let ((string
 282              (buffer-substring
 283               (save-excursion (forward-sexp -1) (point)) (point))))
 284         (save-excursion
 285           (save-window-excursion
 286             (pop-to-buffer gnus-summary-buffer)
 287             (eval (car (read-from-string string))))))
 288     (ding) (gnus-message 2 "No newsgroup is selected.")))
 289
 290 (defun gnus-kill-file-exit ()
 291   "Save a kill file, then return to the previous buffer."
 292   (interactive)
 293   (save-buffer)
 294   (let ((killbuf (current-buffer)))
 295     ;; We don't want to return to article buffer.
 296     (and (get-buffer gnus-article-buffer)
 297          (bury-buffer gnus-article-buffer))
 298     ;; Delete the KILL file windows.
 299     (delete-windows-on killbuf)
 300     ;; Restore last window configuration if available.
 301     (and gnus-winconf-kill-file
 302          (set-window-configuration gnus-winconf-kill-file))
 303     (setq gnus-winconf-kill-file nil)
 304     ;; Kill the KILL file buffer.  Suggested by tale@pawl.rpi.edu.
 305     (kill-buffer killbuf)))
 306
 307 ;; For kill files
 308
 309 (defun gnus-Newsgroup-kill-file (newsgroup)
 310   "Return the name of a kill file for NEWSGROUP.
 311 If NEWSGROUP is nil, return the global kill file instead."
 312   (cond ((or (null newsgroup)
 313              (string-equal newsgroup ""))
 314          ;; The global kill file is placed at top of the directory.
 315          (expand-file-name gnus-kill-file-name
 316                            (or gnus-kill-files-directory "~/News")))
 317         (gnus-use-long-file-name
 318          ;; Append ".KILL" to capitalized newsgroup name.
 319          (expand-file-name (concat (gnus-capitalize-newsgroup newsgroup)
 320                                    "." gnus-kill-file-name)
 321                            (or gnus-kill-files-directory "~/News")))
 322         (t
 323          ;; Place "KILL" under the hierarchical directory.
 324          (expand-file-name (concat (gnus-newsgroup-directory-form newsgroup)
 325                                    "/" gnus-kill-file-name)
 326                            (or gnus-kill-files-directory "~/News")))))
 327
 328 (defun gnus-expunge (marks)
 329   "Remove lines marked with MARKS."
 330   (save-excursion
 331     (set-buffer gnus-summary-buffer)
 332     (gnus-summary-limit-to-marks marks 'reverse)))
 333
 334 (defun gnus-apply-kill-file-unless-scored ()
 335   "Apply .KILL file, unless a .SCORE file for the same newsgroup exists."
 336   (cond ((file-exists-p (gnus-score-file-name gnus-newsgroup-name))
 337          ;; Ignores global KILL.
 338          (if (file-exists-p (gnus-newsgroup-kill-file gnus-newsgroup-name))
 339              (gnus-message 3 "Note: Ignoring %s.KILL; preferring .SCORE"
 340                              gnus-newsgroup-name))
 341          0)
 342         ((or (file-exists-p (gnus-newsgroup-kill-file nil))
 343              (file-exists-p (gnus-newsgroup-kill-file gnus-newsgroup-name)))
 344          (gnus-apply-kill-file-internal))
 345         (t
 346          0)))
 347
 348 (defun gnus-apply-kill-file-internal ()
 349   "Apply a kill file to the current newsgroup.
 350 Returns the number of articles marked as read."
 351   (let* ((kill-files (list (gnus-newsgroup-kill-file nil)
 352                            (gnus-newsgroup-kill-file gnus-newsgroup-name)))
 353          (unreads (length gnus-newsgroup-unreads))
 354          (gnus-summary-inhibit-highlight t)
 355          beg)
 356     (setq gnus-newsgroup-kill-headers nil)
 357     ;; If there are any previously scored articles, we remove these
 358     ;; from the `gnus-newsgroup-headers' list that the score functions
 359     ;; will see. This is probably pretty wasteful when it comes to
 360     ;; conses, but is, I think, faster than having to assq in every
 361     ;; single score function.
 362     (let ((files kill-files))
 363       (while files
 364         (if (file-exists-p (car files))
 365             (let ((headers gnus-newsgroup-headers))
 366               (if gnus-kill-killed
 367                   (setq gnus-newsgroup-kill-headers
 368                         (mapcar (lambda (header) (mail-header-number header))
 369                                 headers))
 370                 (while headers
 371                   (or (gnus-member-of-range
 372                        (mail-header-number (car headers))
 373                        gnus-newsgroup-killed)
 374                       (setq gnus-newsgroup-kill-headers
 375                             (cons (mail-header-number (car headers))
 376                                   gnus-newsgroup-kill-headers)))
 377                   (setq headers (cdr headers))))
 378               (setq files nil))
 379           (setq files (cdr files)))))
 380     (if (not gnus-newsgroup-kill-headers)
 381         ()
 382       (save-window-excursion
 383         (save-excursion
 384           (while kill-files
 385             (if (not (file-exists-p (car kill-files)))
 386                 ()
 387               (gnus-message 6 "Processing kill file %s..." (car kill-files))
 388               (find-file (car kill-files))
 389               (gnus-add-current-to-buffer-list)
 390               (goto-char (point-min))
 391
 392               (if (consp (condition-case nil (read (current-buffer))
 393                            (error nil)))
 394                   (gnus-kill-parse-gnus-kill-file)
 395                 (gnus-kill-parse-rn-kill-file))
 396
 397               (gnus-message
 398                6 "Processing kill file %s...done" (car kill-files)))
 399             (setq kill-files (cdr kill-files)))))
 400
 401       (gnus-set-mode-line 'summary)
 402
 403       (if beg
 404           (let ((nunreads (- unreads (length gnus-newsgroup-unreads))))
 405             (or (eq nunreads 0)
 406                 (gnus-message 6 "Marked %d articles as read" nunreads))
 407             nunreads)
 408         0))))
 409
 410 ;; Parse a Gnus killfile.
 411 (defun gnus-score-insert-help (string alist idx)
 412   (save-excursion
 413     (pop-to-buffer "*Score Help*")
 414     (buffer-disable-undo (current-buffer))
 415     (erase-buffer)
 416     (insert string ":\n\n")
 417     (while alist
 418       (insert (format " %c: %s\n" (caar alist) (nth idx (car alist))))
 419       (setq alist (cdr alist)))))
 420
 421 (defun gnus-kill-parse-gnus-kill-file ()
 422   (goto-char (point-min))
 423   (gnus-kill-file-mode)
 424   (let (beg form)
 425     (while (progn
 426              (setq beg (point))
 427              (setq form (condition-case () (read (current-buffer))
 428                           (error nil))))
 429       (or (listp form)
 430           (error "Illegal kill entry (possibly rn kill file?): %s" form))
 431       (if (or (eq (car form) 'gnus-kill)
 432               (eq (car form) 'gnus-raise)
 433               (eq (car form) 'gnus-lower))
 434           (progn
 435             (delete-region beg (point))
 436             (insert (or (eval form) "")))
 437         (save-excursion
 438           (set-buffer gnus-summary-buffer)
 439           (condition-case () (eval form) (error nil)))))
 440     (and (buffer-modified-p)
 441          gnus-kill-save-kill-file
 442          (save-buffer))
 443     (set-buffer-modified-p nil)))
 444
 445 ;; Parse an rn killfile.
 446 (defun gnus-kill-parse-rn-kill-file ()
 447   (goto-char (point-min))
 448   (gnus-kill-file-mode)
 449   (let ((mod-to-header
 450          '((?a . "")
 451            (?h . "")
 452            (?f . "from")
 453            (?: . "subject")))
 454         (com-to-com
 455          '((?m . " ")
 456            (?j . "X")))
 457         pattern modifier commands)
 458     (while (not (eobp))
 459       (if (not (looking-at "[ \t]*/\\([^/]*\\)/\\([ahfcH]\\)?:\\([a-z=:]*\\)"))
 460           ()
 461         (setq pattern (buffer-substring (match-beginning 1) (match-end 1)))
 462         (setq modifier (if (match-beginning 2) (char-after (match-beginning 2))
 463                          ?s))
 464         (setq commands (buffer-substring (match-beginning 3) (match-end 3)))
 465
 466         ;; The "f:+" command marks everything *but* the matches as read,
 467         ;; so we simply first match everything as read, and then unmark
 468         ;; PATTERN later.
 469         (and (string-match "\\+" commands)
 470              (progn
 471                (gnus-kill "from" ".")
 472                (setq commands "m")))
 473
 474         (gnus-kill
 475          (or (cdr (assq modifier mod-to-header)) "subject")
 476          pattern
 477          (if (string-match "m" commands)
 478              '(gnus-summary-mark-as-unread nil " ")
 479            '(gnus-summary-mark-as-read nil "X"))
 480          nil t))
 481       (forward-line 1))))
 482
 483 ;; Kill changes and new format by suggested by JWZ and Sudish Joseph
 484 ;; <joseph@cis.ohio-state.edu>.
 485 (defun gnus-kill (field regexp &optional exe-command all silent)
 486   "If FIELD of an article matches REGEXP, execute COMMAND.
 487 Optional 1st argument COMMAND is default to
 488         (gnus-summary-mark-as-read nil \"X\").
 489 If optional 2nd argument ALL is non-nil, articles marked are also applied to.
 490 If FIELD is an empty string (or nil), entire article body is searched for.
 491 COMMAND must be a lisp expression or a string representing a key sequence."
 492   ;; We don't want to change current point nor window configuration.
 493   (let ((old-buffer (current-buffer)))
 494     (save-excursion
 495       (save-window-excursion
 496         ;; Selected window must be summary buffer to execute keyboard
 497         ;; macros correctly. See command_loop_1.
 498         (switch-to-buffer gnus-summary-buffer 'norecord)
 499         (goto-char (point-min))         ;From the beginning.
 500         (let ((kill-list regexp)
 501               (date (current-time-string))
 502               (command (or exe-command '(gnus-summary-mark-as-read
 503                                          nil gnus-kill-file-mark)))
 504               kill kdate prev)
 505           (if (listp kill-list)
 506               ;; It is a list.
 507               (if (not (consp (cdr kill-list)))
 508                   ;; It's on the form (regexp . date).
 509                   (if (zerop (gnus-execute field (car kill-list)
 510                                            command nil (not all)))
 511                       (if (> (gnus-days-between date (cdr kill-list))
 512                              gnus-kill-expiry-days)
 513                           (setq regexp nil))
 514                     (setcdr kill-list date))
 515                 (while (setq kill (car kill-list))
 516                   (if (consp kill)
 517                       ;; It's a temporary kill.
 518                       (progn
 519                         (setq kdate (cdr kill))
 520                         (if (zerop (gnus-execute
 521                                     field (car kill) command nil (not all)))
 522                             (if (> (gnus-days-between date kdate)
 523                                    gnus-kill-expiry-days)
 524                                 ;; Time limit has been exceeded, so we
 525                                 ;; remove the match.
 526                                 (if prev
 527                                     (setcdr prev (cdr kill-list))
 528                                   (setq regexp (cdr regexp))))
 529                           ;; Successful kill. Set the date to today.
 530                           (setcdr kill date)))
 531                     ;; It's a permanent kill.
 532                     (gnus-execute field kill command nil (not all)))
 533                   (setq prev kill-list)
 534                   (setq kill-list (cdr kill-list))))
 535             (gnus-execute field kill-list command nil (not all))))))
 536     (switch-to-buffer old-buffer)
 537     (if (and (eq major-mode 'gnus-kill-file-mode) regexp (not silent))
 538         (gnus-pp-gnus-kill
 539          (nconc (list 'gnus-kill field
 540                       (if (consp regexp) (list 'quote regexp) regexp))
 541                 (if (or exe-command all) (list (list 'quote exe-command)))
 542                 (if all (list t) nil))))))
 543
 544 (defun gnus-pp-gnus-kill (object)
 545   (if (or (not (consp (nth 2 object)))
 546           (not (consp (cdr (nth 2 object))))
 547           (and (eq 'quote (car (nth 2 object)))
 548                (not (consp (cdadr (nth 2 object))))))
 549       (concat "\n" (prin1-to-string object))
 550     (save-excursion
 551       (set-buffer (get-buffer-create "*Gnus PP*"))
 552       (buffer-disable-undo (current-buffer))
 553       (erase-buffer)
 554       (insert (format "\n(%S %S\n  '(" (nth 0 object) (nth 1 object)))
 555       (let ((klist (cadr (nth 2 object)))
 556             (first t))
 557         (while klist
 558           (insert (if first (progn (setq first nil) "")  "\n    ")
 559                   (prin1-to-string (car klist)))
 560           (setq klist (cdr klist))))
 561       (insert ")")
 562       (and (nth 3 object)
 563            (insert "\n  "
 564                    (if (and (consp (nth 3 object))
 565                             (not (eq 'quote (car (nth 3 object)))))
 566                        "'" "")
 567                    (prin1-to-string (nth 3 object))))
 568       (and (nth 4 object)
 569            (insert "\n  t"))
 570       (insert ")")
 571       (prog1
 572           (buffer-substring (point-min) (point-max))
 573         (kill-buffer (current-buffer))))))
 574
 575 (defun gnus-execute-1 (function regexp form header)
 576   (save-excursion
 577     (let (did-kill)
 578       (if (null header)
 579           nil                           ;Nothing to do.
 580         (if function
 581             ;; Compare with header field.
 582             (let (value)
 583               (and header
 584                    (progn
 585                      (setq value (funcall function header))
 586                      ;; Number (Lines:) or symbol must be converted to string.
 587                      (or (stringp value)
 588                          (setq value (prin1-to-string value)))
 589                      (setq did-kill (string-match regexp value)))
 590                    (cond ((stringp form)        ;Keyboard macro.
 591                           (execute-kbd-macro form))
 592                          ((gnus-functionp form)
 593                           (funcall form))
 594                          (t
 595                           (eval form)))))
 596           ;; Search article body.
 597           (let ((gnus-current-article nil) ;Save article pointer.
 598                 (gnus-last-article nil)
 599                 (gnus-break-pages nil)  ;No need to break pages.
 600                 (gnus-mark-article-hook nil)) ;Inhibit marking as read.
 601             (gnus-message
 602              6 "Searching for article: %d..." (mail-header-number header))
 603             (gnus-article-setup-buffer)
 604             (gnus-article-prepare (mail-header-number header) t)
 605             (if (save-excursion
 606                   (set-buffer gnus-article-buffer)
 607                   (goto-char (point-min))
 608                   (setq did-kill (re-search-forward regexp nil t)))
 609                 (if (stringp form)      ;Keyboard macro.
 610                     (execute-kbd-macro form)
 611                   (eval form))))))
 612       did-kill)))
 613
 614 (defun gnus-execute (field regexp form &optional backward ignore-marked)
 615   "If FIELD of article header matches REGEXP, execute lisp FORM (or a string).
 616 If FIELD is an empty string (or nil), entire article body is searched for.
 617 If optional 1st argument BACKWARD is non-nil, do backward instead.
 618 If optional 2nd argument IGNORE-MARKED is non-nil, articles which are
 619 marked as read or ticked are ignored."
 620   (save-excursion
 621     (let ((killed-no 0)
 622           function article header)
 623       (cond
 624        ;; Search body.
 625        ((or (null field)
 626             (string-equal field ""))
 627         (setq function nil))
 628        ;; Get access function of header field.
 629        ((fboundp
 630          (setq function
 631                (intern-soft
 632                 (concat "mail-header-" (downcase field)))))
 633         (setq function `(lambda (h) (,function h))))
 634        ;; Signal error.
 635        (t
 636         (error "Unknown header field: \"%s\"" field)))
 637       ;; Starting from the current article.
 638       (while (or
 639               ;; First article.
 640               (and (not article)
 641                    (setq article (gnus-summary-article-number)))
 642               ;; Find later articles.
 643               (setq article
 644                     (gnus-summary-search-forward
 645                      (not ignore-marked) nil backward)))
 646         (and (or (null gnus-newsgroup-kill-headers)
 647                  (memq article gnus-newsgroup-kill-headers))
 648              (vectorp (setq header (gnus-summary-article-header article)))
 649              (gnus-execute-1 function regexp form header)
 650              (setq killed-no (1+ killed-no))))
 651       ;; Return the number of killed articles.
 652       killed-no)))
 653
 654 (provide 'gnus-kill)
 655
 656 ;;; gnus-kill.el ends here