cgit.sxemacs.org Git - gnus/blob - lisp/gnus-demon.el

   1 ;;; gnus-demon.el --- daemonic Gnus behaviour
   2
   3 ;; Copyright (C) 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003, 2004,
   4 ;;   2005, 2006, 2007 Free Software Foundation, Inc.
   5
   6 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   7 ;; Keywords: news
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  24 ;; Boston, MA 02110-1301, USA.
  25
  26 ;;; Commentary:
  27
  28 ;;; Code:
  29
  30 (eval-when-compile (require 'cl))
  31
  32 (require 'gnus)
  33 (require 'gnus-int)
  34 (require 'nnheader)
  35 (require 'nntp)
  36 (require 'nnmail)
  37 (require 'gnus-util)
  38
  39 (autoload 'parse-time-string "parse-time" nil nil)
  40
  41 (defgroup gnus-demon nil
  42   "Demonic behaviour."
  43   :group 'gnus)
  44
  45 (defcustom gnus-demon-handlers nil
  46   "Alist of daemonic handlers to be run at intervals.
  47 Each handler is a list on the form
  48
  49 \(FUNCTION TIME IDLE)
  50
  51 FUNCTION is the function to be called.
  52 TIME is the number of `gnus-demon-timestep's between each call.
  53 If nil, never call.  If t, call each `gnus-demon-timestep'.
  54 If IDLE is t, only call if Emacs has been idle for a while.  If IDLE
  55 is a number, only call when Emacs has been idle more than this number
  56 of `gnus-demon-timestep's.  If IDLE is nil, don't care about
  57 idleness.  If IDLE is a number and TIME is nil, then call once each
  58 time Emacs has been idle for IDLE `gnus-demon-timestep's."
  59   :group 'gnus-demon
  60   :type '(repeat (list function
  61                        (choice :tag "Time"
  62                                (const :tag "never" nil)
  63                                (const :tag "one" t)
  64                                (integer :tag "steps" 1))
  65                        (choice :tag "Idle"
  66                                (const :tag "don't care" nil)
  67                                (const :tag "for a while" t)
  68                                (integer :tag "steps" 1)))))
  69
  70 (defcustom gnus-demon-timestep 60
  71   "*Number of seconds in each demon timestep."
  72   :group 'gnus-demon
  73   :type 'integer)
  74
  75 ;;; Internal variables.
  76
  77 (defvar gnus-demon-timer nil)
  78 (defvar gnus-demon-idle-has-been-called nil)
  79 (defvar gnus-demon-idle-time 0)
  80 (defvar gnus-demon-handler-state nil)
  81 (defvar gnus-demon-last-keys nil)
  82 (defvar gnus-inhibit-demon nil
  83   "*If non-nil, no daemonic function will be run.")
  84
  85 ;;; Functions.
  86
  87 (defun gnus-demon-add-handler (function time idle)
  88   "Add the handler FUNCTION to be run at TIME and IDLE."
  89   ;; First remove any old handlers that use this function.
  90   (gnus-demon-remove-handler function)
  91   ;; Then add the new one.
  92   (push (list function time idle) gnus-demon-handlers)
  93   (gnus-demon-init))
  94
  95 (defun gnus-demon-remove-handler (function &optional no-init)
  96   "Remove the handler FUNCTION from the list of handlers."
  97   (gnus-pull function gnus-demon-handlers)
  98   (unless no-init
  99     (gnus-demon-init)))
 100
 101 (defun gnus-demon-init ()
 102   "Initialize the Gnus daemon."
 103   (interactive)
 104   (gnus-demon-cancel)
 105   (when gnus-demon-handlers
 106     ;; Set up the timer.
 107     (setq gnus-demon-timer
 108           (run-at-time
 109            gnus-demon-timestep gnus-demon-timestep 'gnus-demon))
 110     ;; Reset control variables.
 111     (setq gnus-demon-handler-state
 112           (mapcar
 113            (lambda (handler)
 114              (list (car handler) (gnus-demon-time-to-step (nth 1 handler))
 115                    (nth 2 handler)))
 116            gnus-demon-handlers))
 117     (setq gnus-demon-idle-time 0)
 118     (setq gnus-demon-idle-has-been-called nil)))
 119
 120 (gnus-add-shutdown 'gnus-demon-cancel 'gnus)
 121
 122 (defun gnus-demon-cancel ()
 123   "Cancel any Gnus daemons."
 124   (interactive)
 125   (when gnus-demon-timer
 126     (nnheader-cancel-timer gnus-demon-timer))
 127   (setq gnus-demon-timer nil
 128         gnus-demon-idle-has-been-called nil)
 129   (condition-case ()
 130       (nnheader-cancel-function-timers 'gnus-demon)
 131     (error t)))
 132
 133 (defun gnus-demon-is-idle-p ()
 134   "Whether Emacs is idle or not."
 135   ;; We do this simply by comparing the 100 most recent keystrokes
 136   ;; with the ones we had last time.  If they are the same, one might
 137   ;; guess that Emacs is indeed idle.  This only makes sense if one
 138   ;; calls this function seldom -- like once a minute, which is what
 139   ;; we do here.
 140   (let ((keys (recent-keys)))
 141     (or (equal keys gnus-demon-last-keys)
 142         (progn
 143           (setq gnus-demon-last-keys keys)
 144           nil))))
 145
 146 (defun gnus-demon-time-to-step (time)
 147   "Find out how many seconds to TIME, which is on the form \"17:43\"."
 148   (if (not (stringp time))
 149       time
 150     (let* ((now (current-time))
 151            ;; obtain NOW as discrete components -- make a vector for speed
 152            (nowParts (decode-time now))
 153            ;; obtain THEN as discrete components
 154            (thenParts (parse-time-string time))
 155            (thenHour (elt thenParts 2))
 156            (thenMin (elt thenParts 1))
 157            ;; convert time as elements into number of seconds since EPOCH.
 158            (then (encode-time 0
 159                               thenMin
 160                               thenHour
 161                               ;; If THEN is earlier than NOW, make it
 162                               ;; same time tomorrow.  Doc for encode-time
 163                               ;; says that this is OK.
 164                               (+ (elt nowParts 3)
 165                                  (if (or (< thenHour (elt nowParts 2))
 166                                          (and (= thenHour (elt nowParts 2))
 167                                               (<= thenMin (elt nowParts 1))))
 168                                      1 0))
 169                               (elt nowParts 4)
 170                               (elt nowParts 5)
 171                               (elt nowParts 6)
 172                               (elt nowParts 7)
 173                               (elt nowParts 8)))
 174            ;; calculate number of seconds between NOW and THEN
 175            (diff (+ (* 65536 (- (car then) (car now)))
 176                     (- (cadr then) (cadr now)))))
 177       ;; return number of timesteps in the number of seconds
 178       (round (/ diff gnus-demon-timestep)))))
 179
 180 (defun gnus-demon ()
 181   "The Gnus daemon that takes care of running all Gnus handlers."
 182   ;; Increase or reset the time Emacs has been idle.
 183   (if (gnus-demon-is-idle-p)
 184       (incf gnus-demon-idle-time)
 185     (setq gnus-demon-idle-time 0)
 186     (setq gnus-demon-idle-has-been-called nil))
 187   ;; Disable all daemonic stuff if we're in the minibuffer
 188   (when (and (not (window-minibuffer-p (selected-window)))
 189              (not gnus-inhibit-demon))
 190     ;; Then we go through all the handler and call those that are
 191     ;; sufficiently ripe.
 192     (let ((handlers gnus-demon-handler-state)
 193           (gnus-inhibit-demon t)
 194           ;; Try to avoid dialog boxes, e.g. by Mailcrypt.
 195           ;; Unfortunately, Emacs 20's `message-or-box...' doesn't
 196           ;; obey `use-dialog-box'.
 197           use-dialog-box (last-nonmenu-event 10)
 198           handler time idle)
 199       (while handlers
 200         (setq handler (pop handlers))
 201         (cond
 202          ((numberp (setq time (nth 1 handler)))
 203           ;; These handlers use a regular timeout mechanism.  We decrease
 204           ;; the timer if it hasn't reached zero yet.
 205           (unless (zerop time)
 206             (setcar (nthcdr 1 handler) (decf time)))
 207           (and (zerop time)             ; If the timer now is zero...
 208                ;; Test for appropriate idleness
 209                (progn
 210                  (setq idle (nth 2 handler))
 211                  (cond
 212                   ((null idle) t)       ; Don't care about idle.
 213                   ((numberp idle)       ; Numerical idle...
 214                    (< idle gnus-demon-idle-time)) ; Idle timed out.
 215                   (t (< 0 gnus-demon-idle-time)))) ; Or just need to be idle.
 216                ;; So we call the handler.
 217                (gnus-with-local-quit
 218                  (ignore-errors (funcall (car handler)))
 219                  ;; And reset the timer.
 220                  (setcar (nthcdr 1 handler)
 221                          (gnus-demon-time-to-step
 222                           (nth 1 (assq (car handler) gnus-demon-handlers)))))))
 223          ;; These are only supposed to be called when Emacs is idle.
 224          ((null (setq idle (nth 2 handler)))
 225           ;; We do nothing.
 226           )
 227          ((and (not (numberp idle))
 228                (gnus-demon-is-idle-p))
 229           ;; We want to call this handler each and every time that
 230           ;; Emacs is idle.
 231           (gnus-with-local-quit
 232             (ignore-errors (funcall (car handler)))))
 233          (t
 234           ;; We want to call this handler only if Emacs has been idle
 235           ;; for a specified number of timesteps.
 236           (and (not (memq (car handler) gnus-demon-idle-has-been-called))
 237                (< idle gnus-demon-idle-time)
 238                (gnus-demon-is-idle-p)
 239                (gnus-with-local-quit
 240                  (ignore-errors (funcall (car handler)))
 241                  ;; Make sure the handler won't be called once more in
 242                  ;; this idle-cycle.
 243                  (push (car handler) gnus-demon-idle-has-been-called)))))))))
 244
 245 (defun gnus-demon-add-nocem ()
 246   "Add daemonic NoCeM handling to Gnus."
 247   (gnus-demon-add-handler 'gnus-demon-scan-nocem 60 30))
 248
 249 (defun gnus-demon-scan-nocem ()
 250   "Scan NoCeM groups for NoCeM messages."
 251   (save-window-excursion
 252     (gnus-nocem-scan-groups)))
 253
 254 (defun gnus-demon-add-disconnection ()
 255   "Add daemonic server disconnection to Gnus."
 256   (gnus-demon-add-handler 'gnus-demon-close-connections nil 30))
 257
 258 (defun gnus-demon-close-connections ()
 259   (save-window-excursion
 260     (gnus-close-backends)))
 261
 262 (defun gnus-demon-add-nntp-close-connection ()
 263   "Add daemonic nntp server disconnection to Gnus.
 264 If no commands have gone out via nntp during the last five
 265 minutes, the connection is closed."
 266   (gnus-demon-add-handler 'gnus-demon-nntp-close-connections 5 nil))
 267
 268 (defun gnus-demon-nntp-close-connection ()
 269   (save-window-excursion
 270     (when (time-less-p '(0 300) (time-since nntp-last-command-time))
 271       (nntp-close-server))))
 272
 273 (defun gnus-demon-add-scanmail ()
 274   "Add daemonic scanning of mail from the mail backends."
 275   (gnus-demon-add-handler 'gnus-demon-scan-mail 120 60))
 276
 277 (defun gnus-demon-scan-mail ()
 278   (save-window-excursion
 279     (let ((servers gnus-opened-servers)
 280           server
 281           (nnmail-fetched-sources (list t)))
 282       (while (setq server (car (pop servers)))
 283         (and (gnus-check-backend-function 'request-scan (car server))
 284              (or (gnus-server-opened server)
 285                  (gnus-open-server server))
 286              (gnus-request-scan nil server))))))
 287
 288 (defun gnus-demon-add-rescan ()
 289   "Add daemonic scanning of new articles from all backends."
 290   (gnus-demon-add-handler 'gnus-demon-scan-news 120 60))
 291
 292 (defun gnus-demon-scan-news ()
 293   (let ((win (current-window-configuration)))
 294     (unwind-protect
 295         (save-window-excursion
 296           (save-excursion
 297             (when (gnus-alive-p)
 298               (save-excursion
 299                 (set-buffer gnus-group-buffer)
 300                 (gnus-group-get-new-news)))))
 301       (set-window-configuration win))))
 302
 303 (defun gnus-demon-add-scan-timestamps ()
 304   "Add daemonic updating of timestamps in empty newgroups."
 305   (gnus-demon-add-handler 'gnus-demon-scan-timestamps nil 30))
 306
 307 (defun gnus-demon-scan-timestamps ()
 308   "Set the timestamp on all newsgroups with no unread and no ticked articles."
 309   (when (gnus-alive-p)
 310     (let ((cur-time (current-time))
 311           (newsrc (cdr gnus-newsrc-alist))
 312           info group unread has-ticked)
 313       (while (setq info (pop newsrc))
 314         (setq group (gnus-info-group info)
 315               unread (gnus-group-unread group)
 316               has-ticked (cdr (assq 'tick (gnus-info-marks info))))
 317         (when (and (numberp unread)
 318                    (= unread 0)
 319                    (not has-ticked))
 320           (gnus-group-set-parameter group 'timestamp cur-time))))))
 321
 322 (provide 'gnus-demon)
 323
 324 ;;; arch-tag: 8dd5cd3d-6ae4-46b4-9b15-f5fca09fd392
 325 ;;; gnus-demon.el ends here