cgit.sxemacs.org Git - gnus/blob - lisp/gnus-cache.el

   1 ;;; gnus-cache.el --- cache interface for Gnus
   2 ;; Copyright (C) 1995,96,97 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@ifi.uio.no>
   5 ;; Keywords: news
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  22 ;; Boston, MA 02111-1307, USA.
  23
  24 ;;; Commentary:
  25
  26 ;;; Code:
  27
  28 (eval-when-compile (require 'cl))
  29
  30 (require 'gnus)
  31 (require 'gnus-int)
  32 (require 'gnus-range)
  33 (require 'gnus-start)
  34 (eval-when-compile
  35   (require 'gnus-sum))
  36
  37 (defgroup gnus-cache nil
  38   "Cache interface."
  39   :group 'gnus)
  40
  41 (defcustom gnus-cache-directory
  42   (nnheader-concat gnus-directory "cache/")
  43   "*The directory where cached articles will be stored."
  44   :group 'gnus-cache
  45   :type 'directory)
  46
  47 (defcustom gnus-cache-active-file
  48   (concat (file-name-as-directory gnus-cache-directory) "active")
  49   "*The cache active file."
  50   :group 'gnus-cache
  51   :type 'file)
  52
  53 (defcustom gnus-cache-enter-articles '(ticked dormant)
  54   "Classes of articles to enter into the cache."
  55   :group 'gnus-cache
  56   :type '(set (const ticked) (const dormant) (const unread) (const read)))
  57
  58 (defcustom gnus-cache-remove-articles '(read)
  59   "Classes of articles to remove from the cache."
  60   :group 'gnus-cache
  61   :type '(set (const ticked) (const dormant) (const unread) (const read)))
  62
  63 (defcustom gnus-uncacheable-groups nil
  64   "*Groups that match this regexp will not be cached.
  65
  66 If you want to avoid caching your nnml groups, you could set this
  67 variable to \"^nnml\"."
  68   :group 'gnus-cache
  69   :type '(choice (const :tag "off" nil)
  70                  regexp))
  71
  72 \f
  73
  74 ;;; Internal variables.
  75
  76 (defvar gnus-cache-removable-articles nil)
  77 (defvar gnus-cache-buffer nil)
  78 (defvar gnus-cache-active-hashtb nil)
  79 (defvar gnus-cache-active-altered nil)
  80
  81 (eval-and-compile
  82   (autoload 'nnml-generate-nov-databases-1 "nnml")
  83   (autoload 'nnvirtual-find-group-art "nnvirtual"))
  84
  85 \f
  86
  87 ;;; Functions called from Gnus.
  88
  89 (defun gnus-cache-open ()
  90   "Initialize the cache."
  91   (when (or (file-exists-p gnus-cache-directory)
  92             (and gnus-use-cache
  93                  (not (eq gnus-use-cache 'passive))))
  94     (gnus-cache-read-active)))
  95
  96 ;; Complexities of byte-compiling make this kludge necessary.  Eeek.
  97 (ignore-errors
  98   (gnus-add-shutdown 'gnus-cache-close 'gnus))
  99
 100 (defun gnus-cache-close ()
 101   "Shut down the cache."
 102   (gnus-cache-write-active)
 103   (gnus-cache-save-buffers)
 104   (setq gnus-cache-active-hashtb nil))
 105
 106 (defun gnus-cache-save-buffers ()
 107   ;; save the overview buffer if it exists and has been modified
 108   ;; delete empty cache subdirectories
 109   (when gnus-cache-buffer
 110     (let ((buffer (cdr gnus-cache-buffer))
 111           (overview-file (gnus-cache-file-name
 112                           (car gnus-cache-buffer) ".overview")))
 113       ;; write the overview only if it was modified
 114       (when (buffer-modified-p buffer)
 115         (save-excursion
 116           (set-buffer buffer)
 117           (if (> (buffer-size) 0)
 118               ;; Non-empty overview, write it to a file.
 119               (gnus-write-buffer overview-file)
 120             ;; Empty overview file, remove it
 121             (when (file-exists-p overview-file)
 122               (delete-file overview-file))
 123             ;; If possible, remove group's cache subdirectory.
 124             (condition-case nil
 125                 ;; FIXME: we can detect the error type and warn the user
 126                 ;; of any inconsistencies (articles w/o nov entries?).
 127                 ;; for now, just be conservative...delete only if safe -- sj
 128                 (delete-directory (file-name-directory overview-file))
 129               (error nil)))))
 130       ;; Kill the buffer -- it's either unmodified or saved.
 131       (gnus-kill-buffer buffer)
 132       (setq gnus-cache-buffer nil))))
 133
 134 (defun gnus-cache-possibly-enter-article
 135   (group article headers ticked dormant unread &optional force)
 136   (when (and (or force (not (eq gnus-use-cache 'passive)))
 137              (numberp article)
 138              (> article 0)
 139              (vectorp headers))         ; This might be a dummy article.
 140     ;; If this is a virtual group, we find the real group.
 141     (when (gnus-virtual-group-p group)
 142       (let ((result (nnvirtual-find-group-art
 143                      (gnus-group-real-name group) article)))
 144         (setq group (car result)
 145               headers (copy-sequence headers))
 146         (mail-header-set-number headers (cdr result))))
 147     (let ((number (mail-header-number headers))
 148           file dir)
 149       (when (and number
 150                  (> number 0)           ; Reffed article.
 151                  (or force
 152                      (and (or (not gnus-uncacheable-groups)
 153                               (not (string-match
 154                                     gnus-uncacheable-groups group)))
 155                           (gnus-cache-member-of-class
 156                            gnus-cache-enter-articles ticked dormant unread)))
 157                  (not (file-exists-p (setq file (gnus-cache-file-name
 158                                                  group number)))))
 159         ;; Possibly create the cache directory.
 160         (gnus-make-directory (setq dir (file-name-directory file)))
 161         ;; Save the article in the cache.
 162         (if (file-exists-p file)
 163             t                           ; The article already is saved.
 164           (save-excursion
 165             (set-buffer nntp-server-buffer)
 166             (let ((gnus-use-cache nil))
 167               (gnus-request-article-this-buffer number group))
 168             (when (> (buffer-size) 0)
 169               (gnus-write-buffer file)
 170               (gnus-cache-change-buffer group)
 171               (set-buffer (cdr gnus-cache-buffer))
 172               (goto-char (point-max))
 173               (forward-line -1)
 174               (while (condition-case ()
 175                          (when (not (bobp))
 176                            (> (read (current-buffer)) number))
 177                        (error
 178                         ;; The line was malformed, so we just remove it!!
 179                         (gnus-delete-line)
 180                         t))
 181                 (forward-line -1))
 182               (if (bobp)
 183                   (if (not (eobp))
 184                       (progn
 185                         (beginning-of-line)
 186                         (when (< (read (current-buffer)) number)
 187                           (forward-line 1)))
 188                     (beginning-of-line))
 189                 (forward-line 1))
 190               (beginning-of-line)
 191               ;; [number subject from date id references chars lines xref]
 192               (insert (format "%s\t%s\t%s\t%s\t%s\t%s\t%s\t%s\t%s\t\n"
 193                               (mail-header-number headers)
 194                               (mail-header-subject headers)
 195                               (mail-header-from headers)
 196                               (mail-header-date headers)
 197                               (mail-header-id headers)
 198                               (or (mail-header-references headers) "")
 199                               (or (mail-header-chars headers) "")
 200                               (or (mail-header-lines headers) "")
 201                               (or (mail-header-xref headers) "")))
 202               ;; Update the active info.
 203               (set-buffer gnus-summary-buffer)
 204               (gnus-cache-update-active group number)
 205               (push article gnus-newsgroup-cached)
 206               (gnus-summary-update-secondary-mark article))
 207             t))))))
 208
 209 (defun gnus-cache-enter-remove-article (article)
 210   "Mark ARTICLE for later possible removal."
 211   (when article
 212     (push article gnus-cache-removable-articles)))
 213
 214 (defun gnus-cache-possibly-remove-articles ()
 215   "Possibly remove some of the removable articles."
 216   (if (not (gnus-virtual-group-p gnus-newsgroup-name))
 217       (gnus-cache-possibly-remove-articles-1)
 218     (let ((arts gnus-cache-removable-articles)
 219           ga)
 220       (while arts
 221         (when (setq ga (nnvirtual-find-group-art
 222                         (gnus-group-real-name gnus-newsgroup-name) (pop arts)))
 223           (let ((gnus-cache-removable-articles (list (cdr ga)))
 224                 (gnus-newsgroup-name (car ga)))
 225             (gnus-cache-possibly-remove-articles-1)))))
 226     (setq gnus-cache-removable-articles nil)))
 227
 228 (defun gnus-cache-possibly-remove-articles-1 ()
 229   "Possibly remove some of the removable articles."
 230   (unless (eq gnus-use-cache 'passive)
 231     (let ((articles gnus-cache-removable-articles)
 232           (cache-articles gnus-newsgroup-cached)
 233           article)
 234       (gnus-cache-change-buffer gnus-newsgroup-name)
 235       (while articles
 236         (when (memq (setq article (pop articles)) cache-articles)
 237           ;; The article was in the cache, so we see whether we are
 238           ;; supposed to remove it from the cache.
 239           (gnus-cache-possibly-remove-article
 240            article (memq article gnus-newsgroup-marked)
 241            (memq article gnus-newsgroup-dormant)
 242            (or (memq article gnus-newsgroup-unreads)
 243                (memq article gnus-newsgroup-unselected))))))
 244     ;; The overview file might have been modified, save it
 245     ;; safe because we're only called at group exit anyway.
 246     (gnus-cache-save-buffers)))
 247
 248 (defun gnus-cache-request-article (article group)
 249   "Retrieve ARTICLE in GROUP from the cache."
 250   (let ((file (gnus-cache-file-name group article))
 251         (buffer-read-only nil))
 252     (when (file-exists-p file)
 253       (erase-buffer)
 254       (gnus-kill-all-overlays)
 255       (insert-file-contents file)
 256       t)))
 257
 258 (defun gnus-cache-possibly-alter-active (group active)
 259   "Alter the ACTIVE info for GROUP to reflect the articles in the cache."
 260   (when gnus-cache-active-hashtb
 261     (let ((cache-active (gnus-gethash group gnus-cache-active-hashtb)))
 262       (when cache-active
 263         (when (< (car cache-active) (car active))
 264           (setcar active (car cache-active)))
 265         (when (> (cdr cache-active) (cdr active))
 266           (setcdr active (cdr cache-active)))))))
 267
 268 (defun gnus-cache-retrieve-headers (articles group &optional fetch-old)
 269   "Retrieve the headers for ARTICLES in GROUP."
 270   (let ((cached
 271          (setq gnus-newsgroup-cached (gnus-cache-articles-in-group group))))
 272     (if (not cached)
 273         ;; No cached articles here, so we just retrieve them
 274         ;; the normal way.
 275         (let ((gnus-use-cache nil))
 276           (gnus-retrieve-headers articles group fetch-old))
 277       (let ((uncached-articles (gnus-sorted-intersection
 278                                 (gnus-sorted-complement articles cached)
 279                                 articles))
 280             (cache-file (gnus-cache-file-name group ".overview"))
 281             type)
 282         ;; We first retrieve all the headers that we don't have in
 283         ;; the cache.
 284         (let ((gnus-use-cache nil))
 285           (when uncached-articles
 286             (setq type (and articles
 287                             (gnus-retrieve-headers
 288                              uncached-articles group fetch-old)))))
 289         (gnus-cache-save-buffers)
 290         ;; Then we insert the cached headers.
 291         (save-excursion
 292           (cond
 293            ((not (file-exists-p cache-file))
 294             ;; There are no cached headers.
 295             type)
 296            ((null type)
 297             ;; There were no uncached headers (or retrieval was
 298             ;; unsuccessful), so we use the cached headers exclusively.
 299             (set-buffer nntp-server-buffer)
 300             (erase-buffer)
 301             (insert-file-contents cache-file)
 302             'nov)
 303            ((eq type 'nov)
 304             ;; We have both cached and uncached NOV headers, so we
 305             ;; braid them.
 306             (gnus-cache-braid-nov group cached)
 307             type)
 308            (t
 309             ;; We braid HEADs.
 310             (gnus-cache-braid-heads group (gnus-sorted-intersection
 311                                            cached articles))
 312             type)))))))
 313
 314 (defun gnus-cache-enter-article (&optional n)
 315   "Enter the next N articles into the cache.
 316 If not given a prefix, use the process marked articles instead.
 317 Returns the list of articles entered."
 318   (interactive "P")
 319   (gnus-set-global-variables)
 320   (let ((articles (gnus-summary-work-articles n))
 321         article out)
 322     (while (setq article (pop articles))
 323       (if (natnump article)
 324           (when (gnus-cache-possibly-enter-article
 325                  gnus-newsgroup-name article
 326                  (gnus-summary-article-header article)
 327                  nil nil nil t)
 328             (push article out))
 329         (gnus-message 2 "Can't cache article %d" article))
 330       (gnus-summary-remove-process-mark article)
 331       (gnus-summary-update-secondary-mark article))
 332     (gnus-summary-next-subject 1)
 333     (gnus-summary-position-point)
 334     (nreverse out)))
 335
 336 (defun gnus-cache-remove-article (n)
 337   "Remove the next N articles from the cache.
 338 If not given a prefix, use the process marked articles instead.
 339 Returns the list of articles removed."
 340   (interactive "P")
 341   (gnus-set-global-variables)
 342   (gnus-cache-change-buffer gnus-newsgroup-name)
 343   (let ((articles (gnus-summary-work-articles n))
 344         article out)
 345     (while articles
 346       (setq article (pop articles))
 347       (when (gnus-cache-possibly-remove-article article nil nil nil t)
 348         (push article out))
 349       (gnus-summary-remove-process-mark article)
 350       (gnus-summary-update-secondary-mark article))
 351     (gnus-summary-next-subject 1)
 352     (gnus-summary-position-point)
 353     (nreverse out)))
 354
 355 (defun gnus-cached-article-p (article)
 356   "Say whether ARTICLE is cached in the current group."
 357   (memq article gnus-newsgroup-cached))
 358
 359 (defun gnus-summary-insert-cached-articles ()
 360   "Insert all the articles cached for this group into the current buffer."
 361   (interactive)
 362   (let ((cached gnus-newsgroup-cached)
 363         (gnus-verbose (max 6 gnus-verbose)))
 364     (unless cached
 365       (gnus-message 3 "No cached articles for this group"))
 366     (while cached
 367       (gnus-summary-goto-subject (pop cached) t))))
 368
 369 (defalias 'gnus-summary-limit-include-cached
 370   'gnus-summary-insert-cached-articles)
 371
 372 ;;; Internal functions.
 373
 374 (defun gnus-cache-change-buffer (group)
 375   (and gnus-cache-buffer
 376        ;; See if the current group's overview cache has been loaded.
 377        (or (string= group (car gnus-cache-buffer))
 378            ;; Another overview cache is current, save it.
 379            (gnus-cache-save-buffers)))
 380   ;; if gnus-cache buffer is nil, create it
 381   (unless gnus-cache-buffer
 382     ;; Create cache buffer
 383     (save-excursion
 384       (setq gnus-cache-buffer
 385             (cons group
 386                   (set-buffer (get-buffer-create " *gnus-cache-overview*"))))
 387       (buffer-disable-undo (current-buffer))
 388       ;; Insert the contents of this group's cache overview.
 389       (erase-buffer)
 390       (let ((file (gnus-cache-file-name group ".overview")))
 391         (when (file-exists-p file)
 392           (nnheader-insert-file-contents file)))
 393       ;; We have a fresh (empty/just loaded) buffer,
 394       ;; mark it as unmodified to save a redundant write later.
 395       (set-buffer-modified-p nil))))
 396
 397 ;; Return whether an article is a member of a class.
 398 (defun gnus-cache-member-of-class (class ticked dormant unread)
 399   (or (and ticked (memq 'ticked class))
 400       (and dormant (memq 'dormant class))
 401       (and unread (memq 'unread class))
 402       (and (not unread) (not ticked) (not dormant) (memq 'read class))))
 403
 404 (defun gnus-cache-file-name (group article)
 405   (concat (file-name-as-directory gnus-cache-directory)
 406           (file-name-as-directory
 407            (nnheader-translate-file-chars
 408             (if (gnus-use-long-file-name 'not-cache)
 409                 group
 410               (let ((group (nnheader-replace-chars-in-string group ?/ ?_)))
 411                 ;; Translate the first colon into a slash.
 412                 (when (string-match ":" group)
 413                   (aset group (match-beginning 0) ?/))
 414                 (nnheader-replace-chars-in-string group ?. ?/)))))
 415           (if (stringp article) article (int-to-string article))))
 416
 417 (defun gnus-cache-update-article (group article)
 418   "If ARTICLE is in the cache, remove it and re-enter it."
 419   (when (gnus-cache-possibly-remove-article article nil nil nil t)
 420     (let ((gnus-use-cache nil))
 421       (gnus-cache-possibly-enter-article
 422        gnus-newsgroup-name article (gnus-summary-article-header article)
 423        nil nil nil t))))
 424
 425 (defun gnus-cache-possibly-remove-article (article ticked dormant unread
 426                                                    &optional force)
 427   "Possibly remove ARTICLE from the cache."
 428   (let ((group gnus-newsgroup-name)
 429         (number article)
 430         file)
 431     ;; If this is a virtual group, we find the real group.
 432     (when (gnus-virtual-group-p group)
 433       (let ((result (nnvirtual-find-group-art
 434                      (gnus-group-real-name group) article)))
 435         (setq group (car result)
 436               number (cdr result))))
 437     (setq file (gnus-cache-file-name group number))
 438     (when (and (file-exists-p file)
 439                (or force
 440                    (gnus-cache-member-of-class
 441                     gnus-cache-remove-articles ticked dormant unread)))
 442       (save-excursion
 443         (delete-file file)
 444         (set-buffer (cdr gnus-cache-buffer))
 445         (goto-char (point-min))
 446         (when (or (looking-at (concat (int-to-string number) "\t"))
 447                   (search-forward (concat "\n" (int-to-string number) "\t")
 448                                   (point-max) t))
 449           (delete-region (progn (beginning-of-line) (point))
 450                          (progn (forward-line 1) (point)))))
 451       (setq gnus-newsgroup-cached
 452             (delq article gnus-newsgroup-cached))
 453       (gnus-summary-update-secondary-mark article)
 454       t)))
 455
 456 (defun gnus-cache-articles-in-group (group)
 457   "Return a sorted list of cached articles in GROUP."
 458   (let ((dir (file-name-directory (gnus-cache-file-name group 1)))
 459         articles)
 460     (when (file-exists-p dir)
 461       (setq articles
 462             (sort (mapcar (lambda (name) (string-to-int name))
 463                           (directory-files dir nil "^[0-9]+$" t))
 464                   '<))
 465       ;; Update the cache active file, just to synch more.
 466       (when articles
 467         (gnus-cache-update-active group (car articles) t)
 468         (gnus-cache-update-active group (car (last articles))))
 469       articles)))
 470
 471 (defun gnus-cache-braid-nov (group cached &optional file)
 472   (let ((cache-buf (get-buffer-create " *gnus-cache*"))
 473         beg end)
 474     (gnus-cache-save-buffers)
 475     (save-excursion
 476       (set-buffer cache-buf)
 477       (buffer-disable-undo (current-buffer))
 478       (erase-buffer)
 479       (insert-file-contents (or file (gnus-cache-file-name group ".overview")))
 480       (goto-char (point-min))
 481       (insert "\n")
 482       (goto-char (point-min)))
 483     (set-buffer nntp-server-buffer)
 484     (goto-char (point-min))
 485     (while cached
 486       (while (and (not (eobp))
 487                   (< (read (current-buffer)) (car cached)))
 488         (forward-line 1))
 489       (beginning-of-line)
 490       (save-excursion
 491         (set-buffer cache-buf)
 492         (if (search-forward (concat "\n" (int-to-string (car cached)) "\t")
 493                             nil t)
 494             (setq beg (progn (beginning-of-line) (point))
 495                   end (progn (end-of-line) (point)))
 496           (setq beg nil)))
 497       (when beg
 498         (insert-buffer-substring cache-buf beg end)
 499         (insert "\n"))
 500       (setq cached (cdr cached)))
 501     (kill-buffer cache-buf)))
 502
 503 (defun gnus-cache-braid-heads (group cached)
 504   (let ((cache-buf (get-buffer-create " *gnus-cache*")))
 505     (save-excursion
 506       (set-buffer cache-buf)
 507       (buffer-disable-undo (current-buffer))
 508       (erase-buffer))
 509     (set-buffer nntp-server-buffer)
 510     (goto-char (point-min))
 511     (while cached
 512       (while (and (not (eobp))
 513                   (looking-at "2.. +\\([0-9]+\\) ")
 514                   (< (progn (goto-char (match-beginning 1))
 515                             (read (current-buffer)))
 516                      (car cached)))
 517         (search-forward "\n.\n" nil 'move))
 518       (beginning-of-line)
 519       (save-excursion
 520         (set-buffer cache-buf)
 521         (erase-buffer)
 522         (insert-file-contents (gnus-cache-file-name group (car cached)))
 523         (goto-char (point-min))
 524         (insert "220 ")
 525         (princ (car cached) (current-buffer))
 526         (insert " Article retrieved.\n")
 527         (search-forward "\n\n" nil 'move)
 528         (delete-region (point) (point-max))
 529         (forward-char -1)
 530         (insert "."))
 531       (insert-buffer-substring cache-buf)
 532       (setq cached (cdr cached)))
 533     (kill-buffer cache-buf)))
 534
 535 ;;;###autoload
 536 (defun gnus-jog-cache ()
 537   "Go through all groups and put the articles into the cache.
 538
 539 Usage:
 540 $ emacs -batch -l ~/.emacs -l gnus -f gnus-jog-cache"
 541   (interactive)
 542   (let ((gnus-mark-article-hook nil)
 543         (gnus-expert-user t)
 544         (nnmail-spool-file nil)
 545         (gnus-use-dribble-file nil)
 546         (gnus-novice-user nil)
 547         (gnus-large-newsgroup nil))
 548     ;; Start Gnus.
 549     (gnus)
 550     ;; Go through all groups...
 551     (gnus-group-mark-buffer)
 552     (gnus-group-iterate nil
 553       (lambda (group)
 554         (let (gnus-auto-select-next)
 555           (gnus-summary-read-group group nil t)
 556           ;; ... and enter the articles into the cache.
 557           (when (eq major-mode 'gnus-summary-mode)
 558             (gnus-uu-mark-buffer)
 559             (gnus-cache-enter-article)
 560             (kill-buffer (current-buffer))))))))
 561
 562 (defun gnus-cache-read-active (&optional force)
 563   "Read the cache active file."
 564   (gnus-make-directory gnus-cache-directory)
 565   (if (or (not (file-exists-p gnus-cache-active-file))
 566           force)
 567       ;; There is no active file, so we generate one.
 568       (gnus-cache-generate-active)
 569     ;; We simply read the active file.
 570     (save-excursion
 571       (gnus-set-work-buffer)
 572       (insert-file-contents gnus-cache-active-file)
 573       (gnus-active-to-gnus-format
 574        nil (setq gnus-cache-active-hashtb
 575                  (gnus-make-hashtable
 576                   (count-lines (point-min) (point-max)))))
 577       (setq gnus-cache-active-altered nil))))
 578
 579 (defun gnus-cache-write-active (&optional force)
 580   "Write the active hashtb to the active file."
 581   (when (or force
 582             (and gnus-cache-active-hashtb
 583                  gnus-cache-active-altered))
 584     (nnheader-temp-write gnus-cache-active-file
 585       (mapatoms
 586        (lambda (sym)
 587          (when (and sym (boundp sym))
 588            (insert (format "%s %d %d y\n"
 589                            (symbol-name sym) (cdr (symbol-value sym))
 590                            (car (symbol-value sym))))))
 591        gnus-cache-active-hashtb))
 592     ;; Mark the active hashtb as unaltered.
 593     (setq gnus-cache-active-altered nil)))
 594
 595 (defun gnus-cache-update-active (group number &optional low)
 596   "Update the upper bound of the active info of GROUP to NUMBER.
 597 If LOW, update the lower bound instead."
 598   (let ((active (gnus-gethash group gnus-cache-active-hashtb)))
 599     (if (null active)
 600         ;; We just create a new active entry for this group.
 601         (gnus-sethash group (cons number number) gnus-cache-active-hashtb)
 602       ;; Update the lower or upper bound.
 603       (if low
 604           (setcar active number)
 605         (setcdr active number)))
 606     ;; Mark the active hashtb as altered.
 607     (setq gnus-cache-active-altered t)))
 608
 609 ;;;###autoload
 610 (defun gnus-cache-generate-active (&optional directory)
 611   "Generate the cache active file."
 612   (interactive)
 613   (let* ((top (null directory))
 614          (directory (expand-file-name (or directory gnus-cache-directory)))
 615          (files (directory-files directory 'full))
 616          (group
 617           (if top
 618               ""
 619             (string-match
 620              (concat "^" (file-name-as-directory
 621                           (expand-file-name gnus-cache-directory)))
 622              (directory-file-name directory))
 623             (nnheader-replace-chars-in-string
 624              (substring (directory-file-name directory) (match-end 0))
 625              ?/ ?.)))
 626          nums alphs)
 627     (when top
 628       (gnus-message 5 "Generating the cache active file...")
 629       (setq gnus-cache-active-hashtb (gnus-make-hashtable 123)))
 630     ;; Separate articles from all other files and directories.
 631     (while files
 632       (if (string-match "^[0-9]+$" (file-name-nondirectory (car files)))
 633           (push (string-to-int (file-name-nondirectory (pop files))) nums)
 634         (push (pop files) alphs)))
 635     ;; If we have nums, then this is probably a valid group.
 636     (when (setq nums (sort nums '<))
 637       (gnus-sethash group (cons (car nums) (gnus-last-element nums))
 638                     gnus-cache-active-hashtb))
 639     ;; Go through all the other files.
 640     (while alphs
 641       (when (and (file-directory-p (car alphs))
 642                  (not (string-match "^\\.\\.?$"
 643                                     (file-name-nondirectory (car alphs)))))
 644         ;; We descend directories.
 645         (gnus-cache-generate-active (car alphs)))
 646       (setq alphs (cdr alphs)))
 647     ;; Write the new active file.
 648     (when top
 649       (gnus-cache-write-active t)
 650       (gnus-message 5 "Generating the cache active file...done"))))
 651
 652 ;;;###autoload
 653 (defun gnus-cache-generate-nov-databases (dir)
 654   "Generate NOV files recursively starting in DIR."
 655   (interactive (list gnus-cache-directory))
 656   (gnus-cache-close)
 657   (let ((nnml-generate-active-function 'identity))
 658     (nnml-generate-nov-databases-1 dir)))
 659
 660 (defun gnus-cache-move-cache (dir)
 661   "Move the cache tree to somewhere else."
 662   (interactive "FMove the cache tree to: ")
 663   (rename-file gnus-cache-directory dir))
 664
 665 (provide 'gnus-cache)
 666
 667 ;;; gnus-cache.el ends here