cgit.sxemacs.org Git - gnus/blob - contrib/hashcash.el

   1 ;;; hashcash.el --- Add hashcash payments to email
   2
   3 ;; $Revision: 1.10 $
   4 ;; Copyright (C) 1997--2002 Paul E. Foley
   5 ;; Copyright (C) 2003 Free Software Foundation
   6
   7 ;; Maintainer: Paul Foley <mycroft@actrix.gen.nz>
   8 ;; Keywords: mail, hashcash
   9
  10 ;; Released under the GNU General Public License
  11 ;;   (http://www.gnu.org/licenses/gpl.html)
  12
  13 ;;; Commentary:
  14
  15 ;; The hashcash binary is at http://www.cypherspace.org/hashcash/
  16 ;;
  17 ;; Call mail-add-payment to add a hashcash payment to a mail message
  18 ;; in the current buffer.
  19 ;;
  20 ;; To automatically add payments to all outgoing mail:
  21 ;;    (add-hook 'message-send-hook 'mail-add-payment)
  22
  23 ;;; Code:
  24
  25 (eval-and-compile
  26  (autoload 'executable-find "executable"))
  27
  28 (defcustom hashcash-default-payment 0
  29   "*The default number of bits to pay to unknown users.
  30 If this is zero, no payment header will be generated.
  31 See `hashcash-payment-alist'."
  32   :type 'integer)
  33
  34 (defcustom hashcash-payment-alist '()
  35   "*An association list mapping email addresses to payment amounts.
  36 Elements may consist of (ADDR AMOUNT) or (ADDR STRING AMOUNT), where
  37 ADDR is the email address of the intended recipient and AMOUNT is
  38 the value of hashcash payment to be made to that user.  STRING, if
  39 present, is the string to be hashed; if not present ADDR will be used.")
  40
  41 (defcustom hashcash-default-accept-payment 10
  42   "*The default minimum number of bits to accept on incoming payments."
  43   :type 'integer)
  44
  45 (defcustom hashcash-accept-resources `((,user-mail-address nil))
  46   "*An association list mapping hashcash resources to payment amounts.
  47 Resources named here are to be accepted in incoming payments.  If the
  48 corresponding AMOUNT is NIL, the value of `hashcash-default-accept-payment'
  49 is used instead.")
  50
  51 (defcustom hashcash-path (executable-find "hashcash")
  52   "*The path to the hashcash binary.")
  53
  54 (defcustom hashcash-double-spend-database "hashcash.db"
  55   "*The path to the double-spending database.")
  56
  57 (defcustom hashcash-in-news nil
  58   "*Specifies whether or not hashcash payments should be made to newsgroups."
  59   :type 'boolean)
  60
  61 (require 'mail-utils)
  62
  63 (if (fboundp 'point-at-bol)
  64     (defalias 'hashcash-point-at-bol 'point-at-bol)
  65   (defalias 'hashcash-point-at-bol 'line-beginning-position))
  66
  67 (if (fboundp 'point-at-eol)
  68     (defalias 'hashcash-point-at-eol 'point-at-eol)
  69   (defalias 'hashcash-point-at-eol 'line-end-position))
  70
  71 (defun hashcash-strip-quoted-names (addr)
  72   (setq addr (mail-strip-quoted-names addr))
  73   (if (and addr (string-match "^[^+@]+\\(\\+[^@]*\\)@" addr))
  74       (concat (subseq addr 0 (match-beginning 1)) (subseq addr (match-end 1)))
  75     addr))
  76
  77 (defun hashcash-payment-required (addr)
  78   "Return the hashcash payment value required for the given address."
  79   (let ((val (assoc addr hashcash-payment-alist)))
  80     (if val
  81         (if (cddr val)
  82             (caddr val)
  83           (cadr val))
  84       hashcash-default-payment)))
  85
  86 (defun hashcash-payment-to (addr)
  87   "Return the string with which hashcash payments should collide."
  88   (let ((val (assoc addr hashcash-payment-alist)))
  89     (if val
  90         (if (cddr val)
  91             (cadr val)
  92           (car val))
  93       addr)))
  94
  95 (defun hashcash-generate-payment (str val)
  96   "Generate a hashcash payment by finding a VAL-bit collison on STR."
  97   (if (> val 0)
  98       (save-excursion
  99         (set-buffer (get-buffer-create " *hashcash*"))
 100         (erase-buffer)
 101         (call-process hashcash-path nil t nil
 102                       (concat "-b " (number-to-string val)) str)
 103         (goto-char (point-min))
 104         (buffer-substring (hashcash-point-at-bol) (hashcash-point-at-eol)))
 105     nil))
 106
 107 (defun hashcash-check-payment (token str val)
 108   "Check the validity of a hashcash payment."
 109   (zerop (call-process hashcash-path nil nil nil "-c"
 110                        "-d" "-f" hashcash-double-spend-database
 111                        "-b" (number-to-string val)
 112                        "-r" str
 113                        token)))
 114
 115 (defun hashcash-version (token)
 116   "Find the format version of a hashcash token."
 117   ;; Version 1.2 looks like n:yymmdd:rrrrr:xxxxxxxxxxxxxxxx
 118   ;;   This carries its own version number embedded in the token,
 119   ;;   so no further format number changes should be necessary
 120   ;;   in the X-Payment header.
 121   ;;
 122   ;; Version 1.1 looks like yymmdd:rrrrr:xxxxxxxxxxxxxxxx
 123   ;;   You need to upgrade your hashcash binary.
 124   ;;
 125   ;; Version 1.0 looked like nnnnnrrrrrxxxxxxxxxxxxxxxx
 126   ;;   This is no longer supported.
 127   (cond ((equal (aref token 1) ?:) 1.2)
 128         ((equal (aref token 6) ?:) 1.1)
 129         (t (error "Unknown hashcash format version"))))
 130
 131 ;;;###autoload
 132 (defun hashcash-insert-payment (arg)
 133   "Insert X-Payment and X-Hashcash headers with a payment for ARG"
 134   (interactive "sPay to: ")
 135   (let ((pay (hashcash-generate-payment (hashcash-payment-to arg)
 136                                         (hashcash-payment-required arg))))
 137     (when pay
 138       (insert-before-markers "X-Payment: hashcash "
 139                              (number-to-string (hashcash-version pay)) " "
 140                              pay "\n")
 141       (insert-before-markers "X-Hashcash: " pay "\n"))))
 142
 143 ;;;###autoload
 144 (defun hashcash-verify-payment (token &optional resource amount)
 145   "Verify a hashcash payment"
 146   (let ((key (if (< (hashcash-version token) 1.2)
 147                  (cadr (split-string token ":"))
 148                  (caddr (split-string token ":")))))
 149     (cond ((null resource)
 150            (let ((elt (assoc key hashcash-accept-resources)))
 151              (and elt (hashcash-check-payment token (car elt)
 152                         (or (cadr elt) hashcash-default-accept-payment)))))
 153           ((equal token key)
 154            (hashcash-check-payment token resource
 155                                 (or amount hashcash-default-accept-payment)))
 156           (t nil))))
 157
 158 ;;;###autoload
 159 (defun mail-add-payment (&optional arg)
 160   "Add X-Payment: and X-Hashcash: headers with a hashcash payment
 161 for each recipient address.  Prefix arg sets default payment temporarily."
 162   (interactive "P")
 163   (let ((hashcash-default-payment (if arg (prefix-numeric-value arg)
 164                                     hashcash-default-payment))
 165         (addrlist nil))
 166     (save-excursion
 167       (save-restriction
 168         (goto-char (point-min))
 169         (search-forward mail-header-separator)
 170         (beginning-of-line)
 171         (narrow-to-region (point-min) (point))
 172         (let ((to (hashcash-strip-quoted-names (mail-fetch-field "To" nil t)))
 173               (cc (hashcash-strip-quoted-names (mail-fetch-field "Cc" nil t)))
 174               (ng (hashcash-strip-quoted-names (mail-fetch-field "Newsgroups"
 175                                                                  nil t))))
 176           (when to
 177             (setq addrlist (split-string to ",[ \t\n]*")))
 178           (when cc
 179             (setq addrlist (nconc addrlist (split-string cc ",[ \t\n]*"))))
 180           (when (and hashcash-in-news ng)
 181             (setq addrlist (nconc addrlist (split-string ng ",[ \t\n]*")))))
 182         (when addrlist
 183           (mapc #'hashcash-insert-payment addrlist)))))
 184   t)
 185
 186 ;;;###autoload
 187 (defun mail-check-payment (&optional arg)
 188   "Look for a valid X-Payment: or X-Hashcash: header.
 189 Prefix arg sets default accept amount temporarily."
 190   (interactive "P")
 191   (let ((hashcash-default-accept-payment (if arg (prefix-numeric-value arg)
 192                                            hashcash-default-accept-payment))
 193         (version (hashcash-version (hashcash-generate-payment "x" 1))))
 194     (save-excursion
 195       (goto-char (point-min))
 196       (search-forward "\n\n")
 197       (beginning-of-line)
 198       (let ((end (point))
 199             (ok nil))
 200         (goto-char (point-min))
 201         (while (and (not ok) (search-forward "X-Payment: hashcash " end t))
 202           (let ((value (split-string
 203                           (buffer-substring (point) (hashcash-point-at-eol))
 204                           " ")))
 205             (when (equal (car value) (number-to-string version))
 206               (setq ok (hashcash-verify-payment (cadr value))))))
 207         (goto-char (point-min))
 208         (while (and (not ok) (search-forward "X-Hashcash: " end t))
 209           (setq ok (hashcash-verify-payment
 210                     (buffer-substring (point) (hashcash-point-at-eol)))))
 211         (when ok
 212           (message "Payment valid"))
 213         ok))))
 214
 215 (provide 'hashcash)