cgit.sxemacs.org Git - gnus/blob - lisp/gnus-draft.el

   1 ;;; gnus-draft.el --- draft message support for Gnus
   2
   3 ;; Copyright (C) 1997, 1998, 1999, 2000, 2001, 2002, 2003, 2004,
   4 ;;   2005, 2006, 2007, 2008, 2009 Free Software Foundation, Inc.
   5
   6 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   7 ;; Keywords: news
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;;; Code:
  27
  28 (require 'gnus)
  29 (require 'gnus-sum)
  30 (require 'message)
  31 (require 'gnus-msg)
  32 (require 'nndraft)
  33 (require 'gnus-agent)
  34 (eval-when-compile (require 'cl))
  35
  36 ;;; Draft minor mode
  37
  38 (defvar gnus-draft-mode nil
  39   "Minor mode for providing a draft summary buffers.")
  40
  41 (defvar gnus-draft-mode-map nil)
  42
  43 (unless gnus-draft-mode-map
  44   (setq gnus-draft-mode-map (make-sparse-keymap))
  45
  46   (gnus-define-keys gnus-draft-mode-map
  47     "Dt" gnus-draft-toggle-sending
  48     "e"  gnus-draft-edit-message ;; Use `B w' for `gnus-summary-edit-article'
  49     "De" gnus-draft-edit-message
  50     "Ds" gnus-draft-send-message
  51     "DS" gnus-draft-send-all-messages))
  52
  53 (defun gnus-draft-make-menu-bar ()
  54   (unless (boundp 'gnus-draft-menu)
  55     (easy-menu-define
  56      gnus-draft-menu gnus-draft-mode-map ""
  57      '("Drafts"
  58        ["Toggle whether to send" gnus-draft-toggle-sending t]
  59        ["Edit" gnus-draft-edit-message t]
  60        ["Send selected message(s)" gnus-draft-send-message t]
  61        ["Send all messages" gnus-draft-send-all-messages t]
  62        ["Delete draft" gnus-summary-delete-article t]))))
  63
  64 (defun gnus-draft-mode (&optional arg)
  65   "Minor mode for providing a draft summary buffers.
  66
  67 \\{gnus-draft-mode-map}"
  68   (interactive "P")
  69   (when (eq major-mode 'gnus-summary-mode)
  70     (when (set (make-local-variable 'gnus-draft-mode)
  71                (if (null arg) (not gnus-draft-mode)
  72                  (> (prefix-numeric-value arg) 0)))
  73       ;; Set up the menu.
  74       (when (gnus-visual-p 'draft-menu 'menu)
  75         (gnus-draft-make-menu-bar))
  76       (add-minor-mode 'gnus-draft-mode " Draft" gnus-draft-mode-map)
  77       (gnus-run-hooks 'gnus-draft-mode-hook))))
  78
  79 ;;; Commands
  80
  81 (defun gnus-draft-toggle-sending (article)
  82   "Toggle whether to send an article or not."
  83   (interactive (list (gnus-summary-article-number)))
  84   (if (gnus-draft-article-sendable-p article)
  85       (progn
  86         (push article gnus-newsgroup-unsendable)
  87         (gnus-summary-mark-article article gnus-unsendable-mark))
  88     (setq gnus-newsgroup-unsendable
  89           (delq article gnus-newsgroup-unsendable))
  90     (gnus-summary-mark-article article gnus-unread-mark))
  91   (gnus-summary-position-point))
  92
  93 (defun gnus-draft-edit-message ()
  94   "Enter a mail/post buffer to edit and send the draft."
  95   (interactive)
  96   (let ((article (gnus-summary-article-number))
  97         (group gnus-newsgroup-name))
  98     (gnus-draft-check-draft-articles (list article))
  99     (gnus-summary-mark-as-read article gnus-canceled-mark)
 100     (gnus-draft-setup article group t)
 101     (set-buffer-modified-p t)
 102     (save-excursion
 103       (save-restriction
 104         (message-narrow-to-headers)
 105         (message-remove-header "date")))
 106     (let ((message-draft-headers
 107            (delq 'Date (copy-sequence message-draft-headers))))
 108       (save-buffer))
 109     (let ((gnus-verbose-backends nil))
 110       (gnus-request-expire-articles (list article) group t))
 111     (push
 112      `((lambda ()
 113          (when (gnus-buffer-exists-p ,gnus-summary-buffer)
 114            (save-excursion
 115              (set-buffer ,gnus-summary-buffer)
 116              (gnus-cache-possibly-remove-article ,article nil nil nil t)))))
 117      message-send-actions)))
 118
 119 (defun gnus-draft-send-message (&optional n)
 120   "Send the current draft(s).
 121 Obeys the standard process/prefix convention."
 122   (interactive "P")
 123   (let* ((articles (gnus-summary-work-articles n))
 124          (total (length articles))
 125          article)
 126     (gnus-draft-check-draft-articles articles)
 127     (while (setq article (pop articles))
 128       (gnus-summary-remove-process-mark article)
 129       (unless (memq article gnus-newsgroup-unsendable)
 130         (let ((message-sending-message
 131                (format "Sending message %d of %d..."
 132                        (- total (length articles)) total)))
 133           (gnus-draft-send article gnus-newsgroup-name t))
 134         (gnus-summary-mark-article article gnus-canceled-mark)))))
 135
 136 (defun gnus-draft-send (article &optional group interactive)
 137   "Send message ARTICLE."
 138   (let* ((is-queue (or (not group)
 139                        (equal group "nndraft:queue")))
 140          (message-syntax-checks (if interactive message-syntax-checks
 141                                   'dont-check-for-anything-just-trust-me))
 142          (message-hidden-headers nil)
 143          (message-inhibit-body-encoding (or is-queue
 144                                             message-inhibit-body-encoding))
 145          (message-send-hook (and (not is-queue)
 146                                  message-send-hook))
 147          (message-setup-hook (and (not is-queue)
 148                                   message-setup-hook))
 149          (gnus-message-setup-hook (and (not is-queue)
 150                                        gnus-message-setup-hook))
 151          (message-signature (and (not is-queue)
 152                                  message-signature))
 153          (gnus-agent-queue-mail (and (not is-queue)
 154                                      gnus-agent-queue-mail))
 155          (rfc2047-encode-encoded-words nil)
 156          type method move-to)
 157     (gnus-draft-setup article (or group "nndraft:queue"))
 158     ;; We read the meta-information that says how and where
 159     ;; this message is to be sent.
 160     (save-restriction
 161       (message-narrow-to-headers)
 162       (when (re-search-forward
 163              (concat "^" (regexp-quote gnus-agent-target-move-group-header)
 164                      ":") nil t)
 165         (skip-syntax-forward "-")
 166         (setq move-to (buffer-substring (point) (point-at-eol)))
 167         (message-remove-header gnus-agent-target-move-group-header))
 168       (goto-char (point-min))
 169       (when (re-search-forward
 170              (concat "^" (regexp-quote gnus-agent-meta-information-header) ":")
 171              nil t)
 172         (setq type (ignore-errors (read (current-buffer)))
 173               method (ignore-errors (read (current-buffer))))
 174         (message-remove-header gnus-agent-meta-information-header)))
 175     ;; Let Agent restore any GCC lines and have message.el perform them.
 176     (gnus-agent-restore-gcc)
 177     ;; Then we send it.  If we have no meta-information, we just send
 178     ;; it and let Message figure out how.
 179     (when (and (or (null method)
 180                    (gnus-server-opened method)
 181                    (gnus-open-server method))
 182                (if type
 183                    (let ((message-this-is-news (eq type 'news))
 184                          (message-this-is-mail (eq type 'mail))
 185                          (gnus-post-method method)
 186                          (message-post-method method))
 187                      (if move-to
 188                          (gnus-inews-do-gcc move-to)
 189                        (message-send-and-exit)))
 190                  (if move-to
 191                      (gnus-inews-do-gcc move-to)
 192                    (message-send-and-exit))))
 193       (let ((gnus-verbose-backends nil))
 194         (gnus-request-expire-articles
 195          (list article) (or group "nndraft:queue") t)))))
 196
 197 (defun gnus-draft-send-all-messages ()
 198   "Send all the sendable drafts."
 199   (interactive)
 200   (when (or
 201          gnus-expert-user
 202          (gnus-y-or-n-p
 203           "Send all drafts? "))
 204     (gnus-uu-mark-buffer)
 205     (gnus-draft-send-message)))
 206
 207 (defun gnus-group-send-queue ()
 208   "Send all sendable articles from the queue group."
 209   (interactive)
 210   (when (or gnus-plugged
 211             (not gnus-agent-prompt-send-queue)
 212             (gnus-y-or-n-p "Gnus is unplugged; really send queue? "))
 213     (gnus-activate-group "nndraft:queue")
 214     (save-excursion
 215       (let* ((articles (nndraft-articles))
 216              (unsendable (gnus-uncompress-range
 217                           (cdr (assq 'unsend
 218                                      (gnus-info-marks
 219                                       (gnus-get-info "nndraft:queue"))))))
 220              (gnus-posting-styles nil)
 221              message-send-mail-partially-limit
 222              (total (length articles))
 223              article)
 224         (while (setq article (pop articles))
 225           (unless (memq article unsendable)
 226             (let ((message-sending-message
 227                    (format "Sending message %d of %d..."
 228                            (- total (length articles)) total)))
 229               (gnus-draft-send article))))))))
 230
 231 ;;;###autoload
 232 (defun gnus-draft-reminder ()
 233   "Reminder user if there are unsent drafts."
 234   (interactive)
 235   (if (gnus-alive-p)
 236       (let (active)
 237         (catch 'continue
 238           (dolist (group '("nndraft:drafts" "nndraft:queue"))
 239             (setq active (gnus-activate-group group))
 240             (if (and active (>= (cdr active) (car active)))
 241                 (if (y-or-n-p "There are unsent drafts.  Confirm to exit? ")
 242                     (throw 'continue t)
 243                   (error "Stop!"))))))))
 244
 245 (defcustom gnus-draft-setup-hook nil
 246   "Hook run after setting up a draft buffer."
 247   :group 'gnus-message
 248   :version "23.1" ;; No Gnus
 249   :type 'hook)
 250
 251 ;;; Utility functions
 252
 253 ;;;!!!If this is byte-compiled, it fails miserably.
 254 ;;;!!!This is because `gnus-setup-message' uses uninterned symbols.
 255 ;;;!!!This has been fixed in recent versions of Emacs and XEmacs,
 256 ;;;!!!but for the time being, we'll just run this tiny function uncompiled.
 257
 258 (progn
 259   (defun gnus-draft-setup (narticle group &optional restore)
 260     (let (ga)
 261       (gnus-setup-message 'forward
 262         (let ((article narticle))
 263           (message-mail)
 264           (erase-buffer)
 265           (if (not (gnus-request-restore-buffer article group))
 266               (error "Couldn't restore the article")
 267             (when (and restore
 268                        (equal group "nndraft:queue"))
 269               (mime-to-mml))
 270             ;; Insert the separator.
 271             (goto-char (point-min))
 272             (search-forward "\n\n")
 273             (forward-char -1)
 274             (save-restriction
 275               (narrow-to-region (point-min) (point))
 276               (setq ga
 277                     (message-fetch-field gnus-draft-meta-information-header)))
 278             (insert mail-header-separator)
 279             (forward-line 1)
 280             (message-set-auto-save-file-name))))
 281       (gnus-backlog-remove-article group narticle)
 282       (when (and ga
 283                  (ignore-errors (setq ga (car (read-from-string ga)))))
 284         (setq gnus-newsgroup-name
 285               (if (equal (car ga) "") nil (car ga)))
 286         (gnus-configure-posting-styles)
 287         (setq gnus-message-group-art (cons gnus-newsgroup-name (cadr ga)))
 288         (setq message-post-method
 289               `(lambda (arg)
 290                  (gnus-post-method arg ,(car ga))))
 291         (unless (equal (cadr ga) "")
 292           (dolist (article (cdr ga))
 293             (message-add-action
 294              `(progn
 295                 (gnus-add-mark ,(car ga) 'replied ,article)
 296                 (gnus-request-set-mark ,(car ga) (list (list (list ,article)
 297                                                              'add '(reply)))))
 298              'send))))
 299       (run-hooks 'gnus-draft-setup-hook))))
 300
 301 (defun gnus-draft-article-sendable-p (article)
 302   "Say whether ARTICLE is sendable."
 303   (not (memq article gnus-newsgroup-unsendable)))
 304
 305 (defun gnus-draft-check-draft-articles (articles)
 306   "Check whether the draft articles ARTICLES are under edit."
 307   (when (equal gnus-newsgroup-name "nndraft:drafts")
 308     (let ((buffers (buffer-list))
 309           file buffs buff)
 310       (save-current-buffer
 311         (while (and articles
 312                     (not buff))
 313           (setq file (nndraft-article-filename (pop articles))
 314                 buffs buffers)
 315           (while buffs
 316             (set-buffer (setq buff (pop buffs)))
 317             (if (and buffer-file-name
 318                      (string-equal (file-truename buffer-file-name)
 319                                    (file-truename file))
 320                      (buffer-modified-p))
 321                 (setq buffs nil)
 322               (setq buff nil)))))
 323       (when buff
 324         (let* ((window (get-buffer-window buff t))
 325                (frame (and window (window-frame window))))
 326           (if frame
 327               (gnus-select-frame-set-input-focus frame)
 328             (pop-to-buffer buff t)))
 329         (error "The draft %s is under edit" file)))))
 330
 331 (provide 'gnus-draft)
 332
 333 ;; arch-tag: 3d92af58-8c97-4a5c-9db4-a98e85198022
 334 ;;; gnus-draft.el ends here