cgit.sxemacs.org Git - gnus/blob - lisp/gnus-draft.el

   1 ;;; gnus-draft.el --- draft message support for Gnus
   2
   3 ;; Copyright (C) 1997, 1998, 1999, 2000, 2001, 2002, 2003, 2004,
   4 ;;   2005, 2006, 2007, 2008 Free Software Foundation, Inc.
   5
   6 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   7 ;; Keywords: news
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;;; Code:
  27
  28 (require 'gnus)
  29 (require 'gnus-sum)
  30 (require 'message)
  31 (require 'gnus-msg)
  32 (require 'nndraft)
  33 (require 'gnus-agent)
  34 (eval-when-compile (require 'cl))
  35
  36 ;;; Draft minor mode
  37
  38 (defvar gnus-draft-mode nil
  39   "Minor mode for providing a draft summary buffers.")
  40
  41 (defvar gnus-draft-mode-map nil)
  42
  43 (unless gnus-draft-mode-map
  44   (setq gnus-draft-mode-map (make-sparse-keymap))
  45
  46   (gnus-define-keys gnus-draft-mode-map
  47     "Dt" gnus-draft-toggle-sending
  48     "e"  gnus-draft-edit-message ;; Use `B w' for `gnus-summary-edit-article'
  49     "De" gnus-draft-edit-message
  50     "Ds" gnus-draft-send-message
  51     "DS" gnus-draft-send-all-messages))
  52
  53 (defun gnus-draft-make-menu-bar ()
  54   (unless (boundp 'gnus-draft-menu)
  55     (easy-menu-define
  56      gnus-draft-menu gnus-draft-mode-map ""
  57      '("Drafts"
  58        ["Toggle whether to send" gnus-draft-toggle-sending t]
  59        ["Edit" gnus-draft-edit-message t]
  60        ["Send selected message(s)" gnus-draft-send-message t]
  61        ["Send all messages" gnus-draft-send-all-messages t]
  62        ["Delete draft" gnus-summary-delete-article t]))))
  63
  64 (defun gnus-draft-mode (&optional arg)
  65   "Minor mode for providing a draft summary buffers.
  66
  67 \\{gnus-draft-mode-map}"
  68   (interactive "P")
  69   (when (eq major-mode 'gnus-summary-mode)
  70     (when (set (make-local-variable 'gnus-draft-mode)
  71                (if (null arg) (not gnus-draft-mode)
  72                  (> (prefix-numeric-value arg) 0)))
  73       ;; Set up the menu.
  74       (when (gnus-visual-p 'draft-menu 'menu)
  75         (gnus-draft-make-menu-bar))
  76       (add-minor-mode 'gnus-draft-mode " Draft" gnus-draft-mode-map)
  77       (gnus-run-hooks 'gnus-draft-mode-hook))))
  78
  79 ;;; Commands
  80
  81 (defun gnus-draft-toggle-sending (article)
  82   "Toggle whether to send an article or not."
  83   (interactive (list (gnus-summary-article-number)))
  84   (if (gnus-draft-article-sendable-p article)
  85       (progn
  86         (push article gnus-newsgroup-unsendable)
  87         (gnus-summary-mark-article article gnus-unsendable-mark))
  88     (setq gnus-newsgroup-unsendable
  89           (delq article gnus-newsgroup-unsendable))
  90     (gnus-summary-mark-article article gnus-unread-mark))
  91   (gnus-summary-position-point))
  92
  93 (defun gnus-draft-edit-message ()
  94   "Enter a mail/post buffer to edit and send the draft."
  95   (interactive)
  96   (let ((article (gnus-summary-article-number))
  97         (group gnus-newsgroup-name))
  98     (gnus-draft-check-draft-articles (list article))
  99     (gnus-summary-mark-as-read article gnus-canceled-mark)
 100     (gnus-draft-setup article group t)
 101     (set-buffer-modified-p t)
 102     (save-excursion
 103       (save-restriction
 104         (message-narrow-to-headers)
 105         (message-remove-header "date")))
 106     (let ((message-draft-headers
 107            (delq 'Date (copy-sequence message-draft-headers))))
 108       (save-buffer))
 109     (let ((gnus-verbose-backends nil))
 110       (gnus-request-expire-articles (list article) group t))
 111     (push
 112      `((lambda ()
 113          (when (gnus-buffer-exists-p ,gnus-summary-buffer)
 114            (save-excursion
 115              (set-buffer ,gnus-summary-buffer)
 116              (gnus-cache-possibly-remove-article ,article nil nil nil t)))))
 117      message-send-actions)))
 118
 119 (defun gnus-draft-send-message (&optional n)
 120   "Send the current draft(s).
 121 Obeys the standard process/prefix convention."
 122   (interactive "P")
 123   (let* ((articles (gnus-summary-work-articles n))
 124          (total (length articles))
 125          article)
 126     (gnus-draft-check-draft-articles articles)
 127     (while (setq article (pop articles))
 128       (gnus-summary-remove-process-mark article)
 129       (unless (memq article gnus-newsgroup-unsendable)
 130         (let ((message-sending-message
 131                (format "Sending message %d of %d..."
 132                        (- total (length articles)) total)))
 133           (gnus-draft-send article gnus-newsgroup-name t))
 134         (gnus-summary-mark-article article gnus-canceled-mark)))))
 135
 136 (defun gnus-draft-send (article &optional group interactive)
 137   "Send message ARTICLE."
 138   (let* ((is-queue (or (not group)
 139                        (equal group "nndraft:queue")))
 140          (message-syntax-checks (if interactive message-syntax-checks
 141                                   'dont-check-for-anything-just-trust-me))
 142          (message-hidden-headers nil)
 143          (message-inhibit-body-encoding (or is-queue
 144                                             message-inhibit-body-encoding))
 145          (message-send-hook (and (not is-queue)
 146                                  message-send-hook))
 147          (message-setup-hook (and (not is-queue)
 148                                   message-setup-hook))
 149          (message-signature (and (not is-queue)
 150                                  message-signature))
 151          (gnus-agent-queue-mail (and (not is-queue)
 152                                      gnus-agent-queue-mail))
 153          (rfc2047-encode-encoded-words nil)
 154          type method move-to)
 155     (gnus-draft-setup article (or group "nndraft:queue"))
 156     ;; We read the meta-information that says how and where
 157     ;; this message is to be sent.
 158     (save-restriction
 159       (message-narrow-to-headers)
 160       (when (re-search-forward
 161              (concat "^" (regexp-quote gnus-agent-target-move-group-header)
 162                      ":") nil t)
 163         (skip-syntax-forward "-")
 164         (setq move-to (buffer-substring (point) (point-at-eol)))
 165         (message-remove-header gnus-agent-target-move-group-header))
 166       (goto-char (point-min))
 167       (when (re-search-forward
 168              (concat "^" (regexp-quote gnus-agent-meta-information-header) ":")
 169              nil t)
 170         (setq type (ignore-errors (read (current-buffer)))
 171               method (ignore-errors (read (current-buffer))))
 172         (message-remove-header gnus-agent-meta-information-header)))
 173     ;; Let Agent restore any GCC lines and have message.el perform them.
 174     (gnus-agent-restore-gcc)
 175     ;; Then we send it.  If we have no meta-information, we just send
 176     ;; it and let Message figure out how.
 177     (when (and (or (null method)
 178                    (gnus-server-opened method)
 179                    (gnus-open-server method))
 180                (if type
 181                    (let ((message-this-is-news (eq type 'news))
 182                          (message-this-is-mail (eq type 'mail))
 183                          (gnus-post-method method)
 184                          (message-post-method method))
 185                      (if move-to
 186                          (gnus-inews-do-gcc move-to)
 187                        (message-send-and-exit)))
 188                  (if move-to
 189                      (gnus-inews-do-gcc move-to)
 190                    (message-send-and-exit))))
 191       (let ((gnus-verbose-backends nil))
 192         (gnus-request-expire-articles
 193          (list article) (or group "nndraft:queue") t)))))
 194
 195 (defun gnus-draft-send-all-messages ()
 196   "Send all the sendable drafts."
 197   (interactive)
 198   (when (or
 199          gnus-expert-user
 200          (gnus-y-or-n-p
 201           "Send all drafts? "))
 202     (gnus-uu-mark-buffer)
 203     (gnus-draft-send-message)))
 204
 205 (defun gnus-group-send-queue ()
 206   "Send all sendable articles from the queue group."
 207   (interactive)
 208   (when (or gnus-plugged
 209             (not gnus-agent-prompt-send-queue)
 210             (gnus-y-or-n-p "Gnus is unplugged; really send queue? "))
 211     (gnus-activate-group "nndraft:queue")
 212     (save-excursion
 213       (let* ((articles (nndraft-articles))
 214              (unsendable (gnus-uncompress-range
 215                           (cdr (assq 'unsend
 216                                      (gnus-info-marks
 217                                       (gnus-get-info "nndraft:queue"))))))
 218              (gnus-posting-styles nil)
 219              (total (length articles))
 220              article)
 221         (while (setq article (pop articles))
 222           (unless (memq article unsendable)
 223             (let ((message-sending-message
 224                    (format "Sending message %d of %d..."
 225                            (- total (length articles)) total)))
 226               (gnus-draft-send article))))))))
 227
 228 ;;;###autoload
 229 (defun gnus-draft-reminder ()
 230   "Reminder user if there are unsent drafts."
 231   (interactive)
 232   (if (gnus-alive-p)
 233       (let (active)
 234         (catch 'continue
 235           (dolist (group '("nndraft:drafts" "nndraft:queue"))
 236             (setq active (gnus-activate-group group))
 237             (if (and active (>= (cdr active) (car active)))
 238                 (if (y-or-n-p "There are unsent drafts.  Confirm to exit? ")
 239                     (throw 'continue t)
 240                   (error "Stop!"))))))))
 241
 242 (defcustom gnus-draft-setup-hook nil
 243   "Hook run after setting up a draft buffer."
 244   :group 'gnus-message
 245   :version "23.1" ;; No Gnus
 246   :type 'hook)
 247
 248 ;;; Utility functions
 249
 250 ;;;!!!If this is byte-compiled, it fails miserably.
 251 ;;;!!!This is because `gnus-setup-message' uses uninterned symbols.
 252 ;;;!!!This has been fixed in recent versions of Emacs and XEmacs,
 253 ;;;!!!but for the time being, we'll just run this tiny function uncompiled.
 254
 255 (progn
 256   (defun gnus-draft-setup (narticle group &optional restore)
 257     (let (ga)
 258       (gnus-setup-message 'forward
 259         (let ((article narticle))
 260           (message-mail)
 261           (erase-buffer)
 262           (if (not (gnus-request-restore-buffer article group))
 263               (error "Couldn't restore the article")
 264             (when (and restore
 265                        (equal group "nndraft:queue"))
 266               (mime-to-mml))
 267             ;; Insert the separator.
 268             (goto-char (point-min))
 269             (search-forward "\n\n")
 270             (forward-char -1)
 271             (save-restriction
 272               (narrow-to-region (point-min) (point))
 273               (setq ga
 274                     (message-fetch-field gnus-draft-meta-information-header)))
 275             (insert mail-header-separator)
 276             (forward-line 1)
 277             (message-set-auto-save-file-name))))
 278       (gnus-backlog-remove-article group narticle)
 279       (when (and ga
 280                  (ignore-errors (setq ga (car (read-from-string ga)))))
 281         (setq gnus-newsgroup-name
 282               (if (equal (car ga) "") nil (car ga)))
 283         (gnus-configure-posting-styles)
 284         (setq gnus-message-group-art (cons gnus-newsgroup-name (cadr ga)))
 285         (setq message-post-method
 286               `(lambda (arg)
 287                  (gnus-post-method arg ,(car ga))))
 288         (unless (equal (cadr ga) "")
 289           (dolist (article (cdr ga))
 290             (message-add-action
 291              `(progn
 292                 (gnus-add-mark ,(car ga) 'replied ,article)
 293                 (gnus-request-set-mark ,(car ga) (list (list (list ,article)
 294                                                              'add '(reply)))))
 295              'send))))
 296       (run-hooks 'gnus-draft-setup-hook))))
 297
 298 (defun gnus-draft-article-sendable-p (article)
 299   "Say whether ARTICLE is sendable."
 300   (not (memq article gnus-newsgroup-unsendable)))
 301
 302 (defun gnus-draft-check-draft-articles (articles)
 303   "Check whether the draft articles ARTICLES are under edit."
 304   (when (equal gnus-newsgroup-name "nndraft:drafts")
 305     (let ((buffers (buffer-list))
 306           file buffs buff)
 307       (save-current-buffer
 308         (while (and articles
 309                     (not buff))
 310           (setq file (nndraft-article-filename (pop articles))
 311                 buffs buffers)
 312           (while buffs
 313             (set-buffer (setq buff (pop buffs)))
 314             (if (and buffer-file-name
 315                      (string-equal (file-truename buffer-file-name)
 316                                    (file-truename file))
 317                      (buffer-modified-p))
 318                 (setq buffs nil)
 319               (setq buff nil)))))
 320       (when buff
 321         (let* ((window (get-buffer-window buff t))
 322                (frame (and window (window-frame window))))
 323           (if frame
 324               (gnus-select-frame-set-input-focus frame)
 325             (pop-to-buffer buff t)))
 326         (error "The draft %s is under edit" file)))))
 327
 328 (provide 'gnus-draft)
 329
 330 ;; arch-tag: 3d92af58-8c97-4a5c-9db4-a98e85198022
 331 ;;; gnus-draft.el ends here