cgit.sxemacs.org Git - gnus/blob - lisp/gnus-cache.el

   1 ;;; gnus-cache.el --- cache interface for Gnus
   2 ;; Copyright (C) 1995,96,97 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@ifi.uio.no>
   5 ;; Keywords: news
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  22 ;; Boston, MA 02111-1307, USA.
  23
  24 ;;; Commentary:
  25
  26 ;;; Code:
  27
  28 (eval-when-compile (require 'cl))
  29
  30 (require 'gnus)
  31 (require 'gnus-int)
  32 (require 'gnus-range)
  33 (require 'gnus-start)
  34 (eval-when-compile
  35   (require 'gnus-sum))
  36
  37 (defgroup gnus-cache nil
  38   "Cache interface."
  39   :group 'gnus)
  40
  41 (defcustom gnus-cache-directory
  42   (nnheader-concat gnus-directory "cache/")
  43   "*The directory where cached articles will be stored."
  44   :group 'gnus-cache
  45   :type 'directory)
  46
  47 (defcustom gnus-cache-active-file
  48   (concat (file-name-as-directory gnus-cache-directory) "active")
  49   "*The cache active file."
  50   :group 'gnus-cache
  51   :type 'file)
  52
  53 (defcustom gnus-cache-enter-articles '(ticked dormant)
  54   "Classes of articles to enter into the cache."
  55   :group 'gnus-cache
  56   :type '(set (const ticked) (const dormant) (const unread) (const read)))
  57
  58 (defcustom gnus-cache-remove-articles '(read)
  59   "Classes of articles to remove from the cache."
  60   :group 'gnus-cache
  61   :type '(set (const ticked) (const dormant) (const unread) (const read)))
  62
  63 (defcustom gnus-uncacheable-groups nil
  64   "*Groups that match this regexp will not be cached.
  65
  66 If you want to avoid caching your nnml groups, you could set this
  67 variable to \"^nnml\"."
  68   :group 'gnus-cache
  69   :type '(choice (const :tag "off" nil)
  70                  regexp))
  71
  72 \f
  73
  74 ;;; Internal variables.
  75
  76 (defvar gnus-cache-removable-articles nil)
  77 (defvar gnus-cache-buffer nil)
  78 (defvar gnus-cache-active-hashtb nil)
  79 (defvar gnus-cache-active-altered nil)
  80
  81 (eval-and-compile
  82   (autoload 'nnml-generate-nov-databases-1 "nnml")
  83   (autoload 'nnvirtual-find-group-art "nnvirtual"))
  84
  85 \f
  86
  87 ;;; Functions called from Gnus.
  88
  89 (defun gnus-cache-open ()
  90   "Initialize the cache."
  91   (when (or (file-exists-p gnus-cache-directory)
  92             (and gnus-use-cache
  93                  (not (eq gnus-use-cache 'passive))))
  94     (gnus-cache-read-active)))
  95
  96 ;; Complexities of byte-compiling make this kludge necessary.  Eeek.
  97 (ignore-errors
  98   (gnus-add-shutdown 'gnus-cache-close 'gnus))
  99
 100 (defun gnus-cache-close ()
 101   "Shut down the cache."
 102   (gnus-cache-write-active)
 103   (gnus-cache-save-buffers)
 104   (setq gnus-cache-active-hashtb nil))
 105
 106 (defun gnus-cache-save-buffers ()
 107   ;; save the overview buffer if it exists and has been modified
 108   ;; delete empty cache subdirectories
 109   (when gnus-cache-buffer
 110     (let ((buffer (cdr gnus-cache-buffer))
 111           (overview-file (gnus-cache-file-name
 112                           (car gnus-cache-buffer) ".overview")))
 113       ;; write the overview only if it was modified
 114       (when (buffer-modified-p buffer)
 115         (save-excursion
 116           (set-buffer buffer)
 117           (if (> (buffer-size) 0)
 118               ;; Non-empty overview, write it to a file.
 119               (gnus-write-buffer overview-file)
 120             ;; Empty overview file, remove it
 121             (when (file-exists-p overview-file)
 122               (delete-file overview-file))
 123             ;; If possible, remove group's cache subdirectory.
 124             (condition-case nil
 125                 ;; FIXME: we can detect the error type and warn the user
 126                 ;; of any inconsistencies (articles w/o nov entries?).
 127                 ;; for now, just be conservative...delete only if safe -- sj
 128                 (delete-directory (file-name-directory overview-file))
 129               (error nil)))))
 130       ;; Kill the buffer -- it's either unmodified or saved.
 131       (gnus-kill-buffer buffer)
 132       (setq gnus-cache-buffer nil))))
 133
 134 (defun gnus-cache-possibly-enter-article
 135   (group article headers ticked dormant unread &optional force)
 136   (when (and (or force (not (eq gnus-use-cache 'passive)))
 137              (numberp article)
 138              (> article 0)
 139              (vectorp headers))         ; This might be a dummy article.
 140     ;; If this is a virtual group, we find the real group.
 141     (when (gnus-virtual-group-p group)
 142       (let ((result (nnvirtual-find-group-art
 143                      (gnus-group-real-name group) article)))
 144         (setq group (car result)
 145               headers (copy-sequence headers))
 146         (mail-header-set-number headers (cdr result))))
 147     (let ((number (mail-header-number headers))
 148           file dir)
 149       (when (and number
 150                  (> number 0)           ; Reffed article.
 151                  (or force
 152                      (and (or (not gnus-uncacheable-groups)
 153                               (not (string-match
 154                                     gnus-uncacheable-groups group)))
 155                           (gnus-cache-member-of-class
 156                            gnus-cache-enter-articles ticked dormant unread)))
 157                  (not (file-exists-p (setq file (gnus-cache-file-name
 158                                                  group number)))))
 159         ;; Possibly create the cache directory.
 160         (gnus-make-directory (setq dir (file-name-directory file)))
 161         ;; Save the article in the cache.
 162         (if (file-exists-p file)
 163             t                           ; The article already is saved.
 164           (save-excursion
 165             (set-buffer nntp-server-buffer)
 166             (let ((gnus-use-cache nil))
 167               (gnus-request-article-this-buffer number group))
 168             (when (> (buffer-size) 0)
 169               (gnus-write-buffer file)
 170               (gnus-cache-change-buffer group)
 171               (set-buffer (cdr gnus-cache-buffer))
 172               (goto-char (point-max))
 173               (forward-line -1)
 174               (while (condition-case ()
 175                          (when (not (bobp))
 176                            (> (read (current-buffer)) number))
 177                        (error
 178                         ;; The line was malformed, so we just remove it!!
 179                         (gnus-delete-line)
 180                         t))
 181                 (forward-line -1))
 182               (if (bobp)
 183                   (if (not (eobp))
 184                       (progn
 185                         (beginning-of-line)
 186                         (when (< (read (current-buffer)) number)
 187                           (forward-line 1)))
 188                     (beginning-of-line))
 189                 (forward-line 1))
 190               (beginning-of-line)
 191               ;; [number subject from date id references chars lines xref]
 192               (insert (format "%s\t%s\t%s\t%s\t%s\t%s\t%s\t%s\t%s\t\n"
 193                               (mail-header-number headers)
 194                               (mail-header-subject headers)
 195                               (mail-header-from headers)
 196                               (mail-header-date headers)
 197                               (mail-header-id headers)
 198                               (or (mail-header-references headers) "")
 199                               (or (mail-header-chars headers) "")
 200                               (or (mail-header-lines headers) "")
 201                               (or (mail-header-xref headers) "")))
 202               ;; Update the active info.
 203               (set-buffer gnus-summary-buffer)
 204               (gnus-cache-update-active group number)
 205               (push article gnus-newsgroup-cached)
 206               (gnus-summary-update-secondary-mark article))
 207             t))))))
 208
 209 (defun gnus-cache-enter-remove-article (article)
 210   "Mark ARTICLE for later possible removal."
 211   (when article
 212     (push article gnus-cache-removable-articles)))
 213
 214 (defun gnus-cache-possibly-remove-articles ()
 215   "Possibly remove some of the removable articles."
 216   (if (not (gnus-virtual-group-p gnus-newsgroup-name))
 217       (gnus-cache-possibly-remove-articles-1)
 218     (let ((arts gnus-cache-removable-articles)
 219           ga)
 220       (while arts
 221         (when (setq ga (nnvirtual-find-group-art
 222                         (gnus-group-real-name gnus-newsgroup-name) (pop arts)))
 223           (let ((gnus-cache-removable-articles (list (cdr ga)))
 224                 (gnus-newsgroup-name (car ga)))
 225             (gnus-cache-possibly-remove-articles-1)))))
 226     (setq gnus-cache-removable-articles nil)))
 227
 228 (defun gnus-cache-possibly-remove-articles-1 ()
 229   "Possibly remove some of the removable articles."
 230   (unless (eq gnus-use-cache 'passive)
 231     (let ((articles gnus-cache-removable-articles)
 232           (cache-articles gnus-newsgroup-cached)
 233           article)
 234       (gnus-cache-change-buffer gnus-newsgroup-name)
 235       (while articles
 236         (when (memq (setq article (pop articles)) cache-articles)
 237           ;; The article was in the cache, so we see whether we are
 238           ;; supposed to remove it from the cache.
 239           (gnus-cache-possibly-remove-article
 240            article (memq article gnus-newsgroup-marked)
 241            (memq article gnus-newsgroup-dormant)
 242            (or (memq article gnus-newsgroup-unreads)
 243                (memq article gnus-newsgroup-unselected))))))
 244     ;; The overview file might have been modified, save it
 245     ;; safe because we're only called at group exit anyway.
 246     (gnus-cache-save-buffers)))
 247
 248 (defun gnus-cache-request-article (article group)
 249   "Retrieve ARTICLE in GROUP from the cache."
 250   (let ((file (gnus-cache-file-name group article))
 251         (buffer-read-only nil))
 252     (when (file-exists-p file)
 253       (erase-buffer)
 254       (gnus-kill-all-overlays)
 255       (insert-file-contents file)
 256       t)))
 257
 258 (defun gnus-cache-possibly-alter-active (group active)
 259   "Alter the ACTIVE info for GROUP to reflect the articles in the cache."
 260   (when gnus-cache-active-hashtb
 261     (let ((cache-active (gnus-gethash group gnus-cache-active-hashtb)))
 262       (when cache-active
 263         (when (< (car cache-active) (car active))
 264           (setcar active (car cache-active)))
 265         (when (> (cdr cache-active) (cdr active))
 266           (setcdr active (cdr cache-active)))))))
 267
 268 (defun gnus-cache-retrieve-headers (articles group &optional fetch-old)
 269   "Retrieve the headers for ARTICLES in GROUP."
 270   (let ((cached
 271          (setq gnus-newsgroup-cached (gnus-cache-articles-in-group group))))
 272     (if (not cached)
 273         ;; No cached articles here, so we just retrieve them
 274         ;; the normal way.
 275         (let ((gnus-use-cache nil))
 276           (gnus-retrieve-headers articles group fetch-old))
 277       (let ((uncached-articles (gnus-sorted-intersection
 278                                 (gnus-sorted-complement articles cached)
 279                                 articles))
 280             (cache-file (gnus-cache-file-name group ".overview"))
 281             type)
 282         ;; We first retrieve all the headers that we don't have in
 283         ;; the cache.
 284         (let ((gnus-use-cache nil))
 285           (when uncached-articles
 286             (setq type (and articles
 287                             (gnus-retrieve-headers
 288                              uncached-articles group fetch-old)))))
 289         (gnus-cache-save-buffers)
 290         ;; Then we insert the cached headers.
 291         (save-excursion
 292           (cond
 293            ((not (file-exists-p cache-file))
 294             ;; There are no cached headers.
 295             type)
 296            ((null type)
 297             ;; There were no uncached headers (or retrieval was
 298             ;; unsuccessful), so we use the cached headers exclusively.
 299             (set-buffer nntp-server-buffer)
 300             (erase-buffer)
 301             (insert-file-contents cache-file)
 302             'nov)
 303            ((eq type 'nov)
 304             ;; We have both cached and uncached NOV headers, so we
 305             ;; braid them.
 306             (gnus-cache-braid-nov group cached)
 307             type)
 308            (t
 309             ;; We braid HEADs.
 310             (gnus-cache-braid-heads group (gnus-sorted-intersection
 311                                            cached articles))
 312             type)))))))
 313
 314 (defun gnus-cache-enter-article (&optional n)
 315   "Enter the next N articles into the cache.
 316 If not given a prefix, use the process marked articles instead.
 317 Returns the list of articles entered."
 318   (interactive "P")
 319   (let ((articles (gnus-summary-work-articles n))
 320         article out)
 321     (while (setq article (pop articles))
 322       (if (natnump article)
 323           (when (gnus-cache-possibly-enter-article
 324                  gnus-newsgroup-name article
 325                  (gnus-summary-article-header article)
 326                  nil nil nil t)
 327             (push article out))
 328         (gnus-message 2 "Can't cache article %d" article))
 329       (gnus-summary-remove-process-mark article)
 330       (gnus-summary-update-secondary-mark article))
 331     (gnus-summary-next-subject 1)
 332     (gnus-summary-position-point)
 333     (nreverse out)))
 334
 335 (defun gnus-cache-remove-article (n)
 336   "Remove the next N articles from the cache.
 337 If not given a prefix, use the process marked articles instead.
 338 Returns the list of articles removed."
 339   (interactive "P")
 340   (gnus-cache-change-buffer gnus-newsgroup-name)
 341   (let ((articles (gnus-summary-work-articles n))
 342         article out)
 343     (while articles
 344       (setq article (pop articles))
 345       (when (gnus-cache-possibly-remove-article article nil nil nil t)
 346         (push article out))
 347       (gnus-summary-remove-process-mark article)
 348       (gnus-summary-update-secondary-mark article))
 349     (gnus-summary-next-subject 1)
 350     (gnus-summary-position-point)
 351     (nreverse out)))
 352
 353 (defun gnus-cached-article-p (article)
 354   "Say whether ARTICLE is cached in the current group."
 355   (memq article gnus-newsgroup-cached))
 356
 357 (defun gnus-summary-insert-cached-articles ()
 358   "Insert all the articles cached for this group into the current buffer."
 359   (interactive)
 360   (let ((cached gnus-newsgroup-cached)
 361         (gnus-verbose (max 6 gnus-verbose)))
 362     (unless cached
 363       (gnus-message 3 "No cached articles for this group"))
 364     (while cached
 365       (gnus-summary-goto-subject (pop cached) t))))
 366
 367 (defalias 'gnus-summary-limit-include-cached
 368   'gnus-summary-insert-cached-articles)
 369
 370 ;;; Internal functions.
 371
 372 (defun gnus-cache-change-buffer (group)
 373   (and gnus-cache-buffer
 374        ;; See if the current group's overview cache has been loaded.
 375        (or (string= group (car gnus-cache-buffer))
 376            ;; Another overview cache is current, save it.
 377            (gnus-cache-save-buffers)))
 378   ;; if gnus-cache buffer is nil, create it
 379   (unless gnus-cache-buffer
 380     ;; Create cache buffer
 381     (save-excursion
 382       (setq gnus-cache-buffer
 383             (cons group
 384                   (set-buffer (get-buffer-create " *gnus-cache-overview*"))))
 385       (buffer-disable-undo (current-buffer))
 386       ;; Insert the contents of this group's cache overview.
 387       (erase-buffer)
 388       (let ((file (gnus-cache-file-name group ".overview")))
 389         (when (file-exists-p file)
 390           (nnheader-insert-file-contents file)))
 391       ;; We have a fresh (empty/just loaded) buffer,
 392       ;; mark it as unmodified to save a redundant write later.
 393       (set-buffer-modified-p nil))))
 394
 395 ;; Return whether an article is a member of a class.
 396 (defun gnus-cache-member-of-class (class ticked dormant unread)
 397   (or (and ticked (memq 'ticked class))
 398       (and dormant (memq 'dormant class))
 399       (and unread (memq 'unread class))
 400       (and (not unread) (not ticked) (not dormant) (memq 'read class))))
 401
 402 (defun gnus-cache-file-name (group article)
 403   (concat (file-name-as-directory gnus-cache-directory)
 404           (file-name-as-directory
 405            (nnheader-translate-file-chars
 406             (if (gnus-use-long-file-name 'not-cache)
 407                 group
 408               (let ((group (nnheader-replace-chars-in-string group ?/ ?_)))
 409                 ;; Translate the first colon into a slash.
 410                 (when (string-match ":" group)
 411                   (aset group (match-beginning 0) ?/))
 412                 (nnheader-replace-chars-in-string group ?. ?/)))))
 413           (if (stringp article) article (int-to-string article))))
 414
 415 (defun gnus-cache-update-article (group article)
 416   "If ARTICLE is in the cache, remove it and re-enter it."
 417   (when (gnus-cache-possibly-remove-article article nil nil nil t)
 418     (let ((gnus-use-cache nil))
 419       (gnus-cache-possibly-enter-article
 420        gnus-newsgroup-name article (gnus-summary-article-header article)
 421        nil nil nil t))))
 422
 423 (defun gnus-cache-possibly-remove-article (article ticked dormant unread
 424                                                    &optional force)
 425   "Possibly remove ARTICLE from the cache."
 426   (let ((group gnus-newsgroup-name)
 427         (number article)
 428         file)
 429     ;; If this is a virtual group, we find the real group.
 430     (when (gnus-virtual-group-p group)
 431       (let ((result (nnvirtual-find-group-art
 432                      (gnus-group-real-name group) article)))
 433         (setq group (car result)
 434               number (cdr result))))
 435     (setq file (gnus-cache-file-name group number))
 436     (when (and (file-exists-p file)
 437                (or force
 438                    (gnus-cache-member-of-class
 439                     gnus-cache-remove-articles ticked dormant unread)))
 440       (save-excursion
 441         (delete-file file)
 442         (set-buffer (cdr gnus-cache-buffer))
 443         (goto-char (point-min))
 444         (when (or (looking-at (concat (int-to-string number) "\t"))
 445                   (search-forward (concat "\n" (int-to-string number) "\t")
 446                                   (point-max) t))
 447           (delete-region (progn (beginning-of-line) (point))
 448                          (progn (forward-line 1) (point)))))
 449       (setq gnus-newsgroup-cached
 450             (delq article gnus-newsgroup-cached))
 451       (gnus-summary-update-secondary-mark article)
 452       t)))
 453
 454 (defun gnus-cache-articles-in-group (group)
 455   "Return a sorted list of cached articles in GROUP."
 456   (let ((dir (file-name-directory (gnus-cache-file-name group 1)))
 457         articles)
 458     (when (file-exists-p dir)
 459       (setq articles
 460             (sort (mapcar (lambda (name) (string-to-int name))
 461                           (directory-files dir nil "^[0-9]+$" t))
 462                   '<))
 463       ;; Update the cache active file, just to synch more.
 464       (when articles
 465         (gnus-cache-update-active group (car articles) t)
 466         (gnus-cache-update-active group (car (last articles))))
 467       articles)))
 468
 469 (defun gnus-cache-braid-nov (group cached &optional file)
 470   (let ((cache-buf (get-buffer-create " *gnus-cache*"))
 471         beg end)
 472     (gnus-cache-save-buffers)
 473     (save-excursion
 474       (set-buffer cache-buf)
 475       (buffer-disable-undo (current-buffer))
 476       (erase-buffer)
 477       (insert-file-contents (or file (gnus-cache-file-name group ".overview")))
 478       (goto-char (point-min))
 479       (insert "\n")
 480       (goto-char (point-min)))
 481     (set-buffer nntp-server-buffer)
 482     (goto-char (point-min))
 483     (while cached
 484       (while (and (not (eobp))
 485                   (< (read (current-buffer)) (car cached)))
 486         (forward-line 1))
 487       (beginning-of-line)
 488       (save-excursion
 489         (set-buffer cache-buf)
 490         (if (search-forward (concat "\n" (int-to-string (car cached)) "\t")
 491                             nil t)
 492             (setq beg (progn (beginning-of-line) (point))
 493                   end (progn (end-of-line) (point)))
 494           (setq beg nil)))
 495       (when beg
 496         (insert-buffer-substring cache-buf beg end)
 497         (insert "\n"))
 498       (setq cached (cdr cached)))
 499     (kill-buffer cache-buf)))
 500
 501 (defun gnus-cache-braid-heads (group cached)
 502   (let ((cache-buf (get-buffer-create " *gnus-cache*")))
 503     (save-excursion
 504       (set-buffer cache-buf)
 505       (buffer-disable-undo (current-buffer))
 506       (erase-buffer))
 507     (set-buffer nntp-server-buffer)
 508     (goto-char (point-min))
 509     (while cached
 510       (while (and (not (eobp))
 511                   (looking-at "2.. +\\([0-9]+\\) ")
 512                   (< (progn (goto-char (match-beginning 1))
 513                             (read (current-buffer)))
 514                      (car cached)))
 515         (search-forward "\n.\n" nil 'move))
 516       (beginning-of-line)
 517       (save-excursion
 518         (set-buffer cache-buf)
 519         (erase-buffer)
 520         (insert-file-contents (gnus-cache-file-name group (car cached)))
 521         (goto-char (point-min))
 522         (insert "220 ")
 523         (princ (car cached) (current-buffer))
 524         (insert " Article retrieved.\n")
 525         (search-forward "\n\n" nil 'move)
 526         (delete-region (point) (point-max))
 527         (forward-char -1)
 528         (insert "."))
 529       (insert-buffer-substring cache-buf)
 530       (setq cached (cdr cached)))
 531     (kill-buffer cache-buf)))
 532
 533 ;;;###autoload
 534 (defun gnus-jog-cache ()
 535   "Go through all groups and put the articles into the cache.
 536
 537 Usage:
 538 $ emacs -batch -l ~/.emacs -l gnus -f gnus-jog-cache"
 539   (interactive)
 540   (let ((gnus-mark-article-hook nil)
 541         (gnus-expert-user t)
 542         (nnmail-spool-file nil)
 543         (gnus-use-dribble-file nil)
 544         (gnus-novice-user nil)
 545         (gnus-large-newsgroup nil))
 546     ;; Start Gnus.
 547     (gnus)
 548     ;; Go through all groups...
 549     (gnus-group-mark-buffer)
 550     (gnus-group-iterate nil
 551       (lambda (group)
 552         (let (gnus-auto-select-next)
 553           (gnus-summary-read-group group nil t)
 554           ;; ... and enter the articles into the cache.
 555           (when (eq major-mode 'gnus-summary-mode)
 556             (gnus-uu-mark-buffer)
 557             (gnus-cache-enter-article)
 558             (kill-buffer (current-buffer))))))))
 559
 560 (defun gnus-cache-read-active (&optional force)
 561   "Read the cache active file."
 562   (gnus-make-directory gnus-cache-directory)
 563   (if (or (not (file-exists-p gnus-cache-active-file))
 564           (not (zerop (nth 7 (file-attributes gnus-cache-active-file))))
 565           force)
 566       ;; There is no active file, so we generate one.
 567       (gnus-cache-generate-active)
 568     ;; We simply read the active file.
 569     (save-excursion
 570       (gnus-set-work-buffer)
 571       (insert-file-contents gnus-cache-active-file)
 572       (gnus-active-to-gnus-format
 573        nil (setq gnus-cache-active-hashtb
 574                  (gnus-make-hashtable
 575                   (count-lines (point-min) (point-max)))))
 576       (setq gnus-cache-active-altered nil))))
 577
 578 (defun gnus-cache-write-active (&optional force)
 579   "Write the active hashtb to the active file."
 580   (when (or force
 581             (and gnus-cache-active-hashtb
 582                  gnus-cache-active-altered))
 583     (nnheader-temp-write gnus-cache-active-file
 584       (mapatoms
 585        (lambda (sym)
 586          (when (and sym (boundp sym))
 587            (insert (format "%s %d %d y\n"
 588                            (symbol-name sym) (cdr (symbol-value sym))
 589                            (car (symbol-value sym))))))
 590        gnus-cache-active-hashtb))
 591     ;; Mark the active hashtb as unaltered.
 592     (setq gnus-cache-active-altered nil)))
 593
 594 (defun gnus-cache-update-active (group number &optional low)
 595   "Update the upper bound of the active info of GROUP to NUMBER.
 596 If LOW, update the lower bound instead."
 597   (let ((active (gnus-gethash group gnus-cache-active-hashtb)))
 598     (if (null active)
 599         ;; We just create a new active entry for this group.
 600         (gnus-sethash group (cons number number) gnus-cache-active-hashtb)
 601       ;; Update the lower or upper bound.
 602       (if low
 603           (setcar active number)
 604         (setcdr active number)))
 605     ;; Mark the active hashtb as altered.
 606     (setq gnus-cache-active-altered t)))
 607
 608 ;;;###autoload
 609 (defun gnus-cache-generate-active (&optional directory)
 610   "Generate the cache active file."
 611   (interactive)
 612   (let* ((top (null directory))
 613          (directory (expand-file-name (or directory gnus-cache-directory)))
 614          (files (directory-files directory 'full))
 615          (group
 616           (if top
 617               ""
 618             (string-match
 619              (concat "^" (file-name-as-directory
 620                           (expand-file-name gnus-cache-directory)))
 621              (directory-file-name directory))
 622             (nnheader-replace-chars-in-string
 623              (substring (directory-file-name directory) (match-end 0))
 624              ?/ ?.)))
 625          nums alphs)
 626     (when top
 627       (gnus-message 5 "Generating the cache active file...")
 628       (setq gnus-cache-active-hashtb (gnus-make-hashtable 123)))
 629     ;; Separate articles from all other files and directories.
 630     (while files
 631       (if (string-match "^[0-9]+$" (file-name-nondirectory (car files)))
 632           (push (string-to-int (file-name-nondirectory (pop files))) nums)
 633         (push (pop files) alphs)))
 634     ;; If we have nums, then this is probably a valid group.
 635     (when (setq nums (sort nums '<))
 636       (gnus-sethash group (cons (car nums) (gnus-last-element nums))
 637                     gnus-cache-active-hashtb))
 638     ;; Go through all the other files.
 639     (while alphs
 640       (when (and (file-directory-p (car alphs))
 641                  (not (string-match "^\\.\\.?$"
 642                                     (file-name-nondirectory (car alphs)))))
 643         ;; We descend directories.
 644         (gnus-cache-generate-active (car alphs)))
 645       (setq alphs (cdr alphs)))
 646     ;; Write the new active file.
 647     (when top
 648       (gnus-cache-write-active t)
 649       (gnus-message 5 "Generating the cache active file...done"))))
 650
 651 ;;;###autoload
 652 (defun gnus-cache-generate-nov-databases (dir)
 653   "Generate NOV files recursively starting in DIR."
 654   (interactive (list gnus-cache-directory))
 655   (gnus-cache-close)
 656   (let ((nnml-generate-active-function 'identity))
 657     (nnml-generate-nov-databases-1 dir)))
 658
 659 (defun gnus-cache-move-cache (dir)
 660   "Move the cache tree to somewhere else."
 661   (interactive "FMove the cache tree to: ")
 662   (rename-file gnus-cache-directory dir))
 663
 664 (provide 'gnus-cache)
 665
 666 ;;; gnus-cache.el ends here