cgit.sxemacs.org Git - gnus/blob - lisp/dgnushack.el

   1 ;;; dgnushack.el --- a hack to set the load path for byte-compiling
   2 ;; Copyright (C) 1994, 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2003,
   3 ;; 2004, 2005, 2006, 2007, 2008, 2009, 2010
   4 ;;        Free Software Foundation, Inc.
   5
   6 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   7 ;; Version: 4.19
   8 ;; Keywords: news, path
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 3, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  25 ;; Boston, MA 02110-1301, USA.
  26
  27 ;;; Commentary:
  28
  29 ;;; Code:
  30
  31 (defvar dgnushack-default-load-path (copy-sequence load-path))
  32
  33 (defalias 'facep 'ignore)
  34
  35 (require 'cl)
  36
  37 (defvar srcdir (or (getenv "srcdir") "."))
  38 (defvar loaddir (and load-file-name (file-name-directory load-file-name)))
  39
  40 (defun my-getenv (str)
  41   (let ((val (getenv str)))
  42     (if (equal val "no") nil val)))
  43
  44 (if (my-getenv "lispdir")
  45     (push (my-getenv "lispdir") load-path))
  46
  47 (push (or (my-getenv "URLDIR") (expand-file-name "../../url/lisp/" loaddir))
  48       load-path)
  49
  50 (push (or (my-getenv "W3DIR") (expand-file-name "../../w3/lisp/" loaddir))
  51       load-path)
  52
  53 ;(push "/usr/share/emacs/site-lisp" load-path)
  54
  55 ;; If we are building w3 in a different directory than the source
  56 ;; directory, we must read *.el from source directory and write *.elc
  57 ;; into the building directory.  For that, we define this function
  58 ;; before loading bytecomp.  Bytecomp doesn't overwrite this function.
  59 (defun byte-compile-dest-file (filename)
  60   "Convert an Emacs Lisp source file name to a compiled file name.
  61  In addition, remove directory name part from FILENAME."
  62   (setq filename (byte-compiler-base-file-name filename))
  63   (setq filename (file-name-sans-versions filename))
  64   (setq filename (file-name-nondirectory filename))
  65   (if (eq system-type 'windows-nt)
  66       (setq filename (downcase filename)))
  67   (cond ((eq system-type 'vax-vms)
  68          (concat (substring filename 0 (string-match ";" filename)) "c"))
  69         ((string-match emacs-lisp-file-regexp filename)
  70          (concat (substring filename 0 (match-beginning 0)) ".elc"))
  71         (t (concat filename ".elc"))))
  72
  73 (require 'bytecomp)
  74 ;; To avoid having defsubsts and inlines happen.
  75 ;(if (featurep 'xemacs)
  76 ;    (require 'byte-optimize)
  77 ;  (require 'byte-opt))
  78 ;(defun byte-optimize-inline-handler (form)
  79 ;  "byte-optimize-handler for the `inline' special-form."
  80 ;  (cons 'progn (cdr form)))
  81 ;(defalias 'byte-compile-file-form-defsubst 'byte-compile-file-form-defun)
  82
  83 (when (and (not (featurep 'xemacs))
  84            (= emacs-major-version 21)
  85            (>= emacs-minor-version 3)
  86            (condition-case code
  87                (let ((byte-compile-error-on-warn t))
  88                  (byte-optimize-form (quote (pop x)) t)
  89                  nil)
  90              (error (string-match "called for effect"
  91                                   (error-message-string code)))))
  92   (defadvice byte-optimize-form-code-walker (around silence-warn-for-pop
  93                                                     (form for-effect)
  94                                                     activate)
  95     "Silence the warning \"...called for effect\" for the `pop' form.
  96 It is effective only when the `pop' macro is defined by cl.el rather
  97 than subr.el."
  98     (let (tmp)
  99       (if (and (eq (car-safe form) 'car)
 100                for-effect
 101                (setq tmp (get 'car 'side-effect-free))
 102                (not byte-compile-delete-errors)
 103                (not (eq tmp 'error-free))
 104                (eq (car-safe (cadr form)) 'prog1)
 105                (let ((var (cadr (cadr form)))
 106                      (last (nth 2 (cadr form))))
 107                  (and (symbolp var)
 108                       (null (nthcdr 3 (cadr form)))
 109                       (eq (car-safe last) 'setq)
 110                       (eq (cadr last) var)
 111                       (eq (car-safe (nth 2 last)) 'cdr)
 112                       (eq (cadr (nth 2 last)) var))))
 113           (progn
 114             (put 'car 'side-effect-free 'error-free)
 115             (unwind-protect
 116                 ad-do-it
 117               (put 'car 'side-effect-free tmp)))
 118         ad-do-it))))
 119
 120 (when (and (not (featurep 'xemacs))
 121            (byte-optimize-form
 122             '(and (> 0 1)
 123                   (message "This should not appear in the byte-code."))
 124             t))
 125   (defadvice byte-optimize-form-code-walker
 126     (around fix-bug-in-and/or-forms (form for-effect) activate)
 127     "Optimize the rest of the and/or forms.
 128 It has been fixed in XEmacs before releasing 21.4 and also has been
 129 fixed in Emacs 22."
 130     (if (and for-effect (memq (car-safe form) '(and or)))
 131         (let ((fn (car form))
 132               (backwards (reverse (cdr form))))
 133           (while (and backwards
 134                       (null (setcar backwards
 135                                     (byte-optimize-form (car backwards) t))))
 136             (setq backwards (cdr backwards)))
 137           (if (and (cdr form) (null backwards))
 138               (byte-compile-log
 139                "  all subforms of %s called for effect; deleted" form))
 140           (when backwards
 141             (setcdr backwards
 142                     (mapcar 'byte-optimize-form (cdr backwards))))
 143           (setq ad-return-value (cons fn (nreverse backwards))))
 144       ad-do-it)))
 145
 146 ;; Work around for an incompatibility (XEmacs 21.4 vs. 21.5), see the
 147 ;; following threads:
 148 ;;
 149 ;; http://thread.gmane.org/gmane.emacs.gnus.general/56414
 150 ;; Subject: attachment problems found but not fixed
 151 ;;
 152 ;; http://thread.gmane.org/gmane.emacs.gnus.general/56459
 153 ;; Subject: Splitting mail -- XEmacs 21.4 vs 21.5
 154 ;;
 155 ;; http://thread.gmane.org/gmane.emacs.xemacs.beta/20519
 156 ;; Subject: XEmacs 21.5 and Gnus fancy splitting.
 157 ;;
 158 ;; Should be fixed in XEmacs (March 2007).
 159 ;; http://thread.gmane.org/gmane.emacs.xemacs.patches/8124
 160 ;; When should we remove this workaround?
 161 ;;
 162 (when (and (featurep 'xemacs)
 163            (let ((table (copy-syntax-table emacs-lisp-mode-syntax-table)))
 164              (modify-syntax-entry ?= " " table)
 165              (with-temp-buffer
 166                (with-syntax-table table
 167                  (insert "foo=bar")
 168                  (goto-char (point-min))
 169                  (forward-sexp 1)
 170                  (eolp)))))
 171   ;; The original `with-syntax-table' uses `copy-syntax-table' which
 172   ;; doesn't seem to copy modified syntax entries in XEmacs 21.5.
 173   (defmacro with-syntax-table (syntab &rest body)
 174     "Evaluate BODY with the SYNTAB as the current syntax table."
 175     `(let ((stab (syntax-table)))
 176        (unwind-protect
 177            (progn
 178              ;;(set-syntax-table (copy-syntax-table ,syntab))
 179              (set-syntax-table ,syntab)
 180              ,@body)
 181          (set-syntax-table stab)))))
 182
 183 (push srcdir load-path)
 184 (push loaddir load-path)
 185 (load (expand-file-name "lpath.el" loaddir) nil t)
 186
 187 (defalias 'device-sound-enabled-p 'ignore)
 188 (defalias 'play-sound-file 'ignore)
 189 (defalias 'efs-re-read-dir 'ignore)
 190 (defalias 'ange-ftp-re-read-dir 'ignore)
 191 (defalias 'define-mail-user-agent 'ignore)
 192
 193 (eval-and-compile
 194   (unless (featurep 'xemacs)
 195     (defalias 'get-popup-menu-response 'ignore)
 196     (defalias 'event-object 'ignore)
 197     (autoload 'netrc-credentials "netrc")
 198     (defalias 'x-defined-colors 'ignore)
 199     (defalias 'read-color 'ignore)))
 200
 201 (eval-and-compile
 202   (when (featurep 'xemacs)
 203     (unless (fboundp 'defadvice)
 204       (autoload 'defadvice "advice" nil nil 'macro))
 205     (autoload 'Info-directory "info" nil t)
 206     (autoload 'Info-index "info" nil t)
 207     (autoload 'Info-index-next "info" nil t)
 208     (autoload 'Info-menu "info" nil t)
 209     (autoload 'ad-add-advice "advice")
 210     (unless (and (emacs-version>= 21 5)
 211                  (not (featurep 'sxemacs)))
 212       ;; calendar/auto-autoloads.el provides it.
 213       (autoload 'add-to-invisibility-spec "dummy"))
 214     (autoload 'annotations-at "annotations")
 215     (autoload 'apropos "apropos" nil t)
 216     (autoload 'apropos-command "apropos" nil t)
 217     (autoload 'bbdb-complete-name "bbdb-com" nil t)
 218     (autoload 'browse-url "browse-url" nil t)
 219     (autoload 'browse-url-of-file "browse-url" nil t)
 220     (autoload 'c-mode "cc-mode" nil t)
 221     (autoload 'customize-apropos "cus-edit" nil t)
 222     (autoload 'customize-group "cus-edit" nil t)
 223     (autoload 'customize-save-variable "cus-edit" nil t)
 224     (autoload 'customize-set-variable "cus-edit" nil t)
 225     (autoload 'customize-variable "cus-edit" nil t)
 226     (autoload 'debug "debug" nil t)
 227     (if (featurep 'mule)
 228         (unless (locate-library "mule-ccl")
 229           (autoload 'define-ccl-program "ccl" nil nil 'macro))
 230       (defalias 'define-ccl-program 'ignore))
 231     (autoload 'delete-annotation "annotations")
 232     (autoload 'dolist "cl-macs" nil nil 'macro)
 233     (autoload 'enriched-decode "enriched")
 234     (autoload 'eudc-expand-inline "eudc" nil t)
 235     (autoload 'executable-find "executable")
 236     (autoload 'font-lock-fontify-buffer "font-lock" nil t)
 237     (when (and (emacs-version>= 21 5)
 238                (not (featurep 'sxemacs)))
 239       (autoload 'get-display-table "disp-table")
 240       (autoload 'put-display-table "disp-table"))
 241     (autoload 'info "info" nil t)
 242     (autoload 'mail-extract-address-components "mail-extr")
 243     (autoload 'mail-fetch-field "mail-utils")
 244     (autoload 'make-annotation "annotations")
 245     (autoload 'make-display-table "disp-table")
 246     (autoload 'pgg-snarf-keys-region "pgg" nil t)
 247     (autoload 'pp "pp")
 248     (autoload 'ps-despool "ps-print" nil t)
 249     (autoload 'ps-spool-buffer "ps-print" nil t)
 250     (autoload 'ps-spool-buffer-with-faces "ps-print" nil t)
 251     (autoload 'read-passwd "passwd")
 252     (autoload 'regexp-opt "regexp-opt")
 253     (autoload 'reporter-submit-bug-report "reporter")
 254     (if (and (emacs-version>= 21 5)
 255              (not (featurep 'sxemacs)))
 256         (autoload 'setenv "process" nil t)
 257       (autoload 'setenv "env" nil t))
 258     (autoload 'sgml-mode "psgml" nil t)
 259     (autoload 'smtpmail-send-it "smtpmail")
 260     (autoload 'sort-numeric-fields "sort" nil t)
 261     (autoload 'sort-subr "sort")
 262     (autoload 'thing-at-point "thingatpt")
 263     (autoload 'toggle-truncate-lines "view-less" nil t)
 264     (autoload 'trace-function-background "trace" nil t)
 265     (autoload 'unmorse-region "morse" nil t)
 266     (autoload 'w3-do-setup "w3")
 267     (autoload 'w3-prepare-buffer "w3-display")
 268     (autoload 'w3-region "w3-display" nil t)
 269     (defalias 'frame-char-height 'frame-height)
 270     (defalias 'frame-char-width 'frame-width)
 271     (defalias 'frame-parameter 'frame-property)
 272     (defalias 'make-overlay 'ignore)
 273     (defalias 'overlay-end 'ignore)
 274     (defalias 'overlay-get 'ignore)
 275     (defalias 'overlay-put 'ignore)
 276     (defalias 'overlay-start 'ignore)
 277     (defalias 'overlays-in 'ignore)
 278     (defalias 'replace-dehighlight 'ignore)
 279     (defalias 'replace-highlight 'ignore)
 280     (defalias 'w3-coding-system-for-mime-charset 'ignore)))
 281
 282 (defun dgnushack-emacs-compile-defcustom-p ()
 283   "Return non-nil if Emacs byte compiles `defcustom' forms.
 284 Those Emacsen will warn against undefined variables and functions used
 285 in `defcustom' forms."
 286   (let ((outbuf (with-temp-buffer
 287                   (insert "(defcustom foo (1+ (random)) \"\" :group 'emacs)\n")
 288                   (byte-compile-from-buffer (current-buffer) "foo.el"))))
 289     (when outbuf
 290       (prog1
 291           (with-current-buffer outbuf
 292             (goto-char (point-min))
 293             (search-forward " 'foo '(byte-code " nil t))
 294         (kill-buffer outbuf)))))
 295
 296 (when (dgnushack-emacs-compile-defcustom-p)
 297   (maybe-fbind '(defined-colors face-attribute))
 298   (maybe-bind '(idna-program installation-directory)))
 299
 300 (defun dgnushack-compile-verbosely ()
 301   "Call dgnushack-compile with warnings ENABLED.  If you are compiling
 302 patches to gnus, you should consider modifying make.bat to call
 303 dgnushack-compile-verbosely.  All other users should continue to use
 304 dgnushack-compile."
 305   (dgnushack-compile t))
 306
 307 (defun dgnushack-compile (&optional warn)
 308   ;;(setq byte-compile-dynamic t)
 309   (unless warn
 310     (setq byte-compile-warnings
 311           '(free-vars unresolved callargs redefine suspicious)))
 312   (let ((files (directory-files srcdir nil "^[^=].*\\.el$"))
 313         ;;(byte-compile-generate-call-tree t)
 314         file elc)
 315     ;; Avoid barfing (from gnus-xmas) because the etc directory is not yet
 316     ;; installed.
 317     (when (featurep 'xemacs)
 318       (setq gnus-xmas-glyph-directory "dummy"))
 319     (dolist (file '(".dir-locals.el" "dgnushack.el" "lpath.el"))
 320       (setq files (delete file files)))
 321     (when (featurep 'base64)
 322       (setq files (delete "base64.el" files)))
 323     (condition-case code
 324         (require 'w3-parse)
 325       (error
 326        (message "No w3: %s %s" (cadr code) (or (locate-library "w3-parse") ""))
 327        (dolist (file '("webmail.el" "nnwfm.el"))
 328          (setq files (delete file files)))))
 329     (condition-case code
 330         ;; Under XEmacs 21.4 this loads easy-mmode.elc that provides
 331         ;; the Emacs functions `propertize' and `replace-regexp-in-string'.
 332         (require 'mh-e)
 333       (error
 334        (message "No mh-e: %s %s" (cadr code) (or (locate-library "mh-e") ""))
 335        (setq files (delete "gnus-mh.el" files))))
 336     (condition-case code
 337         (require 'xml)
 338       (error
 339        (message "No xml: %s %s" (cadr code) (or (locate-library "xml") ""))
 340        (setq files (delete "nnrss.el" files))))
 341     (dolist (file
 342              (if (featurep 'xemacs)
 343                  '("md5.el")
 344                '("gnus-xmas.el" "messagexmas.el" "nnheaderxm.el")))
 345       (setq files (delete file files)))
 346
 347     (dolist (file files)
 348       (setq file (expand-file-name file srcdir))
 349       (when (and (file-exists-p
 350                   (setq elc (concat (file-name-nondirectory file) "c")))
 351                  (file-newer-than-file-p file elc))
 352         (delete-file elc)))
 353
 354     (while (setq file (pop files))
 355       (setq file (expand-file-name file srcdir))
 356       (when (or (not (file-exists-p
 357                       (setq elc (concat (file-name-nondirectory file) "c"))))
 358                 (file-newer-than-file-p file elc))
 359         (ignore-errors
 360           (byte-compile-file file))))))
 361
 362 (defun dgnushack-recompile ()
 363   (require 'gnus)
 364   (byte-recompile-directory "." 0))
 365
 366 (defvar dgnushack-gnus-load-file
 367   (if (featurep 'xemacs)
 368       (expand-file-name "auto-autoloads.el")
 369     (expand-file-name "gnus-load.el")))
 370
 371 (defvar dgnushack-cus-load-file
 372   (if (featurep 'xemacs)
 373       (expand-file-name "custom-load.el")
 374     (expand-file-name "cus-load.el")))
 375
 376 (defun dgnushack-make-cus-load ()
 377   (load "cus-dep")
 378   (let ((cusload-base-file dgnushack-cus-load-file))
 379     (defadvice directory-files (after exclude-dir-locals activate)
 380       "Exclude .dir-locals.el file."
 381       (dolist (file ad-return-value)
 382         (if (string-match "\\(?:\\`\\|/\\)\\.dir-locals\\.el\\'" file)
 383             (setq ad-return-value (delete file ad-return-value)))))
 384     (unwind-protect
 385         (if (fboundp 'custom-make-dependencies)
 386             (custom-make-dependencies)
 387           (Custom-make-dependencies))
 388       (ad-unadvise 'directory-files))
 389     (when (featurep 'xemacs)
 390       (message "Compiling %s..." dgnushack-cus-load-file)
 391       (byte-compile-file dgnushack-cus-load-file))))
 392
 393 (defun dgnushack-make-auto-load ()
 394   (require 'autoload)
 395   (unless (make-autoload '(define-derived-mode child parent name
 396                             "docstring" body)
 397                          "file")
 398     (defadvice make-autoload (around handle-define-derived-mode activate)
 399       "Handle `define-derived-mode'."
 400       (if (eq (car-safe (ad-get-arg 0)) 'define-derived-mode)
 401           (setq ad-return-value
 402                 (list 'autoload
 403                       (list 'quote (nth 1 (ad-get-arg 0)))
 404                       (ad-get-arg 1)
 405                       (nth 4 (ad-get-arg 0))
 406                       t nil))
 407         ad-do-it))
 408     (put 'define-derived-mode 'doc-string-elt 3))
 409   (let ((generated-autoload-file dgnushack-gnus-load-file)
 410         (make-backup-files nil)
 411         (autoload-package-name "gnus"))
 412     (if (featurep 'xemacs)
 413         (if (file-exists-p generated-autoload-file)
 414             (delete-file generated-autoload-file))
 415       (with-temp-file generated-autoload-file
 416         (insert ?\014)))
 417     (defadvice directory-files (after exclude-dir-locals activate)
 418       "Exclude .dir-locals.el file."
 419       (dolist (file ad-return-value)
 420         (if (string-match "\\(?:\\`\\|/\\)\\.dir-locals\\.el\\'" file)
 421             (setq ad-return-value (delete file ad-return-value)))))
 422     (unwind-protect
 423         (batch-update-autoloads)
 424       (ad-unadvise 'directory-files))))
 425
 426 (defun dgnushack-make-load ()
 427   (unless (featurep 'xemacs)
 428     (message "Generating %s..." dgnushack-gnus-load-file)
 429     (with-temp-file dgnushack-gnus-load-file
 430       (insert-file-contents dgnushack-cus-load-file)
 431       (delete-file dgnushack-cus-load-file)
 432       (goto-char (point-min))
 433       (search-forward ";;; Code:")
 434       (forward-line)
 435       (delete-region (point-min) (point))
 436       (insert "\
 437 ;;; gnus-load.el --- automatically extracted custom dependencies and autoload
 438 ;;
 439 ;;; Code:
 440 ")
 441       (goto-char (point-max))
 442       (if (search-backward "custom-versions-load-alist" nil t)
 443           (forward-line -1)
 444         (forward-line -1)
 445         (while (eq (char-after) ?\;)
 446           (forward-line -1))
 447         (forward-line))
 448       (delete-region (point) (point-max))
 449       (insert "\n")
 450       ;; smiley-* are duplicated. Remove them all.
 451       (let ((point (point)))
 452         (insert-file-contents dgnushack-gnus-load-file)
 453         (goto-char point)
 454         (while (search-forward "smiley-" nil t)
 455           (beginning-of-line)
 456           (if (looking-at "(autoload ")
 457               (delete-region (point) (progn (forward-sexp) (point)))
 458             (forward-line))))
 459       ;;
 460       (goto-char (point-max))
 461       (when (search-backward "\n(provide " nil t)
 462         (forward-line -1)
 463         (delete-region (point) (point-max)))
 464       (insert "\
 465
 466 \(provide 'gnus-load)
 467
 468 ;;; Local Variables:
 469 ;;; version-control: never
 470 ;;; no-byte-compile: t
 471 ;;; no-update-autoloads: t
 472 ;;; End:
 473 ;;; gnus-load.el ends here
 474 ")
 475       ))
 476   (message "Compiling %s..." dgnushack-gnus-load-file)
 477   (byte-compile-file dgnushack-gnus-load-file)
 478   (when (featurep 'xemacs)
 479     (message "Creating dummy gnus-load.el...")
 480     (with-temp-file (expand-file-name "gnus-load.el")
 481       (insert "\
 482
 483 \(provide 'gnus-load)
 484
 485 ;;; Local Variables:
 486 ;;; version-control: never
 487 ;;; no-byte-compile: t
 488 ;;; no-update-autoloads: t
 489 ;;; End:
 490 ;;; gnus-load.el ends here"))))
 491
 492 (defun dgnushack-find-lisp-shadows (&optional lispdir)
 493   "Return a list of directories in which other Gnus installations exist.
 494 This function looks for the other Gnus installations which will shadow
 495 the new Gnus Lisp modules which have been installed in LISPDIR, using
 496 the default `load-path'.  The return value will make sense only when
 497 LISPDIR is existent and is listed in the default `load-path'.  Assume
 498 LISPDIR will be prepended to `load-path' by a user if the default
 499 `load-path' does not contain it."
 500   (unless lispdir
 501     (setq lispdir (getenv "lispdir")))
 502   (when (and lispdir (file-directory-p lispdir))
 503     (setq lispdir (file-truename (directory-file-name lispdir)))
 504     (let ((indices '("gnus.elc" "gnus.el" "gnus.el.bz2" "gnus.el.gz"
 505                      "message.elc" "message.el" "message.el.bz2"
 506                      "message.el.gz"))
 507           (path (delq nil (mapcar
 508                            (lambda (p)
 509                              (condition-case nil
 510                                  (when (and p (file-directory-p p))
 511                                    (file-truename (directory-file-name p)))
 512                                (error nil)))
 513                            dgnushack-default-load-path)))
 514           rest elcs)
 515       (while path
 516         (setq rest (cons (car path) rest)
 517               path (delete (car rest) (cdr path))))
 518       (setq path (nreverse (cdr (member lispdir rest)))
 519             rest nil)
 520       (while path
 521         (setq elcs indices)
 522         (while elcs
 523           (when (file-exists-p (expand-file-name (pop elcs) (car path)))
 524             (setq rest (cons (car path) rest)
 525                   elcs nil)))
 526         (setq path (cdr path)))
 527       (prog1
 528           (setq path (nreverse rest))
 529         (when path
 530           (let (print-level print-length)
 531             (princ (concat "\n\
 532 WARNING: The other Gnus installation" (if (cdr path) "s have" " has") "\
 533  been detected in:\n\n  " (mapconcat 'identity path "\n  ") "\n\n\
 534 You will need to modify the run-time `load-path', remove them manually,
 535 or remove them using `make remove-installed-shadows'.\n\n"))))))))
 536
 537 (defun dgnushack-remove-lisp-shadows (&optional lispdir)
 538   "Remove the other Gnus installations which shadow the recent one."
 539   (let ((path (with-temp-buffer
 540                 (let ((standard-output (current-buffer)))
 541                   (dgnushack-find-lisp-shadows lispdir))))
 542         elcs files shadows file)
 543     (when path
 544       (unless (setq elcs (directory-files srcdir nil "\\.elc\\'"))
 545         (error "You should build .elc files first."))
 546       (setq files
 547             (apply
 548              'append
 549              (mapcar
 550               (lambda (el)
 551                 (list (concat el "c") el (concat el ".bz2") (concat el ".gz")))
 552               (append
 553                (list (file-name-nondirectory dgnushack-gnus-load-file)
 554                      (file-name-nondirectory dgnushack-cus-load-file))
 555                (mapcar (lambda (elc) (substring elc 0 -1)) elcs)))))
 556       (while path
 557         (setq shadows files)
 558         (while shadows
 559           (setq file (expand-file-name (pop shadows) (car path)))
 560           (when (file-exists-p file)
 561             (princ (concat "  Removing " file "..."))
 562             (condition-case nil
 563                 (progn
 564                   (delete-file file)
 565                   (princ "done\n"))
 566               (error (princ "failed\n")))))
 567         (setq path (cdr path))))))
 568
 569 ;;; dgnushack.el ends here