cgit.sxemacs.org Git - gnus/blob - lisp/dgnushack.el

   1 ;;; dgnushack.el --- a hack to set the load path for byte-compiling
   2 ;; Copyright (C) 1994-2011 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   5 ;; Version: 4.19
   6 ;; Keywords: news, path
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 3, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  23 ;; Boston, MA 02110-1301, USA.
  24
  25 ;;; Commentary:
  26
  27 ;;; Code:
  28
  29 (defvar dgnushack-default-load-path (copy-sequence load-path))
  30
  31 (defalias 'facep 'ignore)
  32
  33 (require 'cl)
  34 (require 'iswitchb)
  35
  36 (condition-case nil
  37     (require 'org-entities)
  38   (error nil))
  39
  40 (defvar srcdir (or (getenv "srcdir") "."))
  41 (defvar loaddir (and load-file-name (file-name-directory load-file-name)))
  42
  43 (defun my-getenv (str)
  44   (let ((val (getenv str)))
  45     (if (equal val "no") nil val)))
  46
  47 (if (my-getenv "lispdir")
  48     (push (my-getenv "lispdir") load-path))
  49
  50 (push (or (my-getenv "URLDIR") (expand-file-name "../../url/lisp/" loaddir))
  51       load-path)
  52
  53 (push (or (my-getenv "W3DIR") (expand-file-name "../../w3/lisp/" loaddir))
  54       load-path)
  55
  56 ;(push "/usr/share/emacs/site-lisp" load-path)
  57
  58 ;; If we are building w3 in a different directory than the source
  59 ;; directory, we must read *.el from source directory and write *.elc
  60 ;; into the building directory.  For that, we define this function
  61 ;; before loading bytecomp.  Bytecomp doesn't overwrite this function.
  62 (defun byte-compile-dest-file (filename)
  63   "Convert an Emacs Lisp source file name to a compiled file name.
  64  In addition, remove directory name part from FILENAME."
  65   (setq filename (byte-compiler-base-file-name filename))
  66   (setq filename (file-name-sans-versions filename))
  67   (setq filename (file-name-nondirectory filename))
  68   (if (eq system-type 'windows-nt)
  69       (setq filename (downcase filename)))
  70   (cond ((eq system-type 'vax-vms)
  71          (concat (substring filename 0 (string-match ";" filename)) "c"))
  72         ((string-match emacs-lisp-file-regexp filename)
  73          (concat (substring filename 0 (match-beginning 0)) ".elc"))
  74         (t (concat filename ".elc"))))
  75
  76 (require 'bytecomp)
  77 ;; To avoid having defsubsts and inlines happen.
  78 ;(if (featurep 'xemacs)
  79 ;    (require 'byte-optimize)
  80 ;  (require 'byte-opt))
  81 ;(defun byte-optimize-inline-handler (form)
  82 ;  "byte-optimize-handler for the `inline' special-form."
  83 ;  (cons 'progn (cdr form)))
  84 ;(defalias 'byte-compile-file-form-defsubst 'byte-compile-file-form-defun)
  85
  86 ;; Work around for an incompatibility (XEmacs 21.4 vs. 21.5), see the
  87 ;; following threads:
  88 ;;
  89 ;; http://thread.gmane.org/gmane.emacs.gnus.general/56414
  90 ;; Subject: attachment problems found but not fixed
  91 ;;
  92 ;; http://thread.gmane.org/gmane.emacs.gnus.general/56459
  93 ;; Subject: Splitting mail -- XEmacs 21.4 vs 21.5
  94 ;;
  95 ;; http://thread.gmane.org/gmane.emacs.xemacs.beta/20519
  96 ;; Subject: XEmacs 21.5 and Gnus fancy splitting.
  97 ;;
  98 ;; Should be fixed in XEmacs (March 2007).
  99 ;; http://thread.gmane.org/gmane.emacs.xemacs.patches/8124
 100 ;; When should we remove this workaround?
 101 ;;
 102 (when (and (featurep 'xemacs)
 103            (let ((table (copy-syntax-table emacs-lisp-mode-syntax-table)))
 104              (modify-syntax-entry ?= " " table)
 105              (with-temp-buffer
 106                (with-syntax-table table
 107                  (insert "foo=bar")
 108                  (goto-char (point-min))
 109                  (forward-sexp 1)
 110                  (eolp)))))
 111   ;; The original `with-syntax-table' uses `copy-syntax-table' which
 112   ;; doesn't seem to copy modified syntax entries in old XEmacs 21.5.
 113   (defmacro with-syntax-table (syntab &rest body)
 114     "Evaluate BODY with the SYNTAB as the current syntax table."
 115     `(let ((stab (syntax-table)))
 116        (unwind-protect
 117            (progn
 118              ;;(set-syntax-table (copy-syntax-table ,syntab))
 119              (set-syntax-table ,syntab)
 120              ,@body)
 121          (set-syntax-table stab)))))
 122
 123 (push srcdir load-path)
 124 (push loaddir load-path)
 125 (load (expand-file-name "lpath.el" loaddir) nil t)
 126
 127 (defalias 'device-sound-enabled-p 'ignore)
 128 (defalias 'play-sound-file 'ignore)
 129 (defalias 'efs-re-read-dir 'ignore)
 130 (defalias 'ange-ftp-re-read-dir 'ignore)
 131 (defalias 'define-mail-user-agent 'ignore)
 132 (defalias 'debbugs-gnu-summary-mode 'ignore)
 133 (defvar debbugs-gnu-bug-number nil)
 134
 135 (eval-and-compile
 136   (unless (featurep 'xemacs)
 137     (defalias 'get-popup-menu-response 'ignore)
 138     (defalias 'event-object 'ignore)
 139     (autoload 'iswitchb-read-buffer "iswitchb")
 140     (autoload 'netrc-credentials "netrc")
 141     (defalias 'x-defined-colors 'ignore)
 142     (defalias 'read-color 'ignore)))
 143
 144 (eval-and-compile
 145   (when (featurep 'xemacs)
 146     (unless (fboundp 'defadvice)
 147       (autoload 'defadvice "advice" nil nil 'macro))
 148     (unless (boundp 'help-echo-owns-message)
 149       (defvar help-echo-owns-message))
 150     (unless (fboundp 'url-retrieve-synchronously)
 151       (defalias 'url-retrieve-synchronously 'url-retrieve))
 152     (unless (fboundp 'url-queue-retrieve)
 153       (defun url-queue-retrieve (url callback &optional cbargs silent)
 154         (url-retrieve url callback cbargs)))
 155     (autoload 'Info-directory "info" nil t)
 156     (autoload 'Info-index "info" nil t)
 157     (autoload 'Info-index-next "info" nil t)
 158     (autoload 'Info-menu "info" nil t)
 159     (autoload 'ad-add-advice "advice")
 160     (unless (and (emacs-version>= 21 5)
 161                  (not (featurep 'sxemacs)))
 162       ;; calendar/auto-autoloads.el provides it.
 163       (autoload 'add-to-invisibility-spec "dummy"))
 164     (autoload 'annotations-at "annotations")
 165     (autoload 'apropos "apropos" nil t)
 166     (autoload 'apropos-command "apropos" nil t)
 167     (autoload 'bbdb-complete-name "bbdb-com" nil t)
 168     (autoload 'browse-url "browse-url" nil t)
 169     (autoload 'browse-url-of-file "browse-url" nil t)
 170     (autoload 'c-mode "cc-mode" nil t)
 171     (autoload 'customize-apropos "cus-edit" nil t)
 172     (autoload 'customize-group "cus-edit" nil t)
 173     (autoload 'customize-save-variable "cus-edit" nil t)
 174     (autoload 'customize-set-variable "cus-edit" nil t)
 175     (autoload 'customize-variable "cus-edit" nil t)
 176     (autoload 'debug "debug" nil t)
 177     (autoload 'sha1 "sha1")
 178     (if (featurep 'mule)
 179         (unless (locate-library "mule-ccl")
 180           (autoload 'define-ccl-program "ccl" nil nil 'macro))
 181       (defalias 'define-ccl-program 'ignore))
 182     (autoload 'delete-annotation "annotations")
 183     (autoload 'dolist "cl-macs" nil nil 'macro)
 184     (autoload 'enriched-decode "enriched")
 185     (autoload 'eudc-expand-inline "eudc" nil t)
 186     (autoload 'executable-find "executable")
 187     (autoload 'font-lock-fontify-buffer "font-lock" nil t)
 188     (when (and (emacs-version>= 21 5)
 189                (not (featurep 'sxemacs)))
 190       (autoload 'get-display-table "disp-table")
 191       (autoload 'put-display-table "disp-table"))
 192     (autoload 'info "info" nil t)
 193     (autoload 'mail-extract-address-components "mail-extr")
 194     (autoload 'mail-fetch-field "mail-utils")
 195     (autoload 'make-annotation "annotations")
 196     (autoload 'make-display-table "disp-table")
 197     (autoload 'pgg-snarf-keys-region "pgg" nil t)
 198     (autoload 'pp "pp")
 199     (autoload 'ps-despool "ps-print" nil t)
 200     (autoload 'ps-spool-buffer "ps-print" nil t)
 201     (autoload 'ps-spool-buffer-with-faces "ps-print" nil t)
 202     (autoload 'read-passwd "passwd")
 203     (autoload 'regexp-opt "regexp-opt")
 204     (autoload 'reporter-submit-bug-report "reporter")
 205     (if (condition-case nil
 206             (progn
 207               (require 'rot13)
 208               (not (fboundp 'rot13-string)))
 209           (error nil))
 210         (defmacro rot13-string (string)
 211           "Return ROT13 encryption of STRING."
 212           `(let ((string ,string))
 213              (with-temp-buffer
 214                (insert string)
 215                (translate-region (point-min) (point-max) ,rot13-display-table)
 216                (buffer-string)))))
 217     (if (and (emacs-version>= 21 5)
 218              (not (featurep 'sxemacs)))
 219         (autoload 'setenv "process" nil t)
 220       (autoload 'setenv "env" nil t))
 221     (autoload 'sgml-mode "psgml" nil t)
 222     (autoload 'smtpmail-send-it "smtpmail")
 223     (autoload 'sort-numeric-fields "sort" nil t)
 224     (autoload 'sort-subr "sort")
 225     (autoload 'thing-at-point "thingatpt")
 226     (autoload 'toggle-truncate-lines "view-less" nil t)
 227     (autoload 'trace-function-background "trace" nil t)
 228     (autoload 'unmorse-region "morse" nil t)
 229     (autoload 'w3-do-setup "w3")
 230     (autoload 'w3-prepare-buffer "w3-display")
 231     (autoload 'w3-region "w3-display" nil t)
 232     (defalias 'frame-char-height 'frame-height)
 233     (defalias 'frame-char-width 'frame-width)
 234     (defalias 'frame-parameter 'frame-property)
 235     (defalias 'make-overlay 'ignore)
 236     (defalias 'overlay-end 'ignore)
 237     (defalias 'overlay-get 'ignore)
 238     (defalias 'overlay-put 'ignore)
 239     (defalias 'overlay-start 'ignore)
 240     (defalias 'overlays-in 'ignore)
 241     (defalias 'replace-dehighlight 'ignore)
 242     (defalias 'replace-highlight 'ignore)
 243     (defalias 'gnutls-available-p 'ignore)
 244     (defvar timer-list nil)
 245     (defalias 'w3-coding-system-for-mime-charset 'ignore)))
 246
 247 (defun dgnushack-emacs-compile-defcustom-p ()
 248   "Return non-nil if Emacs byte compiles `defcustom' forms.
 249 Those Emacsen will warn against undefined variables and functions used
 250 in `defcustom' forms."
 251   (let ((outbuf (with-temp-buffer
 252                   (insert "(defcustom foo (1+ (random)) \"\" :group 'emacs)\n")
 253                   (byte-compile-from-buffer (current-buffer) "foo.el"))))
 254     (when outbuf
 255       (prog1
 256           (with-current-buffer outbuf
 257             (goto-char (point-min))
 258             (search-forward " 'foo '(byte-code " nil t))
 259         (kill-buffer outbuf)))))
 260
 261 (when (and (featurep 'xemacs)
 262            (dgnushack-emacs-compile-defcustom-p))
 263   (maybe-fbind '(defined-colors face-attribute))
 264   (maybe-bind '(idna-program installation-directory)))
 265
 266 (when (featurep 'xemacs)
 267   (defadvice byte-optimize-apply (before use-mapcan (form) activate)
 268     "Replace (apply 'nconc (mapcar ...)) with (mapcan ...)."
 269     (let ((last (nth (1- (length form)) form)))
 270       (when (and (eq last (third form))
 271                  (consp last)
 272                  (eq 'mapcar (car last))
 273                  (equal (nth 1 form) ''nconc))
 274         (setq form (cons 'mapcan (cdr last)))))))
 275
 276 (defun dgnushack-compile-verbosely ()
 277   "Call dgnushack-compile with warnings ENABLED.  If you are compiling
 278 patches to gnus, you should consider modifying make.bat to call
 279 dgnushack-compile-verbosely.  All other users should continue to use
 280 dgnushack-compile."
 281   (dgnushack-compile t))
 282
 283 (defun dgnushack-compile-error-on-warn ()
 284   "Call dgnushack-compile with minimal warnings, but with error-on-warn ENABLED.
 285 This means that every warning will be reported as an error."
 286   (unless (dgnushack-compile nil t)
 287     (error "Error during byte compilation (warnings were reported as errors!).")))
 288
 289 (defun dgnushack-compile (&optional warn error-on-warn)
 290   ;;(setq byte-compile-dynamic t)
 291   (unless warn
 292     (setq byte-compile-warnings
 293           '(free-vars unresolved callargs redefine suspicious)))
 294   (let ((files (directory-files srcdir nil "^[^=].*\\.el$"))
 295         (compilesuccess t)
 296         ;;(byte-compile-generate-call-tree t)
 297         file elc)
 298     ;; Avoid barfing (from gnus-xmas) because the etc directory is not yet
 299     ;; installed.
 300     (when (featurep 'xemacs)
 301       (setq gnus-xmas-glyph-directory "dummy"))
 302     (dolist (file '(".dir-locals.el" "dgnushack.el" "lpath.el"))
 303       (setq files (delete file files)))
 304     (when (featurep 'base64)
 305       (setq files (delete "base64.el" files)))
 306     (condition-case code
 307         (require 'w3-parse)
 308       (error
 309        (message "No w3: %s %s" (cadr code) (or (locate-library "w3-parse") ""))
 310        (dolist (file '("webmail.el" "nnwfm.el"))
 311          (setq files (delete file files)))))
 312     (condition-case code
 313         ;; Under XEmacs 21.4 this loads easy-mmode.elc that provides
 314         ;; the Emacs functions `propertize' and `replace-regexp-in-string'.
 315         (require 'mh-e)
 316       (error
 317        (message "No mh-e: %s %s" (cadr code) (or (locate-library "mh-e") ""))
 318        (setq files (delete "gnus-mh.el" files))))
 319     (condition-case code
 320         (require 'xml)
 321       (error
 322        (message "No xml: %s %s" (cadr code) (or (locate-library "xml") ""))
 323        (setq files (delete "nnrss.el" files))))
 324     (dolist (file
 325              (if (featurep 'xemacs)
 326                  '("md5.el")
 327                '("gnus-xmas.el" "messagexmas.el" "nnheaderxm.el")))
 328       (setq files (delete file files)))
 329     (unless (and (fboundp 'libxml-parse-html-region)
 330                  ;; lpath.el binds it.
 331                  (not (eq (symbol-function 'libxml-parse-html-region)
 332                           'ignore)))
 333       (dolist (file '("color.el" "shr-color.el" "shr.el"))
 334         (setq files (delete file files))))
 335     (unless (locate-library "epg")
 336       (setq files (delete "plstore.el" files)))
 337
 338     (dolist (file files)
 339       (setq file (expand-file-name file srcdir))
 340       (when (and (file-exists-p
 341                   (setq elc (concat (file-name-nondirectory file) "c")))
 342                  (file-newer-than-file-p file elc))
 343         (delete-file elc)))
 344
 345     (while (setq file (pop files))
 346       (setq file (expand-file-name file srcdir))
 347       (when (or (not (file-exists-p
 348                       (setq elc (concat (file-name-nondirectory file) "c"))))
 349                 (file-newer-than-file-p file elc))
 350         (if error-on-warn
 351             (let ((byte-compile-error-on-warn t))
 352               (unless (ignore-errors
 353                         (byte-compile-file file))
 354                 (setq compilesuccess nil)))
 355           (ignore-errors
 356             (byte-compile-file file)))))
 357     compilesuccess))
 358
 359 (defun dgnushack-recompile ()
 360   (require 'gnus)
 361   (byte-recompile-directory "." 0))
 362
 363 (defvar dgnushack-gnus-load-file
 364   (if (featurep 'xemacs)
 365       (expand-file-name "auto-autoloads.el")
 366     (expand-file-name "gnus-load.el")))
 367
 368 (defvar dgnushack-cus-load-file
 369   (if (featurep 'xemacs)
 370       (expand-file-name "custom-load.el")
 371     (expand-file-name "cus-load.el")))
 372
 373 (defun dgnushack-make-cus-load ()
 374   (load "cus-dep")
 375   (let ((cusload-base-file dgnushack-cus-load-file))
 376     (defadvice directory-files (after exclude-dir-locals activate)
 377       "Exclude .dir-locals.el file."
 378       (dolist (file ad-return-value)
 379         (if (string-match "\\(?:\\`\\|/\\)\\.dir-locals\\.el\\'" file)
 380             (setq ad-return-value (delete file ad-return-value)))))
 381     (unwind-protect
 382         (if (fboundp 'custom-make-dependencies)
 383             (custom-make-dependencies)
 384           (Custom-make-dependencies))
 385       (ad-unadvise 'directory-files))
 386     (when (featurep 'xemacs)
 387       (message "Compiling %s..." dgnushack-cus-load-file)
 388       (byte-compile-file dgnushack-cus-load-file))))
 389
 390 (defun dgnushack-make-auto-load ()
 391   (require 'autoload)
 392   (let ((generated-autoload-file dgnushack-gnus-load-file)
 393         (make-backup-files nil)
 394         (autoload-package-name "gnus"))
 395     (if (featurep 'xemacs)
 396         (if (file-exists-p generated-autoload-file)
 397             (delete-file generated-autoload-file))
 398       (with-temp-file generated-autoload-file
 399         (insert ?\014)))
 400     (defadvice directory-files (after exclude-dir-locals activate)
 401       "Exclude .dir-locals.el file."
 402       (dolist (file ad-return-value)
 403         (if (string-match "\\(?:\\`\\|/\\)\\.dir-locals\\.el\\'" file)
 404             (setq ad-return-value (delete file ad-return-value)))))
 405     (unwind-protect
 406         (batch-update-autoloads)
 407       (ad-unadvise 'directory-files))))
 408
 409 (defun dgnushack-make-load ()
 410   (unless (featurep 'xemacs)
 411     (message "Generating %s..." dgnushack-gnus-load-file)
 412     (with-temp-file dgnushack-gnus-load-file
 413       (insert-file-contents dgnushack-cus-load-file)
 414       (delete-file dgnushack-cus-load-file)
 415       (goto-char (point-min))
 416       (search-forward ";;; Code:")
 417       (forward-line)
 418       (delete-region (point-min) (point))
 419       (insert "\
 420 ;;; gnus-load.el --- automatically extracted custom dependencies and autoload
 421 ;;
 422 ;;; Code:
 423 ")
 424       (goto-char (point-max))
 425       (if (search-backward "custom-versions-load-alist" nil t)
 426           (forward-line -1)
 427         (forward-line -1)
 428         (while (eq (char-after) ?\;)
 429           (forward-line -1))
 430         (forward-line))
 431       (delete-region (point) (point-max))
 432       (insert "\n")
 433       ;; smiley-* are duplicated. Remove them all.
 434       (let ((point (point)))
 435         (insert-file-contents dgnushack-gnus-load-file)
 436         (goto-char point)
 437         (while (search-forward "smiley-" nil t)
 438           (beginning-of-line)
 439           (if (looking-at "(autoload ")
 440               (delete-region (point) (progn (forward-sexp) (point)))
 441             (forward-line))))
 442       ;;
 443       (goto-char (point-max))
 444       (when (search-backward "\n(provide " nil t)
 445         (forward-line -1)
 446         (delete-region (point) (point-max)))
 447       (insert "\
 448
 449 \(provide 'gnus-load)
 450
 451 ;;; Local Variables:
 452 ;;; version-control: never
 453 ;;; no-byte-compile: t
 454 ;;; no-update-autoloads: t
 455 ;;; End:
 456 ;;; gnus-load.el ends here
 457 ")
 458       ))
 459   (message "Compiling %s..." dgnushack-gnus-load-file)
 460   (byte-compile-file dgnushack-gnus-load-file)
 461   (when (featurep 'xemacs)
 462     (message "Creating dummy gnus-load.el...")
 463     (with-temp-file (expand-file-name "gnus-load.el")
 464       (insert "\
 465
 466 \(provide 'gnus-load)
 467
 468 ;;; Local Variables:
 469 ;;; version-control: never
 470 ;;; no-byte-compile: t
 471 ;;; no-update-autoloads: t
 472 ;;; End:
 473 ;;; gnus-load.el ends here"))))
 474
 475 (defun dgnushack-find-lisp-shadows (&optional lispdir)
 476   "Return a list of directories in which other Gnus installations exist.
 477 This function looks for the other Gnus installations which will shadow
 478 the new Gnus Lisp modules which have been installed in LISPDIR, using
 479 the default `load-path'.  The return value will make sense only when
 480 LISPDIR is existent and is listed in the default `load-path'.  Assume
 481 LISPDIR will be prepended to `load-path' by a user if the default
 482 `load-path' does not contain it."
 483   (unless lispdir
 484     (setq lispdir (getenv "lispdir")))
 485   (when (and lispdir (file-directory-p lispdir))
 486     (setq lispdir (file-truename (directory-file-name lispdir)))
 487     (let ((indices '("gnus.elc" "gnus.el" "gnus.el.bz2" "gnus.el.gz"
 488                      "message.elc" "message.el" "message.el.bz2"
 489                      "message.el.gz"))
 490           (path (delq nil (mapcar
 491                            (lambda (p)
 492                              (condition-case nil
 493                                  (when (and p (file-directory-p p))
 494                                    (file-truename (directory-file-name p)))
 495                                (error nil)))
 496                            dgnushack-default-load-path)))
 497           rest elcs)
 498       (while path
 499         (setq rest (cons (car path) rest)
 500               path (delete (car rest) (cdr path))))
 501       (setq path (nreverse (cdr (member lispdir rest)))
 502             rest nil)
 503       (while path
 504         (setq elcs indices)
 505         (while elcs
 506           (when (file-exists-p (expand-file-name (pop elcs) (car path)))
 507             (setq rest (cons (car path) rest)
 508                   elcs nil)))
 509         (setq path (cdr path)))
 510       (prog1
 511           (setq path (nreverse rest))
 512         (when path
 513           (let (print-level print-length)
 514             (princ (concat "\n\
 515 WARNING: The other Gnus installation" (if (cdr path) "s have" " has") "\
 516  been detected in:\n\n  " (mapconcat 'identity path "\n  ") "\n\n\
 517 You will need to modify the run-time `load-path', remove them manually,
 518 or remove them using `make remove-installed-shadows'.\n\n"))))))))
 519
 520 (defun dgnushack-remove-lisp-shadows (&optional lispdir)
 521   "Remove the other Gnus installations which shadow the recent one."
 522   (let ((path (with-temp-buffer
 523                 (let ((standard-output (current-buffer)))
 524                   (dgnushack-find-lisp-shadows lispdir))))
 525         elcs files shadows file)
 526     (when path
 527       (unless (setq elcs (directory-files srcdir nil "\\.elc\\'"))
 528         (error "You should build .elc files first."))
 529       (setq files
 530             (apply
 531              'append
 532              (mapcar
 533               (lambda (el)
 534                 (list (concat el "c") el (concat el ".bz2") (concat el ".gz")))
 535               (append
 536                (list (file-name-nondirectory dgnushack-gnus-load-file)
 537                      (file-name-nondirectory dgnushack-cus-load-file))
 538                (mapcar (lambda (elc) (substring elc 0 -1)) elcs)))))
 539       (while path
 540         (setq shadows files)
 541         (while shadows
 542           (setq file (expand-file-name (pop shadows) (car path)))
 543           (when (file-exists-p file)
 544             (princ (concat "  Removing " file "..."))
 545             (condition-case nil
 546                 (progn
 547                   (delete-file file)
 548                   (princ "done\n"))
 549               (error (princ "failed\n")))))
 550         (setq path (cdr path))))))
 551
 552 (unless (fboundp 'with-demoted-errors)
 553   (defmacro with-demoted-errors (&rest body)
 554     "Run BODY and demote any errors to simple messages.
 555 If `debug-on-error' is non-nil, run BODY without catching its errors.
 556 This is to be used around code which is not expected to signal an error
 557 but which should be robust in the unexpected case that an error is signaled."
 558     (declare (debug t) (indent 0))
 559     (let ((err (make-symbol "err")))
 560       `(condition-case-no-debug ,err
 561            (progn ,@body)
 562          (error (message "Error: %S" ,err) nil)))))
 563
 564 ;;; dgnushack.el ends here