cgit.sxemacs.org Git - gnus/blob - lisp/gnus-cache.el

   1 ;;; gnus-cache.el --- cache interface for Gnus
   2 ;; Copyright (C) 1995,96,97,98 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   5 ;; Keywords: news
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  22 ;; Boston, MA 02111-1307, USA.
  23
  24 ;;; Commentary:
  25
  26 ;;; Code:
  27
  28 (eval-when-compile (require 'cl))
  29
  30 (require 'gnus)
  31 (require 'gnus-int)
  32 (require 'gnus-range)
  33 (require 'gnus-start)
  34 (eval-when-compile
  35   (require 'gnus-sum))
  36
  37 (defcustom gnus-cache-active-file
  38   (concat (file-name-as-directory gnus-cache-directory) "active")
  39   "*The cache active file."
  40   :group 'gnus-cache
  41   :type 'file)
  42
  43 (defcustom gnus-cache-enter-articles '(ticked dormant)
  44   "Classes of articles to enter into the cache."
  45   :group 'gnus-cache
  46   :type '(set (const ticked) (const dormant) (const unread) (const read)))
  47
  48 (defcustom gnus-cache-remove-articles '(read)
  49   "Classes of articles to remove from the cache."
  50   :group 'gnus-cache
  51   :type '(set (const ticked) (const dormant) (const unread) (const read)))
  52
  53 (defcustom gnus-cacheable-groups nil
  54   "*Groups that match this regexp will be cached.
  55
  56 If you only want to cache your nntp groups, you could set this
  57 variable to \"^nntp\".
  58
  59 If a group matches both gnus-cacheable-groups and gnus-uncacheable-groups
  60 it's not cached."
  61   :group 'gnus-cache
  62   :type '(choice (const :tag "off" nil)
  63                 regexp))
  64
  65 (defcustom gnus-uncacheable-groups nil
  66   "*Groups that match this regexp will not be cached.
  67
  68 If you want to avoid caching your nnml groups, you could set this
  69 variable to \"^nnml\".
  70
  71 If a group matches both gnus-cacheable-groups and gnus-uncacheable-groups
  72 it's not cached."
  73   :group 'gnus-cache
  74   :type '(choice (const :tag "off" nil)
  75                  regexp))
  76
  77 (defvar gnus-cache-overview-coding-system 'raw-text
  78   "Coding system used on Gnus cache files.")
  79
  80 \f
  81
  82 ;;; Internal variables.
  83
  84 (defvar gnus-cache-removable-articles nil)
  85 (defvar gnus-cache-buffer nil)
  86 (defvar gnus-cache-active-hashtb nil)
  87 (defvar gnus-cache-active-altered nil)
  88
  89 (eval-and-compile
  90   (autoload 'nnml-generate-nov-databases-1 "nnml")
  91   (autoload 'nnvirtual-find-group-art "nnvirtual"))
  92
  93 \f
  94
  95 ;;; Functions called from Gnus.
  96
  97 (defun gnus-cache-open ()
  98   "Initialize the cache."
  99   (when (or (file-exists-p gnus-cache-directory)
 100             (and gnus-use-cache
 101                  (not (eq gnus-use-cache 'passive))))
 102     (gnus-cache-read-active)))
 103
 104 ;; Complexities of byte-compiling make this kludge necessary.  Eeek.
 105 (ignore-errors
 106   (gnus-add-shutdown 'gnus-cache-close 'gnus))
 107
 108 (defun gnus-cache-close ()
 109   "Shut down the cache."
 110   (gnus-cache-write-active)
 111   (gnus-cache-save-buffers)
 112   (setq gnus-cache-active-hashtb nil))
 113
 114 (defun gnus-cache-save-buffers ()
 115   ;; save the overview buffer if it exists and has been modified
 116   ;; delete empty cache subdirectories
 117   (when gnus-cache-buffer
 118     (let ((buffer (cdr gnus-cache-buffer))
 119           (overview-file (gnus-cache-file-name
 120                           (car gnus-cache-buffer) ".overview")))
 121       ;; write the overview only if it was modified
 122       (when (buffer-modified-p buffer)
 123         (save-excursion
 124           (set-buffer buffer)
 125           (if (> (buffer-size) 0)
 126               ;; Non-empty overview, write it to a file.
 127               (let ((coding-system-for-write
 128                      gnus-cache-overview-coding-system))
 129                 (gnus-write-buffer overview-file))
 130             ;; Empty overview file, remove it
 131             (when (file-exists-p overview-file)
 132               (delete-file overview-file))
 133             ;; If possible, remove group's cache subdirectory.
 134             (condition-case nil
 135                 ;; FIXME: we can detect the error type and warn the user
 136                 ;; of any inconsistencies (articles w/o nov entries?).
 137                 ;; for now, just be conservative...delete only if safe -- sj
 138                 (delete-directory (file-name-directory overview-file))
 139               (error nil)))))
 140       ;; Kill the buffer -- it's either unmodified or saved.
 141       (gnus-kill-buffer buffer)
 142       (setq gnus-cache-buffer nil))))
 143
 144 (defun gnus-cache-possibly-enter-article
 145   (group article headers ticked dormant unread &optional force)
 146   (when (and (or force (not (eq gnus-use-cache 'passive)))
 147              (numberp article)
 148              (> article 0)
 149              (vectorp headers))         ; This might be a dummy article.
 150     ;; If this is a virtual group, we find the real group.
 151     (when (gnus-virtual-group-p group)
 152       (let ((result (nnvirtual-find-group-art
 153                      (gnus-group-real-name group) article)))
 154         (setq group (car result)
 155               headers (copy-sequence headers))
 156         (mail-header-set-number headers (cdr result))))
 157     (let ((number (mail-header-number headers))
 158           file)
 159       (when (and number
 160                  (> number 0)           ; Reffed article.
 161                  (or force
 162                      (and (or (not gnus-cacheable-groups)
 163                               (string-match gnus-cacheable-groups group))
 164                           (or (not gnus-uncacheable-groups)
 165                               (not (string-match
 166                                     gnus-uncacheable-groups group)))
 167                           (gnus-cache-member-of-class
 168                            gnus-cache-enter-articles ticked dormant unread)))
 169                  (not (file-exists-p (setq file (gnus-cache-file-name
 170                                                  group number)))))
 171         ;; Possibly create the cache directory.
 172         (gnus-make-directory (file-name-directory file))
 173         ;; Save the article in the cache.
 174         (if (file-exists-p file)
 175             t                           ; The article already is saved.
 176           (save-excursion
 177             (set-buffer nntp-server-buffer)
 178             (let ((gnus-use-cache nil))
 179               (gnus-request-article-this-buffer number group))
 180             (when (> (buffer-size) 0)
 181               (gnus-write-buffer file)
 182               (gnus-cache-change-buffer group)
 183               (set-buffer (cdr gnus-cache-buffer))
 184               (goto-char (point-max))
 185               (forward-line -1)
 186               (while (condition-case ()
 187                          (when (not (bobp))
 188                            (> (read (current-buffer)) number))
 189                        (error
 190                         ;; The line was malformed, so we just remove it!!
 191                         (gnus-delete-line)
 192                         t))
 193                 (forward-line -1))
 194               (if (bobp)
 195                   (if (not (eobp))
 196                       (progn
 197                         (beginning-of-line)
 198                         (when (< (read (current-buffer)) number)
 199                           (forward-line 1)))
 200                     (beginning-of-line))
 201                 (forward-line 1))
 202               (beginning-of-line)
 203               ;; [number subject from date id references chars lines xref]
 204               (insert (format "%s\t%s\t%s\t%s\t%s\t%s\t%s\t%s\t%s\t\n"
 205                               (mail-header-number headers)
 206                               (mail-header-subject headers)
 207                               (mail-header-from headers)
 208                               (mail-header-date headers)
 209                               (mail-header-id headers)
 210                               (or (mail-header-references headers) "")
 211                               (or (mail-header-chars headers) "")
 212                               (or (mail-header-lines headers) "")
 213                               (or (mail-header-xref headers) "")))
 214               ;; Update the active info.
 215               (set-buffer gnus-summary-buffer)
 216               (gnus-cache-update-active group number)
 217               (push article gnus-newsgroup-cached)
 218               (gnus-summary-update-secondary-mark article))
 219             t))))))
 220
 221 (defun gnus-cache-enter-remove-article (article)
 222   "Mark ARTICLE for later possible removal."
 223   (when article
 224     (push article gnus-cache-removable-articles)))
 225
 226 (defun gnus-cache-possibly-remove-articles ()
 227   "Possibly remove some of the removable articles."
 228   (if (not (gnus-virtual-group-p gnus-newsgroup-name))
 229       (gnus-cache-possibly-remove-articles-1)
 230     (let ((arts gnus-cache-removable-articles)
 231           ga)
 232       (while arts
 233         (when (setq ga (nnvirtual-find-group-art
 234                         (gnus-group-real-name gnus-newsgroup-name) (pop arts)))
 235           (let ((gnus-cache-removable-articles (list (cdr ga)))
 236                 (gnus-newsgroup-name (car ga)))
 237             (gnus-cache-possibly-remove-articles-1)))))
 238     (setq gnus-cache-removable-articles nil)))
 239
 240 (defun gnus-cache-possibly-remove-articles-1 ()
 241   "Possibly remove some of the removable articles."
 242   (unless (eq gnus-use-cache 'passive)
 243     (let ((articles gnus-cache-removable-articles)
 244           (cache-articles gnus-newsgroup-cached)
 245           article)
 246       (gnus-cache-change-buffer gnus-newsgroup-name)
 247       (while articles
 248         (when (memq (setq article (pop articles)) cache-articles)
 249           ;; The article was in the cache, so we see whether we are
 250           ;; supposed to remove it from the cache.
 251           (gnus-cache-possibly-remove-article
 252            article (memq article gnus-newsgroup-marked)
 253            (memq article gnus-newsgroup-dormant)
 254            (or (memq article gnus-newsgroup-unreads)
 255                (memq article gnus-newsgroup-unselected))))))
 256     ;; The overview file might have been modified, save it
 257     ;; safe because we're only called at group exit anyway.
 258     (gnus-cache-save-buffers)))
 259
 260 (defun gnus-cache-request-article (article group)
 261   "Retrieve ARTICLE in GROUP from the cache."
 262   (let ((file (gnus-cache-file-name group article))
 263         (buffer-read-only nil))
 264     (when (file-exists-p file)
 265       (erase-buffer)
 266       (gnus-kill-all-overlays)
 267       (insert-file-contents file)
 268       t)))
 269
 270 (defun gnus-cache-possibly-alter-active (group active)
 271   "Alter the ACTIVE info for GROUP to reflect the articles in the cache."
 272   (when gnus-cache-active-hashtb
 273     (let ((cache-active (gnus-gethash group gnus-cache-active-hashtb)))
 274       (when cache-active
 275         (when (< (car cache-active) (car active))
 276           (setcar active (car cache-active)))
 277         (when (> (cdr cache-active) (cdr active))
 278           (setcdr active (cdr cache-active)))))))
 279
 280 (defun gnus-cache-retrieve-headers (articles group &optional fetch-old)
 281   "Retrieve the headers for ARTICLES in GROUP."
 282   (let ((cached
 283          (setq gnus-newsgroup-cached (gnus-cache-articles-in-group group))))
 284     (if (not cached)
 285         ;; No cached articles here, so we just retrieve them
 286         ;; the normal way.
 287         (let ((gnus-use-cache nil))
 288           (gnus-retrieve-headers articles group fetch-old))
 289       (let ((uncached-articles (gnus-sorted-intersection
 290                                 (gnus-sorted-complement articles cached)
 291                                 articles))
 292             (cache-file (gnus-cache-file-name group ".overview"))
 293             type)
 294         ;; We first retrieve all the headers that we don't have in
 295         ;; the cache.
 296         (let ((gnus-use-cache nil))
 297           (when uncached-articles
 298             (setq type (and articles
 299                             (gnus-retrieve-headers
 300                              uncached-articles group fetch-old)))))
 301         (gnus-cache-save-buffers)
 302         ;; Then we insert the cached headers.
 303         (save-excursion
 304           (cond
 305            ((not (file-exists-p cache-file))
 306             ;; There are no cached headers.
 307             type)
 308            ((null type)
 309             ;; There were no uncached headers (or retrieval was
 310             ;; unsuccessful), so we use the cached headers exclusively.
 311             (set-buffer nntp-server-buffer)
 312             (erase-buffer)
 313             (insert-file-contents cache-file)
 314             'nov)
 315            ((eq type 'nov)
 316             ;; We have both cached and uncached NOV headers, so we
 317             ;; braid them.
 318             (gnus-cache-braid-nov group cached)
 319             type)
 320            (t
 321             ;; We braid HEADs.
 322             (gnus-cache-braid-heads group (gnus-sorted-intersection
 323                                            cached articles))
 324             type)))))))
 325
 326 (defun gnus-cache-enter-article (&optional n)
 327   "Enter the next N articles into the cache.
 328 If not given a prefix, use the process marked articles instead.
 329 Returns the list of articles entered."
 330   (interactive "P")
 331   (let ((articles (gnus-summary-work-articles n))
 332         article out)
 333     (while (setq article (pop articles))
 334       (gnus-summary-remove-process-mark article)
 335       (if (natnump article)
 336           (when (gnus-cache-possibly-enter-article
 337                  gnus-newsgroup-name article
 338                  (gnus-summary-article-header article)
 339                  nil nil nil t)
 340             (push article out))
 341         (gnus-message 2 "Can't cache article %d" article))
 342       (gnus-summary-update-secondary-mark article))
 343     (gnus-summary-next-subject 1)
 344     (gnus-summary-position-point)
 345     (nreverse out)))
 346
 347 (defun gnus-cache-remove-article (n)
 348   "Remove the next N articles from the cache.
 349 If not given a prefix, use the process marked articles instead.
 350 Returns the list of articles removed."
 351   (interactive "P")
 352   (gnus-cache-change-buffer gnus-newsgroup-name)
 353   (let ((articles (gnus-summary-work-articles n))
 354         article out)
 355     (while articles
 356       (setq article (pop articles))
 357       (gnus-summary-remove-process-mark article)
 358       (when (gnus-cache-possibly-remove-article article nil nil nil t)
 359         (push article out))
 360       (gnus-summary-update-secondary-mark article))
 361     (gnus-summary-next-subject 1)
 362     (gnus-summary-position-point)
 363     (nreverse out)))
 364
 365 (defun gnus-cached-article-p (article)
 366   "Say whether ARTICLE is cached in the current group."
 367   (memq article gnus-newsgroup-cached))
 368
 369 (defun gnus-summary-insert-cached-articles ()
 370   "Insert all the articles cached for this group into the current buffer."
 371   (interactive)
 372   (let ((cached (sort (copy-sequence gnus-newsgroup-cached) '<))
 373         (gnus-verbose (max 6 gnus-verbose)))
 374     (unless cached
 375       (gnus-message 3 "No cached articles for this group"))
 376     (while cached
 377       (gnus-summary-goto-subject (pop cached) t))))
 378
 379 (defalias 'gnus-summary-limit-include-cached
 380   'gnus-summary-insert-cached-articles)
 381
 382 ;;; Internal functions.
 383
 384 (defun gnus-cache-change-buffer (group)
 385   (and gnus-cache-buffer
 386        ;; See if the current group's overview cache has been loaded.
 387        (or (string= group (car gnus-cache-buffer))
 388            ;; Another overview cache is current, save it.
 389            (gnus-cache-save-buffers)))
 390   ;; if gnus-cache buffer is nil, create it
 391   (unless gnus-cache-buffer
 392     ;; Create cache buffer
 393     (save-excursion
 394       (setq gnus-cache-buffer
 395             (cons group
 396                   (set-buffer (gnus-get-buffer-create
 397                                " *gnus-cache-overview*"))))
 398       (buffer-disable-undo (current-buffer))
 399       ;; Insert the contents of this group's cache overview.
 400       (erase-buffer)
 401       (let ((file (gnus-cache-file-name group ".overview")))
 402         (when (file-exists-p file)
 403           (nnheader-insert-file-contents file)))
 404       ;; We have a fresh (empty/just loaded) buffer,
 405       ;; mark it as unmodified to save a redundant write later.
 406       (set-buffer-modified-p nil))))
 407
 408 ;; Return whether an article is a member of a class.
 409 (defun gnus-cache-member-of-class (class ticked dormant unread)
 410   (or (and ticked (memq 'ticked class))
 411       (and dormant (memq 'dormant class))
 412       (and unread (memq 'unread class))
 413       (and (not unread) (not ticked) (not dormant) (memq 'read class))))
 414
 415 (defun gnus-cache-file-name (group article)
 416   (concat (file-name-as-directory gnus-cache-directory)
 417           (file-name-as-directory
 418            (nnheader-translate-file-chars
 419             (if (gnus-use-long-file-name 'not-cache)
 420                 group
 421               (let ((group (nnheader-replace-chars-in-string group ?/ ?_)))
 422                 ;; Translate the first colon into a slash.
 423                 (when (string-match ":" group)
 424                   (aset group (match-beginning 0) ?/))
 425                 (nnheader-replace-chars-in-string group ?. ?/)))
 426             t))
 427           (if (stringp article) article (int-to-string article))))
 428
 429 (defun gnus-cache-update-article (group article)
 430   "If ARTICLE is in the cache, remove it and re-enter it."
 431   (gnus-cache-change-buffer group)
 432   (when (gnus-cache-possibly-remove-article article nil nil nil t)
 433     (let ((gnus-use-cache nil))
 434       (gnus-cache-possibly-enter-article
 435        gnus-newsgroup-name article (gnus-summary-article-header article)
 436        nil nil nil t))))
 437
 438 (defun gnus-cache-possibly-remove-article (article ticked dormant unread
 439                                                    &optional force)
 440   "Possibly remove ARTICLE from the cache."
 441   (let ((group gnus-newsgroup-name)
 442         (number article)
 443         file)
 444     ;; If this is a virtual group, we find the real group.
 445     (when (gnus-virtual-group-p group)
 446       (let ((result (nnvirtual-find-group-art
 447                      (gnus-group-real-name group) article)))
 448         (setq group (car result)
 449               number (cdr result))))
 450     (setq file (gnus-cache-file-name group number))
 451     (when (and (file-exists-p file)
 452                (or force
 453                    (gnus-cache-member-of-class
 454                     gnus-cache-remove-articles ticked dormant unread)))
 455       (save-excursion
 456         (delete-file file)
 457         (set-buffer (cdr gnus-cache-buffer))
 458         (goto-char (point-min))
 459         (when (or (looking-at (concat (int-to-string number) "\t"))
 460                   (search-forward (concat "\n" (int-to-string number) "\t")
 461                                   (point-max) t))
 462           (delete-region (progn (beginning-of-line) (point))
 463                          (progn (forward-line 1) (point)))))
 464       (setq gnus-newsgroup-cached
 465             (delq article gnus-newsgroup-cached))
 466       (gnus-summary-update-secondary-mark article)
 467       t)))
 468
 469 (defun gnus-cache-articles-in-group (group)
 470   "Return a sorted list of cached articles in GROUP."
 471   (let ((dir (file-name-directory (gnus-cache-file-name group 1)))
 472         articles)
 473     (when (file-exists-p dir)
 474       (setq articles
 475             (sort (mapcar (lambda (name) (string-to-int name))
 476                           (directory-files dir nil "^[0-9]+$" t))
 477                   '<))
 478       ;; Update the cache active file, just to synch more.
 479       (when articles
 480         (gnus-cache-update-active group (car articles) t)
 481         (gnus-cache-update-active group (car (last articles))))
 482       articles)))
 483
 484 (defun gnus-cache-braid-nov (group cached &optional file)
 485   (let ((cache-buf (gnus-get-buffer-create " *gnus-cache*"))
 486         beg end)
 487     (gnus-cache-save-buffers)
 488     (save-excursion
 489       (set-buffer cache-buf)
 490       (buffer-disable-undo (current-buffer))
 491       (erase-buffer)
 492       (insert-file-contents (or file (gnus-cache-file-name group ".overview")))
 493       (goto-char (point-min))
 494       (insert "\n")
 495       (goto-char (point-min)))
 496     (set-buffer nntp-server-buffer)
 497     (goto-char (point-min))
 498     (while cached
 499       (while (and (not (eobp))
 500                   (< (read (current-buffer)) (car cached)))
 501         (forward-line 1))
 502       (beginning-of-line)
 503       (save-excursion
 504         (set-buffer cache-buf)
 505         (if (search-forward (concat "\n" (int-to-string (car cached)) "\t")
 506                             nil t)
 507             (setq beg (progn (beginning-of-line) (point))
 508                   end (progn (end-of-line) (point)))
 509           (setq beg nil)))
 510       (when beg
 511         (insert-buffer-substring cache-buf beg end)
 512         (insert "\n"))
 513       (setq cached (cdr cached)))
 514     (kill-buffer cache-buf)))
 515
 516 (defun gnus-cache-braid-heads (group cached)
 517   (let ((cache-buf (gnus-get-buffer-create " *gnus-cache*")))
 518     (save-excursion
 519       (set-buffer cache-buf)
 520       (buffer-disable-undo (current-buffer))
 521       (erase-buffer))
 522     (set-buffer nntp-server-buffer)
 523     (goto-char (point-min))
 524     (while cached
 525       (while (and (not (eobp))
 526                   (looking-at "2.. +\\([0-9]+\\) ")
 527                   (< (progn (goto-char (match-beginning 1))
 528                             (read (current-buffer)))
 529                      (car cached)))
 530         (search-forward "\n.\n" nil 'move))
 531       (beginning-of-line)
 532       (save-excursion
 533         (set-buffer cache-buf)
 534         (erase-buffer)
 535         (insert-file-contents (gnus-cache-file-name group (car cached)))
 536         (goto-char (point-min))
 537         (insert "220 ")
 538         (princ (car cached) (current-buffer))
 539         (insert " Article retrieved.\n")
 540         (search-forward "\n\n" nil 'move)
 541         (delete-region (point) (point-max))
 542         (forward-char -1)
 543         (insert "."))
 544       (insert-buffer-substring cache-buf)
 545       (setq cached (cdr cached)))
 546     (kill-buffer cache-buf)))
 547
 548 ;;;###autoload
 549 (defun gnus-jog-cache ()
 550   "Go through all groups and put the articles into the cache.
 551
 552 Usage:
 553 $ emacs -batch -l ~/.emacs -l gnus -f gnus-jog-cache"
 554   (interactive)
 555   (let ((gnus-mark-article-hook nil)
 556         (gnus-expert-user t)
 557         (nnmail-spool-file nil)
 558         (gnus-use-dribble-file nil)
 559         (gnus-novice-user nil)
 560         (gnus-large-newsgroup nil))
 561     ;; Start Gnus.
 562     (gnus)
 563     ;; Go through all groups...
 564     (gnus-group-mark-buffer)
 565     (gnus-group-iterate nil
 566       (lambda (group)
 567         (let (gnus-auto-select-next)
 568           (gnus-summary-read-group group nil t)
 569           ;; ... and enter the articles into the cache.
 570           (when (eq major-mode 'gnus-summary-mode)
 571             (gnus-uu-mark-buffer)
 572             (gnus-cache-enter-article)
 573             (kill-buffer (current-buffer))))))))
 574
 575 (defun gnus-cache-read-active (&optional force)
 576   "Read the cache active file."
 577   (gnus-make-directory gnus-cache-directory)
 578   (if (or (not (file-exists-p gnus-cache-active-file))
 579           (not (zerop (nth 7 (file-attributes gnus-cache-active-file))))
 580           force)
 581       ;; There is no active file, so we generate one.
 582       (gnus-cache-generate-active)
 583     ;; We simply read the active file.
 584     (save-excursion
 585       (gnus-set-work-buffer)
 586       (insert-file-contents gnus-cache-active-file)
 587       (gnus-active-to-gnus-format
 588        nil (setq gnus-cache-active-hashtb
 589                  (gnus-make-hashtable
 590                   (count-lines (point-min) (point-max)))))
 591       (setq gnus-cache-active-altered nil))))
 592
 593 (defun gnus-cache-write-active (&optional force)
 594   "Write the active hashtb to the active file."
 595   (when (or force
 596             (and gnus-cache-active-hashtb
 597                  gnus-cache-active-altered))
 598     (with-temp-file gnus-cache-active-file
 599       (mapatoms
 600        (lambda (sym)
 601          (when (and sym (boundp sym))
 602            (insert (format "%s %d %d y\n"
 603                            (symbol-name sym) (cdr (symbol-value sym))
 604                            (car (symbol-value sym))))))
 605        gnus-cache-active-hashtb))
 606     ;; Mark the active hashtb as unaltered.
 607     (setq gnus-cache-active-altered nil)))
 608
 609 (defun gnus-cache-update-active (group number &optional low)
 610   "Update the upper bound of the active info of GROUP to NUMBER.
 611 If LOW, update the lower bound instead."
 612   (let ((active (gnus-gethash group gnus-cache-active-hashtb)))
 613     (if (null active)
 614         ;; We just create a new active entry for this group.
 615         (gnus-sethash group (cons number number) gnus-cache-active-hashtb)
 616       ;; Update the lower or upper bound.
 617       (if low
 618           (setcar active number)
 619         (setcdr active number)))
 620     ;; Mark the active hashtb as altered.
 621     (setq gnus-cache-active-altered t)))
 622
 623 ;;;###autoload
 624 (defun gnus-cache-generate-active (&optional directory)
 625   "Generate the cache active file."
 626   (interactive)
 627   (let* ((top (null directory))
 628          (directory (expand-file-name (or directory gnus-cache-directory)))
 629          (files (directory-files directory 'full))
 630          (group
 631           (if top
 632               ""
 633             (string-match
 634              (concat "^" (regexp-quote
 635                           (file-name-as-directory
 636                            (expand-file-name gnus-cache-directory))))
 637              (directory-file-name directory))
 638             (nnheader-replace-chars-in-string
 639              (substring (directory-file-name directory) (match-end 0))
 640              ?/ ?.)))
 641          nums alphs)
 642     (when top
 643       (gnus-message 5 "Generating the cache active file...")
 644       (setq gnus-cache-active-hashtb (gnus-make-hashtable 123)))
 645     ;; Separate articles from all other files and directories.
 646     (while files
 647       (if (string-match "^[0-9]+$" (file-name-nondirectory (car files)))
 648           (push (string-to-int (file-name-nondirectory (pop files))) nums)
 649         (push (pop files) alphs)))
 650     ;; If we have nums, then this is probably a valid group.
 651     (when (setq nums (sort nums '<))
 652       (gnus-sethash group (cons (car nums) (gnus-last-element nums))
 653                     gnus-cache-active-hashtb))
 654     ;; Go through all the other files.
 655     (while alphs
 656       (when (and (file-directory-p (car alphs))
 657                  (not (string-match "^\\.\\.?$"
 658                                     (file-name-nondirectory (car alphs)))))
 659         ;; We descend directories.
 660         (gnus-cache-generate-active (car alphs)))
 661       (setq alphs (cdr alphs)))
 662     ;; Write the new active file.
 663     (when top
 664       (gnus-cache-write-active t)
 665       (gnus-message 5 "Generating the cache active file...done"))))
 666
 667 ;;;###autoload
 668 (defun gnus-cache-generate-nov-databases (dir)
 669   "Generate NOV files recursively starting in DIR."
 670   (interactive (list gnus-cache-directory))
 671   (gnus-cache-close)
 672   (let ((nnml-generate-active-function 'identity))
 673     (nnml-generate-nov-databases-1 dir)))
 674
 675 (defun gnus-cache-move-cache (dir)
 676   "Move the cache tree to somewhere else."
 677   (interactive "FMove the cache tree to: ")
 678   (rename-file gnus-cache-directory dir))
 679
 680 (provide 'gnus-cache)
 681
 682 ;;; gnus-cache.el ends here