cgit.sxemacs.org Git - gnus/blob - lisp/dgnushack.el

   1 ;;; dgnushack.el --- a hack to set the load path for byte-compiling
   2 ;; Copyright (C) 1994, 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2003,
   3 ;; 2004, 2005, 2006, 2007, 2008
   4 ;;        Free Software Foundation, Inc.
   5
   6 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   7 ;; Version: 4.19
   8 ;; Keywords: news, path
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 3, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  25 ;; Boston, MA 02110-1301, USA.
  26
  27 ;;; Commentary:
  28
  29 ;;; Code:
  30
  31 (defvar dgnushack-default-load-path (copy-sequence load-path))
  32
  33 (defalias 'facep 'ignore)
  34
  35 (require 'cl)
  36
  37 (defvar srcdir (or (getenv "srcdir") "."))
  38 (defvar loaddir (and load-file-name (file-name-directory load-file-name)))
  39
  40 (defun my-getenv (str)
  41   (let ((val (getenv str)))
  42     (if (equal val "no") nil val)))
  43
  44 (if (my-getenv "lispdir")
  45     (push (my-getenv "lispdir") load-path))
  46
  47 (push (or (my-getenv "URLDIR") (expand-file-name "../../url/lisp/" loaddir))
  48       load-path)
  49
  50 (push (or (my-getenv "W3DIR") (expand-file-name "../../w3/lisp/" loaddir))
  51       load-path)
  52
  53 ;(push "/usr/share/emacs/site-lisp" load-path)
  54
  55 ;; If we are building w3 in a different directory than the source
  56 ;; directory, we must read *.el from source directory and write *.elc
  57 ;; into the building directory.  For that, we define this function
  58 ;; before loading bytecomp.  Bytecomp doesn't overwrite this function.
  59 (defun byte-compile-dest-file (filename)
  60   "Convert an Emacs Lisp source file name to a compiled file name.
  61  In addition, remove directory name part from FILENAME."
  62   (setq filename (byte-compiler-base-file-name filename))
  63   (setq filename (file-name-sans-versions filename))
  64   (setq filename (file-name-nondirectory filename))
  65   (if (memq system-type '(win32 w32 mswindows windows-nt))
  66       (setq filename (downcase filename)))
  67   (cond ((eq system-type 'vax-vms)
  68          (concat (substring filename 0 (string-match ";" filename)) "c"))
  69         ((string-match emacs-lisp-file-regexp filename)
  70          (concat (substring filename 0 (match-beginning 0)) ".elc"))
  71         (t (concat filename ".elc"))))
  72
  73 (require 'bytecomp)
  74 ;; To avoid having defsubsts and inlines happen.
  75 ;(if (featurep 'xemacs)
  76 ;    (require 'byte-optimize)
  77 ;  (require 'byte-opt))
  78 ;(defun byte-optimize-inline-handler (form)
  79 ;  "byte-optimize-handler for the `inline' special-form."
  80 ;  (cons 'progn (cdr form)))
  81 ;(defalias 'byte-compile-file-form-defsubst 'byte-compile-file-form-defun)
  82
  83 (when (and (not (featurep 'xemacs))
  84            (= emacs-major-version 21)
  85            (>= emacs-minor-version 3)
  86            (condition-case code
  87                (let ((byte-compile-error-on-warn t))
  88                  (byte-optimize-form (quote (pop x)) t)
  89                  nil)
  90              (error (string-match "called for effect"
  91                                   (error-message-string code)))))
  92   (defadvice byte-optimize-form-code-walker (around silence-warn-for-pop
  93                                                     (form for-effect)
  94                                                     activate)
  95     "Silence the warning \"...called for effect\" for the `pop' form.
  96 It is effective only when the `pop' macro is defined by cl.el rather
  97 than subr.el."
  98     (let (tmp)
  99       (if (and (eq (car-safe form) 'car)
 100                for-effect
 101                (setq tmp (get 'car 'side-effect-free))
 102                (not byte-compile-delete-errors)
 103                (not (eq tmp 'error-free))
 104                (eq (car-safe (cadr form)) 'prog1)
 105                (let ((var (cadr (cadr form)))
 106                      (last (nth 2 (cadr form))))
 107                  (and (symbolp var)
 108                       (null (nthcdr 3 (cadr form)))
 109                       (eq (car-safe last) 'setq)
 110                       (eq (cadr last) var)
 111                       (eq (car-safe (nth 2 last)) 'cdr)
 112                       (eq (cadr (nth 2 last)) var))))
 113           (progn
 114             (put 'car 'side-effect-free 'error-free)
 115             (unwind-protect
 116                 ad-do-it
 117               (put 'car 'side-effect-free tmp)))
 118         ad-do-it))))
 119
 120 (when (and (not (featurep 'xemacs))
 121            (byte-optimize-form
 122             '(and (> 0 1)
 123                   (message "This should not appear in the byte-code."))
 124             t))
 125   (defadvice byte-optimize-form-code-walker
 126     (around fix-bug-in-and/or-forms (form for-effect) activate)
 127     "Optimize the rest of the and/or forms.
 128 It has been fixed in XEmacs before releasing 21.4 and also has been
 129 fixed in Emacs 22."
 130     (if (and for-effect (memq (car-safe form) '(and or)))
 131         (let ((fn (car form))
 132               (backwards (reverse (cdr form))))
 133           (while (and backwards
 134                       (null (setcar backwards
 135                                     (byte-optimize-form (car backwards) t))))
 136             (setq backwards (cdr backwards)))
 137           (if (and (cdr form) (null backwards))
 138               (byte-compile-log
 139                "  all subforms of %s called for effect; deleted" form))
 140           (when backwards
 141             (setcdr backwards
 142                     (mapcar 'byte-optimize-form (cdr backwards))))
 143           (setq ad-return-value (cons fn (nreverse backwards))))
 144       ad-do-it)))
 145
 146 ;; Work around for an incompatibility (XEmacs 21.4 vs. 21.5), see the
 147 ;; following threads:
 148 ;;
 149 ;; http://thread.gmane.org/gmane.emacs.gnus.general/56414
 150 ;; Subject: attachment problems found but not fixed
 151 ;;
 152 ;; http://thread.gmane.org/gmane.emacs.gnus.general/56459
 153 ;; Subject: Splitting mail -- XEmacs 21.4 vs 21.5
 154 ;;
 155 ;; http://thread.gmane.org/gmane.emacs.xemacs.beta/20519
 156 ;; Subject: XEmacs 21.5 and Gnus fancy splitting.
 157 ;;
 158 ;; Should be fixed in XEmacs (March 2007).
 159 ;; http://thread.gmane.org/gmane.emacs.xemacs.patches/8124
 160 ;; When should we remove this workaround?
 161 ;;
 162 (when (and (featurep 'xemacs)
 163            (let ((table (copy-syntax-table emacs-lisp-mode-syntax-table)))
 164              (modify-syntax-entry ?= " " table)
 165              (with-temp-buffer
 166                (with-syntax-table table
 167                  (insert "foo=bar")
 168                  (goto-char (point-min))
 169                  (forward-sexp 1)
 170                  (eolp)))))
 171   ;; The original `with-syntax-table' uses `copy-syntax-table' which
 172   ;; doesn't seem to copy modified syntax entries in XEmacs 21.5.
 173   (defmacro with-syntax-table (syntab &rest body)
 174     "Evaluate BODY with the SYNTAB as the current syntax table."
 175     `(let ((stab (syntax-table)))
 176        (unwind-protect
 177            (progn
 178              ;;(set-syntax-table (copy-syntax-table ,syntab))
 179              (set-syntax-table ,syntab)
 180              ,@body)
 181          (set-syntax-table stab)))))
 182
 183 (push srcdir load-path)
 184 (push loaddir load-path)
 185 (load (expand-file-name "lpath.el" loaddir) nil t)
 186
 187 (defalias 'device-sound-enabled-p 'ignore)
 188 (defalias 'play-sound-file 'ignore)
 189 (defalias 'nndb-request-article 'ignore)
 190 (defalias 'efs-re-read-dir 'ignore)
 191 (defalias 'ange-ftp-re-read-dir 'ignore)
 192 (defalias 'define-mail-user-agent 'ignore)
 193
 194 (eval-and-compile
 195   (unless (featurep 'xemacs)
 196     (defalias 'get-popup-menu-response 'ignore)
 197     (defalias 'event-object 'ignore)
 198     (defalias 'x-defined-colors 'ignore)
 199     (defalias 'read-color 'ignore)))
 200
 201 (eval-and-compile
 202   (when (featurep 'xemacs)
 203     (unless (fboundp 'defadvice)
 204       (autoload 'defadvice "advice" nil nil 'macro))
 205     (autoload 'Info-directory "info" nil t)
 206     (autoload 'Info-index "info" nil t)
 207     (autoload 'Info-index-next "info" nil t)
 208     (autoload 'Info-menu "info" nil t)
 209     (autoload 'ad-add-advice "advice")
 210     (autoload 'annotations-at "annotations")
 211     (autoload 'apropos "apropos" nil t)
 212     (autoload 'apropos-command "apropos" nil t)
 213     (autoload 'bbdb-complete-name "bbdb-com" nil t)
 214     (autoload 'browse-url "browse-url" nil t)
 215     (autoload 'browse-url-of-file "browse-url" nil t)
 216     (autoload 'c-mode "cc-mode" nil t)
 217     (autoload 'customize-apropos "cus-edit" nil t)
 218     (autoload 'customize-group "cus-edit" nil t)
 219     (autoload 'customize-save-variable "cus-edit" nil t)
 220     (autoload 'customize-set-variable "cus-edit" nil t)
 221     (autoload 'customize-variable "cus-edit" nil t)
 222     (autoload 'debug "debug" nil t)
 223     (if (featurep 'mule)
 224         (unless (locate-library "mule-ccl")
 225           (autoload 'define-ccl-program "ccl" nil nil 'macro))
 226       (defalias 'define-ccl-program 'ignore))
 227     (autoload 'delete-annotation "annotations")
 228     (autoload 'dolist "cl-macs" nil nil 'macro)
 229     (autoload 'enriched-decode "enriched")
 230     (autoload 'eudc-expand-inline "eudc" nil t)
 231     (autoload 'executable-find "executable")
 232     (autoload 'font-lock-fontify-buffer "font-lock" nil t)
 233     (when (and (emacs-version>= 21 5)
 234                (not (featurep 'sxemacs)))
 235       (autoload 'get-display-table "disp-table.el")
 236       (autoload 'put-display-table "disp-table.el"))
 237     (autoload 'info "info" nil t)
 238     (autoload 'mail-extract-address-components "mail-extr")
 239     (autoload 'mail-fetch-field "mail-utils")
 240     (autoload 'make-annotation "annotations")
 241     (autoload 'make-display-table "disp-table")
 242     (autoload 'pgg-snarf-keys-region "pgg" nil t)
 243     (autoload 'pp "pp")
 244     (autoload 'ps-despool "ps-print" nil t)
 245     (autoload 'ps-spool-buffer "ps-print" nil t)
 246     (autoload 'ps-spool-buffer-with-faces "ps-print" nil t)
 247     (autoload 'read-passwd "passwd")
 248     (autoload 'regexp-opt "regexp-opt")
 249     (autoload 'reporter-submit-bug-report "reporter")
 250     (if (and (emacs-version>= 21 5)
 251              (not (featurep 'sxemacs)))
 252         (autoload 'setenv "process" nil t)
 253       (autoload 'setenv "env" nil t))
 254     (autoload 'sgml-mode "psgml" nil t)
 255     (autoload 'smtpmail-send-it "smtpmail")
 256     (autoload 'sort-numeric-fields "sort" nil t)
 257     (autoload 'sort-subr "sort")
 258     (autoload 'toggle-truncate-lines "view-less" nil t)
 259     (autoload 'trace-function-background "trace" nil t)
 260     (autoload 'unmorse-region "morse" nil t)
 261     (autoload 'w3-do-setup "w3")
 262     (autoload 'w3-prepare-buffer "w3-display")
 263     (autoload 'w3-region "w3-display" nil t)
 264     (defalias 'frame-char-height 'frame-height)
 265     (defalias 'frame-char-width 'frame-width)
 266     (defalias 'frame-parameter 'frame-property)
 267     (defalias 'make-overlay 'ignore)
 268     (defalias 'overlay-end 'ignore)
 269     (defalias 'overlay-get 'ignore)
 270     (defalias 'overlay-put 'ignore)
 271     (defalias 'overlay-start 'ignore)
 272     (defalias 'overlays-in 'ignore)
 273     (defalias 'replace-dehighlight 'ignore)
 274     (defalias 'replace-highlight 'ignore)
 275     (defalias 'w3-coding-system-for-mime-charset 'ignore)))
 276
 277 (defun dgnushack-emacs-compile-defcustom-p ()
 278   "Return non-nil if Emacs byte compiles `defcustom' forms.
 279 Those Emacsen will warn against undefined variables and functions used
 280 in `defcustom' forms."
 281   (let ((outbuf (with-temp-buffer
 282                   (insert "(defcustom foo (1+ (random)) \"\" :group 'emacs)\n")
 283                   (byte-compile-from-buffer (current-buffer) "foo.el"))))
 284     (when outbuf
 285       (prog1
 286           (with-current-buffer outbuf
 287             (goto-char (point-min))
 288             (search-forward " 'foo '(byte-code " nil t))
 289         (kill-buffer outbuf)))))
 290
 291 (when (dgnushack-emacs-compile-defcustom-p)
 292   (maybe-fbind '(defined-colors face-attribute))
 293   (maybe-bind '(idna-program installation-directory)))
 294
 295 (defun dgnushack-compile-verbosely ()
 296   "Call dgnushack-compile with warnings ENABLED.  If you are compiling
 297 patches to gnus, you should consider modifying make.bat to call
 298 dgnushack-compile-verbosely.  All other users should continue to use
 299 dgnushack-compile."
 300   (dgnushack-compile t))
 301
 302 (defun dgnushack-compile (&optional warn)
 303   ;;(setq byte-compile-dynamic t)
 304   (unless warn
 305     (setq byte-compile-warnings
 306           '(free-vars unresolved callargs redefine)))
 307   (let ((files (directory-files srcdir nil "^[^=].*\\.el$"))
 308         ;;(byte-compile-generate-call-tree t)
 309         file elc)
 310     ;; Avoid barfing (from gnus-xmas) because the etc directory is not yet
 311     ;; installed.
 312     (when (featurep 'xemacs)
 313       (setq gnus-xmas-glyph-directory "dummy"))
 314     (dolist (file '("dgnushack.el" "lpath.el"))
 315       (setq files (delete file files)))
 316     (when (featurep 'base64)
 317       (setq files (delete "base64.el" files)))
 318     (condition-case code
 319         (require 'w3-parse)
 320       (error
 321        (message "No w3: %s %s" (cadr code) (or (locate-library "w3-parse") ""))
 322        (dolist (file '("nnultimate.el" "webmail.el" "nnwfm.el"))
 323          (setq files (delete file files)))))
 324     (condition-case code
 325         (require 'mh-e)
 326       (error
 327        (message "No mh-e: %s %s" (cadr code) (or (locate-library "mh-e") ""))
 328        (setq files (delete "gnus-mh.el" files))))
 329     (condition-case code
 330         (require 'xml)
 331       (error
 332        (message "No xml: %s %s" (cadr code) (or (locate-library "xml") ""))
 333        (setq files (delete "nnrss.el" files))))
 334     (dolist (file
 335              (if (featurep 'xemacs)
 336                  '("md5.el")
 337                '("gnus-xmas.el" "messagexmas.el" "nnheaderxm.el")))
 338       (setq files (delete file files)))
 339
 340     (dolist (file files)
 341       (setq file (expand-file-name file srcdir))
 342       (when (and (file-exists-p
 343                   (setq elc (concat (file-name-nondirectory file) "c")))
 344                  (file-newer-than-file-p file elc))
 345         (delete-file elc)))
 346
 347     (while (setq file (pop files))
 348       (setq file (expand-file-name file srcdir))
 349       (when (or (not (file-exists-p
 350                       (setq elc (concat (file-name-nondirectory file) "c"))))
 351                 (file-newer-than-file-p file elc))
 352         (ignore-errors
 353           (byte-compile-file file))))))
 354
 355 (defun dgnushack-recompile ()
 356   (require 'gnus)
 357   (byte-recompile-directory "." 0))
 358
 359 (defvar dgnushack-gnus-load-file
 360   (if (featurep 'xemacs)
 361       (expand-file-name "auto-autoloads.el")
 362     (expand-file-name "gnus-load.el")))
 363
 364 (defvar dgnushack-cus-load-file
 365   (if (featurep 'xemacs)
 366       (expand-file-name "custom-load.el")
 367     (expand-file-name "cus-load.el")))
 368
 369 (defun dgnushack-make-cus-load ()
 370   (load "cus-dep")
 371   (let ((cusload-base-file dgnushack-cus-load-file))
 372     (if (fboundp 'custom-make-dependencies)
 373         (custom-make-dependencies)
 374       (Custom-make-dependencies))
 375     (when (featurep 'xemacs)
 376       (message "Compiling %s..." dgnushack-cus-load-file)
 377       (byte-compile-file dgnushack-cus-load-file))))
 378
 379 (defun dgnushack-make-auto-load ()
 380   (require 'autoload)
 381   (unless (make-autoload '(define-derived-mode child parent name
 382                             "docstring" body)
 383                          "file")
 384     (defadvice make-autoload (around handle-define-derived-mode activate)
 385       "Handle `define-derived-mode'."
 386       (if (eq (car-safe (ad-get-arg 0)) 'define-derived-mode)
 387           (setq ad-return-value
 388                 (list 'autoload
 389                       (list 'quote (nth 1 (ad-get-arg 0)))
 390                       (ad-get-arg 1)
 391                       (nth 4 (ad-get-arg 0))
 392                       t nil))
 393         ad-do-it))
 394     (put 'define-derived-mode 'doc-string-elt 3))
 395   (let ((generated-autoload-file dgnushack-gnus-load-file)
 396         (make-backup-files nil)
 397         (autoload-package-name "gnus"))
 398     (if (featurep 'xemacs)
 399         (if (file-exists-p generated-autoload-file)
 400             (delete-file generated-autoload-file))
 401       (with-temp-file generated-autoload-file
 402         (insert ?\014)))
 403     (batch-update-autoloads)))
 404
 405 (defun dgnushack-make-load ()
 406   (unless (featurep 'xemacs)
 407     (message "Generating %s..." dgnushack-gnus-load-file)
 408     (with-temp-file dgnushack-gnus-load-file
 409       (insert-file-contents dgnushack-cus-load-file)
 410       (delete-file dgnushack-cus-load-file)
 411       (goto-char (point-min))
 412       (search-forward ";;; Code:")
 413       (forward-line)
 414       (delete-region (point-min) (point))
 415       (insert "\
 416 ;;; gnus-load.el --- automatically extracted custom dependencies and autoload
 417 ;;
 418 ;;; Code:
 419 ")
 420       (goto-char (point-max))
 421       (if (search-backward "custom-versions-load-alist" nil t)
 422           (forward-line -1)
 423         (forward-line -1)
 424         (while (eq (char-after) ?\;)
 425           (forward-line -1))
 426         (forward-line))
 427       (delete-region (point) (point-max))
 428       (insert "\n")
 429       ;; smiley-* are duplicated. Remove them all.
 430       (let ((point (point)))
 431         (insert-file-contents dgnushack-gnus-load-file)
 432         (goto-char point)
 433         (while (search-forward "smiley-" nil t)
 434           (beginning-of-line)
 435           (if (looking-at "(autoload ")
 436               (delete-region (point) (progn (forward-sexp) (point)))
 437             (forward-line))))
 438       ;;
 439       (goto-char (point-max))
 440       (when (search-backward "\n(provide " nil t)
 441         (forward-line -1)
 442         (delete-region (point) (point-max)))
 443       (insert "\
 444
 445 \(provide 'gnus-load)
 446
 447 ;;; Local Variables:
 448 ;;; version-control: never
 449 ;;; no-byte-compile: t
 450 ;;; no-update-autoloads: t
 451 ;;; End:
 452 ;;; gnus-load.el ends here
 453 ")
 454       ))
 455   (message "Compiling %s..." dgnushack-gnus-load-file)
 456   (byte-compile-file dgnushack-gnus-load-file)
 457   (when (featurep 'xemacs)
 458     (message "Creating dummy gnus-load.el...")
 459     (with-temp-file (expand-file-name "gnus-load.el")
 460       (insert "\
 461
 462 \(provide 'gnus-load)
 463
 464 ;;; Local Variables:
 465 ;;; version-control: never
 466 ;;; no-byte-compile: t
 467 ;;; no-update-autoloads: t
 468 ;;; End:
 469 ;;; gnus-load.el ends here"))))
 470
 471 (defun dgnushack-find-lisp-shadows (&optional lispdir)
 472   "Return a list of directories in which other Gnus installations exist.
 473 This function looks for the other Gnus installations which will shadow
 474 the new Gnus Lisp modules which have been installed in LISPDIR, using
 475 the default `load-path'.  The return value will make sense only when
 476 LISPDIR is existent and is listed in the default `load-path'.  Assume
 477 LISPDIR will be prepended to `load-path' by a user if the default
 478 `load-path' does not contain it."
 479   (unless lispdir
 480     (setq lispdir (getenv "lispdir")))
 481   (when (and lispdir (file-directory-p lispdir))
 482     (setq lispdir (file-truename (directory-file-name lispdir)))
 483     (let ((indices '("gnus.elc" "gnus.el" "gnus.el.bz2" "gnus.el.gz"
 484                      "message.elc" "message.el" "message.el.bz2"
 485                      "message.el.gz"))
 486           (path (delq nil (mapcar
 487                            (lambda (p)
 488                              (condition-case nil
 489                                  (when (and p (file-directory-p p))
 490                                    (file-truename (directory-file-name p)))
 491                                (error nil)))
 492                            dgnushack-default-load-path)))
 493           rest elcs)
 494       (while path
 495         (setq rest (cons (car path) rest)
 496               path (delete (car rest) (cdr path))))
 497       (setq path (nreverse (cdr (member lispdir rest)))
 498             rest nil)
 499       (while path
 500         (setq elcs indices)
 501         (while elcs
 502           (when (file-exists-p (expand-file-name (pop elcs) (car path)))
 503             (setq rest (cons (car path) rest)
 504                   elcs nil)))
 505         (setq path (cdr path)))
 506       (prog1
 507           (setq path (nreverse rest))
 508         (when path
 509           (let (print-level print-length)
 510             (princ (concat "\n\
 511 WARNING: The other Gnus installation" (if (cdr path) "s have" " has") "\
 512  been detected in:\n\n  " (mapconcat 'identity path "\n  ") "\n\n\
 513 You will need to modify the run-time `load-path', remove them manually,
 514 or remove them using `make remove-installed-shadows'.\n\n"))))))))
 515
 516 (defun dgnushack-remove-lisp-shadows (&optional lispdir)
 517   "Remove the other Gnus installations which shadow the recent one."
 518   (let ((path (with-temp-buffer
 519                 (let ((standard-output (current-buffer)))
 520                   (dgnushack-find-lisp-shadows lispdir))))
 521         elcs files shadows file)
 522     (when path
 523       (unless (setq elcs (directory-files srcdir nil "\\.elc\\'"))
 524         (error "You should build .elc files first."))
 525       (setq files
 526             (apply
 527              'append
 528              (mapcar
 529               (lambda (el)
 530                 (list (concat el "c") el (concat el ".bz2") (concat el ".gz")))
 531               (append
 532                (list (file-name-nondirectory dgnushack-gnus-load-file)
 533                      (file-name-nondirectory dgnushack-cus-load-file))
 534                (mapcar (lambda (elc) (substring elc 0 -1)) elcs)))))
 535       (while path
 536         (setq shadows files)
 537         (while shadows
 538           (setq file (expand-file-name (pop shadows) (car path)))
 539           (when (file-exists-p file)
 540             (princ (concat "  Removing " file "..."))
 541             (condition-case nil
 542                 (progn
 543                   (delete-file file)
 544                   (princ "done\n"))
 545               (error (princ "failed\n")))))
 546         (setq path (cdr path))))))
 547
 548 ;;; dgnushack.el ends here
 549
 550 ;;; arch-tag: 579f585a-24eb-4e1c-8d34-4808e11b68f2