cgit.sxemacs.org Git - gnus/blob - lisp/gnus-async.el

   1 ;;; gnus-async.el --- asynchronous support for Gnus
   2
   3 ;; Copyright (C) 1996, 1997, 1998, 1999, 2000, 2002, 2003, 2004,
   4 ;;   2005 Free Software Foundation, Inc.
   5
   6 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   7 ;; Keywords: news
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  24 ;; Boston, MA 02110-1301, USA.
  25
  26 ;;; Commentary:
  27
  28 ;;; Code:
  29
  30 (eval-when-compile (require 'cl))
  31
  32 (require 'gnus)
  33 (require 'gnus-sum)
  34 (require 'nntp)
  35
  36 (eval-when-compile
  37   (when (featurep 'xemacs)
  38     (require 'timer-funcs)))
  39
  40 (defgroup gnus-asynchronous nil
  41   "Support for asynchronous operations."
  42   :group 'gnus)
  43
  44 (defcustom gnus-use-article-prefetch 30
  45   "*If non-nil, prefetch articles in groups that allow this.
  46 If a number, prefetch only that many articles forward;
  47 if t, prefetch as many articles as possible."
  48   :group 'gnus-asynchronous
  49   :type '(choice (const :tag "off" nil)
  50                  (const :tag "all" t)
  51                  (integer :tag "some" 0)))
  52
  53 (defcustom gnus-asynchronous nil
  54   "*If nil, inhibit all Gnus asynchronicity.
  55 If non-nil, let the other asynch variables be heeded."
  56   :group 'gnus-asynchronous
  57   :type 'boolean)
  58
  59 (defcustom gnus-prefetched-article-deletion-strategy '(read exit)
  60   "List of symbols that say when to remove articles from the prefetch buffer.
  61 Possible values in this list are `read', which means that
  62 articles are removed as they are read, and `exit', which means
  63 that all articles belonging to a group are removed on exit
  64 from that group."
  65   :group 'gnus-asynchronous
  66   :type '(set (const read) (const exit)))
  67
  68 (defcustom gnus-use-header-prefetch nil
  69   "*If non-nil, prefetch the headers to the next group."
  70   :group 'gnus-asynchronous
  71   :type 'boolean)
  72
  73 (defcustom gnus-async-prefetch-article-p 'gnus-async-unread-p
  74   "Function called to say whether an article should be prefetched or not.
  75 The function is called with one parameter -- the article data.
  76 It should return non-nil if the article is to be prefetched."
  77   :group 'gnus-asynchronous
  78   :type 'function)
  79
  80 ;;; Internal variables.
  81
  82 (defvar gnus-async-prefetch-article-buffer " *Async Prefetch Article*")
  83 (defvar gnus-async-article-alist nil)
  84 (defvar gnus-async-article-semaphore '(nil))
  85 (defvar gnus-async-fetch-list nil)
  86 (defvar gnus-async-hashtb nil)
  87 (defvar gnus-async-current-prefetch-group nil)
  88 (defvar gnus-async-current-prefetch-article nil)
  89 (defvar gnus-async-timer nil)
  90
  91 (defvar gnus-async-prefetch-headers-buffer " *Async Prefetch Headers*")
  92 (defvar gnus-async-header-prefetched nil)
  93
  94 ;;; Utility functions.
  95
  96 (defun gnus-group-asynchronous-p (group)
  97   "Say whether GROUP is fetched from a server that supports asynchronicity."
  98   (gnus-asynchronous-p (gnus-find-method-for-group group)))
  99
 100 ;;; Somewhat bogus semaphores.
 101
 102 (defun gnus-async-get-semaphore (semaphore)
 103   "Wait until SEMAPHORE is released."
 104   (while (/= (length (nconc (symbol-value semaphore) (list nil))) 2)
 105     (sleep-for 1)))
 106
 107 (defun gnus-async-release-semaphore (semaphore)
 108   "Release SEMAPHORE."
 109   (setcdr (symbol-value semaphore) nil))
 110
 111 (defmacro gnus-async-with-semaphore (&rest forms)
 112   `(unwind-protect
 113        (progn
 114          (gnus-async-get-semaphore 'gnus-async-article-semaphore)
 115          ,@forms)
 116      (gnus-async-release-semaphore 'gnus-async-article-semaphore)))
 117
 118 (put 'gnus-async-with-semaphore 'lisp-indent-function 0)
 119 (put 'gnus-async-with-semaphore 'edebug-form-spec '(body))
 120
 121 ;;;
 122 ;;; Article prefetch
 123 ;;;
 124
 125 (gnus-add-shutdown 'gnus-async-close 'gnus)
 126 (defun gnus-async-close ()
 127   (gnus-kill-buffer gnus-async-prefetch-article-buffer)
 128   (gnus-kill-buffer gnus-async-prefetch-headers-buffer)
 129   (setq gnus-async-hashtb nil
 130         gnus-async-article-alist nil
 131         gnus-async-header-prefetched nil))
 132
 133 (defun gnus-async-set-buffer ()
 134   (nnheader-set-temp-buffer gnus-async-prefetch-article-buffer t)
 135   (unless gnus-async-hashtb
 136     (setq gnus-async-hashtb (gnus-make-hashtable 1023))))
 137
 138 (defun gnus-async-halt-prefetch ()
 139   "Stop prefetching."
 140   (setq gnus-async-fetch-list nil))
 141
 142 (defun gnus-async-prefetch-next (group article summary)
 143   "Possibly prefetch several articles starting with the article after ARTICLE."
 144   (when (and (gnus-buffer-live-p summary)
 145              gnus-asynchronous
 146              (gnus-group-asynchronous-p group))
 147     (save-excursion
 148       (set-buffer gnus-summary-buffer)
 149       (let ((next (caadr (gnus-data-find-list article))))
 150         (when next
 151           (if (not (fboundp 'run-with-idle-timer))
 152               ;; This is either an older Emacs or XEmacs, so we
 153               ;; do this, which leads to slightly slower article
 154               ;; buffer display.
 155               (gnus-async-prefetch-article group next summary)
 156             (when gnus-async-timer
 157               (ignore-errors
 158                 (nnheader-cancel-timer 'gnus-async-timer)))
 159             (setq gnus-async-timer
 160                   (run-with-idle-timer
 161                    0.1 nil 'gnus-async-prefetch-article
 162                    group next summary))))))))
 163
 164 (defun gnus-async-prefetch-article (group article summary &optional next)
 165   "Possibly prefetch several articles starting with ARTICLE."
 166   (if (not (gnus-buffer-live-p summary))
 167       (gnus-async-with-semaphore
 168         (setq gnus-async-fetch-list nil))
 169     (when (and gnus-asynchronous
 170                (gnus-alive-p))
 171       (when next
 172         (gnus-async-with-semaphore
 173           (pop gnus-async-fetch-list)))
 174       (let ((do-fetch next)
 175             (do-message t))             ;(eq major-mode 'gnus-summary-mode)))
 176         (when (and (gnus-group-asynchronous-p group)
 177                    (gnus-buffer-live-p summary)
 178                    (or (not next)
 179                        gnus-async-fetch-list))
 180           (gnus-async-with-semaphore
 181             (unless next
 182               (setq do-fetch (not gnus-async-fetch-list))
 183               ;; Nix out any outstanding requests.
 184               (setq gnus-async-fetch-list nil)
 185               ;; Fill in the new list.
 186               (let ((n gnus-use-article-prefetch)
 187                     (data (gnus-data-find-list article))
 188                     d)
 189                 (while (and (setq d (pop data))
 190                             (if (numberp n)
 191                                 (natnump (decf n))
 192                               n))
 193                   (unless (or (gnus-async-prefetched-article-entry
 194                                group (setq article (gnus-data-number d)))
 195                               (not (natnump article))
 196                               (not (funcall gnus-async-prefetch-article-p d)))
 197                     ;; Not already fetched -- so we add it to the list.
 198                     (push article gnus-async-fetch-list)))
 199                 (setq gnus-async-fetch-list
 200                       (nreverse gnus-async-fetch-list))))
 201
 202             (when do-fetch
 203               (setq article (car gnus-async-fetch-list))))
 204
 205           (when (and do-fetch article)
 206             ;; We want to fetch some more articles.
 207             (save-excursion
 208               (set-buffer summary)
 209               (let (mark)
 210                 (gnus-async-set-buffer)
 211                 (goto-char (point-max))
 212                 (setq mark (point-marker))
 213                 (let ((nnheader-callback-function
 214                        (gnus-make-async-article-function
 215                         group article mark summary next))
 216                       (nntp-server-buffer
 217                        (get-buffer gnus-async-prefetch-article-buffer)))
 218                   (when do-message
 219                     (gnus-message 9 "Prefetching article %d in group %s"
 220                                   article group))
 221                   (setq gnus-async-current-prefetch-group group)
 222                   (setq gnus-async-current-prefetch-article article)
 223                   (gnus-request-article article group))))))))))
 224
 225 (defun gnus-make-async-article-function (group article mark summary next)
 226   "Return a callback function."
 227   `(lambda (arg)
 228      (gnus-async-article-callback arg ,group ,article ,mark ,summary ,next)))
 229
 230 (defun gnus-async-article-callback (arg group article mark summary next)
 231   "Function called when an async article is done being fetched."
 232   (save-excursion
 233     (setq gnus-async-current-prefetch-article nil)
 234     (when arg
 235       (gnus-async-set-buffer)
 236       (gnus-async-with-semaphore
 237         (setq
 238          gnus-async-article-alist
 239          (cons (list (intern (format "%s-%d" group article)
 240                              gnus-async-hashtb)
 241                      mark (set-marker (make-marker) (point-max))
 242                      group article)
 243                gnus-async-article-alist))))
 244     (if (not (gnus-buffer-live-p summary))
 245         (gnus-async-with-semaphore
 246           (setq gnus-async-fetch-list nil))
 247       (gnus-async-prefetch-article group next summary t))))
 248
 249 (defun gnus-async-unread-p (data)
 250   "Return non-nil if DATA represents an unread article."
 251   (gnus-data-unread-p data))
 252
 253 (defun gnus-async-request-fetched-article (group article buffer)
 254   "See whether we have ARTICLE from GROUP and put it in BUFFER."
 255   (when (numberp article)
 256     (when (and (equal group gnus-async-current-prefetch-group)
 257                (eq article gnus-async-current-prefetch-article))
 258       (gnus-async-wait-for-article article))
 259     (let ((entry (gnus-async-prefetched-article-entry group article)))
 260       (when entry
 261         (save-excursion
 262           (gnus-async-set-buffer)
 263           (copy-to-buffer buffer (cadr entry) (caddr entry))
 264           ;; Remove the read article from the prefetch buffer.
 265           (when (memq 'read gnus-prefetched-article-deletion-strategy)
 266             (gnus-async-delete-prefetched-entry entry))
 267           t)))))
 268
 269 (defun gnus-async-wait-for-article (article)
 270   "Wait until ARTICLE is no longer the currently-being-fetched article."
 271   (save-excursion
 272     (gnus-async-set-buffer)
 273     (let ((proc (nntp-find-connection (current-buffer)))
 274           (nntp-server-buffer (current-buffer))
 275           (nntp-have-messaged nil)
 276           (tries 0))
 277       (when proc
 278         (condition-case nil
 279             ;; FIXME: we could stop waiting after some
 280             ;; timeout, but this is the wrong place to do it.
 281             ;; rather than checking time-spent-waiting, we
 282             ;; should check time-since-last-output, which
 283             ;; needs to be done in nntp.el.
 284             (while (eq article gnus-async-current-prefetch-article)
 285               (incf tries)
 286               (when (nntp-accept-process-output proc)
 287                 (setq tries 0))
 288               (when (and (not nntp-have-messaged)
 289                          (= tries 3))
 290                 (gnus-message 5 "Waiting for async article...")
 291                 (setq nntp-have-messaged t)))
 292           (quit
 293            ;; if the user interrupted on a slow/hung connection,
 294            ;; do something friendly.
 295            (when (> tries 3)
 296              (setq gnus-async-current-prefetch-article nil))
 297            (signal 'quit nil)))
 298         (when nntp-have-messaged
 299           (gnus-message 5 ""))))))
 300
 301 (defun gnus-async-delete-prefetched-entry (entry)
 302   "Delete ENTRY from buffer and alist."
 303   (ignore-errors
 304     (delete-region (cadr entry) (caddr entry))
 305     (set-marker (cadr entry) nil)
 306     (set-marker (caddr entry) nil))
 307   (gnus-async-with-semaphore
 308     (setq gnus-async-article-alist
 309           (delq entry gnus-async-article-alist))))
 310
 311 (defun gnus-async-prefetch-remove-group (group)
 312   "Remove all articles belonging to GROUP from the prefetch buffer."
 313   (when (and (gnus-group-asynchronous-p group)
 314              (memq 'exit gnus-prefetched-article-deletion-strategy))
 315     (save-excursion
 316       (gnus-async-set-buffer)
 317       (dolist (entry gnus-async-article-alist)
 318         (when (equal group (nth 3 entry))
 319           (gnus-async-delete-prefetched-entry entry))))))
 320
 321 (defun gnus-async-prefetched-article-entry (group article)
 322   "Return the entry for ARTICLE in GROUP iff it has been prefetched."
 323   (let ((entry (save-excursion
 324                  (gnus-async-set-buffer)
 325                  (assq (intern (format "%s-%d" group article)
 326                                gnus-async-hashtb)
 327                        gnus-async-article-alist))))
 328     ;; Perhaps something has emptied the buffer?
 329     (if (and entry
 330              (= (cadr entry) (caddr entry)))
 331         (progn
 332           (ignore-errors
 333             (set-marker (cadr entry) nil)
 334             (set-marker (caddr entry) nil))
 335           (setq gnus-async-article-alist
 336                 (delq entry gnus-async-article-alist))
 337           nil)
 338       entry)))
 339
 340 ;;;
 341 ;;; Header prefetch
 342 ;;;
 343
 344 (defun gnus-async-prefetch-headers (group)
 345   "Prefetch the headers for group GROUP."
 346   (save-excursion
 347     (let (unread)
 348       (when (and gnus-use-header-prefetch
 349                  gnus-asynchronous
 350                  (gnus-group-asynchronous-p group)
 351                  (listp gnus-async-header-prefetched)
 352                  (setq unread (gnus-list-of-unread-articles group)))
 353         ;; Mark that a fetch is in progress.
 354         (setq gnus-async-header-prefetched t)
 355         (nnheader-set-temp-buffer gnus-async-prefetch-headers-buffer t)
 356         (erase-buffer)
 357         (let ((nntp-server-buffer (current-buffer))
 358               (nnheader-callback-function
 359                `(lambda (arg)
 360                   (setq gnus-async-header-prefetched
 361                         ,(cons group unread)))))
 362           (gnus-retrieve-headers unread group gnus-fetch-old-headers))))))
 363
 364 (defun gnus-async-retrieve-fetched-headers (articles group)
 365   "See whether we have prefetched headers."
 366   (when (and gnus-use-header-prefetch
 367              (gnus-group-asynchronous-p group)
 368              (listp gnus-async-header-prefetched)
 369              (equal group (car gnus-async-header-prefetched))
 370              (equal articles (cdr gnus-async-header-prefetched)))
 371     (save-excursion
 372       (nnheader-set-temp-buffer gnus-async-prefetch-headers-buffer t)
 373       (nntp-decode-text)
 374       (copy-to-buffer nntp-server-buffer (point-min) (point-max))
 375       (erase-buffer)
 376       (setq gnus-async-header-prefetched nil)
 377       t)))
 378
 379 (provide 'gnus-async)
 380
 381 ;;; arch-tag: fee61de5-3ea2-4de6-8578-2f90ce89391d
 382 ;;; gnus-async.el ends here