cgit.sxemacs.org Git - gnus/blob - lisp/gnus-cus.el

   1 ;;; gnus-cus.el --- customization commands for Gnus
   2 ;;
   3 ;; Copyright (C) 1996, 1999, 2000, 2001, 2002, 2003, 2004, 2005
   4 ;;        Free Software Foundation, Inc.
   5
   6 ;; Author: Per Abrahamsen <abraham@dina.kvl.dk>
   7 ;; Keywords: news
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;;; Code:
  29
  30 (require 'wid-edit)
  31 (require 'gnus)
  32 (require 'gnus-agent)
  33 (require 'gnus-score)
  34 (require 'gnus-topic)
  35 (require 'gnus-art)
  36
  37 ;;; Widgets:
  38
  39 (defun gnus-custom-mode ()
  40   "Major mode for editing Gnus customization buffers.
  41
  42 The following commands are available:
  43
  44 \\[widget-forward]              Move to next button or editable field.
  45 \\[widget-backward]             Move to previous button or editable field.
  46 \\[widget-button-click]         Activate button under the mouse pointer.
  47 \\[widget-button-press]         Activate button under point.
  48
  49 Entry to this mode calls the value of `gnus-custom-mode-hook'
  50 if that value is non-nil."
  51   (kill-all-local-variables)
  52   (setq major-mode 'gnus-custom-mode
  53         mode-name "Gnus Customize")
  54   (use-local-map widget-keymap)
  55   ;; Emacs 21 stuff:
  56   (when (and (facep 'custom-button-face)
  57              (facep 'custom-button-pressed-face))
  58     (set (make-local-variable 'widget-button-face)
  59          'custom-button-face)
  60     (set (make-local-variable 'widget-button-pressed-face)
  61          'custom-button-pressed-face)
  62     (set (make-local-variable 'widget-mouse-face)
  63          'custom-button-pressed-face))
  64   (when (and (boundp 'custom-raised-buttons)
  65              (symbol-value 'custom-raised-buttons))
  66     (set (make-local-variable 'widget-push-button-prefix) "")
  67     (set (make-local-variable 'widget-push-button-suffix) "")
  68     (set (make-local-variable 'widget-link-prefix) "")
  69     (set (make-local-variable 'widget-link-suffix) ""))
  70   (gnus-run-mode-hooks 'gnus-custom-mode-hook))
  71
  72 ;;; Group Customization:
  73
  74 (defconst gnus-group-parameters
  75   '((extra-aliases (choice
  76                     :tag "Extra Aliases"
  77                     (list
  78                      :tag "List"
  79                      (editable-list
  80                       :inline t
  81                       (gnus-email-address :tag "Address")))
  82                     (gnus-email-address :tag "Address")) "\
  83 Store messages posted from or to this address in this group.
  84
  85 You must be using gnus-group-split for this to work.  The VALUE of the
  86 nnmail-split-fancy SPLIT generated for this group will match these
  87 addresses.")
  88
  89     (split-regexp (regexp :tag "gnus-group-split Regular Expression") "\
  90 Like gnus-group-split Address, but expects a regular expression.")
  91
  92     (split-exclude (list :tag "gnus-group-split Restricts"
  93                          (editable-list
  94                           :inline t (regexp :tag "Restrict"))) "\
  95 Regular expression that cancels gnus-group-split matches.
  96
  97 Each entry is added to the nnmail-split-fancy SPLIT as a separate
  98 RESTRICT clause.")
  99
 100     (split-spec (choice :tag "gnus-group-split Overrider"
 101                         (sexp :tag "Fancy Split")
 102                         (const :tag "Catch All" catch-all)
 103                         (const :tag "Ignore" nil)) "\
 104 Override all other gnus-group-split fields.
 105
 106 In `Fancy Split', you can enter any nnmail-split-fancy SPLIT.  Note
 107 that the name of this group won't be automatically assumed, you have
 108 to add it to the SPLITs yourself.  This means you can use such splits
 109 to split messages to other groups too.
 110
 111 If you select `Catch All', this group will get postings for any
 112 messages not matched in any other group.  It overrides the variable
 113 gnus-group-split-default-catch-all-group.
 114
 115 Selecting `Ignore' forces no SPLIT to be generated for this group,
 116 disabling all other gnus-group-split fields.")
 117
 118     (broken-reply-to (const :tag "Broken Reply To" t) "\
 119 Ignore `Reply-To' headers in this group.
 120
 121 That can be useful if you're reading a mailing list group where the
 122 listserv has inserted `Reply-To' headers that point back to the
 123 listserv itself.  This is broken behavior.  So there!")
 124
 125     (to-group (string :tag "To Group") "\
 126 All posts will be sent to the specified group.")
 127
 128     (gcc-self (choice :tag  "GCC"
 129                       :value t
 130                       (const :tag "To current group" t)
 131                       (const none)
 132                       (string :format "%v" :hide-front-space t)) "\
 133 Specify default value for GCC header.
 134
 135 If this symbol is present in the group parameter list and set to t,
 136 new composed messages will be `Gcc''d to the current group.  If it is
 137 present and set to `none', no `Gcc:' header will be generated, if it
 138 is present and a string, this string will be inserted literally as a
 139 `gcc' header (this symbol takes precedence over any default `Gcc'
 140 rules as described later).")
 141
 142     (expiry-wait (choice :tag  "Expire Wait"
 143                          :value never
 144                          (const never)
 145                          (const immediate)
 146                          (number :hide-front-space t
 147                                  :format "%v")) "\
 148 When to expire.
 149
 150 Overrides any `nnmail-expiry-wait' and `nnmail-expiry-wait-function'
 151 when expiring expirable messages.  The value can either be a number of
 152 days (not necessarily an integer) or the symbols `never' or
 153 `immediate'.")
 154
 155     (expiry-target (choice :tag "Expiry Target"
 156                            :value delete
 157                            (const delete)
 158                            (function :format "%v" nnmail-)
 159                            string) "\
 160 Where expired messages end up.
 161
 162 Overrides `nnmail-expiry-target'.")
 163
 164     (score-file (file :tag "Score File") "\
 165 Make the specified file into the current score file.
 166 This means that all score commands you issue will end up in this file.")
 167
 168     (adapt-file (file :tag "Adapt File") "\
 169 Make the specified file into the current adaptive file.
 170 All adaptive score entries will be put into this file.")
 171
 172     (admin-address (gnus-email-address :tag "Admin Address") "\
 173 Administration address for a mailing list.
 174
 175 When unsubscribing to a mailing list you should never send the
 176 unsubscription notice to the mailing list itself.  Instead, you'd
 177 send messages to the administrative address.  This parameter allows
 178 you to put the admin address somewhere convenient.")
 179
 180     (display (choice :tag "Display"
 181                      :value default
 182                      (const all)
 183                      (integer)
 184                      (const default)
 185                      (sexp  :tag "Other")) "\
 186 Which articles to display on entering the group.
 187
 188 `all'
 189      Display all articles, both read and unread.
 190
 191 `integer'
 192      Display the last NUMBER articles in the group.  This is the same as
 193      entering the group with C-u NUMBER.
 194
 195 `default'
 196      Display the default visible articles, which normally includes
 197      unread and ticked articles.
 198
 199 `Other'
 200      Display the articles that satisfy the S-expression. The S-expression
 201      should be in an array form.")
 202
 203     (comment (string :tag  "Comment") "\
 204 An arbitrary comment on the group.")
 205
 206     (visible (const :tag "Permanently visible" t) "\
 207 Always display this group, even when there are no unread articles in it.")
 208
 209     (highlight-words
 210      (choice :tag "Highlight words"
 211              :value nil
 212              (repeat (list (regexp :tag "Highlight regexp")
 213                            (number :tag "Group for entire word" 0)
 214                            (number :tag "Group for displayed part" 0)
 215                            (symbol :tag "Face"
 216                                    gnus-emphasis-highlight-words))))
 217      "highlight regexps.
 218 See `gnus-emphasis-alist'.")
 219
 220     (posting-style
 221      (choice :tag "Posting style"
 222              :value nil
 223              (repeat (list
 224                       (choice :tag "Type"
 225                               :value nil
 226                               (const signature)
 227                               (const signature-file)
 228                               (const organization)
 229                               (const address)
 230                               (const name)
 231                               (const body))
 232                       (string :format "%v"))))
 233      "post style.
 234 See `gnus-posting-styles'."))
 235   "Alist of valid group or topic parameters.
 236
 237 Each entry has the form (NAME TYPE DOC), where NAME is the parameter
 238 itself (a symbol), TYPE is the parameters type (a sexp widget), and
 239 DOC is a documentation string for the parameter.")
 240
 241 (defconst gnus-extra-topic-parameters
 242   '((subscribe (regexp :tag "Subscribe") "\
 243 If `gnus-subscribe-newsgroup-method' or
 244 `gnus-subscribe-options-newsgroup-method' is set to
 245 `gnus-subscribe-topics', new groups that matches this regexp will
 246 automatically be subscribed to this topic")
 247     (subscribe-level (integer :tag "Subscribe Level" :value 1) "\
 248 If this topic parameter is set, when new groups are subscribed
 249 automatically under this topic (via the `subscribe' topic parameter)
 250 assign this level to the group, rather than the default level
 251 set in `gnus-level-default-subscribed'"))
 252   "Alist of topic parameters that are not also group parameters.
 253
 254 Each entry has the form (NAME TYPE DOC), where NAME is the parameter
 255 itself (a symbol), TYPE is the parameters type (a sexp widget), and
 256 DOC is a documentation string for the parameter.")
 257
 258 (defconst gnus-extra-group-parameters
 259   '((uidvalidity (string :tag "IMAP uidvalidity") "\
 260 Server-assigned value attached to IMAP groups, used to maintain consistency."))
 261   "Alist of group parameters that are not also topic parameters.
 262
 263 Each entry has the form (NAME TYPE DOC), where NAME is the parameter
 264 itself (a symbol), TYPE is the parameters type (a sexp widget), and
 265 DOC is a documentation string for the parameter.")
 266
 267 (eval-and-compile
 268   (defconst gnus-agent-parameters
 269     '((agent-predicate
 270        (sexp :tag "Selection Predicate" :value false)
 271        "Predicate used to automatically select articles for downloading."
 272        gnus-agent-cat-predicate)
 273       (agent-score
 274        (choice :tag "Score File" :value nil
 275                (const file :tag "Use group's score files")
 276                (repeat (list (string :format "%v" :tag "File name"))))
 277        "Which score files to use when using score to select articles to fetch.
 278
 279     `nil'
 280          All articles will be scored to zero (0).
 281
 282     `file'
 283          The group's score files will be used to score the articles.
 284
 285     `List'
 286          A list of score file names."
 287        gnus-agent-cat-score-file)
 288       (agent-short-article
 289        (integer :tag "Max Length of Short Article" :value "")
 290        "The SHORT predicate will evaluate to true when the article is
 291 shorter than this length."  gnus-agent-cat-length-when-short)
 292       (agent-long-article
 293        (integer :tag "Min Length of Long Article" :value "")
 294        "The LONG predicate will evaluate to true when the article is
 295 longer than this length."  gnus-agent-cat-length-when-long)
 296       (agent-low-score
 297        (integer :tag "Low Score Limit" :value "")
 298        "The LOW predicate will evaluate to true when the article scores
 299 lower than this limit."  gnus-agent-cat-low-score)
 300       (agent-high-score
 301        (integer :tag "High Score Limit" :value "")
 302        "The HIGH predicate will evaluate to true when the article scores
 303 higher than this limit."  gnus-agent-cat-high-score)
 304       (agent-days-until-old
 305        (integer :tag "Days Until Old" :value "")
 306        "The OLD predicate will evaluate to true when the fetched article
 307 has been stored locally for at least this many days."
 308        gnus-agent-cat-days-until-old)
 309       (agent-enable-expiration
 310        (radio :tag "Expire in this Group or Topic" :value nil
 311               (const :format "Enable " ENABLE)
 312               (const :format "Disable " DISABLE))
 313        "\nEnable, or disable, agent expiration in this group or topic."
 314        gnus-agent-cat-enable-expiration)
 315       (agent-enable-undownloaded-faces
 316        (boolean :tag "Enable Agent Faces")
 317        "Have the summary buffer use the agent's undownloaded faces.
 318 These faces, when enabled, act as a warning that an article has not
 319 been fetched into either the agent nor the cache.  This is of most use
 320 to users who use the agent as a cache (i.e. they only operate on
 321 articles that have been downloaded).  Leave disabled to display normal
 322 article faces even when the article hasn't been downloaded."
 323 gnus-agent-cat-enable-undownloaded-faces))
 324     "Alist of group parameters that are not also topic parameters.
 325
 326 Each entry has the form (NAME TYPE DOC ACCESSOR), where NAME is the
 327 parameter itself (a symbol), TYPE is the parameters type (a sexp
 328 widget), DOC is a documentation string for the parameter, and ACCESSOR
 329 is a function (symbol) that extracts the current value from the
 330 category."))
 331
 332 (defvar gnus-custom-params)
 333 (defvar gnus-custom-method)
 334 (defvar gnus-custom-group)
 335 (defvar gnus-custom-topic)
 336
 337 (defun gnus-group-customize (group &optional topic)
 338   "Edit the group or topic on the current line."
 339   (interactive (list (gnus-group-group-name) (gnus-group-topic-name)))
 340   (let (info
 341         (types (mapcar (lambda (entry)
 342                          `(cons :format "%v%h\n"
 343                                 :doc ,(nth 2 entry)
 344                                 (const :format "" ,(nth 0 entry))
 345                                 ,(nth 1 entry)))
 346                        (append (reverse gnus-group-parameters-more)
 347                                gnus-group-parameters
 348                                (if group
 349                                    gnus-extra-group-parameters
 350                                  gnus-extra-topic-parameters))))
 351         (agent (mapcar (lambda (entry)
 352                          (let ((type (nth 1 entry))
 353                                vcons)
 354                            (if (listp type)
 355                                (setq type (copy-sequence type)))
 356
 357                            (setq vcons (cdr (memq :value type)))
 358
 359                            (if (symbolp (car vcons))
 360                                (condition-case nil
 361                                    (setcar vcons (symbol-value (car vcons)))
 362                                  (error)))
 363                            `(cons :format "%v%h\n"
 364                                   :doc ,(nth 2 entry)
 365                                   (const :format "" ,(nth 0 entry))
 366                                   ,type)))
 367                        (if gnus-agent
 368                            gnus-agent-parameters))))
 369     (unless (or group topic)
 370       (error "No group on current line"))
 371     (when (and group topic)
 372       (error "Both a group an topic on current line"))
 373     (unless (or topic (setq info (gnus-get-info group)))
 374       (error "Killed group; can't be edited"))
 375     ;; Ready.
 376     (gnus-kill-buffer (gnus-get-buffer-create "*Gnus Customize*"))
 377     (switch-to-buffer (gnus-get-buffer-create "*Gnus Customize*"))
 378     (gnus-custom-mode)
 379     (make-local-variable 'gnus-custom-group)
 380     (setq gnus-custom-group group)
 381     (make-local-variable 'gnus-custom-topic)
 382     (setq gnus-custom-topic topic)
 383     (buffer-disable-undo)
 384     (widget-insert "Customize the ")
 385     (if group
 386         (widget-create 'info-link
 387                        :help-echo "Push me to learn more."
 388                        :tag "group parameters"
 389                        "(gnus)Group Parameters")
 390       (widget-create 'info-link
 391                      :help-echo "Push me to learn more."
 392                      :tag  "topic parameters"
 393                      "(gnus)Topic Parameters"))
 394     (widget-insert " for <")
 395     (widget-insert (gnus-group-decoded-name (or group topic)))
 396     (widget-insert "> and press ")
 397     (widget-create 'push-button
 398                    :tag "done"
 399                    :help-echo "Push me when done customizing."
 400                    :action 'gnus-group-customize-done)
 401     (widget-insert ".\n\n")
 402     (make-local-variable 'gnus-custom-params)
 403
 404     (let ((values (if group
 405                       (gnus-info-params info)
 406                     (gnus-topic-parameters topic))))
 407
 408       ;; The parameters in values may contain duplicates.  This is
 409       ;; normally OK as assq returns the first. However, right here
 410       ;; every duplicate ends up being displayed.  So, rather than
 411       ;; display them, remove them from the list.
 412
 413       (let ((tmp (setq values (gnus-copy-sequence values)))
 414             elem)
 415         (while (cdr tmp)
 416           (while (setq elem (assq (caar tmp) (cdr tmp)))
 417             (delq elem tmp))
 418           (setq tmp (cdr tmp))))
 419
 420       (setq gnus-custom-params
 421             (apply 'widget-create 'group
 422                    :value values
 423                    (delq nil
 424                          (list `(set :inline t
 425                                      :greedy t
 426                                      :tag "Parameters"
 427                                      :format "%t:\n%h%v"
 428                                      :doc "\
 429 These special parameters are recognized by Gnus.
 430 Check the [ ] for the parameters you want to apply to this group or
 431 to the groups in this topic, then edit the value to suit your taste."
 432                                      ,@types)
 433                                (when gnus-agent
 434                                  `(set :inline t
 435                                        :greedy t
 436                                        :tag "Agent Parameters"
 437                                        :format "%t:\n%h%v"
 438                                        :doc "\ These agent parameters are
 439 recognized by Gnus.  They control article selection and expiration for
 440 use in the unplugged cache.  Check the [ ] for the parameters you want
 441 to apply to this group or to the groups in this topic, then edit the
 442 value to suit your taste.
 443
 444 For those interested, group parameters override topic parameters while
 445 topic parameters override agent category parameters.  Underlying
 446 category parameters are the customizable variables."  ,@agent))
 447                                '(repeat :inline t
 448                                         :tag "Variables"
 449                                         :format "%t:\n%h%v%i\n\n"
 450                                         :doc "\
 451 Set variables local to the group you are entering.
 452
 453 If you want to turn threading off in `news.answers', you could put
 454 `(gnus-show-threads nil)' in the group parameters of that group.
 455 `gnus-show-threads' will be made into a local variable in the summary
 456 buffer you enter, and the form nil will be `eval'ed there.
 457
 458 This can also be used as a group-specific hook function, if you'd
 459 like.  If you want to hear a beep when you enter a group, you could
 460 put something like `(dummy-variable (ding))' in the parameters of that
 461 group.  `dummy-variable' will be set to the result of the `(ding)'
 462 form, but who cares?"
 463                                         (list :format "%v" :value (nil nil)
 464                                               (symbol :tag "Variable")
 465                                               (sexp :tag
 466                                                     "Value")))
 467
 468                                '(repeat :inline t
 469                                         :tag "Unknown entries"
 470                                         sexp))))))
 471     (when group
 472       (widget-insert "\n\nYou can also edit the ")
 473       (widget-create 'info-link
 474                      :tag "select method"
 475                      :help-echo "Push me to learn more about select methods."
 476                      "(gnus)Select Methods")
 477       (widget-insert " for the group.\n")
 478       (setq gnus-custom-method
 479             (widget-create 'sexp
 480                            :tag "Method"
 481                            :value (gnus-info-method info))))
 482     (use-local-map widget-keymap)
 483     (widget-setup)
 484     (buffer-enable-undo)
 485     (goto-char (point-min))))
 486
 487 (defun gnus-group-customize-done (&rest ignore)
 488   "Apply changes and bury the buffer."
 489   (interactive)
 490   (if gnus-custom-topic
 491       (gnus-topic-set-parameters gnus-custom-topic
 492                                  (widget-value gnus-custom-params))
 493     (gnus-group-edit-group-done 'params gnus-custom-group
 494                                 (widget-value gnus-custom-params))
 495     (gnus-group-edit-group-done 'method gnus-custom-group
 496                                 (widget-value gnus-custom-method)))
 497   (bury-buffer))
 498
 499 ;;; Score Customization:
 500
 501 (defconst gnus-score-parameters
 502   '((mark (number :tag "Mark") "\
 503 The value of this entry should be a number.
 504 Any articles with a score lower than this number will be marked as read.")
 505
 506     (expunge (number :tag "Expunge") "\
 507 The value of this entry should be a number.
 508 Any articles with a score lower than this number will be removed from
 509 the summary buffer.")
 510
 511     (mark-and-expunge (number :tag "Mark-and-expunge") "\
 512 The value of this entry should be a number.
 513 Any articles with a score lower than this number will be marked as
 514 read and removed from the summary buffer.")
 515
 516     (thread-mark-and-expunge (number :tag "Thread-mark-and-expunge") "\
 517 The value of this entry should be a number.
 518 All articles that belong to a thread that has a total score below this
 519 number will be marked as read and removed from the summary buffer.
 520 `gnus-thread-score-function' says how to compute the total score
 521 for a thread.")
 522
 523     (files (repeat :inline t :tag "Files" file) "\
 524 The value of this entry should be any number of file names.
 525 These files are assumed to be score files as well, and will be loaded
 526 the same way this one was.")
 527
 528     (exclude-files (repeat :inline t :tag "Exclude-files" file) "\
 529 The clue of this entry should be any number of files.
 530 These files will not be loaded, even though they would normally be so,
 531 for some reason or other.")
 532
 533     (eval (sexp :tag "Eval" :value nil) "\
 534 The value of this entry will be `eval'el.
 535 This element will be ignored when handling global score files.")
 536
 537     (read-only (boolean :tag "Read-only" :value t) "\
 538 Read-only score files will not be updated or saved.
 539 Global score files should feature this atom.")
 540
 541     (orphan (number :tag "Orphan") "\
 542 The value of this entry should be a number.
 543 Articles that do not have parents will get this number added to their
 544 scores.  Imagine you follow some high-volume newsgroup, like
 545 `comp.lang.c'.  Most likely you will only follow a few of the threads,
 546 also want to see any new threads.
 547
 548 You can do this with the following two score file entries:
 549
 550      (orphan -500)
 551      (mark-and-expunge -100)
 552
 553 When you enter the group the first time, you will only see the new
 554 threads.  You then raise the score of the threads that you find
 555 interesting (with `I T' or `I S'), and ignore (`C y') the rest.
 556 Next time you enter the group, you will see new articles in the
 557 interesting threads, plus any new threads.
 558
 559 I.e.---the orphan score atom is for high-volume groups where there
 560 exist a few interesting threads which can't be found automatically
 561 by ordinary scoring rules.")
 562
 563     (adapt (choice :tag "Adapt"
 564                    (const t)
 565                    (const ignore)
 566                    (sexp :format "%v"
 567                          :hide-front-space t)) "\
 568 This entry controls the adaptive scoring.
 569 If it is t, the default adaptive scoring rules will be used.  If it
 570 is `ignore', no adaptive scoring will be performed on this group.  If
 571 it is a list, this list will be used as the adaptive scoring rules.
 572 If it isn't present, or is something other than t or `ignore', the
 573 default adaptive scoring rules will be used.  If you want to use
 574 adaptive scoring on most groups, you'd set `gnus-use-adaptive-scoring'
 575 to t, and insert an `(adapt ignore)' in the groups where you do not
 576 want adaptive scoring.  If you only want adaptive scoring in a few
 577 groups, you'd set `gnus-use-adaptive-scoring' to nil, and insert
 578 `(adapt t)' in the score files of the groups where you want it.")
 579
 580     (adapt-file (file :tag "Adapt-file") "\
 581 All adaptive score entries will go to the file named by this entry.
 582 It will also be applied when entering the group.  This atom might
 583 be handy if you want to adapt on several groups at once, using the
 584 same adaptive file for a number of groups.")
 585
 586     (local (repeat :tag "Local"
 587                    (group :value (nil nil)
 588                           (symbol :tag "Variable")
 589                           (sexp :tag "Value"))) "\
 590 The value of this entry should be a list of `(VAR VALUE)' pairs.
 591 Each VAR will be made buffer-local to the current summary buffer,
 592 and set to the value specified.  This is a convenient, if somewhat
 593 strange, way of setting variables in some groups if you don't like
 594 hooks much.")
 595     (touched (sexp :format "Touched\n") "Internal variable."))
 596   "Alist of valid symbolic score parameters.
 597
 598 Each entry has the form (NAME TYPE DOC), where NAME is the parameter
 599 itself (a symbol), TYPE is the parameters type (a sexp widget), and DOC is a
 600 documentation string for the parameter.")
 601
 602 (define-widget 'gnus-score-string 'group
 603   "Edit score entries for string-valued headers."
 604   :convert-widget 'gnus-score-string-convert)
 605
 606 (defun gnus-score-string-convert (widget)
 607   ;; Set args appropriately.
 608   (let* ((tag (widget-get widget :tag))
 609          (item `(const :format "" :value ,(downcase tag)))
 610          (match '(string :tag "Match"))
 611          (score '(choice :tag "Score"
 612                          (const :tag "default" nil)
 613                          (integer :format "%v"
 614                                   :hide-front-space t)))
 615          (expire '(choice :tag "Expire"
 616                           (const :tag "off" nil)
 617                           (integer :format "%v"
 618                                    :hide-front-space t)))
 619          (type '(choice :tag "Type"
 620                         :value s
 621                         ;; I should really create a forgiving :match
 622                         ;; function for each type below, that only
 623                         ;; looked at the first letter.
 624                         (const :tag "Regexp" r)
 625                         (const :tag "Regexp (fixed case)" R)
 626                         (const :tag "Substring" s)
 627                         (const :tag "Substring (fixed case)" S)
 628                         (const :tag "Exact" e)
 629                         (const :tag "Exact (fixed case)" E)
 630                         (const :tag "Word" w)
 631                         (const :tag "Word (fixed case)" W)
 632                         (const :tag "default" nil)))
 633          (group `(group ,match ,score ,expire ,type))
 634          (doc (concat (or (widget-get widget :doc)
 635                           (concat "Change score based on the " tag
 636                                   " header.\n"))
 637                       "
 638 You can have an arbitrary number of score entries for this header,
 639 each score entry has four elements:
 640
 641 1. The \"match element\".  This should be the string to look for in the
 642    header.
 643
 644 2. The \"score element\".  This number should be an integer in the
 645    neginf to posinf interval.  This number is added to the score
 646    of the article if the match is successful.  If this element is
 647    not present, the `gnus-score-interactive-default-score' number
 648    will be used instead.  This is 1000 by default.
 649
 650 3. The \"date element\".  This date says when the last time this score
 651    entry matched, which provides a mechanism for expiring the
 652    score entries.  It this element is not present, the score
 653    entry is permanent.  The date is represented by the number of
 654    days since December 31, 1 ce.
 655
 656 4. The \"type element\".  This element specifies what function should
 657    be used to see whether this score entry matches the article.
 658
 659    There are the regexp, as well as substring types, and exact match,
 660    and word match types.  If this element is not present, Gnus will
 661    assume that substring matching should be used.  There is case
 662    sensitive variants of all match types.")))
 663     (widget-put widget :args `(,item
 664                                (repeat :inline t
 665                                        :indent 0
 666                                        :tag ,tag
 667                                        :doc ,doc
 668                                        :format "%t:\n%h%v%i\n\n"
 669                                        (choice :format "%v"
 670                                                :value ("" nil nil s)
 671                                                ,group
 672                                                sexp)))))
 673   widget)
 674
 675 (define-widget 'gnus-score-integer 'group
 676   "Edit score entries for integer-valued headers."
 677   :convert-widget 'gnus-score-integer-convert)
 678
 679 (defun gnus-score-integer-convert (widget)
 680   ;; Set args appropriately.
 681   (let* ((tag (widget-get widget :tag))
 682          (item `(const :format "" :value ,(downcase tag)))
 683          (match '(integer :tag "Match"))
 684          (score '(choice :tag "Score"
 685                          (const :tag "default" nil)
 686                          (integer :format "%v"
 687                                   :hide-front-space t)))
 688          (expire '(choice :tag "Expire"
 689                           (const :tag "off" nil)
 690                           (integer :format "%v"
 691                                    :hide-front-space t)))
 692          (type '(choice :tag "Type"
 693                         :value <
 694                         (const <)
 695                         (const >)
 696                         (const =)
 697                         (const >=)
 698                         (const <=)))
 699          (group `(group ,match ,score ,expire ,type))
 700          (doc (concat (or (widget-get widget :doc)
 701                           (concat "Change score based on the " tag
 702                                   " header.")))))
 703     (widget-put widget :args `(,item
 704                                (repeat :inline t
 705                                        :indent 0
 706                                        :tag ,tag
 707                                        :doc ,doc
 708                                        :format "%t:\n%h%v%i\n\n"
 709                                        ,group))))
 710   widget)
 711
 712 (define-widget 'gnus-score-date 'group
 713   "Edit score entries for date-valued headers."
 714   :convert-widget 'gnus-score-date-convert)
 715
 716 (defun gnus-score-date-convert (widget)
 717   ;; Set args appropriately.
 718   (let* ((tag (widget-get widget :tag))
 719          (item `(const :format "" :value ,(downcase tag)))
 720          (match '(string :tag "Match"))
 721          (score '(choice :tag "Score"
 722                          (const :tag "default" nil)
 723                          (integer :format "%v"
 724                                   :hide-front-space t)))
 725          (expire '(choice :tag "Expire"
 726                           (const :tag "off" nil)
 727                           (integer :format "%v"
 728                                    :hide-front-space t)))
 729          (type '(choice :tag "Type"
 730                         :value regexp
 731                         (const regexp)
 732                         (const before)
 733                         (const at)
 734                         (const after)))
 735          (group `(group ,match ,score ,expire ,type))
 736          (doc (concat (or (widget-get widget :doc)
 737                           (concat "Change score based on the " tag
 738                                   " header."))
 739                       "
 740 For the Date header we have three kinda silly match types: `before',
 741 `at' and `after'.  I can't really imagine this ever being useful, but,
 742 like, it would feel kinda silly not to provide this function.  Just in
 743 case.  You never know.  Better safe than sorry.  Once burnt, twice
 744 shy.  Don't judge a book by its cover.  Never not have sex on a first
 745 date.  (I have been told that at least one person, and I quote,
 746 \"found this function indispensable\", however.)
 747
 748 A more useful match type is `regexp'.  With it, you can match the date
 749 string using a regular expression.  The date is normalized to ISO8601
 750 compact format first---`YYYYMMDDTHHMMSS'.  If you want to match all
 751 articles that have been posted on April 1st in every year, you could
 752 use `....0401.........' as a match string, for instance.  (Note that
 753 the date is kept in its original time zone, so this will match
 754 articles that were posted when it was April 1st where the article was
 755 posted from.  Time zones are such wholesome fun for the whole family,
 756 eh?")))
 757     (widget-put widget :args `(,item
 758                                (repeat :inline t
 759                                        :indent 0
 760                                        :tag ,tag
 761                                        :doc ,doc
 762                                        :format "%t:\n%h%v%i\n\n"
 763                                        ,group))))
 764   widget)
 765
 766 (defvar gnus-custom-scores)
 767 (defvar gnus-custom-score-alist)
 768
 769 (defun gnus-score-customize (file)
 770   "Customize score file FILE.
 771 When called interactively, FILE defaults to the current score file.
 772 This can be changed using the `\\[gnus-score-change-score-file]' command."
 773   (interactive (list gnus-current-score-file))
 774   (unless file
 775     (error "No score file for %s"
 776            (gnus-group-decoded-name gnus-newsgroup-name)))
 777   (let ((scores (gnus-score-load file))
 778         (types (mapcar (lambda (entry)
 779                          `(group :format "%v%h\n"
 780                                  :doc ,(nth 2 entry)
 781                                  (const :format "" ,(nth 0 entry))
 782                                  ,(nth 1 entry)))
 783                        gnus-score-parameters)))
 784     ;; Ready.
 785     (kill-buffer (gnus-get-buffer-create "*Gnus Customize*"))
 786     (switch-to-buffer (gnus-get-buffer-create "*Gnus Customize*"))
 787     (gnus-custom-mode)
 788     (make-local-variable 'gnus-custom-score-alist)
 789     (setq gnus-custom-score-alist scores)
 790     (widget-insert "Customize the ")
 791     (widget-create 'info-link
 792                    :help-echo "Push me to learn more."
 793                    :tag "score entries"
 794                    "(gnus)Score File Format")
 795     (widget-insert " for\n\t")
 796     (widget-insert file)
 797     (widget-insert "\nand press ")
 798     (widget-create 'push-button
 799                    :tag "done"
 800                    :help-echo "Push me when done customizing."
 801                    :action 'gnus-score-customize-done)
 802     (widget-insert ".\n
 803 Check the [ ] for the entries you want to apply to this score file, then
 804 edit the value to suit your taste.  Don't forget to mark the checkbox,
 805 if you do all your changes will be lost.  ")
 806     (widget-create 'push-button
 807                    :action (lambda (&rest ignore)
 808                              (require 'gnus-audio)
 809                              (gnus-audio-play "Evil_Laugh.au"))
 810                    "Bhahahah!")
 811     (widget-insert "\n\n")
 812     (make-local-variable 'gnus-custom-scores)
 813     (setq gnus-custom-scores
 814           (widget-create 'group
 815                          :value scores
 816                          `(checklist :inline t
 817                                      :greedy t
 818                                      (gnus-score-string :tag "From")
 819                                      (gnus-score-string :tag "Subject")
 820                                      (gnus-score-string :tag "References")
 821                                      (gnus-score-string :tag "Xref")
 822                                      (gnus-score-string :tag "Extra")
 823                                      (gnus-score-string :tag "Message-ID")
 824                                      (gnus-score-integer :tag "Lines")
 825                                      (gnus-score-integer :tag "Chars")
 826                                      (gnus-score-date :tag "Date")
 827                                      (gnus-score-string :tag "Head"
 828                                                         :doc "\
 829 Match all headers in the article.
 830
 831 Using one of `Head', `Body', `All' will slow down scoring considerable.
 832 ")
 833                                      (gnus-score-string :tag "Body"
 834                                                         :doc "\
 835 Match the body sans header of the article.
 836
 837 Using one of `Head', `Body', `All' will slow down scoring considerable.
 838 ")
 839                                      (gnus-score-string :tag "All"
 840                                                         :doc "\
 841 Match the entire article, including both headers and body.
 842
 843 Using one of `Head', `Body', `All' will slow down scoring
 844 considerable.
 845 ")
 846                                      (gnus-score-string :tag
 847                                                         "Followup"
 848                                                         :doc "\
 849 Score all followups to the specified authors.
 850
 851 This entry is somewhat special, in that it will match the `From:'
 852 header, and affect the score of not only the matching articles, but
 853 also all followups to the matching articles.  This allows you
 854 e.g. increase the score of followups to your own articles, or decrease
 855 the score of followups to the articles of some known trouble-maker.
 856 ")
 857                                      (gnus-score-string :tag "Thread"
 858                                                         :doc "\
 859 Add a score entry on all articles that are part of a thread.
 860
 861 This match key works along the same lines as the `Followup' match key.
 862 If you say that you want to score on a (sub-)thread that is started by
 863 an article with a `Message-ID' X, then you add a `thread' match.  This
 864 will add a new `thread' match for each article that has X in its
 865 `References' header.  (These new `thread' matches will use the
 866 `Message-ID's of these matching articles.)  This will ensure that you
 867 can raise/lower the score of an entire thread, even though some
 868 articles in the thread may not have complete `References' headers.
 869 Note that using this may lead to undeterministic scores of the
 870 articles in the thread.
 871 ")
 872                                      ,@types)
 873                          '(repeat :inline t
 874                                   :tag "Unknown entries"
 875                                   sexp)))
 876     (use-local-map widget-keymap)
 877     (widget-setup)))
 878
 879 (defun gnus-score-customize-done (&rest ignore)
 880   "Reset the score alist with the present value."
 881   (let ((alist gnus-custom-score-alist)
 882         (value (widget-value gnus-custom-scores)))
 883     (setcar alist (car value))
 884     (setcdr alist (cdr value))
 885     (gnus-score-set 'touched '(t) alist))
 886   (bury-buffer))
 887
 888 (eval-when-compile
 889   (defvar category-fields nil)
 890   (defvar gnus-agent-cat-name)
 891   (defvar gnus-agent-cat-score-file)
 892   (defvar gnus-agent-cat-length-when-short)
 893   (defvar gnus-agent-cat-length-when-long)
 894   (defvar gnus-agent-cat-low-score)
 895   (defvar gnus-agent-cat-high-score)
 896   (defvar gnus-agent-cat-enable-expiration)
 897   (defvar gnus-agent-cat-days-until-old)
 898   (defvar gnus-agent-cat-predicate)
 899   (defvar gnus-agent-cat-groups)
 900   (defvar gnus-agent-cat-enable-undownloaded-faces)
 901 )
 902
 903 (defun gnus-trim-whitespace (s)
 904   (when (string-match "\\`[ \n\t]+" s)
 905     (setq s (substring s (match-end 0))))
 906   (when (string-match "[ \n\t]+\\'" s)
 907     (setq s (substring s 0 (match-beginning 0))))
 908   s)
 909
 910 (defmacro gnus-agent-cat-prepare-category-field (parameter)
 911   (let* ((entry (assq parameter gnus-agent-parameters))
 912          (field (nth 3 entry)))
 913     `(let* ((type (copy-sequence
 914                    (nth 1 (assq ',parameter gnus-agent-parameters))))
 915             (val (,field info))
 916             (deflt (if (,field defaults)
 917                        (concat " [" (gnus-trim-whitespace
 918                                      (gnus-pp-to-string (,field defaults)))
 919                                "]")))
 920             symb)
 921
 922        (if (eq (car type) 'radio)
 923            (let* ((rtype (nreverse type))
 924                   (rt rtype))
 925              (while (listp (or (cadr rt) 'not-list))
 926                (setq rt (cdr rt)))
 927
 928              (setcdr rt (cons '(const :format "Inherit " nil) (cdr rt)))
 929              (setq type (nreverse rtype))))
 930
 931        (if deflt
 932            (let ((tag (cdr (memq :tag type))))
 933              (when (string-match "\n" deflt)
 934                (while (progn (setq deflt (replace-match "\n " t t
 935                                                         deflt))
 936                              (string-match "\n" deflt (match-end 0))))
 937                (setq deflt (concat "\n" deflt)))
 938
 939              (setcar tag (concat (car tag) deflt))))
 940
 941        (widget-insert "\n")
 942
 943        (setq val (if val
 944                      (widget-create type :value val)
 945                    (widget-create type))
 946              symb (set (make-local-variable ',field) val))
 947
 948        (widget-put symb :default val)
 949        (widget-put symb :accessor ',field)
 950        (push symb category-fields))))
 951
 952 (defun gnus-agent-customize-category (category)
 953   "Edit the CATEGORY."
 954   (interactive (list (gnus-category-name)))
 955   (let ((info (assq category gnus-category-alist))
 956         (defaults (list nil '(agent-predicate . false)
 957                         (cons 'agent-enable-expiration
 958                               gnus-agent-enable-expiration)
 959                         '(agent-days-until-old . 7)
 960                         (cons 'agent-length-when-short
 961                               gnus-agent-short-article)
 962                         (cons 'agent-length-when-long gnus-agent-long-article)
 963                         (cons 'agent-low-score gnus-agent-low-score)
 964                         (cons 'agent-high-score gnus-agent-high-score))))
 965
 966     (let ((old (get-buffer "*Gnus Agent Category Customize*")))
 967       (when old
 968         (gnus-kill-buffer old)))
 969     (switch-to-buffer (gnus-get-buffer-create
 970                        "*Gnus Agent Category Customize*"))
 971
 972     (let ((inhibit-read-only t))
 973       (gnus-custom-mode)
 974       (buffer-disable-undo)
 975
 976       (let* ((name (gnus-agent-cat-name info)))
 977         (widget-insert "Customize the Agent Category '")
 978         (widget-insert (symbol-name name))
 979         (widget-insert "' and press ")
 980         (widget-create
 981          'push-button
 982          :notify
 983          '(lambda (&rest ignore)
 984             (let* ((info (assq gnus-agent-cat-name gnus-category-alist))
 985                    (widgets category-fields))
 986               (while widgets
 987                 (let* ((widget (pop widgets))
 988                        (value (condition-case nil (widget-value widget) (error))))
 989                   (eval `(setf (,(widget-get widget :accessor) ',info)
 990                                ',value)))))
 991             (gnus-category-write)
 992             (gnus-kill-buffer (current-buffer))
 993             (when (get-buffer gnus-category-buffer)
 994               (switch-to-buffer (get-buffer gnus-category-buffer))
 995               (gnus-category-list)))
 996                        "Done")
 997         (widget-insert
 998          "\n    Note: Empty fields default to the customizable global\
 999  variables.\n\n")
1000
1001         (set (make-local-variable 'gnus-agent-cat-name)
1002              name))
1003
1004       (set (make-local-variable 'category-fields) nil)
1005       (gnus-agent-cat-prepare-category-field agent-predicate)
1006
1007       (gnus-agent-cat-prepare-category-field agent-score)
1008       (gnus-agent-cat-prepare-category-field agent-short-article)
1009       (gnus-agent-cat-prepare-category-field agent-long-article)
1010       (gnus-agent-cat-prepare-category-field agent-low-score)
1011       (gnus-agent-cat-prepare-category-field agent-high-score)
1012
1013       ;; The group list is NOT handled with
1014       ;; gnus-agent-cat-prepare-category-field as I don't want the
1015       ;; group list to appear when customizing a topic.
1016       (widget-insert "\n")
1017
1018       (let ((symb
1019              (set
1020               (make-local-variable 'gnus-agent-cat-groups)
1021               (widget-create
1022                `(choice
1023                  :format "%[Select Member Groups%]\n%v" :value ignore
1024                  (const :menu-tag "do not change" :tag "" :value ignore)
1025                  (checklist :entry-format "%b %v"
1026                             :menu-tag "display group selectors"
1027                             :greedy t
1028                             :value
1029                             ,(delq nil
1030                                    (mapcar
1031                                     (lambda (newsrc)
1032                                       (car (member
1033                                             (gnus-info-group newsrc)
1034                                             (gnus-agent-cat-groups info))))
1035                                     (cdr gnus-newsrc-alist)))
1036                             ,@(mapcar (lambda (newsrc)
1037                                         `(const ,(gnus-info-group newsrc)))
1038                                       (cdr gnus-newsrc-alist))))))))
1039
1040       (widget-put symb :default (gnus-agent-cat-groups info))
1041       (widget-put symb :accessor 'gnus-agent-cat-groups)
1042       (push symb category-fields))
1043
1044       (widget-insert "\nExpiration Settings ")
1045
1046       (gnus-agent-cat-prepare-category-field agent-enable-expiration)
1047       (gnus-agent-cat-prepare-category-field agent-days-until-old)
1048
1049       (widget-insert "\nVisual Settings ")
1050
1051       (gnus-agent-cat-prepare-category-field agent-enable-undownloaded-faces)
1052
1053       (use-local-map widget-keymap)
1054       (widget-setup)
1055       (buffer-enable-undo))))
1056
1057 ;;; The End:
1058
1059 (provide 'gnus-cus)
1060
1061 ;;; arch-tag: a37c285a-49bc-4235-8244-804536effeaf
1062 ;;; gnus-cus.el ends here