cgit.sxemacs.org Git - gnus/blob - lisp/gnus-draft.el

   1 ;;; gnus-draft.el --- draft message support for Gnus
   2
   3 ;; Copyright (C) 1997, 1998, 1999, 2000, 2001, 2002, 2003, 2004,
   4 ;;   2005, 2006, 2007, 2008 Free Software Foundation, Inc.
   5
   6 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   7 ;; Keywords: news
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 3, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  24 ;; Boston, MA 02110-1301, USA.
  25
  26 ;;; Commentary:
  27
  28 ;;; Code:
  29
  30 (require 'gnus)
  31 (require 'gnus-sum)
  32 (require 'message)
  33 (require 'gnus-msg)
  34 (require 'nndraft)
  35 (require 'gnus-agent)
  36 (eval-when-compile (require 'cl))
  37
  38 ;;; Draft minor mode
  39
  40 (defvar gnus-draft-mode nil
  41   "Minor mode for providing a draft summary buffers.")
  42
  43 (defvar gnus-draft-mode-map nil)
  44
  45 (unless gnus-draft-mode-map
  46   (setq gnus-draft-mode-map (make-sparse-keymap))
  47
  48   (gnus-define-keys gnus-draft-mode-map
  49     "Dt" gnus-draft-toggle-sending
  50     "e"  gnus-draft-edit-message ;; Use `B w' for `gnus-summary-edit-article'
  51     "De" gnus-draft-edit-message
  52     "Ds" gnus-draft-send-message
  53     "DS" gnus-draft-send-all-messages))
  54
  55 (defun gnus-draft-make-menu-bar ()
  56   (unless (boundp 'gnus-draft-menu)
  57     (easy-menu-define
  58      gnus-draft-menu gnus-draft-mode-map ""
  59      '("Drafts"
  60        ["Toggle whether to send" gnus-draft-toggle-sending t]
  61        ["Edit" gnus-draft-edit-message t]
  62        ["Send selected message(s)" gnus-draft-send-message t]
  63        ["Send all messages" gnus-draft-send-all-messages t]
  64        ["Delete draft" gnus-summary-delete-article t]))))
  65
  66 (defun gnus-draft-mode (&optional arg)
  67   "Minor mode for providing a draft summary buffers.
  68
  69 \\{gnus-draft-mode-map}"
  70   (interactive "P")
  71   (when (eq major-mode 'gnus-summary-mode)
  72     (when (set (make-local-variable 'gnus-draft-mode)
  73                (if (null arg) (not gnus-draft-mode)
  74                  (> (prefix-numeric-value arg) 0)))
  75       ;; Set up the menu.
  76       (when (gnus-visual-p 'draft-menu 'menu)
  77         (gnus-draft-make-menu-bar))
  78       (add-minor-mode 'gnus-draft-mode " Draft" gnus-draft-mode-map)
  79       (gnus-run-hooks 'gnus-draft-mode-hook))))
  80
  81 ;;; Commands
  82
  83 (defun gnus-draft-toggle-sending (article)
  84   "Toggle whether to send an article or not."
  85   (interactive (list (gnus-summary-article-number)))
  86   (if (gnus-draft-article-sendable-p article)
  87       (progn
  88         (push article gnus-newsgroup-unsendable)
  89         (gnus-summary-mark-article article gnus-unsendable-mark))
  90     (setq gnus-newsgroup-unsendable
  91           (delq article gnus-newsgroup-unsendable))
  92     (gnus-summary-mark-article article gnus-unread-mark))
  93   (gnus-summary-position-point))
  94
  95 (defun gnus-draft-edit-message ()
  96   "Enter a mail/post buffer to edit and send the draft."
  97   (interactive)
  98   (let ((article (gnus-summary-article-number))
  99         (group gnus-newsgroup-name))
 100     (gnus-draft-check-draft-articles (list article))
 101     (gnus-summary-mark-as-read article gnus-canceled-mark)
 102     (gnus-draft-setup article group t)
 103     (set-buffer-modified-p t)
 104     (save-excursion
 105       (save-restriction
 106         (message-narrow-to-headers)
 107         (message-remove-header "date")))
 108     (let ((message-draft-headers
 109            (delq 'Date (copy-sequence message-draft-headers))))
 110       (save-buffer))
 111     (let ((gnus-verbose-backends nil))
 112       (gnus-request-expire-articles (list article) group t))
 113     (push
 114      `((lambda ()
 115          (when (gnus-buffer-exists-p ,gnus-summary-buffer)
 116            (save-excursion
 117              (set-buffer ,gnus-summary-buffer)
 118              (gnus-cache-possibly-remove-article ,article nil nil nil t)))))
 119      message-send-actions)))
 120
 121 (defun gnus-draft-send-message (&optional n)
 122   "Send the current draft(s).
 123 Obeys the standard process/prefix convention."
 124   (interactive "P")
 125   (let* ((articles (gnus-summary-work-articles n))
 126          (total (length articles))
 127          article)
 128     (gnus-draft-check-draft-articles articles)
 129     (while (setq article (pop articles))
 130       (gnus-summary-remove-process-mark article)
 131       (unless (memq article gnus-newsgroup-unsendable)
 132         (let ((message-sending-message
 133                (format "Sending message %d of %d..."
 134                        (- total (length articles)) total)))
 135           (gnus-draft-send article gnus-newsgroup-name t))
 136         (gnus-summary-mark-article article gnus-canceled-mark)))))
 137
 138 (defun gnus-draft-send (article &optional group interactive)
 139   "Send message ARTICLE."
 140   (let* ((is-queue (or (not group)
 141                        (equal group "nndraft:queue")))
 142          (message-syntax-checks (if interactive message-syntax-checks
 143                                   'dont-check-for-anything-just-trust-me))
 144          (message-hidden-headers nil)
 145          (message-inhibit-body-encoding (or is-queue
 146                                             message-inhibit-body-encoding))
 147          (message-send-hook (and (not is-queue)
 148                                  message-send-hook))
 149          (message-setup-hook (and (not is-queue)
 150                                   message-setup-hook))
 151          (message-signature (and (not is-queue)
 152                                  message-signature))
 153          (gnus-agent-queue-mail (and (not is-queue)
 154                                      gnus-agent-queue-mail))
 155          (rfc2047-encode-encoded-words nil)
 156          type method move-to)
 157     (gnus-draft-setup article (or group "nndraft:queue"))
 158     ;; We read the meta-information that says how and where
 159     ;; this message is to be sent.
 160     (save-restriction
 161       (message-narrow-to-headers)
 162       (when (re-search-forward
 163              (concat "^" (regexp-quote gnus-agent-target-move-group-header)
 164                      ":") nil t)
 165         (skip-syntax-forward "-")
 166         (setq move-to (buffer-substring (point) (point-at-eol)))
 167         (message-remove-header gnus-agent-target-move-group-header))
 168       (goto-char (point-min))
 169       (when (re-search-forward
 170              (concat "^" (regexp-quote gnus-agent-meta-information-header) ":")
 171              nil t)
 172         (setq type (ignore-errors (read (current-buffer)))
 173               method (ignore-errors (read (current-buffer))))
 174         (message-remove-header gnus-agent-meta-information-header)))
 175     ;; Let Agent restore any GCC lines and have message.el perform them.
 176     (gnus-agent-restore-gcc)
 177     ;; Then we send it.  If we have no meta-information, we just send
 178     ;; it and let Message figure out how.
 179     (when (and (or (null method)
 180                    (gnus-server-opened method)
 181                    (gnus-open-server method))
 182                (if type
 183                    (let ((message-this-is-news (eq type 'news))
 184                          (message-this-is-mail (eq type 'mail))
 185                          (gnus-post-method method)
 186                          (message-post-method method))
 187                      (if move-to
 188                          (gnus-inews-do-gcc move-to)
 189                        (message-send-and-exit)))
 190                  (if move-to
 191                      (gnus-inews-do-gcc move-to)
 192                    (message-send-and-exit))))
 193       (let ((gnus-verbose-backends nil))
 194         (gnus-request-expire-articles
 195          (list article) (or group "nndraft:queue") t)))))
 196
 197 (defun gnus-draft-send-all-messages ()
 198   "Send all the sendable drafts."
 199   (interactive)
 200   (when (or
 201          gnus-expert-user
 202          (gnus-y-or-n-p
 203           "Send all drafts? "))
 204     (gnus-uu-mark-buffer)
 205     (gnus-draft-send-message)))
 206
 207 (defun gnus-group-send-queue ()
 208   "Send all sendable articles from the queue group."
 209   (interactive)
 210   (when (or gnus-plugged
 211             (not gnus-agent-prompt-send-queue)
 212             (gnus-y-or-n-p "Gnus is unplugged; really send queue? "))
 213     (gnus-activate-group "nndraft:queue")
 214     (save-excursion
 215       (let* ((articles (nndraft-articles))
 216              (unsendable (gnus-uncompress-range
 217                           (cdr (assq 'unsend
 218                                      (gnus-info-marks
 219                                       (gnus-get-info "nndraft:queue"))))))
 220              (gnus-posting-styles nil)
 221              (total (length articles))
 222              article)
 223         (while (setq article (pop articles))
 224           (unless (memq article unsendable)
 225             (let ((message-sending-message
 226                    (format "Sending message %d of %d..."
 227                            (- total (length articles)) total)))
 228               (gnus-draft-send article))))))))
 229
 230 ;;;###autoload
 231 (defun gnus-draft-reminder ()
 232   "Reminder user if there are unsent drafts."
 233   (interactive)
 234   (if (gnus-alive-p)
 235       (let (active)
 236         (catch 'continue
 237           (dolist (group '("nndraft:drafts" "nndraft:queue"))
 238             (setq active (gnus-activate-group group))
 239             (if (and active (>= (cdr active) (car active)))
 240                 (if (y-or-n-p "There are unsent drafts.  Confirm to exit? ")
 241                     (throw 'continue t)
 242                   (error "Stop!"))))))))
 243
 244 (defcustom gnus-draft-setup-hook nil
 245   "Hook run after setting up a draft buffer."
 246   :group 'gnus-message
 247   :version "23.1" ;; No Gnus
 248   :type 'hook)
 249
 250 ;;; Utility functions
 251
 252 ;;;!!!If this is byte-compiled, it fails miserably.
 253 ;;;!!!This is because `gnus-setup-message' uses uninterned symbols.
 254 ;;;!!!This has been fixed in recent versions of Emacs and XEmacs,
 255 ;;;!!!but for the time being, we'll just run this tiny function uncompiled.
 256
 257 (progn
 258   (defun gnus-draft-setup (narticle group &optional restore)
 259     (let (ga)
 260       (gnus-setup-message 'forward
 261         (let ((article narticle))
 262           (message-mail)
 263           (erase-buffer)
 264           (if (not (gnus-request-restore-buffer article group))
 265               (error "Couldn't restore the article")
 266             (when (and restore
 267                        (equal group "nndraft:queue"))
 268               (mime-to-mml))
 269             ;; Insert the separator.
 270             (goto-char (point-min))
 271             (search-forward "\n\n")
 272             (forward-char -1)
 273             (save-restriction
 274               (narrow-to-region (point-min) (point))
 275               (setq ga
 276                     (message-fetch-field gnus-draft-meta-information-header)))
 277             (insert mail-header-separator)
 278             (forward-line 1)
 279             (message-set-auto-save-file-name))))
 280       (gnus-backlog-remove-article group narticle)
 281       (when (and ga
 282                  (ignore-errors (setq ga (car (read-from-string ga)))))
 283         (setq gnus-newsgroup-name
 284               (if (equal (car ga) "") nil (car ga)))
 285         (gnus-configure-posting-styles)
 286         (setq gnus-message-group-art (cons gnus-newsgroup-name (cadr ga)))
 287         (setq message-post-method
 288               `(lambda (arg)
 289                  (gnus-post-method arg ,(car ga))))
 290         (unless (equal (cadr ga) "")
 291           (dolist (article (cdr ga))
 292             (message-add-action
 293              `(progn
 294                 (gnus-add-mark ,(car ga) 'replied ,article)
 295                 (gnus-request-set-mark ,(car ga) (list (list (list ,article)
 296                                                              'add '(reply)))))
 297              'send))))
 298       (run-hooks 'gnus-draft-setup-hook))))
 299
 300 (defun gnus-draft-article-sendable-p (article)
 301   "Say whether ARTICLE is sendable."
 302   (not (memq article gnus-newsgroup-unsendable)))
 303
 304 (defun gnus-draft-check-draft-articles (articles)
 305   "Check whether the draft articles ARTICLES are under edit."
 306   (when (equal gnus-newsgroup-name "nndraft:drafts")
 307     (let ((buffers (buffer-list))
 308           file buffs buff)
 309       (save-current-buffer
 310         (while (and articles
 311                     (not buff))
 312           (setq file (nndraft-article-filename (pop articles))
 313                 buffs buffers)
 314           (while buffs
 315             (set-buffer (setq buff (pop buffs)))
 316             (if (and buffer-file-name
 317                      (string-equal (file-truename buffer-file-name)
 318                                    (file-truename file))
 319                      (buffer-modified-p))
 320                 (setq buffs nil)
 321               (setq buff nil)))))
 322       (when buff
 323         (let* ((window (get-buffer-window buff t))
 324                (frame (and window (window-frame window))))
 325           (if frame
 326               (gnus-select-frame-set-input-focus frame)
 327             (pop-to-buffer buff t)))
 328         (error "The draft %s is under edit" file)))))
 329
 330 (provide 'gnus-draft)
 331
 332 ;; arch-tag: 3d92af58-8c97-4a5c-9db4-a98e85198022
 333 ;;; gnus-draft.el ends here