cgit.sxemacs.org Git - gnus/blob - lisp/gnus-int.el

   1 ;;; gnus-int.el --- backend interface functions for Gnus
   2
   3 ;; Copyright (C) 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003, 2004
   4 ;;   2005, 2006, 2007, 2008, 2009, 2010 Free Software Foundation, Inc.
   5
   6 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   7 ;; Keywords: news
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;;; Code:
  27
  28 (eval-when-compile (require 'cl))
  29
  30 (require 'gnus)
  31 (require 'message)
  32 (require 'gnus-range)
  33
  34 (autoload 'gnus-agent-expire "gnus-agent")
  35 (autoload 'gnus-agent-regenerate-group "gnus-agent")
  36 (autoload 'gnus-agent-read-servers-validate-native "gnus-agent")
  37 (autoload 'gnus-agent-possibly-synchronize-flags-server "gnus-agent")
  38
  39 (defcustom gnus-open-server-hook nil
  40   "Hook called just before opening connection to the news server."
  41   :group 'gnus-start
  42   :type 'hook)
  43
  44 (defcustom gnus-server-unopen-status nil
  45   "The default status if the server is not able to open.
  46 If the server is covered by Gnus agent, the possible values are
  47 `denied', set the server denied; `offline', set the server offline;
  48 nil, ask user.  If the server is not covered by Gnus agent, set the
  49 server denied."
  50   :version "22.1"
  51   :group 'gnus-start
  52   :type '(choice (const :tag "Ask" nil)
  53                  (const :tag "Deny server" denied)
  54                  (const :tag "Unplug Agent" offline)))
  55
  56 (defvar gnus-internal-registry-spool-current-method nil
  57   "The current method, for the registry.")
  58
  59
  60 (defun gnus-server-opened (gnus-command-method)
  61   "Check whether a connection to GNUS-COMMAND-METHOD has been opened."
  62   (unless (eq (gnus-server-status gnus-command-method)
  63               'denied)
  64     (when (stringp gnus-command-method)
  65       (setq gnus-command-method (gnus-server-to-method gnus-command-method)))
  66     (funcall (inline (gnus-get-function gnus-command-method 'server-opened))
  67              (nth 1 gnus-command-method))))
  68
  69 (defun gnus-status-message (gnus-command-method)
  70   "Return the status message from GNUS-COMMAND-METHOD.
  71 If GNUS-COMMAND-METHOD is a string, it is interpreted as a group
  72 name.  The method this group uses will be queried."
  73   (let ((gnus-command-method
  74          (if (stringp gnus-command-method)
  75              (gnus-find-method-for-group gnus-command-method)
  76            gnus-command-method)))
  77     (funcall (gnus-get-function gnus-command-method 'status-message)
  78              (nth 1 gnus-command-method))))
  79
  80 ;;;
  81 ;;; Server Communication
  82 ;;;
  83
  84 (defun gnus-start-news-server (&optional confirm)
  85   "Open a method for getting news.
  86 If CONFIRM is non-nil, the user will be asked for an NNTP server."
  87   (let (how)
  88     (if gnus-current-select-method
  89         ;; Stream is already opened.
  90         nil
  91       ;; Open NNTP server.
  92       (unless gnus-nntp-service
  93         (setq gnus-nntp-server nil))
  94       (when confirm
  95         ;; Read server name with completion.
  96         (setq gnus-nntp-server
  97               (completing-read "NNTP server: "
  98                                (mapcar 'list
  99                                        (cons (list gnus-nntp-server)
 100                                              gnus-secondary-servers))
 101                                nil nil gnus-nntp-server)))
 102
 103       (when (and gnus-nntp-server
 104                  (stringp gnus-nntp-server)
 105                  (not (string= gnus-nntp-server "")))
 106         (setq gnus-select-method
 107               (cond ((or (string= gnus-nntp-server "")
 108                          (string= gnus-nntp-server "::"))
 109                      (list 'nnspool (system-name)))
 110                     ((string-match "^:" gnus-nntp-server)
 111                      (list 'nnmh gnus-nntp-server
 112                            (list 'nnmh-directory
 113                                  (file-name-as-directory
 114                                   (expand-file-name
 115                                    (substring gnus-nntp-server 1) "~/")))
 116                            (list 'nnmh-get-new-mail nil)))
 117                     (t
 118                      (list 'nntp gnus-nntp-server)))))
 119
 120       (setq how (car gnus-select-method))
 121       (cond
 122        ((eq how 'nnspool)
 123         (require 'nnspool)
 124         (gnus-message 5 "Looking up local news spool..."))
 125        ((eq how 'nnmh)
 126         (require 'nnmh)
 127         (gnus-message 5 "Looking up mh spool..."))
 128        (t
 129         (require 'nntp)))
 130       (setq gnus-current-select-method gnus-select-method)
 131       (gnus-run-hooks 'gnus-open-server-hook)
 132
 133       ;; Partially validate agent covered methods now that the
 134       ;; gnus-select-method is known.
 135
 136       (if gnus-agent
 137           ;; NOTE: This is here for one purpose only.  By validating
 138           ;; the current select method, it converts the old 5.10.3,
 139           ;; and earlier, format to the current format.  That enables
 140           ;; the agent code within gnus-open-server to function
 141           ;; correctly.
 142           (gnus-agent-read-servers-validate-native gnus-select-method))
 143
 144       (or
 145        ;; gnus-open-server-hook might have opened it
 146        (gnus-server-opened gnus-select-method)
 147        (gnus-open-server gnus-select-method)
 148        gnus-batch-mode
 149        (gnus-y-or-n-p
 150         (format
 151          "%s (%s) open error: '%s'.  Continue? "
 152          (car gnus-select-method) (cadr gnus-select-method)
 153          (gnus-status-message gnus-select-method)))
 154        (gnus-error 1 "Couldn't open server on %s"
 155                    (nth 1 gnus-select-method))))))
 156
 157 (defun gnus-check-group (group)
 158   "Try to make sure that the server where GROUP exists is alive."
 159   (let ((method (gnus-find-method-for-group group)))
 160     (or (gnus-server-opened method)
 161         (gnus-open-server method))))
 162
 163 (defun gnus-check-server (&optional method silent)
 164   "Check whether the connection to METHOD is down.
 165 If METHOD is nil, use `gnus-select-method'.
 166 If it is down, start it up (again)."
 167   (let ((method (or method gnus-select-method))
 168         result)
 169     ;; Transform virtual server names into select methods.
 170     (when (stringp method)
 171       (setq method (gnus-server-to-method method)))
 172     (if (gnus-server-opened method)
 173         ;; The stream is already opened.
 174         t
 175       ;; Open the server.
 176       (unless silent
 177         (gnus-message 5 "Opening %s server%s..." (car method)
 178                       (if (equal (nth 1 method) "") ""
 179                         (format " on %s" (nth 1 method)))))
 180       (gnus-run-hooks 'gnus-open-server-hook)
 181       (prog1
 182           (setq result (gnus-open-server method))
 183         (unless silent
 184           (gnus-message 5 "Opening %s server%s...%s" (car method)
 185                         (if (equal (nth 1 method) "") ""
 186                           (format " on %s" (nth 1 method)))
 187                         (if result "done" "failed")))))))
 188
 189 (defun gnus-get-function (method function &optional noerror)
 190   "Return a function symbol based on METHOD and FUNCTION."
 191   ;; Translate server names into methods.
 192   (unless method
 193     (error "Attempted use of a nil select method"))
 194   (when (stringp method)
 195     (setq method (gnus-server-to-method method)))
 196   ;; Check cache of constructed names.
 197   (let* ((method-sym (if gnus-agent
 198                          (inline (gnus-agent-get-function method))
 199                        (car method)))
 200          (method-fns (get method-sym 'gnus-method-functions))
 201          (func (let ((method-fnlist-elt (assq function method-fns)))
 202                  (unless method-fnlist-elt
 203                    (setq method-fnlist-elt
 204                          (cons function
 205                                (intern (format "%s-%s" method-sym function))))
 206                    (put method-sym 'gnus-method-functions
 207                         (cons method-fnlist-elt method-fns)))
 208                  (cdr method-fnlist-elt))))
 209     ;; Maybe complain if there is no function.
 210     (unless (fboundp func)
 211       (unless (car method)
 212         (error "Trying to require a method that doesn't exist"))
 213       (require (car method))
 214       (when (not (fboundp func))
 215         (if noerror
 216             (setq func nil)
 217           (error "No such function: %s" func))))
 218     func))
 219
 220 \f
 221 ;;;
 222 ;;; Interface functions to the backends.
 223 ;;;
 224
 225 (defun gnus-method-denied-p (method)
 226   (eq (nth 1 (assoc method gnus-opened-servers))
 227       'denied))
 228
 229 (defvar gnus-backend-trace t)
 230
 231 (defun gnus-open-server (gnus-command-method)
 232   "Open a connection to GNUS-COMMAND-METHOD."
 233   (when (stringp gnus-command-method)
 234     (setq gnus-command-method (gnus-server-to-method gnus-command-method)))
 235   (when gnus-backend-trace
 236     (with-current-buffer (get-buffer-create "*gnus trace*")
 237       (buffer-disable-undo)
 238       (goto-char (point-max))
 239       (insert (format-time-string "%H:%M:%S")
 240               (format " %S\n" gnus-command-method))))
 241   (let ((elem (assoc gnus-command-method gnus-opened-servers))
 242         (server (gnus-method-to-server-name gnus-command-method)))
 243     ;; If this method was previously denied, we just return nil.
 244     (if (eq (nth 1 elem) 'denied)
 245         (progn
 246           (gnus-message 1 "Denied server %s" server)
 247           nil)
 248       ;; Open the server.
 249       (let* ((open-server-function (gnus-get-function gnus-command-method 'open-server))
 250              (result
 251              (condition-case err
 252                  (funcall open-server-function
 253                           (nth 1 gnus-command-method)
 254                           (nthcdr 2 gnus-command-method))
 255                (error
 256                 (gnus-message 1 "Unable to open server %s due to: %s"
 257                               server (error-message-string err))
 258                 nil)
 259                (quit
 260                 (gnus-message 1 "Quit trying to open server %s" server)
 261                 nil)))
 262             open-offline)
 263         ;; If this hasn't been opened before, we add it to the list.
 264         (unless elem
 265           (setq elem (list gnus-command-method nil)
 266                 gnus-opened-servers (cons elem gnus-opened-servers)))
 267         ;; Set the status of this server.
 268         (setcar
 269          (cdr elem)
 270          (cond (result
 271                 (if (eq open-server-function #'nnagent-open-server)
 272                     ;; The agent's backend has a "special" status
 273                     'offline
 274                   'ok))
 275                ((and gnus-agent
 276                      (gnus-agent-method-p gnus-command-method))
 277                 (cond
 278                  (gnus-server-unopen-status
 279                   ;; Set the server's status to the unopen
 280                   ;; status.  If that status is offline,
 281                   ;; recurse to open the agent's backend.
 282                   (setq open-offline (eq gnus-server-unopen-status 'offline))
 283                   gnus-server-unopen-status)
 284                  ((not gnus-batch-mode)
 285                   (setq open-offline t)
 286                   'offline)
 287                  (t
 288                   ;; This agentized server was still denied
 289                   'denied)))
 290                (t
 291                 ;; This unagentized server must be denied
 292                 'denied)))
 293
 294         ;; NOTE: I MUST set the server's status to offline before this
 295         ;; recursive call as this status will drive the
 296         ;; gnus-get-function (called above) to return the agent's
 297         ;; backend.
 298         (if open-offline
 299             ;; Recursively open this offline server to perform the
 300             ;; open-server function of the agent's backend.
 301             (let ((gnus-server-unopen-status 'denied))
 302               ;; Bind gnus-server-unopen-status to avoid recursively
 303               ;; prompting with "go offline?".  This is only a concern
 304               ;; when the agent's backend fails to open the server.
 305               (gnus-open-server gnus-command-method))
 306           (when (and (eq (cadr elem) 'ok) gnus-agent
 307                      (gnus-agent-method-p gnus-command-method))
 308             (save-excursion
 309               (gnus-agent-possibly-synchronize-flags-server
 310                gnus-command-method)))
 311           result)))))
 312
 313 (defun gnus-close-server (gnus-command-method)
 314   "Close the connection to GNUS-COMMAND-METHOD."
 315   (when (stringp gnus-command-method)
 316     (setq gnus-command-method (gnus-server-to-method gnus-command-method)))
 317   (funcall (gnus-get-function gnus-command-method 'close-server)
 318            (nth 1 gnus-command-method)))
 319
 320 (defun gnus-request-list (gnus-command-method)
 321   "Request the active file from GNUS-COMMAND-METHOD."
 322   (when (stringp gnus-command-method)
 323     (setq gnus-command-method (gnus-server-to-method gnus-command-method)))
 324   (funcall (gnus-get-function gnus-command-method 'request-list)
 325            (nth 1 gnus-command-method)))
 326
 327 (defun gnus-finish-retrieve-group-infos (gnus-command-method infos data)
 328   "Read and update infos from GNUS-COMMAND-METHOD."
 329   (when (stringp gnus-command-method)
 330     (setq gnus-command-method (gnus-server-to-method gnus-command-method)))
 331   (funcall (gnus-get-function gnus-command-method 'finish-retrieve-group-infos)
 332            (nth 1 gnus-command-method)
 333            infos data))
 334
 335 (defun gnus-retrieve-group-data-early (gnus-command-method infos)
 336   "Start early async retrival of data from GNUS-COMMAND-METHOD."
 337   (when (stringp gnus-command-method)
 338     (setq gnus-command-method (gnus-server-to-method gnus-command-method)))
 339   (funcall (gnus-get-function gnus-command-method 'retrieve-group-data-early)
 340            (nth 1 gnus-command-method)
 341            infos))
 342
 343 (defun gnus-request-list-newsgroups (gnus-command-method)
 344   "Request the newsgroups file from GNUS-COMMAND-METHOD."
 345   (when (stringp gnus-command-method)
 346     (setq gnus-command-method (gnus-server-to-method gnus-command-method)))
 347   (funcall (gnus-get-function gnus-command-method 'request-list-newsgroups)
 348            (nth 1 gnus-command-method)))
 349
 350 (defun gnus-request-newgroups (date gnus-command-method)
 351   "Request all new groups since DATE from GNUS-COMMAND-METHOD."
 352   (when (stringp gnus-command-method)
 353     (setq gnus-command-method (gnus-server-to-method gnus-command-method)))
 354   (let ((func (gnus-get-function gnus-command-method 'request-newgroups t)))
 355     (when func
 356       (funcall func date (nth 1 gnus-command-method)))))
 357
 358 (defun gnus-request-regenerate (gnus-command-method)
 359   "Request a data generation from GNUS-COMMAND-METHOD."
 360   (when (stringp gnus-command-method)
 361     (setq gnus-command-method (gnus-server-to-method gnus-command-method)))
 362   (funcall (gnus-get-function gnus-command-method 'request-regenerate)
 363            (nth 1 gnus-command-method)))
 364
 365 (defun gnus-request-compact-group (group)
 366   (let* ((method (gnus-find-method-for-group group))
 367          (gnus-command-method method)
 368          (result
 369           (funcall (gnus-get-function gnus-command-method
 370                                       'request-compact-group)
 371                    (gnus-group-real-name group)
 372                    (nth 1 gnus-command-method) t)))
 373     result))
 374
 375 (defun gnus-request-compact (gnus-command-method)
 376   "Request groups compaction  from GNUS-COMMAND-METHOD."
 377   (when (stringp gnus-command-method)
 378     (setq gnus-command-method (gnus-server-to-method gnus-command-method)))
 379   (funcall (gnus-get-function gnus-command-method 'request-compact)
 380            (nth 1 gnus-command-method)))
 381
 382 (defun gnus-request-group (group &optional dont-check gnus-command-method info)
 383   "Request GROUP.  If DONT-CHECK, no information is required."
 384   (let ((gnus-command-method
 385          (or gnus-command-method (inline (gnus-find-method-for-group group)))))
 386     (when (stringp gnus-command-method)
 387       (setq gnus-command-method
 388             (inline (gnus-server-to-method gnus-command-method))))
 389     (funcall (inline (gnus-get-function gnus-command-method 'request-group))
 390              (gnus-group-real-name group) (nth 1 gnus-command-method)
 391              dont-check
 392              info)))
 393
 394 (defun gnus-list-active-group (group)
 395   "Request active information on GROUP."
 396   (let ((gnus-command-method (gnus-find-method-for-group group))
 397         (func 'list-active-group))
 398     (when (gnus-check-backend-function func group)
 399       (funcall (gnus-get-function gnus-command-method func)
 400                (gnus-group-real-name group) (nth 1 gnus-command-method)))))
 401
 402 (defun gnus-request-group-description (group)
 403   "Request a description of GROUP."
 404   (let ((gnus-command-method (gnus-find-method-for-group group))
 405         (func 'request-group-description))
 406     (when (gnus-check-backend-function func group)
 407       (funcall (gnus-get-function gnus-command-method func)
 408                (gnus-group-real-name group) (nth 1 gnus-command-method)))))
 409
 410 (defun gnus-request-group-articles (group)
 411   "Request a list of existing articles in GROUP."
 412   (let ((gnus-command-method (gnus-find-method-for-group group))
 413         (func 'request-group-articles))
 414     (when (gnus-check-backend-function func group)
 415       (funcall (gnus-get-function gnus-command-method func)
 416                (gnus-group-real-name group) (nth 1 gnus-command-method)))))
 417
 418 (defun gnus-close-group (group)
 419   "Request the GROUP be closed."
 420   (let ((gnus-command-method (inline (gnus-find-method-for-group group))))
 421     (funcall (gnus-get-function gnus-command-method 'close-group)
 422              (gnus-group-real-name group) (nth 1 gnus-command-method))))
 423
 424 (defun gnus-retrieve-headers (articles group &optional fetch-old)
 425   "Request headers for ARTICLES in GROUP.
 426 If FETCH-OLD, retrieve all headers (or some subset thereof) in the group."
 427   (let ((gnus-command-method (gnus-find-method-for-group group)))
 428     (cond
 429      ((and gnus-use-cache (numberp (car articles)))
 430       (gnus-cache-retrieve-headers articles group fetch-old))
 431      ((and gnus-agent (gnus-online gnus-command-method)
 432            (gnus-agent-method-p gnus-command-method))
 433       (gnus-agent-retrieve-headers articles group fetch-old))
 434      (t
 435       (funcall (gnus-get-function gnus-command-method 'retrieve-headers)
 436                articles (gnus-group-real-name group)
 437                (nth 1 gnus-command-method) fetch-old)))))
 438
 439 (defun gnus-retrieve-articles (articles group)
 440   "Request ARTICLES in GROUP."
 441   (let ((gnus-command-method (gnus-find-method-for-group group)))
 442     (funcall (gnus-get-function gnus-command-method 'retrieve-articles)
 443              articles (gnus-group-real-name group)
 444              (nth 1 gnus-command-method))))
 445
 446 (defun gnus-retrieve-groups (groups gnus-command-method)
 447   "Request active information on GROUPS from GNUS-COMMAND-METHOD."
 448   (when (stringp gnus-command-method)
 449     (setq gnus-command-method (gnus-server-to-method gnus-command-method)))
 450   (funcall (gnus-get-function gnus-command-method 'retrieve-groups)
 451            groups (nth 1 gnus-command-method)))
 452
 453 (defun gnus-request-type (group &optional article)
 454   "Return the type (`post' or `mail') of GROUP (and ARTICLE)."
 455   (let ((gnus-command-method (gnus-find-method-for-group group)))
 456     (if (not (gnus-check-backend-function
 457               'request-type (car gnus-command-method)))
 458         'unknown
 459       (funcall (gnus-get-function gnus-command-method 'request-type)
 460                (gnus-group-real-name group) article))))
 461
 462 (defun gnus-request-set-mark (group action)
 463   "Set marks on articles in the back end."
 464   (let ((gnus-command-method (gnus-find-method-for-group group)))
 465     (if (not (gnus-check-backend-function
 466               'request-set-mark (car gnus-command-method)))
 467         action
 468       (funcall (gnus-get-function gnus-command-method 'request-set-mark)
 469                (gnus-group-real-name group) action
 470                (nth 1 gnus-command-method)))))
 471
 472 (defun gnus-request-update-mark (group article mark)
 473   "Allow the back end to change the mark the user tries to put on an article."
 474   (let ((gnus-command-method (gnus-find-method-for-group group)))
 475     (if (not (gnus-check-backend-function
 476               'request-update-mark (car gnus-command-method)))
 477         mark
 478       (funcall (gnus-get-function gnus-command-method 'request-update-mark)
 479                (gnus-group-real-name group) article mark))))
 480
 481 (defun gnus-request-article (article group &optional buffer)
 482   "Request the ARTICLE in GROUP.
 483 ARTICLE can either be an article number or an article Message-ID.
 484 If BUFFER, insert the article in that group."
 485   (let ((gnus-command-method (gnus-find-method-for-group group)))
 486     (funcall (gnus-get-function gnus-command-method 'request-article)
 487              article (gnus-group-real-name group)
 488              (nth 1 gnus-command-method) buffer)))
 489
 490 (defun gnus-request-head (article group)
 491   "Request the head of ARTICLE in GROUP."
 492   (let* ((gnus-command-method (gnus-find-method-for-group group))
 493          (head (gnus-get-function gnus-command-method 'request-head t))
 494          res clean-up)
 495     (cond
 496      ;; Check the cache.
 497      ((and gnus-use-cache
 498            (numberp article)
 499            (gnus-cache-request-article article group))
 500       (setq res (cons group article)
 501             clean-up t))
 502      ;; Check the agent cache.
 503      ((gnus-agent-request-article article group)
 504       (setq res (cons group article)
 505             clean-up t))
 506      ;; Use `head' function.
 507      ((fboundp head)
 508       (setq res (funcall head article (gnus-group-real-name group)
 509                          (nth 1 gnus-command-method))))
 510      ;; Use `article' function.
 511      (t
 512       (setq res (gnus-request-article article group)
 513             clean-up t)))
 514     (when clean-up
 515       (with-current-buffer nntp-server-buffer
 516         (goto-char (point-min))
 517         (when (search-forward "\n\n" nil t)
 518           (delete-region (1- (point)) (point-max)))
 519         (nnheader-fold-continuation-lines)))
 520     res))
 521
 522 (defun gnus-request-body (article group)
 523   "Request the body of ARTICLE in GROUP."
 524   (let* ((gnus-command-method (gnus-find-method-for-group group))
 525          (head (gnus-get-function gnus-command-method 'request-body t))
 526          res clean-up)
 527     (cond
 528      ;; Check the cache.
 529      ((and gnus-use-cache
 530            (numberp article)
 531            (gnus-cache-request-article article group))
 532       (setq res (cons group article)
 533             clean-up t))
 534      ;; Check the agent cache.
 535      ((gnus-agent-request-article article group)
 536       (setq res (cons group article)
 537             clean-up t))
 538      ;; Use `head' function.
 539      ((fboundp head)
 540       (setq res (funcall head article (gnus-group-real-name group)
 541                          (nth 1 gnus-command-method))))
 542      ;; Use `article' function.
 543      (t
 544       (setq res (gnus-request-article article group)
 545             clean-up t)))
 546     (when clean-up
 547       (with-current-buffer nntp-server-buffer
 548         (goto-char (point-min))
 549         (when (search-forward "\n\n" nil t)
 550           (delete-region (point-min) (1- (point))))))
 551     res))
 552
 553 (defun gnus-request-post (gnus-command-method)
 554   "Post the current buffer using GNUS-COMMAND-METHOD."
 555   (when (stringp gnus-command-method)
 556     (setq gnus-command-method (gnus-server-to-method gnus-command-method)))
 557   (funcall (gnus-get-function gnus-command-method 'request-post)
 558            (nth 1 gnus-command-method)))
 559
 560 (defun gnus-request-expunge-group (group gnus-command-method)
 561   "Expunge GROUP, which is removing articles that have been marked as deleted."
 562   (when (stringp gnus-command-method)
 563     (setq gnus-command-method (gnus-server-to-method gnus-command-method)))
 564   (funcall (gnus-get-function gnus-command-method 'request-expunge-group)
 565            (gnus-group-real-name group)
 566            (nth 1 gnus-command-method)))
 567
 568 (defun gnus-request-scan (group gnus-command-method)
 569   "Request a SCAN being performed in GROUP from GNUS-COMMAND-METHOD.
 570 If GROUP is nil, all groups on GNUS-COMMAND-METHOD are scanned."
 571   (let ((gnus-command-method
 572          (if group (gnus-find-method-for-group group) gnus-command-method))
 573         (gnus-inhibit-demon t)
 574         (mail-source-plugged gnus-plugged))
 575     (when (or gnus-plugged
 576               (not (gnus-agent-method-p gnus-command-method)))
 577       (setq gnus-internal-registry-spool-current-method gnus-command-method)
 578       (funcall (gnus-get-function gnus-command-method 'request-scan)
 579                (and group (gnus-group-real-name group))
 580                (nth 1 gnus-command-method)))))
 581
 582 (defun gnus-request-update-info (info gnus-command-method)
 583   (when (gnus-check-backend-function
 584          'request-update-info (car gnus-command-method))
 585     (when (stringp gnus-command-method)
 586       (setq gnus-command-method (gnus-server-to-method gnus-command-method)))
 587     (funcall (gnus-get-function gnus-command-method 'request-update-info)
 588              (gnus-group-real-name (gnus-info-group info)) info
 589              (nth 1 gnus-command-method))))
 590
 591 (defsubst gnus-request-marks (info gnus-command-method)
 592   "Request that GNUS-COMMAND-METHOD update INFO."
 593   (when (stringp gnus-command-method)
 594     (setq gnus-command-method (gnus-server-to-method gnus-command-method)))
 595   (when (gnus-check-backend-function
 596          'request-marks (car gnus-command-method))
 597     (let ((group (gnus-info-group info)))
 598       (and (funcall (gnus-get-function gnus-command-method
 599                                        'request-update-info)
 600                     (gnus-group-real-name group)
 601                     info (nth 1 gnus-command-method))
 602            ;; If the minimum article number is greater than 1, then all
 603            ;; smaller article numbers are known not to exist; we'll
 604            ;; artificially add those to the 'read range.
 605            (let* ((active (gnus-active group))
 606                   (min (car active)))
 607              (when (> min 1)
 608                (let* ((range (if (= min 2) 1 (cons 1 (1- min))))
 609                       (read (gnus-info-read info))
 610                       (new-read (gnus-range-add read (list range))))
 611                  (gnus-info-set-read info new-read)))
 612              info)))))
 613
 614 (defun gnus-request-expire-articles (articles group &optional force)
 615   (let* ((gnus-command-method (gnus-find-method-for-group group))
 616          (gnus-inhibit-demon t)
 617          (not-deleted
 618           (funcall
 619            (gnus-get-function gnus-command-method 'request-expire-articles)
 620            articles (gnus-group-real-name group) (nth 1 gnus-command-method)
 621            force)))
 622     (when (and gnus-agent
 623                (gnus-agent-method-p gnus-command-method))
 624       (let ((expired-articles (gnus-sorted-difference articles not-deleted)))
 625         (when expired-articles
 626           (gnus-agent-expire expired-articles group 'force))))
 627     not-deleted))
 628
 629 (defun gnus-request-move-article (article group server accept-function
 630                                           &optional last move-is-internal)
 631   (let* ((gnus-command-method (gnus-find-method-for-group group))
 632          (result (funcall (gnus-get-function gnus-command-method
 633                                              'request-move-article)
 634                           article (gnus-group-real-name group)
 635                           (nth 1 gnus-command-method) accept-function last move-is-internal)))
 636     (when (and result gnus-agent
 637                (gnus-agent-method-p gnus-command-method))
 638       (gnus-agent-unfetch-articles group (list article)))
 639     result))
 640
 641 (defun gnus-request-accept-article (group &optional gnus-command-method last
 642                                           no-encode)
 643   ;; Make sure there's a newline at the end of the article.
 644   (when (stringp gnus-command-method)
 645     (setq gnus-command-method (gnus-server-to-method gnus-command-method)))
 646   (when (and (not gnus-command-method)
 647              (stringp group))
 648     (setq gnus-command-method (or (gnus-find-method-for-group group)
 649                                   (gnus-group-name-to-method group))))
 650   (goto-char (point-max))
 651   (unless (bolp)
 652     (insert "\n"))
 653   (unless no-encode
 654     (let ((message-options message-options))
 655       (message-options-set-recipient)
 656       (save-restriction
 657         (message-narrow-to-head)
 658         (let ((mail-parse-charset message-default-charset))
 659           (mail-encode-encoded-word-buffer)))
 660       (message-encode-message-body)))
 661   (let ((gnus-command-method (or gnus-command-method
 662                                  (gnus-find-method-for-group group)))
 663         (result
 664          (funcall
 665           (gnus-get-function gnus-command-method 'request-accept-article)
 666           (if (stringp group) (gnus-group-real-name group) group)
 667           (cadr gnus-command-method)
 668           last)))
 669     (when (and gnus-agent (gnus-agent-method-p gnus-command-method))
 670       (gnus-agent-regenerate-group group (list (cdr result))))
 671     result))
 672
 673 (defun gnus-request-replace-article (article group buffer &optional no-encode)
 674   (unless no-encode
 675     (let ((message-options message-options))
 676       (message-options-set-recipient)
 677       (save-restriction
 678         (message-narrow-to-head)
 679         (let ((mail-parse-charset message-default-charset))
 680           (mail-encode-encoded-word-buffer)))
 681       (message-encode-message-body)))
 682   (let* ((func (car (gnus-group-name-to-method group)))
 683          (result (funcall (intern (format "%s-request-replace-article" func))
 684                           article (gnus-group-real-name group) buffer)))
 685     (when (and gnus-agent (gnus-agent-method-p gnus-command-method))
 686       (gnus-agent-regenerate-group group (list article)))
 687     result))
 688
 689 (defun gnus-request-associate-buffer (group)
 690   (let ((gnus-command-method (gnus-find-method-for-group group)))
 691     (funcall (gnus-get-function gnus-command-method 'request-associate-buffer)
 692              (gnus-group-real-name group))))
 693
 694 (defun gnus-request-restore-buffer (article group)
 695   "Request a new buffer restored to the state of ARTICLE."
 696   (let ((gnus-command-method (gnus-find-method-for-group group)))
 697     (funcall (gnus-get-function gnus-command-method 'request-restore-buffer)
 698              article (gnus-group-real-name group)
 699              (nth 1 gnus-command-method))))
 700
 701 (defun gnus-request-create-group (group &optional gnus-command-method args)
 702   (when (stringp gnus-command-method)
 703     (setq gnus-command-method (gnus-server-to-method gnus-command-method)))
 704   (let ((gnus-command-method
 705          (or gnus-command-method (gnus-find-method-for-group group))))
 706     (funcall (gnus-get-function gnus-command-method 'request-create-group)
 707              (gnus-group-real-name group) (nth 1 gnus-command-method) args)))
 708
 709 (defun gnus-request-delete-group (group &optional force)
 710   (let* ((gnus-command-method (gnus-find-method-for-group group))
 711          (result
 712           (funcall (gnus-get-function gnus-command-method 'request-delete-group)
 713                    (gnus-group-real-name group) force (nth 1 gnus-command-method))))
 714     (when result
 715       (gnus-cache-delete-group group)
 716       (gnus-agent-delete-group group))
 717     result))
 718
 719 (defun gnus-request-rename-group (group new-name)
 720   (let* ((gnus-command-method (gnus-find-method-for-group group))
 721          (result
 722           (funcall (gnus-get-function gnus-command-method 'request-rename-group)
 723                    (gnus-group-real-name group)
 724                    (gnus-group-real-name new-name) (nth 1 gnus-command-method))))
 725     (when result
 726       (gnus-cache-rename-group group new-name)
 727       (gnus-agent-rename-group group new-name))
 728     result))
 729
 730 (defun gnus-close-backends ()
 731   ;; Send a close request to all backends that support such a request.
 732   (let ((methods gnus-valid-select-methods)
 733         (gnus-inhibit-demon t)
 734         func gnus-command-method)
 735     (while (setq gnus-command-method (pop methods))
 736       (when (fboundp (setq func (intern
 737                                  (concat (car gnus-command-method)
 738                                          "-request-close"))))
 739         (funcall func)))))
 740
 741 (defun gnus-asynchronous-p (gnus-command-method)
 742   (let ((func (gnus-get-function gnus-command-method 'asynchronous-p t)))
 743     (when (fboundp func)
 744       (funcall func))))
 745
 746 (defun gnus-remove-denial (gnus-command-method)
 747   (when (stringp gnus-command-method)
 748     (setq gnus-command-method (gnus-server-to-method gnus-command-method)))
 749   (let* ((elem (assoc gnus-command-method gnus-opened-servers))
 750          (status (cadr elem)))
 751     ;; If this hasn't been opened before, we add it to the list.
 752     (when (eq status 'denied)
 753       ;; Set the status of this server.
 754       (setcar (cdr elem) 'closed))))
 755
 756 (provide 'gnus-int)
 757
 758 ;;; gnus-int.el ends here