cgit.sxemacs.org Git - gnus/blob - lisp/gnus-eform.el

   1 ;;; gnus-eform.el --- a mode for editing forms for Gnus
   2
   3 ;; Copyright (C) 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003, 2004,
   4 ;;   2005, 2006 Free Software Foundation, Inc.
   5
   6 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   7 ;; Keywords: news
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  24 ;; Boston, MA 02110-1301, USA.
  25
  26 ;;; Commentary:
  27
  28 ;;; Code:
  29
  30 (require 'gnus)
  31 (require 'gnus-win)
  32
  33 ;;;
  34 ;;; Editing forms
  35 ;;;
  36
  37 (defgroup gnus-edit-form nil
  38   "A mode for editing forms."
  39   :group 'gnus)
  40
  41 (defcustom gnus-edit-form-mode-hook nil
  42   "Hook run in `gnus-edit-form-mode' buffers."
  43   :group 'gnus-edit-form
  44   :type 'hook)
  45
  46 (defcustom gnus-edit-form-menu-hook nil
  47   "Hook run when creating menus in `gnus-edit-form-mode' buffers."
  48   :group 'gnus-edit-form
  49   :type 'hook)
  50
  51 ;;; Internal variables
  52
  53 (defvar gnus-edit-form-buffer "*Gnus edit form*")
  54 (defvar gnus-edit-form-done-function nil)
  55
  56 (defvar gnus-edit-form-mode-map nil)
  57 (unless gnus-edit-form-mode-map
  58   (setq gnus-edit-form-mode-map (make-sparse-keymap))
  59   (set-keymap-parent gnus-edit-form-mode-map emacs-lisp-mode-map)
  60   (gnus-define-keys gnus-edit-form-mode-map
  61     "\C-c\C-c" gnus-edit-form-done
  62     "\C-c\C-k" gnus-edit-form-exit))
  63
  64 (defun gnus-edit-form-make-menu-bar ()
  65   (unless (boundp 'gnus-edit-form-menu)
  66     (easy-menu-define
  67      gnus-edit-form-menu gnus-edit-form-mode-map ""
  68      '("Edit Form"
  69        ["Exit and save changes" gnus-edit-form-done t]
  70        ["Exit" gnus-edit-form-exit t]))
  71     (gnus-run-hooks 'gnus-edit-form-menu-hook)))
  72
  73 (defun gnus-edit-form-mode ()
  74   "Major mode for editing forms.
  75 It is a slightly enhanced emacs-lisp-mode.
  76
  77 \\{gnus-edit-form-mode-map}"
  78   (interactive)
  79   (when (gnus-visual-p 'group-menu 'menu)
  80     (gnus-edit-form-make-menu-bar))
  81   (kill-all-local-variables)
  82   (setq major-mode 'gnus-edit-form-mode)
  83   (setq mode-name "Edit Form")
  84   (use-local-map gnus-edit-form-mode-map)
  85   (make-local-variable 'gnus-edit-form-done-function)
  86   (make-local-variable 'gnus-prev-winconf)
  87   (gnus-run-mode-hooks 'gnus-edit-form-mode-hook))
  88
  89 (defun gnus-edit-form (form documentation exit-func)
  90   "Edit FORM in a new buffer.
  91 Call EXIT-FUNC on exit.  Display DOCUMENTATION in the beginning
  92 of the buffer."
  93   (let ((winconf (current-window-configuration)))
  94     (set-buffer (gnus-get-buffer-create gnus-edit-form-buffer))
  95     (gnus-configure-windows 'edit-form)
  96     (gnus-edit-form-mode)
  97     (setq gnus-prev-winconf winconf)
  98     (setq gnus-edit-form-done-function exit-func)
  99     (erase-buffer)
 100     (insert documentation)
 101     (unless (bolp)
 102       (insert "\n"))
 103     (goto-char (point-min))
 104     (while (not (eobp))
 105       (insert ";;; ")
 106       (forward-line 1))
 107     (insert ";; Type `C-c C-c' after you've finished editing.\n")
 108     (insert "\n")
 109     (let ((p (point)))
 110       (gnus-pp form)
 111       (insert "\n")
 112       (goto-char p))))
 113
 114 (defun gnus-edit-form-done ()
 115   "Update changes and kill the current buffer."
 116   (interactive)
 117   (goto-char (point-min))
 118   (let ((form (condition-case nil
 119                   (read (current-buffer))
 120                 (end-of-file nil)))
 121         (func gnus-edit-form-done-function))
 122     (gnus-edit-form-exit)
 123     (funcall func form)))
 124
 125 (defun gnus-edit-form-exit ()
 126   "Kill the current buffer."
 127   (interactive)
 128   (let ((winconf gnus-prev-winconf))
 129     (kill-buffer (current-buffer))
 130     (set-window-configuration winconf)))
 131
 132 (provide 'gnus-eform)
 133
 134 ;;; arch-tag: ef50678c-2c28-49ef-affc-e53b3b2c0bf6
 135 ;;; gnus-eform.el ends here