cgit.sxemacs.org Git - gnus/blob - lisp/deuglify.el

   1 ;;; deuglify.el --- deuglify broken Outlook (Express) articles
   2
   3 ;; Copyright (C) 2002, 2003, 2004 Free Software Foundation, Inc.
   4 ;; Copyright (C) 2001, 2002 Raymond Scholz
   5
   6 ;; Author: Raymond Scholz <rscholz@zonix.de>
   7 ;;         Thomas Steffen (unwrapping algorithm,
   8 ;;                         based on an idea of Stefan Monnier)
   9 ;; Keywords: mail, news
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; GNU Emacs is free software; you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation; either version 2, or (at your option)
  16 ;; any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  25 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  26 ;; Boston, MA 02111-1307, USA.
  27
  28 ;;; Commentary:
  29
  30 ;; This file enables Gnus to repair broken citations produced by
  31 ;; common user agents like MS Outlook (Express).  It may repair
  32 ;; articles of other user agents too.
  33 ;;
  34 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  35
  36 ;;
  37 ;; Outlook sometimes wraps cited lines before sending a message as
  38 ;; seen in this example:
  39 ;;
  40 ;; Example #1
  41 ;; ----------
  42 ;;
  43 ;; John Doe wrote:
  44 ;;
  45 ;; > This sentence no verb.  This sentence no verb.  This sentence
  46 ;; no
  47 ;; > verb.  This sentence no verb.  This sentence no verb.  This
  48 ;; > sentence no verb.
  49 ;;
  50 ;; The function `gnus-article-outlook-unwrap-lines' tries to recognize those
  51 ;; erroneously wrapped lines and will unwrap them.  I.e. putting the
  52 ;; wrapped parts ("no" in this example) back where they belong (at the
  53 ;; end of the cited line above).
  54 ;;
  55 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  56 ;;
  57 ;; Note that some people not only use broken user agents but also
  58 ;; practice a bad citation style by omitting blank lines between the
  59 ;; cited text and their own text.
  60 ;:
  61 ;; Example #2
  62 ;; ----------
  63 ;;
  64 ;; John Doe wrote:
  65 ;;
  66 ;; > This sentence no verb.  This sentence no verb.  This sentence no
  67 ;; You forgot in all your sentences.
  68 ;; > verb.  This sentence no verb.  This sentence no verb.  This
  69 ;; > sentence no verb.
  70 ;;
  71 ;; Unwrapping "You forgot in all your sentences." would be illegal as
  72 ;; this part wasn't intended to be cited text.
  73 ;; `gnus-article-outlook-unwrap-lines' will only unwrap lines if the resulting
  74 ;; citation line will be of a certain maximum length.  You can control
  75 ;; this by adjusting `gnus-outlook-deuglify-unwrap-max'.  Also
  76 ;; unwrapping will only be done if the line above the (possibly)
  77 ;; wrapped line has a minimum length of `gnus-outlook-deuglify-unwrap-min'.
  78 ;;
  79 ;; Furthermore no unwrapping will be undertaken if the last character
  80 ;; is one of the chars specified in
  81 ;; `gnus-outlook-deuglify-unwrap-stop-chars'.  Setting this to ".?!"
  82 ;; inhibits unwrapping if the cited line ends with a full stop,
  83 ;; question mark or exclamation mark.  Note that this variable
  84 ;; defaults to `nil', triggering a few false positives but generally
  85 ;; giving you better results.
  86 ;;
  87 ;; Unwrapping works on every level of citation.  Thus you will be able
  88 ;; repair broken citations of broken user agents citing broken
  89 ;; citations of broken user agents citing broken citations...
  90 ;;
  91 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  92 ;;
  93 ;; Citations are commonly introduced with an attribution line
  94 ;; indicating who wrote the cited text.  Outlook adds superfluous
  95 ;; information that can be found in the header of the message to this
  96 ;; line and often wraps it.
  97 ;;
  98 ;; If that weren't enough, lots of people write their own text above
  99 ;; the cited text and cite the complete original article below.
 100 ;;
 101 ;; Example #3
 102 ;; ----------
 103 ;;
 104 ;; Hey, John.  There's no in all your sentences!
 105 ;;
 106 ;; John Doe <john.doe@some.domain> wrote in message
 107 ;; news:a87usw8$dklsssa$2@some.news.server...
 108 ;; > This sentence no verb.  This sentence no verb.  This sentence
 109 ;; no
 110 ;; > verb.  This sentence no verb.  This sentence no verb.  This
 111 ;; > sentence no verb.
 112 ;; >
 113 ;; > Bye, John
 114 ;;
 115 ;; Repairing the attribution line will be done by function
 116 ;; `gnus-article-outlook-repair-attribution which calls other function that
 117 ;; try to recognize and repair broken attribution lines.  See variable
 118 ;; `gnus-outlook-deuglify-attrib-cut-regexp' for stuff that should be
 119 ;; cut off from the beginning of an attribution line and variable
 120 ;; `gnus-outlook-deuglify-attrib-verb-regexp' for the verbs that are
 121 ;; required to be found in an attribution line.  These function return
 122 ;; the point where the repaired attribution line starts.
 123 ;;
 124 ;; Rearranging the article so that the cited text appears above the
 125 ;; new text will be done by function
 126 ;; `gnus-article-outlook-rearrange-citation'.  This function calls
 127 ;; `gnus-article-outlook-repair-attribution to find and repair an attribution
 128 ;; line.
 129 ;;
 130 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 131 ;;
 132 ;; Well, and that's what the message will look like after applying
 133 ;; deuglification:
 134 ;;
 135 ;; Example #3 (deuglified)
 136 ;; -----------------------
 137 ;;
 138 ;; John Doe <john.doe@some.domain> wrote:
 139 ;;
 140 ;; > This sentence no verb.  This sentence no verb.  This sentence no
 141 ;; > verb.  This sentence no verb.  This sentence no verb.  This
 142 ;; > sentence no verb.
 143 ;; >
 144 ;; > Bye, John
 145 ;;
 146 ;; Hey, John.  There's no in all your sentences!
 147 ;;
 148 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 149 ;;
 150 ;; Usage
 151 ;; -----
 152 ;;
 153 ;; Press `W k' in the Summary Buffer.
 154 ;;
 155 ;; Non recommended usage :-)
 156 ;; ---------------------
 157 ;;
 158 ;; To automatically invoke deuglification on every article you read,
 159 ;; put something like that in your .gnus:
 160 ;;
 161 ;; (add-hook 'gnus-article-decode-hook 'gnus-article-outlook-unwrap-lines)
 162 ;;
 163 ;; or _one_ of the following lines:
 164 ;;
 165 ;; ;; repair broken attribution lines
 166 ;; (add-hook 'gnus-article-decode-hook 'gnus-article-outlook-repair-attribution)
 167 ;;
 168 ;; ;; repair broken attribution lines and citations
 169 ;; (add-hook 'gnus-article-decode-hook 'gnus-article-outlook-rearrange-citation)
 170 ;;
 171 ;; Note that there always may be some false positives, so I suggest
 172 ;; using the manual invocation.  After deuglification you may want to
 173 ;; refill the whole article using `W w'.
 174 ;;
 175 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 176 ;;
 177 ;; Limitations
 178 ;; -----------
 179 ;;
 180 ;; As I said before there may (or will) be a few false positives on
 181 ;; unwrapping cited lines with `gnus-article-outlook-unwrap-lines'.
 182 ;;
 183 ;; `gnus-article-outlook-repair-attribution will only fix the first
 184 ;; attribution line found in the article.  Furthermore it fixed to
 185 ;; certain kinds of attributions.  And there may be horribly many
 186 ;; false positives, vanishing lines and so on -- so don't trust your
 187 ;; eyes.  Again I recommend manual invocation.
 188 ;;
 189 ;; `gnus-article-outlook-rearrange-citation' carries all the limitations of
 190 ;; `gnus-article-outlook-repair-attribution.
 191 ;;
 192 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 193 ;;
 194 ;; See ChangeLog for other changes.
 195 ;;
 196 ;; Revision 1.5  2002/01/27 14:39:17  rscholz
 197 ;; * New variable `gnus-outlook-deuglify-no-wrap-chars' to inhibit
 198 ;;   unwrapping if one these chars is first in the possibly wrapped line.
 199 ;; * Improved rearranging of the article.
 200 ;; * New function `gnus-outlook-repair-attribution-block' for repairing
 201 ;;   those big "Original Message (following some headers)" attributions.
 202 ;;
 203 ;; Revision 1.4  2002/01/03 14:05:00  rscholz
 204 ;; Renamed `gnus-outlook-deuglify-article' to
 205 ;; `gnus-article-outlook-deuglify-article'.
 206 ;; Made it easier to deuglify the article while being in Gnus' Article
 207 ;; Edit Mode.  (suggested by Phil Nitschke)
 208 ;;
 209 ;;
 210 ;; Revision 1.3  2002/01/02 23:35:54  rscholz
 211 ;; Fix a bug that caused succeeding long attribution lines to be
 212 ;; unwrapped.  Minor doc fixes and regular expression tuning.
 213 ;;
 214 ;; Revision 1.2  2001/12/30 20:14:34  rscholz
 215 ;; Clean up source.
 216 ;;
 217 ;; Revision 1.1  2001/12/30 20:13:32  rscholz
 218 ;; Initial revision
 219 ;;
 220 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 221
 222 ;;; Code:
 223
 224 (require 'gnus-art)
 225 (require 'gnus-sum)
 226
 227 (defconst gnus-outlook-deuglify-version "1.5 Gnus version"
 228   "Version of gnus-outlook-deuglify.")
 229
 230 ;;; User Customizable Variables:
 231
 232 (defgroup gnus-outlook-deuglify nil
 233   "Deuglify articles generated by broken user agents like MS Outlook (Express)."
 234   :version "21.4")
 235
 236 ;;;###autoload
 237 (defcustom gnus-outlook-deuglify-unwrap-min 45
 238   "Minimum length of the cited line above the (possibly) wrapped line."
 239   :version "21.4"
 240   :type 'integer
 241   :group 'gnus-outlook-deuglify)
 242
 243 ;;;###autoload
 244 (defcustom gnus-outlook-deuglify-unwrap-max 95
 245   "Maximum length of the cited line after unwrapping."
 246   :version "21.4"
 247   :type 'integer
 248   :group 'gnus-outlook-deuglify)
 249
 250 (defcustom gnus-outlook-deuglify-cite-marks ">|#%"
 251   "Characters that indicate cited lines."
 252   :version "21.4"
 253   :type 'string
 254   :group 'gnus-outlook-deuglify)
 255
 256 (defcustom gnus-outlook-deuglify-unwrap-stop-chars nil ;; ".?!" or nil
 257   "Characters that inhibit unwrapping if they are the last one on the cited line above the possible wrapped line."
 258   :version "21.4"
 259   :type '(radio (const :format "None  " nil)
 260                 (string :value ".?!"))
 261   :group 'gnus-outlook-deuglify)
 262
 263 (defcustom gnus-outlook-deuglify-no-wrap-chars "`"
 264   "Characters that inhibit unwrapping if they are the first one in the possibly wrapped line."
 265   :version "21.4"
 266   :type 'string
 267   :group 'gnus-outlook-deuglify)
 268
 269 (defcustom  gnus-outlook-deuglify-attrib-cut-regexp
 270   "\\(On \\|Am \\)?\\(Mon\\|Tue\\|Wed\\|Thu\\|Fri\\|Sat\\|Sun\\),[^,]+, "
 271   "Regular expression matching the beginning of an attribution line that should be cut off."
 272   :version "21.4"
 273   :type 'string
 274   :group 'gnus-outlook-deuglify)
 275
 276 (defcustom gnus-outlook-deuglify-attrib-verb-regexp
 277   "wrote\\|writes\\|says\\|schrieb\\|schreibt\\|meinte\\|skrev\\|a écrit\\|schreef\\|escribió"
 278   "Regular expression matching the verb used in an attribution line."
 279   :version "21.4"
 280   :type 'string
 281   :group 'gnus-outlook-deuglify)
 282
 283 (defcustom  gnus-outlook-deuglify-attrib-end-regexp
 284   ": *\\|\\.\\.\\."
 285   "Regular expression matching the end of an attribution line."
 286   :version "21.4"
 287   :type 'string
 288   :group 'gnus-outlook-deuglify)
 289
 290 ;;;###autoload
 291 (defcustom gnus-outlook-display-hook nil
 292   "A hook called after an deuglified article has been prepared.
 293 It is run after `gnus-article-prepare-hook'."
 294   :version "21.4"
 295   :type 'hook
 296   :group 'gnus-outlook-deuglify)
 297
 298 ;; Functions
 299
 300 (defun gnus-outlook-display-article-buffer ()
 301   "Redisplay current buffer or article buffer."
 302   (with-current-buffer (or gnus-article-buffer (current-buffer))
 303     ;; "Emulate" `gnus-article-prepare-display' without calling
 304     ;; it. Calling `gnus-article-prepare-display' on an already
 305     ;; prepared article removes all MIME parts.  I'm unsure whether
 306     ;; this is a bug or not.
 307     (gnus-article-highlight t)
 308     (gnus-treat-article nil)
 309     (gnus-run-hooks 'gnus-article-prepare-hook
 310                     'gnus-outlook-display-hook)))
 311
 312 ;;;###autoload
 313 (defun gnus-article-outlook-unwrap-lines (&optional nodisplay)
 314   "Unwrap lines that appear to be wrapped citation lines.
 315 You can control what lines will be unwrapped by frobbing
 316 `gnus-outlook-deuglify-unwrap-min' and `gnus-outlook-deuglify-unwrap-max',
 317 indicating the minimum and maximum length of an unwrapped citation line.  If
 318 NODISPLAY is non-nil, don't redisplay the article buffer."
 319   (interactive "P")
 320   (let ((case-fold-search nil)
 321         (inhibit-read-only t)
 322         (cite-marks gnus-outlook-deuglify-cite-marks)
 323         (no-wrap gnus-outlook-deuglify-no-wrap-chars)
 324         (stop-chars gnus-outlook-deuglify-unwrap-stop-chars))
 325     (gnus-with-article-buffer
 326       (article-goto-body)
 327       (while (re-search-forward
 328               (concat
 329                "^\\([ \t" cite-marks "]*\\)"
 330                "\\([" cite-marks "].*[^\n " stop-chars "]\\)[ \t]?\n"
 331                "\\1\\([^\n " cite-marks no-wrap "]+.*\\)$")
 332               nil t)
 333         (let ((len12 (- (match-end 2) (match-beginning 1)))
 334               (len3 (- (match-end 3) (match-beginning 3))))
 335           (when (and (> len12 gnus-outlook-deuglify-unwrap-min)
 336                      (< (+ len12 len3) gnus-outlook-deuglify-unwrap-max))
 337             (replace-match "\\1\\2 \\3")
 338             (goto-char (match-beginning 0)))))))
 339   (unless nodisplay (gnus-outlook-display-article-buffer)))
 340
 341 (defun gnus-outlook-rearrange-article (attr-start)
 342   "Put the text from ATTR-START to the end of buffer at the top of the article buffer."
 343   (let ((inhibit-read-only t)
 344         (cite-marks gnus-outlook-deuglify-cite-marks))
 345     (gnus-with-article-buffer
 346       (article-goto-body)
 347       ;; article does not start with attribution
 348       (unless (= (point) attr-start)
 349         (gnus-kill-all-overlays)
 350         (let ((cur (point))
 351               ;; before signature or end of buffer
 352               (to (if (gnus-article-search-signature)
 353                       (point)
 354                     (point-max))))
 355           ;; handle the case where the full quote is below the
 356           ;; signature
 357           (if (< to attr-start)
 358               (setq to (point-max)))
 359           (transpose-regions cur attr-start attr-start to))))))
 360
 361 ;; John Doe <john.doe@some.domain> wrote in message
 362 ;; news:a87usw8$dklsssa$2@some.news.server...
 363
 364 (defun gnus-outlook-repair-attribution-outlook ()
 365   "Repair a broken attribution line (Outlook)."
 366   (let ((case-fold-search nil)
 367         (inhibit-read-only t)
 368         (cite-marks gnus-outlook-deuglify-cite-marks))
 369     (gnus-with-article-buffer
 370       (article-goto-body)
 371       (when (re-search-forward
 372              (concat "^\\([^" cite-marks "].+\\)"
 373                      "\\(" gnus-outlook-deuglify-attrib-verb-regexp "\\)"
 374                      "\\(.*\n?[^\n" cite-marks "].*\\)?"
 375                      "\\(" gnus-outlook-deuglify-attrib-end-regexp "\\)$")
 376              nil t)
 377         (gnus-kill-all-overlays)
 378         (replace-match "\\1\\2\\4")
 379         (match-beginning 0)))))
 380
 381
 382 ;; ----- Original Message -----
 383 ;; From: "John Doe" <john.doe@some.domain>
 384 ;; To: "Doe Foundation" <info@doefnd.org>
 385 ;; Sent: Monday, November 19, 2001 12:13 PM
 386 ;; Subject: More Doenuts
 387
 388 (defun gnus-outlook-repair-attribution-block ()
 389   "Repair a big broken attribution block."
 390   (let ((case-fold-search nil)
 391         (inhibit-read-only t)
 392         (cite-marks gnus-outlook-deuglify-cite-marks))
 393     (gnus-with-article-buffer
 394       (article-goto-body)
 395       (when (re-search-forward
 396              (concat "^[" cite-marks " \t]*--* ?[^-]+ [^-]+ ?--*\\s *\n"
 397                      "[^\n:]+:[ \t]*\\([^\n]+\\)\n"
 398                      "\\([^\n:]+:[ \t]*[^\n]+\n\\)+")
 399              nil t)
 400         (gnus-kill-all-overlays)
 401         (replace-match "\\1 wrote:\n")
 402         (match-beginning 0)))))
 403
 404 ;; On Wed, 16 Jan 2002 23:23:30 +0100, John Doe <john.doe@some.domain> wrote:
 405
 406 (defun gnus-outlook-repair-attribution-other ()
 407   "Repair a broken attribution line (other user agents than Outlook)."
 408   (let ((case-fold-search nil)
 409         (inhibit-read-only t)
 410         (cite-marks gnus-outlook-deuglify-cite-marks))
 411     (gnus-with-article-buffer
 412       (article-goto-body)
 413       (when (re-search-forward
 414              (concat "^\\("gnus-outlook-deuglify-attrib-cut-regexp"\\)?"
 415                      "\\([^" cite-marks "].+\\)\n\\([^\n" cite-marks "].*\\)?"
 416                      "\\(" gnus-outlook-deuglify-attrib-verb-regexp "\\).*"
 417                      "\\(" gnus-outlook-deuglify-attrib-end-regexp "\\)$")
 418              nil t)
 419         (gnus-kill-all-overlays)
 420         (replace-match "\\4 \\5\\6\\7")
 421         (match-beginning 0)))))
 422
 423 ;;;###autoload
 424 (defun gnus-article-outlook-repair-attribution (&optional nodisplay)
 425   "Repair a broken attribution line.
 426 If NODISPLAY is non-nil, don't redisplay the article buffer."
 427   (interactive "P")
 428   (let ((attrib-start
 429          (or
 430           (gnus-outlook-repair-attribution-other)
 431           (gnus-outlook-repair-attribution-block)
 432           (gnus-outlook-repair-attribution-outlook))))
 433     (unless nodisplay (gnus-outlook-display-article-buffer))
 434     attrib-start))
 435
 436 (defun gnus-article-outlook-rearrange-citation (&optional nodisplay)
 437   "Repair broken citations.
 438 If NODISPLAY is non-nil, don't redisplay the article buffer."
 439   (interactive "P")
 440   (let ((attrib-start (gnus-article-outlook-repair-attribution 'nodisplay)))
 441     ;; rearrange citations if an attribution line has been recognized
 442     (if attrib-start
 443         (gnus-outlook-rearrange-article attrib-start)))
 444   (unless nodisplay (gnus-outlook-display-article-buffer)))
 445
 446 ;;;###autoload
 447 (defun gnus-outlook-deuglify-article (&optional nodisplay)
 448   "Full deuglify of broken Outlook (Express) articles.
 449 Treat dumbquotes, unwrap lines, repair attribution and rearrange citation.  If
 450 NODISPLAY is non-nil, don't redisplay the article buffer."
 451   (interactive "P")
 452   ;; apply treatment of dumb quotes
 453   (gnus-article-treat-dumbquotes)
 454   ;; repair wrapped cited lines
 455   (gnus-article-outlook-unwrap-lines 'nodisplay)
 456   ;; repair attribution line and rearrange citation.
 457   (gnus-article-outlook-rearrange-citation 'nodisplay)
 458   (unless nodisplay (gnus-outlook-display-article-buffer)))
 459
 460 ;;;###autoload
 461 (defun gnus-article-outlook-deuglify-article ()
 462   "Deuglify broken Outlook (Express) articles and redisplay."
 463   (interactive)
 464   (gnus-outlook-deuglify-article nil))
 465
 466 (provide 'deuglify)
 467
 468 ;; Local Variables:
 469 ;; coding: iso-8859-1
 470 ;; End:
 471
 472 ;;; arch-tag: 5f895cc9-51a9-487c-b42e-28844d79eb73
 473 ;;; deuglify.el ends here