cgit.sxemacs.org Git - gnus/blob - lisp/gnus-cache.el

   1 ;;; gnus-cache.el --- cache interface for Gnus
   2
   3 ;; Copyright (C) 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003,
   4 ;;   2004, 2005, 2006, 2007 Free Software Foundation, Inc.
   5
   6 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   7 ;; Keywords: news
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 3, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  24 ;; Boston, MA 02110-1301, USA.
  25
  26 ;;; Commentary:
  27
  28 ;;; Code:
  29
  30 (eval-when-compile (require 'cl))
  31
  32 (require 'gnus)
  33 (eval-when-compile
  34   (unless (fboundp 'gnus-agent-load-alist)
  35       (defun gnus-agent-load-alist (group)))
  36   (require 'gnus-sum))
  37
  38 (defcustom gnus-cache-active-file
  39   (expand-file-name "active" gnus-cache-directory)
  40   "*The cache active file."
  41   :group 'gnus-cache
  42   :type 'file)
  43
  44 (defcustom gnus-cache-enter-articles '(ticked dormant)
  45   "Classes of articles to enter into the cache."
  46   :group 'gnus-cache
  47   :type '(set (const ticked) (const dormant) (const unread) (const read)))
  48
  49 (defcustom gnus-cache-remove-articles '(read)
  50   "Classes of articles to remove from the cache."
  51   :group 'gnus-cache
  52   :type '(set (const ticked) (const dormant) (const unread) (const read)))
  53
  54 (defcustom gnus-cacheable-groups nil
  55   "*Groups that match this regexp will be cached.
  56
  57 If you only want to cache your nntp groups, you could set this
  58 variable to \"^nntp\".
  59
  60 If a group matches both gnus-cacheable-groups and gnus-uncacheable-groups
  61 it's not cached."
  62   :group 'gnus-cache
  63   :type '(choice (const :tag "off" nil)
  64                  regexp))
  65
  66 (defcustom gnus-uncacheable-groups nil
  67   "*Groups that match this regexp will not be cached.
  68
  69 If you want to avoid caching your nnml groups, you could set this
  70 variable to \"^nnml\".
  71
  72 If a group matches both gnus-cacheable-groups and gnus-uncacheable-groups
  73 it's not cached."
  74   :group 'gnus-cache
  75   :type '(choice (const :tag "off" nil)
  76                  regexp))
  77
  78 (defvar gnus-cache-overview-coding-system 'raw-text
  79   "Coding system used on Gnus cache files.")
  80
  81 (defvar gnus-cache-coding-system 'raw-text
  82   "Coding system used on Gnus cache files.")
  83
  84 \f
  85
  86 ;;; Internal variables.
  87
  88 (defvar gnus-cache-removable-articles nil)
  89 (defvar gnus-cache-buffer nil)
  90 (defvar gnus-cache-active-hashtb nil)
  91 (defvar gnus-cache-active-altered nil)
  92 (defvar gnus-cache-total-fetched-hashtb nil)
  93
  94 (eval-and-compile
  95   (autoload 'nnml-generate-nov-databases-directory "nnml")
  96   (autoload 'nnvirtual-find-group-art "nnvirtual"))
  97
  98 \f
  99
 100 ;;; Functions called from Gnus.
 101
 102 (defun gnus-cache-open ()
 103   "Initialize the cache."
 104   (when (or (file-exists-p gnus-cache-directory)
 105             (and gnus-use-cache
 106                  (not (eq gnus-use-cache 'passive))))
 107     (gnus-cache-read-active)))
 108
 109 ;; Complexities of byte-compiling make this kludge necessary.  Eeek.
 110 (ignore-errors
 111   (gnus-add-shutdown 'gnus-cache-close 'gnus))
 112
 113 (defun gnus-cache-close ()
 114   "Shut down the cache."
 115   (gnus-cache-write-active)
 116   (gnus-cache-save-buffers)
 117   (setq gnus-cache-active-hashtb nil))
 118
 119 (defun gnus-cache-save-buffers ()
 120   ;; save the overview buffer if it exists and has been modified
 121   ;; delete empty cache subdirectories
 122   (when gnus-cache-buffer
 123     (let ((buffer (cdr gnus-cache-buffer))
 124           (overview-file (gnus-cache-file-name
 125                           (car gnus-cache-buffer) ".overview")))
 126       ;; write the overview only if it was modified
 127       (when (and (buffer-live-p buffer) (buffer-modified-p buffer))
 128         (with-current-buffer buffer
 129           (if (> (buffer-size) 0)
 130               ;; Non-empty overview, write it to a file.
 131               (let ((coding-system-for-write
 132                      gnus-cache-overview-coding-system))
 133                 (gnus-write-buffer overview-file))
 134             (let ((file-name-coding-system nnmail-pathname-coding-system))
 135               ;; Empty overview file, remove it
 136               (when (file-exists-p overview-file)
 137                 (delete-file overview-file))
 138               ;; If possible, remove group's cache subdirectory.
 139               (condition-case nil
 140                   ;; FIXME: we can detect the error type and warn the user
 141                   ;; of any inconsistencies (articles w/o nov entries?).
 142                   ;; for now, just be conservative...delete only if safe -- sj
 143                   (delete-directory (file-name-directory overview-file))
 144                 (error))))
 145
 146           (gnus-cache-update-overview-total-fetched-for
 147            (car gnus-cache-buffer) overview-file)))
 148       ;; Kill the buffer -- it's either unmodified or saved.
 149       (gnus-kill-buffer buffer)
 150       (setq gnus-cache-buffer nil))))
 151
 152 (defun gnus-cache-possibly-enter-article
 153   (group article ticked dormant unread &optional force)
 154   (when (and (or force (not (eq gnus-use-cache 'passive)))
 155              (numberp article)
 156              (> article 0))             ; This might be a dummy article.
 157     (let ((number article)
 158           file headers lines-chars
 159           (file-name-coding-system nnmail-pathname-coding-system))
 160       ;; If this is a virtual group, we find the real group.
 161       (when (gnus-virtual-group-p group)
 162         (let ((result (nnvirtual-find-group-art
 163                        (gnus-group-real-name group) article)))
 164           (setq group (car result)
 165                 number (cdr result))))
 166       (when (and number
 167                  (> number 0)           ; Reffed article.
 168                  (or force
 169                      (and (gnus-cache-fully-p group)
 170                           (gnus-cache-member-of-class
 171                            gnus-cache-enter-articles ticked dormant unread)))
 172                  (not (file-exists-p (setq file (gnus-cache-file-name
 173                                                  group number)))))
 174         ;; Possibly create the cache directory.
 175         (gnus-make-directory (file-name-directory file))
 176         ;; Save the article in the cache.
 177         (if (file-exists-p file)
 178             t                           ; The article already is saved.
 179           (save-excursion
 180             (set-buffer nntp-server-buffer)
 181             (require 'gnus-art)
 182             (let ((gnus-use-cache nil)
 183                   (gnus-article-decode-hook nil))
 184               (gnus-request-article-this-buffer number group))
 185             (when (> (buffer-size) 0)
 186               (let ((coding-system-for-write gnus-cache-coding-system))
 187                 (gnus-write-buffer file)
 188                 (gnus-cache-update-file-total-fetched-for group file))
 189               (setq lines-chars (nnheader-get-lines-and-char))
 190               (nnheader-remove-body)
 191               (setq headers (nnheader-parse-naked-head))
 192               (mail-header-set-number headers number)
 193               (mail-header-set-lines headers (car lines-chars))
 194               (mail-header-set-chars headers (cadr lines-chars))
 195               (gnus-cache-change-buffer group)
 196               (set-buffer (cdr gnus-cache-buffer))
 197               (goto-char (point-max))
 198               (forward-line -1)
 199               (while (condition-case ()
 200                          (when (not (bobp))
 201                            (> (read (current-buffer)) number))
 202                        (error
 203                         ;; The line was malformed, so we just remove it!!
 204                         (gnus-delete-line)
 205                         t))
 206                 (forward-line -1))
 207               (if (bobp)
 208                   (if (not (eobp))
 209                       (progn
 210                         (beginning-of-line)
 211                         (when (< (read (current-buffer)) number)
 212                           (forward-line 1)))
 213                     (beginning-of-line))
 214                 (forward-line 1))
 215               (beginning-of-line)
 216               (nnheader-insert-nov headers)
 217               ;; Update the active info.
 218               (set-buffer gnus-summary-buffer)
 219               (gnus-cache-possibly-update-active group (cons number number))
 220               (setq gnus-newsgroup-cached
 221                     (gnus-add-to-sorted-list gnus-newsgroup-cached article))
 222               (gnus-summary-update-secondary-mark article))
 223             t))))))
 224
 225 (defun gnus-cache-enter-remove-article (article)
 226   "Mark ARTICLE for later possible removal."
 227   (when article
 228     (push article gnus-cache-removable-articles)))
 229
 230 (defun gnus-cache-possibly-remove-articles ()
 231   "Possibly remove some of the removable articles."
 232   (if (not (gnus-virtual-group-p gnus-newsgroup-name))
 233       (gnus-cache-possibly-remove-articles-1)
 234     (let ((arts gnus-cache-removable-articles)
 235           ga)
 236       (while arts
 237         (when (setq ga (nnvirtual-find-group-art
 238                         (gnus-group-real-name gnus-newsgroup-name) (pop arts)))
 239           (let ((gnus-cache-removable-articles (list (cdr ga)))
 240                 (gnus-newsgroup-name (car ga)))
 241             (gnus-cache-possibly-remove-articles-1)))))
 242     (setq gnus-cache-removable-articles nil)))
 243
 244 (defun gnus-cache-possibly-remove-articles-1 ()
 245   "Possibly remove some of the removable articles."
 246   (when (gnus-cache-fully-p gnus-newsgroup-name)
 247     (let ((cache-articles gnus-newsgroup-cached))
 248       (gnus-cache-change-buffer gnus-newsgroup-name)
 249       (dolist (article gnus-cache-removable-articles)
 250         (when (memq article cache-articles)
 251           ;; The article was in the cache, so we see whether we are
 252           ;; supposed to remove it from the cache.
 253           (gnus-cache-possibly-remove-article
 254            article (memq article gnus-newsgroup-marked)
 255            (memq article gnus-newsgroup-dormant)
 256            (or (memq article gnus-newsgroup-unreads)
 257                (memq article gnus-newsgroup-unselected))))))
 258     ;; The overview file might have been modified, save it
 259     ;; safe because we're only called at group exit anyway.
 260     (gnus-cache-save-buffers)))
 261
 262 (defun gnus-cache-request-article (article group)
 263   "Retrieve ARTICLE in GROUP from the cache."
 264   (let ((file (gnus-cache-file-name group article))
 265         (buffer-read-only nil)
 266         (file-name-coding-system nnmail-pathname-coding-system))
 267     (when (file-exists-p file)
 268       (erase-buffer)
 269       (gnus-kill-all-overlays)
 270       (let ((coding-system-for-read gnus-cache-coding-system))
 271         (insert-file-contents file))
 272       t)))
 273
 274 (defun gnus-cache-possibly-alter-active (group active)
 275   "Alter the ACTIVE info for GROUP to reflect the articles in the cache."
 276   (when gnus-cache-active-hashtb
 277     (let ((cache-active (gnus-gethash group gnus-cache-active-hashtb)))
 278       (when cache-active
 279         (when (< (car cache-active) (car active))
 280           (setcar active (car cache-active)))
 281         (when (> (cdr cache-active) (cdr active))
 282           (setcdr active (cdr cache-active)))))))
 283
 284 (defun gnus-cache-retrieve-headers (articles group &optional fetch-old)
 285   "Retrieve the headers for ARTICLES in GROUP."
 286   (let ((cached
 287          (setq gnus-newsgroup-cached (gnus-cache-articles-in-group group))))
 288     (if (not cached)
 289         ;; No cached articles here, so we just retrieve them
 290         ;; the normal way.
 291         (let ((gnus-use-cache nil))
 292           (gnus-retrieve-headers articles group fetch-old))
 293       (let ((uncached-articles (gnus-sorted-difference articles cached))
 294             (cache-file (gnus-cache-file-name group ".overview"))
 295             type
 296             (file-name-coding-system nnmail-pathname-coding-system))
 297         ;; We first retrieve all the headers that we don't have in
 298         ;; the cache.
 299         (let ((gnus-use-cache nil))
 300           (when uncached-articles
 301             (setq type (and articles
 302                             (gnus-retrieve-headers
 303                              uncached-articles group fetch-old)))))
 304         (gnus-cache-save-buffers)
 305         ;; Then we insert the cached headers.
 306         (save-excursion
 307           (cond
 308            ((not (file-exists-p cache-file))
 309             ;; There are no cached headers.
 310             type)
 311            ((null type)
 312             ;; There were no uncached headers (or retrieval was
 313             ;; unsuccessful), so we use the cached headers exclusively.
 314             (set-buffer nntp-server-buffer)
 315             (erase-buffer)
 316             (let ((coding-system-for-read
 317                    gnus-cache-overview-coding-system))
 318               (insert-file-contents cache-file))
 319             'nov)
 320            ((eq type 'nov)
 321             ;; We have both cached and uncached NOV headers, so we
 322             ;; braid them.
 323             (gnus-cache-braid-nov group cached)
 324             type)
 325            (t
 326             ;; We braid HEADs.
 327             (gnus-cache-braid-heads group (gnus-sorted-intersection
 328                                            cached articles))
 329             type)))))))
 330
 331 (defun gnus-cache-enter-article (&optional n)
 332   "Enter the next N articles into the cache.
 333 If not given a prefix, use the process marked articles instead.
 334 Returns the list of articles entered."
 335   (interactive "P")
 336   (let (out)
 337     (dolist (article (gnus-summary-work-articles n))
 338       (gnus-summary-remove-process-mark article)
 339       (if (natnump article)
 340           (when (gnus-cache-possibly-enter-article
 341                  gnus-newsgroup-name article
 342                  nil nil nil t)
 343             (setq gnus-newsgroup-undownloaded (delq article gnus-newsgroup-undownloaded))
 344             (push article out))
 345         (gnus-message 2 "Can't cache article %d" article))
 346       (gnus-summary-update-download-mark article)
 347       (gnus-summary-update-secondary-mark article))
 348     (gnus-summary-next-subject 1)
 349     (gnus-summary-position-point)
 350     (nreverse out)))
 351
 352 (defun gnus-cache-remove-article (&optional n)
 353   "Remove the next N articles from the cache.
 354 If not given a prefix, use the process marked articles instead.
 355 Returns the list of articles removed."
 356   (interactive "P")
 357   (gnus-cache-change-buffer gnus-newsgroup-name)
 358   (let (out)
 359     (dolist (article (gnus-summary-work-articles n))
 360       (gnus-summary-remove-process-mark article)
 361       (when (gnus-cache-possibly-remove-article article nil nil nil t)
 362         (when gnus-newsgroup-agentized
 363           (let ((alist (gnus-agent-load-alist gnus-newsgroup-name)))
 364             (unless (cdr (assoc article alist))
 365               (setq gnus-newsgroup-undownloaded
 366                     (gnus-add-to-sorted-list
 367                      gnus-newsgroup-undownloaded article)))))
 368         (push article out))
 369       (gnus-summary-update-download-mark article)
 370       (gnus-summary-update-secondary-mark article))
 371     (gnus-summary-next-subject 1)
 372     (gnus-summary-position-point)
 373     (nreverse out)))
 374
 375 (defun gnus-cached-article-p (article)
 376   "Say whether ARTICLE is cached in the current group."
 377   (memq article gnus-newsgroup-cached))
 378
 379 (defun gnus-summary-insert-cached-articles ()
 380   "Insert all the articles cached for this group into the current buffer."
 381   (interactive)
 382   (let ((gnus-verbose (max 6 gnus-verbose)))
 383     (if (not gnus-newsgroup-cached)
 384         (gnus-message 3 "No cached articles for this group")
 385       (gnus-summary-goto-subjects gnus-newsgroup-cached))))
 386
 387 (defun gnus-summary-limit-include-cached ()
 388   "Limit the summary buffer to articles that are cached."
 389   (interactive)
 390   (let ((gnus-verbose (max 6 gnus-verbose)))
 391     (if gnus-newsgroup-cached
 392         (progn
 393           (gnus-summary-limit gnus-newsgroup-cached)
 394           (gnus-summary-position-point))
 395       (gnus-message 3 "No cached articles for this group"))))
 396
 397 ;;; Internal functions.
 398
 399 (defun gnus-cache-change-buffer (group)
 400   (and gnus-cache-buffer
 401        ;; See if the current group's overview cache has been loaded.
 402        (or (string= group (car gnus-cache-buffer))
 403            ;; Another overview cache is current, save it.
 404            (gnus-cache-save-buffers)))
 405   ;; if gnus-cache buffer is nil, create it
 406   (unless gnus-cache-buffer
 407     ;; Create cache buffer
 408     (save-excursion
 409       (setq gnus-cache-buffer
 410             (cons group
 411                   (set-buffer (gnus-get-buffer-create
 412                                " *gnus-cache-overview*"))))
 413       ;; Insert the contents of this group's cache overview.
 414       (erase-buffer)
 415       (let ((file (gnus-cache-file-name group ".overview"))
 416             (file-name-coding-system nnmail-pathname-coding-system))
 417         (when (file-exists-p file)
 418           (nnheader-insert-file-contents file)))
 419       ;; We have a fresh (empty/just loaded) buffer,
 420       ;; mark it as unmodified to save a redundant write later.
 421       (set-buffer-modified-p nil))))
 422
 423 ;; Return whether an article is a member of a class.
 424 (defun gnus-cache-member-of-class (class ticked dormant unread)
 425   (or (and ticked (memq 'ticked class))
 426       (and dormant (memq 'dormant class))
 427       (and unread (memq 'unread class))
 428       (and (not unread) (not ticked) (not dormant) (memq 'read class))))
 429
 430 (defvar gnus-cache-decoded-group-names nil
 431   "Alist of original group names and decoded group names.
 432 Decoding is done according to `gnus-group-name-charset-method-alist'
 433 or `gnus-group-name-charset-group-alist'.")
 434
 435 (defvar gnus-cache-unified-group-names nil
 436   "Alist of unified decoded group names and original group names.
 437 A group name is decoded according to
 438 `gnus-group-name-charset-method-alist' or
 439 `gnus-group-name-charset-group-alist' first, and is encoded and
 440 decoded again according to `nnmail-pathname-coding-system',
 441 `file-name-coding-system', or `default-file-name-coding-system'.
 442
 443 It is used when asking for a original group name from a cache
 444 directory name, in which non-ASCII characters might have been unified
 445 into the ones of a certain charset particularly if the `utf-8' coding
 446 system for example was used.")
 447
 448 (defun gnus-cache-decoded-group-name (group)
 449   "Return a decoded group name of GROUP."
 450   (or (cdr (assoc group gnus-cache-decoded-group-names))
 451       (let ((decoded (gnus-group-decoded-name group))
 452             (coding (or nnmail-pathname-coding-system
 453                         (and (boundp 'file-name-coding-system)
 454                              file-name-coding-system)
 455                         (and (boundp 'default-file-name-coding-system)
 456                              default-file-name-coding-system))))
 457         (push (cons group decoded) gnus-cache-decoded-group-names)
 458         (push (cons (mm-decode-coding-string
 459                      (mm-encode-coding-string decoded coding)
 460                      coding)
 461                     group)
 462               gnus-cache-unified-group-names)
 463         decoded)))
 464
 465 (defun gnus-cache-file-name (group article)
 466   (setq group (gnus-cache-decoded-group-name group))
 467   (expand-file-name
 468    (if (stringp article) article (int-to-string article))
 469    (file-name-as-directory
 470     (expand-file-name
 471      (nnheader-translate-file-chars
 472       (if (gnus-use-long-file-name 'not-cache)
 473           group
 474         (let ((group (nnheader-replace-duplicate-chars-in-string
 475                       (nnheader-replace-chars-in-string group ?/ ?_)
 476                       ?. ?_)))
 477           ;; Translate the first colon into a slash.
 478           (when (string-match ":" group)
 479                   (setq group (concat (substring group 0 (match-beginning 0))
 480                                       "/" (substring group (match-end 0)))))
 481           (nnheader-replace-chars-in-string group ?. ?/)))
 482       t)
 483      gnus-cache-directory))))
 484
 485 (defun gnus-cache-update-article (group article)
 486   "If ARTICLE is in the cache, remove it and re-enter it."
 487   (gnus-cache-change-buffer group)
 488   (when (gnus-cache-possibly-remove-article article nil nil nil t)
 489     (let ((gnus-use-cache nil))
 490       (gnus-cache-possibly-enter-article
 491        gnus-newsgroup-name article
 492        nil nil nil t))))
 493
 494 (defun gnus-cache-possibly-remove-article (article ticked dormant unread
 495                                                    &optional force)
 496   "Possibly remove ARTICLE from the cache."
 497   (let ((group gnus-newsgroup-name)
 498         (number article)
 499         file
 500         (file-name-coding-system nnmail-pathname-coding-system))
 501     ;; If this is a virtual group, we find the real group.
 502     (when (gnus-virtual-group-p group)
 503       (let ((result (nnvirtual-find-group-art
 504                      (gnus-group-real-name group) article)))
 505         (setq group (car result)
 506               number (cdr result))))
 507     (setq file (gnus-cache-file-name group number))
 508     (when (and (file-exists-p file)
 509                (or force
 510                    (gnus-cache-member-of-class
 511                     gnus-cache-remove-articles ticked dormant unread)))
 512       (save-excursion
 513         (gnus-cache-update-file-total-fetched-for group file t)
 514         (delete-file file)
 515
 516         (set-buffer (cdr gnus-cache-buffer))
 517         (goto-char (point-min))
 518         (when (or (looking-at (concat (int-to-string number) "\t"))
 519                   (search-forward (concat "\n" (int-to-string number) "\t")
 520                                   (point-max) t))
 521             (gnus-delete-line)))
 522       (unless (setq gnus-newsgroup-cached
 523                     (delq article gnus-newsgroup-cached))
 524         (gnus-sethash gnus-newsgroup-name nil gnus-cache-active-hashtb)
 525         (setq gnus-cache-active-altered t))
 526       (gnus-summary-update-secondary-mark article)
 527       t)))
 528
 529 (defun gnus-cache-articles-in-group (group)
 530   "Return a sorted list of cached articles in GROUP."
 531   (let ((dir (file-name-directory (gnus-cache-file-name group 1)))
 532         articles
 533         (file-name-coding-system nnmail-pathname-coding-system))
 534     (when (file-exists-p dir)
 535       (setq articles
 536             (sort (mapcar (lambda (name) (string-to-number name))
 537                           (directory-files dir nil "^[0-9]+$" t))
 538                   '<))
 539       ;; Update the cache active file, just to synch more.
 540       (if articles
 541           (progn
 542             (gnus-cache-update-active group (car articles) t)
 543             (gnus-cache-update-active group (car (last articles))))
 544         (when (gnus-gethash group gnus-cache-active-hashtb)
 545           (gnus-sethash group nil gnus-cache-active-hashtb)
 546           (setq gnus-cache-active-altered t)))
 547       articles)))
 548
 549 (defun gnus-cache-braid-nov (group cached &optional file)
 550   (let ((cache-buf (gnus-get-buffer-create " *gnus-cache*"))
 551         beg end)
 552     (gnus-cache-save-buffers)
 553     (save-excursion
 554       (set-buffer cache-buf)
 555       (erase-buffer)
 556       (let ((coding-system-for-read gnus-cache-overview-coding-system)
 557             (file-name-coding-system nnmail-pathname-coding-system))
 558         (insert-file-contents
 559          (or file (gnus-cache-file-name group ".overview"))))
 560       (goto-char (point-min))
 561       (insert "\n")
 562       (goto-char (point-min)))
 563     (set-buffer nntp-server-buffer)
 564     (goto-char (point-min))
 565     (while cached
 566       (while (and (not (eobp))
 567                   (< (read (current-buffer)) (car cached)))
 568         (forward-line 1))
 569       (beginning-of-line)
 570       (set-buffer cache-buf)
 571       (if (search-forward (concat "\n" (int-to-string (car cached)) "\t")
 572                           nil t)
 573           (setq beg (point-at-bol)
 574                 end (progn (end-of-line) (point)))
 575         (setq beg nil))
 576       (set-buffer nntp-server-buffer)
 577       (when beg
 578         (insert-buffer-substring cache-buf beg end)
 579         (insert "\n"))
 580       (setq cached (cdr cached)))
 581     (kill-buffer cache-buf)))
 582
 583 (defun gnus-cache-braid-heads (group cached)
 584   (let ((cache-buf (gnus-get-buffer-create " *gnus-cache*")))
 585     (with-current-buffer cache-buf
 586       (erase-buffer))
 587     (set-buffer nntp-server-buffer)
 588     (goto-char (point-min))
 589     (dolist (entry cached)
 590       (while (and (not (eobp))
 591                   (looking-at "2.. +\\([0-9]+\\) ")
 592                   (< (progn (goto-char (match-beginning 1))
 593                             (read (current-buffer)))
 594                      entry))
 595         (search-forward "\n.\n" nil 'move))
 596       (beginning-of-line)
 597       (set-buffer cache-buf)
 598       (erase-buffer)
 599       (let ((coding-system-for-read gnus-cache-coding-system)
 600             (file-name-coding-system nnmail-pathname-coding-system))
 601         (insert-file-contents (gnus-cache-file-name group entry)))
 602       (goto-char (point-min))
 603       (insert "220 ")
 604       (princ (car cached) (current-buffer))
 605       (insert " Article retrieved.\n")
 606       (search-forward "\n\n" nil 'move)
 607       (delete-region (point) (point-max))
 608       (forward-char -1)
 609       (insert ".")
 610       (set-buffer nntp-server-buffer)
 611       (insert-buffer-substring cache-buf))
 612     (kill-buffer cache-buf)))
 613
 614 ;;;###autoload
 615 (defun gnus-jog-cache ()
 616   "Go through all groups and put the articles into the cache.
 617
 618 Usage:
 619 $ emacs -batch -l ~/.emacs -l gnus -f gnus-jog-cache"
 620   (interactive)
 621   (let ((gnus-mark-article-hook nil)
 622         (gnus-expert-user t)
 623         (mail-sources nil)
 624         (gnus-use-dribble-file nil)
 625         (gnus-novice-user nil)
 626         (gnus-large-newsgroup nil))
 627     ;; Start Gnus.
 628     (gnus)
 629     ;; Go through all groups...
 630     (gnus-group-mark-buffer)
 631     (gnus-group-iterate nil
 632       (lambda (group)
 633         (let (gnus-auto-select-next)
 634           (gnus-summary-read-group group nil t)
 635           ;; ... and enter the articles into the cache.
 636           (when (eq major-mode 'gnus-summary-mode)
 637             (gnus-uu-mark-buffer)
 638             (gnus-cache-enter-article)
 639             (kill-buffer (current-buffer))))))))
 640
 641 (defun gnus-cache-read-active (&optional force)
 642   "Read the cache active file."
 643   (gnus-make-directory gnus-cache-directory)
 644   (if (or (not (file-exists-p gnus-cache-active-file))
 645           (zerop (nth 7 (file-attributes gnus-cache-active-file)))
 646           force)
 647       ;; There is no active file, so we generate one.
 648       (gnus-cache-generate-active)
 649     ;; We simply read the active file.
 650     (save-excursion
 651       (gnus-set-work-buffer)
 652       (nnheader-insert-file-contents gnus-cache-active-file)
 653       (gnus-active-to-gnus-format
 654        nil (setq gnus-cache-active-hashtb
 655                  (gnus-make-hashtable
 656                   (count-lines (point-min) (point-max)))))
 657       (setq gnus-cache-active-altered nil))))
 658
 659 (defun gnus-cache-write-active (&optional force)
 660   "Write the active hashtb to the active file."
 661   (when (or force
 662             (and gnus-cache-active-hashtb
 663                  gnus-cache-active-altered))
 664     (gnus-write-active-file gnus-cache-active-file gnus-cache-active-hashtb t)
 665     ;; Mark the active hashtb as unaltered.
 666     (setq gnus-cache-active-altered nil)))
 667
 668 (defun gnus-cache-possibly-update-active (group active)
 669   "Update active info bounds of GROUP with ACTIVE if necessary.
 670 The update is performed if ACTIVE contains a higher or lower bound
 671 than the current."
 672   (let ((lower t) (higher t))
 673     (if gnus-cache-active-hashtb
 674         (let ((cache-active (gnus-gethash group gnus-cache-active-hashtb)))
 675           (when cache-active
 676             (unless (< (car active) (car cache-active))
 677               (setq lower nil))
 678             (unless (> (cdr active) (cdr cache-active))
 679               (setq higher nil))))
 680       (gnus-cache-read-active))
 681     (when lower
 682       (gnus-cache-update-active group (car active) t))
 683     (when higher
 684       (gnus-cache-update-active group (cdr active)))))
 685
 686 (defun gnus-cache-update-active (group number &optional low)
 687   "Update the upper bound of the active info of GROUP to NUMBER.
 688 If LOW, update the lower bound instead."
 689   (let ((active (gnus-gethash group gnus-cache-active-hashtb)))
 690     (if (null active)
 691         ;; We just create a new active entry for this group.
 692         (gnus-sethash group (cons number number) gnus-cache-active-hashtb)
 693       ;; Update the lower or upper bound.
 694       (if low
 695           (setcar active number)
 696         (setcdr active number)))
 697     ;; Mark the active hashtb as altered.
 698     (setq gnus-cache-active-altered t)))
 699
 700 ;;;###autoload
 701 (defun gnus-cache-generate-active (&optional directory)
 702   "Generate the cache active file."
 703   (interactive)
 704   (let* ((top (null directory))
 705          (directory (expand-file-name (or directory gnus-cache-directory)))
 706          (file-name-coding-system nnmail-pathname-coding-system)
 707          (files (directory-files directory 'full))
 708          (group
 709           (if top
 710               ""
 711             (string-match
 712              (concat "^" (regexp-quote
 713                           (file-name-as-directory
 714                            (expand-file-name gnus-cache-directory))))
 715              (directory-file-name directory))
 716             (nnheader-replace-chars-in-string
 717              (substring (directory-file-name directory) (match-end 0))
 718              ?/ ?.)))
 719          nums alphs)
 720     (when top
 721       (gnus-message 5 "Generating the cache active file...")
 722       (setq gnus-cache-active-hashtb (gnus-make-hashtable 123)))
 723     (when (string-match "^\\(nn[^_]+\\)_" group)
 724       (setq group (replace-match "\\1:" t nil group)))
 725     ;; Separate articles from all other files and directories.
 726     (while files
 727       (if (string-match "^[0-9]+$" (file-name-nondirectory (car files)))
 728           (push (string-to-number (file-name-nondirectory (pop files))) nums)
 729         (push (pop files) alphs)))
 730     ;; If we have nums, then this is probably a valid group.
 731     (when (setq nums (sort nums '<))
 732       ;; Use non-decoded group name.
 733       ;; FIXME: this is kind of a workaround.  The active file should
 734       ;; be updated at the time articles are cached.  It will make
 735       ;; `gnus-cache-unified-group-names' needless.
 736       (gnus-sethash (or (cdr (assoc group gnus-cache-unified-group-names))
 737                         group)
 738                     (cons (car nums) (gnus-last-element nums))
 739                     gnus-cache-active-hashtb))
 740     ;; Go through all the other files.
 741     (dolist (file alphs)
 742       (when (and (file-directory-p file)
 743                  (not (string-match "^\\."
 744                                     (file-name-nondirectory file))))
 745         ;; We descend directories.
 746         (gnus-cache-generate-active file)))
 747     ;; Write the new active file.
 748     (when top
 749       (gnus-cache-write-active t)
 750       (gnus-message 5 "Generating the cache active file...done"))))
 751
 752 ;;;###autoload
 753 (defun gnus-cache-generate-nov-databases (dir)
 754   "Generate NOV files recursively starting in DIR."
 755   (interactive (list gnus-cache-directory))
 756   (gnus-cache-close)
 757   (let ((nnml-generate-active-function 'identity))
 758     (nnml-generate-nov-databases-directory dir))
 759
 760   (setq gnus-cache-total-fetched-hashtb nil)
 761
 762   (gnus-cache-open))
 763
 764 (defun gnus-cache-move-cache (dir)
 765   "Move the cache tree to somewhere else."
 766   (interactive "FMove the cache tree to: ")
 767   (rename-file gnus-cache-directory dir))
 768
 769 (defun gnus-cache-fully-p (&optional group)
 770   "Returns non-nil if the cache should be fully used.
 771 If GROUP is non-nil, also cater to `gnus-cacheable-groups' and
 772 `gnus-uncacheable-groups'."
 773   (and gnus-use-cache
 774        (not (eq gnus-use-cache 'passive))
 775        (if (null group)
 776            t
 777          (and (or (not gnus-cacheable-groups)
 778                   (string-match gnus-cacheable-groups group))
 779               (or (not gnus-uncacheable-groups)
 780                   (not (string-match gnus-uncacheable-groups group)))))))
 781
 782 ;;;###autoload
 783 (defun gnus-cache-rename-group (old-group new-group)
 784   "Rename OLD-GROUP as NEW-GROUP.
 785 Always updates the cache, even when disabled, as the old cache
 786 files would corrupt Gnus when the cache was next enabled.  It
 787 depends on the caller to determine whether group renaming is
 788 supported."
 789   (let ((old-dir (gnus-cache-file-name old-group ""))
 790         (new-dir (gnus-cache-file-name new-group ""))
 791         (file-name-coding-system nnmail-pathname-coding-system))
 792     (gnus-rename-file old-dir new-dir t))
 793
 794   (gnus-cache-rename-group-total-fetched-for old-group new-group)
 795
 796   (let ((no-save gnus-cache-active-hashtb))
 797     (unless gnus-cache-active-hashtb
 798       (gnus-cache-read-active))
 799     (let* ((old-group-hash-value
 800             (gnus-gethash old-group gnus-cache-active-hashtb))
 801            (new-group-hash-value
 802             (gnus-gethash new-group gnus-cache-active-hashtb))
 803            (delta
 804             (or old-group-hash-value new-group-hash-value)))
 805       (gnus-sethash new-group old-group-hash-value gnus-cache-active-hashtb)
 806       (gnus-sethash old-group nil gnus-cache-active-hashtb)
 807
 808       (if no-save
 809           (setq gnus-cache-active-altered delta)
 810         (gnus-cache-write-active delta)))))
 811
 812 ;;;###autoload
 813 (defun gnus-cache-delete-group (group)
 814   "Delete GROUP from the cache.
 815 Always updates the cache, even when disabled, as the old cache
 816 files would corrupt gnus when the cache was next enabled.
 817 Depends upon the caller to determine whether group deletion is
 818 supported."
 819   (let ((dir (gnus-cache-file-name group ""))
 820         (file-name-coding-system nnmail-pathname-coding-system))
 821     (gnus-delete-directory dir))
 822
 823   (gnus-cache-delete-group-total-fetched-for group)
 824
 825   (let ((no-save gnus-cache-active-hashtb))
 826     (unless gnus-cache-active-hashtb
 827       (gnus-cache-read-active))
 828     (let* ((group-hash-value (gnus-gethash group gnus-cache-active-hashtb)))
 829       (gnus-sethash group nil gnus-cache-active-hashtb)
 830
 831       (if no-save
 832           (setq gnus-cache-active-altered group-hash-value)
 833         (gnus-cache-write-active group-hash-value)))))
 834
 835 (defvar gnus-cache-inhibit-update-total-fetched-for nil)
 836 (defvar gnus-cache-need-update-total-fetched-for nil)
 837
 838 (defmacro gnus-cache-with-refreshed-group (group &rest body)
 839   `(prog1 (let ((gnus-cache-inhibit-update-total-fetched-for t))
 840             ,@body)
 841      (when (and gnus-cache-need-update-total-fetched-for
 842                 (not gnus-cache-inhibit-update-total-fetched-for))
 843         (save-excursion
 844           (set-buffer gnus-group-buffer)
 845           (setq gnus-cache-need-update-total-fetched-for nil)
 846           (gnus-group-update-group ,group t)))))
 847
 848 (defun gnus-cache-update-file-total-fetched-for (group file &optional subtract)
 849   (when gnus-cache-total-fetched-hashtb
 850     (gnus-cache-with-refreshed-group
 851      group
 852      (let* ((entry (or (gnus-gethash group gnus-cache-total-fetched-hashtb)
 853                        (gnus-sethash group (make-vector 2 0)
 854                                      gnus-cache-total-fetched-hashtb)))
 855             size)
 856
 857        (if file
 858            (setq size (or (nth 7 (file-attributes file)) 0))
 859          (let* ((file-name-coding-system nnmail-pathname-coding-system)
 860                 (files (directory-files (gnus-cache-file-name group "")
 861                                         t nil t))
 862                 file attrs)
 863            (setq size 0.0)
 864            (while (setq file (pop files))
 865              (setq attrs (file-attributes file))
 866              (unless (nth 0 attrs)
 867                (incf size (float (nth 7 attrs)))))))
 868
 869        (setq gnus-cache-need-update-total-fetched-for t)
 870
 871        (incf (nth 1 entry) (if subtract (- size) size))))))
 872
 873 (defun gnus-cache-update-overview-total-fetched-for (group file)
 874   (when gnus-cache-total-fetched-hashtb
 875     (gnus-cache-with-refreshed-group
 876      group
 877      (let* ((entry (or (gnus-gethash group gnus-cache-total-fetched-hashtb)
 878                        (gnus-sethash group (make-list 2 0)
 879                                      gnus-cache-total-fetched-hashtb)))
 880             (file-name-coding-system nnmail-pathname-coding-system)
 881             (size (or (nth 7 (file-attributes
 882                               (or file
 883                                   (gnus-cache-file-name group ".overview"))))
 884                       0)))
 885        (setq gnus-cache-need-update-total-fetched-for t)
 886        (setf (nth 0 entry) size)))))
 887
 888 (defun gnus-cache-rename-group-total-fetched-for (old-group new-group)
 889   "Record of disk space used by OLD-GROUP now associated with NEW-GROUP."
 890   (when gnus-cache-total-fetched-hashtb
 891     (let ((entry (gnus-gethash old-group gnus-cache-total-fetched-hashtb)))
 892       (gnus-sethash new-group entry gnus-cache-total-fetched-hashtb)
 893       (gnus-sethash old-group nil gnus-cache-total-fetched-hashtb))))
 894
 895 (defun gnus-cache-delete-group-total-fetched-for (group)
 896   "Delete record of disk space used by GROUP being deleted."
 897   (when gnus-cache-total-fetched-hashtb
 898       (gnus-sethash group nil gnus-cache-total-fetched-hashtb)))
 899
 900 (defun gnus-cache-total-fetched-for (group &optional no-inhibit)
 901   "Get total disk space used by the cache for the specified GROUP."
 902   (unless (equal group "dummy.group")
 903     (unless gnus-cache-total-fetched-hashtb
 904       (setq gnus-cache-total-fetched-hashtb (gnus-make-hashtable 1024)))
 905
 906     (let* ((entry (gnus-gethash group gnus-cache-total-fetched-hashtb)))
 907       (if entry
 908           (apply '+ entry)
 909         (let ((gnus-cache-inhibit-update-total-fetched-for (not no-inhibit)))
 910           (+
 911            (gnus-cache-update-overview-total-fetched-for group nil)
 912            (gnus-cache-update-file-total-fetched-for     group nil)))))))
 913
 914 (provide 'gnus-cache)
 915
 916 ;;; arch-tag: 05a79442-8c58-4e65-bd0a-3cbb1b89a33a
 917 ;;; gnus-cache.el ends here