cgit.sxemacs.org Git - gnus/blob - lisp/gnus-cache.el

   1 ;;; gnus-cache.el --- cache interface for Gnus
   2 ;; Copyright (C) 1995, 1996, 1997, 1998, 1999, 2000
   3 ;;        Free Software Foundation, Inc.
   4
   5 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   6 ;; Keywords: news
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;;; Code:
  28
  29 (eval-when-compile (require 'cl))
  30
  31 (require 'gnus)
  32 (require 'gnus-int)
  33 (require 'gnus-range)
  34 (require 'gnus-start)
  35 (eval-when-compile
  36   (require 'gnus-sum))
  37
  38 (defcustom gnus-cache-active-file
  39   (expand-file-name "active" gnus-cache-directory)
  40   "*The cache active file."
  41   :group 'gnus-cache
  42   :type 'file)
  43
  44 (defcustom gnus-cache-enter-articles '(ticked dormant)
  45   "Classes of articles to enter into the cache."
  46   :group 'gnus-cache
  47   :type '(set (const ticked) (const dormant) (const unread) (const read)))
  48
  49 (defcustom gnus-cache-remove-articles '(read)
  50   "Classes of articles to remove from the cache."
  51   :group 'gnus-cache
  52   :type '(set (const ticked) (const dormant) (const unread) (const read)))
  53
  54 (defcustom gnus-cacheable-groups nil
  55   "*Groups that match this regexp will be cached.
  56
  57 If you only want to cache your nntp groups, you could set this
  58 variable to \"^nntp\".
  59
  60 If a group matches both gnus-cacheable-groups and gnus-uncacheable-groups
  61 it's not cached."
  62   :group 'gnus-cache
  63   :type '(choice (const :tag "off" nil)
  64                  regexp))
  65
  66 (defcustom gnus-uncacheable-groups nil
  67   "*Groups that match this regexp will not be cached.
  68
  69 If you want to avoid caching your nnml groups, you could set this
  70 variable to \"^nnml\".
  71
  72 If a group matches both gnus-cacheable-groups and gnus-uncacheable-groups
  73 it's not cached."
  74   :group 'gnus-cache
  75   :type '(choice (const :tag "off" nil)
  76                  regexp))
  77
  78 (defvar gnus-cache-overview-coding-system 'raw-text
  79   "Coding system used on Gnus cache files.")
  80
  81 (defvar gnus-cache-coding-system 'raw-text
  82   "Coding system used on Gnus cache files.")
  83
  84 \f
  85
  86 ;;; Internal variables.
  87
  88 (defvar gnus-cache-removable-articles nil)
  89 (defvar gnus-cache-buffer nil)
  90 (defvar gnus-cache-active-hashtb nil)
  91 (defvar gnus-cache-active-altered nil)
  92
  93 (eval-and-compile
  94   (autoload 'nnml-generate-nov-databases-1 "nnml")
  95   (autoload 'nnvirtual-find-group-art "nnvirtual"))
  96
  97 \f
  98
  99 ;;; Functions called from Gnus.
 100
 101 (defun gnus-cache-open ()
 102   "Initialize the cache."
 103   (when (or (file-exists-p gnus-cache-directory)
 104             (and gnus-use-cache
 105                  (not (eq gnus-use-cache 'passive))))
 106     (gnus-cache-read-active)))
 107
 108 ;; Complexities of byte-compiling make this kludge necessary.  Eeek.
 109 (ignore-errors
 110   (gnus-add-shutdown 'gnus-cache-close 'gnus))
 111
 112 (defun gnus-cache-close ()
 113   "Shut down the cache."
 114   (gnus-cache-write-active)
 115   (gnus-cache-save-buffers)
 116   (setq gnus-cache-active-hashtb nil))
 117
 118 (defun gnus-cache-save-buffers ()
 119   ;; save the overview buffer if it exists and has been modified
 120   ;; delete empty cache subdirectories
 121   (when gnus-cache-buffer
 122     (let ((buffer (cdr gnus-cache-buffer))
 123           (overview-file (gnus-cache-file-name
 124                           (car gnus-cache-buffer) ".overview")))
 125       ;; write the overview only if it was modified
 126       (when (buffer-modified-p buffer)
 127         (save-excursion
 128           (set-buffer buffer)
 129           (if (> (buffer-size) 0)
 130               ;; Non-empty overview, write it to a file.
 131               (let ((coding-system-for-write
 132                      gnus-cache-overview-coding-system))
 133                 (gnus-write-buffer overview-file))
 134             ;; Empty overview file, remove it
 135             (when (file-exists-p overview-file)
 136               (delete-file overview-file))
 137             ;; If possible, remove group's cache subdirectory.
 138             (condition-case nil
 139                 ;; FIXME: we can detect the error type and warn the user
 140                 ;; of any inconsistencies (articles w/o nov entries?).
 141                 ;; for now, just be conservative...delete only if safe -- sj
 142                 (delete-directory (file-name-directory overview-file))
 143               (error nil)))))
 144       ;; Kill the buffer -- it's either unmodified or saved.
 145       (gnus-kill-buffer buffer)
 146       (setq gnus-cache-buffer nil))))
 147
 148 (defun gnus-cache-possibly-enter-article
 149   (group article ticked dormant unread &optional force)
 150   (when (and (or force (not (eq gnus-use-cache 'passive)))
 151              (numberp article)
 152              (> article 0))             ; This might be a dummy article.
 153     (let ((number article) file headers)
 154       ;; If this is a virtual group, we find the real group.
 155       (when (gnus-virtual-group-p group)
 156         (let ((result (nnvirtual-find-group-art
 157                        (gnus-group-real-name group) article)))
 158           (setq group (car result)
 159                 number (cdr result))))
 160       (when (and number
 161                  (> number 0)           ; Reffed article.
 162                  (or force
 163                      (and (gnus-cache-fully-p group)
 164                           (gnus-cache-member-of-class
 165                            gnus-cache-enter-articles ticked dormant unread)))
 166                  (not (file-exists-p (setq file (gnus-cache-file-name
 167                                                  group number)))))
 168         ;; Possibly create the cache directory.
 169         (gnus-make-directory (file-name-directory file))
 170         ;; Save the article in the cache.
 171         (if (file-exists-p file)
 172             t                           ; The article already is saved.
 173           (save-excursion
 174             (set-buffer nntp-server-buffer)
 175             (require 'gnus-art)
 176             (let ((gnus-use-cache nil)
 177                   (gnus-article-decode-hook nil))
 178               (gnus-request-article-this-buffer number group))
 179             (when (> (buffer-size) 0)
 180               (let ((coding-system-for-write gnus-cache-coding-system))
 181                 (gnus-write-buffer file))
 182               (setq headers (nnheader-parse-head t))
 183               (mail-header-set-number headers number)
 184               (gnus-cache-change-buffer group)
 185               (set-buffer (cdr gnus-cache-buffer))
 186               (goto-char (point-max))
 187               (forward-line -1)
 188               (while (condition-case ()
 189                          (when (not (bobp))
 190                            (> (read (current-buffer)) number))
 191                        (error
 192                         ;; The line was malformed, so we just remove it!!
 193                         (gnus-delete-line)
 194                         t))
 195                 (forward-line -1))
 196               (if (bobp)
 197                   (if (not (eobp))
 198                       (progn
 199                         (beginning-of-line)
 200                         (when (< (read (current-buffer)) number)
 201                           (forward-line 1)))
 202                     (beginning-of-line))
 203                 (forward-line 1))
 204               (beginning-of-line)
 205               (nnheader-insert-nov headers)
 206               ;; Update the active info.
 207               (set-buffer gnus-summary-buffer)
 208               (gnus-cache-possibly-update-active group (cons number number))
 209               (push article gnus-newsgroup-cached)
 210               (gnus-summary-update-secondary-mark article))
 211             t))))))
 212
 213 (defun gnus-cache-enter-remove-article (article)
 214   "Mark ARTICLE for later possible removal."
 215   (when article
 216     (push article gnus-cache-removable-articles)))
 217
 218 (defun gnus-cache-possibly-remove-articles ()
 219   "Possibly remove some of the removable articles."
 220   (if (not (gnus-virtual-group-p gnus-newsgroup-name))
 221       (gnus-cache-possibly-remove-articles-1)
 222     (let ((arts gnus-cache-removable-articles)
 223           ga)
 224       (while arts
 225         (when (setq ga (nnvirtual-find-group-art
 226                         (gnus-group-real-name gnus-newsgroup-name) (pop arts)))
 227           (let ((gnus-cache-removable-articles (list (cdr ga)))
 228                 (gnus-newsgroup-name (car ga)))
 229             (gnus-cache-possibly-remove-articles-1)))))
 230     (setq gnus-cache-removable-articles nil)))
 231
 232 (defun gnus-cache-possibly-remove-articles-1 ()
 233   "Possibly remove some of the removable articles."
 234   (when (gnus-cache-fully-p gnus-newsgroup-name)
 235     (let ((articles gnus-cache-removable-articles)
 236           (cache-articles gnus-newsgroup-cached)
 237           article)
 238       (gnus-cache-change-buffer gnus-newsgroup-name)
 239       (while articles
 240         (when (memq (setq article (pop articles)) cache-articles)
 241           ;; The article was in the cache, so we see whether we are
 242           ;; supposed to remove it from the cache.
 243           (gnus-cache-possibly-remove-article
 244            article (memq article gnus-newsgroup-marked)
 245            (memq article gnus-newsgroup-dormant)
 246            (or (memq article gnus-newsgroup-unreads)
 247                (memq article gnus-newsgroup-unselected))))))
 248     ;; The overview file might have been modified, save it
 249     ;; safe because we're only called at group exit anyway.
 250     (gnus-cache-save-buffers)))
 251
 252 (defun gnus-cache-request-article (article group)
 253   "Retrieve ARTICLE in GROUP from the cache."
 254   (let ((file (gnus-cache-file-name group article))
 255         (buffer-read-only nil))
 256     (when (file-exists-p file)
 257       (erase-buffer)
 258       (gnus-kill-all-overlays)
 259       (let ((coding-system-for-read gnus-cache-coding-system))
 260         (insert-file-contents file))
 261       t)))
 262
 263 (defun gnus-cache-possibly-alter-active (group active)
 264   "Alter the ACTIVE info for GROUP to reflect the articles in the cache."
 265   (when gnus-cache-active-hashtb
 266     (let ((cache-active (gnus-gethash group gnus-cache-active-hashtb)))
 267       (when cache-active
 268         (when (< (car cache-active) (car active))
 269           (setcar active (car cache-active)))
 270         (when (> (cdr cache-active) (cdr active))
 271           (setcdr active (cdr cache-active)))))))
 272
 273 (defun gnus-cache-retrieve-headers (articles group &optional fetch-old)
 274   "Retrieve the headers for ARTICLES in GROUP."
 275   (let ((cached
 276          (setq gnus-newsgroup-cached (gnus-cache-articles-in-group group))))
 277     (if (not cached)
 278         ;; No cached articles here, so we just retrieve them
 279         ;; the normal way.
 280         (let ((gnus-use-cache nil))
 281           (gnus-retrieve-headers articles group fetch-old))
 282       (let ((uncached-articles (gnus-sorted-intersection
 283                                 (gnus-sorted-complement articles cached)
 284                                 articles))
 285             (cache-file (gnus-cache-file-name group ".overview"))
 286             type)
 287         ;; We first retrieve all the headers that we don't have in
 288         ;; the cache.
 289         (let ((gnus-use-cache nil))
 290           (when uncached-articles
 291             (setq type (and articles
 292                             (gnus-retrieve-headers
 293                              uncached-articles group fetch-old)))))
 294         (gnus-cache-save-buffers)
 295         ;; Then we insert the cached headers.
 296         (save-excursion
 297           (cond
 298            ((not (file-exists-p cache-file))
 299             ;; There are no cached headers.
 300             type)
 301            ((null type)
 302             ;; There were no uncached headers (or retrieval was
 303             ;; unsuccessful), so we use the cached headers exclusively.
 304             (set-buffer nntp-server-buffer)
 305             (erase-buffer)
 306             (let ((coding-system-for-read
 307                    gnus-cache-overview-coding-system))
 308               (insert-file-contents cache-file))
 309             'nov)
 310            ((eq type 'nov)
 311             ;; We have both cached and uncached NOV headers, so we
 312             ;; braid them.
 313             (gnus-cache-braid-nov group cached)
 314             type)
 315            (t
 316             ;; We braid HEADs.
 317             (gnus-cache-braid-heads group (gnus-sorted-intersection
 318                                            cached articles))
 319             type)))))))
 320
 321 (defun gnus-cache-enter-article (&optional n)
 322   "Enter the next N articles into the cache.
 323 If not given a prefix, use the process marked articles instead.
 324 Returns the list of articles entered."
 325   (interactive "P")
 326   (let ((articles (gnus-summary-work-articles n))
 327         article out)
 328     (while (setq article (pop articles))
 329       (gnus-summary-remove-process-mark article)
 330       (if (natnump article)
 331           (when (gnus-cache-possibly-enter-article
 332                  gnus-newsgroup-name article
 333                  nil nil nil t)
 334             (push article out))
 335         (gnus-message 2 "Can't cache article %d" article))
 336       (gnus-summary-update-secondary-mark article))
 337     (gnus-summary-next-subject 1)
 338     (gnus-summary-position-point)
 339     (nreverse out)))
 340
 341 (defun gnus-cache-remove-article (n)
 342   "Remove the next N articles from the cache.
 343 If not given a prefix, use the process marked articles instead.
 344 Returns the list of articles removed."
 345   (interactive "P")
 346   (gnus-cache-change-buffer gnus-newsgroup-name)
 347   (let ((articles (gnus-summary-work-articles n))
 348         article out)
 349     (while articles
 350       (setq article (pop articles))
 351       (gnus-summary-remove-process-mark article)
 352       (when (gnus-cache-possibly-remove-article article nil nil nil t)
 353         (push article out))
 354       (gnus-summary-update-secondary-mark article))
 355     (gnus-summary-next-subject 1)
 356     (gnus-summary-position-point)
 357     (nreverse out)))
 358
 359 (defun gnus-cached-article-p (article)
 360   "Say whether ARTICLE is cached in the current group."
 361   (memq article gnus-newsgroup-cached))
 362
 363 (defun gnus-summary-insert-cached-articles ()
 364   "Insert all the articles cached for this group into the current buffer."
 365   (interactive)
 366   (let ((cached (sort (copy-sequence gnus-newsgroup-cached) '>))
 367         (gnus-verbose (max 6 gnus-verbose)))
 368     (unless cached
 369       (gnus-message 3 "No cached articles for this group"))
 370     (while cached
 371       (gnus-summary-goto-subject (pop cached) t))))
 372
 373 (defalias 'gnus-summary-limit-include-cached
 374   'gnus-summary-insert-cached-articles)
 375
 376 ;;; Internal functions.
 377
 378 (defun gnus-cache-change-buffer (group)
 379   (and gnus-cache-buffer
 380        ;; See if the current group's overview cache has been loaded.
 381        (or (string= group (car gnus-cache-buffer))
 382            ;; Another overview cache is current, save it.
 383            (gnus-cache-save-buffers)))
 384   ;; if gnus-cache buffer is nil, create it
 385   (unless gnus-cache-buffer
 386     ;; Create cache buffer
 387     (save-excursion
 388       (setq gnus-cache-buffer
 389             (cons group
 390                   (set-buffer (gnus-get-buffer-create
 391                                " *gnus-cache-overview*"))))
 392       ;; Insert the contents of this group's cache overview.
 393       (erase-buffer)
 394       (let ((file (gnus-cache-file-name group ".overview")))
 395         (when (file-exists-p file)
 396           (nnheader-insert-file-contents file)))
 397       ;; We have a fresh (empty/just loaded) buffer,
 398       ;; mark it as unmodified to save a redundant write later.
 399       (set-buffer-modified-p nil))))
 400
 401 ;; Return whether an article is a member of a class.
 402 (defun gnus-cache-member-of-class (class ticked dormant unread)
 403   (or (and ticked (memq 'ticked class))
 404       (and dormant (memq 'dormant class))
 405       (and unread (memq 'unread class))
 406       (and (not unread) (not ticked) (not dormant) (memq 'read class))))
 407
 408 (defun gnus-cache-file-name (group article)
 409   (expand-file-name
 410    (if (stringp article) article (int-to-string article))
 411    (file-name-as-directory
 412     (expand-file-name
 413      (nnheader-translate-file-chars
 414       (if (gnus-use-long-file-name 'not-cache)
 415           group
 416         (let ((group (nnheader-replace-duplicate-chars-in-string
 417                       (nnheader-replace-chars-in-string group ?/ ?_)
 418                       ?. ?_)))
 419           ;; Translate the first colon into a slash.
 420           (when (string-match ":" group)
 421                   (setq group (concat (substring group 0 (match-beginning 0))
 422                                       "/" (substring group (match-end 0)))))
 423           (nnheader-replace-chars-in-string group ?. ?/)))
 424       t)
 425      gnus-cache-directory))))
 426
 427 (defun gnus-cache-update-article (group article)
 428   "If ARTICLE is in the cache, remove it and re-enter it."
 429   (gnus-cache-change-buffer group)
 430   (when (gnus-cache-possibly-remove-article article nil nil nil t)
 431     (let ((gnus-use-cache nil))
 432       (gnus-cache-possibly-enter-article
 433        gnus-newsgroup-name article
 434        nil nil nil t))))
 435
 436 (defun gnus-cache-possibly-remove-article (article ticked dormant unread
 437                                                    &optional force)
 438   "Possibly remove ARTICLE from the cache."
 439   (let ((group gnus-newsgroup-name)
 440         (number article)
 441         file)
 442     ;; If this is a virtual group, we find the real group.
 443     (when (gnus-virtual-group-p group)
 444       (let ((result (nnvirtual-find-group-art
 445                      (gnus-group-real-name group) article)))
 446         (setq group (car result)
 447               number (cdr result))))
 448     (setq file (gnus-cache-file-name group number))
 449     (when (and (file-exists-p file)
 450                (or force
 451                    (gnus-cache-member-of-class
 452                     gnus-cache-remove-articles ticked dormant unread)))
 453       (save-excursion
 454         (delete-file file)
 455         (set-buffer (cdr gnus-cache-buffer))
 456         (goto-char (point-min))
 457         (when (or (looking-at (concat (int-to-string number) "\t"))
 458                   (search-forward (concat "\n" (int-to-string number) "\t")
 459                                   (point-max) t))
 460           (delete-region (progn (beginning-of-line) (point))
 461                          (progn (forward-line 1) (point)))))
 462       (setq gnus-newsgroup-cached
 463             (delq article gnus-newsgroup-cached))
 464       (gnus-summary-update-secondary-mark article)
 465       t)))
 466
 467 (defun gnus-cache-articles-in-group (group)
 468   "Return a sorted list of cached articles in GROUP."
 469   (let ((dir (file-name-directory (gnus-cache-file-name group 1)))
 470         articles)
 471     (when (file-exists-p dir)
 472       (setq articles
 473             (sort (mapcar (lambda (name) (string-to-int name))
 474                           (directory-files dir nil "^[0-9]+$" t))
 475                   '<))
 476       ;; Update the cache active file, just to synch more.
 477       (when articles
 478         (gnus-cache-update-active group (car articles) t)
 479         (gnus-cache-update-active group (car (last articles))))
 480       articles)))
 481
 482 (defun gnus-cache-braid-nov (group cached &optional file)
 483   (let ((cache-buf (gnus-get-buffer-create " *gnus-cache*"))
 484         beg end)
 485     (gnus-cache-save-buffers)
 486     (save-excursion
 487       (set-buffer cache-buf)
 488       (erase-buffer)
 489       (let ((coding-system-for-read
 490              gnus-cache-overview-coding-system))
 491         (insert-file-contents
 492          (or file (gnus-cache-file-name group ".overview"))))
 493       (goto-char (point-min))
 494       (insert "\n")
 495       (goto-char (point-min)))
 496     (set-buffer nntp-server-buffer)
 497     (goto-char (point-min))
 498     (while cached
 499       (while (and (not (eobp))
 500                   (< (read (current-buffer)) (car cached)))
 501         (forward-line 1))
 502       (beginning-of-line)
 503       (save-excursion
 504         (set-buffer cache-buf)
 505         (if (search-forward (concat "\n" (int-to-string (car cached)) "\t")
 506                             nil t)
 507             (setq beg (progn (beginning-of-line) (point))
 508                   end (progn (end-of-line) (point)))
 509           (setq beg nil)))
 510       (when beg
 511         (insert-buffer-substring cache-buf beg end)
 512         (insert "\n"))
 513       (setq cached (cdr cached)))
 514     (kill-buffer cache-buf)))
 515
 516 (defun gnus-cache-braid-heads (group cached)
 517   (let ((cache-buf (gnus-get-buffer-create " *gnus-cache*")))
 518     (save-excursion
 519       (set-buffer cache-buf)
 520       (erase-buffer))
 521     (set-buffer nntp-server-buffer)
 522     (goto-char (point-min))
 523     (while cached
 524       (while (and (not (eobp))
 525                   (looking-at "2.. +\\([0-9]+\\) ")
 526                   (< (progn (goto-char (match-beginning 1))
 527                             (read (current-buffer)))
 528                      (car cached)))
 529         (search-forward "\n.\n" nil 'move))
 530       (beginning-of-line)
 531       (save-excursion
 532         (set-buffer cache-buf)
 533         (erase-buffer)
 534         (let ((coding-system-for-read
 535                gnus-cache-coding-system))
 536           (insert-file-contents (gnus-cache-file-name group (car cached))))
 537         (goto-char (point-min))
 538         (insert "220 ")
 539         (princ (car cached) (current-buffer))
 540         (insert " Article retrieved.\n")
 541         (search-forward "\n\n" nil 'move)
 542         (delete-region (point) (point-max))
 543         (forward-char -1)
 544         (insert "."))
 545       (insert-buffer-substring cache-buf)
 546       (setq cached (cdr cached)))
 547     (kill-buffer cache-buf)))
 548
 549 ;;;###autoload
 550 (defun gnus-jog-cache ()
 551   "Go through all groups and put the articles into the cache.
 552
 553 Usage:
 554 $ emacs -batch -l ~/.emacs -l gnus -f gnus-jog-cache"
 555   (interactive)
 556   (let ((gnus-mark-article-hook nil)
 557         (gnus-expert-user t)
 558         (nnmail-spool-file nil)
 559         (mail-sources nil)
 560         (gnus-use-dribble-file nil)
 561         (gnus-novice-user nil)
 562         (gnus-large-newsgroup nil))
 563     ;; Start Gnus.
 564     (gnus)
 565     ;; Go through all groups...
 566     (gnus-group-mark-buffer)
 567     (gnus-group-iterate nil
 568       (lambda (group)
 569         (let (gnus-auto-select-next)
 570           (gnus-summary-read-group group nil t)
 571           ;; ... and enter the articles into the cache.
 572           (when (eq major-mode 'gnus-summary-mode)
 573             (gnus-uu-mark-buffer)
 574             (gnus-cache-enter-article)
 575             (kill-buffer (current-buffer))))))))
 576
 577 (defun gnus-cache-read-active (&optional force)
 578   "Read the cache active file."
 579   (gnus-make-directory gnus-cache-directory)
 580   (if (or (not (file-exists-p gnus-cache-active-file))
 581           (zerop (nth 7 (file-attributes gnus-cache-active-file)))
 582           force)
 583       ;; There is no active file, so we generate one.
 584       (gnus-cache-generate-active)
 585     ;; We simply read the active file.
 586     (save-excursion
 587       (gnus-set-work-buffer)
 588       (nnheader-insert-file-contents gnus-cache-active-file)
 589       (gnus-active-to-gnus-format
 590        nil (setq gnus-cache-active-hashtb
 591                  (gnus-make-hashtable
 592                   (count-lines (point-min) (point-max)))))
 593       (setq gnus-cache-active-altered nil))))
 594
 595 (defun gnus-cache-write-active (&optional force)
 596   "Write the active hashtb to the active file."
 597   (when (or force
 598             (and gnus-cache-active-hashtb
 599                  gnus-cache-active-altered))
 600     (gnus-write-active-file gnus-cache-active-file gnus-cache-active-hashtb t)
 601     ;; Mark the active hashtb as unaltered.
 602     (setq gnus-cache-active-altered nil)))
 603
 604 (defun gnus-cache-possibly-update-active (group active)
 605   "Update active info bounds of GROUP with ACTIVE if necessary.
 606 The update is performed if ACTIVE contains a higher or lower bound
 607 than the current."
 608   (let ((lower t) (higher t))
 609     (if gnus-cache-active-hashtb
 610         (let ((cache-active (gnus-gethash group gnus-cache-active-hashtb)))
 611           (when cache-active
 612             (unless (< (car active) (car cache-active))
 613               (setq lower nil))
 614             (unless (> (cdr active) (cdr cache-active))
 615               (setq higher nil))))
 616       (gnus-cache-read-active))
 617     (when lower
 618       (gnus-cache-update-active group (car active) t))
 619     (when higher
 620       (gnus-cache-update-active group (cdr active)))))
 621
 622 (defun gnus-cache-update-active (group number &optional low)
 623   "Update the upper bound of the active info of GROUP to NUMBER.
 624 If LOW, update the lower bound instead."
 625   (let ((active (gnus-gethash group gnus-cache-active-hashtb)))
 626     (if (null active)
 627         ;; We just create a new active entry for this group.
 628         (gnus-sethash group (cons number number) gnus-cache-active-hashtb)
 629       ;; Update the lower or upper bound.
 630       (if low
 631           (setcar active number)
 632         (setcdr active number)))
 633     ;; Mark the active hashtb as altered.
 634     (setq gnus-cache-active-altered t)))
 635
 636 ;;;###autoload
 637 (defun gnus-cache-generate-active (&optional directory)
 638   "Generate the cache active file."
 639   (interactive)
 640   (let* ((top (null directory))
 641          (directory (expand-file-name (or directory gnus-cache-directory)))
 642          (files (directory-files directory 'full))
 643          (group
 644           (if top
 645               ""
 646             (string-match
 647              (concat "^" (regexp-quote
 648                           (file-name-as-directory
 649                            (expand-file-name gnus-cache-directory))))
 650              (directory-file-name directory))
 651             (nnheader-replace-chars-in-string
 652              (substring (directory-file-name directory) (match-end 0))
 653              ?/ ?.)))
 654          nums alphs)
 655     (when top
 656       (gnus-message 5 "Generating the cache active file...")
 657       (setq gnus-cache-active-hashtb (gnus-make-hashtable 123)))
 658     (when (string-match "^\\(nn[^_]+\\)_" group)
 659       (setq group (replace-match "\\1:" t t group)))
 660     ;; Separate articles from all other files and directories.
 661     (while files
 662       (if (string-match "^[0-9]+$" (file-name-nondirectory (car files)))
 663           (push (string-to-int (file-name-nondirectory (pop files))) nums)
 664         (push (pop files) alphs)))
 665     ;; If we have nums, then this is probably a valid group.
 666     (when (setq nums (sort nums '<))
 667       (gnus-sethash group (cons (car nums) (gnus-last-element nums))
 668                     gnus-cache-active-hashtb))
 669     ;; Go through all the other files.
 670     (while alphs
 671       (when (and (file-directory-p (car alphs))
 672                  (not (string-match "^\\."
 673                                     (file-name-nondirectory (car alphs)))))
 674         ;; We descend directories.
 675         (gnus-cache-generate-active (car alphs)))
 676       (setq alphs (cdr alphs)))
 677     ;; Write the new active file.
 678     (when top
 679       (gnus-cache-write-active t)
 680       (gnus-message 5 "Generating the cache active file...done"))))
 681
 682 ;;;###autoload
 683 (defun gnus-cache-generate-nov-databases (dir)
 684   "Generate NOV files recursively starting in DIR."
 685   (interactive (list gnus-cache-directory))
 686   (gnus-cache-close)
 687   (let ((nnml-generate-active-function 'identity))
 688     (nnml-generate-nov-databases-1 dir))
 689   (gnus-cache-open))
 690
 691 (defun gnus-cache-move-cache (dir)
 692   "Move the cache tree to somewhere else."
 693   (interactive "FMove the cache tree to: ")
 694   (rename-file gnus-cache-directory dir))
 695
 696 (defun gnus-cache-fully-p (&optional group)
 697   "Returns non-nil if the cache should be fully used.
 698 If GROUP is non-nil, also cater to `gnus-cacheable-groups' and
 699 `gnus-uncacheable-groups'."
 700   (and gnus-use-cache
 701        (not (eq gnus-use-cache 'passive))
 702        (if (null group)
 703            t
 704          (and (or (not gnus-cacheable-groups)
 705                   (string-match gnus-cacheable-groups group))
 706               (or (not gnus-uncacheable-groups)
 707                   (not (string-match gnus-uncacheable-groups group)))))))
 708
 709
 710 (provide 'gnus-cache)
 711
 712 ;;; gnus-cache.el ends here