cgit.sxemacs.org Git - gnus/blob - lisp/format-spec.el

   1 ;;; format-spec.el --- functions for formatting arbitrary formatting strings
   2
   3 ;; Copyright (C) 1999, 2000, 2001, 2002, 2003, 2004,
   4 ;;   2005, 2006, 2007 Free Software Foundation, Inc.
   5
   6 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   7 ;; Keywords: tools
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 3, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  24 ;; Boston, MA 02110-1301, USA.
  25
  26 ;;; Commentary:
  27
  28 ;;; Code:
  29
  30 (eval-when-compile (require 'cl))
  31
  32 (defun format-spec (format specification)
  33   "Return a string based on FORMAT and SPECIFICATION.
  34 FORMAT is a string containing `format'-like specs like \"bash %u %k\",
  35 while SPECIFICATION is an alist mapping from format spec characters
  36 to values.  Any text properties on a %-spec itself are propagated to
  37 the text that it generates."
  38   (with-temp-buffer
  39     (insert format)
  40     (goto-char (point-min))
  41     (while (search-forward "%" nil t)
  42       (cond
  43        ;; Quoted percent sign.
  44        ((eq (char-after) ?%)
  45         (delete-char 1))
  46        ;; Valid format spec.
  47        ((looking-at "\\([-0-9.]*\\)\\([a-zA-Z]\\)")
  48         (let* ((num (match-string 1))
  49                (spec (string-to-char (match-string 2)))
  50                (val (cdr (assq spec specification))))
  51           (unless val
  52             (error "Invalid format character: `%%%c'" spec))
  53           ;; Pad result to desired length.
  54           (let ((text (format (concat "%" num "s") val)))
  55             ;; Insert first, to preserve text properties.
  56             (insert-and-inherit text)
  57             ;; Delete the specifier body.
  58             (delete-region (+ (match-beginning 0) (length text))
  59                            (+ (match-end 0) (length text)))
  60             ;; Delete the percent sign.
  61             (delete-region (1- (match-beginning 0)) (match-beginning 0)))))
  62        ;; Signal an error on bogus format strings.
  63        (t
  64         (error "Invalid format string"))))
  65     (buffer-string)))
  66
  67 (defun format-spec-make (&rest pairs)
  68   "Return an alist suitable for use in `format-spec' based on PAIRS.
  69 PAIRS is a list where every other element is a character and a value,
  70 starting with a character."
  71   (let (alist)
  72     (while pairs
  73       (unless (cdr pairs)
  74         (error "Invalid list of pairs"))
  75       (push (cons (car pairs) (cadr pairs)) alist)
  76       (setq pairs (cddr pairs)))
  77     (nreverse alist)))
  78
  79 (provide 'format-spec)
  80
  81 ;;; arch-tag: c22d49cf-d167-445d-b7f1-2504d4173f53
  82 ;;; format-spec.el ends here