cgit.sxemacs.org Git - gnus/blob - lisp/gnus-draft.el

   1 ;;; gnus-draft.el --- draft message support for Gnus
   2 ;; Copyright (C) 1997, 1998, 1999, 2000, 2001, 2002, 2003
   3 ;;        Free Software Foundation, Inc.
   4
   5 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   6 ;; Keywords: news
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;;; Code:
  28
  29 (require 'gnus)
  30 (require 'gnus-sum)
  31 (require 'message)
  32 (require 'gnus-msg)
  33 (require 'nndraft)
  34 (require 'gnus-agent)
  35 (eval-when-compile (require 'cl))
  36
  37 ;;; Draft minor mode
  38
  39 (defvar gnus-draft-mode nil
  40   "Minor mode for providing a draft summary buffers.")
  41
  42 (defvar gnus-draft-mode-map nil)
  43
  44 (unless gnus-draft-mode-map
  45   (setq gnus-draft-mode-map (make-sparse-keymap))
  46
  47   (gnus-define-keys gnus-draft-mode-map
  48     "Dt" gnus-draft-toggle-sending
  49     "De" gnus-draft-edit-message
  50     "Ds" gnus-draft-send-message
  51     "DS" gnus-draft-send-all-messages))
  52
  53 (defun gnus-draft-make-menu-bar ()
  54   (unless (boundp 'gnus-draft-menu)
  55     (easy-menu-define
  56      gnus-draft-menu gnus-draft-mode-map ""
  57      '("Drafts"
  58        ["Toggle whether to send" gnus-draft-toggle-sending t]
  59        ["Edit" gnus-draft-edit-message t]
  60        ["Send selected message(s)" gnus-draft-send-message t]
  61        ["Send all messages" gnus-draft-send-all-messages t]
  62        ["Delete draft" gnus-summary-delete-article t]))))
  63
  64 (defun gnus-draft-mode (&optional arg)
  65   "Minor mode for providing a draft summary buffers.
  66
  67 \\{gnus-draft-mode-map}"
  68   (interactive "P")
  69   (when (eq major-mode 'gnus-summary-mode)
  70     (when (set (make-local-variable 'gnus-draft-mode)
  71                (if (null arg) (not gnus-draft-mode)
  72                  (> (prefix-numeric-value arg) 0)))
  73       ;; Set up the menu.
  74       (when (gnus-visual-p 'draft-menu 'menu)
  75         (gnus-draft-make-menu-bar))
  76       (gnus-add-minor-mode 'gnus-draft-mode " Draft" gnus-draft-mode-map)
  77       (mml-mode)
  78       (gnus-run-hooks 'gnus-draft-mode-hook))))
  79
  80 ;;; Commands
  81
  82 (defun gnus-draft-toggle-sending (article)
  83   "Toggle whether to send an article or not."
  84   (interactive (list (gnus-summary-article-number)))
  85   (if (gnus-draft-article-sendable-p article)
  86       (progn
  87         (push article gnus-newsgroup-unsendable)
  88         (gnus-summary-mark-article article gnus-unsendable-mark))
  89     (setq gnus-newsgroup-unsendable
  90           (delq article gnus-newsgroup-unsendable))
  91     (gnus-summary-mark-article article gnus-unread-mark))
  92   (gnus-summary-position-point))
  93
  94 (defun gnus-draft-edit-message ()
  95   "Enter a mail/post buffer to edit and send the draft."
  96   (interactive)
  97   (let ((article (gnus-summary-article-number))
  98         (group gnus-newsgroup-name))
  99     (gnus-summary-mark-as-read article gnus-canceled-mark)
 100     (gnus-draft-setup article group t)
 101     (set-buffer-modified-p t)
 102     (save-excursion
 103       (save-restriction
 104         (message-narrow-to-headers)
 105         (message-remove-header "date")))
 106     (save-buffer)
 107     (let ((gnus-verbose-backends nil))
 108       (gnus-request-expire-articles (list article) group t))
 109     (push
 110      `((lambda ()
 111          (when (gnus-buffer-exists-p ,gnus-summary-buffer)
 112            (save-excursion
 113              (set-buffer ,gnus-summary-buffer)
 114              (gnus-cache-possibly-remove-article ,article nil nil nil t)))))
 115      message-send-actions)))
 116
 117 (defun gnus-draft-send-message (&optional n)
 118   "Send the current draft."
 119   (interactive "P")
 120   (let* ((articles (gnus-summary-work-articles n))
 121          (total (length articles))
 122          article)
 123     (while (setq article (pop articles))
 124       (gnus-summary-remove-process-mark article)
 125       (unless (memq article gnus-newsgroup-unsendable)
 126         (let ((message-sending-message
 127                (format "Sending message %d of %d..."
 128                        (- total (length articles)) total)))
 129           (gnus-draft-send article gnus-newsgroup-name t))
 130         (gnus-summary-mark-article article gnus-canceled-mark)))))
 131
 132 (defun gnus-draft-send (article &optional group interactive)
 133   "Send message ARTICLE."
 134   (let ((message-syntax-checks (if interactive message-syntax-checks
 135                                  'dont-check-for-anything-just-trust-me))
 136         (message-inhibit-body-encoding (or (not group)
 137                                            (equal group "nndraft:queue")
 138                                            message-inhibit-body-encoding))
 139         (message-send-hook (and group (not (equal group "nndraft:queue"))
 140                                 message-send-hook))
 141         (message-setup-hook (and group (not (equal group "nndraft:queue"))
 142                                  message-setup-hook))
 143         type method move-to)
 144     (gnus-draft-setup article (or group "nndraft:queue"))
 145     ;; We read the meta-information that says how and where
 146     ;; this message is to be sent.
 147     (save-restriction
 148       (message-narrow-to-head)
 149       (when (re-search-forward
 150              (concat "^" (regexp-quote gnus-agent-target-move-group-header)
 151                      ":") nil t)
 152         (skip-syntax-forward "-")
 153         (setq move-to (buffer-substring (point) (gnus-point-at-eol)))
 154         (message-remove-header gnus-agent-target-move-group-header))
 155       (goto-char (point-min))
 156       (when (re-search-forward
 157              (concat "^" (regexp-quote gnus-agent-meta-information-header) ":")
 158              nil t)
 159         (setq type (ignore-errors (read (current-buffer)))
 160               method (ignore-errors (read (current-buffer))))
 161         (message-remove-header gnus-agent-meta-information-header)))
 162     ;; Let Agent restore any GCC lines and have message.el perform them.
 163     (gnus-agent-restore-gcc)
 164     ;; Then we send it.  If we have no meta-information, we just send
 165     ;; it and let Message figure out how.
 166     (when (and (or (null method)
 167                    (gnus-server-opened method)
 168                    (gnus-open-server method))
 169                (if type
 170                    (let ((message-this-is-news (eq type 'news))
 171                          (message-this-is-mail (eq type 'mail))
 172                          (gnus-post-method method)
 173                          (message-post-method method))
 174                      (if move-to
 175                          (gnus-inews-do-gcc move-to)
 176                        (message-send-and-exit)))
 177                  (if move-to
 178                      (gnus-inews-do-gcc move-to)
 179                    (message-send-and-exit))))
 180       (let ((gnus-verbose-backends nil))
 181         (gnus-request-expire-articles
 182          (list article) (or group "nndraft:queue") t)))))
 183
 184 (defun gnus-draft-send-all-messages ()
 185   "Send all the sendable drafts."
 186   (interactive)
 187   (gnus-uu-mark-buffer)
 188   (gnus-draft-send-message))
 189
 190 (defun gnus-group-send-queue ()
 191   "Send all sendable articles from the queue group."
 192   (interactive)
 193   (gnus-activate-group "nndraft:queue")
 194   (save-excursion
 195     (let* ((articles (nndraft-articles))
 196            (unsendable (gnus-uncompress-range
 197                         (cdr (assq 'unsend
 198                                    (gnus-info-marks
 199                                     (gnus-get-info "nndraft:queue"))))))
 200            (gnus-posting-styles nil)
 201            (total (length articles))
 202            article)
 203       (while (setq article (pop articles))
 204         (unless (memq article unsendable)
 205           (let ((message-sending-message
 206                  (format "Sending message %d of %d..."
 207                          (- total (length articles)) total)))
 208             (gnus-draft-send article)))))))
 209
 210 ;;;###autoload
 211 (defun gnus-draft-reminder ()
 212   "Reminder user if there are unsent drafts."
 213   (interactive)
 214   (if (gnus-alive-p)
 215       (let (active)
 216         (catch 'continue
 217           (dolist (group '("nndraft:drafts" "nndraft:queue"))
 218             (setq active (gnus-activate-group group))
 219             (if (and active (>= (cdr active) (car active)))
 220                 (if (y-or-n-p "There are unsent drafts. Confirm to exit?")
 221                     (throw 'continue t)
 222                   (error "Stop!"))))))))
 223
 224 ;;; Utility functions
 225
 226 ;;;!!!If this is byte-compiled, it fails miserably.
 227 ;;;!!!This is because `gnus-setup-message' uses uninterned symbols.
 228 ;;;!!!This has been fixed in recent versions of Emacs and XEmacs,
 229 ;;;!!!but for the time being, we'll just run this tiny function uncompiled.
 230
 231 (progn
 232   (defun gnus-draft-setup (narticle group &optional restore)
 233     (let (ga)
 234       (gnus-setup-message 'forward
 235         (let ((article narticle))
 236           (message-mail)
 237           (erase-buffer)
 238           (if (not (gnus-request-restore-buffer article group))
 239               (error "Couldn't restore the article")
 240             (when (and restore
 241                        (equal group "nndraft:queue"))
 242               (mime-to-mml))
 243             ;; Insert the separator.
 244             (goto-char (point-min))
 245             (search-forward "\n\n")
 246             (forward-char -1)
 247             (insert mail-header-separator)
 248             (forward-line 1)
 249             (setq ga (message-fetch-field gnus-draft-meta-information-header))
 250             (message-set-auto-save-file-name))))
 251       (gnus-backlog-remove-article group narticle)
 252       (when (and ga
 253                  (ignore-errors (setq ga (car (read-from-string ga)))))
 254         (setq gnus-newsgroup-name
 255               (if (equal (car ga) "") nil (car ga)))
 256         (gnus-configure-posting-styles)
 257         (setq gnus-message-group-art (cons gnus-newsgroup-name (cadr ga)))
 258         (setq message-post-method
 259               `(lambda (arg)
 260                  (gnus-post-method arg ,(car ga))))
 261         (unless (equal (cadr ga) "")
 262           (message-add-action
 263            `(progn
 264               (gnus-add-mark ,(car ga) 'replied ,(cadr ga))
 265               (gnus-request-set-mark ,(car ga) (list (list (list ,(cadr ga))
 266                                                            'add '(reply)))))
 267            'send))))))
 268
 269 (defun gnus-draft-article-sendable-p (article)
 270   "Say whether ARTICLE is sendable."
 271   (not (memq article gnus-newsgroup-unsendable)))
 272
 273 (provide 'gnus-draft)
 274
 275 ;;; gnus-draft.el ends here