cgit.sxemacs.org Git - gnus/blob - lisp/gnus-eform.el

   1 ;;; gnus-eform.el --- a mode for editing forms for Gnus
   2 ;; Copyright (C) 1996 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@ifi.uio.no>
   5 ;; Keywords: news
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  22 ;; Boston, MA 02111-1307, USA.
  23
  24 ;;; Commentary:
  25
  26 ;;; Code:
  27
  28 (require 'gnus-load)
  29 (require 'gnus-win)
  30 (require 'gnus)
  31
  32 ;;;
  33 ;;; Editing forms
  34 ;;;
  35
  36 (defgroup gnus-edit-form nil
  37   "A mode for editing forms."
  38   :group 'gnus)
  39
  40 (defcustom gnus-edit-form-mode-hook nil
  41   "Hook run in `gnus-edit-form-mode' buffers."
  42   :group 'gnus-edit-form
  43   :type 'hook)
  44
  45 (defcustom gnus-edit-form-menu-hook nil
  46   "Hook run when creating menus in `gnus-edit-form-mode' buffers."
  47   :group 'gnus-edit-form
  48   :type 'hook)
  49
  50 ;;; Internal variables
  51
  52 (defvar gnus-edit-form-done-function nil)
  53 (defvar gnus-edit-form-buffer "*Gnus edit form*")
  54
  55 (defvar gnus-edit-form-mode-map nil)
  56 (unless gnus-edit-form-mode-map
  57   (setq gnus-edit-form-mode-map (copy-keymap emacs-lisp-mode-map))
  58   (gnus-define-keys gnus-edit-form-mode-map
  59     "\C-c\C-c" gnus-edit-form-done
  60     "\C-c\C-k" gnus-edit-form-exit))
  61
  62 (defun gnus-edit-form-make-menu-bar ()
  63   (unless (boundp 'gnus-edit-form-menu)
  64     (easy-menu-define
  65      gnus-edit-form-menu gnus-edit-form-mode-map ""
  66      '("Edit Form"
  67        ["Exit and save changes" gnus-edit-form-done t]
  68        ["Exit" gnus-edit-form-exit t]))
  69     (run-hooks 'gnus-edit-form-menu-hook)))
  70
  71 (defun gnus-edit-form-mode ()
  72   "Major mode for editing forms.
  73 It is a slightly enhanced emacs-lisp-mode.
  74
  75 \\{gnus-edit-form-mode-map}"
  76   (interactive)
  77   (when (and menu-bar-mode
  78              (gnus-visual-p 'group-menu 'menu))
  79     (gnus-edit-form-make-menu-bar))
  80   (kill-all-local-variables)
  81   (setq major-mode 'gnus-edit-form-mode)
  82   (setq mode-name "Edit Form")
  83   (use-local-map gnus-edit-form-mode-map)
  84   (make-local-variable 'gnus-edit-form-done-function)
  85   (make-local-variable 'gnus-prev-winconf)
  86   (run-hooks 'gnus-edit-form-mode-hook))
  87
  88 (defun gnus-edit-form (form documentation exit-func)
  89   "Edit FORM in a new buffer.
  90 Call EXIT-FUNC on exit.  Display DOCUMENTATION in the beginning
  91 of the buffer."
  92   (let ((winconf (current-window-configuration)))
  93     (set-buffer (get-buffer-create gnus-edit-form-buffer))
  94     (gnus-configure-windows 'edit-form)
  95     (gnus-add-current-to-buffer-list)
  96     (gnus-edit-form-mode)
  97     (setq gnus-prev-winconf winconf)
  98     (setq gnus-edit-form-done-function exit-func)
  99     (erase-buffer)
 100     (insert documentation)
 101     (unless (bolp)
 102       (insert "\n"))
 103     (goto-char (point-min))
 104     (while (not (eobp))
 105       (insert ";;; ")
 106       (forward-line 1))
 107     (insert ";; Type `C-c C-c' after you've finished editing.\n")
 108     (insert "\n")
 109     (let ((p (point)))
 110       (pp form (current-buffer))
 111       (insert "\n")
 112       (goto-char p))))
 113
 114 (defun gnus-edit-form-done ()
 115   "Update changes and kill the current buffer."
 116   (interactive)
 117   (goto-char (point-min))
 118   (let ((form (read (current-buffer)))
 119         (func gnus-edit-form-done-function))
 120     (gnus-edit-form-exit)
 121     (funcall func form)))
 122
 123 (defun gnus-edit-form-exit ()
 124   "Kill the current buffer."
 125   (interactive)
 126   (let ((winconf gnus-prev-winconf))
 127     (kill-buffer (current-buffer))
 128     (set-window-configuration winconf)))
 129
 130 (provide 'gnus-eform)
 131
 132 ;;; gnus-eform.el ends here