cgit.sxemacs.org Git - gnus/blob - lisp/gnus-demon.el

   1 ;;; gnus-demon.el --- daemonic Gnus behaviour
   2
   3 ;; Copyright (C) 1995, 1996, 1997, 1998, 1999, 2000, 2002, 2003, 2004,
   4 ;;   2005, 2006 Free Software Foundation, Inc.
   5
   6 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   7 ;; Keywords: news
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  24 ;; Boston, MA 02110-1301, USA.
  25
  26 ;;; Commentary:
  27
  28 ;;; Code:
  29
  30 (eval-when-compile (require 'cl))
  31
  32 (require 'gnus)
  33 (require 'gnus-int)
  34 (require 'nnheader)
  35 (require 'nntp)
  36 (require 'nnmail)
  37 (require 'gnus-util)
  38 (eval-and-compile
  39   (if (featurep 'xemacs)
  40       (require 'timer-funcs)
  41     (require 'timer)))
  42
  43 (autoload 'parse-time-string "parse-time" nil nil)
  44
  45 (defgroup gnus-demon nil
  46   "Demonic behaviour."
  47   :group 'gnus)
  48
  49 (defcustom gnus-demon-handlers nil
  50   "Alist of daemonic handlers to be run at intervals.
  51 Each handler is a list on the form
  52
  53 \(FUNCTION TIME IDLE)
  54
  55 FUNCTION is the function to be called.
  56 TIME is the number of `gnus-demon-timestep's between each call.
  57 If nil, never call.  If t, call each `gnus-demon-timestep'.
  58 If IDLE is t, only call if Emacs has been idle for a while.  If IDLE
  59 is a number, only call when Emacs has been idle more than this number
  60 of `gnus-demon-timestep's.  If IDLE is nil, don't care about
  61 idleness.  If IDLE is a number and TIME is nil, then call once each
  62 time Emacs has been idle for IDLE `gnus-demon-timestep's."
  63   :group 'gnus-demon
  64   :type '(repeat (list function
  65                        (choice :tag "Time"
  66                                (const :tag "never" nil)
  67                                (const :tag "one" t)
  68                                (integer :tag "steps" 1))
  69                        (choice :tag "Idle"
  70                                (const :tag "don't care" nil)
  71                                (const :tag "for a while" t)
  72                                (integer :tag "steps" 1)))))
  73
  74 (defcustom gnus-demon-timestep 60
  75   "*Number of seconds in each demon timestep."
  76   :group 'gnus-demon
  77   :type 'integer)
  78
  79 ;;; Internal variables.
  80
  81 (defvar gnus-demon-timer nil)
  82 (defvar gnus-demon-idle-has-been-called nil)
  83 (defvar gnus-demon-idle-time 0)
  84 (defvar gnus-demon-handler-state nil)
  85 (defvar gnus-demon-last-keys nil)
  86 (defvar gnus-inhibit-demon nil
  87   "*If non-nil, no daemonic function will be run.")
  88
  89 ;;; Functions.
  90
  91 (defun gnus-demon-add-handler (function time idle)
  92   "Add the handler FUNCTION to be run at TIME and IDLE."
  93   ;; First remove any old handlers that use this function.
  94   (gnus-demon-remove-handler function)
  95   ;; Then add the new one.
  96   (push (list function time idle) gnus-demon-handlers)
  97   (gnus-demon-init))
  98
  99 (defun gnus-demon-remove-handler (function &optional no-init)
 100   "Remove the handler FUNCTION from the list of handlers."
 101   (gnus-pull function gnus-demon-handlers)
 102   (unless no-init
 103     (gnus-demon-init)))
 104
 105 (defun gnus-demon-init ()
 106   "Initialize the Gnus daemon."
 107   (interactive)
 108   (gnus-demon-cancel)
 109   (when gnus-demon-handlers
 110     ;; Set up the timer.
 111     (setq gnus-demon-timer
 112           (run-at-time
 113            gnus-demon-timestep gnus-demon-timestep 'gnus-demon))
 114     ;; Reset control variables.
 115     (setq gnus-demon-handler-state
 116           (mapcar
 117            (lambda (handler)
 118              (list (car handler) (gnus-demon-time-to-step (nth 1 handler))
 119                    (nth 2 handler)))
 120            gnus-demon-handlers))
 121     (setq gnus-demon-idle-time 0)
 122     (setq gnus-demon-idle-has-been-called nil)))
 123
 124 (gnus-add-shutdown 'gnus-demon-cancel 'gnus)
 125
 126 (defun gnus-demon-cancel ()
 127   "Cancel any Gnus daemons."
 128   (interactive)
 129   (when gnus-demon-timer
 130     (nnheader-cancel-timer gnus-demon-timer))
 131   (setq gnus-demon-timer nil
 132         gnus-demon-idle-has-been-called nil)
 133   (condition-case ()
 134       (nnheader-cancel-function-timers 'gnus-demon)
 135     (error t)))
 136
 137 (defun gnus-demon-is-idle-p ()
 138   "Whether Emacs is idle or not."
 139   ;; We do this simply by comparing the 100 most recent keystrokes
 140   ;; with the ones we had last time.  If they are the same, one might
 141   ;; guess that Emacs is indeed idle.  This only makes sense if one
 142   ;; calls this function seldom -- like once a minute, which is what
 143   ;; we do here.
 144   (let ((keys (recent-keys)))
 145     (or (equal keys gnus-demon-last-keys)
 146         (progn
 147           (setq gnus-demon-last-keys keys)
 148           nil))))
 149
 150 (defun gnus-demon-time-to-step (time)
 151   "Find out how many seconds to TIME, which is on the form \"17:43\"."
 152   (if (not (stringp time))
 153       time
 154     (let* ((now (current-time))
 155            ;; obtain NOW as discrete components -- make a vector for speed
 156            (nowParts (decode-time now))
 157            ;; obtain THEN as discrete components
 158            (thenParts (parse-time-string time))
 159            (thenHour (elt thenParts 2))
 160            (thenMin (elt thenParts 1))
 161            ;; convert time as elements into number of seconds since EPOCH.
 162            (then (encode-time 0
 163                               thenMin
 164                               thenHour
 165                               ;; If THEN is earlier than NOW, make it
 166                               ;; same time tomorrow.  Doc for encode-time
 167                               ;; says that this is OK.
 168                               (+ (elt nowParts 3)
 169                                  (if (or (< thenHour (elt nowParts 2))
 170                                          (and (= thenHour (elt nowParts 2))
 171                                               (<= thenMin (elt nowParts 1))))
 172                                      1 0))
 173                               (elt nowParts 4)
 174                               (elt nowParts 5)
 175                               (elt nowParts 6)
 176                               (elt nowParts 7)
 177                               (elt nowParts 8)))
 178            ;; calculate number of seconds between NOW and THEN
 179            (diff (+ (* 65536 (- (car then) (car now)))
 180                     (- (cadr then) (cadr now)))))
 181       ;; return number of timesteps in the number of seconds
 182       (round (/ diff gnus-demon-timestep)))))
 183
 184 (defun gnus-demon ()
 185   "The Gnus daemon that takes care of running all Gnus handlers."
 186   ;; Increase or reset the time Emacs has been idle.
 187   (if (gnus-demon-is-idle-p)
 188       (incf gnus-demon-idle-time)
 189     (setq gnus-demon-idle-time 0)
 190     (setq gnus-demon-idle-has-been-called nil))
 191   ;; Disable all daemonic stuff if we're in the minibuffer
 192   (when (and (not (window-minibuffer-p (selected-window)))
 193              (not gnus-inhibit-demon))
 194     ;; Then we go through all the handler and call those that are
 195     ;; sufficiently ripe.
 196     (let ((handlers gnus-demon-handler-state)
 197           (gnus-inhibit-demon t)
 198           ;; Try to avoid dialog boxes, e.g. by Mailcrypt.
 199           ;; Unfortunately, Emacs 20's `message-or-box...' doesn't
 200           ;; obey `use-dialog-box'.
 201           use-dialog-box (last-nonmenu-event 10)
 202           handler time idle)
 203       (while handlers
 204         (setq handler (pop handlers))
 205         (cond
 206          ((numberp (setq time (nth 1 handler)))
 207           ;; These handlers use a regular timeout mechanism.  We decrease
 208           ;; the timer if it hasn't reached zero yet.
 209           (unless (zerop time)
 210             (setcar (nthcdr 1 handler) (decf time)))
 211           (and (zerop time)             ; If the timer now is zero...
 212                ;; Test for appropriate idleness
 213                (progn
 214                  (setq idle (nth 2 handler))
 215                  (cond
 216                   ((null idle) t)       ; Don't care about idle.
 217                   ((numberp idle)       ; Numerical idle...
 218                    (< idle gnus-demon-idle-time)) ; Idle timed out.
 219                   (t (< 0 gnus-demon-idle-time)))) ; Or just need to be idle.
 220                ;; So we call the handler.
 221                (progn
 222                  (ignore-errors (funcall (car handler)))
 223                  ;; And reset the timer.
 224                  (setcar (nthcdr 1 handler)
 225                          (gnus-demon-time-to-step
 226                           (nth 1 (assq (car handler) gnus-demon-handlers)))))))
 227          ;; These are only supposed to be called when Emacs is idle.
 228          ((null (setq idle (nth 2 handler)))
 229           ;; We do nothing.
 230           )
 231          ((and (not (numberp idle))
 232                (gnus-demon-is-idle-p))
 233           ;; We want to call this handler each and every time that
 234           ;; Emacs is idle.
 235           (ignore-errors (funcall (car handler))))
 236          (t
 237           ;; We want to call this handler only if Emacs has been idle
 238           ;; for a specified number of timesteps.
 239           (and (not (memq (car handler) gnus-demon-idle-has-been-called))
 240                (< idle gnus-demon-idle-time)
 241                (gnus-demon-is-idle-p)
 242                (progn
 243                  (ignore-errors (funcall (car handler)))
 244                  ;; Make sure the handler won't be called once more in
 245                  ;; this idle-cycle.
 246                  (push (car handler) gnus-demon-idle-has-been-called)))))))))
 247
 248 (defun gnus-demon-add-nocem ()
 249   "Add daemonic NoCeM handling to Gnus."
 250   (gnus-demon-add-handler 'gnus-demon-scan-nocem 60 30))
 251
 252 (defun gnus-demon-scan-nocem ()
 253   "Scan NoCeM groups for NoCeM messages."
 254   (save-window-excursion
 255     (gnus-nocem-scan-groups)))
 256
 257 (defun gnus-demon-add-disconnection ()
 258   "Add daemonic server disconnection to Gnus."
 259   (gnus-demon-add-handler 'gnus-demon-close-connections nil 30))
 260
 261 (defun gnus-demon-close-connections ()
 262   (save-window-excursion
 263     (gnus-close-backends)))
 264
 265 (defun gnus-demon-add-nntp-close-connection ()
 266   "Add daemonic nntp server disconnection to Gnus.
 267 If no commands have gone out via nntp during the last five
 268 minutes, the connection is closed."
 269   (gnus-demon-add-handler 'gnus-demon-nntp-close-connections 5 nil))
 270
 271 (defun gnus-demon-nntp-close-connection ()
 272   (save-window-excursion
 273     (when (time-less-p '(0 300) (time-since nntp-last-command-time))
 274       (nntp-close-server))))
 275
 276 (defun gnus-demon-add-scanmail ()
 277   "Add daemonic scanning of mail from the mail backends."
 278   (gnus-demon-add-handler 'gnus-demon-scan-mail 120 60))
 279
 280 (defun gnus-demon-scan-mail ()
 281   (save-window-excursion
 282     (let ((servers gnus-opened-servers)
 283           server
 284           (nnmail-fetched-sources (list t)))
 285       (while (setq server (car (pop servers)))
 286         (and (gnus-check-backend-function 'request-scan (car server))
 287              (or (gnus-server-opened server)
 288                  (gnus-open-server server))
 289              (gnus-request-scan nil server))))))
 290
 291 (defun gnus-demon-add-rescan ()
 292   "Add daemonic scanning of new articles from all backends."
 293   (gnus-demon-add-handler 'gnus-demon-scan-news 120 60))
 294
 295 (defun gnus-demon-scan-news ()
 296   (let ((win (current-window-configuration)))
 297     (unwind-protect
 298         (save-window-excursion
 299           (save-excursion
 300             (when (gnus-alive-p)
 301               (save-excursion
 302                 (set-buffer gnus-group-buffer)
 303                 (gnus-group-get-new-news)))))
 304       (set-window-configuration win))))
 305
 306 (defun gnus-demon-add-scan-timestamps ()
 307   "Add daemonic updating of timestamps in empty newgroups."
 308   (gnus-demon-add-handler 'gnus-demon-scan-timestamps nil 30))
 309
 310 (defun gnus-demon-scan-timestamps ()
 311   "Set the timestamp on all newsgroups with no unread and no ticked articles."
 312   (when (gnus-alive-p)
 313     (let ((cur-time (current-time))
 314           (newsrc (cdr gnus-newsrc-alist))
 315           info group unread has-ticked)
 316       (while (setq info (pop newsrc))
 317         (setq group (gnus-info-group info)
 318               unread (gnus-group-unread group)
 319               has-ticked (cdr (assq 'tick (gnus-info-marks info))))
 320         (when (and (numberp unread)
 321                    (= unread 0)
 322                    (not has-ticked))
 323           (gnus-group-set-parameter group 'timestamp cur-time))))))
 324
 325 (provide 'gnus-demon)
 326
 327 ;;; arch-tag: 8dd5cd3d-6ae4-46b4-9b15-f5fca09fd392
 328 ;;; gnus-demon.el ends here